configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [8.4-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if necessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183
 184 dnl Some special handling for ICC later on
 185 if test "$CC" = "icc"; then
 186     cc_is_icc="yes"
 187 fi
 188
 189 PKG_PROG_PKG_CONFIG
 190
 191 dnl it's 2019, sed is sed.
 192 SED=sed
 193 AC_SUBST([SED])
 194
 195 dnl try and enable CFLAGS that are useful for FRR
 196 dnl - specifically, options to control warnings
 197
 198 AC_SUBST([AC_CFLAGS])
 199 AC_USE_SYSTEM_EXTENSIONS
 200 AC_DEFUN([AC_C_FLAG], [{
 201     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 202     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 203         AC_LANG_PUSH([C])
 204         ac_c_flag_save="$CFLAGS"
 205         CFLAGS="$CFLAGS $1"
 206         AC_COMPILE_IFELSE(
 207                 [AC_LANG_PROGRAM([[$4]])],
 208                 [
 209                         cachename=yes
 210                 ], [
 211                         cachename=no
 212                 ])
 213         CFLAGS="$ac_c_flag_save"
 214         AC_LANG_POP([C])
 215     ])
 216     if test "$cachename" = "yes"; then
 217         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 218     else
 219         :
 220         $2
 221     fi
 222     m4_popdef([cachename])
 223 }])
 224
 225 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 226         AC_LANG_PUSH([C])
 227         ac_cflags_save="$CFLAGS"
 228         ac_libs_save="$LIBS"
 229         CFLAGS="$CFLAGS $1"
 230         LIBS="$LIBS $2"
 231         AC_LINK_IFELSE(
 232                 [$3],
 233                 [
 234                         CFLAGS="$ac_cflags_save"
 235                         LIBS="$ac_libs_save"
 236                         m4_default([$5], [
 237                                 AC_MSG_RESULT([yes])
 238                         ])
 239                 ], [
 240                         CFLAGS="$ac_cflags_save"
 241                         LIBS="$ac_libs_save"
 242                         m4_default([$4], [
 243                                 AC_MSG_RESULT([no])
 244                         ])
 245                 ])
 246         AC_LANG_POP([C])
 247         }])
 248
 249 dnl ICC won't bail on unknown options without -diag-error 10006
 250 dnl need to do this first so we get useful results for the other options
 251 if test "$cc_is_icc" = "yes"; then
 252     AC_C_FLAG([-diag-error 10006])
 253 fi
 254
 255 dnl autoconf 2.69 AC_PROG_CC_C99 is "state of the art"
 256 dnl autoconf 2.70 AC_PROG_CC_C99 is deprecated and AC_PROC_CC tries to do C11
 257 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
 258   dnl autoconf < 2.70
 259   AC_PROG_CC_C99
 260
 261   dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 262   ac_cc="$CC"
 263   CC="${CC% -std=gnu99}"
 264   CC="${CC% -std=c99}"
 265
 266   AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 267 ], [
 268   dnl autoconf >= 2.70
 269   if test "$ac_cv_prog_cc_c11" = "no"; then
 270     AC_MSG_ERROR([ISO C11 compiler support (with GNU extensions) is required.])
 271   fi
 272 ])
 273
 274 dnl if the user has specified any CFLAGS, override our settings
 275 if test "$enable_gcov" = "yes"; then
 276    if test "$orig_cflags" = ""; then
 277       AC_C_FLAG([--coverage])
 278       AC_C_FLAG([-O0])
 279    fi
 280
 281    AC_LDFLAGS="${AC_LDFLAGS} --coverage"
 282 fi
 283
 284 if test "$enable_clang_coverage" = "yes"; then
 285    AC_C_FLAG([-fprofile-instr-generate], [
 286      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 287    ])
 288    AC_C_FLAG([-fcoverage-mapping], [
 289      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 290    ])
 291 fi
 292
 293 AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"])
 294
 295 if test "$enable_scripting" = "yes"; then
 296    AX_PROG_LUA([5.3], [5.4], [], [
 297      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 298    ])
 299    AX_LUA_HEADERS([], [
 300      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 301    ])
 302    AX_LUA_LIBS([
 303      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 304      LIBS="$LIBS $LUA_LIB"
 305      SCRIPTING=true
 306    ], [
 307      SCRIPTING=false
 308      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 309    ])
 310 fi
 311
 312 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 313 dnl sense to be overridden by the user
 314 if test "$enable_dev_build" = "yes"; then
 315    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 316    if test "$orig_cflags" = ""; then
 317       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 318       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 319       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 320    fi
 321 else
 322    if test "$orig_cflags" = ""; then
 323       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 324       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 325    fi
 326 fi
 327
 328 dnl just stick -g into LDFLAGS, if we don't have it in CFLAGS it won't do much
 329 LDFLAGS="$LDFLAGS -g"
 330
 331 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 332
 333 dnl -fms-extensions causes clang to have a built-in __wchar_t on OpenBSD,
 334 dnl which just straight up breaks compiling any code.
 335 dnl (2022-04-04 / OpenBSD 7 / clang 11.1.0)
 336 AH_VERBATIM([OpenBSD], [
 337 #ifdef __OpenBSD__
 338 #define __wchar_t __wchar_t_ignore
 339 #include <stdint.h>
 340 #undef __wchar_t
 341 #endif
 342 ])
 343
 344 dnl always want these CFLAGS
 345 AC_C_FLAG([-fms-extensions], [
 346   AC_MSG_ERROR([$CC does not support unnamed struct fields (-fms-extensions)])
 347 ])
 348 AC_C_FLAG([-fno-omit-frame-pointer])
 349 AC_C_FLAG([-funwind-tables])
 350 AC_C_FLAG([-Wall])
 351 AC_C_FLAG([-Wextra])
 352 AC_C_FLAG([-Wstrict-prototypes])
 353 AC_C_FLAG([-Wmissing-prototypes])
 354 AC_C_FLAG([-Wmissing-declarations])
 355 AC_C_FLAG([-Wpointer-arith])
 356 AC_C_FLAG([-Wbad-function-cast])
 357 AC_C_FLAG([-Wwrite-strings])
 358 AC_C_FLAG([-Wundef])
 359 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 360   AC_C_FLAG([-Wcast-qual])
 361   AC_C_FLAG([-Wmissing-noreturn])
 362   AC_C_FLAG([-Wmissing-format-attribute])
 363   AC_C_FLAG([-Wunreachable-code])
 364   AC_C_FLAG([-Wpacked])
 365   AC_C_FLAG([-Wpadded])
 366   AC_C_FLAG([-Wshadow])
 367 else
 368   AC_C_FLAG([-Wno-unused-result])
 369 fi
 370 AC_C_FLAG([-Wno-unused-parameter])
 371 AC_C_FLAG([-Wno-missing-field-initializers])
 372
 373 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 374 AC_SUBST([CXX_COMPAT_CFLAGS])
 375
 376 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 377 dnl for some reason the string consts get 'promoted' to char *,
 378 dnl triggering a const to non-const conversion warning.
 379 if test "$cc_is_icc" = "yes"; then
 380     AC_C_FLAG([-diag-disable 3179])
 381 fi
 382
 383 if test "$enable_werror" = "yes" ; then
 384   WERROR="-Werror"
 385 fi
 386 AC_SUBST([WERROR])
 387
 388 SAN_FLAGS=""
 389 if test "$enable_address_sanitizer" = "yes"; then
 390   AC_C_FLAG([-fsanitize=address], [
 391     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 392   ], [
 393     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 394   ])
 395 fi
 396 if test "$enable_thread_sanitizer" = "yes"; then
 397   AC_C_FLAG([-fsanitize=thread], [
 398     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 399   ], [
 400     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 401   ])
 402 fi
 403 if test "$enable_memory_sanitizer" = "yes"; then
 404   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 405     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 406   ], [
 407     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 408   ])
 409 fi
 410 if test "$enable_undefined_sanitizer" = "yes"; then
 411   AC_C_FLAG([-fsanitize=undefined], [
 412     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 413   ], [
 414     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 415   ])
 416 fi
 417 AC_SUBST([SAN_FLAGS])
 418
 419 dnl frr-format.so
 420 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 421   AC_C_FLAG([-fplugin=${with_frr_format}], [
 422     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 423   ],,[
 424 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 425 #error plugin not loaded
 426 #endif
 427 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 428 #error plugin too old
 429 #endif
 430   ])
 431 elif test "$with_frr_format" = "no"; then
 432   : #nothing
 433 else
 434   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 435     AC_C_FLAG([-fplugin=frr-format],[
 436       if test "$with_frr_format" = "yes"; then
 437         AC_MSG_ERROR([frr-format plugin requested but not found])
 438       fi
 439     ],,[
 440 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 441 #error plugin not loaded
 442 #endif
 443 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 444 #error plugin too old
 445 #endif
 446     ])
 447   ],,[
 448 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 449 #error plugin not loaded
 450 #endif
 451 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 452 #error plugin too old
 453 #endif
 454   ])
 455 fi
 456
 457 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 458 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 459 #include <stdio.h>
 460 int __attribute__((section("secttest"))) var = 1;
 461 extern int __start_secttest, __stop_secttest;
 462 ]], [[
 463   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 464   printf("%p %p %p\n", a, b, c);
 465 ]])], [
 466   AC_MSG_RESULT(yes)
 467   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 468 ], [
 469   AC_MSG_RESULT(no)
 470 ])
 471
 472 dnl ----------
 473 dnl Essentials
 474 dnl ----------
 475
 476 AX_PTHREAD([
 477   CC="$PTHREAD_CC"
 478   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 479   LIBS="$PTHREAD_LIBS $LIBS"
 480 ], [
 481   AC_MSG_FAILURE([This FRR version needs pthreads])
 482 ])
 483
 484 orig_cflags="$CFLAGS"
 485 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 486
 487 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 488                 [frr_cv_pthread_condattr_setclock=yes],
 489                 [frr_cv_pthread_condattr_setclock=no])
 490 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 491   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 492 fi
 493
 494 AC_CHECK_HEADERS([pthread_np.h],,, [
 495 #include <pthread.h>
 496 ])
 497 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 498
 499 CFLAGS="$orig_cflags"
 500
 501 dnl --------------
 502 dnl Check programs
 503 dnl --------------
 504 AC_PROG_INSTALL
 505 AC_PROG_LN_S
 506 AC_CHECK_TOOL([AR], [ar])
 507
 508 dnl -------
 509 dnl libtool
 510 dnl -------
 511 AC_ARG_ENABLE([static-bin],
 512   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 513 LT_INIT
 514 _LT_CONFIG_LIBTOOL([
 515   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 516     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 517 dnl the -i option is not POSIX sed and the BSDs implement it differently
 518 dnl cat'ing the output back instead of mv/cp keeps permissions on libtool intact
 519   sed -e 's%func_warning "relinking%true #\0%'                   libtool > libtool.sed && cat libtool.sed > libtool
 520   sed -e 's%func_warning "remember to run%true #\0%'             libtool > libtool.sed && cat libtool.sed > libtool
 521   sed -e 's%func_warning ".*has not been installed in%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool
 522   test -f libtool.sed && rm libtool.sed
 523 ])
 524 if test "$enable_static_bin" = "yes"; then
 525   AC_LDFLAGS_EXEC="-static"
 526   if test "$enable_static" != "yes"; then
 527     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 528   fi
 529 fi
 530 if test "$enable_shared" != "yes"; then
 531   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 532 fi
 533 AC_SUBST([AC_LDFLAGS])
 534 AC_SUBST([AC_LDFLAGS_EXEC])
 535 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 536
 537 dnl libtool, the repository of all knowledge related linkers, is too stupid to
 538 dnl correctly tell the linker how to build modules.
 539 if test -z "$module_cmds"; then
 540   module_cmds="`echo \"$archive_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 541 fi
 542 if test -z "$module_expsym_cmds"; then
 543   module_expsym_cmds="`echo \"$archive_expsym_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 544 fi
 545
 546 AC_ARG_ENABLE([rpath],
 547   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 548   [],
 549   [enable_rpath=yes])
 550
 551 dnl $AR and $RANLIB are set by LT_INIT above
 552 AC_MSG_CHECKING([whether $AR supports D option])
 553 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 554   AC_MSG_RESULT([yes])
 555   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 556   ARFLAGS="crD"
 557   AR_FLAGS="crD"
 558 else
 559   AC_MSG_RESULT([no])
 560   ARFLAGS="cru"
 561   AR_FLAGS="cru"
 562 fi
 563 AC_SUBST([ARFLAGS])
 564 AC_SUBST([AR_FLAGS])
 565
 566 AC_MSG_CHECKING([whether $RANLIB supports D option])
 567 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 568   if grep -q -- '-D' conftest.err; then
 569     AC_MSG_RESULT([no])
 570   else
 571     AC_MSG_RESULT([yes])
 572     RANLIB="$RANLIB -D"
 573   fi
 574 else
 575   AC_MSG_RESULT([no])
 576 fi
 577 AC_SUBST([RANLIB])
 578
 579 test -f conftest.err && rm conftest.err
 580 test -f conftest.a && rm conftest.a
 581
 582 dnl ----------------------
 583 dnl Packages configuration
 584 dnl ----------------------
 585 if test -f config.version; then
 586   . ./config.version
 587 elif test -f "${srcdir}/config.version"; then
 588   . "${srcdir}/config.version"
 589 fi
 590 AC_ARG_WITH([pkg-extra-version],
 591   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 592   if test "$withval" = "no"; then
 593     EXTRAVERSION=
 594   else
 595     EXTRAVERSION=$withval
 596   fi
 597 ], [])
 598 AC_ARG_WITH([pkg-git-version],
 599         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 600         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 601 AC_ARG_WITH([clippy],
 602   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 603 AC_ARG_WITH([vtysh_pager],
 604         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 605         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 606 AC_ARG_ENABLE([vtysh],
 607   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 608 AC_ARG_ENABLE([doc],
 609   AS_HELP_STRING([--disable-doc], [do not build docs]))
 610 AC_ARG_ENABLE([doc-html],
 611   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 612 AC_ARG_ENABLE([zebra],
 613   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 614 AC_ARG_ENABLE([bgpd],
 615   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 616 AC_ARG_ENABLE([ripd],
 617   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 618 AC_ARG_ENABLE([ripngd],
 619   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 620 AC_ARG_ENABLE([ospfd],
 621   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 622 AC_ARG_ENABLE([ospf6d],
 623   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 624 AC_ARG_ENABLE([ldpd],
 625   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 626 AC_ARG_ENABLE([nhrpd],
 627   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 628 AC_ARG_ENABLE([eigrpd],
 629   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 630 AC_ARG_ENABLE([babeld],
 631   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 632 AC_ARG_ENABLE([watchfrr],
 633   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 634 AC_ARG_ENABLE([isisd],
 635   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 636 AC_ARG_ENABLE([pimd],
 637   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 638 AC_ARG_ENABLE([pbrd],
 639   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 640 AC_ARG_ENABLE([sharpd],
 641   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 642 AC_ARG_ENABLE([staticd],
 643   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 644 AC_ARG_ENABLE([fabricd],
 645   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 646 AC_ARG_ENABLE([vrrpd],
 647   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 648 AC_ARG_ENABLE([pathd],
 649   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 650 AC_ARG_ENABLE([bgp-announce],
 651   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 652 AC_ARG_ENABLE([bgp-vnc],
 653   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 654 AC_ARG_ENABLE([bgp-bmp],
 655   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 656 AC_ARG_ENABLE([snmp],
 657   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 658 AC_ARG_ENABLE([config_rollbacks],
 659   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 660 AC_ARG_ENABLE([confd],
 661   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 662 AC_ARG_ENABLE([sysrepo],
 663   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 664 AC_ARG_ENABLE([grpc],
 665   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 666 AC_ARG_ENABLE([zeromq],
 667   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 668 AC_ARG_ENABLE([lttng],
 669   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 670 AC_ARG_ENABLE([usdt],
 671   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 672 AC_ARG_WITH([libpam],
 673   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 674 AC_ARG_ENABLE([ospfapi],
 675   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 676 AC_ARG_ENABLE([ospfclient],
 677   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 678                           (this is the default if --disable-ospfapi is set)]))
 679 AC_ARG_ENABLE([multipath],
 680   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 681 AC_ARG_WITH([service_timeout],
 682   AS_HELP_STRING([--with-service-timeout=ARG], [set service timeout value (2 minutes by default), ARG must be digit]))
 683 AC_ARG_ENABLE([user],
 684   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 685 AC_ARG_ENABLE([group],
 686   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 687 AC_ARG_ENABLE([vty_group],
 688   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 689 AC_ARG_ENABLE([configfile_mask],
 690   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 691 AC_ARG_ENABLE([logfile_mask],
 692   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 693 AC_ARG_ENABLE([shell_access],
 694   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 695 AC_ARG_ENABLE([realms],
 696   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 697 AC_ARG_ENABLE([rtadv],
 698   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 699 AC_ARG_ENABLE([irdp],
 700   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 701 AC_ARG_ENABLE([capabilities],
 702   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 703 AC_ARG_ENABLE([gcc_ultra_verbose],
 704   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 705 AC_ARG_ENABLE([backtrace],
 706   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 707 AC_ARG_ENABLE([time-check],
 708   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 709 AC_ARG_ENABLE([cpu-time],
 710   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 711 AC_ARG_ENABLE([pcreposix],
 712   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 713 AC_ARG_ENABLE([fpm],
 714   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 715 AC_ARG_ENABLE([werror],
 716   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 717 AC_ARG_ENABLE([cumulus],
 718   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 719 AC_ARG_ENABLE([datacenter],
 720   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 721 AC_ARG_ENABLE([rr-semantics],
 722   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 723 AC_ARG_ENABLE([protobuf],
 724   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 725 AC_ARG_ENABLE([oldvpn_commands],
 726   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 727 AC_ARG_ENABLE([rpki],
 728   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 729 AC_ARG_ENABLE([clippy-only],
 730   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 731 AC_ARG_ENABLE([numeric_version],
 732   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 733 AC_ARG_ENABLE([gcov],
 734   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 735 AC_ARG_ENABLE([clang_coverage],
 736   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 737 AC_ARG_ENABLE([bfdd],
 738   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 739 AC_ARG_ENABLE([address-sanitizer],
 740   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 741 AC_ARG_ENABLE([thread-sanitizer],
 742   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 743 AC_ARG_ENABLE([memory-sanitizer],
 744   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 745 AC_ARG_ENABLE([undefined-sanitizer],
 746   AS_HELP_STRING([--enable-undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 747 AC_ARG_WITH([crypto],
 748   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 749 AC_ARG_WITH([frr-format],
 750   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 751
 752 AC_ARG_ENABLE([version-build-config],
 753   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 754
 755 #if openssl, else use the internal
 756 AS_IF([test "$with_crypto" = "openssl"], [
 757 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 758 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 759   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 760 else
 761   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 762 fi
 763 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 764 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 765 )
 766
 767 AS_IF([test "$enable_clippy_only" != "yes"], [
 768 AC_CHECK_HEADERS([json-c/json.h])
 769 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 770 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 771   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 772   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 773       AC_MSG_ERROR([libjson is needed to compile])
 774   fi
 775 fi
 776 ])
 777
 778 AC_ARG_ENABLE([dev_build],
 779     AS_HELP_STRING([--enable-dev-build], [build for development]))
 780
 781 AC_ARG_ENABLE([scripting],
 782     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 783
 784 AC_ARG_ENABLE([netlink-debug],
 785   AS_HELP_STRING([--disable-netlink-debug], [don't pretty print netlink debug messages]))
 786
 787 if test "$enable_netlink_debug" != "no" ; then
 788   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 789 fi
 790
 791 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 792
 793 if test "$enable_time_check" != "no" ; then
 794   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 795     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 796   else
 797     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 798   fi
 799 fi
 800
 801 case "${enable_cpu_time}" in
 802   "no")
 803   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 804   ;;
 805   "*")
 806   ;;
 807 esac
 808
 809 if test "$enable_rr_semantics" != "no" ; then
 810   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 811 fi
 812
 813 if test "$enable_datacenter" = "yes" ; then
 814   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 815   DFLT_NAME="datacenter"
 816 else
 817   DFLT_NAME="traditional"
 818 fi
 819
 820 if test "$enable_cumulus" = "yes" ; then
 821   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 822 fi
 823
 824 AC_SUBST([DFLT_NAME])
 825 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 826
 827 if test "$enable_shell_access" = "yes"; then
 828    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 829 fi
 830
 831 #
 832 # Python for clippy
 833 #
 834
 835 AS_IF([test "$host" = "$build"], [
 836   AM_PATH_PYTHON([3])
 837   AC_CHECK_HEADER([gelf.h], [], [
 838     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 839   ])
 840
 841   LIBS_save="$LIBS"
 842   AC_CHECK_LIB([elf], [elf_memory], [], [
 843     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 844   ])
 845
 846   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 847     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 848   ])
 849   AC_CHECK_LIB([elf], [gelf_getnote], [
 850     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 851   ])
 852   LIBS="$LIBS_save"
 853   unset LIBS_save
 854
 855   FRR_PYTHON_DEV
 856 ], [
 857   FRR_PYTHON
 858 ])
 859
 860 FRR_PYTHON_MODULES([pytest])
 861
 862 if test "$enable_doc" != "no"; then
 863   FRR_PYTHON_MODULES([sphinx], , [
 864     if test "$enable_doc" = "yes"; then
 865       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 866     fi
 867   ])
 868 fi
 869 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 870 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 871
 872 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 873   PYSPHINX="-m sphinx"
 874 ], [
 875   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 876 ])
 877 AC_SUBST([PYSPHINX])
 878
 879 #
 880 # Logic for old vpn commands support.
 881 #
 882 if test "$enable_oldvpn_commands" = "yes"; then
 883    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 884 fi
 885
 886 #
 887 # End of logic for protobuf support.
 888 #
 889
 890 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 891 if test "$enable_rtadv" != "no"; then
 892   AC_MSG_RESULT([yes])
 893   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 894 else
 895   AC_MSG_RESULT([no])
 896 fi
 897
 898 if test "$enable_user" = "no"; then
 899   enable_user=""
 900 else
 901   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 902     enable_user="frr"
 903   fi
 904   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 905 fi
 906
 907 if test "$enable_group" = "no"; then
 908   enable_group=""
 909 else
 910   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 911     enable_group="frr"
 912   fi
 913   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 914 fi
 915
 916 if test "$enable_vty_group" = "yes" ; then
 917   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 918 elif test "$enable_vty_group" != ""; then
 919   if test "$enable_vty_group" != "no"; then
 920     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 921   fi
 922 fi
 923 AC_SUBST([enable_user])
 924 AC_SUBST([enable_group])
 925 AC_SUBST([enable_vty_group])
 926
 927 enable_configfile_mask=${enable_configfile_mask:-0600}
 928 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 929 AC_SUBST([enable_configfile_mask])
 930
 931 enable_logfile_mask=${enable_logfile_mask:-0600}
 932 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 933
 934 MPATH_NUM=16
 935
 936 case "${enable_multipath}" in
 937   0)
 938     MPATH_NUM=64
 939     ;;
 940   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 941     MPATH_NUM="${enable_multipath}"
 942     ;;
 943   "")
 944     ;;
 945   *)
 946     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 947     ;;
 948 esac
 949
 950 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 951
 952 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 953
 954
 955 TIMEOUT_MIN=2
 956 case "${with_service_timeout}" in
 957   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 958     TIMEOUT_MIN="${with_service_timeout}"
 959     ;;
 960   0|"")
 961     ;;
 962   *)
 963     AC_MSG_FAILURE([Please specify digit for timeout ARG])
 964     ;;
 965 esac
 966 AC_SUBST([TIMEOUT_MIN])
 967
 968 dnl --------------------
 969 dnl Enable code coverage
 970 dnl --------------------
 971 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 972
 973 dnl ------------------------------------
 974 dnl Alpine only accepts numeric versions
 975 dnl ------------------------------------
 976 if test "$enable_numeric_version" != "" ; then
 977   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 978   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 979 fi
 980
 981 dnl -----------------------------------
 982 dnl Add extra version string to package
 983 dnl name, string and version fields.
 984 dnl -----------------------------------
 985 if test "$EXTRAVERSION" != "" ; then
 986   VERSION="${VERSION}${EXTRAVERSION}"
 987   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 988   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 989   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 990 fi
 991 AC_SUBST([EXTRAVERSION])
 992
 993 if test "$with_pkg_git_version" = "yes"; then
 994         if test -e "${srcdir}/.git"; then
 995                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 996         else    with_pkg_git_version="no"
 997                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 998         fi
 999 fi
1000 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
1001
1002 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
1003 if test "$OBJCOPY" != ":"; then
1004   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
1005     frr_cv_interp=""
1006     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
1007       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
1008         frr_cv_interp="`xargs -0 echo < conftest.interp`"
1009       fi
1010       test -f conftest.interp && rm conftest.interp
1011     ])
1012   ])
1013 fi
1014 if test -n "$frr_cv_interp"; then
1015   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
1016 fi
1017
1018 dnl -------------------------
1019 dnl Check other header files.
1020 dnl -------------------------
1021 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
1022         linux/version.h asm/types.h endian.h sys/endian.h])
1023
1024 ac_stdatomic_ok=false
1025 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
1026 AC_CHECK_HEADER([stdatomic.h],[
1027
1028   AC_MSG_CHECKING([whether _Atomic qualifier works])
1029   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1030 #include <stdatomic.h>
1031 int main(int argc, char **argv) {
1032   _Atomic int i = 0;
1033   return i;
1034 }
1035 ]])], [
1036     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
1037     AC_MSG_RESULT([yes])
1038     ac_stdatomic_ok=true
1039   ], [
1040     AC_MSG_RESULT([no])
1041   ])
1042 ])
1043
1044 AS_IF([$ac_stdatomic_ok], [true], [
1045   AC_MSG_CHECKING([for __atomic_* builtins])
1046   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1047 int main(int argc, char **argv) {
1048   volatile int i = 1;
1049   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1050   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1051 }
1052 ]])], [
1053     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1054     AC_MSG_RESULT([yes])
1055   ], [
1056     AC_MSG_RESULT([no])
1057
1058     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1059     AC_MSG_CHECKING([for __sync_* builtins])
1060     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1061 int main(int argc, char **argv) {
1062   volatile int i = 1;
1063   __sync_fetch_and_sub (&i, 1);
1064   return __sync_val_compare_and_swap (&i, 0, 1);
1065 }
1066 ]])], [
1067       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1068       AC_MSG_RESULT([yes])
1069
1070       AC_MSG_CHECKING([for __sync_swap builtin])
1071       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1072 int main(int argc, char **argv) {
1073   volatile int i = 1;
1074   return __sync_swap (&i, 2);
1075 }
1076 ]])], [
1077         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1078         AC_MSG_RESULT([yes])
1079       ], [
1080         AC_MSG_RESULT([no])
1081       ])
1082
1083     ], [
1084       AC_MSG_RESULT([no])
1085       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1086     ])
1087   ])
1088 ])
1089
1090 needsync=true
1091
1092 AS_IF([$needsync], [
1093   dnl Linux
1094   AC_MSG_CHECKING([for Linux futex() support])
1095   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1096 #ifndef _GNU_SOURCE
1097 #define _GNU_SOURCE
1098 #endif
1099 #include <unistd.h>
1100 #include <limits.h>
1101 #include <sys/time.h>
1102 #include <sys/syscall.h>
1103 #include <linux/futex.h>
1104
1105 int main(void);
1106 ],
1107 [
1108 {
1109   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1110 }
1111 ])], [
1112     AC_MSG_RESULT([yes])
1113     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1114     needsync=false
1115   ], [
1116     AC_MSG_RESULT([no])
1117   ])
1118 ])
1119
1120 AS_IF([$needsync], [
1121   dnl FreeBSD
1122   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1123   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1124 #include <errno.h>
1125 #include <stdlib.h>
1126 #include <sys/types.h>
1127 #include <sys/umtx.h>
1128 int main(void);
1129 ],
1130 [
1131 {
1132   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1133 }
1134 ])], [
1135     AC_MSG_RESULT([yes])
1136     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1137     needsync=false
1138   ], [
1139     AC_MSG_RESULT([no])
1140   ])
1141 ])
1142
1143 AS_IF([$needsync], [
1144   dnl OpenBSD patch (not upstream at the time of writing this)
1145   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1146   AC_MSG_CHECKING([for OpenBSD futex() support])
1147   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1148 #include <sys/futex.h>
1149 int main(void);
1150 ],
1151 [
1152 {
1153   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1154 }
1155 ])], [
1156     AC_MSG_RESULT([yes])
1157     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1158     needsync=false
1159   ], [
1160     AC_MSG_RESULT([no])
1161   ])
1162 ])
1163
1164 dnl Utility macro to avoid retyping includes all the time
1165 m4_define([FRR_INCLUDES],
1166 [#ifdef SUNOS_5
1167 #define _POSIX_C_SOURCE 200809L
1168 #define __EXTENSIONS__
1169 #endif
1170 #include <stdio.h>
1171 #include <stdlib.h>
1172 #include <stddef.h>
1173 #include <sys/types.h>
1174 /* sys/conf.h depends on param.h on FBSD at least */
1175 #include <sys/param.h>
1176 /* Required for MAXSIG */
1177 #include <signal.h>
1178 #include <sys/socket.h>
1179 #ifdef __APPLE__
1180 # define __APPLE_USE_RFC_3542
1181 #endif
1182 #include <netinet/in.h>
1183 #include <sys/time.h>
1184 #include <time.h>
1185 #include <net/if.h>
1186 ])dnl
1187
1188 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1189 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1190 dnl an additional round for it.
1191
1192 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1193
1194 m4_define([FRR_INCLUDES],
1195 FRR_INCLUDES
1196 [#ifdef HAVE_NET_IF_VAR_H
1197 # include <net/if_var.h>
1198 #endif
1199 ])dnl
1200
1201 AC_CHECK_HEADERS([netinet/in_var.h \
1202         net/if_dl.h net/netopt.h \
1203         inet/nd.h netinet/ip_icmp.h \
1204         sys/sysctl.h sys/sockio.h sys/conf.h],
1205         [], [], [FRR_INCLUDES])
1206
1207 AC_CHECK_HEADERS([ucontext.h], [], [],
1208 [#ifndef __USE_GNU
1209 #define __USE_GNU
1210 #endif /* __USE_GNU */
1211 FRR_INCLUDES
1212 ])
1213
1214 m4_define([UCONTEXT_INCLUDES],
1215 [#include <ucontext.h>])dnl
1216
1217 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1218   [], [], [UCONTEXT_INCLUDES])
1219 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1220   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1221    [], [], [UCONTEXT_INCLUDES])],
1222   [], [UCONTEXT_INCLUDES])
1223 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1224   [], [], [UCONTEXT_INCLUDES])
1225
1226 m4_define([FRR_INCLUDES],
1227 FRR_INCLUDES
1228 [
1229 #include <sys/un.h>
1230 #include <netinet/in_systm.h>
1231 #ifdef HAVE_NETINET_IN_VAR_H
1232 # include <netinet/in_var.h>
1233 #endif
1234 #ifdef HAVE_NET_IF_DL_H
1235 # include <net/if_dl.h>
1236 #endif
1237 #ifdef HAVE_NET_NETOPT_H
1238 # include <net/netopt.h>
1239 #endif
1240 #include <net/route.h>
1241 #ifdef HAVE_INET_ND_H
1242 # include <inet/nd.h>
1243 #endif
1244 #include <arpa/inet.h>
1245 /* Required for IDRP */
1246 #ifdef HAVE_NETINET_IP_ICMP_H
1247 # include <netinet/ip_icmp.h>
1248 #endif
1249 ])dnl
1250
1251 dnl V6 headers are checked below, after we check for v6
1252
1253 is_linux=false
1254
1255 AC_MSG_CHECKING([which operating system interface to use])
1256 case "$host_os" in
1257   sunos* | solaris2*)
1258     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1259     ;;
1260   linux*)
1261     AC_MSG_RESULT([Linux])
1262
1263     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1264     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1265     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1266
1267     dnl Linux has a compilation problem with mixing
1268     dnl netinet/in.h and linux/in6.h they are not
1269     dnl compatible.  There has been discussion on
1270     dnl how to fix it but no real progress on implementation
1271     dnl when they fix it, remove this
1272     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1273
1274     is_linux=true
1275     ;;
1276   openbsd*)
1277     AC_MSG_RESULT([OpenBSD])
1278
1279     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1280     AC_DEFINE([KAME], [1], [KAME IPv6])
1281     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1282     ;;
1283   *)
1284     AC_MSG_RESULT([BSD])
1285
1286     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1287     AC_DEFINE([KAME], [1], [KAME IPv6])
1288     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1289     ;;
1290 esac
1291 AM_CONDITIONAL([LINUX], [${is_linux}])
1292
1293 AC_SYS_LARGEFILE
1294
1295 dnl ------------------------
1296 dnl Integrated REALMS option
1297 dnl ------------------------
1298 if test "$enable_realms" = "yes"; then
1299     case "$host_os" in
1300       linux*)
1301        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1302        ;;
1303       *)
1304        echo "Sorry, only Linux has REALMS support"
1305        exit 1
1306        ;;
1307     esac
1308 fi
1309
1310 dnl ---------------
1311 dnl other functions
1312 dnl ---------------
1313 AC_CHECK_FUNCS([ \
1314         strlcat strlcpy \
1315         getgrouplist \
1316         openat \
1317         unlinkat \
1318         posix_fallocate \
1319         sendmmsg \
1320         explicit_bzero \
1321         ])
1322
1323 AC_CHECK_MEMBERS([struct mmsghdr.msg_hdr], [], [], FRR_INCLUDES)
1324
1325 dnl ##########################################################################
1326 dnl LARGE if block spans a lot of "configure"!
1327 if test "$enable_clippy_only" != "yes"; then
1328 dnl ##########################################################################
1329
1330 #
1331 # Logic for protobuf support.
1332 #
1333 PROTO3=false
1334 if test "$enable_protobuf" = "yes"; then
1335   # Check for protoc & protoc-c
1336
1337   # protoc is not required, it's only for a "be nice" helper target
1338   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1339
1340   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1341   if test "$PROTOC_C" = "/bin/false"; then
1342     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1343   fi
1344
1345   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1346     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1347   ])
1348
1349   PROTO3=true
1350   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1351                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1352                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1353                                             [1], [Have Protobuf version 3]),
1354                                   [PROTO3=false],
1355                                   [#include <google/protobuf-c/protobuf-c.h>])],
1356                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1357
1358   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1359 fi
1360
1361
1362 dnl ---------------------
1363 dnl Integrated VTY option
1364 dnl ---------------------
1365 case "${enable_vtysh}" in
1366 "no")
1367   VTYSH="";;
1368 *)
1369   VTYSH="vtysh";
1370   AC_DEFINE([VTYSH], [1], [VTY shell])
1371
1372   prev_libs="$LIBS"
1373   AC_CHECK_LIB([readline], [main], [
1374     LIBREADLINE="-lreadline"
1375   ], [
1376     dnl readline failed - it might be incorrectly linked and missing its
1377     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1378     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1379       LIBREADLINE="$ac_cv_search_tputs"
1380     ], [
1381       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1382     ])
1383
1384     dnl re-try with the lib we found above
1385     unset ac_cv_lib_readline_main
1386     AC_CHECK_LIB([readline], [main], [
1387       LIBREADLINE="-lreadline $LIBREADLINE"
1388     ], [
1389       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1390     ], [$LIBREADLINE])
1391   ], [])
1392   LIBS="$LIBS -lreadline"
1393   AC_CHECK_FUNCS([rl_clear_visible_line])
1394   LIBS="$prev_libs"
1395
1396   AC_CHECK_HEADER([readline/history.h])
1397   if test "$ac_cv_header_readline_history_h" = "no"; then
1398     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1399   fi
1400   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1401   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1402     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1403   fi
1404   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1405   if test "$frr_cv_append_history" = "yes"; then
1406     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1407   fi
1408   ;;
1409 esac
1410 AC_SUBST([LIBREADLINE])
1411
1412 dnl ----------
1413 dnl PAM module
1414 dnl
1415 dnl FRR detects the PAM library it is built against by checking for a
1416 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1417 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1418 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1419 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1420 dnl of OpenPAM.
1421 dnl ----------
1422 if test "$with_libpam" = "yes"; then
1423   AC_CHECK_HEADER([security/pam_misc.h],
1424     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1425      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1426      pam_conv_func="misc_conv"
1427     ],
1428     [], FRR_INCLUDES)
1429   AC_CHECK_HEADER([security/openpam.h],
1430     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1431      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1432      pam_conv_func="openpam_ttyconv"
1433     ],
1434     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1435   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1436     AC_MSG_WARN([*** pam support will not be built ***])
1437     with_libpam="no"
1438   fi
1439 fi
1440
1441 if test "$with_libpam" = "yes"; then
1442 dnl took this test from proftpds configure.in and suited to our needs
1443 dnl -------------------------------------------------------------------------
1444 dnl
1445 dnl This next check looks funky due to a linker problem with some versions
1446 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1447 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1448 dnl with RedHat 6.2 and Debian 2.2 or better.
1449 AC_CHECK_LIB([pam], [pam_start],
1450   [AC_CHECK_LIB([pam], [$pam_conv_func],
1451     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1452      LIBPAM="-lpam"],
1453     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1454      LIBPAM="-lpam -lpam_misc"]
1455     )
1456   ],
1457
1458   [AC_CHECK_LIB([pam], [pam_end],
1459     [AC_CHECK_LIB([pam], [$pam_conv_func],
1460       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1461        LIBPAM="-lpam -ldl"],
1462       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1463        LIBPAM="-lpam -ldl -lpam_misc"]
1464      )
1465   ],AC_MSG_WARN([*** pam support will not be built ***]),
1466   [-ldl])
1467   ]
1468 )
1469 fi
1470 AC_SUBST([LIBPAM])
1471
1472 dnl -------------------------------
1473 dnl bgpd needs pow() and hence libm
1474 dnl -------------------------------
1475 TMPLIBS="$LIBS"
1476 LIBS=""
1477 AC_SEARCH_LIBS([pow], [m], [
1478   LIBM="$LIBS"
1479 ], [
1480   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1481 ])
1482 LIBS="$TMPLIBS"
1483 AC_SUBST([LIBM])
1484
1485 AC_CHECK_FUNCS([ppoll], [
1486   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1487 ])
1488 AC_CHECK_FUNCS([pollts], [
1489   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1490 ])
1491
1492 AC_CHECK_HEADER([asm-generic/unistd.h],
1493                 [AC_CHECK_DECL(__NR_setns,
1494                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1495                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1496                                ])
1497                  AC_CHECK_FUNCS([setns])]
1498                )
1499
1500 dnl --------------------------
1501 dnl Determine IS-IS I/O method
1502 dnl --------------------------
1503 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1504 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1505 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1506 AC_CHECK_HEADER([net/bpf.h])
1507 AC_CHECK_HEADER([sys/dlpi.h])
1508 AC_MSG_CHECKING([zebra IS-IS I/O method])
1509
1510 case "$host_os" in
1511   linux*)
1512     AC_MSG_RESULT([pfpacket])
1513     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1514     ;;
1515   *)
1516     if test "$ac_cv_header_net_bpf_h" = "no"; then
1517       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1518         AC_MSG_RESULT([none])
1519         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1520           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1521         fi
1522         AC_MSG_WARN([*** IS-IS support will not be built ***])
1523         enable_isisd="no"
1524         enable_fabricd="no"
1525       else
1526         AC_MSG_RESULT([DLPI])
1527       fi
1528       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1529     else
1530       AC_MSG_RESULT([BPF])
1531       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1532     fi
1533     ;;
1534 esac
1535 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1536
1537 dnl ---------------------------------------------------------------
1538 dnl figure out how to specify an interface in multicast sockets API
1539 dnl ---------------------------------------------------------------
1540 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1541
1542 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1543         #include <sys/socket.h>
1544         #include <netinet/in.h>
1545         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1546         #include <linux/types.h>
1547 ])
1548
1549 AC_CHECK_HEADERS([linux/mroute6.h], [], [],[
1550         #include <sys/socket.h>
1551         #include <netinet/in.h>
1552         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1553         #include <linux/types.h>
1554 ])
1555
1556 m4_define([FRR_INCLUDES],
1557 FRR_INCLUDES
1558 [#ifdef HAVE_LINUX_MROUTE_H
1559 # include <linux/mroute.h>
1560 #endif
1561 ])dnl
1562
1563 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1564         #include <sys/socket.h>
1565         #include <sys/types.h>
1566         #include <netinet/in.h>
1567         #include <net/route.h>
1568 ])
1569
1570 m4_define([FRR_INCLUDES],
1571 FRR_INCLUDES
1572 [#ifdef HAVE_NETINET_IP_MROUTE_H
1573 # include <netinet/ip_mroute.h>
1574 #endif
1575 ])dnl
1576
1577 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1578 AC_COMPILE_IFELSE(
1579 [ AC_LANG_PROGRAM([[
1580       #include <sys/types.h>
1581       #include <netinet/in.h>
1582   ]], [[
1583       struct group_req gr;
1584       int sock;
1585       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1586   ]])
1587 ],[
1588   AC_MSG_RESULT([yes])
1589   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1590 ],[
1591   AC_MSG_RESULT(no)
1592 ])
1593
1594 dnl ---------------------------------------------------------------
1595 dnl figure out how to check link-state
1596 dnl ---------------------------------------------------------------
1597 AC_CHECK_HEADER([net/if_media.h],
1598   [m4_define([LINK_DETECT_INCLUDES],
1599     FRR_INCLUDES
1600     [#include <net/if_media.h>
1601   ])
1602   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1603     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1604     [], LINK_DETECT_INCLUDES)],
1605   [],
1606   FRR_INCLUDES)
1607
1608 dnl ---------------------------------------------------------------
1609 dnl Additional, newer way to check link-state using ifi_link_state.
1610 dnl Not available in all BSD's when ifmediareq available
1611 dnl ---------------------------------------------------------------
1612 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1613   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1614   [], FRR_INCLUDES)
1615
1616 dnl ------------------------
1617 dnl TCP_MD5SIG socket option
1618 dnl ------------------------
1619
1620 AC_CHECK_HEADER([netinet/tcp.h],
1621    [m4_define([MD5_INCLUDES],
1622       FRR_INCLUDES
1623       [#include <netinet/tcp.h>
1624     ])
1625     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1626    [],
1627    FRR_INCLUDES)
1628 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1629   AC_CHECK_HEADER([linux/tcp.h],
1630        [m4_define([MD5_INCLUDES],
1631           FRR_INCLUDES
1632           [#include <linux/tcp.h>
1633         ])
1634        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1635 fi
1636
1637 LIBS_save="$LIBS"
1638 AC_CHECK_LIB([crypt], [crypt], [], [
1639   AC_CHECK_LIB([crypto], [DES_crypt])
1640 ])
1641 LIBCRYPT="$LIBS"
1642 LIBCRYPT="${LIBCRYPT%$LIBS_save}"
1643 LIBCRYPT="${LIBCRYPT#$LIBS_save}"
1644 AC_SUBST([LIBCRYPT])
1645 LIBS="$LIBS_save"
1646 unset LIBS_save
1647
1648 AC_CHECK_LIB([resolv], [res_init])
1649
1650 dnl ---------------------------
1651 dnl check system has PCRE regexp
1652 dnl ---------------------------
1653 if test "$enable_pcreposix" = "yes"; then
1654   AC_CHECK_LIB([pcreposix], [regexec], [], [
1655     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1656   ])
1657 fi
1658 AC_SUBST([HAVE_LIBPCREPOSIX])
1659
1660 dnl ##########################################################################
1661 dnl test "$enable_clippy_only" != "yes"
1662 fi
1663 dnl END OF LARGE if block
1664 dnl ##########################################################################
1665
1666 dnl ------------------
1667 dnl check C-Ares library
1668 dnl ------------------
1669 PKG_CHECK_MODULES([CARES], [libcares], [
1670   c_ares_found=true
1671 ],[
1672   c_ares_found=false
1673 ])
1674 AM_CONDITIONAL([CARES], [$c_ares_found])
1675
1676
1677 dnl ----------------------------------------------------------------------------
1678 dnl figure out if domainname is available in the utsname struct (GNU extension).
1679 dnl ----------------------------------------------------------------------------
1680 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1681
1682 dnl ------------------
1683 dnl IPv6 header checks
1684 dnl ------------------
1685 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1686         netinet6/in6_var.h netinet6/nd6.h], [], [],
1687         FRR_INCLUDES)
1688
1689 m4_define([FRR_INCLUDES],dnl
1690 FRR_INCLUDES
1691 [#ifdef HAVE_NETINET6_IN6_H
1692 #include <netinet6/in6.h>
1693 #endif
1694 #ifdef HAVE_NETINET_IN6_VAR_H
1695 #include <netinet/in6_var.h>
1696 #endif
1697 #include <netinet/icmp6.h>
1698 #ifdef HAVE_NETINET6_IN6_VAR_H
1699 # include <netinet6/in6_var.h>
1700 #endif
1701 #ifdef HAVE_NETINET6_ND6_H
1702 # include <netinet6/nd6.h>
1703 #endif
1704 ])dnl
1705
1706 dnl --------------------
1707 dnl Daemon disable check
1708 dnl --------------------
1709
1710 AS_IF([test "$enable_bgpd" != "no"], [
1711   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1712 ])
1713
1714 AS_IF([test "$enable_ripd" != "no"], [
1715   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1716 ])
1717
1718 AS_IF([test "$enable_ripngd" != "no"], [
1719   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1720 ])
1721
1722 AS_IF([test "$enable_ospfd" != "no"], [
1723   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1724 ])
1725
1726 AS_IF([test "$enable_ospf6d" != "no"], [
1727   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1728 ])
1729
1730 AS_IF([test "$enable_ldpd" != "no"], [
1731   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1732 ])
1733
1734 AS_IF([test "$enable_nhrpd" != "no"], [
1735   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1736 ])
1737
1738 AS_IF([test "$enable_eigrpd" != "no"], [
1739   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1740 ])
1741
1742 AS_IF([test "$enable_babeld" != "no"], [
1743   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1744 ])
1745
1746 AS_IF([test "$enable_isisd" != "no"], [
1747   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1748 ])
1749
1750 AS_IF([test "$enable_pimd" != "no"], [
1751   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1752 ])
1753
1754 AS_IF([test "$enable_pbrd" != "no"], [
1755   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1756 ])
1757
1758 AS_IF([test "$enable_sharpd" = "yes"], [
1759   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1760 ])
1761
1762 AS_IF([test "$enable_staticd" != "no"], [
1763   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1764 ])
1765
1766 AS_IF([test "$enable_fabricd" != "no"], [
1767   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1768 ])
1769
1770 AS_IF([test "$enable_vrrpd" != "no"], [
1771   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1772 ])
1773
1774 if test "$enable_bfdd" = "no"; then
1775   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1776   BFDD=""
1777 else
1778   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1779   BFDD="bfdd"
1780
1781   case $host_os in
1782     linux*)
1783       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1784       ;;
1785
1786     *)
1787       AC_DEFINE([BFD_BSD], [1], [bfdd])
1788       ;;
1789   esac
1790 fi
1791
1792 AS_IF([test "$enable_pathd" != "no"], [
1793   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1794 ])
1795
1796
1797 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1798   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1799 fi
1800
1801 NHRPD=""
1802 case "$host_os" in
1803   linux*)
1804     case "${enable_nhrpd}" in
1805       no)
1806         ;;
1807       yes)
1808         if test "$enable_clippy_only" != "yes"; then
1809         if test "$c_ares_found" != "true" ; then
1810           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1811         fi
1812         fi
1813         NHRPD="nhrpd"
1814         ;;
1815       *)
1816         if test "$c_ares_found" = "true" ; then
1817           NHRPD="nhrpd"
1818         fi
1819         ;;
1820     esac
1821     ;;
1822   *)
1823     if test "$enable_nhrpd" = "yes"; then
1824       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1825     fi
1826     ;;
1827 esac
1828
1829 if test "$enable_watchfrr" = "no";then
1830   WATCHFRR=""
1831 else
1832   WATCHFRR="watchfrr"
1833 fi
1834
1835 OSPFCLIENT=""
1836 if test "$enable_ospfapi" != "no";then
1837     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1838
1839   if test "$enable_ospfclient" != "no";then
1840       OSPFCLIENT="ospfclient"
1841   fi
1842 fi
1843
1844 if test "$enable_bgp_announce" = "no";then
1845   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1846 else
1847   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1848 fi
1849
1850 if test "$enable_bgp_vnc" != "no";then
1851   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1852 fi
1853
1854 bgpd_bmp=false
1855 case "${enable_bgp_bmp}" in
1856   no)
1857     ;;
1858   yes)
1859     if test "$c_ares_found" != "true" ; then
1860       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1861     fi
1862     bgpd_bmp=true
1863     ;;
1864   *)
1865     if test "$c_ares_found" = "true" ; then
1866       bgpd_bmp=true
1867     fi
1868     ;;
1869 esac
1870
1871 if test "$enable_version_build_config" != "no";then
1872   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1873 fi
1874
1875 dnl ##########################################################################
1876 dnl LARGE if block
1877 if test "$enable_clippy_only" != "yes"; then
1878 dnl ##########################################################################
1879
1880 dnl ------------------
1881 dnl check Net-SNMP library
1882 dnl ------------------
1883 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1884    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1885    if test "$NETSNMP_CONFIG" = "no"; then
1886       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1887    fi
1888    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1889    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1890    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1891    # among other things we avoid a GPL vs. OpenSSL license conflict here
1892    for removelib in crypto ssl sensors pci wrap; do
1893      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1894    done
1895    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1896    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1897 int main(void);
1898 ],
1899 [
1900 {
1901   return 0;
1902 }
1903 ])], [
1904      AC_MSG_RESULT([no])
1905      AC_MSG_ERROR([--enable-snmp given but not usable])])
1906    case "${enable_snmp}" in
1907      yes)
1908       SNMP_METHOD=agentx
1909       ;;
1910      agentx)
1911       SNMP_METHOD="${enable_snmp}"
1912       ;;
1913      *)
1914       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1915       ;;
1916    esac
1917    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1918    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1919 fi
1920 AC_SUBST([SNMP_LIBS])
1921 AC_SUBST([SNMP_CFLAGS])
1922
1923 dnl ---------------
1924 dnl libyang
1925 dnl ---------------
1926 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1927   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1928 ])
1929 ac_cflags_save="$CFLAGS"
1930 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1931 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1932   AC_MSG_ERROR([m4_normalize([
1933     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1934     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1935   ])
1936 ], [[#include <libyang/libyang.h>]])
1937 CFLAGS="$ac_cflags_save"
1938
1939 dnl ---------------
1940 dnl configuration rollbacks
1941 dnl ---------------
1942 SQLITE3=false
1943 if test "$enable_config_rollbacks" = "yes"; then
1944   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1945     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1946     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1947     SQLITE3=true
1948   ], [
1949     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1950   ])
1951 fi
1952
1953 dnl ---------------
1954 dnl confd
1955 dnl ---------------
1956 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1957    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1958    if test "$CONFD" = "/bin/false"; then
1959       AC_MSG_ERROR([confd was not found on your system.])]
1960    fi
1961    AC_CHECK_PROG([CONFDC], [confdc], [confdc], [/bin/false], "${enable_confd}/bin")
1962    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1963    AC_SUBST([CONFD_CFLAGS])
1964    CONFD_LIBS="-lconfd"
1965    AC_SUBST([CONFD_LIBS])
1966    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1967 fi
1968
1969 dnl ---------------
1970 dnl sysrepo
1971 dnl ---------------
1972 if test "$enable_sysrepo" = "yes"; then
1973   PKG_CHECK_MODULES([SYSREPO], [sysrepo >= 2.1.42],
1974       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1975       SYSREPO=true],
1976       [SYSREPO=false
1977       AC_MSG_ERROR([sysrepo was not found on your system.])]
1978   )
1979 fi
1980
1981 dnl ---------------
1982 dnl gRPC
1983 dnl ---------------
1984 if test "$enable_grpc" = "yes"; then
1985   AC_LANG_PUSH([C++])
1986   AX_CXX_COMPILE_STDCXX([11], [ext])
1987   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
1988     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1989     if test "$PROTOC" = "/bin/false"; then
1990       AC_MSG_FAILURE([grpc requested but protoc not found.])
1991     fi
1992
1993     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1994     GRPC=true
1995   ], [
1996     GRPC=false
1997     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1998   ])
1999   AC_LANG_POP([C++])
2000 fi
2001
2002 dnl -----
2003 dnl LTTng
2004 dnl -----
2005 if test "$enable_lttng" = "yes"; then
2006   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.9.0], [
2007     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
2008     LTTNG=true
2009   ], [
2010     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
2011   ])
2012 fi
2013
2014 dnl ----
2015 dnl USDT
2016 dnl ----
2017 if test "$enable_usdt" = "yes"; then
2018   AC_CHECK_HEADERS([sys/sdt.h], [
2019     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
2020     USDT=true
2021   ], [
2022     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
2023   ])
2024 fi
2025
2026 dnl ------
2027 dnl ZeroMQ
2028 dnl ------
2029 if test "$enable_zeromq" != "no"; then
2030   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2031     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2032     ZEROMQ=true
2033   ], [
2034     if test "$enable_zeromq" = "yes"; then
2035       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2036     fi
2037   ])
2038 fi
2039
2040 dnl ------------------------------------
2041 dnl Enable RPKI and add librtr to libs
2042 dnl ------------------------------------
2043 if test "$enable_rpki" = "yes"; then
2044   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.8.0],
2045       [RPKI=true],
2046       [RPKI=false
2047       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2048   )
2049 fi
2050
2051 dnl ------------------------------------
2052 dnl pimd is not supported on OpenBSD and MacOS
2053 dnl ------------------------------------
2054 if test "$enable_pimd" != "no"; then
2055 AC_MSG_CHECKING([for pimd OS support])
2056 case "$host_os" in
2057   darwin*)
2058     AC_MSG_RESULT([no])
2059     enable_pimd="no"
2060     ;;
2061   openbsd*)
2062     AC_MSG_RESULT([no])
2063     enable_pimd="no"
2064     ;;
2065   *)
2066     AC_MSG_RESULT([yes])
2067     ;;
2068 esac
2069 fi
2070
2071 dnl -------------------------------------
2072 dnl VRRP is only supported on linux
2073 dnl -------------------------------------
2074 if test "$enable_vrrpd" != "no"; then
2075 AC_MSG_CHECKING([for VRRP OS support])
2076 case "$host_os" in
2077   linux*)
2078     AC_MSG_RESULT([yes])
2079     ;;
2080   *)
2081     AC_MSG_RESULT([no])
2082     enable_vrrpd="no"
2083     ;;
2084 esac
2085 fi
2086
2087 dnl ------------------------------------------
2088 dnl Check whether rtrlib was build with ssh support
2089 dnl ------------------------------------------
2090 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2091 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2092                         [[struct tr_ssh_config config;]])],
2093         [AC_MSG_RESULT([yes])
2094         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2095         AC_MSG_RESULT([no])
2096 )
2097
2098 dnl ---------------
2099 dnl dlopen & dlinfo
2100 dnl ---------------
2101 LIBS_save="$LIBS"
2102 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2103   AC_MSG_ERROR([unable to find the dlopen()])
2104 ])
2105
2106 AC_CHECK_HEADERS([link.h])
2107
2108 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2109   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2110 #include <stdlib.h>
2111 #ifdef HAVE_LINK_H
2112 #include <link.h>
2113 #endif
2114 #include <dlfcn.h>
2115 ]], [[
2116   char origin[1];
2117   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2118 ]])], [
2119     frr_cv_rtld_di_origin=yes
2120   ], [
2121     frr_cv_rtld_di_origin=no
2122   ])
2123 ])
2124 if test "$frr_cv_rtld_di_origin" = "yes"; then
2125   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2126 fi
2127
2128 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2129   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2130 #include <stdlib.h>
2131 #ifdef HAVE_LINK_H
2132 #include <link.h>
2133 #endif
2134 #include <dlfcn.h>
2135 ]], [[
2136   struct link_map *lm = NULL;
2137   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2138 ]])], [
2139     frr_cv_rtld_di_linkmap=yes
2140   ], [
2141     frr_cv_rtld_di_linkmap=no
2142   ])
2143 ])
2144 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2145   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2146 fi
2147
2148 LIBDL="$LIBS"
2149 LIBDL="${LIBDL%$LIBS_save}"
2150 LIBDL="${LIBDL#$LIBS_save}"
2151 AC_SUBST([LIBDL])
2152 LIBS="$LIBS_save"
2153 unset LIBS_save
2154
2155 dnl ##########################################################################
2156 dnl test "$enable_clippy_only" != "yes"
2157 fi
2158 dnl END OF LARGE if block
2159 dnl ##########################################################################
2160
2161 dnl ---------------------------
2162 dnl sockaddr and netinet checks
2163 dnl ---------------------------
2164 AC_CHECK_TYPES([
2165         struct sockaddr_dl,
2166         struct vifctl, struct mfcctl, struct sioc_sg_req,
2167         vifi_t, struct sioc_vif_req, struct igmpmsg,
2168         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2169         struct nd_opt_adv_interval,
2170         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2171         struct nd_opt_rdnss, struct nd_opt_dnssl],
2172         [], [], FRR_INCLUDES)
2173
2174 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2175         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2176         struct sockaddr_dl.sdl_len,
2177         struct if6_aliasreq.ifra_lifetime,
2178         struct nd_opt_adv_interval.nd_opt_ai_type],
2179         [], [], FRR_INCLUDES)
2180
2181 dnl ---------------------------
2182 dnl IRDP/pktinfo/icmphdr checks
2183 dnl ---------------------------
2184
2185 AC_CHECK_TYPES([struct in_pktinfo], [
2186   AC_CHECK_TYPES([struct icmphdr], [
2187     IRDP=true
2188   ], [
2189     IRDP=false
2190   ], [FRR_INCLUDES])
2191 ], [
2192   IRDP=false
2193 ], [FRR_INCLUDES])
2194
2195 case "${enable_irdp}" in
2196 yes)
2197   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2198   ;;
2199 no)
2200   IRDP=false
2201   ;;
2202 esac
2203
2204
2205 dnl -----------------------
2206 dnl checking for IP_PKTINFO
2207 dnl -----------------------
2208 AC_MSG_CHECKING([for IP_PKTINFO])
2209 AC_COMPILE_IFELSE(
2210 [ AC_LANG_PROGRAM([[
2211         #include <netdb.h>
2212    ]], [[
2213         int opt = IP_PKTINFO;
2214    ]])
2215 ],[
2216   AC_MSG_RESULT([yes])
2217   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2218 ],[
2219   AC_MSG_RESULT([no])
2220 ])
2221
2222 dnl ---------------------------
2223 dnl checking for IP_RECVDSTADDR
2224 dnl ---------------------------
2225 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2226 AC_COMPILE_IFELSE(
2227 [ AC_LANG_PROGRAM([[
2228         #include <netinet/in.h>
2229   ]], [[
2230         int opt = IP_RECVDSTADDR;
2231   ]])
2232 ],[
2233   AC_MSG_RESULT([yes])
2234   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2235 ],[
2236   AC_MSG_RESULT([no])
2237 ])
2238
2239 dnl ----------------------
2240 dnl checking for IP_RECVIF
2241 dnl ----------------------
2242 AC_MSG_CHECKING([for IP_RECVIF])
2243 AC_COMPILE_IFELSE(
2244 [ AC_LANG_PROGRAM([[
2245         #include <netinet/in.h>
2246   ]], [[
2247         int opt = IP_RECVIF;
2248   ]])
2249 ],[
2250   AC_MSG_RESULT([yes])
2251   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2252 ],[
2253   AC_MSG_RESULT([no])
2254 ])
2255
2256 dnl ----------------------
2257 dnl checking for SO_BINDANY
2258 dnl ----------------------
2259 AC_MSG_CHECKING([for SO_BINDANY])
2260 AC_COMPILE_IFELSE(
2261 [ AC_LANG_PROGRAM([[
2262         #include <sys/socket.h>
2263   ]], [[
2264         int opt = SO_BINDANY;
2265   ]])
2266 ],[
2267   AC_MSG_RESULT([yes])
2268   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2269 ],[
2270   AC_MSG_RESULT([no])
2271 ])
2272
2273 dnl ----------------------
2274 dnl checking for IP_FREEBIND
2275 dnl ----------------------
2276 AC_MSG_CHECKING([for IP_FREEBIND])
2277 AC_COMPILE_IFELSE(
2278 [ AC_LANG_PROGRAM([[
2279         #include <netinet/in.h>
2280   ]], [[
2281         int opt = IP_FREEBIND;
2282   ]])
2283 ],[
2284   AC_MSG_RESULT([yes])
2285   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2286 ],[
2287   AC_MSG_RESULT([no])
2288 ])
2289
2290 dnl --------------------------------------
2291 dnl checking for be32dec existence or not
2292 dnl --------------------------------------
2293 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2294         #ifdef HAVE_SYS_ENDIAN_H
2295         #include <sys/endian.h>
2296         #endif
2297         #ifdef HAVE_ENDIAN_H
2298         #include <endian.h>
2299         #endif
2300 ])
2301
2302 dnl --------------------------------------
2303 dnl checking for clock_time monotonic struct and call
2304 dnl --------------------------------------
2305 AC_CHECK_DECL([CLOCK_MONOTONIC],
2306         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2307          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2308 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2309
2310 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2311          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2312 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2313
2314 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2315   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2316 ])
2317
2318 dnl --------------------------------------
2319 dnl checking for flex and bison
2320 dnl --------------------------------------
2321
2322 dnl autoconf 2.69 AC_PROG_LEX has no parameters
2323 dnl autoconf 2.70 AC_PROG_LEX prints a deprecation warning without params
2324 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
2325   dnl autoconf < 2.70
2326   AC_PROG_LEX
2327 ], [
2328   dnl autoconf >= 2.70
2329   AC_PROG_LEX([noyywrap])
2330 ])
2331
2332 AC_MSG_CHECKING([version of flex])
2333 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2334 frr_ac_flex_version="${frr_ac_flex_version##* }"
2335 AC_MSG_RESULT([$frr_ac_flex_version])
2336 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2337   LEX="$SHELL $missing_dir/missing flex"
2338   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2339     AC_MSG_WARN([using pregenerated flex output files])
2340   else
2341     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2342   fi
2343   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2344   AC_SUBST([LEXLIB], [''])
2345 ])
2346
2347 AC_PROG_YACC
2348 dnl thanks GNU bison for this b*llshit...
2349 AC_MSG_CHECKING([version of bison])
2350 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2351 frr_ac_bison_version="${frr_ac_bison_version##* }"
2352 frr_ac_bison_missing="false"
2353 case "x${frr_ac_bison_version}x" in
2354   x2.7*)
2355     BISON_OPENBRACE='"'
2356     BISON_CLOSEBRACE='"'
2357     BISON_VERBOSE=''
2358     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2359     ;;
2360   x2.*|x1.*)
2361     AC_MSG_RESULT([$frr_ac_bison_version])
2362     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2363     frr_ac_bison_missing="true"
2364     ;;
2365   x)
2366     AC_MSG_RESULT([none])
2367     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2368     frr_ac_bison_missing="true"
2369     ;;
2370   x3.[012][^0-9]*)
2371     BISON_OPENBRACE='{'
2372     BISON_CLOSEBRACE='}'
2373     BISON_VERBOSE='-Dparse.error=verbose'
2374     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2375     ;;
2376   *)
2377     BISON_OPENBRACE='{'
2378     BISON_CLOSEBRACE='}'
2379     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2380     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2381     ;;
2382 esac
2383 AC_SUBST([BISON_OPENBRACE])
2384 AC_SUBST([BISON_CLOSEBRACE])
2385 AC_SUBST([BISON_VERBOSE])
2386
2387 if $frr_ac_bison_missing; then
2388   YACC="$SHELL $missing_dir/missing bison -y"
2389   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2390     AC_MSG_WARN([using pregenerated bison output files])
2391   else
2392     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2393   fi
2394 fi
2395
2396 dnl -------------------
2397 dnl capabilities checks
2398 dnl -------------------
2399 if test "$enable_capabilities" != "no"; then
2400   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2401   AC_COMPILE_IFELSE(
2402   [ AC_LANG_PROGRAM([[
2403         #include <sys/prctl.h>
2404     ]], [[
2405         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2406     ]])
2407   ],[AC_MSG_RESULT([yes])
2408      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2409      frr_ac_keepcaps="yes"
2410   ],[AC_MSG_RESULT(no)
2411   ])
2412   if test "$frr_ac_keepcaps" = "yes"; then
2413     AC_CHECK_HEADERS([sys/capability.h])
2414   fi
2415   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2416     AC_CHECK_LIB([cap], [cap_init],
2417       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2418        LIBCAP="-lcap"
2419        frr_ac_lcaps="yes"]
2420     )
2421   fi
2422   if test "$frr_ac_scaps" = "yes" \
2423        -o "$frr_ac_lcaps" = "yes"; then
2424     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2425   fi
2426
2427   case "$host_os" in
2428   linux*)
2429     if test "$enable_clippy_only" != "yes"; then
2430     if test "$frr_ac_lcaps" != "yes"; then
2431       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2432     fi
2433     fi
2434     ;;
2435   esac
2436 else
2437   case "$host_os" in
2438   linux*)
2439     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2440     ;;
2441   esac
2442 fi
2443 AC_SUBST([LIBCAP])
2444
2445 dnl ---------------------------
2446 dnl check for glibc 'backtrace'
2447 dnl ---------------------------
2448 if test "$enable_backtrace" != "no" ; then
2449   backtrace_ok=no
2450   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2451     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2452     backtrace_ok=yes
2453   ], [
2454     true
2455   ])
2456
2457   if test "$backtrace_ok" = "no"; then
2458     AC_CHECK_HEADER([unwind.h], [
2459       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2460         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2461         backtrace_ok=yes
2462       ])
2463     ])
2464   fi
2465
2466   if test "$backtrace_ok" = "no"; then
2467     AC_CHECK_HEADER([execinfo.h], [
2468       AC_SEARCH_LIBS([backtrace], [execinfo], [
2469         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2470         backtrace_ok=yes
2471       ],, [-lm])
2472     ])
2473   fi
2474
2475   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2476     dnl user explicitly requested backtrace but we failed to find support
2477     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2478   fi
2479 fi
2480
2481 dnl -----------------------------------------
2482 dnl check for malloc mallinfo struct and call
2483 dnl this must try and link using LIBS, in
2484 dnl order to check no alternative allocator
2485 dnl has been specified, which might not provide
2486 dnl mallinfo
2487 dnl -----------------------------------------
2488 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2489
2490 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2491   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2492 #ifdef HAVE_MALLOC_H
2493 #include <malloc.h>
2494 #endif
2495 #ifdef HAVE_MALLOC_NP_H
2496 #include <malloc_np.h>
2497 #endif
2498 #ifdef HAVE_MALLOC_MALLOC_H
2499 #include <malloc/malloc.h>
2500 #endif
2501 ]], [[
2502 struct mallinfo ac_x; ac_x = mallinfo ();
2503 ]])], [
2504     frr_cv_mallinfo=yes
2505   ], [
2506     frr_cv_mallinfo=no
2507   ])
2508 ])
2509 if test "$frr_cv_mallinfo" = "yes"; then
2510   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2511 fi
2512
2513 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2514   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2515 #ifdef HAVE_MALLOC_H
2516 #include <malloc.h>
2517 #endif
2518 #ifdef HAVE_MALLOC_NP_H
2519 #include <malloc_np.h>
2520 #endif
2521 #ifdef HAVE_MALLOC_MALLOC_H
2522 #include <malloc/malloc.h>
2523 #endif
2524 ]], [[
2525 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2526 ]])], [
2527     frr_cv_mallinfo2=yes
2528   ], [
2529     frr_cv_mallinfo2=no
2530   ])
2531 ])
2532 if test "$frr_cv_mallinfo2" = "yes"; then
2533   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2534 fi
2535
2536 AC_MSG_CHECKING([whether malloc_usable_size is available])
2537 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2538 #ifdef HAVE_MALLOC_H
2539 #include <malloc.h>
2540 #endif
2541 #ifdef HAVE_MALLOC_MALLOC_H
2542 #include <malloc/malloc.h>
2543 #endif
2544 ]], [[
2545 size_t ac_x; ac_x = malloc_usable_size(NULL);
2546 ]])], [
2547   AC_MSG_RESULT([yes])
2548   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2549 ], [
2550   AC_MSG_RESULT([no])
2551
2552   AC_MSG_CHECKING([whether malloc_size is available])
2553   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2554 #ifdef HAVE_MALLOC_H
2555 #include <malloc.h>
2556 #endif
2557 #ifdef HAVE_MALLOC_MALLOC_H
2558 #include <malloc/malloc.h>
2559 #endif
2560 ]], [[
2561 size_t ac_x; ac_x = malloc_size(NULL);
2562 ]])], [
2563     AC_MSG_RESULT([yes])
2564     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2565   ], [
2566     AC_MSG_RESULT([no])
2567   ])
2568 ])
2569
2570 dnl ----------
2571 dnl configure date
2572 dnl ----------
2573 dev_version=`echo $VERSION | grep dev`
2574 #don't expire deprecated code in non 'dev' branch
2575 if test "$dev_version" = ""; then
2576    CONFDATE=0
2577 else
2578    CONFDATE=`date '+%Y%m%d'`
2579 fi
2580 AC_SUBST([CONFDATE])
2581
2582 dnl ------------------------------
2583 dnl set paths for state directory
2584 dnl ------------------------------
2585 AC_MSG_CHECKING([directory to use for state file])
2586 if test "$prefix" = "NONE"; then
2587   frr_statedir_prefix="";
2588 else
2589   frr_statedir_prefix=${prefix}
2590 fi
2591 if test "$localstatedir" = '${prefix}/var'; then
2592   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2593                         ${frr_statedir_prefix}/var/adm dnl
2594                         ${frr_statedir_prefix}/etc dnl
2595                         /var/run        dnl
2596                         /var/adm        dnl
2597                         /etc            dnl
2598                         /dev/null;
2599   do
2600     test -d $FRR_STATE_DIR && break
2601   done
2602   frr_statedir=$FRR_STATE_DIR
2603 else
2604   frr_statedir=${localstatedir}
2605 fi
2606 if test "$frr_statedir" = "/dev/null"; then
2607     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2608 fi
2609 AC_MSG_RESULT([${frr_statedir}])
2610 AC_SUBST([frr_statedir])
2611
2612 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2613 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2614 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2615 AC_DEFINE_UNQUOTED([OSPFD_GR_STATE], ["$frr_statedir%s/ospfd-gr.json"], [ospfd GR state information])
2616 AC_DEFINE_UNQUOTED([OSPF6D_GR_STATE], ["$frr_statedir/ospf6d-gr.json"], [ospf6d GR state information])
2617 AC_DEFINE_UNQUOTED([OSPF6_AUTH_SEQ_NUM_FILE], ["$frr_statedir/ospf6d-at-seq-no.dat"], [ospf6d AT Sequence number information])
2618 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2619 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2620
2621 dnl autoconf does this, but it does it too late...
2622 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2623 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2624
2625 dnl get the full path, recursing through variables...
2626 vtysh_bin="$bindir/vtysh"
2627 for I in 1 2 3 4 5 6 7 8 9 10; do
2628         eval vtysh_bin="\"$vtysh_bin\""
2629 done
2630 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2631 AC_SUBST([vtysh_bin])
2632
2633 CFG_SYSCONF="$sysconfdir"
2634 CFG_SBIN="$sbindir"
2635 CFG_STATE="$frr_statedir"
2636 CFG_MODULE="$moduledir"
2637 CFG_YANGMODELS="$yangmodelsdir"
2638 CFG_SCRIPT="$scriptdir"
2639 for I in 1 2 3 4 5 6 7 8 9 10; do
2640         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2641         eval CFG_SBIN="\"$CFG_SBIN\""
2642         eval CFG_STATE="\"$CFG_STATE\""
2643         eval CFG_MODULE="\"$CFG_MODULE\""
2644         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2645         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2646 done
2647 AC_SUBST([CFG_SYSCONF])
2648 AC_SUBST([CFG_SBIN])
2649 AC_SUBST([CFG_STATE])
2650 AC_SUBST([CFG_MODULE])
2651 AC_SUBST([CFG_SCRIPT])
2652 AC_SUBST([CFG_YANGMODELS])
2653 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2654 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2655 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2656 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2657
2658 dnl various features
2659 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2660 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2661 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2662 dnl northbound
2663 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2664 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2665 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2666 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2667 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2668 dnl plugins
2669 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2670 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2671 AM_CONDITIONAL([IRDP], [$IRDP])
2672 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2673 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2674 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2675
2676 dnl PCEP plugin
2677 AS_IF([test "$enable_pathd" != "no"], [
2678        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2679        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2680        ])
2681 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2682 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2683 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2684 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2685
2686 dnl daemons
2687 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2688 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2689 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2690 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2691 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2692 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2693 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2694 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2695 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2696 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2697 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2698 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2699 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2700 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2701 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2702 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2703 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2704 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2705 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2706 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2707 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2708 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2709 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2710
2711 AC_CONFIG_FILES([Makefile],[
2712         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2713         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2714 ], [
2715         PYTHON="$PYTHON"
2716         enable_dev_build="$enable_dev_build"
2717 ])
2718
2719 AC_CONFIG_FILES([
2720           config.version
2721           redhat/frr.spec
2722           alpine/APKBUILD
2723           snapcraft/snapcraft.yaml
2724           lib/version.h
2725           tests/lib/cli/test_cli.refout
2726           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2727           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2728           pkgsrc/eigrpd.sh])
2729
2730 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2731 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2732 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2733 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2734 AC_CONFIG_FILES([tools/frrcommon.sh])
2735 AC_CONFIG_FILES([tools/frr.service])
2736 AC_CONFIG_FILES([tools/frr@.service])
2737
2738 AS_IF([test "$with_pkg_git_version" = "yes"], [
2739     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2740         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2741         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2742                 "${ac_abs_top_srcdir}" \
2743                 > "${dst}.tmp"
2744         test -f "$dst" \
2745                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2746                 && rm "${dst}.tmp" \
2747                 || mv "${dst}.tmp" "${dst}"
2748     ], [
2749         PERL="$PERL"
2750     ])
2751 ])
2752
2753 ## Hack, but working solution to avoid rebuilding of frr.info.
2754 ## It's already in CVS until texinfo 4.7 is more common.
2755 AC_OUTPUT
2756
2757 if test "$enable_rpath" = "yes" ; then
2758         true
2759 else
2760         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2761         sed -e 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool > libtool.sed && cat libtool.sed > libtool
2762         sed -e 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g'         libtool > libtool.sed && cat libtool.sed > libtool
2763         test -f libtool.sed && rm libtool.sed
2764 fi
2765
2766 echo "
2767 FRRouting configuration
2768 ------------------------------
2769 FRR version             : ${PACKAGE_VERSION}
2770 host operating system   : ${host_os}
2771 source code location    : ${srcdir}
2772 compiler                : ${CC}
2773 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2774 make                    : ${MAKE-make}
2775 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2776 state file directory    : ${frr_statedir}
2777 config file directory   : `eval echo \`echo ${sysconfdir}\``
2778 module directory        : ${CFG_MODULE}
2779 script directory        : ${CFG_SCRIPT}
2780 user to run as          : ${enable_user}
2781 group to run as         : ${enable_group}
2782 group for vty sockets   : ${enable_vty_group}
2783 config file mask        : ${enable_configfile_mask}
2784 log file mask           : ${enable_logfile_mask}
2785 zebra protobuf enabled  : ${enable_protobuf:-no}
2786 vici socket path        : ${vici_socket}
2787
2788 The above user and group must have read/write access to the state file
2789 directory and to the config files in the config file directory."
2790
2791 if test -n "$enable_datacenter"; then
2792   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2793 fi
2794 if test -n "$enable_time_check"; then
2795   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2796 fi
2797 if test -n "$enable_cpu_time"; then
2798   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2799 fi
2800
2801 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2802   AC_MSG_WARN([sphinx is missing but required to build documentation])
2803 fi
2804 if test "$frr_py_mod_pytest" = "false"; then
2805   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2806 fi