NetworkPkg: Replace BSD License with BSD+Patent License

[mirror_edk2.git] / Vlv2TbltDevicePkg / bld_vlv.bat

@REM @file\r
@REM   Windows batch file to build BIOS ROM\r
@REM\r
@REM Copyright (c) 2006 - 2018, Intel Corporation. All rights reserved.<BR>\r
@REM This program and the accompanying materials\r
@REM are licensed and made available under the terms and conditions of the BSD License\r
@REM which accompanies this distribution.  The full text of the license may be found at\r
@REM http://opensource.org/licenses/bsd-license.php\r
@REM\r
@REM THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
@REM WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
@REM\r
\r
@echo off\r
setlocal EnableDelayedExpansion EnableExtensions\r
echo.\r
echo %date%  %time%\r
echo.\r
\r
\r
::**********************************************************************\r
:: Initial Setup\r
::**********************************************************************\r
set WORKSPACE=%CD%\r
if %WORKSPACE:~-1%==\ set WORKSPACE=%WORKSPACE:~0,-1%\r
set /a build_threads=1\r
set "Build_Flags= "\r
set exitCode=0\r
set Arch=X64\r
set Source=0\r
set CORE_PATH=%WORKSPACE%\edk2\r
set PLATFORM_PATH=%WORKSPACE%\edk2\r
cd ./edk2\r
\r
:: Clean up previous build files.\r
if exist %CORE_PATH%\edk2.log del %CORE_PATH%\edk2.log\r
if exist %CORE_PATH%\unitool.log del %CORE_PATH%\unitool.log\r
if exist %CORE_PATH%\Conf\target.txt del %CORE_PATH%\Conf\target.txt\r
if exist %CORE_PATH%\Conf\tools_def.txt del %CORE_PATH%\Conf\tools_def.txt\r
if exist %CORE_PATH%\Conf\build_rule.txt del %CORE_PATH%\Conf\build_rule.txt\r
if exist %CORE_PATH%\Conf\FrameworkDatabase.db del %CORE_PATH%\Conf\FrameworkDatabase.db\r
if exist conf\.cache rmdir /q/s conf\.cache\r
\r
:: Setup EDK environment. Edksetup puts new copies of target.txt, tools_def.txt, build_rule.txt in WorkSpace\Conf\r
:: Also run edksetup as soon as possible to avoid it from changing environment variables we're overriding\r
call %CORE_PATH%\edksetup.bat Rebuild\r
@echo off\r
\r
:: Define platform specific environment variables.\r
set PLATFORM_NAME=Vlv2TbltDevicePkg\r
set PLATFORM_PACKAGE=%PLATFORM_PATH%\Vlv2TbltDevicePkg\r
set config_file=%PLATFORM_PACKAGE%\PlatformPkgConfig.dsc\r
set auto_config_inc=%PLATFORM_PACKAGE%\AutoPlatformCFG.txt\r
\r
\r
\r
::create new AutoPlatformCFG.txt file\r
copy /y nul %auto_config_inc% >nul\r
\r
::**********************************************************************\r
:: Parse command line arguments\r
::**********************************************************************\r
\r
:: Optional arguments\r
:OptLoop\r
if /i "%~1"=="/?" goto Usage\r
\r
if /i "%~1"=="/l" (\r
    set Build_Flags=%Build_Flags% -j EDK2.log\r
    shift\r
    goto OptLoop\r
)\r
if /i "%~1"=="/y" (\r
    set Build_Flags=%Build_Flags% -y %PLATFORM_PACKAGE%\EDK2_%PLATFORM_PACKAGE%.report\r
    shift\r
    goto OptLoop\r
)\r
if /i "%~1"=="/m" (\r
    if defined NUMBER_OF_PROCESSORS (\r
        set /a build_threads=%NUMBER_OF_PROCESSORS%+1\r
    )\r
    shift\r
    goto OptLoop\r
)\r
if /i "%~1" == "/c" (\r
    echo Removing previous build files ...\r
    if exist build (\r
        del /f/s/q build > nul\r
        rmdir /s/q build\r
    )\r
    if exist conf\.cache (\r
        del /f/s/q conf\.cache > nul\r
        rmdir /s/q conf\.cache\r
    )\r
    echo.\r
    shift\r
    goto OptLoop\r
)\r
\r
if /i "%~1"=="/x64" (\r
    set Arch=X64\r
    shift\r
    goto OptLoop\r
)\r
if /i "%~1"=="/IA32" (\r
    set Arch=IA32\r
    shift\r
    goto OptLoop\r
)\r
\r
:: Required argument(s)\r
if "%~1"=="" goto Usage\r
\r
::Remove the values for Platform_Type and Build_Target from BiosIdX.env and stage in Conf\\r
if "%Arch%"=="IA32" (\r
    findstr /b /v "BOARD_ID  BUILD_TYPE" %PLATFORM_PACKAGE%\BiosIdR.env > Conf\BiosId.env\r
    echo DEFINE X64_CONFIG = FALSE  >> %auto_config_inc%\r
) else if "%Arch%"=="X64" (\r
    findstr /b /v "BOARD_ID  BUILD_TYPE" %PLATFORM_PACKAGE%\BiosIdx64R.env > Conf\BiosId.env\r
    echo DEFINE X64_CONFIG = TRUE  >> %auto_config_inc%\r
)\r
\r
:: -- Build flags settings for each Platform --\r
echo Setting  %1  platform configuration and BIOS ID...\r
if /i "%~1" == "MNW2" (\r
    echo BOARD_ID = MNW2MAX >> Conf\BiosId.env\r
    echo DEFINE ENBDT_PF_BUILD = TRUE   >> %auto_config_inc%\r
    \r
) else (\r
    echo Error - Unsupported PlatformType: %1\r
    goto Usage\r
)\r
set Platform_Type=%~1\r
\r
if /i "%~2" == "RELEASE" (\r
    set target=RELEASE\r
    echo BUILD_TYPE = R >> Conf\BiosId.env\r
) else (\r
    set target=DEBUG\r
    echo BUILD_TYPE = D >> Conf\BiosId.env\r
)\r
\r
::**********************************************************************\r
:: Additional EDK Build Setup/Configuration\r
::**********************************************************************\r
echo.\r
echo Setting the Build environment for VS2015/VS2013/VS2012/VS2010/VS2008...\r
if defined VS140COMNTOOLS (\r
  if not defined VSINSTALLDIR call "%VS140COMNTOOLS%\vsvars32.bat"\r
  if /I "%VS140COMNTOOLS%" == "C:\Program Files\Microsoft Visual Studio 14.0\Common7\Tools\" (\r
    set TOOL_CHAIN_TAG=VS2015\r
  ) else (\r
    set TOOL_CHAIN_TAG=VS2015x86\r
  ) \r
) else if defined VS120COMNTOOLS (\r
  if not defined VSINSTALLDIR call "%VS120COMNTOOLS%\vsvars32.bat"\r
  if /I "%VS120COMNTOOLS%" == "C:\Program Files\Microsoft Visual Studio 12.0\Common7\Tools\" (\r
    set TOOL_CHAIN_TAG=VS2013\r
  ) else (\r
    set TOOL_CHAIN_TAG=VS2013x86\r
  )\r
) else if defined VS110COMNTOOLS (\r
  if not defined VSINSTALLDIR call "%VS110COMNTOOLS%\vsvars32.bat"\r
  if /I "%VS110COMNTOOLS%" == "C:\Program Files\Microsoft Visual Studio 11.0\Common7\Tools\" (\r
    set TOOL_CHAIN_TAG=VS2012\r
  ) else (\r
    set TOOL_CHAIN_TAG=VS2012x86\r
  )\r
) else if defined VS100COMNTOOLS (\r
  if not defined VSINSTALLDIR call "%VS100COMNTOOLS%\vsvars32.bat"\r
  if /I "%VS100COMNTOOLS%" == "C:\Program Files\Microsoft Visual Studio 10.0\Common7\Tools\" (\r
    set TOOL_CHAIN_TAG=VS2010\r
  ) else (\r
    set TOOL_CHAIN_TAG=VS2010x86\r
  )\r
) else if defined VS90COMNTOOLS (\r
  if not defined VSINSTALLDIR call "%VS90COMNTOOLS%\vsvars32.bat"\r
  if /I "%VS90COMNTOOLS%" == "C:\Program Files\Microsoft Visual Studio 9.0\Common7\Tools\" (\r
     set TOOL_CHAIN_TAG=VS2008\r
  ) else (\r
     set TOOL_CHAIN_TAG=VS2008x86\r
  )\r
) else (\r
  echo  --ERROR: VS2015/VS2013/VS2012/VS2010/VS2008 not installed correctly. VS140COMNTOOLS/VS120COMNTOOLS/VS110COMNTOOLS/VS100COMNTOOLS/VS90COMNTOOLS not defined ^^!\r
  echo.\r
  goto :BldFail\r
)\r
\r
echo Ensuring correct build directory is present for GenBiosId...\r
set BUILD_PATH=Build\%PLATFORM_NAME%\%TARGET%_%TOOL_CHAIN_TAG%\r
\r
echo Modifing Conf files for this build...\r
:: Remove lines with these tags from target.txt\r
findstr /V "TARGET  TARGET_ARCH  TOOL_CHAIN_TAG  BUILD_RULE_CONF  ACTIVE_PLATFORM  MAX_CONCURRENT_THREAD_NUMBER" Conf\target.txt > Conf\target.txt.tmp\r
\r
echo TARGET          = %TARGET%                                  >> Conf\target.txt.tmp\r
if "%Arch%"=="IA32" (\r
    echo TARGET_ARCH = IA32                                       >> Conf\target.txt.tmp\r
) else if "%Arch%"=="X64" (\r
    echo TARGET_ARCH = IA32 X64                                  >> Conf\target.txt.tmp\r
)\r
echo TOOL_CHAIN_TAG  = %TOOL_CHAIN_TAG%                                  >> Conf\target.txt.tmp\r
echo BUILD_RULE_CONF = Conf/build_rule.txt                               >> Conf\target.txt.tmp\r
if %Source% == 0 (\r
  echo ACTIVE_PLATFORM = %PLATFORM_PACKAGE%/PlatformPkg%Arch%.dsc        >> Conf\target.txt.tmp\r
) else (\r
  echo ACTIVE_PLATFORM = %PLATFORM_PACKAGE%/PlatformPkg%Arch%Source.dsc  >> Conf\target.txt.tmp\r
)\r
echo MAX_CONCURRENT_THREAD_NUMBER = %build_threads%                      >> Conf\target.txt.tmp\r
\r
move /Y Conf\target.txt.tmp Conf\target.txt >nul\r
\r
::**********************************************************************\r
:: Build BIOS\r
::**********************************************************************\r
\r
echo Creating BiosId...\r
pushd %PLATFORM_PACKAGE%\r
if not exist %WORKSPACE%\%BUILD_PATH%\IA32  mkdir %WORKSPACE%\%BUILD_PATH%\IA32\r
  GenBiosId.exe -i %CORE_PATH%\Conf\BiosId.env -o %WORKSPACE%\%BUILD_PATH%\IA32\BiosId.bin -ob %CORE_PATH%\Conf\BiosId.bat\r
if "%Arch%"=="X64" (\r
   if not exist %WORKSPACE%\%BUILD_PATH%\X64  mkdir %WORKSPACE%\%BUILD_PATH%\X64\r
   GenBiosId.exe -i %CORE_PATH%\Conf\BiosId.env -o %WORKSPACE%\%BUILD_PATH%\X64\BiosId.bin -ob %CORE_PATH%\Conf\BiosId.bat\r
)\r
popd\r
\r
\r
if %ERRORLEVEL% NEQ 0 goto BldFail\r
\r
echo.\r
echo Invoking EDK2 build...\r
call build %Build_Flags%\r
\r
if %ERRORLEVEL% NEQ 0 goto BldFail\r
\r
::**********************************************************************\r
:: Post Build processing and cleanup\r
::**********************************************************************\r
\r
echo Running fce...\r
\r
pushd %PLATFORM_PACKAGE%\r
:: Extract Hii data from build and store in HiiDefaultData.txt\r
fce read -i %WORKSPACE%\%BUILD_PATH%\FV\Vlv.fd > %WORKSPACE%\%BUILD_PATH%\FV\HiiDefaultData.txt\r
\r
:: save changes to VlvXXX.fd\r
fce update -i %WORKSPACE%\%BUILD_PATH%\FV\Vlv.fd -s %WORKSPACE%\%BUILD_PATH%\FV\HiiDefaultData.txt -o %WORKSPACE%\%BUILD_PATH%\FV\Vlv%Arch%.fd\r
popd\r
\r
if %ERRORLEVEL% NEQ 0 goto BldFail\r
::echo FD successfully updated with default Hii values.\r
\r
:: Set the Board_Id, Build_Type, Version_Major, and Version_Minor environment variables\r
find /v "#" Conf\BiosId.env > ver_strings\r
for /f "tokens=1,3" %%i in (ver_strings) do set %%i=%%j\r
del /f/q ver_strings >nul\r
\r
set BIOS_Name=%BOARD_ID%_%Arch%_%BUILD_TYPE%_%VERSION_MAJOR%_%VERSION_MINOR%.ROM\r
copy /y/b %WORKSPACE%\%BUILD_PATH%\FV\Vlv%Arch%.fd  %PLATFORM_PATH%\%BIOS_Name% >nul\r
copy /y/b %WORKSPACE%\%BUILD_PATH%\FV\Vlv%Arch%.fd  %WORKSPACE%\%BUILD_PATH%\FV\Vlv.ROM >nul\r
\r
echo.\r
echo Build location:     %BUILD_PATH%\r
echo BIOS ROM Created:   %BIOS_Name%\r
echo.\r
echo -------------------- The EDKII BIOS build has successfully completed. --------------------\r
echo.\r
\r
@REM build capsule here\r
@REMif "%openssl_path%" == "" (\r
@REM    echo -- Error:  OPENSSL_PATH not set.  Capule and Recovery images not generated.\r
@REM    set exitCode=1\r
@REM    goto Exit\r
@REM\r
@REM echo > %BUILD_PATH%\FV\SYSTEMFIRMWAREUPDATECARGO.Fv\r
@REM build -p %PLATFORM_PACKAGE%\PlatformCapsule.dsc\r
\r
goto Exit\r
\r
:Usage\r
echo.\r
echo ***************************************************************************\r
echo Build BIOS rom for VLV platforms.\r
echo.\r
echo Usage: bld_vlv.bat [options] PlatformType [Build Target]\r
echo.\r
echo    /c    CleanAll before building\r
echo    /l    Generate build log file\r
echo    /y    Generate build report file\r
echo    /m    Enable multi-processor build\r
echo    /IA32 Set Arch to IA32 (default: X64)\r
echo    /X64  Set Arch to X64 (default: X64)\r
echo.\r
echo        Platform Types:  MNW2\r
echo        Build Targets:   Debug, Release  (default: Debug)\r
echo.\r
echo Examples:\r
echo    bld_vlv.bat MNW2                 : X64 Debug build for MinnowMax\r
echo    bld_vlv.bat /IA32 MNW2 release   : IA32 Release build for MinnowMax\r
echo.\r
echo ***************************************************************************\r
set exitCode=1\r
goto Exit\r
\r
:BldFail\r
set exitCode=1\r
echo  -- Error:  EDKII BIOS Build has failed!\r
echo See EDK2.log for more details\r
\r
:Exit\r
echo %date%  %time%\r
exit /b %exitCode%\r
\r
EndLocal\r