MdePkg: Clean up source files

[mirror_edk2.git] / MdePkg / Library / BaseLib / X64 / DisablePaging64.S

#------------------------------------------------------------------------------\r
#\r
# Copyright (c) 2006 - 2018, Intel Corporation. All rights reserved.<BR>\r
# This program and the accompanying materials\r
# are licensed and made available under the terms and conditions of the BSD License\r
# which accompanies this distribution.  The full text of the license may be found at\r
# http://opensource.org/licenses/bsd-license.php.\r
#\r
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
#\r
# Module Name:\r
#\r
#   DisablePaging64.S\r
#\r
# Abstract:\r
#\r
#   AsmDisablePaging64 function\r
#\r
# Notes:\r
#\r
#------------------------------------------------------------------------------\r
\r
\r
\r
#------------------------------------------------------------------------------\r
# VOID\r
# EFIAPI\r
# InternalX86DisablePaging64 (\r
#   IN      UINT16                    Cs,\r
#   IN      UINT32                    EntryPoint,\r
#   IN      UINT32                    Context1,  OPTIONAL\r
#   IN      UINT32                    Context2,  OPTIONAL\r
#   IN      UINT32                    NewStack\r
#   );\r
#------------------------------------------------------------------------------\r
\r
ASM_GLOBAL ASM_PFX(InternalX86DisablePaging64)\r
ASM_PFX(InternalX86DisablePaging64):\r
    cli\r
    lea    L1(%rip), %rsi                 # rsi <- The start address of transition code\r
    mov    0x28(%rsp), %edi               # rdi <- New stack\r
    lea    _mTransitionEnd(%rip), %rax    # rax <- end of transition code\r
    sub    %rsi, %rax                     # rax <- The size of transition piece code\r
    add    $4, %rax                       # round rax up to the next 4 byte boundary\r
    and    $0xfc, %al\r
    sub    %rax, %rdi                     # rdi <- use stack to hold transition code\r
    mov    %edi, %r10d                    # r10 <- The start address of transicition code below 4G\r
    push   %rcx                           # save rcx to stack\r
    mov    %rax, %rcx                     # rcx <- The size of transition piece code\r
    rep\r
    movsb                                 # copy transition code to (new stack - 64byte) below 4G\r
    pop    %rcx                           # restore rcx\r
\r
    mov    %r8d, %esi\r
    mov    %r9d, %edi\r
    mov    %r10d, %eax\r
    sub    $4, %eax\r
    push   %rcx                           # push Cs to stack\r
    push   %r10                           # push address of transition code on stack\r
    .byte  0x48, 0xcb                     # retq: Use far return to load CS register from stack\r
                                          # (Use raw byte code since some GNU assemblers generates incorrect code for "retq")\r
L1:\r
    mov    %eax,%esp                      # set up new stack\r
    mov    %cr0,%rax\r
    btr    $0x1f,%eax                     # clear CR0.PG\r
    mov    %rax,%cr0                      # disable paging\r
\r
    mov    %edx,%ebx                      # save EntryPoint to ebx, for rdmsr will overwrite edx\r
    mov    $0xc0000080,%ecx\r
    rdmsr\r
    and    $0xfe,%ah                      # clear LME\r
    wrmsr\r
    mov    %cr4,%rax\r
    and    $0xdf,%al                      # clear PAE\r
    mov    %rax,%cr4\r
    push   %rdi                           # push Context2\r
    push   %rsi                           # push Context1\r
    callq  *%rbx                          # transfer control to EntryPoint\r
    jmp    .                              # no one should get here\r
\r
_mTransitionEnd :\r