configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.1], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST([HOSTTOOLS])
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS([config.h])
  64
  65 AC_PATH_PROG([PERL], [perl])
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST([exampledir])
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST([pkgsrcrcdir])
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94
  95 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
  96         yangmodelsdir="$withval"
  97 ], [
  98         yangmodelsdir="\${datarootdir}/yang"
  99 ])
 100 AC_SUBST([yangmodelsdir])
 101
 102 AC_ARG_WITH([libyang_pluginsdir], [AS_HELP_STRING([--with-libyang-pluginsdir=DIR], [yangmodule plugins directory (${libdir}/frr/libyang_plugins)])], [
 103         libyang_pluginsdir="$withval"
 104 ], [
 105    libyang_pluginsdir="\${libdir}/frr/libyang_plugins"
 106 ])
 107 AC_SUBST([libyang_pluginsdir])
 108
 109 AC_ARG_ENABLE(tcmalloc,
 110         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 111 [case "${enableval}" in
 112   yes) tcmalloc_enabled=true
 113 LIBS="$LIBS -ltcmalloc_minimal"
 114  ;;
 115   no)  tcmalloc_enabled=false ;;
 116   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 117 esac],[tcmalloc_enabled=false])
 118
 119
 120 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 121 dnl flag determination logic.
 122 CFLAGS="${CFLAGS:-}"
 123
 124 dnl --------------------
 125 dnl Check CC and friends
 126 dnl --------------------
 127 dnl note orig_cflags is also used further down
 128 orig_cflags="$CFLAGS"
 129 orig_cxxflags="$CXXFLAGS"
 130 AC_LANG([C])
 131 AC_PROG_CC
 132 AC_PROG_CPP
 133 AC_PROG_CXX
 134 AM_PROG_CC_C_O
 135 dnl remove autoconf default "-g -O2"
 136 CFLAGS="$orig_cflags"
 137 CXXFLAGS="$orig_cxxflags"
 138 AC_PROG_CC_C99
 139 dnl NB: see C11 below
 140
 141 AC_PROG_EGREP
 142 PKG_PROG_PKG_CONFIG
 143
 144 dnl autoconf 2.59 appears not to support AC_PROG_SED
 145 dnl AC_PROG_SED
 146 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 147
 148 dnl try and enable CFLAGS that are useful for FRR
 149 dnl - specifically, options to control warnings
 150
 151 AC_USE_SYSTEM_EXTENSIONS
 152 AC_DEFUN([AC_C_FLAG], [{
 153     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+],[____])])
 154     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 155         AC_LANG_PUSH([C])
 156         ac_c_flag_save="$CFLAGS"
 157         CFLAGS="$CFLAGS $1"
 158         AC_COMPILE_IFELSE(
 159                 [AC_LANG_PROGRAM([[]])],
 160                 [
 161                         cachename=yes
 162                 ], [
 163                         cachename=no
 164                 ])
 165         CFLAGS="$ac_c_flag_save"
 166         AC_LANG_POP([C])
 167     ])
 168     if test "${cachename}" = yes; then
 169         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 170     else
 171         :
 172         $2
 173     fi
 174     m4_popdef([cachename])
 175 }])
 176
 177 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 178         AC_LANG_PUSH([C])
 179         ac_cflags_save="$CFLAGS"
 180         ac_libs_save="$LIBS"
 181         CFLAGS="$CFLAGS $1"
 182         LIBS="$LIBS $2"
 183         AC_LINK_IFELSE(
 184                 [$3],
 185                 [
 186                         AC_MSG_RESULT([yes])
 187                         CFLAGS="$ac_cflags_save"
 188                         LIBS="$ac_libs_save"
 189                         $5
 190                 ], [
 191                         AC_MSG_RESULT([no])
 192                         CFLAGS="$ac_cflags_save"
 193                         LIBS="$ac_libs_save"
 194                         $4
 195                 ])
 196         AC_LANG_POP([C])
 197         }])
 198
 199 dnl ICC won't bail on unknown options without -diag-error 10006
 200 dnl need to do this first so we get useful results for the other options
 201 AC_C_FLAG([-diag-error 10006])
 202
 203 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 204 ac_cc="$CC"
 205 CC="${CC% -std=gnu99}"
 206 CC="${CC% -std=c99}"
 207
 208 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 209
 210 dnl if the user has specified any CFLAGS, override our settings
 211 if test "x${enable_gcov}" = "xyes"; then
 212    if test "z$orig_cflags" = "z"; then
 213       AC_C_FLAG([-coverage])
 214       AC_C_FLAG([-O0])
 215    fi
 216
 217    LDFLAGS="${LDFLAGS} -lgcov"
 218 elif test "x${enable_dev_build}" = "xyes"; then
 219    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 220    if test "z$orig_cflags" = "z"; then
 221       AC_C_FLAG([-g3])
 222       AC_C_FLAG([-O0])
 223    fi
 224    if test "x${enable_lua}" = "xyes"; then
 225       AC_CHECK_LIB([lua], [lua_newstate],
 226       [LIBS="$LIBS -llua"])
 227       AC_DEFINE([HAVE_LUA], [1], [Lua enabled for development])
 228    fi
 229 else
 230    if test "x${enable_lua}" = "xyes"; then
 231       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 232    fi
 233    if test "z$orig_cflags" = "z"; then
 234       AC_C_FLAG([-g])
 235       AC_C_FLAG([-Os], [
 236         AC_C_FLAG([-O2])
 237       ])
 238    fi
 239 fi
 240 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 241
 242 dnl always want these CFLAGS
 243 AC_C_FLAG([-fno-omit-frame-pointer])
 244 AC_C_FLAG([-funwind-tables])
 245 AC_C_FLAG([-Wall])
 246 AC_C_FLAG([-Wextra])
 247 AC_C_FLAG([-Wmissing-prototypes])
 248 AC_C_FLAG([-Wmissing-declarations])
 249 AC_C_FLAG([-Wpointer-arith])
 250 AC_C_FLAG([-Wbad-function-cast])
 251 AC_C_FLAG([-Wwrite-strings])
 252 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 253   AC_C_FLAG([-Wcast-qual])
 254   AC_C_FLAG([-Wstrict-prototypes])
 255   AC_C_FLAG([-Wmissing-noreturn])
 256   AC_C_FLAG([-Wmissing-format-attribute])
 257   AC_C_FLAG([-Wunreachable-code])
 258   AC_C_FLAG([-Wpacked])
 259   AC_C_FLAG([-Wpadded])
 260   AC_C_FLAG([-Wshadow])
 261 else
 262   AC_C_FLAG([-Wno-unused-result])
 263 fi
 264 AC_C_FLAG([-Wno-unused-parameter])
 265 AC_C_FLAG([-Wno-missing-field-initializers])
 266
 267 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 268 AC_SUBST([CXX_COMPAT_CFLAGS])
 269
 270 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 271 dnl for some reason the string consts get 'promoted' to char *,
 272 dnl triggering a const to non-const conversion warning.
 273 AC_C_FLAG([-diag-disable 3179])
 274
 275 if test x"${enable_werror}" = x"yes" ; then
 276   WERROR="-Werror"
 277 fi
 278 AC_SUBST([WERROR])
 279
 280 SAN_FLAGS=""
 281 if test "$enable_address_sanitizer" = "yes"; then
 282   AC_C_FLAG([-fsanitize=address], [
 283     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 284   ], [
 285     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 286   ])
 287 fi
 288 if test "$enable_thread_sanitizer" = "yes"; then
 289   AC_C_FLAG([-fsanitize=thread], [
 290     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 291   ], [
 292     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 293   ])
 294 fi
 295 if test "$enable_memory_sanitizer" = "yes"; then
 296   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 297     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 298   ], [
 299     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 300   ])
 301 fi
 302 AC_SUBST([SAN_FLAGS])
 303
 304 dnl ----------
 305 dnl Essentials
 306 dnl ----------
 307
 308 AX_PTHREAD([
 309   CC="$PTHREAD_CC"
 310   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 311   LIBS="$PTHREAD_LIBS $LIBS"
 312 ], [
 313   AC_MSG_FAILURE([This FRR version needs pthreads])
 314 ])
 315
 316 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 317                 [frr_cv_pthread_condattr_setclock=yes],
 318                 [frr_cv_pthread_condattr_setclock=no])
 319 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 320   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 321 fi
 322
 323 dnl --------------
 324 dnl Check programs
 325 dnl --------------
 326 AC_PROG_INSTALL
 327 AC_PROG_LN_S
 328 AC_PROG_MAKE_SET
 329 AC_CHECK_TOOL([AR], [ar])
 330
 331 dnl -------
 332 dnl libtool
 333 dnl -------
 334 AC_ARG_ENABLE([static-bin],
 335   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 336 LT_INIT
 337 _LT_CONFIG_LIBTOOL([
 338   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 339     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 340 ])
 341 if test "$enable_static_bin" = "yes"; then
 342   AC_LDFLAGS="-static"
 343   if test "$enable_static" != "yes"; then
 344     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 345   fi
 346 fi
 347 if test "$enable_shared" != "yes"; then
 348   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 349 fi
 350 AC_SUBST([AC_LDFLAGS])
 351 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 352
 353 dnl $AR and $RANLIB are set by LT_INIT above
 354 AC_MSG_CHECKING([whether $AR supports D option])
 355 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 356   AC_MSG_RESULT([yes])
 357   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 358   ARFLAGS="crD"
 359   AR_FLAGS="crD"
 360 else
 361   AC_MSG_RESULT([no])
 362   ARFLAGS="cru"
 363   AR_FLAGS="cru"
 364 fi
 365 AC_SUBST([ARFLAGS])
 366 AC_SUBST([AR_FLAGS])
 367
 368 AC_MSG_CHECKING([whether $RANLIB supports D option])
 369 if $RANLIB -D conftest.a >/dev/null 2>/dev/null; then
 370   AC_MSG_RESULT([yes])
 371   RANLIB="$RANLIB -D"
 372 else
 373   AC_MSG_RESULT([no])
 374 fi
 375 AC_SUBST([RANLIB])
 376
 377 test -f conftest.a && rm conftest.a
 378
 379 dnl ----------------------
 380 dnl Packages configuration
 381 dnl ----------------------
 382 if test -f config.version; then
 383   . ./config.version
 384 elif test -f "${srcdir}/config.version"; then
 385   . "${srcdir}/config.version"
 386 fi
 387 AC_ARG_WITH([pkg-extra-version],
 388   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 389   if test "$withval" = "no"; then
 390     EXTRAVERSION=
 391   else
 392     EXTRAVERSION=$withval
 393   fi
 394 ], [])
 395 AC_ARG_WITH([pkg-git-version],
 396         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 397         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 398 AC_ARG_WITH([vtysh_pager],
 399         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 400         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 401 AC_ARG_ENABLE([vtysh],
 402   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 403 AC_ARG_ENABLE([doc],
 404   AS_HELP_STRING([--disable-doc], [do not build docs]))
 405 AC_ARG_ENABLE([doc-html],
 406   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 407 AC_ARG_ENABLE([zebra],
 408   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 409 AC_ARG_ENABLE([bgpd],
 410   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 411 AC_ARG_ENABLE([ripd],
 412   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 413 AC_ARG_ENABLE([ripngd],
 414   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 415 AC_ARG_ENABLE([ospfd],
 416   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 417 AC_ARG_ENABLE([ospf6d],
 418   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 419 AC_ARG_ENABLE([ldpd],
 420   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 421 AC_ARG_ENABLE([nhrpd],
 422   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 423 AC_ARG_ENABLE([eigrpd],
 424   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 425 AC_ARG_ENABLE([babeld],
 426   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 427 AC_ARG_ENABLE([watchfrr],
 428   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 429 AC_ARG_ENABLE([isisd],
 430   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 431 AC_ARG_ENABLE([pimd],
 432   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 433 AC_ARG_ENABLE([pbrd],
 434   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 435 AC_ARG_ENABLE([sharpd],
 436   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 437 AC_ARG_ENABLE([staticd],
 438   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 439 AC_ARG_ENABLE([fabricd],
 440   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 441 AC_ARG_ENABLE([bgp-announce],
 442   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 443 AC_ARG_ENABLE([bgp-vnc],
 444   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 445 AC_ARG_ENABLE([snmp],
 446   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 447 AC_ARG_ENABLE([config_rollbacks],
 448   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 449 AC_ARG_ENABLE([confd],
 450   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 451 AC_ARG_ENABLE([sysrepo],
 452   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 453 AC_ARG_ENABLE([grpc],
 454   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 455 AC_ARG_ENABLE([zeromq],
 456   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 457 AC_ARG_WITH([libpam],
 458   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 459 AC_ARG_ENABLE([ospfapi],
 460   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 461 AC_ARG_ENABLE([ospfclient],
 462   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 463                           (this is the default if --disable-ospfapi is set)]))
 464 AC_ARG_ENABLE([multipath],
 465   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 466 AC_ARG_ENABLE([user],
 467   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 468 AC_ARG_ENABLE([group],
 469   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 470 AC_ARG_ENABLE([vty_group],
 471   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 472 AC_ARG_ENABLE([configfile_mask],
 473   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 474 AC_ARG_ENABLE([logfile_mask],
 475   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 476 AC_ARG_ENABLE([shell_access],
 477   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 478 AC_ARG_ENABLE([realms],
 479   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 480 AC_ARG_ENABLE([rtadv],
 481   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 482 AC_ARG_ENABLE([irdp],
 483   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 484 AC_ARG_ENABLE([capabilities],
 485   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 486 AC_ARG_ENABLE([rusage],
 487   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 488 AC_ARG_ENABLE([gcc_ultra_verbose],
 489   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 490 AC_ARG_ENABLE([backtrace],
 491   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 492 AC_ARG_ENABLE([time-check],
 493   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 494 AC_ARG_ENABLE([pcreposix],
 495   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 496 AC_ARG_ENABLE([fpm],
 497   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 498 AC_ARG_ENABLE([systemd],
 499   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 500 AC_ARG_ENABLE([werror],
 501   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 502 AC_ARG_ENABLE([cumulus],
 503   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 504 AC_ARG_ENABLE([datacenter],
 505   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 506 AC_ARG_ENABLE([fuzzing],
 507   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 508 AC_ARG_ENABLE([netlink_fuzzing],
 509   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 510 AC_ARG_ENABLE([rr-semantics],
 511   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 512 AC_ARG_ENABLE([protobuf],
 513   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 514 AC_ARG_ENABLE([oldvpn_commands],
 515   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 516 AC_ARG_ENABLE([rpki],
 517   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 518 AC_ARG_ENABLE([clippy-only],
 519   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 520 AC_ARG_ENABLE([numeric_version],
 521   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 522 AC_ARG_ENABLE([gcov],
 523   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 524 AC_ARG_ENABLE([bfdd],
 525   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 526 AC_ARG_ENABLE([address-sanitizer],
 527   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 528 AC_ARG_ENABLE([thread-sanitizer],
 529   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 530 AC_ARG_ENABLE([memory-sanitizer],
 531   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 532
 533 AS_IF([test "${enable_clippy_only}" != "yes"], [
 534 AC_CHECK_HEADERS([json-c/json.h])
 535 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 536 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 537   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 538   if test "$ac_cv_lib_json_json_object_get" = no; then
 539       AC_MSG_ERROR([libjson is needed to compile])
 540   fi
 541 fi
 542 ])
 543
 544 AC_ARG_ENABLE([dev_build],
 545     AS_HELP_STRING([--enable-dev-build], [build for development]))
 546
 547 AC_ARG_ENABLE([lua],
 548     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 549
 550 if test x"${enable_time_check}" != x"no" ; then
 551   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 552     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 553   else
 554     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 555   fi
 556 fi
 557
 558 case "${enable_systemd}" in
 559   "no") ;;
 560   "yes")
 561   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 562   if test $ac_cv_lib_systemd_sd_notify = no; then
 563     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 564   else
 565     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 566   fi
 567   ;;
 568   "*") ;;
 569 esac
 570
 571 if test "${enable_rr_semantics}" != "no" ; then
 572   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 573 fi
 574
 575 if test "${enable_datacenter}" = "yes" ; then
 576   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 577   DFLT_NAME="datacenter"
 578 else
 579   DFLT_NAME="traditional"
 580 fi
 581
 582 if test "${enable_fuzzing}" = "yes" ; then
 583   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 584 fi
 585
 586 if test "${enable_netlink_fuzzing}" = "yes" ; then
 587   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 588 fi
 589
 590 if test "${enable_cumulus}" = "yes" ; then
 591   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 592 fi
 593
 594 AC_SUBST([DFLT_NAME])
 595 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 596
 597 if test "${enable_shell_access}" = "yes"; then
 598    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 599 fi
 600
 601 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 602
 603 #
 604 # Python for clippy
 605 #
 606
 607 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 608   AC_MSG_CHECKING([whether we found a working Python version])
 609   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 610 #include <Python.h>
 611 #if PY_VERSION_HEX < 0x02070000
 612 #error python too old
 613 #endif
 614 int main(void);
 615 ],
 616 [
 617 {
 618   Py_Initialize();
 619   return 0;
 620 }
 621 ])], [
 622     # some python installs are missing the zlib dependency...
 623     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 624     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 625 #include <Python.h>
 626 #if PY_VERSION_HEX < 0x02070000
 627 #error python too old
 628 #endif
 629 int main(void);
 630 ],
 631 [
 632 {
 633   Py_Initialize();
 634   return 0;
 635 }
 636 ])], [
 637       m4_if([$1], [], [
 638         PYTHONCONFIG=""
 639         unset PYTHON_LIBS
 640         unset PYTHON_CFLAGS
 641       ], [$1])
 642     ])
 643   ])
 644 ])
 645
 646 AS_IF([test "$host" = "$build"], [
 647   PYTHONCONFIG=""
 648
 649   # ordering:
 650   # 1.  try python3, but respect the user's preference on which minor ver
 651   # 2.  try python, which might be py3 or py2 again on the user's preference
 652   # 3.  try python2 (can really only be 2.7 but eh)
 653   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 654   #
 655   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 656   # (AX_PYTHON does not do what we need)
 657
 658   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 659         python3-config \
 660         python-config \
 661         python2-config \
 662         python3.6-config \
 663         python3.5-config \
 664         python3.4-config \
 665         python3.3-config \
 666         python3.2-config \
 667         python2.7-config ])
 668   if test -n "$PYTHONCONFIG"; then
 669     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 670     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 671
 672     FRR_PYTHON_CHECK_WORKING([])
 673   fi
 674
 675   if test -z "$PYTHONCONFIG"; then
 676     PKG_CHECK_MODULES([PYTHON], [python-3.6], [], [
 677       PKG_CHECK_MODULES([PYTHON], [python-3.5], [], [
 678         PKG_CHECK_MODULES([PYTHON], [python-3.4], [], [
 679           PKG_CHECK_MODULES([PYTHON], [python-3.3], [], [
 680             PKG_CHECK_MODULES([PYTHON], [python-3.2], [], [
 681               PKG_CHECK_MODULES([PYTHON], [python-2.7], [], [
 682                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 683                 ])])])])])])
 684
 685
 686     FRR_PYTHON_CHECK_WORKING([
 687       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 688     ])
 689   fi
 690 ])
 691 AC_SUBST([PYTHON_CFLAGS])
 692 AC_SUBST([PYTHON_LIBS])
 693
 694 #
 695 # Logic for protobuf support.
 696 #
 697 if test "$enable_protobuf" = "yes"; then
 698   # Check for protoc & protoc-c
 699
 700   # protoc is not required, it's only for a "be nice" helper target
 701   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 702
 703   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 704   if test "$PROTOC_C" = "/bin/false"; then
 705     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 706   fi
 707
 708   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 709     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 710   ])
 711   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 712     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 713   ])
 714
 715   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
 716 fi
 717 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 718
 719 #
 720 # Logic for old vpn commands support.
 721 #
 722 if test "$enable_oldvpn_commands" = "yes"; then
 723    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 724 fi
 725
 726 #
 727 # End of logic for protobuf support.
 728 #
 729
 730 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 731 if test "${enable_rtadv}" != "no"; then
 732   AC_MSG_RESULT([yes])
 733   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 734 else
 735   AC_MSG_RESULT([no])
 736 fi
 737
 738 if test x"${enable_user}" = x"no"; then
 739   enable_user=""
 740 else
 741   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 742     enable_user="frr"
 743   fi
 744   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 745 fi
 746
 747 if test x"${enable_group}" = x"no"; then
 748   enable_group=""
 749 else
 750   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 751     enable_group="frr"
 752   fi
 753   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 754 fi
 755
 756 if test x"${enable_vty_group}" = x"yes" ; then
 757   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 758 elif test x"${enable_vty_group}" != x""; then
 759   if test x"${enable_vty_group}" != x"no"; then
 760     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 761   fi
 762 fi
 763 AC_SUBST([enable_user])
 764 AC_SUBST([enable_group])
 765 AC_SUBST([enable_vty_group])
 766
 767 enable_configfile_mask=${enable_configfile_mask:-0600}
 768 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 769
 770 enable_logfile_mask=${enable_logfile_mask:-0600}
 771 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 772
 773 MPATH_NUM=16
 774
 775 case "${enable_multipath}" in
 776   0)
 777     MPATH_NUM=64
 778     ;;
 779   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 780     MPATH_NUM="${enable_multipath}"
 781     ;;
 782   "")
 783     ;;
 784   *)
 785     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 786     ;;
 787 esac
 788
 789 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 790
 791 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 792
 793 dnl --------------------
 794 dnl Enable code coverage
 795 dnl --------------------
 796 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 797
 798 dnl ------------------------------------
 799 dnl Alpine only accepts numeric versions
 800 dnl ------------------------------------
 801 if test "x${enable_numeric_version}" != "x" ; then
 802   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 803   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 804 fi
 805
 806 dnl -----------------------------------
 807 dnl Add extra version string to package
 808 dnl name, string and version fields.
 809 dnl -----------------------------------
 810 if test "x${EXTRAVERSION}" != "x" ; then
 811   VERSION="${VERSION}${EXTRAVERSION}"
 812   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 813   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 814   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 815 fi
 816 AC_SUBST([EXTRAVERSION])
 817
 818 if test "x$with_pkg_git_version" = "xyes"; then
 819         if test -d "${srcdir}/.git"; then
 820                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 821         else    with_pkg_git_version="no"
 822                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 823         fi
 824 fi
 825 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 826
 827 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 828 if test "x${OBJCOPY}" != "x:"; then
 829   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 830     frr_cv_interp=""
 831     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 832       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 833         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 834       fi
 835       test -f conftest.interp && rm conftest.interp
 836     ])
 837   ])
 838 fi
 839 if test -n "$frr_cv_interp"; then
 840   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 841 fi
 842
 843 dnl ------------------------------------
 844 dnl Check C keywords and standard  types
 845 dnl ------------------------------------
 846 AC_C_CONST
 847 AC_C_INLINE
 848 AC_C_VOLATILE
 849 AC_HEADER_STDC
 850 dnl AC_TYPE_PID_T
 851 AC_TYPE_UID_T
 852 AC_TYPE_MODE_T
 853 AC_TYPE_SIZE_T
 854 AC_STRUCT_TM
 855
 856 dnl -------------------------
 857 dnl Check other header files.
 858 dnl -------------------------
 859 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 860         linux/version.h asm/types.h \
 861         sys/cdefs.h])
 862
 863 ac_stdatomic_ok=false
 864 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 865 AC_CHECK_HEADER([stdatomic.h],[
 866
 867   AC_MSG_CHECKING([whether _Atomic qualifier works])
 868   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 869 #include <stdatomic.h>
 870 int main(int argc, char **argv) {
 871   _Atomic int i = 0;
 872   return i;
 873 }
 874 ]])], [
 875     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 876     AC_MSG_RESULT([yes])
 877     ac_stdatomic_ok=true
 878   ], [
 879     AC_MSG_RESULT([no])
 880   ])
 881 ])
 882
 883 AS_IF([$ac_stdatomic_ok], [true], [
 884   AC_MSG_CHECKING([for __atomic_* builtins])
 885   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 886 int main(int argc, char **argv) {
 887   volatile int i = 1;
 888   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 889   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 890 }
 891 ]])], [
 892     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 893     AC_MSG_RESULT([yes])
 894   ], [
 895     AC_MSG_RESULT([no])
 896
 897     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 898     AC_MSG_CHECKING([for __sync_* builtins])
 899     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 900 int main(int argc, char **argv) {
 901   volatile int i = 1;
 902   __sync_fetch_and_sub (&i, 1);
 903   return __sync_val_compare_and_swap (&i, 0, 1);
 904 }
 905 ]])], [
 906       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 907       AC_MSG_RESULT([yes])
 908
 909       AC_MSG_CHECKING([for __sync_swap builtin])
 910       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 911 int main(int argc, char **argv) {
 912   volatile int i = 1;
 913   return __sync_swap (&i, 2);
 914 }
 915 ]])], [
 916         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 917         AC_MSG_RESULT([yes])
 918       ], [
 919         AC_MSG_RESULT([no])
 920       ])
 921
 922     ], [
 923       AC_MSG_RESULT([no])
 924       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 925     ])
 926   ])
 927 ])
 928
 929 AC_CHECK_HEADERS([pthread_np.h],,, [
 930 #include <pthread.h>
 931 ])
 932 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 933
 934 needsync=true
 935
 936 AS_IF([$needsync], [
 937   dnl Linux
 938   AC_MSG_CHECKING([for Linux futex() support])
 939   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 940 #ifndef _GNU_SOURCE
 941 #define _GNU_SOURCE
 942 #endif
 943 #include <unistd.h>
 944 #include <limits.h>
 945 #include <sys/time.h>
 946 #include <sys/syscall.h>
 947 #include <linux/futex.h>
 948
 949 int main(void);
 950 ],
 951 [
 952 {
 953   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 954 }
 955 ])], [
 956     AC_MSG_RESULT([yes])
 957     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 958     needsync=false
 959   ], [
 960     AC_MSG_RESULT([no])
 961   ])
 962 ])
 963
 964 AS_IF([$needsync], [
 965   dnl FreeBSD
 966   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 967   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 968 #include <errno.h>
 969 #include <stdlib.h>
 970 #include <sys/types.h>
 971 #include <sys/umtx.h>
 972 int main(void);
 973 ],
 974 [
 975 {
 976   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
 977 }
 978 ])], [
 979     AC_MSG_RESULT([yes])
 980     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
 981     needsync=false
 982   ], [
 983     AC_MSG_RESULT([no])
 984   ])
 985 ])
 986
 987 AS_IF([$needsync], [
 988   dnl OpenBSD patch (not upstream at the time of writing this)
 989   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
 990   AC_MSG_CHECKING([for OpenBSD futex() support])
 991   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 992 #include <sys/futex.h>
 993 int main(void);
 994 ],
 995 [
 996 {
 997   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 998 }
 999 ])], [
1000     AC_MSG_RESULT([yes])
1001     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1002     needsync=false
1003   ], [
1004     AC_MSG_RESULT([no])
1005   ])
1006 ])
1007
1008 dnl Utility macro to avoid retyping includes all the time
1009 m4_define([FRR_INCLUDES],
1010 [#ifdef SUNOS_5
1011 #define _POSIX_C_SOURCE 200809L
1012 #define __EXTENSIONS__
1013 #endif
1014 #include <stdio.h>
1015 #include <stdlib.h>
1016 #include <stddef.h>
1017 #include <sys/types.h>
1018 /* sys/conf.h depends on param.h on FBSD at least */
1019 #include <sys/param.h>
1020 /* Required for MAXSIG */
1021 #include <signal.h>
1022 #include <sys/socket.h>
1023 #ifdef __APPLE__
1024 # define __APPLE_USE_RFC_3542
1025 #endif
1026 #include <netinet/in.h>
1027 #include <sys/time.h>
1028 #include <time.h>
1029 #include <net/if.h>
1030 ])dnl
1031
1032 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1033 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1034 dnl an additional round for it.
1035
1036 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1037
1038 m4_define([FRR_INCLUDES],
1039 FRR_INCLUDES
1040 [#if HAVE_NET_IF_VAR_H
1041 # include <net/if_var.h>
1042 #endif
1043 ])dnl
1044
1045 AC_CHECK_HEADERS([netinet/in_var.h \
1046         net/if_dl.h net/netopt.h \
1047         inet/nd.h netinet/ip_icmp.h \
1048         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
1049         [], [], [FRR_INCLUDES])
1050
1051 AC_CHECK_HEADERS([ucontext.h], [], [],
1052 [#ifndef __USE_GNU
1053 #define __USE_GNU
1054 #endif /* __USE_GNU */
1055 FRR_INCLUDES
1056 ])
1057
1058 m4_define([UCONTEXT_INCLUDES],
1059 [#include <ucontext.h>])dnl
1060
1061 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1062   [], [], [UCONTEXT_INCLUDES])
1063 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1064   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1065    [], [], [UCONTEXT_INCLUDES])],
1066   [], [UCONTEXT_INCLUDES])
1067 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1068   [], [], [UCONTEXT_INCLUDES])
1069
1070 m4_define([FRR_INCLUDES],
1071 FRR_INCLUDES
1072 [
1073 #include <sys/un.h>
1074 #include <netinet/in_systm.h>
1075 #if HAVE_NETINET_IN_VAR_H
1076 # include <netinet/in_var.h>
1077 #endif
1078 #if HAVE_NET_IF_DL_H
1079 # include <net/if_dl.h>
1080 #endif
1081 #if HAVE_NET_NETOPT_H
1082 # include <net/netopt.h>
1083 #endif
1084 #include <net/route.h>
1085 #if HAVE_INET_ND_H
1086 # include <inet/nd.h>
1087 #endif
1088 #include <arpa/inet.h>
1089 /* Required for IDRP */
1090 #if HAVE_NETINET_IP_ICMP_H
1091 # include <netinet/ip_icmp.h>
1092 #endif
1093 ])dnl
1094
1095 dnl V6 headers are checked below, after we check for v6
1096
1097 AC_MSG_CHECKING([which operating system interface to use])
1098 case "$host_os" in
1099   sunos* | solaris2*)
1100     AC_MSG_RESULT([Solaris])
1101
1102     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1103     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1104     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1105
1106     AC_CHECK_LIB([socket], [main])
1107     AC_CHECK_LIB([nsl], [main])
1108     AC_CHECK_LIB([umem], [main])
1109     SOLARIS="solaris"
1110     ;;
1111   linux*)
1112     AC_MSG_RESULT([Linux])
1113
1114     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1115     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1116     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1117
1118     dnl Linux has a compilation problem with mixing
1119     dnl netinet/in.h and linux/in6.h they are not
1120     dnl compatible.  There has been discussion on
1121     dnl how to fix it but no real progress on implementation
1122     dnl when they fix it, remove this
1123     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1124     ;;
1125   openbsd*)
1126     AC_MSG_RESULT([OpenBSD])
1127
1128     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1129     AC_DEFINE([KAME], [1], [KAME IPv6])
1130     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1131
1132     if test "x${enable_pimd}" != "xno"; then
1133       case "$host_os" in
1134       openbsd6.0)
1135         ;;
1136       openbsd[6-9]*)
1137         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1138         ;;
1139       esac
1140     fi
1141     ;;
1142   *)
1143     AC_MSG_RESULT([BSD])
1144
1145     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1146     AC_DEFINE([KAME], [1], [KAME IPv6])
1147     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1148     ;;
1149 esac
1150 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1151
1152 AC_SYS_LARGEFILE
1153
1154 dnl ------------------------
1155 dnl Integrated REALMS option
1156 dnl ------------------------
1157 if test "${enable_realms}" = "yes"; then
1158     case "$host_os" in
1159       linux*)
1160        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1161        ;;
1162       *)
1163        echo "Sorry, only Linux has REALMS support"
1164        exit 1
1165        ;;
1166     esac
1167 fi
1168 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1169
1170 dnl ---------------------
1171 dnl Integrated VTY option
1172 dnl ---------------------
1173 case "${enable_vtysh}" in
1174 "no")
1175   VTYSH="";;
1176 *)
1177   VTYSH="vtysh";
1178   AC_DEFINE([VTYSH], [1], [VTY shell])
1179
1180   prev_libs="$LIBS"
1181   AC_CHECK_LIB([readline], [main], [
1182     LIBREADLINE="-lreadline"
1183   ], [
1184     dnl readline failed - it might be incorrectly linked and missing its
1185     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1186     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1187       LIBREADLINE="$ac_cv_search_tputs"
1188     ], [
1189       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1190     ])
1191
1192     dnl re-try with the lib we found above
1193     unset ac_cv_lib_readline_main
1194     AC_CHECK_LIB([readline], [main], [
1195       LIBREADLINE="-lreadline $LIBREADLINE"
1196     ], [
1197       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1198     ], [$LIBREADLINE])
1199   ], [])
1200   LIBS="$prev_libs"
1201
1202   AC_CHECK_HEADER([readline/history.h])
1203   if test $ac_cv_header_readline_history_h = no;then
1204     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1205   fi
1206   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1207   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1208     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1209   fi
1210   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1211   if test "$frr_cv_append_history" = yes; then
1212     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1213   fi
1214   ;;
1215 esac
1216 AC_SUBST([LIBREADLINE])
1217 AM_CONDITIONAL([VTYSH], test "x$VTYSH" = "xvtysh")
1218
1219 dnl ----------
1220 dnl PAM module
1221 dnl
1222 dnl FRR detects the PAM library it is built against by checking for a
1223 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1224 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1225 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1226 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1227 dnl of OpenPAM.
1228 dnl ----------
1229 if test "$with_libpam" = "yes"; then
1230   AC_CHECK_HEADER([security/pam_misc.h],
1231     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1232      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1233      pam_conv_func="misc_conv"
1234     ],
1235     [], FRR_INCLUDES)
1236   AC_CHECK_HEADER([security/openpam.h],
1237     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1238      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1239      pam_conv_func="openpam_ttyconv"
1240     ],
1241     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1242   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1243     AC_MSG_WARN([*** pam support will not be built ***])
1244     with_libpam="no"
1245   fi
1246 fi
1247
1248 if test "$with_libpam" = "yes"; then
1249 dnl took this test from proftpds configure.in and suited to our needs
1250 dnl -------------------------------------------------------------------------
1251 dnl
1252 dnl This next check looks funky due to a linker problem with some versions
1253 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1254 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1255 dnl with RedHat 6.2 and Debian 2.2 or better.
1256 AC_CHECK_LIB([pam], [pam_start],
1257   [AC_CHECK_LIB([pam], [$pam_conv_func],
1258     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1259      LIBPAM="-lpam"],
1260     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1261      LIBPAM="-lpam -lpam_misc"]
1262     )
1263   ],
1264
1265   [AC_CHECK_LIB([pam], [pam_end],
1266     [AC_CHECK_LIB([pam], [$pam_conv_func],
1267       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1268        LIBPAM="-lpam -ldl"],
1269       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1270        LIBPAM="-lpam -ldl -lpam_misc"]
1271      )
1272   ],AC_MSG_WARN([*** pam support will not be built ***]),
1273   [-ldl])
1274   ]
1275 )
1276 fi
1277 AC_SUBST([LIBPAM])
1278
1279 dnl -------------------------------
1280 dnl Endian-ness check
1281 dnl -------------------------------
1282 AC_WORDS_BIGENDIAN
1283
1284 dnl -------------------------------
1285 dnl check the size in byte of the C
1286 dnl -------------------------------
1287 dnl AC_CHECK_SIZEOF(char)
1288 dnl AC_CHECK_SIZEOF(int)
1289 dnl AC_CHECK_SIZEOF(short)
1290 dnl AC_CHECK_SIZEOF(long)
1291
1292 dnl ----------------------------
1293 dnl check existance of functions
1294 dnl ----------------------------
1295 AC_FUNC_FNMATCH
1296 AC_FUNC_FORK
1297 AC_FUNC_MKTIME
1298 AC_FUNC_STAT
1299
1300 dnl -------------------------------
1301 dnl bgpd needs pow() and hence libm
1302 dnl -------------------------------
1303 TMPLIBS="$LIBS"
1304 AC_CHECK_HEADER([math.h],
1305   [AC_CHECK_LIB([m], [pow],
1306     [LIBM="-lm"
1307      LIBS="$LIBS $LIBM"
1308      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1309     ])
1310 ])
1311 if test x"$LIBM" = x ; then
1312   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1313 fi
1314 LIBS="$TMPLIBS"
1315
1316 AC_SUBST([LIBM])
1317
1318 AC_CHECK_FUNCS([ppoll], [
1319   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1320 ])
1321 AC_CHECK_FUNCS([pollts], [
1322   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1323 ])
1324
1325 dnl ---------------
1326 dnl other functions
1327 dnl ---------------
1328 AC_CHECK_FUNCS([ \
1329         strlcat strlcpy \
1330         getgrouplist])
1331
1332 AC_CHECK_HEADER([asm-generic/unistd.h],
1333                 [AC_CHECK_DECL(__NR_setns,
1334                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1335                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1336                                ])
1337                  AC_CHECK_FUNCS([setns])]
1338                )
1339
1340 dnl --------------------------
1341 dnl Determine IS-IS I/O method
1342 dnl --------------------------
1343 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1344 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1345 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1346 AC_CHECK_HEADER([net/bpf.h])
1347 AC_CHECK_HEADER([sys/dlpi.h])
1348 AC_MSG_CHECKING([zebra IS-IS I/O method])
1349
1350 case "$host_os" in
1351   linux*)
1352     AC_MSG_RESULT([pfpacket])
1353     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1354     ;;
1355   solaris* | sunos*)
1356     AC_MSG_RESULT([DLPI])
1357     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1358     ;;
1359   *)
1360     if test $ac_cv_header_net_bpf_h = no; then
1361       if test $ac_cv_header_sys_dlpi_h = no; then
1362         AC_MSG_RESULT([none])
1363         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1364           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1365         fi
1366         AC_MSG_WARN([*** IS-IS support will not be built ***])
1367         enable_isisd="no"
1368         enable_fabricd="no"
1369       else
1370         AC_MSG_RESULT([DLPI])
1371       fi
1372       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1373     else
1374       AC_MSG_RESULT([BPF])
1375       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1376     fi
1377     ;;
1378 esac
1379 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1380
1381 dnl ---------------------------------------------------------------
1382 dnl figure out how to specify an interface in multicast sockets API
1383 dnl ---------------------------------------------------------------
1384 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1385
1386 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1387         #include <sys/socket.h>
1388         #include <netinet/in.h>
1389         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1390         #include <linux/types.h>
1391 ])
1392
1393 m4_define([FRR_INCLUDES],
1394 FRR_INCLUDES
1395 [#if HAVE_LINUX_MROUTE_H
1396 # include <linux/mroute.h>
1397 #endif
1398 ])dnl
1399
1400 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1401         #include <sys/socket.h>
1402         #include <sys/types.h>
1403         #include <netinet/in.h>
1404         #include <net/route.h>
1405 ])
1406
1407 m4_define([FRR_INCLUDES],
1408 FRR_INCLUDES
1409 [#if HAVE_NETINET_IP_MROUTE_H
1410 # include <netinet/ip_mroute.h>
1411 #endif
1412 ])dnl
1413
1414 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1415 AC_TRY_COMPILE([#include <sys/param.h>],
1416 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1417   return (0);
1418 #else
1419   #error No support for BSD struct ip_mreq hack detected
1420 #endif],[AC_MSG_RESULT([yes])
1421 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1422 AC_MSG_RESULT([no]))
1423
1424 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1425 AC_TRY_COMPILE([
1426 #include <sys/types.h>
1427 #include <netinet/in.h>
1428 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1429 ], [AC_MSG_RESULT([yes])
1430 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1431 AC_MSG_RESULT([no]))
1432
1433 dnl ---------------------------------------------------------------
1434 dnl figure out how to check link-state
1435 dnl ---------------------------------------------------------------
1436 AC_CHECK_HEADER([net/if_media.h],
1437   [m4_define([LINK_DETECT_INCLUDES],
1438     FRR_INCLUDES
1439     [#include <net/if_media.h>
1440   ])
1441   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1442     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1443     [], LINK_DETECT_INCLUDES)],
1444   [],
1445   FRR_INCLUDES)
1446
1447 dnl ---------------------------------------------------------------
1448 dnl Additional, newer way to check link-state using ifi_link_state.
1449 dnl Not available in all BSD's when ifmediareq available
1450 dnl ---------------------------------------------------------------
1451 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1452   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1453   [], FRR_INCLUDES)
1454
1455 dnl ------------------------
1456 dnl TCP_MD5SIG socket option
1457 dnl ------------------------
1458
1459 AC_CHECK_HEADER([netinet/tcp.h],
1460    [m4_define([MD5_INCLUDES],
1461       FRR_INCLUDES
1462       [#include <netinet/tcp.h>
1463     ])
1464     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1465    [],
1466    FRR_INCLUDES)
1467 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1468   AC_CHECK_HEADER([linux/tcp.h],
1469        [m4_define([MD5_INCLUDES],
1470           FRR_INCLUDES
1471           [#include <linux/tcp.h>
1472         ])
1473        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1474 fi
1475
1476 dnl ----------------------------------------------------------------------------
1477 dnl figure out if domainname is available in the utsname struct (GNU extension).
1478 dnl ----------------------------------------------------------------------------
1479 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1480
1481 dnl ------------------
1482 dnl IPv6 header checks
1483 dnl ------------------
1484 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1485         netinet6/in6_var.h netinet6/nd6.h], [], [],
1486         FRR_INCLUDES)
1487
1488 m4_define([FRR_INCLUDES],dnl
1489 FRR_INCLUDES
1490 [#if HAVE_NETINET6_IN6_H
1491 #include <netinet6/in6.h>
1492 #endif
1493 #if HAVE_NETINET_IN6_VAR_H
1494 #include <netinet/in6_var.h>
1495 #endif
1496 #include <netinet/icmp6.h>
1497 #if HAVE_NETINET6_IN6_VAR_H
1498 # include <netinet6/in6_var.h>
1499 #endif
1500 #if HAVE_NETINET6_ND6_H
1501 # include <netinet6/nd6.h>
1502 #endif
1503 ])dnl
1504
1505 dnl disable doc check
1506 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1507 if test "$SPHINXBUILD" = "/bin/false"; then
1508   if test "${enable_doc}" = "yes"; then
1509     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1510   fi
1511 fi
1512 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false"])
1513 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
1514
1515 dnl --------------------
1516 dnl Daemon disable check
1517 dnl --------------------
1518 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
1519
1520 if test "${enable_bgpd}" = "no";then
1521   BGPD=""
1522 else
1523   BGPD="bgpd"
1524 fi
1525 AM_CONDITIONAL([BGPD], [test "x$BGPD" = "xbgpd"])
1526
1527 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
1528 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
1529 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
1530
1531 AS_IF([test "${enable_ldpd}" != "no"], [
1532   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1533 ])
1534
1535 if test "$enable_bfdd" = "no"; then
1536   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1537   BFDD=""
1538 else
1539   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1540   BFDD="bfdd"
1541
1542   case $host_os in
1543     linux*)
1544       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1545       ;;
1546
1547     *)
1548       AC_DEFINE([BFD_BSD], [1], [bfdd])
1549       ;;
1550   esac
1551 fi
1552
1553 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
1554
1555 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1556   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1557 fi
1558
1559 NHRPD=""
1560 case "$host_os" in
1561   linux*)
1562     if test "${enable_nhrpd}" != "no"; then
1563       NHRPD="nhrpd"
1564     fi
1565     ;;
1566   *)
1567     if test "${enable_nhrpd}" = "yes"; then
1568       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1569     fi
1570     ;;
1571 esac
1572 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
1573
1574 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
1575
1576 if test "${enable_watchfrr}" = "no";then
1577   WATCHFRR=""
1578 else
1579   WATCHFRR="watchfrr"
1580 fi
1581 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
1582
1583 OSPFCLIENT=""
1584 if test "${enable_ospfapi}" != "no";then
1585     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1586
1587   if test "${enable_ospfclient}" != "no";then
1588       OSPFCLIENT="ospfclient"
1589   fi
1590 fi
1591
1592 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
1593 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
1594 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
1595 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
1596 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
1597 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
1598 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
1599 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
1600 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
1601 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
1602
1603 if test "${enable_bgp_announce}" = "no";then
1604   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1605 else
1606   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1607 fi
1608
1609 if test "${enable_bgp_vnc}" != "no";then
1610   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1611 fi
1612 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1613
1614 AC_SUBST([SOLARIS])
1615 AC_CHECK_LIB([crypt], [crypt], [],
1616                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1617 AC_CHECK_LIB([resolv], [res_init])
1618
1619 dnl ---------------------------
1620 dnl check system has PCRE regexp
1621 dnl ---------------------------
1622 if test "x$enable_pcreposix" = "xyes"; then
1623   AC_CHECK_LIB([pcreposix], [regexec], [], [
1624     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1625   ])
1626 fi
1627 AC_SUBST([HAVE_LIBPCREPOSIX])
1628
1629 dnl ------------------
1630 dnl check C-Ares library
1631 dnl ------------------
1632 if test "${NHRPD}" != ""; then
1633   PKG_CHECK_MODULES([CARES], [libcares], ,[
1634     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1635   ])
1636 fi
1637
1638
1639 dnl ------------------
1640 dnl check Net-SNMP library
1641 dnl ------------------
1642 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1643    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1644    if test x"$NETSNMP_CONFIG" = x"no"; then
1645       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1646    fi
1647    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1648    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1649    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1650    # among other things we avoid a GPL vs. OpenSSL license conflict here
1651    for removelib in crypto ssl sensors pci wrap; do
1652      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1653    done
1654    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1655    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1656 int main(void);
1657 ],
1658 [
1659 {
1660   return 0;
1661 }
1662 ])], [
1663      AC_MSG_ERROR([--enable-snmp given but not usable])])
1664    case "${enable_snmp}" in
1665      yes)
1666       SNMP_METHOD=agentx
1667       ;;
1668      agentx)
1669       SNMP_METHOD="${enable_snmp}"
1670       ;;
1671      *)
1672       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1673       ;;
1674    esac
1675    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1676    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1677 fi
1678 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1679 AC_SUBST([SNMP_LIBS])
1680 AC_SUBST([SNMP_CFLAGS])
1681
1682 dnl ---------------
1683 dnl libyang
1684 dnl ---------------
1685 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.7], , [
1686   AC_MSG_ERROR([libyang (>= 0.16.7) was not found on your system.])
1687 ])
1688 ac_cflags_save="$CFLAGS"
1689 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1690 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1691   AC_MSG_ERROR([m4_normalize([
1692     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1693     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1694   ])
1695 ], [[#include <libyang/libyang.h>]])
1696 CFLAGS="$ac_cflags_save"
1697
1698 dnl ---------------
1699 dnl configuration rollbacks
1700 dnl ---------------
1701 SQLITE3=false
1702 if test "$enable_config_rollbacks" = "yes"; then
1703   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1704     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1705     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1706     SQLITE3=true
1707   ], [
1708     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1709   ])
1710 fi
1711 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
1712
1713 dnl ---------------
1714 dnl confd
1715 dnl ---------------
1716 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1717    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1718    if test "x$CONFD" = "x/bin/false"; then
1719       AC_MSG_ERROR([confd was not found on your system.])]
1720    fi
1721    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1722    AC_SUBST([CONFD_CFLAGS])
1723    CONFD_LIBS="-lconfd"
1724    AC_SUBST([CONFD_LIBS])
1725    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1726 fi
1727 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
1728
1729 dnl ---------------
1730 dnl sysrepo
1731 dnl ---------------
1732 if test "$enable_sysrepo" = "yes"; then
1733   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1734       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1735       SYSREPO=true],
1736       [SYSREPO=false
1737       AC_MSG_ERROR([sysrepo was not found on your system.])]
1738   )
1739 fi
1740 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
1741
1742 dnl ---------------
1743 dnl gRPC
1744 dnl ---------------
1745 if test "$enable_grpc" = "yes"; then
1746   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1747     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1748     if test "$PROTOC" = "/bin/false"; then
1749       AC_MSG_FAILURE([grpc requested but protoc not found.])
1750     fi
1751
1752     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1753     GRPC=true
1754   ], [
1755     GRPC=false
1756     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1757   ])
1758 fi
1759 AM_CONDITIONAL([GRPC], [test "x$enable_grpc" = "xyes"])
1760
1761 dnl ---------------
1762 dnl math
1763 dnl ---------------
1764 AC_SEARCH_LIBS([sqrt], [m])
1765
1766 dnl ---------------
1767 dnl dlopen & dlinfo
1768 dnl ---------------
1769 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1770   AC_MSG_ERROR([unable to find the dlopen()])
1771 ])
1772
1773 AC_CHECK_HEADERS([link.h])
1774
1775 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1776   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1777 #include <stdlib.h>
1778 #ifdef HAVE_LINK_H
1779 #include <link.h>
1780 #endif
1781 #include <dlfcn.h>
1782 ]], [[
1783   char origin[1];
1784   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1785 ]])], [
1786     frr_cv_rtld_di_origin=yes
1787   ], [
1788     frr_cv_rtld_di_origin=no
1789   ])
1790 ])
1791 if test "$frr_cv_rtld_di_origin" = yes; then
1792   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1793 fi
1794
1795 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1796   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1797 #include <stdlib.h>
1798 #ifdef HAVE_LINK_H
1799 #include <link.h>
1800 #endif
1801 #include <dlfcn.h>
1802 ]], [[
1803   struct link_map *lm = NULL;
1804   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1805 ]])], [
1806     frr_cv_rtld_di_linkmap=yes
1807   ], [
1808     frr_cv_rtld_di_linkmap=no
1809   ])
1810 ])
1811 if test "$frr_cv_rtld_di_linkmap" = yes; then
1812   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1813 fi
1814
1815 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
1816
1817 dnl ---------------------------
1818 dnl sockaddr and netinet checks
1819 dnl ---------------------------
1820 AC_CHECK_TYPES([
1821         struct sockaddr_dl,
1822         struct vifctl, struct mfcctl, struct sioc_sg_req,
1823         vifi_t, struct sioc_vif_req, struct igmpmsg,
1824         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1825         struct nd_opt_adv_interval, struct rt_addrinfo,
1826         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1827         struct nd_opt_rdnss, struct nd_opt_dnssl],
1828         [], [], FRR_INCLUDES)
1829
1830 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1831         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1832         struct sockaddr_dl.sdl_len,
1833         struct if6_aliasreq.ifra_lifetime,
1834         struct nd_opt_adv_interval.nd_opt_ai_type],
1835         [], [], FRR_INCLUDES)
1836
1837 dnl ---------------------------
1838 dnl IRDP/pktinfo/icmphdr checks
1839 dnl ---------------------------
1840
1841 AC_CHECK_TYPES([struct in_pktinfo], [
1842   AC_CHECK_TYPES([struct icmphdr], [
1843     IRDP=true
1844   ], [
1845     IRDP=false
1846   ], [FRR_INCLUDES])
1847 ], [
1848   IRDP=false
1849 ], [FRR_INCLUDES])
1850
1851 case "${enable_irdp}" in
1852 yes)
1853   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1854   ;;
1855 no)
1856   IRDP=false
1857   ;;
1858 esac
1859
1860 AM_CONDITIONAL([IRDP], [$IRDP])
1861
1862 dnl -----------------------
1863 dnl checking for IP_PKTINFO
1864 dnl -----------------------
1865 AC_MSG_CHECKING([for IP_PKTINFO])
1866 AC_TRY_COMPILE([#include <netdb.h>], [
1867   int opt = IP_PKTINFO;
1868 ], [
1869   AC_MSG_RESULT([yes])
1870   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1871 ], [
1872   AC_MSG_RESULT([no])
1873 ])
1874
1875 dnl ---------------------------
1876 dnl checking for IP_RECVDSTADDR
1877 dnl ---------------------------
1878 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1879 AC_TRY_COMPILE([#include <netinet/in.h>], [
1880   int opt = IP_RECVDSTADDR;
1881 ], [
1882   AC_MSG_RESULT([yes])
1883   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1884 ], [
1885   AC_MSG_RESULT([no])
1886 ])
1887
1888 dnl ----------------------
1889 dnl checking for IP_RECVIF
1890 dnl ----------------------
1891 AC_MSG_CHECKING([for IP_RECVIF])
1892 AC_TRY_COMPILE([#include <netinet/in.h>], [
1893   int opt = IP_RECVIF;
1894 ], [
1895   AC_MSG_RESULT([yes])
1896   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1897 ], [
1898   AC_MSG_RESULT([no])
1899 ])
1900
1901 dnl ----------------------
1902 dnl checking for SO_BINDANY
1903 dnl ----------------------
1904 AC_MSG_CHECKING([for SO_BINDANY])
1905 AC_TRY_COMPILE([#include <sys/socket.h>], [
1906   int opt = SO_BINDANY;
1907 ], [
1908   AC_MSG_RESULT([yes])
1909   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1910 ], [
1911   AC_MSG_RESULT([no])
1912 ])
1913
1914 dnl ----------------------
1915 dnl checking for IP_FREEBIND
1916 dnl ----------------------
1917 AC_MSG_CHECKING([for IP_FREEBIND])
1918 AC_TRY_COMPILE([#include <netinet/in.h>], [
1919   int opt = IP_FREEBIND;
1920 ], [
1921   AC_MSG_RESULT([yes])
1922   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1923 ], [
1924   AC_MSG_RESULT([no])
1925 ])
1926
1927 dnl --------------------------------------
1928 dnl checking for be32dec existence or not
1929 dnl --------------------------------------
1930 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1931                [#include <sys/endian.h>])
1932
1933 dnl --------------------------------------
1934 dnl checking for clock_time monotonic struct and call
1935 dnl --------------------------------------
1936 AC_CHECK_DECL([CLOCK_MONOTONIC],
1937         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1938          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1939 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1940
1941 dnl --------------------------------------
1942 dnl checking for flex and bison
1943 dnl --------------------------------------
1944
1945 AM_PROG_LEX
1946 AC_MSG_CHECKING([version of flex])
1947 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1948 frr_ac_flex_version="${frr_ac_flex_version##* }"
1949 AC_MSG_RESULT([$frr_ac_flex_version])
1950 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1951   LEX="$SHELL $missing_dir/missing flex"
1952   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1953     AC_MSG_WARN([using pregenerated flex output files])
1954   else
1955     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1956   fi
1957   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1958   AC_SUBST([LEXLIB], [''])
1959 ])
1960
1961 AC_PROG_YACC
1962 dnl thanks GNU bison for this b*llshit...
1963 AC_MSG_CHECKING([version of bison])
1964 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1965 frr_ac_bison_version="${frr_ac_bison_version##* }"
1966 frr_ac_bison_missing="false"
1967 case "x${frr_ac_bison_version}" in
1968   x2.7*)
1969     BISON_OPENBRACE='"'
1970     BISON_CLOSEBRACE='"'
1971     BISON_VERBOSE=''
1972     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1973     ;;
1974   x2.*|x1.*)
1975     AC_MSG_RESULT([$frr_ac_bison_version])
1976     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1977     frr_ac_bison_missing="true"
1978     ;;
1979   x)
1980     AC_MSG_RESULT([none])
1981     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1982     frr_ac_bison_missing="true"
1983     ;;
1984   *)
1985     BISON_OPENBRACE='{'
1986     BISON_CLOSEBRACE='}'
1987     BISON_VERBOSE='-Dparse.error=verbose'
1988     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1989     ;;
1990 esac
1991 AC_SUBST([BISON_OPENBRACE])
1992 AC_SUBST([BISON_CLOSEBRACE])
1993 AC_SUBST([BISON_VERBOSE])
1994
1995 if $frr_ac_bison_missing; then
1996   YACC="$SHELL $missing_dir/missing bison -y"
1997   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1998     AC_MSG_WARN([using pregenerated bison output files])
1999   else
2000     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2001   fi
2002 fi
2003
2004 dnl -------------------
2005 dnl capabilities checks
2006 dnl -------------------
2007 if test "${enable_capabilities}" != "no"; then
2008   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2009   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2010     [AC_MSG_RESULT([yes])
2011      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2012      frr_ac_keepcaps="yes"],
2013      AC_MSG_RESULT([no])
2014   )
2015   if test x"${frr_ac_keepcaps}" = x"yes"; then
2016     AC_CHECK_HEADERS([sys/capability.h])
2017   fi
2018   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
2019     AC_CHECK_LIB([cap], [cap_init],
2020       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2021        LIBCAP="-lcap"
2022        frr_ac_lcaps="yes"]
2023     )
2024   else
2025     AC_CHECK_HEADERS([priv.h],
2026      [AC_MSG_CHECKING([Solaris style privileges are available])
2027       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
2028           [AC_MSG_RESULT([yes])
2029            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
2030            frr_ac_scaps="yes"],
2031            AC_MSG_RESULT(no)
2032       )
2033      ]
2034    )
2035   fi
2036   if test x"${frr_ac_scaps}" = x"yes" \
2037        -o x"${frr_ac_lcaps}" = x"yes"; then
2038     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2039   fi
2040 fi
2041 AC_SUBST([LIBCAP])
2042
2043 dnl ---------------------------
2044 dnl check for glibc 'backtrace'
2045 dnl ---------------------------
2046 if test x"${enable_backtrace}" != x"no" ; then
2047   backtrace_ok=no
2048   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2049     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2050     backtrace_ok=yes
2051   ], [
2052     case "$host_os" in
2053     sunos* | solaris2*)
2054       AC_CHECK_FUNCS([printstack], [
2055         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
2056         backtrace_ok=yes
2057       ])
2058       ;;
2059     esac
2060     if test "$backtrace_ok" = no; then
2061       AC_CHECK_HEADER([execinfo.h], [
2062         AC_SEARCH_LIBS([backtrace], [execinfo], [
2063           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2064           backtrace_ok=yes
2065         ],, [-lm])
2066       ])
2067     fi
2068   ])
2069
2070   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
2071     dnl user explicitly requested backtrace but we failed to find support
2072     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2073   fi
2074 fi
2075
2076 dnl -----------------------------------------
2077 dnl check for malloc mallinfo struct and call
2078 dnl this must try and link using LIBS, in
2079 dnl order to check no alternative allocator
2080 dnl has been specified, which might not provide
2081 dnl mallinfo, e.g. such as Umem on Solaris.
2082 dnl -----------------------------------------
2083 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2084
2085 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2086   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2087 #ifdef HAVE_MALLOC_H
2088 #include <malloc.h>
2089 #endif
2090 #ifdef HAVE_MALLOC_NP_H
2091 #include <malloc_np.h>
2092 #endif
2093 #ifdef HAVE_MALLOC_MALLOC_H
2094 #include <malloc/malloc.h>
2095 #endif
2096 ]], [[
2097 struct mallinfo ac_x; ac_x = mallinfo ();
2098 ]])], [
2099     frr_cv_mallinfo=yes
2100   ], [
2101     frr_cv_mallinfo=no
2102   ])
2103 ])
2104 if test "$frr_cv_mallinfo" = yes; then
2105   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2106 fi
2107
2108 AC_MSG_CHECKING([whether malloc_usable_size is available])
2109 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2110 #ifdef HAVE_MALLOC_H
2111 #include <malloc.h>
2112 #endif
2113 #ifdef HAVE_MALLOC_MALLOC_H
2114 #include <malloc/malloc.h>
2115 #endif
2116 ]], [[
2117 size_t ac_x; ac_x = malloc_usable_size(NULL);
2118 ]])], [
2119   AC_MSG_RESULT([yes])
2120   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2121 ], [
2122   AC_MSG_RESULT([no])
2123
2124   AC_MSG_CHECKING([whether malloc_size is available])
2125   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2126 #ifdef HAVE_MALLOC_H
2127 #include <malloc.h>
2128 #endif
2129 #ifdef HAVE_MALLOC_MALLOC_H
2130 #include <malloc/malloc.h>
2131 #endif
2132 ]], [[
2133 size_t ac_x; ac_x = malloc_size(NULL);
2134 ]])], [
2135     AC_MSG_RESULT([yes])
2136     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2137   ], [
2138     AC_MSG_RESULT([no])
2139   ])
2140 ])
2141
2142 dnl ------
2143 dnl ZeroMQ
2144 dnl ------
2145 if test "x$enable_zeromq" != "xno"; then
2146   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2147     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2148     ZEROMQ=true
2149   ], [
2150     if test "x$enable_zeromq" = "xyes"; then
2151       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2152     fi
2153   ])
2154 fi
2155 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2156
2157 dnl ----------
2158 dnl configure date
2159 dnl ----------
2160 dev_version=`echo $VERSION | grep dev`
2161 #don't expire deprecated code in non 'dev' branch
2162 if test "${dev_version}" = ""; then
2163    CONFDATE=0
2164 else
2165    CONFDATE=`date '+%Y%m%d'`
2166 fi
2167 AC_SUBST([CONFDATE])
2168
2169 dnl ------------------------------
2170 dnl set paths for state directory
2171 dnl ------------------------------
2172 AC_MSG_CHECKING([directory to use for state file])
2173 if test "${prefix}" = "NONE"; then
2174   frr_statedir_prefix="";
2175 else
2176   frr_statedir_prefix=${prefix}
2177 fi
2178 if test "${localstatedir}" = '${prefix}/var'; then
2179   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2180                         ${frr_statedir_prefix}/var/adm dnl
2181                         ${frr_statedir_prefix}/etc dnl
2182                         /var/run        dnl
2183                         /var/adm        dnl
2184                         /etc            dnl
2185                         /dev/null;
2186   do
2187     test -d $FRR_STATE_DIR && break
2188   done
2189   frr_statedir=$FRR_STATE_DIR
2190 else
2191   frr_statedir=${localstatedir}
2192 fi
2193 if test $frr_statedir = "/dev/null"; then
2194     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2195 fi
2196 AC_MSG_RESULT([${frr_statedir}])
2197 AC_SUBST([frr_statedir])
2198
2199 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir/ldpd.sock"], [ldpd control socket])
2200 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir/zserv.api"], [zebra api socket])
2201 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir/bfdd.sock"], [bfdd control socket])
2202 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir"], [daemon vty directory])
2203 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2204
2205 dnl autoconf does this, but it does it too late...
2206 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2207 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2208
2209 dnl get the full path, recursing through variables...
2210 vtysh_bin="$bindir/vtysh"
2211 for I in 1 2 3 4 5 6 7 8 9 10; do
2212         eval vtysh_bin="\"$vtysh_bin\""
2213 done
2214 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2215 AC_SUBST([vtysh_bin])
2216
2217 CFG_SYSCONF="$sysconfdir"
2218 CFG_SBIN="$sbindir"
2219 CFG_STATE="$frr_statedir"
2220 CFG_MODULE="$moduledir"
2221 CFG_YANGMODELS="$yangmodelsdir"
2222 CFG_LIBYANG_PLUGINS="$libyang_pluginsdir"
2223 for I in 1 2 3 4 5 6 7 8 9 10; do
2224         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2225         eval CFG_SBIN="\"$CFG_SBIN\""
2226         eval CFG_STATE="\"$CFG_STATE\""
2227         eval CFG_MODULE="\"$CFG_MODULE\""
2228         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2229         eval CFG_LIBYANG_PLUGINS="\"$CFG_LIBYANG_PLUGINS\""
2230 done
2231 AC_SUBST([CFG_SYSCONF])
2232 AC_SUBST([CFG_SBIN])
2233 AC_SUBST([CFG_STATE])
2234 AC_SUBST([CFG_MODULE])
2235 AC_SUBST([CFG_YANGMODELS])
2236 AC_SUBST([CFG_LIBYANG_PLUGINS])
2237 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2238 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2239 AC_DEFINE_UNQUOTED([LIBYANG_PLUGINS_PATH], ["$CFG_LIBYANG_PLUGINS"], [path to libyang plugins])
2240 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2241
2242 dnl ------------------------------------
2243 dnl Enable RPKI and add librtr to libs
2244 dnl ------------------------------------
2245 if test "${enable_rpki}" = "yes"; then
2246   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
2247       [RPKI=true],
2248       [RPKI=false
2249       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2250   )
2251 fi
2252 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2253
2254 dnl ------------------------------------------
2255 dnl Check whether rtrlib was build with ssh support
2256 dnl ------------------------------------------
2257 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2258 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2259                         [[struct tr_ssh_config config;]])],
2260         [AC_MSG_RESULT([yes])
2261         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2262         AC_MSG_RESULT([no])
2263 )
2264
2265 dnl ---------------------------
2266 dnl Check htonl works correctly
2267 dnl ---------------------------
2268 AC_MSG_CHECKING([for working htonl])
2269 AC_CACHE_VAL(ac_cv_htonl_works,
2270  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2271                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2272  ]
2273 )
2274 AC_MSG_RESULT([$ac_cv_htonl_works])
2275
2276 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2277
2278 AC_CONFIG_FILES([
2279           config.version
2280           changelog-auto
2281           redhat/frr.spec
2282           solaris/Makefile
2283           alpine/APKBUILD
2284           snapcraft/snapcraft.yaml
2285           lib/version.h
2286           tests/lib/cli/test_cli.refout
2287           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2288           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2289           pkgsrc/eigrpd.sh])
2290
2291 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2292 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2293 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2294 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2295 AC_CONFIG_FILES([tools/frrcommon.sh])
2296
2297 AC_CONFIG_COMMANDS([lib/route_types.h], [
2298         dst="${ac_abs_top_builddir}/lib/route_types.h"
2299         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2300                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2301                 > "${dst}.tmp"
2302         test -f "${dst}" \
2303                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2304                 && rm "${dst}.tmp" \
2305                 || mv "${dst}.tmp" "${dst}"
2306 ], [
2307         PERL="$PERL"
2308 ])
2309
2310 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2311     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2312         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2313         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2314                 "${ac_abs_top_srcdir}" \
2315                 > "${dst}.tmp"
2316         test -f "${dst}" \
2317                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2318                 && rm "${dst}.tmp" \
2319                 || mv "${dst}.tmp" "${dst}"
2320     ], [
2321         PERL="$PERL"
2322     ])
2323 ])
2324
2325 ## Hack, but working solution to avoid rebuilding of frr.info.
2326 ## It's already in CVS until texinfo 4.7 is more common.
2327 AC_OUTPUT
2328
2329 echo "
2330 FRRouting configuration
2331 ------------------------------
2332 FRR version             : ${PACKAGE_VERSION}
2333 host operating system   : ${host_os}
2334 source code location    : ${srcdir}
2335 compiler                : ${CC}
2336 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2337 make                    : ${MAKE-make}
2338 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2339 state file directory    : ${frr_statedir}
2340 config file directory   : `eval echo \`echo ${sysconfdir}\``
2341 example directory       : `eval echo \`echo ${exampledir}\``
2342 module directory        : ${CFG_MODULE}
2343 user to run as          : ${enable_user}
2344 group to run as         : ${enable_group}
2345 group for vty sockets   : ${enable_vty_group}
2346 config file mask        : ${enable_configfile_mask}
2347 log file mask           : ${enable_logfile_mask}
2348 zebra protobuf enabled  : ${enable_protobuf:-no}
2349
2350 The above user and group must have read/write access to the state file
2351 directory and to the config files in the config file directory."
2352
2353 if test "${enable_doc}" != "no";then
2354   AS_IF([test "$SPHINXBUILD" = /bin/false],
2355      AC_MSG_WARN([sphinx-build is missing but required to build documentation]))
2356 fi