OVMF ResetVector: Modify interface with SEC module

[mirror_edk2.git] / OvmfPkg / ResetVector / Ia32 / SearchForBfvBase.asm

;------------------------------------------------------------------------------\r
; @file\r
; Search for the Boot Firmware Volume (BFV) base address\r
;\r
; Copyright (c) 2008 - 2009, Intel Corporation\r
; All rights reserved. This program and the accompanying materials\r
; are licensed and made available under the terms and conditions of the BSD License\r
; which accompanies this distribution.  The full text of the license may be found at\r
; http://opensource.org/licenses/bsd-license.php\r
;\r
; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
;\r
;------------------------------------------------------------------------------\r
\r
;#define EFI_FIRMWARE_FILE_SYSTEM2_GUID \\r
;  { 0x8c8ce578, 0x8a3d, 0x4f1c, { 0x99, 0x35, 0x89, 0x61, 0x85, 0xc3, 0x2d, 0xd3 } }\r
%define FFS_GUID_DWORD0 0x8c8ce578\r
%define FFS_GUID_DWORD1 0x4f1c8a3d\r
%define FFS_GUID_DWORD2 0x61893599\r
%define FFS_GUID_DWORD3 0xd32dc385\r
\r
BITS    32\r
\r
;\r
; Modified:  EAX, EBX\r
; Preserved: EDI, ESP\r
;\r
; @param[out]  EBP  Address of Boot Firmware Volume (BFV)\r
;\r
Flat32SearchForBfvBase:\r
\r
    xor     eax, eax\r
searchingForBfvHeaderLoop:\r
    ;\r
    ; We check for a firmware volume at every 4KB address in the top 16MB\r
    ; just below 4GB.  (Addresses at 0xffHHH000 where H is any hex digit.)\r
    ;\r
    sub     eax, 0x1000\r
    cmp     eax, 0xff000000\r
    jb      searchedForBfvHeaderButNotFound\r
\r
    ;\r
    ; Check FFS GUID\r
    ;\r
    cmp     dword [eax + 0x10], FFS_GUID_DWORD0\r
    jne     searchingForBfvHeaderLoop\r
    cmp     dword [eax + 0x14], FFS_GUID_DWORD1\r
    jne     searchingForBfvHeaderLoop\r
    cmp     dword [eax + 0x18], FFS_GUID_DWORD2\r
    jne     searchingForBfvHeaderLoop\r
    cmp     dword [eax + 0x1c], FFS_GUID_DWORD3\r
    jne     searchingForBfvHeaderLoop\r
\r
    ;\r
    ; Check FV Length\r
    ;\r
    cmp     dword [eax + 0x24], 0\r
    jne     searchingForBfvHeaderLoop\r
    mov     ebx, eax\r
    add     ebx, dword [eax + 0x20]\r
    jnz     searchingForBfvHeaderLoop\r
\r
    jmp     searchedForBfvHeaderAndItWasFound\r
\r
searchedForBfvHeaderButNotFound:\r
    ;\r
    ; Hang if the SEC entry point was not found\r
    ;\r
    debugShowPostCode POSTCODE_BFV_NOT_FOUND\r
\r
    ;\r
    ; 0xbfbfbfbf in the EAX & EBP registers helps signal what failed\r
    ; for debugging purposes.\r
    ;\r
    mov     eax, 0xBFBFBFBF\r
    mov     ebp, eax\r
    jmp     $\r
\r
searchedForBfvHeaderAndItWasFound:\r
    mov     ebp, eax\r
\r
    debugShowPostCode POSTCODE_BFV_FOUND\r
\r
    OneTimeCallRet Flat32SearchForBfvBase\r
\r