configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.4-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 hosttools_clippy="false"
  29 build_clippy="true"
  30
  31 dnl case 1: external clippy
  32 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  33   if test "$enable_clippy_only" = "yes"; then
  34     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  35   fi
  36
  37   CLIPPY="$with_clippy"
  38   build_clippy="false"
  39   if test ! -x "$with_clippy"; then
  40     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  41   fi
  42
  43 dnl case 2: cross-compiling internal clippy
  44 elif test "$host" != "$build"; then
  45   if test "$srcdir" = "."; then
  46     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  47   fi
  48   test -d hosttools || mkdir hosttools
  49   abssrc="`cd \"${srcdir}\"; pwd`"
  50
  51   AC_MSG_NOTICE([...])
  52   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  53   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  54   AC_MSG_NOTICE([...])
  55
  56   (
  57     for var in $ac_precious_vars; do
  58       dnl special cases
  59       case "$var" in
  60       YACC|YFLAGS) continue;;
  61       PYTHON*)     retain=true;;
  62       *)           retain=false;
  63       esac
  64
  65       eval "hostvar=\"\${HOST_$var}\""
  66       eval "targetvar=\"\${$var}\""
  67       if test -n "$hostvar"; then
  68         eval "$var='$hostvar'"
  69         _AS_ECHO_LOG([host $var='$hostvar'])
  70       elif $retain; then
  71         _AS_ECHO_LOG([host retain $var='$targetvar'])
  72       else
  73         eval "unset $var"
  74         _AS_ECHO_LOG([host unset $var])
  75       fi
  76     done
  77     cd hosttools
  78     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  79   ) || exit 1
  80
  81   AC_MSG_NOTICE([...])
  82   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  83   AC_MSG_NOTICE([...])
  84
  85   build_clippy="false"
  86   hosttools_clippy="true"
  87   CLIPPY="hosttools/lib/clippy"
  88
  89 dnl case 3: normal build internal clippy
  90 else
  91   CLIPPY="lib/clippy\$(EXEEXT)"
  92 fi
  93 AC_SUBST([CLIPPY])
  94 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  95 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
  96 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
  97
  98 # Disable portability warnings -- our automake code (in particular
  99 # common.am) uses some constructs specific to gmake.
 100 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 101 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 102 AM_SILENT_RULES([yes])
 103 AC_CONFIG_HEADERS([config.h])
 104
 105 AC_PATH_PROG([PERL], [perl])
 106 PKG_PROG_PKG_CONFIG
 107
 108 dnl default is to match previous behavior
 109 exampledir=${sysconfdir}
 110 AC_ARG_ENABLE([exampledir],
 111           AS_HELP_STRING([--enable-exampledir],
 112                          [specify alternate directory for examples]),
 113                          exampledir="$enableval",)
 114 dnl XXX add --exampledir to autoconf standard directory list somehow
 115 AC_SUBST([exampledir])
 116
 117 dnl default is to match previous behavior
 118 pkgsrcrcdir=""
 119 AC_ARG_ENABLE([pkgsrcrcdir],
 120           AS_HELP_STRING([--enable-pkgsrcrcdir],
 121                          [specify directory for rc.d scripts]),
 122                          pkgsrcrcdir="$enableval",)
 123 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 124 AC_SUBST([pkgsrcrcdir])
 125 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
 126
 127 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 128         moduledir="$withval"
 129 ], [
 130         moduledir="\${libdir}/frr/modules"
 131 ])
 132 AC_SUBST([moduledir], [$moduledir])
 133
 134
 135 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 136         yangmodelsdir="$withval"
 137 ], [
 138         yangmodelsdir="\${datarootdir}/yang"
 139 ])
 140 AC_SUBST([yangmodelsdir])
 141
 142 AC_ARG_ENABLE(tcmalloc,
 143         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 144 [case "${enableval}" in
 145   yes) tcmalloc_enabled=true
 146 LIBS="$LIBS -ltcmalloc_minimal"
 147  ;;
 148   no)  tcmalloc_enabled=false ;;
 149   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 150 esac],[tcmalloc_enabled=false])
 151
 152
 153 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 154 dnl flag determination logic.
 155 CFLAGS="${CFLAGS:-}"
 156
 157 dnl --------------------
 158 dnl Check CC and friends
 159 dnl --------------------
 160 dnl note orig_cflags is also used further down
 161 orig_cflags="$CFLAGS"
 162 orig_cxxflags="$CXXFLAGS"
 163 AC_LANG([C])
 164 AC_PROG_CC
 165 AC_PROG_CPP
 166 AC_PROG_CXX
 167 AM_PROG_CC_C_O
 168 dnl remove autoconf default "-g -O2"
 169 CFLAGS="$orig_cflags"
 170 CXXFLAGS="$orig_cxxflags"
 171 AC_PROG_CC_C99
 172 dnl NB: see C11 below
 173
 174 PKG_PROG_PKG_CONFIG
 175
 176 dnl it's 2019, sed is sed.
 177 SED=sed
 178 AC_SUBST([SED])
 179
 180 dnl try and enable CFLAGS that are useful for FRR
 181 dnl - specifically, options to control warnings
 182
 183 AC_USE_SYSTEM_EXTENSIONS
 184 AC_DEFUN([AC_C_FLAG], [{
 185     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+],[____])])
 186     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 187         AC_LANG_PUSH([C])
 188         ac_c_flag_save="$CFLAGS"
 189         CFLAGS="$CFLAGS $1"
 190         AC_COMPILE_IFELSE(
 191                 [AC_LANG_PROGRAM([[]])],
 192                 [
 193                         cachename=yes
 194                 ], [
 195                         cachename=no
 196                 ])
 197         CFLAGS="$ac_c_flag_save"
 198         AC_LANG_POP([C])
 199     ])
 200     if test "${cachename}" = yes; then
 201         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 202     else
 203         :
 204         $2
 205     fi
 206     m4_popdef([cachename])
 207 }])
 208
 209 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 210         AC_LANG_PUSH([C])
 211         ac_cflags_save="$CFLAGS"
 212         ac_libs_save="$LIBS"
 213         CFLAGS="$CFLAGS $1"
 214         LIBS="$LIBS $2"
 215         AC_LINK_IFELSE(
 216                 [$3],
 217                 [
 218                         CFLAGS="$ac_cflags_save"
 219                         LIBS="$ac_libs_save"
 220                         m4_default([$5], [
 221                                 AC_MSG_RESULT([yes])
 222                         ])
 223                 ], [
 224                         CFLAGS="$ac_cflags_save"
 225                         LIBS="$ac_libs_save"
 226                         m4_default([$4], [
 227                                 AC_MSG_RESULT([no])
 228                         ])
 229                 ])
 230         AC_LANG_POP([C])
 231         }])
 232
 233 dnl ICC won't bail on unknown options without -diag-error 10006
 234 dnl need to do this first so we get useful results for the other options
 235 AC_C_FLAG([-diag-error 10006])
 236
 237 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 238 ac_cc="$CC"
 239 CC="${CC% -std=gnu99}"
 240 CC="${CC% -std=c99}"
 241
 242 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 243
 244 dnl if the user has specified any CFLAGS, override our settings
 245 if test "x${enable_gcov}" = "xyes"; then
 246    if test "z$orig_cflags" = "z"; then
 247       AC_C_FLAG([-coverage])
 248       AC_C_FLAG([-O0])
 249    fi
 250
 251    LDFLAGS="${LDFLAGS} -lgcov"
 252 fi
 253
 254 if test "x${enable_clang_coverage}" = "xyes"; then
 255    AC_C_FLAG([-fprofile-instr-generate], [
 256      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 257    ])
 258    AC_C_FLAG([-fcoverage-mapping], [
 259      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 260    ])
 261 fi
 262
 263 if test "x${enable_dev_build}" = "xyes"; then
 264    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 265    if test "z$orig_cflags" = "z"; then
 266       AC_C_FLAG([-g3])
 267       AC_C_FLAG([-O0])
 268    fi
 269    if test "x${enable_lua}" = "xyes"; then
 270       AX_PROG_LUA([5.3])
 271       AX_LUA_HEADERS
 272       AX_LUA_LIBS([
 273          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 274          LIBS="$LIBS $LUA_LIB"
 275       ])
 276    fi
 277 else
 278    if test "x${enable_lua}" = "xyes"; then
 279       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 280    fi
 281    if test "z$orig_cflags" = "z"; then
 282       AC_C_FLAG([-g])
 283       AC_C_FLAG([-O2])
 284    fi
 285 fi
 286 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 287
 288 dnl always want these CFLAGS
 289 AC_C_FLAG([-fno-omit-frame-pointer])
 290 AC_C_FLAG([-funwind-tables])
 291 AC_C_FLAG([-Wall])
 292 AC_C_FLAG([-Wextra])
 293 AC_C_FLAG([-Wmissing-prototypes])
 294 AC_C_FLAG([-Wmissing-declarations])
 295 AC_C_FLAG([-Wpointer-arith])
 296 AC_C_FLAG([-Wbad-function-cast])
 297 AC_C_FLAG([-Wwrite-strings])
 298 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 299   AC_C_FLAG([-Wcast-qual])
 300   AC_C_FLAG([-Wstrict-prototypes])
 301   AC_C_FLAG([-Wmissing-noreturn])
 302   AC_C_FLAG([-Wmissing-format-attribute])
 303   AC_C_FLAG([-Wunreachable-code])
 304   AC_C_FLAG([-Wpacked])
 305   AC_C_FLAG([-Wpadded])
 306   AC_C_FLAG([-Wshadow])
 307 else
 308   AC_C_FLAG([-Wno-unused-result])
 309 fi
 310 AC_C_FLAG([-Wno-unused-parameter])
 311 AC_C_FLAG([-Wno-missing-field-initializers])
 312
 313 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 314 AC_SUBST([CXX_COMPAT_CFLAGS])
 315
 316 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 317 dnl for some reason the string consts get 'promoted' to char *,
 318 dnl triggering a const to non-const conversion warning.
 319 AC_C_FLAG([-diag-disable 3179])
 320
 321 if test x"${enable_werror}" = x"yes" ; then
 322   WERROR="-Werror"
 323 fi
 324 AC_SUBST([WERROR])
 325
 326 SAN_FLAGS=""
 327 if test "$enable_address_sanitizer" = "yes"; then
 328   AC_C_FLAG([-fsanitize=address], [
 329     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 330   ], [
 331     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 332   ])
 333 fi
 334 if test "$enable_thread_sanitizer" = "yes"; then
 335   AC_C_FLAG([-fsanitize=thread], [
 336     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 337   ], [
 338     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 339   ])
 340 fi
 341 if test "$enable_memory_sanitizer" = "yes"; then
 342   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 343     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 344   ], [
 345     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 346   ])
 347 fi
 348 if test "$enable_undefined_sanitizer" = "yes"; then
 349   AC_C_FLAG([-fsanitize=undefined], [
 350     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 351   ], [
 352     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 353   ])
 354 fi
 355 AC_SUBST([SAN_FLAGS])
 356
 357 dnl ----------
 358 dnl Essentials
 359 dnl ----------
 360
 361 AX_PTHREAD([
 362   CC="$PTHREAD_CC"
 363   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 364   LIBS="$PTHREAD_LIBS $LIBS"
 365 ], [
 366   AC_MSG_FAILURE([This FRR version needs pthreads])
 367 ])
 368
 369 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 370                 [frr_cv_pthread_condattr_setclock=yes],
 371                 [frr_cv_pthread_condattr_setclock=no])
 372 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 373   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 374 fi
 375
 376 dnl --------------
 377 dnl Check programs
 378 dnl --------------
 379 AC_PROG_INSTALL
 380 AC_PROG_LN_S
 381 AC_CHECK_TOOL([AR], [ar])
 382
 383 dnl -------
 384 dnl libtool
 385 dnl -------
 386 AC_ARG_ENABLE([static-bin],
 387   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 388 LT_INIT
 389 _LT_CONFIG_LIBTOOL([
 390   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 391     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 392 ])
 393 if test "$enable_static_bin" = "yes"; then
 394   AC_LDFLAGS="-static"
 395   if test "$enable_static" != "yes"; then
 396     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 397   fi
 398 fi
 399 if test "$enable_shared" != "yes"; then
 400   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 401 fi
 402 AC_SUBST([AC_LDFLAGS])
 403 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 404
 405 dnl $AR and $RANLIB are set by LT_INIT above
 406 AC_MSG_CHECKING([whether $AR supports D option])
 407 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 408   AC_MSG_RESULT([yes])
 409   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 410   ARFLAGS="crD"
 411   AR_FLAGS="crD"
 412 else
 413   AC_MSG_RESULT([no])
 414   ARFLAGS="cru"
 415   AR_FLAGS="cru"
 416 fi
 417 AC_SUBST([ARFLAGS])
 418 AC_SUBST([AR_FLAGS])
 419
 420 AC_MSG_CHECKING([whether $RANLIB supports D option])
 421 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 422   if grep -q -- '-D' conftest.err; then
 423     AC_MSG_RESULT([no])
 424   else
 425     AC_MSG_RESULT([yes])
 426     RANLIB="$RANLIB -D"
 427   fi
 428 else
 429   AC_MSG_RESULT([no])
 430 fi
 431 AC_SUBST([RANLIB])
 432
 433 test -f conftest.err && rm conftest.err
 434 test -f conftest.a && rm conftest.a
 435
 436 dnl ----------------------
 437 dnl Packages configuration
 438 dnl ----------------------
 439 if test -f config.version; then
 440   . ./config.version
 441 elif test -f "${srcdir}/config.version"; then
 442   . "${srcdir}/config.version"
 443 fi
 444 AC_ARG_WITH([pkg-extra-version],
 445   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 446   if test "$withval" = "no"; then
 447     EXTRAVERSION=
 448   else
 449     EXTRAVERSION=$withval
 450   fi
 451 ], [])
 452 AC_ARG_WITH([pkg-git-version],
 453         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 454         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 455 AC_ARG_WITH([clippy],
 456   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 457 AC_ARG_WITH([vtysh_pager],
 458         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 459         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 460 AC_ARG_ENABLE([vtysh],
 461   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 462 AC_ARG_ENABLE([doc],
 463   AS_HELP_STRING([--disable-doc], [do not build docs]))
 464 AC_ARG_ENABLE([doc-html],
 465   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 466 AC_ARG_ENABLE([zebra],
 467   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 468 AC_ARG_ENABLE([bgpd],
 469   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 470 AC_ARG_ENABLE([ripd],
 471   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 472 AC_ARG_ENABLE([ripngd],
 473   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 474 AC_ARG_ENABLE([ospfd],
 475   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 476 AC_ARG_ENABLE([ospf6d],
 477   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 478 AC_ARG_ENABLE([ldpd],
 479   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 480 AC_ARG_ENABLE([nhrpd],
 481   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 482 AC_ARG_ENABLE([eigrpd],
 483   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 484 AC_ARG_ENABLE([babeld],
 485   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 486 AC_ARG_ENABLE([watchfrr],
 487   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 488 AC_ARG_ENABLE([isisd],
 489   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 490 AC_ARG_ENABLE([pimd],
 491   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 492 AC_ARG_ENABLE([pbrd],
 493   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 494 AC_ARG_ENABLE([sharpd],
 495   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 496 AC_ARG_ENABLE([staticd],
 497   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 498 AC_ARG_ENABLE([fabricd],
 499   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 500 AC_ARG_ENABLE([vrrpd],
 501   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 502 AC_ARG_ENABLE([bgp-announce],
 503   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 504 AC_ARG_ENABLE([bgp-vnc],
 505   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 506 AC_ARG_ENABLE([bgp-bmp],
 507   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 508 AC_ARG_ENABLE([snmp],
 509   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 510 AC_ARG_ENABLE([config_rollbacks],
 511   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 512 AC_ARG_ENABLE([confd],
 513   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 514 AC_ARG_ENABLE([sysrepo],
 515   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 516 AC_ARG_ENABLE([grpc],
 517   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 518 AC_ARG_ENABLE([zeromq],
 519   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 520 AC_ARG_WITH([libpam],
 521   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 522 AC_ARG_ENABLE([ospfapi],
 523   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 524 AC_ARG_ENABLE([ospfclient],
 525   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 526                           (this is the default if --disable-ospfapi is set)]))
 527 AC_ARG_ENABLE([multipath],
 528   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 529 AC_ARG_ENABLE([user],
 530   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 531 AC_ARG_ENABLE([group],
 532   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 533 AC_ARG_ENABLE([vty_group],
 534   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 535 AC_ARG_ENABLE([configfile_mask],
 536   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 537 AC_ARG_ENABLE([logfile_mask],
 538   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 539 AC_ARG_ENABLE([shell_access],
 540   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 541 AC_ARG_ENABLE([realms],
 542   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 543 AC_ARG_ENABLE([rtadv],
 544   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 545 AC_ARG_ENABLE([irdp],
 546   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 547 AC_ARG_ENABLE([capabilities],
 548   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 549 AC_ARG_ENABLE([rusage],
 550   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 551 AC_ARG_ENABLE([gcc_ultra_verbose],
 552   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 553 AC_ARG_ENABLE([backtrace],
 554   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 555 AC_ARG_ENABLE([time-check],
 556   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 557 AC_ARG_ENABLE([cpu-time],
 558   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 559 AC_ARG_ENABLE([pcreposix],
 560   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 561 AC_ARG_ENABLE([fpm],
 562   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 563 AC_ARG_ENABLE([systemd],
 564   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 565 AC_ARG_ENABLE([werror],
 566   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 567 AC_ARG_ENABLE([cumulus],
 568   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 569 AC_ARG_ENABLE([datacenter],
 570   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 571 AC_ARG_ENABLE([fuzzing],
 572   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 573 AC_ARG_ENABLE([netlink_fuzzing],
 574   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 575 AC_ARG_ENABLE([rr-semantics],
 576   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 577 AC_ARG_ENABLE([protobuf],
 578   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 579 AC_ARG_ENABLE([oldvpn_commands],
 580   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 581 AC_ARG_ENABLE([rpki],
 582   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 583 AC_ARG_ENABLE([clippy-only],
 584   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 585 AC_ARG_ENABLE([numeric_version],
 586   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 587 AC_ARG_ENABLE([gcov],
 588   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 589 AC_ARG_ENABLE([clang_coverage],
 590   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 591 AC_ARG_ENABLE([bfdd],
 592   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 593 AC_ARG_ENABLE([address-sanitizer],
 594   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 595 AC_ARG_ENABLE([thread-sanitizer],
 596   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 597 AC_ARG_ENABLE([memory-sanitizer],
 598   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 599 AC_ARG_ENABLE([undefined-sanitizer],
 600   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 601 AC_ARG_WITH([crypto],
 602   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 603
 604 #if openssl, else use the internal
 605 AS_IF([test x"${with_crypto}" = x"openssl"], [
 606 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 607 if test $ac_cv_lib_crypto_EVP_DigestInit = no; then
 608   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 609 else
 610   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 611 fi
 612 ], [test x"${with_crypto}" = x"internal" || test x"${with_crypto}" = x"" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 613 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 614 )
 615
 616 AS_IF([test "${enable_clippy_only}" != "yes"], [
 617 AC_CHECK_HEADERS([json-c/json.h])
 618 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 619 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 620   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 621   if test "$ac_cv_lib_json_json_object_get" = no; then
 622       AC_MSG_ERROR([libjson is needed to compile])
 623   fi
 624 fi
 625 ])
 626
 627 AC_ARG_ENABLE([dev_build],
 628     AS_HELP_STRING([--enable-dev-build], [build for development]))
 629
 630 AC_ARG_ENABLE([lua],
 631     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 632
 633 if test x"${enable_time_check}" != x"no" ; then
 634   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 635     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 636   else
 637     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 638   fi
 639 fi
 640
 641 case "${enable_cpu_time}" in
 642   "no")
 643   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 644   ;;
 645   "*")
 646   ;;
 647 esac
 648
 649 case "${enable_systemd}" in
 650   "no") ;;
 651   "yes")
 652   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 653   if test $ac_cv_lib_systemd_sd_notify = no; then
 654     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 655   else
 656     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 657   fi
 658   ;;
 659   "*") ;;
 660 esac
 661
 662 if test "${enable_rr_semantics}" != "no" ; then
 663   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 664 fi
 665
 666 if test "${enable_datacenter}" = "yes" ; then
 667   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 668   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 669   DFLT_NAME="datacenter"
 670 else
 671   DFLT_NAME="traditional"
 672 fi
 673
 674 if test "${enable_fuzzing}" = "yes" ; then
 675   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 676 fi
 677
 678 if test "${enable_netlink_fuzzing}" = "yes" ; then
 679   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 680 fi
 681
 682 if test "${enable_cumulus}" = "yes" ; then
 683   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 684 fi
 685
 686 AC_SUBST([DFLT_NAME])
 687 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 688
 689 if test "${enable_shell_access}" = "yes"; then
 690    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 691 fi
 692
 693 #
 694 # Python for clippy
 695 #
 696
 697 AS_IF([test "$host" = "$build"], [
 698   FRR_PYTHON_DEV
 699 ], [
 700   FRR_PYTHON
 701 ])
 702
 703 FRR_PYTHON_MODULES([pytest])
 704
 705 if test "${enable_doc}" != "no"; then
 706   FRR_PYTHON_MODULES([sphinx], , [
 707     if test "${enable_doc}" = "yes"; then
 708       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 709     fi
 710   ])
 711 fi
 712 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" != "false"])
 713 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
 714
 715 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 716   PYSPHINX="-m sphinx"
 717 ], [
 718   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 719 ])
 720 AC_SUBST([PYSPHINX])
 721
 722 #
 723 # Logic for old vpn commands support.
 724 #
 725 if test "$enable_oldvpn_commands" = "yes"; then
 726    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 727 fi
 728
 729 #
 730 # End of logic for protobuf support.
 731 #
 732
 733 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 734 if test "${enable_rtadv}" != "no"; then
 735   AC_MSG_RESULT([yes])
 736   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 737 else
 738   AC_MSG_RESULT([no])
 739 fi
 740
 741 if test x"${enable_user}" = x"no"; then
 742   enable_user=""
 743 else
 744   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 745     enable_user="frr"
 746   fi
 747   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 748 fi
 749
 750 if test x"${enable_group}" = x"no"; then
 751   enable_group=""
 752 else
 753   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 754     enable_group="frr"
 755   fi
 756   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 757 fi
 758
 759 if test x"${enable_vty_group}" = x"yes" ; then
 760   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 761 elif test x"${enable_vty_group}" != x""; then
 762   if test x"${enable_vty_group}" != x"no"; then
 763     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 764   fi
 765 fi
 766 AC_SUBST([enable_user])
 767 AC_SUBST([enable_group])
 768 AC_SUBST([enable_vty_group])
 769
 770 enable_configfile_mask=${enable_configfile_mask:-0600}
 771 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 772
 773 enable_logfile_mask=${enable_logfile_mask:-0600}
 774 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 775
 776 MPATH_NUM=16
 777
 778 case "${enable_multipath}" in
 779   0)
 780     MPATH_NUM=64
 781     ;;
 782   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 783     MPATH_NUM="${enable_multipath}"
 784     ;;
 785   "")
 786     ;;
 787   *)
 788     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 789     ;;
 790 esac
 791
 792 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 793
 794 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 795
 796 dnl --------------------
 797 dnl Enable code coverage
 798 dnl --------------------
 799 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 800
 801 dnl ------------------------------------
 802 dnl Alpine only accepts numeric versions
 803 dnl ------------------------------------
 804 if test "x${enable_numeric_version}" != "x" ; then
 805   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 806   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 807 fi
 808
 809 dnl -----------------------------------
 810 dnl Add extra version string to package
 811 dnl name, string and version fields.
 812 dnl -----------------------------------
 813 if test "x${EXTRAVERSION}" != "x" ; then
 814   VERSION="${VERSION}${EXTRAVERSION}"
 815   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 816   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 817   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 818 fi
 819 AC_SUBST([EXTRAVERSION])
 820
 821 if test "x$with_pkg_git_version" = "xyes"; then
 822         if test -d "${srcdir}/.git"; then
 823                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 824         else    with_pkg_git_version="no"
 825                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 826         fi
 827 fi
 828 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 829
 830 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 831 if test "x${OBJCOPY}" != "x:"; then
 832   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 833     frr_cv_interp=""
 834     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 835       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 836         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 837       fi
 838       test -f conftest.interp && rm conftest.interp
 839     ])
 840   ])
 841 fi
 842 if test -n "$frr_cv_interp"; then
 843   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 844 fi
 845
 846 dnl -------------------------
 847 dnl Check other header files.
 848 dnl -------------------------
 849 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 850         linux/version.h asm/types.h])
 851
 852 ac_stdatomic_ok=false
 853 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 854 AC_CHECK_HEADER([stdatomic.h],[
 855
 856   AC_MSG_CHECKING([whether _Atomic qualifier works])
 857   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 858 #include <stdatomic.h>
 859 int main(int argc, char **argv) {
 860   _Atomic int i = 0;
 861   return i;
 862 }
 863 ]])], [
 864     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 865     AC_MSG_RESULT([yes])
 866     ac_stdatomic_ok=true
 867   ], [
 868     AC_MSG_RESULT([no])
 869   ])
 870 ])
 871
 872 AS_IF([$ac_stdatomic_ok], [true], [
 873   AC_MSG_CHECKING([for __atomic_* builtins])
 874   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 875 int main(int argc, char **argv) {
 876   volatile int i = 1;
 877   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 878   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 879 }
 880 ]])], [
 881     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 882     AC_MSG_RESULT([yes])
 883   ], [
 884     AC_MSG_RESULT([no])
 885
 886     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 887     AC_MSG_CHECKING([for __sync_* builtins])
 888     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 889 int main(int argc, char **argv) {
 890   volatile int i = 1;
 891   __sync_fetch_and_sub (&i, 1);
 892   return __sync_val_compare_and_swap (&i, 0, 1);
 893 }
 894 ]])], [
 895       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 896       AC_MSG_RESULT([yes])
 897
 898       AC_MSG_CHECKING([for __sync_swap builtin])
 899       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 900 int main(int argc, char **argv) {
 901   volatile int i = 1;
 902   return __sync_swap (&i, 2);
 903 }
 904 ]])], [
 905         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 906         AC_MSG_RESULT([yes])
 907       ], [
 908         AC_MSG_RESULT([no])
 909       ])
 910
 911     ], [
 912       AC_MSG_RESULT([no])
 913       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 914     ])
 915   ])
 916 ])
 917
 918 AC_CHECK_HEADERS([pthread_np.h],,, [
 919 #include <pthread.h>
 920 ])
 921 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 922
 923 needsync=true
 924
 925 AS_IF([$needsync], [
 926   dnl Linux
 927   AC_MSG_CHECKING([for Linux futex() support])
 928   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 929 #ifndef _GNU_SOURCE
 930 #define _GNU_SOURCE
 931 #endif
 932 #include <unistd.h>
 933 #include <limits.h>
 934 #include <sys/time.h>
 935 #include <sys/syscall.h>
 936 #include <linux/futex.h>
 937
 938 int main(void);
 939 ],
 940 [
 941 {
 942   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 943 }
 944 ])], [
 945     AC_MSG_RESULT([yes])
 946     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 947     needsync=false
 948   ], [
 949     AC_MSG_RESULT([no])
 950   ])
 951 ])
 952
 953 AS_IF([$needsync], [
 954   dnl FreeBSD
 955   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 956   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 957 #include <errno.h>
 958 #include <stdlib.h>
 959 #include <sys/types.h>
 960 #include <sys/umtx.h>
 961 int main(void);
 962 ],
 963 [
 964 {
 965   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
 966 }
 967 ])], [
 968     AC_MSG_RESULT([yes])
 969     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
 970     needsync=false
 971   ], [
 972     AC_MSG_RESULT([no])
 973   ])
 974 ])
 975
 976 AS_IF([$needsync], [
 977   dnl OpenBSD patch (not upstream at the time of writing this)
 978   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
 979   AC_MSG_CHECKING([for OpenBSD futex() support])
 980   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 981 #include <sys/futex.h>
 982 int main(void);
 983 ],
 984 [
 985 {
 986   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 987 }
 988 ])], [
 989     AC_MSG_RESULT([yes])
 990     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
 991     needsync=false
 992   ], [
 993     AC_MSG_RESULT([no])
 994   ])
 995 ])
 996
 997 dnl Utility macro to avoid retyping includes all the time
 998 m4_define([FRR_INCLUDES],
 999 [#ifdef SUNOS_5
1000 #define _POSIX_C_SOURCE 200809L
1001 #define __EXTENSIONS__
1002 #endif
1003 #include <stdio.h>
1004 #include <stdlib.h>
1005 #include <stddef.h>
1006 #include <sys/types.h>
1007 /* sys/conf.h depends on param.h on FBSD at least */
1008 #include <sys/param.h>
1009 /* Required for MAXSIG */
1010 #include <signal.h>
1011 #include <sys/socket.h>
1012 #ifdef __APPLE__
1013 # define __APPLE_USE_RFC_3542
1014 #endif
1015 #include <netinet/in.h>
1016 #include <sys/time.h>
1017 #include <time.h>
1018 #include <net/if.h>
1019 ])dnl
1020
1021 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1022 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1023 dnl an additional round for it.
1024
1025 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1026
1027 m4_define([FRR_INCLUDES],
1028 FRR_INCLUDES
1029 [#if HAVE_NET_IF_VAR_H
1030 # include <net/if_var.h>
1031 #endif
1032 ])dnl
1033
1034 AC_CHECK_HEADERS([netinet/in_var.h \
1035         net/if_dl.h net/netopt.h \
1036         inet/nd.h netinet/ip_icmp.h \
1037         sys/sysctl.h sys/sockio.h sys/conf.h],
1038         [], [], [FRR_INCLUDES])
1039
1040 AC_CHECK_HEADERS([ucontext.h], [], [],
1041 [#ifndef __USE_GNU
1042 #define __USE_GNU
1043 #endif /* __USE_GNU */
1044 FRR_INCLUDES
1045 ])
1046
1047 m4_define([UCONTEXT_INCLUDES],
1048 [#include <ucontext.h>])dnl
1049
1050 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1051   [], [], [UCONTEXT_INCLUDES])
1052 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1053   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1054    [], [], [UCONTEXT_INCLUDES])],
1055   [], [UCONTEXT_INCLUDES])
1056 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1057   [], [], [UCONTEXT_INCLUDES])
1058
1059 m4_define([FRR_INCLUDES],
1060 FRR_INCLUDES
1061 [
1062 #include <sys/un.h>
1063 #include <netinet/in_systm.h>
1064 #if HAVE_NETINET_IN_VAR_H
1065 # include <netinet/in_var.h>
1066 #endif
1067 #if HAVE_NET_IF_DL_H
1068 # include <net/if_dl.h>
1069 #endif
1070 #if HAVE_NET_NETOPT_H
1071 # include <net/netopt.h>
1072 #endif
1073 #include <net/route.h>
1074 #if HAVE_INET_ND_H
1075 # include <inet/nd.h>
1076 #endif
1077 #include <arpa/inet.h>
1078 /* Required for IDRP */
1079 #if HAVE_NETINET_IP_ICMP_H
1080 # include <netinet/ip_icmp.h>
1081 #endif
1082 ])dnl
1083
1084 dnl V6 headers are checked below, after we check for v6
1085
1086 is_linux=false
1087
1088 AC_MSG_CHECKING([which operating system interface to use])
1089 case "$host_os" in
1090   sunos* | solaris2*)
1091     AC_MSG_RESULT([Solaris])
1092
1093     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1094     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1095     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1096
1097     AC_CHECK_LIB([socket], [main])
1098     AC_CHECK_LIB([nsl], [main])
1099     AC_CHECK_LIB([umem], [main])
1100     SOLARIS="solaris"
1101     AC_MSG_WARN([--Solaris support is being considered for deprecation, please let us know if you are still using this--])
1102     ;;
1103   linux*)
1104     AC_MSG_RESULT([Linux])
1105
1106     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1107     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1108     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1109
1110     dnl Linux has a compilation problem with mixing
1111     dnl netinet/in.h and linux/in6.h they are not
1112     dnl compatible.  There has been discussion on
1113     dnl how to fix it but no real progress on implementation
1114     dnl when they fix it, remove this
1115     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1116
1117     is_linux=true
1118     ;;
1119   openbsd*)
1120     AC_MSG_RESULT([OpenBSD])
1121
1122     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1123     AC_DEFINE([KAME], [1], [KAME IPv6])
1124     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1125
1126     if test "x${enable_pimd}" != "xno"; then
1127       case "$host_os" in
1128       openbsd6.0)
1129         ;;
1130       openbsd[6-9]*)
1131         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1132         ;;
1133       esac
1134     fi
1135     ;;
1136   *)
1137     AC_MSG_RESULT([BSD])
1138
1139     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1140     AC_DEFINE([KAME], [1], [KAME IPv6])
1141     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1142     ;;
1143 esac
1144 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1145 AM_CONDITIONAL([LINUX], [${is_linux}])
1146
1147 AC_SYS_LARGEFILE
1148
1149 dnl ------------------------
1150 dnl Integrated REALMS option
1151 dnl ------------------------
1152 if test "${enable_realms}" = "yes"; then
1153     case "$host_os" in
1154       linux*)
1155        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1156        ;;
1157       *)
1158        echo "Sorry, only Linux has REALMS support"
1159        exit 1
1160        ;;
1161     esac
1162 fi
1163
1164 dnl -------------------------------
1165 dnl Endian-ness check
1166 dnl -------------------------------
1167 AC_WORDS_BIGENDIAN
1168
1169 dnl ---------------
1170 dnl other functions
1171 dnl ---------------
1172 AC_CHECK_FUNCS([ \
1173         strlcat strlcpy \
1174         getgrouplist])
1175
1176 dnl ##########################################################################
1177 dnl LARGE if block spans a lot of "configure"!
1178 if test "${enable_clippy_only}" != "yes"; then
1179 dnl ##########################################################################
1180
1181 #
1182 # Logic for protobuf support.
1183 #
1184 PROTO3=false
1185 if test "$enable_protobuf" = "yes"; then
1186   # Check for protoc & protoc-c
1187
1188   # protoc is not required, it's only for a "be nice" helper target
1189   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1190
1191   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1192   if test "$PROTOC_C" = "/bin/false"; then
1193     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1194   fi
1195
1196   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1197     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1198   ])
1199
1200   PROTO3=true
1201   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1202                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1203                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1204                                             [1], [Have Protobuf version 3]),
1205                                   [PROTO3=false],
1206                                   [#include <google/protobuf-c/protobuf-c.h>])],
1207                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1208
1209   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1210 fi
1211
1212
1213 dnl ---------------------
1214 dnl Integrated VTY option
1215 dnl ---------------------
1216 case "${enable_vtysh}" in
1217 "no")
1218   VTYSH="";;
1219 *)
1220   VTYSH="vtysh";
1221   AC_DEFINE([VTYSH], [1], [VTY shell])
1222
1223   prev_libs="$LIBS"
1224   AC_CHECK_LIB([readline], [main], [
1225     LIBREADLINE="-lreadline"
1226   ], [
1227     dnl readline failed - it might be incorrectly linked and missing its
1228     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1229     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1230       LIBREADLINE="$ac_cv_search_tputs"
1231     ], [
1232       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1233     ])
1234
1235     dnl re-try with the lib we found above
1236     unset ac_cv_lib_readline_main
1237     AC_CHECK_LIB([readline], [main], [
1238       LIBREADLINE="-lreadline $LIBREADLINE"
1239     ], [
1240       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1241     ], [$LIBREADLINE])
1242   ], [])
1243   LIBS="$prev_libs"
1244
1245   AC_CHECK_HEADER([readline/history.h])
1246   if test $ac_cv_header_readline_history_h = no;then
1247     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1248   fi
1249   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1250   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1251     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1252   fi
1253   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1254   if test "$frr_cv_append_history" = yes; then
1255     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1256   fi
1257   ;;
1258 esac
1259 AC_SUBST([LIBREADLINE])
1260
1261 dnl ----------
1262 dnl PAM module
1263 dnl
1264 dnl FRR detects the PAM library it is built against by checking for a
1265 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1266 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1267 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1268 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1269 dnl of OpenPAM.
1270 dnl ----------
1271 if test "$with_libpam" = "yes"; then
1272   AC_CHECK_HEADER([security/pam_misc.h],
1273     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1274      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1275      pam_conv_func="misc_conv"
1276     ],
1277     [], FRR_INCLUDES)
1278   AC_CHECK_HEADER([security/openpam.h],
1279     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1280      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1281      pam_conv_func="openpam_ttyconv"
1282     ],
1283     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1284   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1285     AC_MSG_WARN([*** pam support will not be built ***])
1286     with_libpam="no"
1287   fi
1288 fi
1289
1290 if test "$with_libpam" = "yes"; then
1291 dnl took this test from proftpds configure.in and suited to our needs
1292 dnl -------------------------------------------------------------------------
1293 dnl
1294 dnl This next check looks funky due to a linker problem with some versions
1295 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1296 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1297 dnl with RedHat 6.2 and Debian 2.2 or better.
1298 AC_CHECK_LIB([pam], [pam_start],
1299   [AC_CHECK_LIB([pam], [$pam_conv_func],
1300     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1301      LIBPAM="-lpam"],
1302     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1303      LIBPAM="-lpam -lpam_misc"]
1304     )
1305   ],
1306
1307   [AC_CHECK_LIB([pam], [pam_end],
1308     [AC_CHECK_LIB([pam], [$pam_conv_func],
1309       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1310        LIBPAM="-lpam -ldl"],
1311       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1312        LIBPAM="-lpam -ldl -lpam_misc"]
1313      )
1314   ],AC_MSG_WARN([*** pam support will not be built ***]),
1315   [-ldl])
1316   ]
1317 )
1318 fi
1319 AC_SUBST([LIBPAM])
1320
1321 dnl -------------------------------
1322 dnl bgpd needs pow() and hence libm
1323 dnl -------------------------------
1324 TMPLIBS="$LIBS"
1325 LIBS=""
1326 AC_SEARCH_LIBS([pow], [m], [
1327   LIBM="$LIBS"
1328 ], [
1329   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1330 ])
1331 LIBS="$TMPLIBS"
1332 AC_SUBST([LIBM])
1333
1334 AC_CHECK_FUNCS([ppoll], [
1335   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1336 ])
1337 AC_CHECK_FUNCS([pollts], [
1338   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1339 ])
1340
1341 AC_CHECK_HEADER([asm-generic/unistd.h],
1342                 [AC_CHECK_DECL(__NR_setns,
1343                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1344                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1345                                ])
1346                  AC_CHECK_FUNCS([setns])]
1347                )
1348
1349 dnl --------------------------
1350 dnl Determine IS-IS I/O method
1351 dnl --------------------------
1352 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1353 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1354 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1355 AC_CHECK_HEADER([net/bpf.h])
1356 AC_CHECK_HEADER([sys/dlpi.h])
1357 AC_MSG_CHECKING([zebra IS-IS I/O method])
1358
1359 case "$host_os" in
1360   linux*)
1361     AC_MSG_RESULT([pfpacket])
1362     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1363     ;;
1364   solaris* | sunos*)
1365     AC_MSG_RESULT([DLPI])
1366     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1367     ;;
1368   *)
1369     if test $ac_cv_header_net_bpf_h = no; then
1370       if test $ac_cv_header_sys_dlpi_h = no; then
1371         AC_MSG_RESULT([none])
1372         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1373           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1374         fi
1375         AC_MSG_WARN([*** IS-IS support will not be built ***])
1376         enable_isisd="no"
1377         enable_fabricd="no"
1378       else
1379         AC_MSG_RESULT([DLPI])
1380       fi
1381       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1382     else
1383       AC_MSG_RESULT([BPF])
1384       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1385     fi
1386     ;;
1387 esac
1388 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1389
1390 dnl ---------------------------------------------------------------
1391 dnl figure out how to specify an interface in multicast sockets API
1392 dnl ---------------------------------------------------------------
1393 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1394
1395 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1396         #include <sys/socket.h>
1397         #include <netinet/in.h>
1398         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1399         #include <linux/types.h>
1400 ])
1401
1402 m4_define([FRR_INCLUDES],
1403 FRR_INCLUDES
1404 [#if HAVE_LINUX_MROUTE_H
1405 # include <linux/mroute.h>
1406 #endif
1407 ])dnl
1408
1409 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1410         #include <sys/socket.h>
1411         #include <sys/types.h>
1412         #include <netinet/in.h>
1413         #include <net/route.h>
1414 ])
1415
1416 m4_define([FRR_INCLUDES],
1417 FRR_INCLUDES
1418 [#if HAVE_NETINET_IP_MROUTE_H
1419 # include <netinet/ip_mroute.h>
1420 #endif
1421 ])dnl
1422
1423 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1424 AC_TRY_COMPILE([#include <sys/param.h>],
1425 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1426   return (0);
1427 #else
1428   #error No support for BSD struct ip_mreq hack detected
1429 #endif],[AC_MSG_RESULT([yes])
1430 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1431 AC_MSG_RESULT([no]))
1432
1433 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1434 AC_TRY_COMPILE([
1435 #include <sys/types.h>
1436 #include <netinet/in.h>
1437 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1438 ], [AC_MSG_RESULT([yes])
1439 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1440 AC_MSG_RESULT([no]))
1441
1442 dnl ---------------------------------------------------------------
1443 dnl figure out how to check link-state
1444 dnl ---------------------------------------------------------------
1445 AC_CHECK_HEADER([net/if_media.h],
1446   [m4_define([LINK_DETECT_INCLUDES],
1447     FRR_INCLUDES
1448     [#include <net/if_media.h>
1449   ])
1450   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1451     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1452     [], LINK_DETECT_INCLUDES)],
1453   [],
1454   FRR_INCLUDES)
1455
1456 dnl ---------------------------------------------------------------
1457 dnl Additional, newer way to check link-state using ifi_link_state.
1458 dnl Not available in all BSD's when ifmediareq available
1459 dnl ---------------------------------------------------------------
1460 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1461   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1462   [], FRR_INCLUDES)
1463
1464 dnl ------------------------
1465 dnl TCP_MD5SIG socket option
1466 dnl ------------------------
1467
1468 AC_CHECK_HEADER([netinet/tcp.h],
1469    [m4_define([MD5_INCLUDES],
1470       FRR_INCLUDES
1471       [#include <netinet/tcp.h>
1472     ])
1473     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1474    [],
1475    FRR_INCLUDES)
1476 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1477   AC_CHECK_HEADER([linux/tcp.h],
1478        [m4_define([MD5_INCLUDES],
1479           FRR_INCLUDES
1480           [#include <linux/tcp.h>
1481         ])
1482        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1483 fi
1484
1485 AC_SUBST([SOLARIS])
1486 AC_CHECK_LIB([crypt], [crypt], [],
1487                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1488 AC_CHECK_LIB([resolv], [res_init])
1489
1490 dnl ---------------------------
1491 dnl check system has PCRE regexp
1492 dnl ---------------------------
1493 if test "x$enable_pcreposix" = "xyes"; then
1494   AC_CHECK_LIB([pcreposix], [regexec], [], [
1495     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1496   ])
1497 fi
1498 AC_SUBST([HAVE_LIBPCREPOSIX])
1499
1500 dnl ##########################################################################
1501 dnl test "${enable_clippy_only}" != "yes"
1502 fi
1503 dnl END OF LARGE if block
1504 dnl ##########################################################################
1505
1506 dnl ------------------
1507 dnl check C-Ares library
1508 dnl ------------------
1509 PKG_CHECK_MODULES([CARES], [libcares], [
1510   c_ares_found=true
1511 ],[
1512   c_ares_found=false
1513 ])
1514 AM_CONDITIONAL([CARES], [$c_ares_found])
1515
1516
1517 dnl ----------------------------------------------------------------------------
1518 dnl figure out if domainname is available in the utsname struct (GNU extension).
1519 dnl ----------------------------------------------------------------------------
1520 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1521
1522 dnl ------------------
1523 dnl IPv6 header checks
1524 dnl ------------------
1525 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1526         netinet6/in6_var.h netinet6/nd6.h], [], [],
1527         FRR_INCLUDES)
1528
1529 m4_define([FRR_INCLUDES],dnl
1530 FRR_INCLUDES
1531 [#if HAVE_NETINET6_IN6_H
1532 #include <netinet6/in6.h>
1533 #endif
1534 #if HAVE_NETINET_IN6_VAR_H
1535 #include <netinet/in6_var.h>
1536 #endif
1537 #include <netinet/icmp6.h>
1538 #if HAVE_NETINET6_IN6_VAR_H
1539 # include <netinet6/in6_var.h>
1540 #endif
1541 #if HAVE_NETINET6_ND6_H
1542 # include <netinet6/nd6.h>
1543 #endif
1544 ])dnl
1545
1546 dnl --------------------
1547 dnl Daemon disable check
1548 dnl --------------------
1549
1550 AS_IF([test "${enable_ldpd}" != "no"], [
1551   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1552 ])
1553
1554 if test "$enable_bfdd" = "no"; then
1555   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1556   BFDD=""
1557 else
1558   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1559   BFDD="bfdd"
1560
1561   case $host_os in
1562     linux*)
1563       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1564       ;;
1565
1566     *)
1567       AC_DEFINE([BFD_BSD], [1], [bfdd])
1568       ;;
1569   esac
1570 fi
1571
1572 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1573   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1574 fi
1575
1576 NHRPD=""
1577 case "$host_os" in
1578   linux*)
1579     case "${enable_nhrpd}" in
1580       no)
1581         ;;
1582       yes)
1583         if test "${enable_clippy_only}" != "yes"; then
1584         if test "$c_ares_found" != "true" ; then
1585           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1586         fi
1587         fi
1588         NHRPD="nhrpd"
1589         ;;
1590       *)
1591         if test "$c_ares_found" = "true" ; then
1592           NHRPD="nhrpd"
1593         fi
1594         ;;
1595     esac
1596     ;;
1597   *)
1598     if test "${enable_nhrpd}" = "yes"; then
1599       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1600     fi
1601     ;;
1602 esac
1603
1604 if test "${enable_watchfrr}" = "no";then
1605   WATCHFRR=""
1606 else
1607   WATCHFRR="watchfrr"
1608 fi
1609
1610 OSPFCLIENT=""
1611 if test "${enable_ospfapi}" != "no";then
1612     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1613
1614   if test "${enable_ospfclient}" != "no";then
1615       OSPFCLIENT="ospfclient"
1616   fi
1617 fi
1618
1619 if test "${enable_bgp_announce}" = "no";then
1620   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1621 else
1622   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1623 fi
1624
1625 if test "${enable_bgp_vnc}" != "no";then
1626   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1627 fi
1628
1629 bgpd_bmp=false
1630 case "${enable_bmp}" in
1631   no)
1632     ;;
1633   yes)
1634     if test "$c_ares_found" != "true" ; then
1635       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1636     fi
1637     bgpd_bmp=true
1638     ;;
1639   *)
1640     if test "$c_ares_found" = "true" ; then
1641       bgpd_bmp=true
1642     fi
1643     ;;
1644 esac
1645
1646 dnl ##########################################################################
1647 dnl LARGE if block
1648 if test "${enable_clippy_only}" != "yes"; then
1649 dnl ##########################################################################
1650
1651 dnl ------------------
1652 dnl check Net-SNMP library
1653 dnl ------------------
1654 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1655    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1656    if test x"$NETSNMP_CONFIG" = x"no"; then
1657       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1658    fi
1659    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1660    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1661    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1662    # among other things we avoid a GPL vs. OpenSSL license conflict here
1663    for removelib in crypto ssl sensors pci wrap; do
1664      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1665    done
1666    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1667    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1668 int main(void);
1669 ],
1670 [
1671 {
1672   return 0;
1673 }
1674 ])], [
1675      AC_MSG_RESULT([no])
1676      AC_MSG_ERROR([--enable-snmp given but not usable])])
1677    case "${enable_snmp}" in
1678      yes)
1679       SNMP_METHOD=agentx
1680       ;;
1681      agentx)
1682       SNMP_METHOD="${enable_snmp}"
1683       ;;
1684      *)
1685       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1686       ;;
1687    esac
1688    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1689    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1690 fi
1691 AC_SUBST([SNMP_LIBS])
1692 AC_SUBST([SNMP_CFLAGS])
1693
1694 dnl ---------------
1695 dnl libyang
1696 dnl ---------------
1697 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.105], , [
1698   AC_MSG_ERROR([libyang (>= 0.16.105) was not found on your system.])
1699 ])
1700 ac_cflags_save="$CFLAGS"
1701 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1702 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1703   AC_MSG_ERROR([m4_normalize([
1704     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1705     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1706   ])
1707 ], [[#include <libyang/libyang.h>]])
1708 CFLAGS="$ac_cflags_save"
1709
1710 dnl ---------------
1711 dnl configuration rollbacks
1712 dnl ---------------
1713 SQLITE3=false
1714 if test "$enable_config_rollbacks" = "yes"; then
1715   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1716     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1717     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1718     SQLITE3=true
1719   ], [
1720     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1721   ])
1722 fi
1723
1724 dnl ---------------
1725 dnl confd
1726 dnl ---------------
1727 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1728    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1729    if test "x$CONFD" = "x/bin/false"; then
1730       AC_MSG_ERROR([confd was not found on your system.])]
1731    fi
1732    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1733    AC_SUBST([CONFD_CFLAGS])
1734    CONFD_LIBS="-lconfd"
1735    AC_SUBST([CONFD_LIBS])
1736    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1737 fi
1738
1739 dnl ---------------
1740 dnl sysrepo
1741 dnl ---------------
1742 if test "$enable_sysrepo" = "yes"; then
1743   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1744       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1745       SYSREPO=true],
1746       [SYSREPO=false
1747       AC_MSG_ERROR([sysrepo was not found on your system.])]
1748   )
1749 fi
1750
1751 dnl ---------------
1752 dnl gRPC
1753 dnl ---------------
1754 if test "$enable_grpc" = "yes"; then
1755   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1756     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1757     if test "$PROTOC" = "/bin/false"; then
1758       AC_MSG_FAILURE([grpc requested but protoc not found.])
1759     fi
1760
1761     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1762     GRPC=true
1763   ], [
1764     GRPC=false
1765     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1766   ])
1767 fi
1768
1769 dnl ------
1770 dnl ZeroMQ
1771 dnl ------
1772 if test "x$enable_zeromq" != "xno"; then
1773   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1774     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1775     ZEROMQ=true
1776   ], [
1777     if test "x$enable_zeromq" = "xyes"; then
1778       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1779     fi
1780   ])
1781 fi
1782
1783 dnl ------------------------------------
1784 dnl Enable RPKI and add librtr to libs
1785 dnl ------------------------------------
1786 if test "${enable_rpki}" = "yes"; then
1787   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1788       [RPKI=true],
1789       [RPKI=false
1790       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1791   )
1792 fi
1793
1794 dnl ------------------------------------------
1795 dnl Check whether rtrlib was build with ssh support
1796 dnl ------------------------------------------
1797 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1798 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1799                         [[struct tr_ssh_config config;]])],
1800         [AC_MSG_RESULT([yes])
1801         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1802         AC_MSG_RESULT([no])
1803 )
1804
1805 dnl ---------------
1806 dnl dlopen & dlinfo
1807 dnl ---------------
1808 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1809   AC_MSG_ERROR([unable to find the dlopen()])
1810 ])
1811
1812 AC_CHECK_HEADERS([link.h])
1813
1814 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1815   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1816 #include <stdlib.h>
1817 #ifdef HAVE_LINK_H
1818 #include <link.h>
1819 #endif
1820 #include <dlfcn.h>
1821 ]], [[
1822   char origin[1];
1823   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1824 ]])], [
1825     frr_cv_rtld_di_origin=yes
1826   ], [
1827     frr_cv_rtld_di_origin=no
1828   ])
1829 ])
1830 if test "$frr_cv_rtld_di_origin" = yes; then
1831   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1832 fi
1833
1834 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1835   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1836 #include <stdlib.h>
1837 #ifdef HAVE_LINK_H
1838 #include <link.h>
1839 #endif
1840 #include <dlfcn.h>
1841 ]], [[
1842   struct link_map *lm = NULL;
1843   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1844 ]])], [
1845     frr_cv_rtld_di_linkmap=yes
1846   ], [
1847     frr_cv_rtld_di_linkmap=no
1848   ])
1849 ])
1850 if test "$frr_cv_rtld_di_linkmap" = yes; then
1851   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1852 fi
1853
1854 dnl ##########################################################################
1855 dnl test "${enable_clippy_only}" != "yes"
1856 fi
1857 dnl END OF LARGE if block
1858 dnl ##########################################################################
1859
1860 dnl ---------------------------
1861 dnl sockaddr and netinet checks
1862 dnl ---------------------------
1863 AC_CHECK_TYPES([
1864         struct sockaddr_dl,
1865         struct vifctl, struct mfcctl, struct sioc_sg_req,
1866         vifi_t, struct sioc_vif_req, struct igmpmsg,
1867         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1868         struct nd_opt_adv_interval,
1869         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1870         struct nd_opt_rdnss, struct nd_opt_dnssl],
1871         [], [], FRR_INCLUDES)
1872
1873 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1874         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1875         struct sockaddr_dl.sdl_len,
1876         struct if6_aliasreq.ifra_lifetime,
1877         struct nd_opt_adv_interval.nd_opt_ai_type],
1878         [], [], FRR_INCLUDES)
1879
1880 dnl ---------------------------
1881 dnl IRDP/pktinfo/icmphdr checks
1882 dnl ---------------------------
1883
1884 AC_CHECK_TYPES([struct in_pktinfo], [
1885   AC_CHECK_TYPES([struct icmphdr], [
1886     IRDP=true
1887   ], [
1888     IRDP=false
1889   ], [FRR_INCLUDES])
1890 ], [
1891   IRDP=false
1892 ], [FRR_INCLUDES])
1893
1894 case "${enable_irdp}" in
1895 yes)
1896   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1897   ;;
1898 no)
1899   IRDP=false
1900   ;;
1901 esac
1902
1903
1904 dnl -----------------------
1905 dnl checking for IP_PKTINFO
1906 dnl -----------------------
1907 AC_MSG_CHECKING([for IP_PKTINFO])
1908 AC_TRY_COMPILE([#include <netdb.h>], [
1909   int opt = IP_PKTINFO;
1910 ], [
1911   AC_MSG_RESULT([yes])
1912   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1913 ], [
1914   AC_MSG_RESULT([no])
1915 ])
1916
1917 dnl ---------------------------
1918 dnl checking for IP_RECVDSTADDR
1919 dnl ---------------------------
1920 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1921 AC_TRY_COMPILE([#include <netinet/in.h>], [
1922   int opt = IP_RECVDSTADDR;
1923 ], [
1924   AC_MSG_RESULT([yes])
1925   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1926 ], [
1927   AC_MSG_RESULT([no])
1928 ])
1929
1930 dnl ----------------------
1931 dnl checking for IP_RECVIF
1932 dnl ----------------------
1933 AC_MSG_CHECKING([for IP_RECVIF])
1934 AC_TRY_COMPILE([#include <netinet/in.h>], [
1935   int opt = IP_RECVIF;
1936 ], [
1937   AC_MSG_RESULT([yes])
1938   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1939 ], [
1940   AC_MSG_RESULT([no])
1941 ])
1942
1943 dnl ----------------------
1944 dnl checking for SO_BINDANY
1945 dnl ----------------------
1946 AC_MSG_CHECKING([for SO_BINDANY])
1947 AC_TRY_COMPILE([#include <sys/socket.h>], [
1948   int opt = SO_BINDANY;
1949 ], [
1950   AC_MSG_RESULT([yes])
1951   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1952 ], [
1953   AC_MSG_RESULT([no])
1954 ])
1955
1956 dnl ----------------------
1957 dnl checking for IP_FREEBIND
1958 dnl ----------------------
1959 AC_MSG_CHECKING([for IP_FREEBIND])
1960 AC_TRY_COMPILE([#include <netinet/in.h>], [
1961   int opt = IP_FREEBIND;
1962 ], [
1963   AC_MSG_RESULT([yes])
1964   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1965 ], [
1966   AC_MSG_RESULT([no])
1967 ])
1968
1969 dnl --------------------------------------
1970 dnl checking for be32dec existence or not
1971 dnl --------------------------------------
1972 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1973                [#include <sys/endian.h>])
1974
1975 dnl --------------------------------------
1976 dnl checking for clock_time monotonic struct and call
1977 dnl --------------------------------------
1978 AC_CHECK_DECL([CLOCK_MONOTONIC],
1979         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1980          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1981 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1982
1983 dnl --------------------------------------
1984 dnl checking for flex and bison
1985 dnl --------------------------------------
1986
1987 AM_PROG_LEX
1988 AC_MSG_CHECKING([version of flex])
1989 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1990 frr_ac_flex_version="${frr_ac_flex_version##* }"
1991 AC_MSG_RESULT([$frr_ac_flex_version])
1992 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1993   LEX="$SHELL $missing_dir/missing flex"
1994   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1995     AC_MSG_WARN([using pregenerated flex output files])
1996   else
1997     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1998   fi
1999   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2000   AC_SUBST([LEXLIB], [''])
2001 ])
2002
2003 AC_PROG_YACC
2004 dnl thanks GNU bison for this b*llshit...
2005 AC_MSG_CHECKING([version of bison])
2006 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2007 frr_ac_bison_version="${frr_ac_bison_version##* }"
2008 frr_ac_bison_missing="false"
2009 case "x${frr_ac_bison_version}x" in
2010   x2.7*)
2011     BISON_OPENBRACE='"'
2012     BISON_CLOSEBRACE='"'
2013     BISON_VERBOSE=''
2014     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2015     ;;
2016   x2.*|x1.*)
2017     AC_MSG_RESULT([$frr_ac_bison_version])
2018     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2019     frr_ac_bison_missing="true"
2020     ;;
2021   x)
2022     AC_MSG_RESULT([none])
2023     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2024     frr_ac_bison_missing="true"
2025     ;;
2026   x3.[012][^0-9]*)
2027     BISON_OPENBRACE='{'
2028     BISON_CLOSEBRACE='}'
2029     BISON_VERBOSE='-Dparse.error=verbose'
2030     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2031     ;;
2032   *)
2033     BISON_OPENBRACE='{'
2034     BISON_CLOSEBRACE='}'
2035     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2036     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2037     ;;
2038 esac
2039 AC_SUBST([BISON_OPENBRACE])
2040 AC_SUBST([BISON_CLOSEBRACE])
2041 AC_SUBST([BISON_VERBOSE])
2042
2043 if $frr_ac_bison_missing; then
2044   YACC="$SHELL $missing_dir/missing bison -y"
2045   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2046     AC_MSG_WARN([using pregenerated bison output files])
2047   else
2048     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2049   fi
2050 fi
2051
2052 dnl -------------------
2053 dnl capabilities checks
2054 dnl -------------------
2055 if test "${enable_capabilities}" != "no"; then
2056   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2057   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2058     [AC_MSG_RESULT([yes])
2059      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2060      frr_ac_keepcaps="yes"],
2061      AC_MSG_RESULT([no])
2062   )
2063   if test x"${frr_ac_keepcaps}" = x"yes"; then
2064     AC_CHECK_HEADERS([sys/capability.h])
2065   fi
2066   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
2067     AC_CHECK_LIB([cap], [cap_init],
2068       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2069        LIBCAP="-lcap"
2070        frr_ac_lcaps="yes"]
2071     )
2072   else
2073     AC_CHECK_HEADERS([priv.h],
2074      [AC_MSG_CHECKING([Solaris style privileges are available])
2075       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
2076           [AC_MSG_RESULT([yes])
2077            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
2078            frr_ac_scaps="yes"],
2079            AC_MSG_RESULT(no)
2080       )
2081      ]
2082    )
2083   fi
2084   if test x"${frr_ac_scaps}" = x"yes" \
2085        -o x"${frr_ac_lcaps}" = x"yes"; then
2086     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2087   fi
2088
2089   case "$host_os" in
2090   linux*)
2091     if test "${enable_clippy_only}" != "yes"; then
2092     if test "$frr_ac_lcaps" != "yes"; then
2093       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2094     fi
2095     fi
2096     ;;
2097   esac
2098 else
2099   case "$host_os" in
2100   linux*)
2101     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2102     ;;
2103   esac
2104 fi
2105 AC_SUBST([LIBCAP])
2106
2107 dnl ---------------------------
2108 dnl check for glibc 'backtrace'
2109 dnl ---------------------------
2110 if test x"${enable_backtrace}" != x"no" ; then
2111   backtrace_ok=no
2112   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2113     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2114     backtrace_ok=yes
2115   ], [
2116     true
2117   ])
2118
2119   if test "$backtrace_ok" = "no"; then
2120     AC_CHECK_HEADER([unwind.h], [
2121       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2122         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2123         backtrace_ok=yes
2124       ])
2125     ])
2126   fi
2127
2128   if test "$backtrace_ok" = "no"; then
2129     case "$host_os" in
2130     sunos* | solaris2*)
2131       AC_CHECK_FUNCS([printstack], [
2132         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
2133         backtrace_ok=yes
2134       ])
2135       ;;
2136     esac
2137     if test "$backtrace_ok" = no; then
2138       AC_CHECK_HEADER([execinfo.h], [
2139         AC_SEARCH_LIBS([backtrace], [execinfo], [
2140           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2141           backtrace_ok=yes
2142         ],, [-lm])
2143       ])
2144     fi
2145   fi
2146
2147   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
2148     dnl user explicitly requested backtrace but we failed to find support
2149     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2150   fi
2151 fi
2152
2153 dnl -----------------------------------------
2154 dnl check for malloc mallinfo struct and call
2155 dnl this must try and link using LIBS, in
2156 dnl order to check no alternative allocator
2157 dnl has been specified, which might not provide
2158 dnl mallinfo, e.g. such as Umem on Solaris.
2159 dnl -----------------------------------------
2160 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2161
2162 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2163   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2164 #ifdef HAVE_MALLOC_H
2165 #include <malloc.h>
2166 #endif
2167 #ifdef HAVE_MALLOC_NP_H
2168 #include <malloc_np.h>
2169 #endif
2170 #ifdef HAVE_MALLOC_MALLOC_H
2171 #include <malloc/malloc.h>
2172 #endif
2173 ]], [[
2174 struct mallinfo ac_x; ac_x = mallinfo ();
2175 ]])], [
2176     frr_cv_mallinfo=yes
2177   ], [
2178     frr_cv_mallinfo=no
2179   ])
2180 ])
2181 if test "$frr_cv_mallinfo" = yes; then
2182   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2183 fi
2184
2185 AC_MSG_CHECKING([whether malloc_usable_size is available])
2186 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2187 #ifdef HAVE_MALLOC_H
2188 #include <malloc.h>
2189 #endif
2190 #ifdef HAVE_MALLOC_MALLOC_H
2191 #include <malloc/malloc.h>
2192 #endif
2193 ]], [[
2194 size_t ac_x; ac_x = malloc_usable_size(NULL);
2195 ]])], [
2196   AC_MSG_RESULT([yes])
2197   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2198 ], [
2199   AC_MSG_RESULT([no])
2200
2201   AC_MSG_CHECKING([whether malloc_size is available])
2202   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2203 #ifdef HAVE_MALLOC_H
2204 #include <malloc.h>
2205 #endif
2206 #ifdef HAVE_MALLOC_MALLOC_H
2207 #include <malloc/malloc.h>
2208 #endif
2209 ]], [[
2210 size_t ac_x; ac_x = malloc_size(NULL);
2211 ]])], [
2212     AC_MSG_RESULT([yes])
2213     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2214   ], [
2215     AC_MSG_RESULT([no])
2216   ])
2217 ])
2218
2219 dnl ----------
2220 dnl configure date
2221 dnl ----------
2222 dev_version=`echo $VERSION | grep dev`
2223 #don't expire deprecated code in non 'dev' branch
2224 if test "${dev_version}" = ""; then
2225    CONFDATE=0
2226 else
2227    CONFDATE=`date '+%Y%m%d'`
2228 fi
2229 AC_SUBST([CONFDATE])
2230
2231 dnl ------------------------------
2232 dnl set paths for state directory
2233 dnl ------------------------------
2234 AC_MSG_CHECKING([directory to use for state file])
2235 if test "${prefix}" = "NONE"; then
2236   frr_statedir_prefix="";
2237 else
2238   frr_statedir_prefix=${prefix}
2239 fi
2240 if test "${localstatedir}" = '${prefix}/var'; then
2241   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2242                         ${frr_statedir_prefix}/var/adm dnl
2243                         ${frr_statedir_prefix}/etc dnl
2244                         /var/run        dnl
2245                         /var/adm        dnl
2246                         /etc            dnl
2247                         /dev/null;
2248   do
2249     test -d $FRR_STATE_DIR && break
2250   done
2251   frr_statedir=$FRR_STATE_DIR
2252 else
2253   frr_statedir=${localstatedir}
2254 fi
2255 if test $frr_statedir = "/dev/null"; then
2256     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2257 fi
2258 AC_MSG_RESULT([${frr_statedir}])
2259 AC_SUBST([frr_statedir])
2260
2261 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2262 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2263 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2264 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2265 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2266
2267 dnl autoconf does this, but it does it too late...
2268 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2269 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2270
2271 dnl get the full path, recursing through variables...
2272 vtysh_bin="$bindir/vtysh"
2273 for I in 1 2 3 4 5 6 7 8 9 10; do
2274         eval vtysh_bin="\"$vtysh_bin\""
2275 done
2276 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2277 AC_SUBST([vtysh_bin])
2278
2279 CFG_SYSCONF="$sysconfdir"
2280 CFG_SBIN="$sbindir"
2281 CFG_STATE="$frr_statedir"
2282 CFG_MODULE="$moduledir"
2283 CFG_YANGMODELS="$yangmodelsdir"
2284 for I in 1 2 3 4 5 6 7 8 9 10; do
2285         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2286         eval CFG_SBIN="\"$CFG_SBIN\""
2287         eval CFG_STATE="\"$CFG_STATE\""
2288         eval CFG_MODULE="\"$CFG_MODULE\""
2289         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2290 done
2291 AC_SUBST([CFG_SYSCONF])
2292 AC_SUBST([CFG_SBIN])
2293 AC_SUBST([CFG_STATE])
2294 AC_SUBST([CFG_MODULE])
2295 AC_SUBST([CFG_YANGMODELS])
2296 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2297 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2298 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2299
2300 dnl various features
2301 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
2302 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
2303 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2304 dnl northbound
2305 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2306 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
2307 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
2308 AM_CONDITIONAL([GRPC], [test "x$enable_grpc" = "xyes"])
2309 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2310 dnl plugins
2311 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2312 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
2313 AM_CONDITIONAL([IRDP], [$IRDP])
2314 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
2315 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
2316 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2317 dnl daemons
2318 AM_CONDITIONAL([VTYSH], [test "x$VTYSH" = "xvtysh"])
2319 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
2320 AM_CONDITIONAL([BGPD], [test "x${enable_bgpd}" != "no"])
2321 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
2322 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
2323 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
2324 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
2325 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
2326 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
2327 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
2328 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
2329 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
2330 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
2331 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
2332 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
2333 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
2334 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
2335 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
2336 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
2337 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
2338 AM_CONDITIONAL([VRRPD], [test "${enable_vrrpd}" != "no"])
2339
2340 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2341
2342 AC_CONFIG_FILES([
2343           config.version
2344           changelog-auto
2345           redhat/frr.spec
2346           solaris/Makefile
2347           alpine/APKBUILD
2348           snapcraft/snapcraft.yaml
2349           lib/version.h
2350           tests/lib/cli/test_cli.refout
2351           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2352           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2353           pkgsrc/eigrpd.sh])
2354
2355 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2356 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2357 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2358 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2359 AC_CONFIG_FILES([tools/frrcommon.sh])
2360
2361 AC_CONFIG_COMMANDS([lib/route_types.h], [
2362         dst="${ac_abs_top_builddir}/lib/route_types.h"
2363         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2364                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2365                 > "${dst}.tmp"
2366         test -f "${dst}" \
2367                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2368                 && rm "${dst}.tmp" \
2369                 || mv "${dst}.tmp" "${dst}"
2370 ], [
2371         PERL="$PERL"
2372 ])
2373
2374 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2375     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2376         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2377         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2378                 "${ac_abs_top_srcdir}" \
2379                 > "${dst}.tmp"
2380         test -f "${dst}" \
2381                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2382                 && rm "${dst}.tmp" \
2383                 || mv "${dst}.tmp" "${dst}"
2384     ], [
2385         PERL="$PERL"
2386     ])
2387 ])
2388
2389 ## Hack, but working solution to avoid rebuilding of frr.info.
2390 ## It's already in CVS until texinfo 4.7 is more common.
2391 AC_OUTPUT
2392
2393 echo "
2394 FRRouting configuration
2395 ------------------------------
2396 FRR version             : ${PACKAGE_VERSION}
2397 host operating system   : ${host_os}
2398 source code location    : ${srcdir}
2399 compiler                : ${CC}
2400 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2401 make                    : ${MAKE-make}
2402 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2403 state file directory    : ${frr_statedir}
2404 config file directory   : `eval echo \`echo ${sysconfdir}\``
2405 example directory       : `eval echo \`echo ${exampledir}\``
2406 module directory        : ${CFG_MODULE}
2407 user to run as          : ${enable_user}
2408 group to run as         : ${enable_group}
2409 group for vty sockets   : ${enable_vty_group}
2410 config file mask        : ${enable_configfile_mask}
2411 log file mask           : ${enable_logfile_mask}
2412 zebra protobuf enabled  : ${enable_protobuf:-no}
2413
2414 The above user and group must have read/write access to the state file
2415 directory and to the config files in the config file directory."
2416
2417 if test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" = false; then
2418   AC_MSG_WARN([sphinx is missing but required to build documentation])
2419 fi
2420 if test "$frr_py_mod_pytest" = false; then
2421   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2422 fi