configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [8.1-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183 AC_PROG_CC_C99
 184 dnl NB: see C11 below
 185
 186 dnl Some special handling for ICC later on
 187 if test "$CC" = "icc"; then
 188     cc_is_icc="yes"
 189 fi
 190
 191 PKG_PROG_PKG_CONFIG
 192
 193 dnl it's 2019, sed is sed.
 194 SED=sed
 195 AC_SUBST([SED])
 196
 197 dnl try and enable CFLAGS that are useful for FRR
 198 dnl - specifically, options to control warnings
 199
 200 AC_SUBST([AC_CFLAGS])
 201 AC_USE_SYSTEM_EXTENSIONS
 202 AC_DEFUN([AC_C_FLAG], [{
 203     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 204     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 205         AC_LANG_PUSH([C])
 206         ac_c_flag_save="$CFLAGS"
 207         CFLAGS="$CFLAGS $1"
 208         AC_COMPILE_IFELSE(
 209                 [AC_LANG_PROGRAM([[$4]])],
 210                 [
 211                         cachename=yes
 212                 ], [
 213                         cachename=no
 214                 ])
 215         CFLAGS="$ac_c_flag_save"
 216         AC_LANG_POP([C])
 217     ])
 218     if test "$cachename" = "yes"; then
 219         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 220     else
 221         :
 222         $2
 223     fi
 224     m4_popdef([cachename])
 225 }])
 226
 227 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 228         AC_LANG_PUSH([C])
 229         ac_cflags_save="$CFLAGS"
 230         ac_libs_save="$LIBS"
 231         CFLAGS="$CFLAGS $1"
 232         LIBS="$LIBS $2"
 233         AC_LINK_IFELSE(
 234                 [$3],
 235                 [
 236                         CFLAGS="$ac_cflags_save"
 237                         LIBS="$ac_libs_save"
 238                         m4_default([$5], [
 239                                 AC_MSG_RESULT([yes])
 240                         ])
 241                 ], [
 242                         CFLAGS="$ac_cflags_save"
 243                         LIBS="$ac_libs_save"
 244                         m4_default([$4], [
 245                                 AC_MSG_RESULT([no])
 246                         ])
 247                 ])
 248         AC_LANG_POP([C])
 249         }])
 250
 251 dnl ICC won't bail on unknown options without -diag-error 10006
 252 dnl need to do this first so we get useful results for the other options
 253 if test "$cc_is_icc" = "yes"; then
 254     AC_C_FLAG([-diag-error 10006])
 255 fi
 256
 257 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 258 ac_cc="$CC"
 259 CC="${CC% -std=gnu99}"
 260 CC="${CC% -std=c99}"
 261
 262 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 263
 264 dnl if the user has specified any CFLAGS, override our settings
 265 if test "$enable_gcov" = "yes"; then
 266    if test "$orig_cflags" = ""; then
 267       AC_C_FLAG([-coverage])
 268       AC_C_FLAG([-O0])
 269    fi
 270
 271    AC_LDFLAGS="${AC_LDFLAGS} -lgcov"
 272 fi
 273
 274 if test "$enable_clang_coverage" = "yes"; then
 275    AC_C_FLAG([-fprofile-instr-generate], [
 276      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 277    ])
 278    AC_C_FLAG([-fcoverage-mapping], [
 279      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 280    ])
 281 fi
 282
 283 AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"])
 284
 285 if test "$enable_scripting" = "yes"; then
 286    AX_PROG_LUA([5.3], [5.4], [], [
 287      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 288    ])
 289    AX_LUA_HEADERS([], [
 290      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 291    ])
 292    AX_LUA_LIBS([
 293      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 294      LIBS="$LIBS $LUA_LIB"
 295      SCRIPTING=true
 296    ], [
 297      SCRIPTING=false
 298      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 299    ])
 300 fi
 301
 302 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 303 dnl sense to be overridden by the user
 304 if test "$enable_dev_build" = "yes"; then
 305    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 306    if test "$orig_cflags" = ""; then
 307       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 308       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 309       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 310    fi
 311 else
 312    if test "$orig_cflags" = ""; then
 313       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 314       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 315    fi
 316 fi
 317
 318 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 319
 320 dnl always want these CFLAGS
 321 AC_C_FLAG([-fno-omit-frame-pointer])
 322 AC_C_FLAG([-funwind-tables])
 323 AC_C_FLAG([-Wall])
 324 AC_C_FLAG([-Wextra])
 325 AC_C_FLAG([-Wmissing-prototypes])
 326 AC_C_FLAG([-Wmissing-declarations])
 327 AC_C_FLAG([-Wpointer-arith])
 328 AC_C_FLAG([-Wbad-function-cast])
 329 AC_C_FLAG([-Wwrite-strings])
 330 AC_C_FLAG([-Wundef])
 331 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 332   AC_C_FLAG([-Wcast-qual])
 333   AC_C_FLAG([-Wstrict-prototypes])
 334   AC_C_FLAG([-Wmissing-noreturn])
 335   AC_C_FLAG([-Wmissing-format-attribute])
 336   AC_C_FLAG([-Wunreachable-code])
 337   AC_C_FLAG([-Wpacked])
 338   AC_C_FLAG([-Wpadded])
 339   AC_C_FLAG([-Wshadow])
 340 else
 341   AC_C_FLAG([-Wno-unused-result])
 342 fi
 343 AC_C_FLAG([-Wno-unused-parameter])
 344 AC_C_FLAG([-Wno-missing-field-initializers])
 345
 346 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 347 AC_SUBST([CXX_COMPAT_CFLAGS])
 348
 349 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 350 dnl for some reason the string consts get 'promoted' to char *,
 351 dnl triggering a const to non-const conversion warning.
 352 if test "$cc_is_icc" = "yes"; then
 353     AC_C_FLAG([-diag-disable 3179])
 354 fi
 355
 356 if test "$enable_werror" = "yes" ; then
 357   WERROR="-Werror"
 358 fi
 359 AC_SUBST([WERROR])
 360
 361 SAN_FLAGS=""
 362 if test "$enable_address_sanitizer" = "yes"; then
 363   AC_C_FLAG([-fsanitize=address], [
 364     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 365   ], [
 366     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 367   ])
 368 fi
 369 if test "$enable_thread_sanitizer" = "yes"; then
 370   AC_C_FLAG([-fsanitize=thread], [
 371     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 372   ], [
 373     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 374   ])
 375 fi
 376 if test "$enable_memory_sanitizer" = "yes"; then
 377   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 378     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 379   ], [
 380     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 381   ])
 382 fi
 383 if test "$enable_undefined_sanitizer" = "yes"; then
 384   AC_C_FLAG([-fsanitize=undefined], [
 385     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 386   ], [
 387     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 388   ])
 389 fi
 390 AC_SUBST([SAN_FLAGS])
 391
 392 dnl frr-format.so
 393 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 394   AC_C_FLAG([-fplugin=${with_frr_format}], [
 395     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 396   ],,[
 397 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 398 #error plugin not loaded
 399 #endif
 400 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 401 #error plugin too old
 402 #endif
 403   ])
 404 elif test "$with_frr_format" = "no"; then
 405   : #nothing
 406 else
 407   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 408     AC_C_FLAG([-fplugin=frr-format],[
 409       if test "$with_frr_format" = "yes"; then
 410         AC_MSG_ERROR([frr-format plugin requested but not found])
 411       fi
 412     ],,[
 413 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 414 #error plugin not loaded
 415 #endif
 416 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 417 #error plugin too old
 418 #endif
 419     ])
 420   ],,[
 421 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 422 #error plugin not loaded
 423 #endif
 424 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 425 #error plugin too old
 426 #endif
 427   ])
 428 fi
 429
 430 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 431 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 432 #include <stdio.h>
 433 int __attribute__((section("secttest"))) var = 1;
 434 extern int __start_secttest, __stop_secttest;
 435 ]], [[
 436   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 437   printf("%p %p %p\n", a, b, c);
 438 ]])], [
 439   AC_MSG_RESULT(yes)
 440   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 441 ], [
 442   AC_MSG_RESULT(no)
 443 ])
 444
 445 dnl ----------
 446 dnl Essentials
 447 dnl ----------
 448
 449 AX_PTHREAD([
 450   CC="$PTHREAD_CC"
 451   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 452   LIBS="$PTHREAD_LIBS $LIBS"
 453 ], [
 454   AC_MSG_FAILURE([This FRR version needs pthreads])
 455 ])
 456
 457 orig_cflags="$CFLAGS"
 458 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 459
 460 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 461                 [frr_cv_pthread_condattr_setclock=yes],
 462                 [frr_cv_pthread_condattr_setclock=no])
 463 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 464   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 465 fi
 466
 467 AC_CHECK_HEADERS([pthread_np.h],,, [
 468 #include <pthread.h>
 469 ])
 470 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 471
 472 CFLAGS="$orig_cflags"
 473
 474 dnl --------------
 475 dnl Check programs
 476 dnl --------------
 477 AC_PROG_INSTALL
 478 AC_PROG_LN_S
 479 AC_CHECK_TOOL([AR], [ar])
 480
 481 dnl -------
 482 dnl libtool
 483 dnl -------
 484 AC_ARG_ENABLE([static-bin],
 485   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 486 LT_INIT
 487 _LT_CONFIG_LIBTOOL([
 488   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 489     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 490   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 491   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 492   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 493 ])
 494 if test "$enable_static_bin" = "yes"; then
 495   AC_LDFLAGS="-static"
 496   if test "$enable_static" != "yes"; then
 497     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 498   fi
 499 fi
 500 if test "$enable_shared" != "yes"; then
 501   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 502 fi
 503 AC_SUBST([AC_LDFLAGS])
 504 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 505
 506 AC_ARG_ENABLE([rpath],
 507   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 508   [],
 509   [enable_rpath=yes])
 510
 511 dnl $AR and $RANLIB are set by LT_INIT above
 512 AC_MSG_CHECKING([whether $AR supports D option])
 513 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 514   AC_MSG_RESULT([yes])
 515   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 516   ARFLAGS="crD"
 517   AR_FLAGS="crD"
 518 else
 519   AC_MSG_RESULT([no])
 520   ARFLAGS="cru"
 521   AR_FLAGS="cru"
 522 fi
 523 AC_SUBST([ARFLAGS])
 524 AC_SUBST([AR_FLAGS])
 525
 526 AC_MSG_CHECKING([whether $RANLIB supports D option])
 527 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 528   if grep -q -- '-D' conftest.err; then
 529     AC_MSG_RESULT([no])
 530   else
 531     AC_MSG_RESULT([yes])
 532     RANLIB="$RANLIB -D"
 533   fi
 534 else
 535   AC_MSG_RESULT([no])
 536 fi
 537 AC_SUBST([RANLIB])
 538
 539 test -f conftest.err && rm conftest.err
 540 test -f conftest.a && rm conftest.a
 541
 542 dnl ----------------------
 543 dnl Packages configuration
 544 dnl ----------------------
 545 if test -f config.version; then
 546   . ./config.version
 547 elif test -f "${srcdir}/config.version"; then
 548   . "${srcdir}/config.version"
 549 fi
 550 AC_ARG_WITH([pkg-extra-version],
 551   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 552   if test "$withval" = "no"; then
 553     EXTRAVERSION=
 554   else
 555     EXTRAVERSION=$withval
 556   fi
 557 ], [])
 558 AC_ARG_WITH([pkg-git-version],
 559         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 560         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 561 AC_ARG_WITH([clippy],
 562   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 563 AC_ARG_WITH([vtysh_pager],
 564         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 565         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 566 AC_ARG_ENABLE([vtysh],
 567   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 568 AC_ARG_ENABLE([doc],
 569   AS_HELP_STRING([--disable-doc], [do not build docs]))
 570 AC_ARG_ENABLE([doc-html],
 571   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 572 AC_ARG_ENABLE([zebra],
 573   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 574 AC_ARG_ENABLE([bgpd],
 575   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 576 AC_ARG_ENABLE([ripd],
 577   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 578 AC_ARG_ENABLE([ripngd],
 579   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 580 AC_ARG_ENABLE([ospfd],
 581   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 582 AC_ARG_ENABLE([ospf6d],
 583   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 584 AC_ARG_ENABLE([ldpd],
 585   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 586 AC_ARG_ENABLE([nhrpd],
 587   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 588 AC_ARG_ENABLE([eigrpd],
 589   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 590 AC_ARG_ENABLE([babeld],
 591   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 592 AC_ARG_ENABLE([watchfrr],
 593   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 594 AC_ARG_ENABLE([isisd],
 595   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 596 AC_ARG_ENABLE([pimd],
 597   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 598 AC_ARG_ENABLE([pbrd],
 599   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 600 AC_ARG_ENABLE([sharpd],
 601   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 602 AC_ARG_ENABLE([staticd],
 603   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 604 AC_ARG_ENABLE([fabricd],
 605   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 606 AC_ARG_ENABLE([vrrpd],
 607   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 608 AC_ARG_ENABLE([pathd],
 609   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 610 AC_ARG_ENABLE([bgp-announce],
 611   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 612 AC_ARG_ENABLE([bgp-vnc],
 613   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 614 AC_ARG_ENABLE([bgp-bmp],
 615   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 616 AC_ARG_ENABLE([snmp],
 617   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 618 AC_ARG_ENABLE([config_rollbacks],
 619   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 620 AC_ARG_ENABLE([confd],
 621   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 622 AC_ARG_ENABLE([sysrepo],
 623   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 624 AC_ARG_ENABLE([grpc],
 625   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 626 AC_ARG_ENABLE([zeromq],
 627   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 628 AC_ARG_ENABLE([lttng],
 629   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 630 AC_ARG_ENABLE([usdt],
 631   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 632 AC_ARG_WITH([libpam],
 633   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 634 AC_ARG_ENABLE([ospfapi],
 635   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 636 AC_ARG_ENABLE([ospfclient],
 637   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 638                           (this is the default if --disable-ospfapi is set)]))
 639 AC_ARG_ENABLE([multipath],
 640   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 641 AC_ARG_ENABLE([user],
 642   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 643 AC_ARG_ENABLE([group],
 644   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 645 AC_ARG_ENABLE([vty_group],
 646   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 647 AC_ARG_ENABLE([configfile_mask],
 648   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 649 AC_ARG_ENABLE([logfile_mask],
 650   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 651 AC_ARG_ENABLE([shell_access],
 652   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 653 AC_ARG_ENABLE([realms],
 654   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 655 AC_ARG_ENABLE([rtadv],
 656   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 657 AC_ARG_ENABLE([irdp],
 658   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 659 AC_ARG_ENABLE([capabilities],
 660   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 661 AC_ARG_ENABLE([gcc_ultra_verbose],
 662   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 663 AC_ARG_ENABLE([backtrace],
 664   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 665 AC_ARG_ENABLE([time-check],
 666   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 667 AC_ARG_ENABLE([cpu-time],
 668   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 669 AC_ARG_ENABLE([pcreposix],
 670   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 671 AC_ARG_ENABLE([fpm],
 672   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 673 AC_ARG_ENABLE([pcep],
 674   AS_HELP_STRING([--enable-pcep], [enable PCEP support for pathd]))
 675 AC_ARG_ENABLE([werror],
 676   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 677 AC_ARG_ENABLE([cumulus],
 678   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 679 AC_ARG_ENABLE([datacenter],
 680   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 681 AC_ARG_ENABLE([rr-semantics],
 682   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 683 AC_ARG_ENABLE([protobuf],
 684   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 685 AC_ARG_ENABLE([oldvpn_commands],
 686   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 687 AC_ARG_ENABLE([rpki],
 688   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 689 AC_ARG_ENABLE([clippy-only],
 690   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 691 AC_ARG_ENABLE([numeric_version],
 692   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 693 AC_ARG_ENABLE([gcov],
 694   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 695 AC_ARG_ENABLE([clang_coverage],
 696   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 697 AC_ARG_ENABLE([bfdd],
 698   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 699 AC_ARG_ENABLE([address-sanitizer],
 700   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 701 AC_ARG_ENABLE([thread-sanitizer],
 702   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 703 AC_ARG_ENABLE([memory-sanitizer],
 704   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 705 AC_ARG_ENABLE([undefined-sanitizer],
 706   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 707 AC_ARG_WITH([crypto],
 708   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 709 AC_ARG_WITH([frr-format],
 710   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 711
 712 AC_ARG_ENABLE([version-build-config],
 713   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 714
 715 #if openssl, else use the internal
 716 AS_IF([test "$with_crypto" = "openssl"], [
 717 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 718 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 719   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 720 else
 721   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 722 fi
 723 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 724 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 725 )
 726
 727 AS_IF([test "$enable_clippy_only" != "yes"], [
 728 AC_CHECK_HEADERS([json-c/json.h])
 729 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 730 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 731   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 732   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 733       AC_MSG_ERROR([libjson is needed to compile])
 734   fi
 735 fi
 736 ])
 737
 738 AC_ARG_ENABLE([dev_build],
 739     AS_HELP_STRING([--enable-dev-build], [build for development]))
 740
 741 AC_ARG_ENABLE([scripting],
 742     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 743
 744 AC_ARG_ENABLE([netlink-debug],
 745   AS_HELP_STRING([--disable-netlink-debug], [pretty print netlink debug messages]))
 746
 747 if test "$enable_netlink_debug" != "no" ; then
 748   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 749 fi
 750
 751 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 752
 753 if test "$enable_time_check" != "no" ; then
 754   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 755     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 756   else
 757     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 758   fi
 759 fi
 760
 761 case "${enable_cpu_time}" in
 762   "no")
 763   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 764   ;;
 765   "*")
 766   ;;
 767 esac
 768
 769 if test "$enable_rr_semantics" != "no" ; then
 770   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 771 fi
 772
 773 if test "$enable_datacenter" = "yes" ; then
 774   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 775   DFLT_NAME="datacenter"
 776 else
 777   DFLT_NAME="traditional"
 778 fi
 779
 780 if test "$enable_cumulus" = "yes" ; then
 781   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 782 fi
 783
 784 AC_SUBST([DFLT_NAME])
 785 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 786
 787 if test "$enable_shell_access" = "yes"; then
 788    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 789 fi
 790
 791 #
 792 # Python for clippy
 793 #
 794
 795 AS_IF([test "$host" = "$build"], [
 796   AC_CHECK_HEADER([gelf.h], [], [
 797     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 798   ])
 799   AC_CHECK_LIB([elf], [elf_memory], [], [
 800     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 801   ])
 802
 803   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 804     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 805   ])
 806   AC_CHECK_LIB([elf], [gelf_getnote], [
 807     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 808   ])
 809
 810   FRR_PYTHON_DEV
 811 ], [
 812   FRR_PYTHON
 813 ])
 814
 815 FRR_PYTHON_MODULES([pytest])
 816
 817 if test "$enable_doc" != "no"; then
 818   FRR_PYTHON_MODULES([sphinx], , [
 819     if test "$enable_doc" = "yes"; then
 820       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 821     fi
 822   ])
 823 fi
 824 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 825 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 826
 827 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 828   PYSPHINX="-m sphinx"
 829 ], [
 830   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 831 ])
 832 AC_SUBST([PYSPHINX])
 833
 834 #
 835 # Logic for old vpn commands support.
 836 #
 837 if test "$enable_oldvpn_commands" = "yes"; then
 838    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 839 fi
 840
 841 #
 842 # End of logic for protobuf support.
 843 #
 844
 845 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 846 if test "$enable_rtadv" != "no"; then
 847   AC_MSG_RESULT([yes])
 848   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 849 else
 850   AC_MSG_RESULT([no])
 851 fi
 852
 853 if test "$enable_user" = "no"; then
 854   enable_user=""
 855 else
 856   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 857     enable_user="frr"
 858   fi
 859   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 860 fi
 861
 862 if test "$enable_group" = "no"; then
 863   enable_group=""
 864 else
 865   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 866     enable_group="frr"
 867   fi
 868   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 869 fi
 870
 871 if test "$enable_vty_group" = "yes" ; then
 872   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 873 elif test "$enable_vty_group" != ""; then
 874   if test "$enable_vty_group" != "no"; then
 875     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 876   fi
 877 fi
 878 AC_SUBST([enable_user])
 879 AC_SUBST([enable_group])
 880 AC_SUBST([enable_vty_group])
 881
 882 enable_configfile_mask=${enable_configfile_mask:-0600}
 883 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 884 AC_SUBST([enable_configfile_mask])
 885
 886 enable_logfile_mask=${enable_logfile_mask:-0600}
 887 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 888
 889 MPATH_NUM=16
 890
 891 case "${enable_multipath}" in
 892   0)
 893     MPATH_NUM=64
 894     ;;
 895   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 896     MPATH_NUM="${enable_multipath}"
 897     ;;
 898   "")
 899     ;;
 900   *)
 901     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 902     ;;
 903 esac
 904
 905 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 906
 907 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 908
 909 dnl --------------------
 910 dnl Enable code coverage
 911 dnl --------------------
 912 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 913
 914 dnl ------------------------------------
 915 dnl Alpine only accepts numeric versions
 916 dnl ------------------------------------
 917 if test "$enable_numeric_version" != "" ; then
 918   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 919   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 920 fi
 921
 922 dnl -----------------------------------
 923 dnl Add extra version string to package
 924 dnl name, string and version fields.
 925 dnl -----------------------------------
 926 if test "$EXTRAVERSION" != "" ; then
 927   VERSION="${VERSION}${EXTRAVERSION}"
 928   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 929   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 930   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 931 fi
 932 AC_SUBST([EXTRAVERSION])
 933
 934 if test "$with_pkg_git_version" = "yes"; then
 935         if test -e "${srcdir}/.git"; then
 936                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 937         else    with_pkg_git_version="no"
 938                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 939         fi
 940 fi
 941 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 942
 943 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 944 if test "$OBJCOPY" != ":"; then
 945   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 946     frr_cv_interp=""
 947     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 948       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 949         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 950       fi
 951       test -f conftest.interp && rm conftest.interp
 952     ])
 953   ])
 954 fi
 955 if test -n "$frr_cv_interp"; then
 956   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 957 fi
 958
 959 dnl -------------------------
 960 dnl Check other header files.
 961 dnl -------------------------
 962 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 963         linux/version.h asm/types.h endian.h sys/endian.h])
 964
 965 ac_stdatomic_ok=false
 966 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 967 AC_CHECK_HEADER([stdatomic.h],[
 968
 969   AC_MSG_CHECKING([whether _Atomic qualifier works])
 970   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 971 #include <stdatomic.h>
 972 int main(int argc, char **argv) {
 973   _Atomic int i = 0;
 974   return i;
 975 }
 976 ]])], [
 977     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 978     AC_MSG_RESULT([yes])
 979     ac_stdatomic_ok=true
 980   ], [
 981     AC_MSG_RESULT([no])
 982   ])
 983 ])
 984
 985 AS_IF([$ac_stdatomic_ok], [true], [
 986   AC_MSG_CHECKING([for __atomic_* builtins])
 987   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 988 int main(int argc, char **argv) {
 989   volatile int i = 1;
 990   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 991   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 992 }
 993 ]])], [
 994     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 995     AC_MSG_RESULT([yes])
 996   ], [
 997     AC_MSG_RESULT([no])
 998
 999     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1000     AC_MSG_CHECKING([for __sync_* builtins])
1001     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1002 int main(int argc, char **argv) {
1003   volatile int i = 1;
1004   __sync_fetch_and_sub (&i, 1);
1005   return __sync_val_compare_and_swap (&i, 0, 1);
1006 }
1007 ]])], [
1008       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1009       AC_MSG_RESULT([yes])
1010
1011       AC_MSG_CHECKING([for __sync_swap builtin])
1012       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1013 int main(int argc, char **argv) {
1014   volatile int i = 1;
1015   return __sync_swap (&i, 2);
1016 }
1017 ]])], [
1018         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1019         AC_MSG_RESULT([yes])
1020       ], [
1021         AC_MSG_RESULT([no])
1022       ])
1023
1024     ], [
1025       AC_MSG_RESULT([no])
1026       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1027     ])
1028   ])
1029 ])
1030
1031 needsync=true
1032
1033 AS_IF([$needsync], [
1034   dnl Linux
1035   AC_MSG_CHECKING([for Linux futex() support])
1036   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1037 #ifndef _GNU_SOURCE
1038 #define _GNU_SOURCE
1039 #endif
1040 #include <unistd.h>
1041 #include <limits.h>
1042 #include <sys/time.h>
1043 #include <sys/syscall.h>
1044 #include <linux/futex.h>
1045
1046 int main(void);
1047 ],
1048 [
1049 {
1050   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1051 }
1052 ])], [
1053     AC_MSG_RESULT([yes])
1054     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1055     needsync=false
1056   ], [
1057     AC_MSG_RESULT([no])
1058   ])
1059 ])
1060
1061 AS_IF([$needsync], [
1062   dnl FreeBSD
1063   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1064   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1065 #include <errno.h>
1066 #include <stdlib.h>
1067 #include <sys/types.h>
1068 #include <sys/umtx.h>
1069 int main(void);
1070 ],
1071 [
1072 {
1073   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1074 }
1075 ])], [
1076     AC_MSG_RESULT([yes])
1077     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1078     needsync=false
1079   ], [
1080     AC_MSG_RESULT([no])
1081   ])
1082 ])
1083
1084 AS_IF([$needsync], [
1085   dnl OpenBSD patch (not upstream at the time of writing this)
1086   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1087   AC_MSG_CHECKING([for OpenBSD futex() support])
1088   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1089 #include <sys/futex.h>
1090 int main(void);
1091 ],
1092 [
1093 {
1094   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1095 }
1096 ])], [
1097     AC_MSG_RESULT([yes])
1098     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1099     needsync=false
1100   ], [
1101     AC_MSG_RESULT([no])
1102   ])
1103 ])
1104
1105 dnl Utility macro to avoid retyping includes all the time
1106 m4_define([FRR_INCLUDES],
1107 [#ifdef SUNOS_5
1108 #define _POSIX_C_SOURCE 200809L
1109 #define __EXTENSIONS__
1110 #endif
1111 #include <stdio.h>
1112 #include <stdlib.h>
1113 #include <stddef.h>
1114 #include <sys/types.h>
1115 /* sys/conf.h depends on param.h on FBSD at least */
1116 #include <sys/param.h>
1117 /* Required for MAXSIG */
1118 #include <signal.h>
1119 #include <sys/socket.h>
1120 #ifdef __APPLE__
1121 # define __APPLE_USE_RFC_3542
1122 #endif
1123 #include <netinet/in.h>
1124 #include <sys/time.h>
1125 #include <time.h>
1126 #include <net/if.h>
1127 ])dnl
1128
1129 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1130 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1131 dnl an additional round for it.
1132
1133 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1134
1135 m4_define([FRR_INCLUDES],
1136 FRR_INCLUDES
1137 [#ifdef HAVE_NET_IF_VAR_H
1138 # include <net/if_var.h>
1139 #endif
1140 ])dnl
1141
1142 AC_CHECK_HEADERS([netinet/in_var.h \
1143         net/if_dl.h net/netopt.h \
1144         inet/nd.h netinet/ip_icmp.h \
1145         sys/sysctl.h sys/sockio.h sys/conf.h],
1146         [], [], [FRR_INCLUDES])
1147
1148 AC_CHECK_HEADERS([ucontext.h], [], [],
1149 [#ifndef __USE_GNU
1150 #define __USE_GNU
1151 #endif /* __USE_GNU */
1152 FRR_INCLUDES
1153 ])
1154
1155 m4_define([UCONTEXT_INCLUDES],
1156 [#include <ucontext.h>])dnl
1157
1158 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1159   [], [], [UCONTEXT_INCLUDES])
1160 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1161   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1162    [], [], [UCONTEXT_INCLUDES])],
1163   [], [UCONTEXT_INCLUDES])
1164 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1165   [], [], [UCONTEXT_INCLUDES])
1166
1167 m4_define([FRR_INCLUDES],
1168 FRR_INCLUDES
1169 [
1170 #include <sys/un.h>
1171 #include <netinet/in_systm.h>
1172 #ifdef HAVE_NETINET_IN_VAR_H
1173 # include <netinet/in_var.h>
1174 #endif
1175 #ifdef HAVE_NET_IF_DL_H
1176 # include <net/if_dl.h>
1177 #endif
1178 #ifdef HAVE_NET_NETOPT_H
1179 # include <net/netopt.h>
1180 #endif
1181 #include <net/route.h>
1182 #ifdef HAVE_INET_ND_H
1183 # include <inet/nd.h>
1184 #endif
1185 #include <arpa/inet.h>
1186 /* Required for IDRP */
1187 #ifdef HAVE_NETINET_IP_ICMP_H
1188 # include <netinet/ip_icmp.h>
1189 #endif
1190 ])dnl
1191
1192 dnl V6 headers are checked below, after we check for v6
1193
1194 is_linux=false
1195
1196 AC_MSG_CHECKING([which operating system interface to use])
1197 case "$host_os" in
1198   sunos* | solaris2*)
1199     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1200     ;;
1201   linux*)
1202     AC_MSG_RESULT([Linux])
1203
1204     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1205     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1206     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1207
1208     dnl Linux has a compilation problem with mixing
1209     dnl netinet/in.h and linux/in6.h they are not
1210     dnl compatible.  There has been discussion on
1211     dnl how to fix it but no real progress on implementation
1212     dnl when they fix it, remove this
1213     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1214
1215     is_linux=true
1216     ;;
1217   openbsd*)
1218     AC_MSG_RESULT([OpenBSD])
1219
1220     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1221     AC_DEFINE([KAME], [1], [KAME IPv6])
1222     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1223     ;;
1224   *)
1225     AC_MSG_RESULT([BSD])
1226
1227     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1228     AC_DEFINE([KAME], [1], [KAME IPv6])
1229     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1230     ;;
1231 esac
1232 AM_CONDITIONAL([LINUX], [${is_linux}])
1233
1234 AC_SYS_LARGEFILE
1235
1236 dnl ------------------------
1237 dnl Integrated REALMS option
1238 dnl ------------------------
1239 if test "$enable_realms" = "yes"; then
1240     case "$host_os" in
1241       linux*)
1242        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1243        ;;
1244       *)
1245        echo "Sorry, only Linux has REALMS support"
1246        exit 1
1247        ;;
1248     esac
1249 fi
1250
1251 dnl ---------------
1252 dnl other functions
1253 dnl ---------------
1254 AC_CHECK_FUNCS([ \
1255         strlcat strlcpy \
1256         getgrouplist \
1257         openat \
1258         unlinkat \
1259         posix_fallocate \
1260         ])
1261
1262 dnl ##########################################################################
1263 dnl LARGE if block spans a lot of "configure"!
1264 if test "$enable_clippy_only" != "yes"; then
1265 dnl ##########################################################################
1266
1267 #
1268 # Logic for protobuf support.
1269 #
1270 PROTO3=false
1271 if test "$enable_protobuf" = "yes"; then
1272   # Check for protoc & protoc-c
1273
1274   # protoc is not required, it's only for a "be nice" helper target
1275   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1276
1277   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1278   if test "$PROTOC_C" = "/bin/false"; then
1279     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1280   fi
1281
1282   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1283     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1284   ])
1285
1286   PROTO3=true
1287   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1288                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1289                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1290                                             [1], [Have Protobuf version 3]),
1291                                   [PROTO3=false],
1292                                   [#include <google/protobuf-c/protobuf-c.h>])],
1293                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1294
1295   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1296 fi
1297
1298
1299 dnl ---------------------
1300 dnl Integrated VTY option
1301 dnl ---------------------
1302 case "${enable_vtysh}" in
1303 "no")
1304   VTYSH="";;
1305 *)
1306   VTYSH="vtysh";
1307   AC_DEFINE([VTYSH], [1], [VTY shell])
1308
1309   prev_libs="$LIBS"
1310   AC_CHECK_LIB([readline], [main], [
1311     LIBREADLINE="-lreadline"
1312   ], [
1313     dnl readline failed - it might be incorrectly linked and missing its
1314     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1315     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1316       LIBREADLINE="$ac_cv_search_tputs"
1317     ], [
1318       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1319     ])
1320
1321     dnl re-try with the lib we found above
1322     unset ac_cv_lib_readline_main
1323     AC_CHECK_LIB([readline], [main], [
1324       LIBREADLINE="-lreadline $LIBREADLINE"
1325     ], [
1326       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1327     ], [$LIBREADLINE])
1328   ], [])
1329   LIBS="$prev_libs"
1330
1331   AC_CHECK_HEADER([readline/history.h])
1332   if test "$ac_cv_header_readline_history_h" = "no"; then
1333     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1334   fi
1335   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1336   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1337     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1338   fi
1339   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1340   if test "$frr_cv_append_history" = "yes"; then
1341     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1342   fi
1343   ;;
1344 esac
1345 AC_SUBST([LIBREADLINE])
1346
1347 dnl ----------
1348 dnl PAM module
1349 dnl
1350 dnl FRR detects the PAM library it is built against by checking for a
1351 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1352 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1353 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1354 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1355 dnl of OpenPAM.
1356 dnl ----------
1357 if test "$with_libpam" = "yes"; then
1358   AC_CHECK_HEADER([security/pam_misc.h],
1359     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1360      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1361      pam_conv_func="misc_conv"
1362     ],
1363     [], FRR_INCLUDES)
1364   AC_CHECK_HEADER([security/openpam.h],
1365     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1366      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1367      pam_conv_func="openpam_ttyconv"
1368     ],
1369     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1370   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1371     AC_MSG_WARN([*** pam support will not be built ***])
1372     with_libpam="no"
1373   fi
1374 fi
1375
1376 if test "$with_libpam" = "yes"; then
1377 dnl took this test from proftpds configure.in and suited to our needs
1378 dnl -------------------------------------------------------------------------
1379 dnl
1380 dnl This next check looks funky due to a linker problem with some versions
1381 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1382 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1383 dnl with RedHat 6.2 and Debian 2.2 or better.
1384 AC_CHECK_LIB([pam], [pam_start],
1385   [AC_CHECK_LIB([pam], [$pam_conv_func],
1386     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1387      LIBPAM="-lpam"],
1388     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1389      LIBPAM="-lpam -lpam_misc"]
1390     )
1391   ],
1392
1393   [AC_CHECK_LIB([pam], [pam_end],
1394     [AC_CHECK_LIB([pam], [$pam_conv_func],
1395       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1396        LIBPAM="-lpam -ldl"],
1397       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1398        LIBPAM="-lpam -ldl -lpam_misc"]
1399      )
1400   ],AC_MSG_WARN([*** pam support will not be built ***]),
1401   [-ldl])
1402   ]
1403 )
1404 fi
1405 AC_SUBST([LIBPAM])
1406
1407 dnl -------------------------------
1408 dnl bgpd needs pow() and hence libm
1409 dnl -------------------------------
1410 TMPLIBS="$LIBS"
1411 LIBS=""
1412 AC_SEARCH_LIBS([pow], [m], [
1413   LIBM="$LIBS"
1414 ], [
1415   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1416 ])
1417 LIBS="$TMPLIBS"
1418 AC_SUBST([LIBM])
1419
1420 AC_CHECK_FUNCS([ppoll], [
1421   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1422 ])
1423 AC_CHECK_FUNCS([pollts], [
1424   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1425 ])
1426
1427 AC_CHECK_HEADER([asm-generic/unistd.h],
1428                 [AC_CHECK_DECL(__NR_setns,
1429                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1430                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1431                                ])
1432                  AC_CHECK_FUNCS([setns])]
1433                )
1434
1435 dnl --------------------------
1436 dnl Determine IS-IS I/O method
1437 dnl --------------------------
1438 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1439 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1440 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1441 AC_CHECK_HEADER([net/bpf.h])
1442 AC_CHECK_HEADER([sys/dlpi.h])
1443 AC_MSG_CHECKING([zebra IS-IS I/O method])
1444
1445 case "$host_os" in
1446   linux*)
1447     AC_MSG_RESULT([pfpacket])
1448     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1449     ;;
1450   *)
1451     if test "$ac_cv_header_net_bpf_h" = "no"; then
1452       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1453         AC_MSG_RESULT([none])
1454         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1455           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1456         fi
1457         AC_MSG_WARN([*** IS-IS support will not be built ***])
1458         enable_isisd="no"
1459         enable_fabricd="no"
1460       else
1461         AC_MSG_RESULT([DLPI])
1462       fi
1463       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1464     else
1465       AC_MSG_RESULT([BPF])
1466       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1467     fi
1468     ;;
1469 esac
1470 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1471
1472 dnl ---------------------------------------------------------------
1473 dnl figure out how to specify an interface in multicast sockets API
1474 dnl ---------------------------------------------------------------
1475 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1476
1477 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1478         #include <sys/socket.h>
1479         #include <netinet/in.h>
1480         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1481         #include <linux/types.h>
1482 ])
1483
1484 m4_define([FRR_INCLUDES],
1485 FRR_INCLUDES
1486 [#ifdef HAVE_LINUX_MROUTE_H
1487 # include <linux/mroute.h>
1488 #endif
1489 ])dnl
1490
1491 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1492         #include <sys/socket.h>
1493         #include <sys/types.h>
1494         #include <netinet/in.h>
1495         #include <net/route.h>
1496 ])
1497
1498 m4_define([FRR_INCLUDES],
1499 FRR_INCLUDES
1500 [#ifdef HAVE_NETINET_IP_MROUTE_H
1501 # include <netinet/ip_mroute.h>
1502 #endif
1503 ])dnl
1504
1505 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1506 AC_COMPILE_IFELSE(
1507 [ AC_LANG_PROGRAM([[
1508       #include <sys/types.h>
1509       #include <netinet/in.h>
1510   ]], [[
1511       struct group_req gr;
1512       int sock;
1513       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1514   ]])
1515 ],[
1516   AC_MSG_RESULT([yes])
1517   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1518 ],[
1519   AC_MSG_RESULT(no)
1520 ])
1521
1522 dnl ---------------------------------------------------------------
1523 dnl figure out how to check link-state
1524 dnl ---------------------------------------------------------------
1525 AC_CHECK_HEADER([net/if_media.h],
1526   [m4_define([LINK_DETECT_INCLUDES],
1527     FRR_INCLUDES
1528     [#include <net/if_media.h>
1529   ])
1530   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1531     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1532     [], LINK_DETECT_INCLUDES)],
1533   [],
1534   FRR_INCLUDES)
1535
1536 dnl ---------------------------------------------------------------
1537 dnl Additional, newer way to check link-state using ifi_link_state.
1538 dnl Not available in all BSD's when ifmediareq available
1539 dnl ---------------------------------------------------------------
1540 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1541   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1542   [], FRR_INCLUDES)
1543
1544 dnl ------------------------
1545 dnl TCP_MD5SIG socket option
1546 dnl ------------------------
1547
1548 AC_CHECK_HEADER([netinet/tcp.h],
1549    [m4_define([MD5_INCLUDES],
1550       FRR_INCLUDES
1551       [#include <netinet/tcp.h>
1552     ])
1553     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1554    [],
1555    FRR_INCLUDES)
1556 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1557   AC_CHECK_HEADER([linux/tcp.h],
1558        [m4_define([MD5_INCLUDES],
1559           FRR_INCLUDES
1560           [#include <linux/tcp.h>
1561         ])
1562        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1563 fi
1564
1565 AC_CHECK_LIB([crypt], [crypt], [],
1566                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1567 AC_CHECK_LIB([resolv], [res_init])
1568
1569 dnl ---------------------------
1570 dnl check system has PCRE regexp
1571 dnl ---------------------------
1572 if test "$enable_pcreposix" = "yes"; then
1573   AC_CHECK_LIB([pcreposix], [regexec], [], [
1574     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1575   ])
1576 fi
1577 AC_SUBST([HAVE_LIBPCREPOSIX])
1578
1579 dnl ##########################################################################
1580 dnl test "$enable_clippy_only" != "yes"
1581 fi
1582 dnl END OF LARGE if block
1583 dnl ##########################################################################
1584
1585 dnl ------------------
1586 dnl check C-Ares library
1587 dnl ------------------
1588 PKG_CHECK_MODULES([CARES], [libcares], [
1589   c_ares_found=true
1590 ],[
1591   c_ares_found=false
1592 ])
1593 AM_CONDITIONAL([CARES], [$c_ares_found])
1594
1595
1596 dnl ----------------------------------------------------------------------------
1597 dnl figure out if domainname is available in the utsname struct (GNU extension).
1598 dnl ----------------------------------------------------------------------------
1599 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1600
1601 dnl ------------------
1602 dnl IPv6 header checks
1603 dnl ------------------
1604 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1605         netinet6/in6_var.h netinet6/nd6.h], [], [],
1606         FRR_INCLUDES)
1607
1608 m4_define([FRR_INCLUDES],dnl
1609 FRR_INCLUDES
1610 [#ifdef HAVE_NETINET6_IN6_H
1611 #include <netinet6/in6.h>
1612 #endif
1613 #ifdef HAVE_NETINET_IN6_VAR_H
1614 #include <netinet/in6_var.h>
1615 #endif
1616 #include <netinet/icmp6.h>
1617 #ifdef HAVE_NETINET6_IN6_VAR_H
1618 # include <netinet6/in6_var.h>
1619 #endif
1620 #ifdef HAVE_NETINET6_ND6_H
1621 # include <netinet6/nd6.h>
1622 #endif
1623 ])dnl
1624
1625 dnl --------------------
1626 dnl Daemon disable check
1627 dnl --------------------
1628
1629 AS_IF([test "$enable_bgpd" != "no"], [
1630   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1631 ])
1632
1633 AS_IF([test "$enable_ripd" != "no"], [
1634   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1635 ])
1636
1637 AS_IF([test "$enable_ripngd" != "no"], [
1638   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1639 ])
1640
1641 AS_IF([test "$enable_ospfd" != "no"], [
1642   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1643 ])
1644
1645 AS_IF([test "$enable_ospf6d" != "no"], [
1646   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1647 ])
1648
1649 AS_IF([test "$enable_ldpd" != "no"], [
1650   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1651 ])
1652
1653 AS_IF([test "$enable_nhrpd" != "no"], [
1654   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1655 ])
1656
1657 AS_IF([test "$enable_eigrpd" != "no"], [
1658   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1659 ])
1660
1661 AS_IF([test "$enable_babeld" != "no"], [
1662   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1663 ])
1664
1665 AS_IF([test "$enable_isisd" != "no"], [
1666   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1667 ])
1668
1669 AS_IF([test "$enable_pimd" != "no"], [
1670   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1671 ])
1672
1673 AS_IF([test "$enable_pbrd" != "no"], [
1674   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1675 ])
1676
1677 AS_IF([test "$enable_sharpd" = "yes"], [
1678   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1679 ])
1680
1681 AS_IF([test "$enable_staticd" != "no"], [
1682   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1683 ])
1684
1685 AS_IF([test "$enable_fabricd" != "no"], [
1686   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1687 ])
1688
1689 AS_IF([test "$enable_vrrpd" != "no"], [
1690   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1691 ])
1692
1693 if test "$enable_bfdd" = "no"; then
1694   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1695   BFDD=""
1696 else
1697   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1698   BFDD="bfdd"
1699
1700   case $host_os in
1701     linux*)
1702       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1703       ;;
1704
1705     *)
1706       AC_DEFINE([BFD_BSD], [1], [bfdd])
1707       ;;
1708   esac
1709 fi
1710
1711 AS_IF([test "$enable_pathd" != "no"], [
1712   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1713   AC_DEFINE([HAVE_PATHD_PCEP], [1], [pathd-pcep])
1714 ])
1715
1716
1717 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1718   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1719 fi
1720
1721 NHRPD=""
1722 case "$host_os" in
1723   linux*)
1724     case "${enable_nhrpd}" in
1725       no)
1726         ;;
1727       yes)
1728         if test "$enable_clippy_only" != "yes"; then
1729         if test "$c_ares_found" != "true" ; then
1730           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1731         fi
1732         fi
1733         NHRPD="nhrpd"
1734         ;;
1735       *)
1736         if test "$c_ares_found" = "true" ; then
1737           NHRPD="nhrpd"
1738         fi
1739         ;;
1740     esac
1741     ;;
1742   *)
1743     if test "$enable_nhrpd" = "yes"; then
1744       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1745     fi
1746     ;;
1747 esac
1748
1749 if test "$enable_watchfrr" = "no";then
1750   WATCHFRR=""
1751 else
1752   WATCHFRR="watchfrr"
1753 fi
1754
1755 OSPFCLIENT=""
1756 if test "$enable_ospfapi" != "no";then
1757     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1758
1759   if test "$enable_ospfclient" != "no";then
1760       OSPFCLIENT="ospfclient"
1761   fi
1762 fi
1763
1764 if test "$enable_bgp_announce" = "no";then
1765   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1766 else
1767   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1768 fi
1769
1770 if test "$enable_bgp_vnc" != "no";then
1771   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1772 fi
1773
1774 bgpd_bmp=false
1775 case "${enable_bmp}" in
1776   no)
1777     ;;
1778   yes)
1779     if test "$c_ares_found" != "true" ; then
1780       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1781     fi
1782     bgpd_bmp=true
1783     ;;
1784   *)
1785     if test "$c_ares_found" = "true" ; then
1786       bgpd_bmp=true
1787     fi
1788     ;;
1789 esac
1790
1791 if test "$enable_version_build_config" != "no";then
1792   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1793 fi
1794
1795 dnl ##########################################################################
1796 dnl LARGE if block
1797 if test "$enable_clippy_only" != "yes"; then
1798 dnl ##########################################################################
1799
1800 dnl ------------------
1801 dnl check Net-SNMP library
1802 dnl ------------------
1803 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1804    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1805    if test "$NETSNMP_CONFIG" = "no"; then
1806       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1807    fi
1808    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1809    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1810    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1811    # among other things we avoid a GPL vs. OpenSSL license conflict here
1812    for removelib in crypto ssl sensors pci wrap; do
1813      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1814    done
1815    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1816    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1817 int main(void);
1818 ],
1819 [
1820 {
1821   return 0;
1822 }
1823 ])], [
1824      AC_MSG_RESULT([no])
1825      AC_MSG_ERROR([--enable-snmp given but not usable])])
1826    case "${enable_snmp}" in
1827      yes)
1828       SNMP_METHOD=agentx
1829       ;;
1830      agentx)
1831       SNMP_METHOD="${enable_snmp}"
1832       ;;
1833      *)
1834       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1835       ;;
1836    esac
1837    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1838    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1839 fi
1840 AC_SUBST([SNMP_LIBS])
1841 AC_SUBST([SNMP_CFLAGS])
1842
1843 dnl ---------------
1844 dnl libyang
1845 dnl ---------------
1846 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1847   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1848 ])
1849 ac_cflags_save="$CFLAGS"
1850 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1851 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1852   AC_MSG_ERROR([m4_normalize([
1853     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1854     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1855   ])
1856 ], [[#include <libyang/libyang.h>]])
1857 CFLAGS="$ac_cflags_save"
1858
1859 dnl ---------------
1860 dnl configuration rollbacks
1861 dnl ---------------
1862 SQLITE3=false
1863 if test "$enable_config_rollbacks" = "yes"; then
1864   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1865     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1866     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1867     SQLITE3=true
1868   ], [
1869     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1870   ])
1871 fi
1872
1873 dnl ---------------
1874 dnl confd
1875 dnl ---------------
1876 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1877    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1878    if test "$CONFD" = "/bin/false"; then
1879       AC_MSG_ERROR([confd was not found on your system.])]
1880    fi
1881    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1882    AC_SUBST([CONFD_CFLAGS])
1883    CONFD_LIBS="-lconfd"
1884    AC_SUBST([CONFD_LIBS])
1885    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1886 fi
1887
1888 dnl ---------------
1889 dnl sysrepo
1890 dnl ---------------
1891 if test "$enable_sysrepo" = "yes"; then
1892   PKG_CHECK_MODULES([SYSREPO], [sysrepo],
1893       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1894       SYSREPO=true],
1895       [SYSREPO=false
1896       AC_MSG_ERROR([sysrepo was not found on your system.])]
1897   )
1898 fi
1899
1900 dnl ---------------
1901 dnl gRPC
1902 dnl ---------------
1903 if test "$enable_grpc" = "yes"; then
1904   AC_LANG_PUSH([C++])
1905   AX_CXX_COMPILE_STDCXX([11], [ext])
1906   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
1907     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1908     if test "$PROTOC" = "/bin/false"; then
1909       AC_MSG_FAILURE([grpc requested but protoc not found.])
1910     fi
1911
1912     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1913     GRPC=true
1914   ], [
1915     GRPC=false
1916     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1917   ])
1918   AC_LANG_POP([C++])
1919 fi
1920
1921 dnl -----
1922 dnl LTTng
1923 dnl -----
1924 if test "$enable_lttng" = "yes"; then
1925   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.12.0], [
1926     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1927     LTTNG=true
1928   ], [
1929     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1930   ])
1931 fi
1932
1933 dnl ----
1934 dnl USDT
1935 dnl ----
1936 if test "$enable_usdt" = "yes"; then
1937   AC_CHECK_HEADERS([sys/sdt.h], [
1938     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1939     USDT=true
1940   ], [
1941     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1942   ])
1943 fi
1944
1945 dnl ------
1946 dnl ZeroMQ
1947 dnl ------
1948 if test "$enable_zeromq" != "no"; then
1949   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1950     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1951     ZEROMQ=true
1952   ], [
1953     if test "$enable_zeromq" = "yes"; then
1954       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1955     fi
1956   ])
1957 fi
1958
1959 dnl ------------------------------------
1960 dnl Enable RPKI and add librtr to libs
1961 dnl ------------------------------------
1962 if test "$enable_rpki" = "yes"; then
1963   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1964       [RPKI=true],
1965       [RPKI=false
1966       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1967   )
1968 fi
1969
1970 dnl ------------------------------------
1971 dnl pimd is not supported on OpenBSD and MacOS
1972 dnl ------------------------------------
1973 if test "$enable_pimd" != "no"; then
1974 AC_MSG_CHECKING([for pimd OS support])
1975 case "$host_os" in
1976   darwin*)
1977     AC_MSG_RESULT([no])
1978     enable_pimd="no"
1979     ;;
1980   openbsd*)
1981     AC_MSG_RESULT([no])
1982     enable_pimd="no"
1983     ;;
1984   *)
1985     AC_MSG_RESULT([yes])
1986     ;;
1987 esac
1988 fi
1989
1990 dnl -------------------------------------
1991 dnl VRRP is only supported on linux
1992 dnl -------------------------------------
1993 if test "$enable_vrrpd" != "no"; then
1994 AC_MSG_CHECKING([for VRRP OS support])
1995 case "$host_os" in
1996   linux*)
1997     AC_MSG_RESULT([yes])
1998     ;;
1999   *)
2000     AC_MSG_RESULT([no])
2001     enable_vrrpd="no"
2002     ;;
2003 esac
2004 fi
2005
2006 dnl ------------------------------------------
2007 dnl Check whether rtrlib was build with ssh support
2008 dnl ------------------------------------------
2009 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2010 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2011                         [[struct tr_ssh_config config;]])],
2012         [AC_MSG_RESULT([yes])
2013         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2014         AC_MSG_RESULT([no])
2015 )
2016
2017 dnl ---------------
2018 dnl dlopen & dlinfo
2019 dnl ---------------
2020 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2021   AC_MSG_ERROR([unable to find the dlopen()])
2022 ])
2023
2024 AC_CHECK_HEADERS([link.h])
2025
2026 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2027   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2028 #include <stdlib.h>
2029 #ifdef HAVE_LINK_H
2030 #include <link.h>
2031 #endif
2032 #include <dlfcn.h>
2033 ]], [[
2034   char origin[1];
2035   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2036 ]])], [
2037     frr_cv_rtld_di_origin=yes
2038   ], [
2039     frr_cv_rtld_di_origin=no
2040   ])
2041 ])
2042 if test "$frr_cv_rtld_di_origin" = "yes"; then
2043   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2044 fi
2045
2046 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2047   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2048 #include <stdlib.h>
2049 #ifdef HAVE_LINK_H
2050 #include <link.h>
2051 #endif
2052 #include <dlfcn.h>
2053 ]], [[
2054   struct link_map *lm = NULL;
2055   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2056 ]])], [
2057     frr_cv_rtld_di_linkmap=yes
2058   ], [
2059     frr_cv_rtld_di_linkmap=no
2060   ])
2061 ])
2062 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2063   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2064 fi
2065
2066 dnl ##########################################################################
2067 dnl test "$enable_clippy_only" != "yes"
2068 fi
2069 dnl END OF LARGE if block
2070 dnl ##########################################################################
2071
2072 dnl ---------------------------
2073 dnl sockaddr and netinet checks
2074 dnl ---------------------------
2075 AC_CHECK_TYPES([
2076         struct sockaddr_dl,
2077         struct vifctl, struct mfcctl, struct sioc_sg_req,
2078         vifi_t, struct sioc_vif_req, struct igmpmsg,
2079         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2080         struct nd_opt_adv_interval,
2081         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2082         struct nd_opt_rdnss, struct nd_opt_dnssl],
2083         [], [], FRR_INCLUDES)
2084
2085 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2086         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2087         struct sockaddr_dl.sdl_len,
2088         struct if6_aliasreq.ifra_lifetime,
2089         struct nd_opt_adv_interval.nd_opt_ai_type],
2090         [], [], FRR_INCLUDES)
2091
2092 dnl ---------------------------
2093 dnl IRDP/pktinfo/icmphdr checks
2094 dnl ---------------------------
2095
2096 AC_CHECK_TYPES([struct in_pktinfo], [
2097   AC_CHECK_TYPES([struct icmphdr], [
2098     IRDP=true
2099   ], [
2100     IRDP=false
2101   ], [FRR_INCLUDES])
2102 ], [
2103   IRDP=false
2104 ], [FRR_INCLUDES])
2105
2106 case "${enable_irdp}" in
2107 yes)
2108   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2109   ;;
2110 no)
2111   IRDP=false
2112   ;;
2113 esac
2114
2115
2116 dnl -----------------------
2117 dnl checking for IP_PKTINFO
2118 dnl -----------------------
2119 AC_MSG_CHECKING([for IP_PKTINFO])
2120 AC_COMPILE_IFELSE(
2121 [ AC_LANG_PROGRAM([[
2122         #include <netdb.h>
2123    ]], [[
2124         int opt = IP_PKTINFO;
2125    ]])
2126 ],[
2127   AC_MSG_RESULT([yes])
2128   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2129 ],[
2130   AC_MSG_RESULT([no])
2131 ])
2132
2133 dnl ---------------------------
2134 dnl checking for IP_RECVDSTADDR
2135 dnl ---------------------------
2136 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2137 AC_COMPILE_IFELSE(
2138 [ AC_LANG_PROGRAM([[
2139         #include <netinet/in.h>
2140   ]], [[
2141         int opt = IP_RECVDSTADDR;
2142   ]])
2143 ],[
2144   AC_MSG_RESULT([yes])
2145   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2146 ],[
2147   AC_MSG_RESULT([no])
2148 ])
2149
2150 dnl ----------------------
2151 dnl checking for IP_RECVIF
2152 dnl ----------------------
2153 AC_MSG_CHECKING([for IP_RECVIF])
2154 AC_COMPILE_IFELSE(
2155 [ AC_LANG_PROGRAM([[
2156         #include <netinet/in.h>
2157   ]], [[
2158         int opt = IP_RECVIF;
2159   ]])
2160 ],[
2161   AC_MSG_RESULT([yes])
2162   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2163 ],[
2164   AC_MSG_RESULT([no])
2165 ])
2166
2167 dnl ----------------------
2168 dnl checking for SO_BINDANY
2169 dnl ----------------------
2170 AC_MSG_CHECKING([for SO_BINDANY])
2171 AC_COMPILE_IFELSE(
2172 [ AC_LANG_PROGRAM([[
2173         #include <sys/socket.h>
2174   ]], [[
2175         int opt = SO_BINDANY;
2176   ]])
2177 ],[
2178   AC_MSG_RESULT([yes])
2179   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2180 ],[
2181   AC_MSG_RESULT([no])
2182 ])
2183
2184 dnl ----------------------
2185 dnl checking for IP_FREEBIND
2186 dnl ----------------------
2187 AC_MSG_CHECKING([for IP_FREEBIND])
2188 AC_COMPILE_IFELSE(
2189 [ AC_LANG_PROGRAM([[
2190         #include <netinet/in.h>
2191   ]], [[
2192         int opt = IP_FREEBIND;
2193   ]])
2194 ],[
2195   AC_MSG_RESULT([yes])
2196   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2197 ],[
2198   AC_MSG_RESULT([no])
2199 ])
2200
2201 dnl --------------------------------------
2202 dnl checking for be32dec existence or not
2203 dnl --------------------------------------
2204 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2205         #ifdef HAVE_SYS_ENDIAN_H
2206         #include <sys/endian.h>
2207         #endif
2208         #ifdef HAVE_ENDIAN_H
2209         #include <endian.h>
2210         #endif
2211 ])
2212
2213 dnl --------------------------------------
2214 dnl checking for clock_time monotonic struct and call
2215 dnl --------------------------------------
2216 AC_CHECK_DECL([CLOCK_MONOTONIC],
2217         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2218          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2219 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2220
2221 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2222          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2223 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2224
2225 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2226   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2227 ])
2228
2229 dnl --------------------------------------
2230 dnl checking for flex and bison
2231 dnl --------------------------------------
2232
2233 AM_PROG_LEX
2234 AC_MSG_CHECKING([version of flex])
2235 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2236 frr_ac_flex_version="${frr_ac_flex_version##* }"
2237 AC_MSG_RESULT([$frr_ac_flex_version])
2238 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2239   LEX="$SHELL $missing_dir/missing flex"
2240   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2241     AC_MSG_WARN([using pregenerated flex output files])
2242   else
2243     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2244   fi
2245   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2246   AC_SUBST([LEXLIB], [''])
2247 ])
2248
2249 AC_PROG_YACC
2250 dnl thanks GNU bison for this b*llshit...
2251 AC_MSG_CHECKING([version of bison])
2252 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2253 frr_ac_bison_version="${frr_ac_bison_version##* }"
2254 frr_ac_bison_missing="false"
2255 case "x${frr_ac_bison_version}x" in
2256   x2.7*)
2257     BISON_OPENBRACE='"'
2258     BISON_CLOSEBRACE='"'
2259     BISON_VERBOSE=''
2260     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2261     ;;
2262   x2.*|x1.*)
2263     AC_MSG_RESULT([$frr_ac_bison_version])
2264     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2265     frr_ac_bison_missing="true"
2266     ;;
2267   x)
2268     AC_MSG_RESULT([none])
2269     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2270     frr_ac_bison_missing="true"
2271     ;;
2272   x3.[012][^0-9]*)
2273     BISON_OPENBRACE='{'
2274     BISON_CLOSEBRACE='}'
2275     BISON_VERBOSE='-Dparse.error=verbose'
2276     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2277     ;;
2278   *)
2279     BISON_OPENBRACE='{'
2280     BISON_CLOSEBRACE='}'
2281     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2282     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2283     ;;
2284 esac
2285 AC_SUBST([BISON_OPENBRACE])
2286 AC_SUBST([BISON_CLOSEBRACE])
2287 AC_SUBST([BISON_VERBOSE])
2288
2289 if $frr_ac_bison_missing; then
2290   YACC="$SHELL $missing_dir/missing bison -y"
2291   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2292     AC_MSG_WARN([using pregenerated bison output files])
2293   else
2294     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2295   fi
2296 fi
2297
2298 dnl -------------------
2299 dnl capabilities checks
2300 dnl -------------------
2301 if test "$enable_capabilities" != "no"; then
2302   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2303   AC_COMPILE_IFELSE(
2304   [ AC_LANG_PROGRAM([[
2305         #include <sys/prctl.h>
2306     ]], [[
2307         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2308     ]])
2309   ],[AC_MSG_RESULT([yes])
2310      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2311      frr_ac_keepcaps="yes"
2312   ],[AC_MSG_RESULT(no)
2313   ])
2314   if test "$frr_ac_keepcaps" = "yes"; then
2315     AC_CHECK_HEADERS([sys/capability.h])
2316   fi
2317   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2318     AC_CHECK_LIB([cap], [cap_init],
2319       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2320        LIBCAP="-lcap"
2321        frr_ac_lcaps="yes"]
2322     )
2323   fi
2324   if test "$frr_ac_scaps" = "yes" \
2325        -o "$frr_ac_lcaps" = "yes"; then
2326     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2327   fi
2328
2329   case "$host_os" in
2330   linux*)
2331     if test "$enable_clippy_only" != "yes"; then
2332     if test "$frr_ac_lcaps" != "yes"; then
2333       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2334     fi
2335     fi
2336     ;;
2337   esac
2338 else
2339   case "$host_os" in
2340   linux*)
2341     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2342     ;;
2343   esac
2344 fi
2345 AC_SUBST([LIBCAP])
2346
2347 dnl ---------------------------
2348 dnl check for glibc 'backtrace'
2349 dnl ---------------------------
2350 if test "$enable_backtrace" != "no" ; then
2351   backtrace_ok=no
2352   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2353     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2354     backtrace_ok=yes
2355   ], [
2356     true
2357   ])
2358
2359   if test "$backtrace_ok" = "no"; then
2360     AC_CHECK_HEADER([unwind.h], [
2361       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2362         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2363         backtrace_ok=yes
2364       ])
2365     ])
2366   fi
2367
2368   if test "$backtrace_ok" = "no"; then
2369     AC_CHECK_HEADER([execinfo.h], [
2370       AC_SEARCH_LIBS([backtrace], [execinfo], [
2371         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2372         backtrace_ok=yes
2373       ],, [-lm])
2374     ])
2375   fi
2376
2377   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2378     dnl user explicitly requested backtrace but we failed to find support
2379     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2380   fi
2381 fi
2382
2383 dnl -----------------------------------------
2384 dnl check for malloc mallinfo struct and call
2385 dnl this must try and link using LIBS, in
2386 dnl order to check no alternative allocator
2387 dnl has been specified, which might not provide
2388 dnl mallinfo
2389 dnl -----------------------------------------
2390 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2391
2392 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2393   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2394 #ifdef HAVE_MALLOC_H
2395 #include <malloc.h>
2396 #endif
2397 #ifdef HAVE_MALLOC_NP_H
2398 #include <malloc_np.h>
2399 #endif
2400 #ifdef HAVE_MALLOC_MALLOC_H
2401 #include <malloc/malloc.h>
2402 #endif
2403 ]], [[
2404 struct mallinfo ac_x; ac_x = mallinfo ();
2405 ]])], [
2406     frr_cv_mallinfo=yes
2407   ], [
2408     frr_cv_mallinfo=no
2409   ])
2410 ])
2411 if test "$frr_cv_mallinfo" = "yes"; then
2412   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2413 fi
2414
2415 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2416   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2417 #ifdef HAVE_MALLOC_H
2418 #include <malloc.h>
2419 #endif
2420 #ifdef HAVE_MALLOC_NP_H
2421 #include <malloc_np.h>
2422 #endif
2423 #ifdef HAVE_MALLOC_MALLOC_H
2424 #include <malloc/malloc.h>
2425 #endif
2426 ]], [[
2427 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2428 ]])], [
2429     frr_cv_mallinfo2=yes
2430   ], [
2431     frr_cv_mallinfo2=no
2432   ])
2433 ])
2434 if test "$frr_cv_mallinfo2" = "yes"; then
2435   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2436 fi
2437
2438 AC_MSG_CHECKING([whether malloc_usable_size is available])
2439 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2440 #ifdef HAVE_MALLOC_H
2441 #include <malloc.h>
2442 #endif
2443 #ifdef HAVE_MALLOC_MALLOC_H
2444 #include <malloc/malloc.h>
2445 #endif
2446 ]], [[
2447 size_t ac_x; ac_x = malloc_usable_size(NULL);
2448 ]])], [
2449   AC_MSG_RESULT([yes])
2450   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2451 ], [
2452   AC_MSG_RESULT([no])
2453
2454   AC_MSG_CHECKING([whether malloc_size is available])
2455   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2456 #ifdef HAVE_MALLOC_H
2457 #include <malloc.h>
2458 #endif
2459 #ifdef HAVE_MALLOC_MALLOC_H
2460 #include <malloc/malloc.h>
2461 #endif
2462 ]], [[
2463 size_t ac_x; ac_x = malloc_size(NULL);
2464 ]])], [
2465     AC_MSG_RESULT([yes])
2466     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2467   ], [
2468     AC_MSG_RESULT([no])
2469   ])
2470 ])
2471
2472 dnl ----------
2473 dnl configure date
2474 dnl ----------
2475 dev_version=`echo $VERSION | grep dev`
2476 #don't expire deprecated code in non 'dev' branch
2477 if test "$dev_version" = ""; then
2478    CONFDATE=0
2479 else
2480    CONFDATE=`date '+%Y%m%d'`
2481 fi
2482 AC_SUBST([CONFDATE])
2483
2484 dnl ------------------------------
2485 dnl set paths for state directory
2486 dnl ------------------------------
2487 AC_MSG_CHECKING([directory to use for state file])
2488 if test "$prefix" = "NONE"; then
2489   frr_statedir_prefix="";
2490 else
2491   frr_statedir_prefix=${prefix}
2492 fi
2493 if test "$localstatedir" = '${prefix}/var'; then
2494   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2495                         ${frr_statedir_prefix}/var/adm dnl
2496                         ${frr_statedir_prefix}/etc dnl
2497                         /var/run        dnl
2498                         /var/adm        dnl
2499                         /etc            dnl
2500                         /dev/null;
2501   do
2502     test -d $FRR_STATE_DIR && break
2503   done
2504   frr_statedir=$FRR_STATE_DIR
2505 else
2506   frr_statedir=${localstatedir}
2507 fi
2508 if test "$frr_statedir" = "/dev/null"; then
2509     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2510 fi
2511 AC_MSG_RESULT([${frr_statedir}])
2512 AC_SUBST([frr_statedir])
2513
2514 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2515 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2516 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2517 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2518 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2519
2520 dnl autoconf does this, but it does it too late...
2521 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2522 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2523
2524 dnl get the full path, recursing through variables...
2525 vtysh_bin="$bindir/vtysh"
2526 for I in 1 2 3 4 5 6 7 8 9 10; do
2527         eval vtysh_bin="\"$vtysh_bin\""
2528 done
2529 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2530 AC_SUBST([vtysh_bin])
2531
2532 CFG_SYSCONF="$sysconfdir"
2533 CFG_SBIN="$sbindir"
2534 CFG_STATE="$frr_statedir"
2535 CFG_MODULE="$moduledir"
2536 CFG_YANGMODELS="$yangmodelsdir"
2537 CFG_SCRIPT="$scriptdir"
2538 for I in 1 2 3 4 5 6 7 8 9 10; do
2539         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2540         eval CFG_SBIN="\"$CFG_SBIN\""
2541         eval CFG_STATE="\"$CFG_STATE\""
2542         eval CFG_MODULE="\"$CFG_MODULE\""
2543         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2544         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2545 done
2546 AC_SUBST([CFG_SYSCONF])
2547 AC_SUBST([CFG_SBIN])
2548 AC_SUBST([CFG_STATE])
2549 AC_SUBST([CFG_MODULE])
2550 AC_SUBST([CFG_SCRIPT])
2551 AC_SUBST([CFG_YANGMODELS])
2552 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2553 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2554 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2555 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2556
2557 dnl various features
2558 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2559 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2560 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2561 dnl northbound
2562 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2563 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2564 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2565 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2566 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2567 dnl plugins
2568 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2569 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2570 AM_CONDITIONAL([IRDP], [$IRDP])
2571 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2572 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2573 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2574
2575 dnl PCEP plugin
2576 AS_IF([test "$enable_pathd" != "no"], [
2577        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2578        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2579        ])
2580 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2581 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2582 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2583 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2584
2585 dnl daemons
2586 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2587 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2588 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2589 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2590 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2591 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2592 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2593 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2594 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2595 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2596 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2597 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2598 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2599 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2600 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2601 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2602 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2603 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2604 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2605 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2606 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2607 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2608 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2609
2610 AC_CONFIG_FILES([Makefile],[
2611         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2612         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2613 ], [
2614         PYTHON="$PYTHON"
2615         enable_dev_build="$enable_dev_build"
2616 ])
2617
2618 AC_CONFIG_FILES([
2619           config.version
2620           redhat/frr.spec
2621           alpine/APKBUILD
2622           snapcraft/snapcraft.yaml
2623           lib/version.h
2624           tests/lib/cli/test_cli.refout
2625           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2626           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2627           pkgsrc/eigrpd.sh])
2628
2629 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2630 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2631 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2632 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2633 AC_CONFIG_FILES([tools/frrcommon.sh])
2634 AC_CONFIG_FILES([tools/frr.service])
2635 AC_CONFIG_FILES([tools/frr@.service])
2636
2637 AS_IF([test "$with_pkg_git_version" = "yes"], [
2638     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2639         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2640         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2641                 "${ac_abs_top_srcdir}" \
2642                 > "${dst}.tmp"
2643         test -f "$dst" \
2644                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2645                 && rm "${dst}.tmp" \
2646                 || mv "${dst}.tmp" "${dst}"
2647     ], [
2648         PERL="$PERL"
2649     ])
2650 ])
2651
2652 ## Hack, but working solution to avoid rebuilding of frr.info.
2653 ## It's already in CVS until texinfo 4.7 is more common.
2654 AC_OUTPUT
2655
2656 if test "$enable_rpath" = "yes" ; then
2657         true
2658 else
2659         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2660         sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
2661         sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool
2662 fi
2663
2664 echo "
2665 FRRouting configuration
2666 ------------------------------
2667 FRR version             : ${PACKAGE_VERSION}
2668 host operating system   : ${host_os}
2669 source code location    : ${srcdir}
2670 compiler                : ${CC}
2671 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2672 make                    : ${MAKE-make}
2673 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2674 state file directory    : ${frr_statedir}
2675 config file directory   : `eval echo \`echo ${sysconfdir}\``
2676 module directory        : ${CFG_MODULE}
2677 script directory        : ${CFG_SCRIPT}
2678 user to run as          : ${enable_user}
2679 group to run as         : ${enable_group}
2680 group for vty sockets   : ${enable_vty_group}
2681 config file mask        : ${enable_configfile_mask}
2682 log file mask           : ${enable_logfile_mask}
2683 zebra protobuf enabled  : ${enable_protobuf:-no}
2684 vici socket path        : ${vici_socket}
2685
2686 The above user and group must have read/write access to the state file
2687 directory and to the config files in the config file directory."
2688
2689 if test -n "$enable_datacenter"; then
2690   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2691 fi
2692 if test -n "$enable_time_check"; then
2693   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2694 fi
2695 if test -n "$enable_cpu_time"; then
2696   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2697 fi
2698
2699 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2700   AC_MSG_WARN([sphinx is missing but required to build documentation])
2701 fi
2702 if test "$frr_py_mod_pytest" = "false"; then
2703   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2704 fi