configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.4-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 hosttools_clippy="false"
  29 build_clippy="true"
  30
  31 dnl case 1: external clippy
  32 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  33   if test "$enable_clippy_only" = "yes"; then
  34     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  35   fi
  36
  37   CLIPPY="$with_clippy"
  38   build_clippy="false"
  39   if test ! -x "$with_clippy"; then
  40     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  41   fi
  42
  43 dnl case 2: cross-compiling internal clippy
  44 elif test "$host" != "$build"; then
  45   if test "$srcdir" = "."; then
  46     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  47   fi
  48   test -d hosttools || mkdir hosttools
  49   abssrc="`cd \"${srcdir}\"; pwd`"
  50
  51   AC_MSG_NOTICE([...])
  52   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  53   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  54   AC_MSG_NOTICE([...])
  55
  56   (
  57     for var in $ac_precious_vars; do
  58       dnl special cases
  59       case "$var" in
  60       YACC|YFLAGS) continue;;
  61       PYTHON*)     retain=true;;
  62       *)           retain=false;
  63       esac
  64
  65       eval "hostvar=\"\${HOST_$var}\""
  66       eval "targetvar=\"\${$var}\""
  67       if test -n "$hostvar"; then
  68         eval "$var='$hostvar'"
  69         _AS_ECHO_LOG([host $var='$hostvar'])
  70       elif $retain; then
  71         _AS_ECHO_LOG([host retain $var='$targetvar'])
  72       else
  73         eval "unset $var"
  74         _AS_ECHO_LOG([host unset $var])
  75       fi
  76     done
  77     cd hosttools
  78     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  79   ) || exit 1
  80
  81   AC_MSG_NOTICE([...])
  82   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  83   AC_MSG_NOTICE([...])
  84
  85   build_clippy="false"
  86   hosttools_clippy="true"
  87   CLIPPY="hosttools/lib/clippy"
  88
  89 dnl case 3: normal build internal clippy
  90 else
  91   CLIPPY="lib/clippy\$(EXEEXT)"
  92 fi
  93 AC_SUBST([CLIPPY])
  94 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  95 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
  96 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
  97
  98 # Disable portability warnings -- our automake code (in particular
  99 # common.am) uses some constructs specific to gmake.
 100 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 101 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 102 AM_SILENT_RULES([yes])
 103 AC_CONFIG_HEADERS([config.h])
 104
 105 AC_PATH_PROG([PERL], [perl])
 106 PKG_PROG_PKG_CONFIG
 107
 108 dnl default is to match previous behavior
 109 exampledir=${sysconfdir}
 110 AC_ARG_ENABLE([exampledir],
 111           AS_HELP_STRING([--enable-exampledir],
 112                          [specify alternate directory for examples]),
 113                          exampledir="$enableval",)
 114 dnl XXX add --exampledir to autoconf standard directory list somehow
 115 AC_SUBST([exampledir])
 116
 117 dnl default is to match previous behavior
 118 pkgsrcrcdir=""
 119 AC_ARG_ENABLE([pkgsrcrcdir],
 120           AS_HELP_STRING([--enable-pkgsrcrcdir],
 121                          [specify directory for rc.d scripts]),
 122                          pkgsrcrcdir="$enableval",)
 123 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 124 AC_SUBST([pkgsrcrcdir])
 125 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 126
 127 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 128         moduledir="$withval"
 129 ], [
 130         moduledir="\${libdir}/frr/modules"
 131 ])
 132 AC_SUBST([moduledir], [$moduledir])
 133
 134
 135 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 136         yangmodelsdir="$withval"
 137 ], [
 138         yangmodelsdir="\${datarootdir}/yang"
 139 ])
 140 AC_SUBST([yangmodelsdir])
 141
 142 AC_ARG_ENABLE(tcmalloc,
 143         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 144 [case "${enableval}" in
 145   yes) tcmalloc_enabled=true
 146 LIBS="$LIBS -ltcmalloc_minimal"
 147  ;;
 148   no)  tcmalloc_enabled=false ;;
 149   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 150 esac],[tcmalloc_enabled=false])
 151
 152
 153 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 154 dnl flag determination logic.
 155 CFLAGS="${CFLAGS:-}"
 156
 157 dnl --------------------
 158 dnl Check CC and friends
 159 dnl --------------------
 160 dnl note orig_cflags is also used further down
 161 orig_cflags="$CFLAGS"
 162 orig_cxxflags="$CXXFLAGS"
 163 AC_LANG([C])
 164 AC_PROG_CC
 165 AC_PROG_CPP
 166 AC_PROG_CXX
 167 AM_PROG_CC_C_O
 168 dnl remove autoconf default "-g -O2"
 169 CFLAGS="$orig_cflags"
 170 CXXFLAGS="$orig_cxxflags"
 171 AC_PROG_CC_C99
 172 dnl NB: see C11 below
 173
 174 PKG_PROG_PKG_CONFIG
 175
 176 dnl it's 2019, sed is sed.
 177 SED=sed
 178 AC_SUBST([SED])
 179
 180 dnl try and enable CFLAGS that are useful for FRR
 181 dnl - specifically, options to control warnings
 182
 183 AC_USE_SYSTEM_EXTENSIONS
 184 AC_DEFUN([AC_C_FLAG], [{
 185     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 186     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 187         AC_LANG_PUSH([C])
 188         ac_c_flag_save="$CFLAGS"
 189         CFLAGS="$CFLAGS $1"
 190         AC_COMPILE_IFELSE(
 191                 [AC_LANG_PROGRAM([[$4]])],
 192                 [
 193                         cachename=yes
 194                 ], [
 195                         cachename=no
 196                 ])
 197         CFLAGS="$ac_c_flag_save"
 198         AC_LANG_POP([C])
 199     ])
 200     if test "$cachename" = "yes"; then
 201         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 202     else
 203         :
 204         $2
 205     fi
 206     m4_popdef([cachename])
 207 }])
 208
 209 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 210         AC_LANG_PUSH([C])
 211         ac_cflags_save="$CFLAGS"
 212         ac_libs_save="$LIBS"
 213         CFLAGS="$CFLAGS $1"
 214         LIBS="$LIBS $2"
 215         AC_LINK_IFELSE(
 216                 [$3],
 217                 [
 218                         CFLAGS="$ac_cflags_save"
 219                         LIBS="$ac_libs_save"
 220                         m4_default([$5], [
 221                                 AC_MSG_RESULT([yes])
 222                         ])
 223                 ], [
 224                         CFLAGS="$ac_cflags_save"
 225                         LIBS="$ac_libs_save"
 226                         m4_default([$4], [
 227                                 AC_MSG_RESULT([no])
 228                         ])
 229                 ])
 230         AC_LANG_POP([C])
 231         }])
 232
 233 dnl ICC won't bail on unknown options without -diag-error 10006
 234 dnl need to do this first so we get useful results for the other options
 235 AC_C_FLAG([-diag-error 10006])
 236
 237 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 238 ac_cc="$CC"
 239 CC="${CC% -std=gnu99}"
 240 CC="${CC% -std=c99}"
 241
 242 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 243
 244 dnl if the user has specified any CFLAGS, override our settings
 245 if test "$enable_gcov" = "yes"; then
 246    if test "$orig_cflags" = ""; then
 247       AC_C_FLAG([-coverage])
 248       AC_C_FLAG([-O0])
 249    fi
 250
 251    LDFLAGS="${LDFLAGS} -lgcov"
 252 fi
 253
 254 if test "$enable_clang_coverage" = "yes"; then
 255    AC_C_FLAG([-fprofile-instr-generate], [
 256      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 257    ])
 258    AC_C_FLAG([-fcoverage-mapping], [
 259      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 260    ])
 261 fi
 262
 263 if test "$enable_dev_build" = "yes"; then
 264    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 265    if test "$orig_cflags" = ""; then
 266       AC_C_FLAG([-g3])
 267       AC_C_FLAG([-O0])
 268    fi
 269    if test "$enable_lua" = "yes"; then
 270       AX_PROG_LUA([5.3])
 271       AX_LUA_HEADERS
 272       AX_LUA_LIBS([
 273          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 274          LIBS="$LIBS $LUA_LIB"
 275       ])
 276    fi
 277 else
 278    if test "$enable_lua" = "yes"; then
 279       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 280    fi
 281    if test "$orig_cflags" = ""; then
 282       AC_C_FLAG([-g])
 283       AC_C_FLAG([-O2])
 284    fi
 285 fi
 286 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 287
 288 dnl always want these CFLAGS
 289 AC_C_FLAG([-fno-omit-frame-pointer])
 290 AC_C_FLAG([-funwind-tables])
 291 AC_C_FLAG([-Wall])
 292 AC_C_FLAG([-Wextra])
 293 AC_C_FLAG([-Wmissing-prototypes])
 294 AC_C_FLAG([-Wmissing-declarations])
 295 AC_C_FLAG([-Wpointer-arith])
 296 AC_C_FLAG([-Wbad-function-cast])
 297 AC_C_FLAG([-Wwrite-strings])
 298 AC_C_FLAG([-Wundef])
 299 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 300   AC_C_FLAG([-Wcast-qual])
 301   AC_C_FLAG([-Wstrict-prototypes])
 302   AC_C_FLAG([-Wmissing-noreturn])
 303   AC_C_FLAG([-Wmissing-format-attribute])
 304   AC_C_FLAG([-Wunreachable-code])
 305   AC_C_FLAG([-Wpacked])
 306   AC_C_FLAG([-Wpadded])
 307   AC_C_FLAG([-Wshadow])
 308 else
 309   AC_C_FLAG([-Wno-unused-result])
 310 fi
 311 AC_C_FLAG([-Wno-unused-parameter])
 312 AC_C_FLAG([-Wno-missing-field-initializers])
 313
 314 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 315 AC_SUBST([CXX_COMPAT_CFLAGS])
 316
 317 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 318 dnl for some reason the string consts get 'promoted' to char *,
 319 dnl triggering a const to non-const conversion warning.
 320 AC_C_FLAG([-diag-disable 3179])
 321
 322 if test "$enable_werror" = "yes" ; then
 323   WERROR="-Werror"
 324 fi
 325 AC_SUBST([WERROR])
 326
 327 SAN_FLAGS=""
 328 if test "$enable_address_sanitizer" = "yes"; then
 329   AC_C_FLAG([-fsanitize=address], [
 330     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 331   ], [
 332     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 333   ])
 334 fi
 335 if test "$enable_thread_sanitizer" = "yes"; then
 336   AC_C_FLAG([-fsanitize=thread], [
 337     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 338   ], [
 339     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 340   ])
 341 fi
 342 if test "$enable_memory_sanitizer" = "yes"; then
 343   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 344     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 345   ], [
 346     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 347   ])
 348 fi
 349 if test "$enable_undefined_sanitizer" = "yes"; then
 350   AC_C_FLAG([-fsanitize=undefined], [
 351     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 352   ], [
 353     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 354   ])
 355 fi
 356 AC_SUBST([SAN_FLAGS])
 357
 358 dnl frr-format.so
 359 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 360   AC_C_FLAG([-fplugin=${with_frr_format}], [
 361     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 362   ],,[
 363 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 364 #error plugin not loaded
 365 #endif
 366 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 367 #error plugin too old
 368 #endif
 369   ])
 370 elif test "$with_frr_format" = "no"; then
 371   : #nothing
 372 else
 373   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 374     AC_C_FLAG([-fplugin=frr-format],[
 375       if test "$with_frr_format" = "yes"; then
 376         AC_MSG_ERROR([frr-format plugin requested but not found])
 377       fi
 378     ],,[
 379 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 380 #error plugin not loaded
 381 #endif
 382 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 383 #error plugin too old
 384 #endif
 385     ])
 386   ],,[
 387 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 388 #error plugin not loaded
 389 #endif
 390 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 391 #error plugin too old
 392 #endif
 393   ])
 394 fi
 395
 396 dnl ----------
 397 dnl Essentials
 398 dnl ----------
 399
 400 AX_PTHREAD([
 401   CC="$PTHREAD_CC"
 402   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 403   LIBS="$PTHREAD_LIBS $LIBS"
 404 ], [
 405   AC_MSG_FAILURE([This FRR version needs pthreads])
 406 ])
 407
 408 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 409                 [frr_cv_pthread_condattr_setclock=yes],
 410                 [frr_cv_pthread_condattr_setclock=no])
 411 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 412   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 413 fi
 414
 415 dnl --------------
 416 dnl Check programs
 417 dnl --------------
 418 AC_PROG_INSTALL
 419 AC_PROG_LN_S
 420 AC_CHECK_TOOL([AR], [ar])
 421
 422 dnl -------
 423 dnl libtool
 424 dnl -------
 425 AC_ARG_ENABLE([static-bin],
 426   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 427 LT_INIT
 428 _LT_CONFIG_LIBTOOL([
 429   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 430     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 431 ])
 432 if test "$enable_static_bin" = "yes"; then
 433   AC_LDFLAGS="-static"
 434   if test "$enable_static" != "yes"; then
 435     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 436   fi
 437 fi
 438 if test "$enable_shared" != "yes"; then
 439   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 440 fi
 441 AC_SUBST([AC_LDFLAGS])
 442 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 443
 444 dnl $AR and $RANLIB are set by LT_INIT above
 445 AC_MSG_CHECKING([whether $AR supports D option])
 446 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 447   AC_MSG_RESULT([yes])
 448   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 449   ARFLAGS="crD"
 450   AR_FLAGS="crD"
 451 else
 452   AC_MSG_RESULT([no])
 453   ARFLAGS="cru"
 454   AR_FLAGS="cru"
 455 fi
 456 AC_SUBST([ARFLAGS])
 457 AC_SUBST([AR_FLAGS])
 458
 459 AC_MSG_CHECKING([whether $RANLIB supports D option])
 460 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 461   if grep -q -- '-D' conftest.err; then
 462     AC_MSG_RESULT([no])
 463   else
 464     AC_MSG_RESULT([yes])
 465     RANLIB="$RANLIB -D"
 466   fi
 467 else
 468   AC_MSG_RESULT([no])
 469 fi
 470 AC_SUBST([RANLIB])
 471
 472 test -f conftest.err && rm conftest.err
 473 test -f conftest.a && rm conftest.a
 474
 475 dnl ----------------------
 476 dnl Packages configuration
 477 dnl ----------------------
 478 if test -f config.version; then
 479   . ./config.version
 480 elif test -f "${srcdir}/config.version"; then
 481   . "${srcdir}/config.version"
 482 fi
 483 AC_ARG_WITH([pkg-extra-version],
 484   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 485   if test "$withval" = "no"; then
 486     EXTRAVERSION=
 487   else
 488     EXTRAVERSION=$withval
 489   fi
 490 ], [])
 491 AC_ARG_WITH([pkg-git-version],
 492         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 493         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 494 AC_ARG_WITH([clippy],
 495   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 496 AC_ARG_WITH([vtysh_pager],
 497         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 498         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 499 AC_ARG_ENABLE([vtysh],
 500   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 501 AC_ARG_ENABLE([doc],
 502   AS_HELP_STRING([--disable-doc], [do not build docs]))
 503 AC_ARG_ENABLE([doc-html],
 504   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 505 AC_ARG_ENABLE([zebra],
 506   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 507 AC_ARG_ENABLE([bgpd],
 508   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 509 AC_ARG_ENABLE([ripd],
 510   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 511 AC_ARG_ENABLE([ripngd],
 512   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 513 AC_ARG_ENABLE([ospfd],
 514   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 515 AC_ARG_ENABLE([ospf6d],
 516   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 517 AC_ARG_ENABLE([ldpd],
 518   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 519 AC_ARG_ENABLE([nhrpd],
 520   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 521 AC_ARG_ENABLE([eigrpd],
 522   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 523 AC_ARG_ENABLE([babeld],
 524   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 525 AC_ARG_ENABLE([watchfrr],
 526   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 527 AC_ARG_ENABLE([isisd],
 528   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 529 AC_ARG_ENABLE([pimd],
 530   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 531 AC_ARG_ENABLE([pbrd],
 532   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 533 AC_ARG_ENABLE([sharpd],
 534   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 535 AC_ARG_ENABLE([staticd],
 536   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 537 AC_ARG_ENABLE([fabricd],
 538   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 539 AC_ARG_ENABLE([vrrpd],
 540   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 541 AC_ARG_ENABLE([bgp-announce],
 542   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 543 AC_ARG_ENABLE([bgp-vnc],
 544   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 545 AC_ARG_ENABLE([bgp-bmp],
 546   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 547 AC_ARG_ENABLE([snmp],
 548   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 549 AC_ARG_ENABLE([config_rollbacks],
 550   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 551 AC_ARG_ENABLE([confd],
 552   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 553 AC_ARG_ENABLE([sysrepo],
 554   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 555 AC_ARG_ENABLE([grpc],
 556   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 557 AC_ARG_ENABLE([zeromq],
 558   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 559 AC_ARG_WITH([libpam],
 560   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 561 AC_ARG_ENABLE([ospfapi],
 562   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 563 AC_ARG_ENABLE([ospfclient],
 564   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 565                           (this is the default if --disable-ospfapi is set)]))
 566 AC_ARG_ENABLE([multipath],
 567   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 568 AC_ARG_ENABLE([user],
 569   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 570 AC_ARG_ENABLE([group],
 571   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 572 AC_ARG_ENABLE([vty_group],
 573   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 574 AC_ARG_ENABLE([configfile_mask],
 575   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 576 AC_ARG_ENABLE([logfile_mask],
 577   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 578 AC_ARG_ENABLE([shell_access],
 579   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 580 AC_ARG_ENABLE([realms],
 581   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 582 AC_ARG_ENABLE([rtadv],
 583   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 584 AC_ARG_ENABLE([irdp],
 585   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 586 AC_ARG_ENABLE([capabilities],
 587   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 588 AC_ARG_ENABLE([rusage],
 589   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 590 AC_ARG_ENABLE([gcc_ultra_verbose],
 591   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 592 AC_ARG_ENABLE([backtrace],
 593   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 594 AC_ARG_ENABLE([time-check],
 595   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 596 AC_ARG_ENABLE([cpu-time],
 597   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 598 AC_ARG_ENABLE([pcreposix],
 599   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 600 AC_ARG_ENABLE([fpm],
 601   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 602 AC_ARG_ENABLE([systemd],
 603   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 604 AC_ARG_ENABLE([werror],
 605   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 606 AC_ARG_ENABLE([cumulus],
 607   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 608 AC_ARG_ENABLE([datacenter],
 609   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 610 AC_ARG_ENABLE([fuzzing],
 611   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 612 AC_ARG_ENABLE([netlink_fuzzing],
 613   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 614 AC_ARG_ENABLE([rr-semantics],
 615   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 616 AC_ARG_ENABLE([protobuf],
 617   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 618 AC_ARG_ENABLE([oldvpn_commands],
 619   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 620 AC_ARG_ENABLE([rpki],
 621   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 622 AC_ARG_ENABLE([clippy-only],
 623   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 624 AC_ARG_ENABLE([numeric_version],
 625   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 626 AC_ARG_ENABLE([gcov],
 627   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 628 AC_ARG_ENABLE([clang_coverage],
 629   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 630 AC_ARG_ENABLE([bfdd],
 631   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 632 AC_ARG_ENABLE([address-sanitizer],
 633   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 634 AC_ARG_ENABLE([thread-sanitizer],
 635   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 636 AC_ARG_ENABLE([memory-sanitizer],
 637   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 638 AC_ARG_ENABLE([undefined-sanitizer],
 639   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 640 AC_ARG_WITH([crypto],
 641   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 642 AC_ARG_WITH([frr-format],
 643   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 644
 645 #if openssl, else use the internal
 646 AS_IF([test "$with_crypto" = "openssl"], [
 647 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 648 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 649   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 650 else
 651   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 652 fi
 653 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 654 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 655 )
 656
 657 AS_IF([test "$enable_clippy_only" != "yes"], [
 658 AC_CHECK_HEADERS([json-c/json.h])
 659 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 660 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 661   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 662   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 663       AC_MSG_ERROR([libjson is needed to compile])
 664   fi
 665 fi
 666 ])
 667
 668 AC_ARG_ENABLE([dev_build],
 669     AS_HELP_STRING([--enable-dev-build], [build for development]))
 670
 671 AC_ARG_ENABLE([lua],
 672     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 673
 674 if test "$enable_time_check" != "no" ; then
 675   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 676     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 677   else
 678     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 679   fi
 680 fi
 681
 682 case "${enable_cpu_time}" in
 683   "no")
 684   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 685   ;;
 686   "*")
 687   ;;
 688 esac
 689
 690 case "${enable_systemd}" in
 691   "no") ;;
 692   "yes")
 693   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 694   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 695     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 696   else
 697     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 698   fi
 699   ;;
 700   "*") ;;
 701 esac
 702
 703 if test "$enable_rr_semantics" != "no" ; then
 704   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 705 fi
 706
 707 if test "$enable_datacenter" = "yes" ; then
 708   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 709   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 710   DFLT_NAME="datacenter"
 711 else
 712   DFLT_NAME="traditional"
 713 fi
 714
 715 if test "$enable_fuzzing" = "yes" ; then
 716   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 717 fi
 718
 719 if test "$enable_netlink_fuzzing" = "yes" ; then
 720   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 721 fi
 722
 723 if test "$enable_cumulus" = "yes" ; then
 724   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 725 fi
 726
 727 AC_SUBST([DFLT_NAME])
 728 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 729
 730 if test "$enable_shell_access" = "yes"; then
 731    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 732 fi
 733
 734 #
 735 # Python for clippy
 736 #
 737
 738 AS_IF([test "$host" = "$build"], [
 739   FRR_PYTHON_DEV
 740 ], [
 741   FRR_PYTHON
 742 ])
 743
 744 FRR_PYTHON_MODULES([pytest])
 745
 746 if test "$enable_doc" != "no"; then
 747   FRR_PYTHON_MODULES([sphinx], , [
 748     if test "$enable_doc" = "yes"; then
 749       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 750     fi
 751   ])
 752 fi
 753 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 754 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 755
 756 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 757   PYSPHINX="-m sphinx"
 758 ], [
 759   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 760 ])
 761 AC_SUBST([PYSPHINX])
 762
 763 #
 764 # Logic for old vpn commands support.
 765 #
 766 if test "$enable_oldvpn_commands" = "yes"; then
 767    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 768 fi
 769
 770 #
 771 # End of logic for protobuf support.
 772 #
 773
 774 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 775 if test "$enable_rtadv" != "no"; then
 776   AC_MSG_RESULT([yes])
 777   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 778 else
 779   AC_MSG_RESULT([no])
 780 fi
 781
 782 if test "$enable_user" = "no"; then
 783   enable_user=""
 784 else
 785   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 786     enable_user="frr"
 787   fi
 788   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 789 fi
 790
 791 if test "$enable_group" = "no"; then
 792   enable_group=""
 793 else
 794   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 795     enable_group="frr"
 796   fi
 797   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 798 fi
 799
 800 if test "$enable_vty_group" = "yes" ; then
 801   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 802 elif test "$enable_vty_group" != ""; then
 803   if test "$enable_vty_group" != "no"; then
 804     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 805   fi
 806 fi
 807 AC_SUBST([enable_user])
 808 AC_SUBST([enable_group])
 809 AC_SUBST([enable_vty_group])
 810
 811 enable_configfile_mask=${enable_configfile_mask:-0600}
 812 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 813
 814 enable_logfile_mask=${enable_logfile_mask:-0600}
 815 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 816
 817 MPATH_NUM=16
 818
 819 case "${enable_multipath}" in
 820   0)
 821     MPATH_NUM=64
 822     ;;
 823   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 824     MPATH_NUM="${enable_multipath}"
 825     ;;
 826   "")
 827     ;;
 828   *)
 829     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 830     ;;
 831 esac
 832
 833 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 834
 835 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 836
 837 dnl --------------------
 838 dnl Enable code coverage
 839 dnl --------------------
 840 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 841
 842 dnl ------------------------------------
 843 dnl Alpine only accepts numeric versions
 844 dnl ------------------------------------
 845 if test "$enable_numeric_version" != "" ; then
 846   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 847   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 848 fi
 849
 850 dnl -----------------------------------
 851 dnl Add extra version string to package
 852 dnl name, string and version fields.
 853 dnl -----------------------------------
 854 if test "$EXTRAVERSION" != "" ; then
 855   VERSION="${VERSION}${EXTRAVERSION}"
 856   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 857   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 858   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 859 fi
 860 AC_SUBST([EXTRAVERSION])
 861
 862 if test "$with_pkg_git_version" = "yes"; then
 863         if test -d "${srcdir}/.git"; then
 864                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 865         else    with_pkg_git_version="no"
 866                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 867         fi
 868 fi
 869 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 870
 871 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 872 if test "$OBJCOPY" != ":"; then
 873   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 874     frr_cv_interp=""
 875     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 876       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 877         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 878       fi
 879       test -f conftest.interp && rm conftest.interp
 880     ])
 881   ])
 882 fi
 883 if test -n "$frr_cv_interp"; then
 884   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 885 fi
 886
 887 dnl -------------------------
 888 dnl Check other header files.
 889 dnl -------------------------
 890 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 891         linux/version.h asm/types.h])
 892
 893 ac_stdatomic_ok=false
 894 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 895 AC_CHECK_HEADER([stdatomic.h],[
 896
 897   AC_MSG_CHECKING([whether _Atomic qualifier works])
 898   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 899 #include <stdatomic.h>
 900 int main(int argc, char **argv) {
 901   _Atomic int i = 0;
 902   return i;
 903 }
 904 ]])], [
 905     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 906     AC_MSG_RESULT([yes])
 907     ac_stdatomic_ok=true
 908   ], [
 909     AC_MSG_RESULT([no])
 910   ])
 911 ])
 912
 913 AS_IF([$ac_stdatomic_ok], [true], [
 914   AC_MSG_CHECKING([for __atomic_* builtins])
 915   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 916 int main(int argc, char **argv) {
 917   volatile int i = 1;
 918   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 919   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 920 }
 921 ]])], [
 922     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 923     AC_MSG_RESULT([yes])
 924   ], [
 925     AC_MSG_RESULT([no])
 926
 927     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 928     AC_MSG_CHECKING([for __sync_* builtins])
 929     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 930 int main(int argc, char **argv) {
 931   volatile int i = 1;
 932   __sync_fetch_and_sub (&i, 1);
 933   return __sync_val_compare_and_swap (&i, 0, 1);
 934 }
 935 ]])], [
 936       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 937       AC_MSG_RESULT([yes])
 938
 939       AC_MSG_CHECKING([for __sync_swap builtin])
 940       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 941 int main(int argc, char **argv) {
 942   volatile int i = 1;
 943   return __sync_swap (&i, 2);
 944 }
 945 ]])], [
 946         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 947         AC_MSG_RESULT([yes])
 948       ], [
 949         AC_MSG_RESULT([no])
 950       ])
 951
 952     ], [
 953       AC_MSG_RESULT([no])
 954       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 955     ])
 956   ])
 957 ])
 958
 959 AC_CHECK_HEADERS([pthread_np.h],,, [
 960 #include <pthread.h>
 961 ])
 962 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 963
 964 needsync=true
 965
 966 AS_IF([$needsync], [
 967   dnl Linux
 968   AC_MSG_CHECKING([for Linux futex() support])
 969   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 970 #ifndef _GNU_SOURCE
 971 #define _GNU_SOURCE
 972 #endif
 973 #include <unistd.h>
 974 #include <limits.h>
 975 #include <sys/time.h>
 976 #include <sys/syscall.h>
 977 #include <linux/futex.h>
 978
 979 int main(void);
 980 ],
 981 [
 982 {
 983   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 984 }
 985 ])], [
 986     AC_MSG_RESULT([yes])
 987     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 988     needsync=false
 989   ], [
 990     AC_MSG_RESULT([no])
 991   ])
 992 ])
 993
 994 AS_IF([$needsync], [
 995   dnl FreeBSD
 996   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 997   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 998 #include <errno.h>
 999 #include <stdlib.h>
1000 #include <sys/types.h>
1001 #include <sys/umtx.h>
1002 int main(void);
1003 ],
1004 [
1005 {
1006   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1007 }
1008 ])], [
1009     AC_MSG_RESULT([yes])
1010     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1011     needsync=false
1012   ], [
1013     AC_MSG_RESULT([no])
1014   ])
1015 ])
1016
1017 AS_IF([$needsync], [
1018   dnl OpenBSD patch (not upstream at the time of writing this)
1019   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1020   AC_MSG_CHECKING([for OpenBSD futex() support])
1021   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1022 #include <sys/futex.h>
1023 int main(void);
1024 ],
1025 [
1026 {
1027   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1028 }
1029 ])], [
1030     AC_MSG_RESULT([yes])
1031     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1032     needsync=false
1033   ], [
1034     AC_MSG_RESULT([no])
1035   ])
1036 ])
1037
1038 dnl Utility macro to avoid retyping includes all the time
1039 m4_define([FRR_INCLUDES],
1040 [#ifdef SUNOS_5
1041 #define _POSIX_C_SOURCE 200809L
1042 #define __EXTENSIONS__
1043 #endif
1044 #include <stdio.h>
1045 #include <stdlib.h>
1046 #include <stddef.h>
1047 #include <sys/types.h>
1048 /* sys/conf.h depends on param.h on FBSD at least */
1049 #include <sys/param.h>
1050 /* Required for MAXSIG */
1051 #include <signal.h>
1052 #include <sys/socket.h>
1053 #ifdef __APPLE__
1054 # define __APPLE_USE_RFC_3542
1055 #endif
1056 #include <netinet/in.h>
1057 #include <sys/time.h>
1058 #include <time.h>
1059 #include <net/if.h>
1060 ])dnl
1061
1062 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1063 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1064 dnl an additional round for it.
1065
1066 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1067
1068 m4_define([FRR_INCLUDES],
1069 FRR_INCLUDES
1070 [#ifdef HAVE_NET_IF_VAR_H
1071 # include <net/if_var.h>
1072 #endif
1073 ])dnl
1074
1075 AC_CHECK_HEADERS([netinet/in_var.h \
1076         net/if_dl.h net/netopt.h \
1077         inet/nd.h netinet/ip_icmp.h \
1078         sys/sysctl.h sys/sockio.h sys/conf.h],
1079         [], [], [FRR_INCLUDES])
1080
1081 AC_CHECK_HEADERS([ucontext.h], [], [],
1082 [#ifndef __USE_GNU
1083 #define __USE_GNU
1084 #endif /* __USE_GNU */
1085 FRR_INCLUDES
1086 ])
1087
1088 m4_define([UCONTEXT_INCLUDES],
1089 [#include <ucontext.h>])dnl
1090
1091 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1092   [], [], [UCONTEXT_INCLUDES])
1093 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1094   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1095    [], [], [UCONTEXT_INCLUDES])],
1096   [], [UCONTEXT_INCLUDES])
1097 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1098   [], [], [UCONTEXT_INCLUDES])
1099
1100 m4_define([FRR_INCLUDES],
1101 FRR_INCLUDES
1102 [
1103 #include <sys/un.h>
1104 #include <netinet/in_systm.h>
1105 #ifdef HAVE_NETINET_IN_VAR_H
1106 # include <netinet/in_var.h>
1107 #endif
1108 #ifdef HAVE_NET_IF_DL_H
1109 # include <net/if_dl.h>
1110 #endif
1111 #ifdef HAVE_NET_NETOPT_H
1112 # include <net/netopt.h>
1113 #endif
1114 #include <net/route.h>
1115 #ifdef HAVE_INET_ND_H
1116 # include <inet/nd.h>
1117 #endif
1118 #include <arpa/inet.h>
1119 /* Required for IDRP */
1120 #ifdef HAVE_NETINET_IP_ICMP_H
1121 # include <netinet/ip_icmp.h>
1122 #endif
1123 ])dnl
1124
1125 dnl V6 headers are checked below, after we check for v6
1126
1127 is_linux=false
1128
1129 AC_MSG_CHECKING([which operating system interface to use])
1130 case "$host_os" in
1131   sunos* | solaris2*)
1132     AC_MSG_RESULT([Solaris])
1133
1134     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1135     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1136     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1137
1138     AC_CHECK_LIB([socket], [main])
1139     AC_CHECK_LIB([nsl], [main])
1140     AC_CHECK_LIB([umem], [main])
1141     SOLARIS="solaris"
1142     AC_MSG_WARN([--Solaris support is being considered for deprecation, please let us know if you are still using this--])
1143     ;;
1144   linux*)
1145     AC_MSG_RESULT([Linux])
1146
1147     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1148     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1149     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1150
1151     dnl Linux has a compilation problem with mixing
1152     dnl netinet/in.h and linux/in6.h they are not
1153     dnl compatible.  There has been discussion on
1154     dnl how to fix it but no real progress on implementation
1155     dnl when they fix it, remove this
1156     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1157
1158     is_linux=true
1159     ;;
1160   openbsd*)
1161     AC_MSG_RESULT([OpenBSD])
1162
1163     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1164     AC_DEFINE([KAME], [1], [KAME IPv6])
1165     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1166     ;;
1167   *)
1168     AC_MSG_RESULT([BSD])
1169
1170     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1171     AC_DEFINE([KAME], [1], [KAME IPv6])
1172     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1173     ;;
1174 esac
1175 AM_CONDITIONAL([SOLARIS], [test "$SOLARIS" = "solaris"])
1176 AM_CONDITIONAL([LINUX], [${is_linux}])
1177
1178 AC_SYS_LARGEFILE
1179
1180 dnl ------------------------
1181 dnl Integrated REALMS option
1182 dnl ------------------------
1183 if test "$enable_realms" = "yes"; then
1184     case "$host_os" in
1185       linux*)
1186        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1187        ;;
1188       *)
1189        echo "Sorry, only Linux has REALMS support"
1190        exit 1
1191        ;;
1192     esac
1193 fi
1194
1195 dnl -------------------------------
1196 dnl Endian-ness check
1197 dnl -------------------------------
1198 AC_WORDS_BIGENDIAN
1199
1200 dnl ---------------
1201 dnl other functions
1202 dnl ---------------
1203 AC_CHECK_FUNCS([ \
1204         strlcat strlcpy \
1205         getgrouplist])
1206
1207 dnl ##########################################################################
1208 dnl LARGE if block spans a lot of "configure"!
1209 if test "$enable_clippy_only" != "yes"; then
1210 dnl ##########################################################################
1211
1212 #
1213 # Logic for protobuf support.
1214 #
1215 PROTO3=false
1216 if test "$enable_protobuf" = "yes"; then
1217   # Check for protoc & protoc-c
1218
1219   # protoc is not required, it's only for a "be nice" helper target
1220   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1221
1222   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1223   if test "$PROTOC_C" = "/bin/false"; then
1224     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1225   fi
1226
1227   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1228     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1229   ])
1230
1231   PROTO3=true
1232   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1233                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1234                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1235                                             [1], [Have Protobuf version 3]),
1236                                   [PROTO3=false],
1237                                   [#include <google/protobuf-c/protobuf-c.h>])],
1238                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1239
1240   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1241 fi
1242
1243
1244 dnl ---------------------
1245 dnl Integrated VTY option
1246 dnl ---------------------
1247 case "${enable_vtysh}" in
1248 "no")
1249   VTYSH="";;
1250 *)
1251   VTYSH="vtysh";
1252   AC_DEFINE([VTYSH], [1], [VTY shell])
1253
1254   prev_libs="$LIBS"
1255   AC_CHECK_LIB([readline], [main], [
1256     LIBREADLINE="-lreadline"
1257   ], [
1258     dnl readline failed - it might be incorrectly linked and missing its
1259     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1260     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1261       LIBREADLINE="$ac_cv_search_tputs"
1262     ], [
1263       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1264     ])
1265
1266     dnl re-try with the lib we found above
1267     unset ac_cv_lib_readline_main
1268     AC_CHECK_LIB([readline], [main], [
1269       LIBREADLINE="-lreadline $LIBREADLINE"
1270     ], [
1271       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1272     ], [$LIBREADLINE])
1273   ], [])
1274   LIBS="$prev_libs"
1275
1276   AC_CHECK_HEADER([readline/history.h])
1277   if test "$ac_cv_header_readline_history_h" = "no"; then
1278     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1279   fi
1280   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1281   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1282     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1283   fi
1284   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1285   if test "$frr_cv_append_history" = "yes"; then
1286     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1287   fi
1288   ;;
1289 esac
1290 AC_SUBST([LIBREADLINE])
1291
1292 dnl ----------
1293 dnl PAM module
1294 dnl
1295 dnl FRR detects the PAM library it is built against by checking for a
1296 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1297 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1298 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1299 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1300 dnl of OpenPAM.
1301 dnl ----------
1302 if test "$with_libpam" = "yes"; then
1303   AC_CHECK_HEADER([security/pam_misc.h],
1304     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1305      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1306      pam_conv_func="misc_conv"
1307     ],
1308     [], FRR_INCLUDES)
1309   AC_CHECK_HEADER([security/openpam.h],
1310     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1311      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1312      pam_conv_func="openpam_ttyconv"
1313     ],
1314     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1315   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1316     AC_MSG_WARN([*** pam support will not be built ***])
1317     with_libpam="no"
1318   fi
1319 fi
1320
1321 if test "$with_libpam" = "yes"; then
1322 dnl took this test from proftpds configure.in and suited to our needs
1323 dnl -------------------------------------------------------------------------
1324 dnl
1325 dnl This next check looks funky due to a linker problem with some versions
1326 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1327 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1328 dnl with RedHat 6.2 and Debian 2.2 or better.
1329 AC_CHECK_LIB([pam], [pam_start],
1330   [AC_CHECK_LIB([pam], [$pam_conv_func],
1331     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1332      LIBPAM="-lpam"],
1333     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1334      LIBPAM="-lpam -lpam_misc"]
1335     )
1336   ],
1337
1338   [AC_CHECK_LIB([pam], [pam_end],
1339     [AC_CHECK_LIB([pam], [$pam_conv_func],
1340       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1341        LIBPAM="-lpam -ldl"],
1342       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1343        LIBPAM="-lpam -ldl -lpam_misc"]
1344      )
1345   ],AC_MSG_WARN([*** pam support will not be built ***]),
1346   [-ldl])
1347   ]
1348 )
1349 fi
1350 AC_SUBST([LIBPAM])
1351
1352 dnl -------------------------------
1353 dnl bgpd needs pow() and hence libm
1354 dnl -------------------------------
1355 TMPLIBS="$LIBS"
1356 LIBS=""
1357 AC_SEARCH_LIBS([pow], [m], [
1358   LIBM="$LIBS"
1359 ], [
1360   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1361 ])
1362 LIBS="$TMPLIBS"
1363 AC_SUBST([LIBM])
1364
1365 AC_CHECK_FUNCS([ppoll], [
1366   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1367 ])
1368 AC_CHECK_FUNCS([pollts], [
1369   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1370 ])
1371
1372 AC_CHECK_HEADER([asm-generic/unistd.h],
1373                 [AC_CHECK_DECL(__NR_setns,
1374                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1375                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1376                                ])
1377                  AC_CHECK_FUNCS([setns])]
1378                )
1379
1380 dnl --------------------------
1381 dnl Determine IS-IS I/O method
1382 dnl --------------------------
1383 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1384 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1385 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1386 AC_CHECK_HEADER([net/bpf.h])
1387 AC_CHECK_HEADER([sys/dlpi.h])
1388 AC_MSG_CHECKING([zebra IS-IS I/O method])
1389
1390 case "$host_os" in
1391   linux*)
1392     AC_MSG_RESULT([pfpacket])
1393     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1394     ;;
1395   solaris* | sunos*)
1396     AC_MSG_RESULT([DLPI])
1397     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1398     ;;
1399   *)
1400     if test "$ac_cv_header_net_bpf_h" = "no"; then
1401       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1402         AC_MSG_RESULT([none])
1403         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1404           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1405         fi
1406         AC_MSG_WARN([*** IS-IS support will not be built ***])
1407         enable_isisd="no"
1408         enable_fabricd="no"
1409       else
1410         AC_MSG_RESULT([DLPI])
1411       fi
1412       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1413     else
1414       AC_MSG_RESULT([BPF])
1415       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1416     fi
1417     ;;
1418 esac
1419 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1420
1421 dnl ---------------------------------------------------------------
1422 dnl figure out how to specify an interface in multicast sockets API
1423 dnl ---------------------------------------------------------------
1424 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1425
1426 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1427         #include <sys/socket.h>
1428         #include <netinet/in.h>
1429         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1430         #include <linux/types.h>
1431 ])
1432
1433 m4_define([FRR_INCLUDES],
1434 FRR_INCLUDES
1435 [#ifdef HAVE_LINUX_MROUTE_H
1436 # include <linux/mroute.h>
1437 #endif
1438 ])dnl
1439
1440 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1441         #include <sys/socket.h>
1442         #include <sys/types.h>
1443         #include <netinet/in.h>
1444         #include <net/route.h>
1445 ])
1446
1447 m4_define([FRR_INCLUDES],
1448 FRR_INCLUDES
1449 [#ifdef HAVE_NETINET_IP_MROUTE_H
1450 # include <netinet/ip_mroute.h>
1451 #endif
1452 ])dnl
1453
1454 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1455 AC_TRY_COMPILE([#include <sys/param.h>],
1456 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1457   return (0);
1458 #else
1459   #error No support for BSD struct ip_mreq hack detected
1460 #endif],[AC_MSG_RESULT([yes])
1461 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1462 AC_MSG_RESULT([no]))
1463
1464 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1465 AC_TRY_COMPILE([
1466 #include <sys/types.h>
1467 #include <netinet/in.h>
1468 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1469 ], [AC_MSG_RESULT([yes])
1470 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1471 AC_MSG_RESULT([no]))
1472
1473 dnl ---------------------------------------------------------------
1474 dnl figure out how to check link-state
1475 dnl ---------------------------------------------------------------
1476 AC_CHECK_HEADER([net/if_media.h],
1477   [m4_define([LINK_DETECT_INCLUDES],
1478     FRR_INCLUDES
1479     [#include <net/if_media.h>
1480   ])
1481   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1482     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1483     [], LINK_DETECT_INCLUDES)],
1484   [],
1485   FRR_INCLUDES)
1486
1487 dnl ---------------------------------------------------------------
1488 dnl Additional, newer way to check link-state using ifi_link_state.
1489 dnl Not available in all BSD's when ifmediareq available
1490 dnl ---------------------------------------------------------------
1491 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1492   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1493   [], FRR_INCLUDES)
1494
1495 dnl ------------------------
1496 dnl TCP_MD5SIG socket option
1497 dnl ------------------------
1498
1499 AC_CHECK_HEADER([netinet/tcp.h],
1500    [m4_define([MD5_INCLUDES],
1501       FRR_INCLUDES
1502       [#include <netinet/tcp.h>
1503     ])
1504     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1505    [],
1506    FRR_INCLUDES)
1507 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1508   AC_CHECK_HEADER([linux/tcp.h],
1509        [m4_define([MD5_INCLUDES],
1510           FRR_INCLUDES
1511           [#include <linux/tcp.h>
1512         ])
1513        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1514 fi
1515
1516 AC_SUBST([SOLARIS])
1517 AC_CHECK_LIB([crypt], [crypt], [],
1518                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1519 AC_CHECK_LIB([resolv], [res_init])
1520
1521 dnl ---------------------------
1522 dnl check system has PCRE regexp
1523 dnl ---------------------------
1524 if test "$enable_pcreposix" = "yes"; then
1525   AC_CHECK_LIB([pcreposix], [regexec], [], [
1526     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1527   ])
1528 fi
1529 AC_SUBST([HAVE_LIBPCREPOSIX])
1530
1531 dnl ##########################################################################
1532 dnl test "$enable_clippy_only" != "yes"
1533 fi
1534 dnl END OF LARGE if block
1535 dnl ##########################################################################
1536
1537 dnl ------------------
1538 dnl check C-Ares library
1539 dnl ------------------
1540 PKG_CHECK_MODULES([CARES], [libcares], [
1541   c_ares_found=true
1542 ],[
1543   c_ares_found=false
1544 ])
1545 AM_CONDITIONAL([CARES], [$c_ares_found])
1546
1547
1548 dnl ----------------------------------------------------------------------------
1549 dnl figure out if domainname is available in the utsname struct (GNU extension).
1550 dnl ----------------------------------------------------------------------------
1551 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1552
1553 dnl ------------------
1554 dnl IPv6 header checks
1555 dnl ------------------
1556 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1557         netinet6/in6_var.h netinet6/nd6.h], [], [],
1558         FRR_INCLUDES)
1559
1560 m4_define([FRR_INCLUDES],dnl
1561 FRR_INCLUDES
1562 [#ifdef HAVE_NETINET6_IN6_H
1563 #include <netinet6/in6.h>
1564 #endif
1565 #ifdef HAVE_NETINET_IN6_VAR_H
1566 #include <netinet/in6_var.h>
1567 #endif
1568 #include <netinet/icmp6.h>
1569 #ifdef HAVE_NETINET6_IN6_VAR_H
1570 # include <netinet6/in6_var.h>
1571 #endif
1572 #ifdef HAVE_NETINET6_ND6_H
1573 # include <netinet6/nd6.h>
1574 #endif
1575 ])dnl
1576
1577 dnl --------------------
1578 dnl Daemon disable check
1579 dnl --------------------
1580
1581 AS_IF([test "$enable_ldpd" != "no"], [
1582   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1583 ])
1584
1585 if test "$enable_bfdd" = "no"; then
1586   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1587   BFDD=""
1588 else
1589   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1590   BFDD="bfdd"
1591
1592   case $host_os in
1593     linux*)
1594       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1595       ;;
1596
1597     *)
1598       AC_DEFINE([BFD_BSD], [1], [bfdd])
1599       ;;
1600   esac
1601 fi
1602
1603 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1604   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1605 fi
1606
1607 NHRPD=""
1608 case "$host_os" in
1609   linux*)
1610     case "${enable_nhrpd}" in
1611       no)
1612         ;;
1613       yes)
1614         if test "$enable_clippy_only" != "yes"; then
1615         if test "$c_ares_found" != "true" ; then
1616           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1617         fi
1618         fi
1619         NHRPD="nhrpd"
1620         ;;
1621       *)
1622         if test "$c_ares_found" = "true" ; then
1623           NHRPD="nhrpd"
1624         fi
1625         ;;
1626     esac
1627     ;;
1628   *)
1629     if test "$enable_nhrpd" = "yes"; then
1630       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1631     fi
1632     ;;
1633 esac
1634
1635 if test "$enable_watchfrr" = "no";then
1636   WATCHFRR=""
1637 else
1638   WATCHFRR="watchfrr"
1639 fi
1640
1641 OSPFCLIENT=""
1642 if test "$enable_ospfapi" != "no";then
1643     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1644
1645   if test "$enable_ospfclient" != "no";then
1646       OSPFCLIENT="ospfclient"
1647   fi
1648 fi
1649
1650 if test "$enable_bgp_announce" = "no";then
1651   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1652 else
1653   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1654 fi
1655
1656 if test "$enable_bgp_vnc" != "no";then
1657   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1658 fi
1659
1660 bgpd_bmp=false
1661 case "${enable_bmp}" in
1662   no)
1663     ;;
1664   yes)
1665     if test "$c_ares_found" != "true" ; then
1666       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1667     fi
1668     bgpd_bmp=true
1669     ;;
1670   *)
1671     if test "$c_ares_found" = "true" ; then
1672       bgpd_bmp=true
1673     fi
1674     ;;
1675 esac
1676
1677 dnl ##########################################################################
1678 dnl LARGE if block
1679 if test "$enable_clippy_only" != "yes"; then
1680 dnl ##########################################################################
1681
1682 dnl ------------------
1683 dnl check Net-SNMP library
1684 dnl ------------------
1685 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1686    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1687    if test "$NETSNMP_CONFIG" = "no"; then
1688       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1689    fi
1690    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1691    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1692    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1693    # among other things we avoid a GPL vs. OpenSSL license conflict here
1694    for removelib in crypto ssl sensors pci wrap; do
1695      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1696    done
1697    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1698    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1699 int main(void);
1700 ],
1701 [
1702 {
1703   return 0;
1704 }
1705 ])], [
1706      AC_MSG_RESULT([no])
1707      AC_MSG_ERROR([--enable-snmp given but not usable])])
1708    case "${enable_snmp}" in
1709      yes)
1710       SNMP_METHOD=agentx
1711       ;;
1712      agentx)
1713       SNMP_METHOD="${enable_snmp}"
1714       ;;
1715      *)
1716       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1717       ;;
1718    esac
1719    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1720    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1721 fi
1722 AC_SUBST([SNMP_LIBS])
1723 AC_SUBST([SNMP_CFLAGS])
1724
1725 dnl ---------------
1726 dnl libyang
1727 dnl ---------------
1728 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.105], , [
1729   AC_MSG_ERROR([libyang (>= 0.16.105) was not found on your system.])
1730 ])
1731 ac_cflags_save="$CFLAGS"
1732 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1733 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1734   AC_MSG_ERROR([m4_normalize([
1735     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1736     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1737   ])
1738 ], [[#include <libyang/libyang.h>]])
1739 CFLAGS="$ac_cflags_save"
1740
1741 dnl ---------------
1742 dnl configuration rollbacks
1743 dnl ---------------
1744 SQLITE3=false
1745 if test "$enable_config_rollbacks" = "yes"; then
1746   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1747     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1748     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1749     SQLITE3=true
1750   ], [
1751     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1752   ])
1753 fi
1754
1755 dnl ---------------
1756 dnl confd
1757 dnl ---------------
1758 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1759    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1760    if test "$CONFD" = "/bin/false"; then
1761       AC_MSG_ERROR([confd was not found on your system.])]
1762    fi
1763    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1764    AC_SUBST([CONFD_CFLAGS])
1765    CONFD_LIBS="-lconfd"
1766    AC_SUBST([CONFD_LIBS])
1767    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1768 fi
1769
1770 dnl ---------------
1771 dnl sysrepo
1772 dnl ---------------
1773 if test "$enable_sysrepo" = "yes"; then
1774   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1775       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1776       SYSREPO=true],
1777       [SYSREPO=false
1778       AC_MSG_ERROR([sysrepo was not found on your system.])]
1779   )
1780 fi
1781
1782 dnl ---------------
1783 dnl gRPC
1784 dnl ---------------
1785 if test "$enable_grpc" = "yes"; then
1786   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1787     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1788     if test "$PROTOC" = "/bin/false"; then
1789       AC_MSG_FAILURE([grpc requested but protoc not found.])
1790     fi
1791
1792     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1793     GRPC=true
1794   ], [
1795     GRPC=false
1796     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1797   ])
1798 fi
1799
1800 dnl ------
1801 dnl ZeroMQ
1802 dnl ------
1803 if test "$enable_zeromq" != "no"; then
1804   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1805     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1806     ZEROMQ=true
1807   ], [
1808     if test "$enable_zeromq" = "yes"; then
1809       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1810     fi
1811   ])
1812 fi
1813
1814 dnl ------------------------------------
1815 dnl Enable RPKI and add librtr to libs
1816 dnl ------------------------------------
1817 if test "$enable_rpki" = "yes"; then
1818   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1819       [RPKI=true],
1820       [RPKI=false
1821       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1822   )
1823 fi
1824
1825 dnl ------------------------------------
1826 dnl pimd is not supported on OpenBSD and MacOS
1827 dnl ------------------------------------
1828 if test "$enable_pimd" != "no"; then
1829 AC_MSG_CHECKING([for pimd OS support])
1830 case "$host_os" in
1831   darwin*)
1832     AC_MSG_RESULT([no])
1833     enable_pimd="no"
1834     ;;
1835   openbsd*)
1836     AC_MSG_RESULT([no])
1837     enable_pimd="no"
1838     ;;
1839   *)
1840     AC_MSG_RESULT([yes])
1841     ;;
1842 esac
1843 fi
1844
1845 dnl -------------------------------------
1846 dnl VRRP is only supported on linux
1847 dnl -------------------------------------
1848 if test "$enable_vrrpd" != "no"; then
1849 AC_MSG_CHECKING([for VRRP OS support])
1850 case "$host_os" in
1851   linux*)
1852     AC_MSG_RESULT([yes])
1853     ;;
1854   *)
1855     AC_MSG_RESULT([no])
1856     enable_vrrpd="no"
1857     ;;
1858 esac
1859 fi
1860
1861 dnl ------------------------------------------
1862 dnl Check whether rtrlib was build with ssh support
1863 dnl ------------------------------------------
1864 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1865 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1866                         [[struct tr_ssh_config config;]])],
1867         [AC_MSG_RESULT([yes])
1868         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1869         AC_MSG_RESULT([no])
1870 )
1871
1872 dnl ---------------
1873 dnl dlopen & dlinfo
1874 dnl ---------------
1875 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1876   AC_MSG_ERROR([unable to find the dlopen()])
1877 ])
1878
1879 AC_CHECK_HEADERS([link.h])
1880
1881 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1882   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1883 #include <stdlib.h>
1884 #ifdef HAVE_LINK_H
1885 #include <link.h>
1886 #endif
1887 #include <dlfcn.h>
1888 ]], [[
1889   char origin[1];
1890   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1891 ]])], [
1892     frr_cv_rtld_di_origin=yes
1893   ], [
1894     frr_cv_rtld_di_origin=no
1895   ])
1896 ])
1897 if test "$frr_cv_rtld_di_origin" = "yes"; then
1898   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1899 fi
1900
1901 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1902   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1903 #include <stdlib.h>
1904 #ifdef HAVE_LINK_H
1905 #include <link.h>
1906 #endif
1907 #include <dlfcn.h>
1908 ]], [[
1909   struct link_map *lm = NULL;
1910   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1911 ]])], [
1912     frr_cv_rtld_di_linkmap=yes
1913   ], [
1914     frr_cv_rtld_di_linkmap=no
1915   ])
1916 ])
1917 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
1918   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1919 fi
1920
1921 dnl ##########################################################################
1922 dnl test "$enable_clippy_only" != "yes"
1923 fi
1924 dnl END OF LARGE if block
1925 dnl ##########################################################################
1926
1927 dnl ---------------------------
1928 dnl sockaddr and netinet checks
1929 dnl ---------------------------
1930 AC_CHECK_TYPES([
1931         struct sockaddr_dl,
1932         struct vifctl, struct mfcctl, struct sioc_sg_req,
1933         vifi_t, struct sioc_vif_req, struct igmpmsg,
1934         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1935         struct nd_opt_adv_interval,
1936         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1937         struct nd_opt_rdnss, struct nd_opt_dnssl],
1938         [], [], FRR_INCLUDES)
1939
1940 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1941         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1942         struct sockaddr_dl.sdl_len,
1943         struct if6_aliasreq.ifra_lifetime,
1944         struct nd_opt_adv_interval.nd_opt_ai_type],
1945         [], [], FRR_INCLUDES)
1946
1947 dnl ---------------------------
1948 dnl IRDP/pktinfo/icmphdr checks
1949 dnl ---------------------------
1950
1951 AC_CHECK_TYPES([struct in_pktinfo], [
1952   AC_CHECK_TYPES([struct icmphdr], [
1953     IRDP=true
1954   ], [
1955     IRDP=false
1956   ], [FRR_INCLUDES])
1957 ], [
1958   IRDP=false
1959 ], [FRR_INCLUDES])
1960
1961 case "${enable_irdp}" in
1962 yes)
1963   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1964   ;;
1965 no)
1966   IRDP=false
1967   ;;
1968 esac
1969
1970
1971 dnl -----------------------
1972 dnl checking for IP_PKTINFO
1973 dnl -----------------------
1974 AC_MSG_CHECKING([for IP_PKTINFO])
1975 AC_TRY_COMPILE([#include <netdb.h>], [
1976   int opt = IP_PKTINFO;
1977 ], [
1978   AC_MSG_RESULT([yes])
1979   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1980 ], [
1981   AC_MSG_RESULT([no])
1982 ])
1983
1984 dnl ---------------------------
1985 dnl checking for IP_RECVDSTADDR
1986 dnl ---------------------------
1987 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1988 AC_TRY_COMPILE([#include <netinet/in.h>], [
1989   int opt = IP_RECVDSTADDR;
1990 ], [
1991   AC_MSG_RESULT([yes])
1992   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1993 ], [
1994   AC_MSG_RESULT([no])
1995 ])
1996
1997 dnl ----------------------
1998 dnl checking for IP_RECVIF
1999 dnl ----------------------
2000 AC_MSG_CHECKING([for IP_RECVIF])
2001 AC_TRY_COMPILE([#include <netinet/in.h>], [
2002   int opt = IP_RECVIF;
2003 ], [
2004   AC_MSG_RESULT([yes])
2005   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2006 ], [
2007   AC_MSG_RESULT([no])
2008 ])
2009
2010 dnl ----------------------
2011 dnl checking for SO_BINDANY
2012 dnl ----------------------
2013 AC_MSG_CHECKING([for SO_BINDANY])
2014 AC_TRY_COMPILE([#include <sys/socket.h>], [
2015   int opt = SO_BINDANY;
2016 ], [
2017   AC_MSG_RESULT([yes])
2018   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2019 ], [
2020   AC_MSG_RESULT([no])
2021 ])
2022
2023 dnl ----------------------
2024 dnl checking for IP_FREEBIND
2025 dnl ----------------------
2026 AC_MSG_CHECKING([for IP_FREEBIND])
2027 AC_TRY_COMPILE([#include <netinet/in.h>], [
2028   int opt = IP_FREEBIND;
2029 ], [
2030   AC_MSG_RESULT([yes])
2031   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2032 ], [
2033   AC_MSG_RESULT([no])
2034 ])
2035
2036 dnl --------------------------------------
2037 dnl checking for be32dec existence or not
2038 dnl --------------------------------------
2039 AC_CHECK_DECLS([be32enc, be32dec], [], [],
2040                [#include <sys/endian.h>])
2041
2042 dnl --------------------------------------
2043 dnl checking for clock_time monotonic struct and call
2044 dnl --------------------------------------
2045 AC_CHECK_DECL([CLOCK_MONOTONIC],
2046         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2047          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2048 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2049
2050 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2051   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2052 ])
2053
2054 dnl --------------------------------------
2055 dnl checking for flex and bison
2056 dnl --------------------------------------
2057
2058 AM_PROG_LEX
2059 AC_MSG_CHECKING([version of flex])
2060 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2061 frr_ac_flex_version="${frr_ac_flex_version##* }"
2062 AC_MSG_RESULT([$frr_ac_flex_version])
2063 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2064   LEX="$SHELL $missing_dir/missing flex"
2065   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2066     AC_MSG_WARN([using pregenerated flex output files])
2067   else
2068     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2069   fi
2070   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2071   AC_SUBST([LEXLIB], [''])
2072 ])
2073
2074 AC_PROG_YACC
2075 dnl thanks GNU bison for this b*llshit...
2076 AC_MSG_CHECKING([version of bison])
2077 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2078 frr_ac_bison_version="${frr_ac_bison_version##* }"
2079 frr_ac_bison_missing="false"
2080 case "x${frr_ac_bison_version}x" in
2081   x2.7*)
2082     BISON_OPENBRACE='"'
2083     BISON_CLOSEBRACE='"'
2084     BISON_VERBOSE=''
2085     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2086     ;;
2087   x2.*|x1.*)
2088     AC_MSG_RESULT([$frr_ac_bison_version])
2089     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2090     frr_ac_bison_missing="true"
2091     ;;
2092   x)
2093     AC_MSG_RESULT([none])
2094     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2095     frr_ac_bison_missing="true"
2096     ;;
2097   x3.[012][^0-9]*)
2098     BISON_OPENBRACE='{'
2099     BISON_CLOSEBRACE='}'
2100     BISON_VERBOSE='-Dparse.error=verbose'
2101     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2102     ;;
2103   *)
2104     BISON_OPENBRACE='{'
2105     BISON_CLOSEBRACE='}'
2106     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2107     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2108     ;;
2109 esac
2110 AC_SUBST([BISON_OPENBRACE])
2111 AC_SUBST([BISON_CLOSEBRACE])
2112 AC_SUBST([BISON_VERBOSE])
2113
2114 if $frr_ac_bison_missing; then
2115   YACC="$SHELL $missing_dir/missing bison -y"
2116   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2117     AC_MSG_WARN([using pregenerated bison output files])
2118   else
2119     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2120   fi
2121 fi
2122
2123 dnl -------------------
2124 dnl capabilities checks
2125 dnl -------------------
2126 if test "$enable_capabilities" != "no"; then
2127   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2128   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2129     [AC_MSG_RESULT([yes])
2130      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2131      frr_ac_keepcaps="yes"],
2132      AC_MSG_RESULT([no])
2133   )
2134   if test "$frr_ac_keepcaps" = "yes"; then
2135     AC_CHECK_HEADERS([sys/capability.h])
2136   fi
2137   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2138     AC_CHECK_LIB([cap], [cap_init],
2139       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2140        LIBCAP="-lcap"
2141        frr_ac_lcaps="yes"]
2142     )
2143   else
2144     AC_CHECK_HEADERS([priv.h],
2145      [AC_MSG_CHECKING([Solaris style privileges are available])
2146       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
2147           [AC_MSG_RESULT([yes])
2148            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
2149            frr_ac_scaps="yes"],
2150            AC_MSG_RESULT(no)
2151       )
2152      ]
2153    )
2154   fi
2155   if test "$frr_ac_scaps" = "yes" \
2156        -o "$frr_ac_lcaps" = "yes"; then
2157     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2158   fi
2159
2160   case "$host_os" in
2161   linux*)
2162     if test "$enable_clippy_only" != "yes"; then
2163     if test "$frr_ac_lcaps" != "yes"; then
2164       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2165     fi
2166     fi
2167     ;;
2168   esac
2169 else
2170   case "$host_os" in
2171   linux*)
2172     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2173     ;;
2174   esac
2175 fi
2176 AC_SUBST([LIBCAP])
2177
2178 dnl ---------------------------
2179 dnl check for glibc 'backtrace'
2180 dnl ---------------------------
2181 if test "$enable_backtrace" != "no" ; then
2182   backtrace_ok=no
2183   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2184     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2185     backtrace_ok=yes
2186   ], [
2187     true
2188   ])
2189
2190   if test "$backtrace_ok" = "no"; then
2191     AC_CHECK_HEADER([unwind.h], [
2192       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2193         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2194         backtrace_ok=yes
2195       ])
2196     ])
2197   fi
2198
2199   if test "$backtrace_ok" = "no"; then
2200     case "$host_os" in
2201     sunos* | solaris2*)
2202       AC_CHECK_FUNCS([printstack], [
2203         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
2204         backtrace_ok=yes
2205       ])
2206       ;;
2207     esac
2208     if test "$backtrace_ok" = "no"; then
2209       AC_CHECK_HEADER([execinfo.h], [
2210         AC_SEARCH_LIBS([backtrace], [execinfo], [
2211           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2212           backtrace_ok=yes
2213         ],, [-lm])
2214       ])
2215     fi
2216   fi
2217
2218   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2219     dnl user explicitly requested backtrace but we failed to find support
2220     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2221   fi
2222 fi
2223
2224 dnl -----------------------------------------
2225 dnl check for malloc mallinfo struct and call
2226 dnl this must try and link using LIBS, in
2227 dnl order to check no alternative allocator
2228 dnl has been specified, which might not provide
2229 dnl mallinfo, e.g. such as Umem on Solaris.
2230 dnl -----------------------------------------
2231 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2232
2233 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2234   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2235 #ifdef HAVE_MALLOC_H
2236 #include <malloc.h>
2237 #endif
2238 #ifdef HAVE_MALLOC_NP_H
2239 #include <malloc_np.h>
2240 #endif
2241 #ifdef HAVE_MALLOC_MALLOC_H
2242 #include <malloc/malloc.h>
2243 #endif
2244 ]], [[
2245 struct mallinfo ac_x; ac_x = mallinfo ();
2246 ]])], [
2247     frr_cv_mallinfo=yes
2248   ], [
2249     frr_cv_mallinfo=no
2250   ])
2251 ])
2252 if test "$frr_cv_mallinfo" = "yes"; then
2253   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2254 fi
2255
2256 AC_MSG_CHECKING([whether malloc_usable_size is available])
2257 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2258 #ifdef HAVE_MALLOC_H
2259 #include <malloc.h>
2260 #endif
2261 #ifdef HAVE_MALLOC_MALLOC_H
2262 #include <malloc/malloc.h>
2263 #endif
2264 ]], [[
2265 size_t ac_x; ac_x = malloc_usable_size(NULL);
2266 ]])], [
2267   AC_MSG_RESULT([yes])
2268   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2269 ], [
2270   AC_MSG_RESULT([no])
2271
2272   AC_MSG_CHECKING([whether malloc_size is available])
2273   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2274 #ifdef HAVE_MALLOC_H
2275 #include <malloc.h>
2276 #endif
2277 #ifdef HAVE_MALLOC_MALLOC_H
2278 #include <malloc/malloc.h>
2279 #endif
2280 ]], [[
2281 size_t ac_x; ac_x = malloc_size(NULL);
2282 ]])], [
2283     AC_MSG_RESULT([yes])
2284     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2285   ], [
2286     AC_MSG_RESULT([no])
2287   ])
2288 ])
2289
2290 dnl ----------
2291 dnl configure date
2292 dnl ----------
2293 dev_version=`echo $VERSION | grep dev`
2294 #don't expire deprecated code in non 'dev' branch
2295 if test "$dev_version" = ""; then
2296    CONFDATE=0
2297 else
2298    CONFDATE=`date '+%Y%m%d'`
2299 fi
2300 AC_SUBST([CONFDATE])
2301
2302 dnl ------------------------------
2303 dnl set paths for state directory
2304 dnl ------------------------------
2305 AC_MSG_CHECKING([directory to use for state file])
2306 if test "$prefix" = "NONE"; then
2307   frr_statedir_prefix="";
2308 else
2309   frr_statedir_prefix=${prefix}
2310 fi
2311 if test "$localstatedir" = '${prefix}/var'; then
2312   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2313                         ${frr_statedir_prefix}/var/adm dnl
2314                         ${frr_statedir_prefix}/etc dnl
2315                         /var/run        dnl
2316                         /var/adm        dnl
2317                         /etc            dnl
2318                         /dev/null;
2319   do
2320     test -d $FRR_STATE_DIR && break
2321   done
2322   frr_statedir=$FRR_STATE_DIR
2323 else
2324   frr_statedir=${localstatedir}
2325 fi
2326 if test "$frr_statedir" = "/dev/null"; then
2327     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2328 fi
2329 AC_MSG_RESULT([${frr_statedir}])
2330 AC_SUBST([frr_statedir])
2331
2332 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2333 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2334 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2335 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2336 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2337
2338 dnl autoconf does this, but it does it too late...
2339 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2340 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2341
2342 dnl get the full path, recursing through variables...
2343 vtysh_bin="$bindir/vtysh"
2344 for I in 1 2 3 4 5 6 7 8 9 10; do
2345         eval vtysh_bin="\"$vtysh_bin\""
2346 done
2347 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2348 AC_SUBST([vtysh_bin])
2349
2350 CFG_SYSCONF="$sysconfdir"
2351 CFG_SBIN="$sbindir"
2352 CFG_STATE="$frr_statedir"
2353 CFG_MODULE="$moduledir"
2354 CFG_YANGMODELS="$yangmodelsdir"
2355 for I in 1 2 3 4 5 6 7 8 9 10; do
2356         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2357         eval CFG_SBIN="\"$CFG_SBIN\""
2358         eval CFG_STATE="\"$CFG_STATE\""
2359         eval CFG_MODULE="\"$CFG_MODULE\""
2360         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2361 done
2362 AC_SUBST([CFG_SYSCONF])
2363 AC_SUBST([CFG_SBIN])
2364 AC_SUBST([CFG_STATE])
2365 AC_SUBST([CFG_MODULE])
2366 AC_SUBST([CFG_YANGMODELS])
2367 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2368 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2369 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2370
2371 dnl various features
2372 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2373 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2374 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2375 dnl northbound
2376 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2377 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2378 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2379 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2380 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2381 dnl plugins
2382 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2383 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2384 AM_CONDITIONAL([IRDP], [$IRDP])
2385 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2386 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2387 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2388 dnl daemons
2389 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2390 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2391 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2392 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2393 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2394 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2395 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2396 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2397 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2398 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2399 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2400 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2401 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2402 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2403 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2404 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2405 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2406 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2407 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2408 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2409 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2410
2411 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2412
2413 AC_CONFIG_FILES([
2414           config.version
2415           changelog-auto
2416           redhat/frr.spec
2417           solaris/Makefile
2418           alpine/APKBUILD
2419           snapcraft/snapcraft.yaml
2420           lib/version.h
2421           tests/lib/cli/test_cli.refout
2422           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2423           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2424           pkgsrc/eigrpd.sh])
2425
2426 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2427 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2428 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2429 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2430 AC_CONFIG_FILES([tools/frrcommon.sh])
2431
2432 AC_CONFIG_COMMANDS([lib/route_types.h], [
2433         dst="${ac_abs_top_builddir}/lib/route_types.h"
2434         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2435                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2436                 > "${dst}.tmp"
2437         test -f "$dst" \
2438                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2439                 && rm "${dst}.tmp" \
2440                 || mv "${dst}.tmp" "${dst}"
2441 ], [
2442         PERL="$PERL"
2443 ])
2444
2445 AS_IF([test "$with_pkg_git_version" = "yes"], [
2446     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2447         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2448         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2449                 "${ac_abs_top_srcdir}" \
2450                 > "${dst}.tmp"
2451         test -f "$dst" \
2452                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2453                 && rm "${dst}.tmp" \
2454                 || mv "${dst}.tmp" "${dst}"
2455     ], [
2456         PERL="$PERL"
2457     ])
2458 ])
2459
2460 ## Hack, but working solution to avoid rebuilding of frr.info.
2461 ## It's already in CVS until texinfo 4.7 is more common.
2462 AC_OUTPUT
2463
2464 echo "
2465 FRRouting configuration
2466 ------------------------------
2467 FRR version             : ${PACKAGE_VERSION}
2468 host operating system   : ${host_os}
2469 source code location    : ${srcdir}
2470 compiler                : ${CC}
2471 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2472 make                    : ${MAKE-make}
2473 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2474 state file directory    : ${frr_statedir}
2475 config file directory   : `eval echo \`echo ${sysconfdir}\``
2476 example directory       : `eval echo \`echo ${exampledir}\``
2477 module directory        : ${CFG_MODULE}
2478 user to run as          : ${enable_user}
2479 group to run as         : ${enable_group}
2480 group for vty sockets   : ${enable_vty_group}
2481 config file mask        : ${enable_configfile_mask}
2482 log file mask           : ${enable_logfile_mask}
2483 zebra protobuf enabled  : ${enable_protobuf:-no}
2484
2485 The above user and group must have read/write access to the state file
2486 directory and to the config files in the config file directory."
2487
2488 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2489   AC_MSG_WARN([sphinx is missing but required to build documentation])
2490 fi
2491 if test "$frr_py_mod_pytest" = "false"; then
2492   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2493 fi