OvmfPkg/Sec: Move TDX APs related nasm code to IntelTdxAPs.nasm

[mirror_edk2.git] / OvmfPkg / Sec / X64 / SecEntry.nasm

;------------------------------------------------------------------------------\r
;*\r
;*   Copyright (c) 2006 - 2013, Intel Corporation. All rights reserved.<BR>\r
;*   SPDX-License-Identifier: BSD-2-Clause-Patent\r
;*\r
;*    CpuAsm.asm\r
;*\r
;*   Abstract:\r
;*\r
;------------------------------------------------------------------------------\r
\r
#include <Base.h>\r
\r
DEFAULT REL\r
SECTION .text\r
\r
extern ASM_PFX(SecCoreStartupWithStack)\r
\r
%macro  tdcall  0\r
  db  0x66, 0x0f, 0x01, 0xcc\r
%endmacro\r
\r
;\r
; SecCore Entry Point\r
;\r
; Processor is in flat protected mode\r
;\r
; @param[in]  RAX   Initial value of the EAX register (BIST: Built-in Self Test)\r
; @param[in]  DI    'BP': boot-strap processor, or 'AP': application processor\r
; @param[in]  RBP   Pointer to the start of the Boot Firmware Volume\r
; @param[in]  DS    Selector allowing flat access to all addresses\r
; @param[in]  ES    Selector allowing flat access to all addresses\r
; @param[in]  FS    Selector allowing flat access to all addresses\r
; @param[in]  GS    Selector allowing flat access to all addresses\r
; @param[in]  SS    Selector allowing flat access to all addresses\r
;\r
; @return     None  This routine does not return\r
;\r
global ASM_PFX(_ModuleEntryPoint)\r
ASM_PFX(_ModuleEntryPoint):\r
\r
    ;\r
    ; Guest type is stored in OVMF_WORK_AREA\r
    ;\r
    %define OVMF_WORK_AREA        FixedPcdGet32 (PcdOvmfWorkAreaBase)\r
    %define VM_GUEST_TYPE_TDX     2\r
    mov     eax, OVMF_WORK_AREA\r
    cmp     byte[eax], VM_GUEST_TYPE_TDX\r
    jne     InitStack\r
\r
    %define TDCALL_TDINFO         1\r
    mov     rax, TDCALL_TDINFO\r
    tdcall\r
\r
    ;\r
    ; R8  [31:0]  NUM_VCPUS\r
    ;     [63:32] MAX_VCPUS\r
    ; R9  [31:0]  VCPU_INDEX\r
    ; Td Guest set the VCPU0 as the BSP, others are the APs\r
    ; APs jump to spinloop and get released by DXE's MpInitLib\r
    ;\r
    mov     rax, r9\r
    and     rax, 0xffff\r
    test    rax, rax\r
    jz      InitStack\r
    mov     rsp, FixedPcdGet32 (PcdOvmfSecGhcbBackupBase)\r
    jmp     ParkAp\r
\r
InitStack:\r
\r
    ;\r
    ; Fill the temporary RAM with the initial stack value.\r
    ; The loop below will seed the heap as well, but that's harmless.\r
    ;\r
    mov     rax, (FixedPcdGet32 (PcdInitValueInTempStack) << 32) | FixedPcdGet32 (PcdInitValueInTempStack)\r
                                                              ; qword to store\r
    mov     rdi, FixedPcdGet32 (PcdOvmfSecPeiTempRamBase)     ; base address,\r
                                                              ;   relative to\r
                                                              ;   ES\r
    mov     rcx, FixedPcdGet32 (PcdOvmfSecPeiTempRamSize) / 8 ; qword count\r
    cld                                                       ; store from base\r
                                                              ;   up\r
    rep stosq\r
\r
    ;\r
    ; Load temporary RAM stack based on PCDs\r
    ;\r
    %define SEC_TOP_OF_STACK (FixedPcdGet32 (PcdOvmfSecPeiTempRamBase) + \\r
                          FixedPcdGet32 (PcdOvmfSecPeiTempRamSize))\r
    mov     rsp, SEC_TOP_OF_STACK\r
    nop\r
\r
    ;\r
    ; Setup parameters and call SecCoreStartupWithStack\r
    ;   rcx: BootFirmwareVolumePtr\r
    ;   rdx: TopOfCurrentStack\r
    ;\r
    mov     rcx, rbp\r
    mov     rdx, rsp\r
    sub     rsp, 0x20\r
    call    ASM_PFX(SecCoreStartupWithStack)\r
\r
%include "../../IntelTdx/Sec/X64/IntelTdxAPs.nasm"\r