UefiCpuPkg: Support FFS3 GUID in SearchForBfvBase.asm

[mirror_edk2.git] / UefiCpuPkg / ResetVector / Vtf0 / Ia32 / SearchForBfvBase.asm

;------------------------------------------------------------------------------\r
; @file\r
; Search for the Boot Firmware Volume (BFV) base address\r
;\r
; Copyright (c) 2008 - 2009, Intel Corporation. All rights reserved.<BR>\r
; SPDX-License-Identifier: BSD-2-Clause-Patent\r
;\r
;------------------------------------------------------------------------------\r
\r
;#define EFI_FIRMWARE_FILE_SYSTEM2_GUID \\r
;  { 0x8c8ce578, 0x8a3d, 0x4f1c, { 0x99, 0x35, 0x89, 0x61, 0x85, 0xc3, 0x2d, 0xd3 } }\r
%define FFS2_GUID_DWORD0 0x8c8ce578\r
%define FFS2_GUID_DWORD1 0x4f1c8a3d\r
%define FFS2_GUID_DWORD2 0x61893599\r
%define FFS2_GUID_DWORD3 0xd32dc385\r
\r
;#define EFI_FIRMWARE_FILE_SYSTEM3_GUID \\r
;  { 0x8c8ce578, 0x3dcb, 0x4dca, { 0xbd, 0x6f, 0x1e, 0x96, 0x89, 0xe7, 0x34, 0x9a } }\r
%define FFS3_GUID_DWORD0 0x5473c07a\r
%define FFS3_GUID_DWORD1 0x4dca3dcb\r
%define FFS3_GUID_DWORD2 0x961e6fbd\r
%define FFS3_GUID_DWORD3 0x9a34e789\r
\r
BITS    32\r
\r
;\r
; Modified:  EAX, EBX\r
; Preserved: EDI, ESP\r
;\r
; @param[out]  EBP  Address of Boot Firmware Volume (BFV)\r
;\r
Flat32SearchForBfvBase:\r
\r
    xor     eax, eax\r
    mov     ecx, 3    ; 3: FFS3 GUID, 2: FFS2 GUID, 1: Not Found\r
searchingForBfvHeaderLoop:\r
    ;\r
    ; We check for a firmware volume at every 4KB address in the top 16MB\r
    ; just below 4GB.  (Addresses at 0xffHHH000 where H is any hex digit.)\r
    ;\r
    sub     eax, 0x1000\r
    cmp     eax, 0xff000000\r
    jb      searchingForBfvWithOtherFfsGuid\r
    cmp     ecx, 3\r
    jne     searchingForFfs2Guid\r
\r
    ;\r
    ; Check FFS3 GUID\r
    ;\r
    cmp     dword [eax + 0x10], FFS3_GUID_DWORD0\r
    jne     searchingForBfvHeaderLoop\r
    cmp     dword [eax + 0x14], FFS3_GUID_DWORD1\r
    jne     searchingForBfvHeaderLoop\r
    cmp     dword [eax + 0x18], FFS3_GUID_DWORD2\r
    jne     searchingForBfvHeaderLoop\r
    cmp     dword [eax + 0x1c], FFS3_GUID_DWORD3\r
    jne     searchingForBfvHeaderLoop\r
    jmp     checkingFvLength\r
\r
searchingForFfs2Guid:\r
    ;\r
    ; Check FFS2 GUID\r
    ;\r
    cmp     dword [eax + 0x10], FFS2_GUID_DWORD0\r
    jne     searchingForBfvHeaderLoop\r
    cmp     dword [eax + 0x14], FFS2_GUID_DWORD1\r
    jne     searchingForBfvHeaderLoop\r
    cmp     dword [eax + 0x18], FFS2_GUID_DWORD2\r
    jne     searchingForBfvHeaderLoop\r
    cmp     dword [eax + 0x1c], FFS2_GUID_DWORD3\r
    jne     searchingForBfvHeaderLoop\r
\r
checkingFvLength:\r
    ;\r
    ; Check FV Length\r
    ;\r
    cmp     dword [eax + 0x24], 0\r
    jne     searchingForBfvHeaderLoop\r
    mov     ebx, eax\r
    add     ebx, dword [eax + 0x20]\r
    jnz     searchingForBfvHeaderLoop\r
\r
    jmp     searchedForBfvHeaderAndItWasFound\r
\r
searchingForBfvWithOtherFfsGuid:\r
    xor     eax, eax\r
    dec     ecx\r
    cmp     ecx, 1\r
    jne     searchingForBfvHeaderLoop\r
\r
searchedForBfvHeaderButNotFound:\r
    ;\r
    ; Hang if the SEC entry point was not found\r
    ;\r
    debugShowPostCode POSTCODE_BFV_NOT_FOUND\r
\r
    ;\r
    ; 0xbfbfbfbf in the EAX & EBP registers helps signal what failed\r
    ; for debugging purposes.\r
    ;\r
    mov     eax, 0xBFBFBFBF\r
    mov     ebp, eax\r
    jmp     $\r
\r
searchedForBfvHeaderAndItWasFound:\r
    mov     ebp, eax\r
\r
    debugShowPostCode POSTCODE_BFV_FOUND\r
\r
    OneTimeCallRet Flat32SearchForBfvBase\r
\r