configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.3-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 hosttools_clippy="false"
  29 build_clippy="true"
  30
  31 dnl case 1: external clippy
  32 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  33   if test "$enable_clippy_only" == "yes"; then
  34     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  35   fi
  36
  37   CLIPPY="$with_clippy"
  38   build_clippy="false"
  39   if test ! -x "$with_clippy"; then
  40     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  41   fi
  42
  43 dnl case 2: cross-compiling internal clippy
  44 elif test "$host" != "$build"; then
  45   if test "$srcdir" = "."; then
  46     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  47   fi
  48   test -d hosttools || mkdir hosttools
  49   abssrc="`cd \"${srcdir}\"; pwd`"
  50
  51   AC_MSG_NOTICE([...])
  52   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  53   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  54   AC_MSG_NOTICE([...])
  55
  56   (
  57     for var in $ac_precious_vars; do
  58       dnl special cases
  59       case "$var" in
  60       YACC|YFLAGS) continue;;
  61       PYTHON*)     retain=true;;
  62       *)           retain=false;
  63       esac
  64
  65       eval "hostvar=\"\${HOST_$var}\""
  66       eval "targetvar=\"\${$var}\""
  67       if test -n "$hostvar"; then
  68         eval "$var='$hostvar'"
  69         _AS_ECHO_LOG([host $var='$hostvar'])
  70       elif $retain; then
  71         _AS_ECHO_LOG([host retain $var='$targetvar'])
  72       else
  73         eval "unset $var"
  74         _AS_ECHO_LOG([host unset $var])
  75       fi
  76     done
  77     cd hosttools
  78     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  79   ) || exit 1
  80
  81   AC_MSG_NOTICE([...])
  82   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  83   AC_MSG_NOTICE([...])
  84
  85   build_clippy="false"
  86   hosttools_clippy="true"
  87   CLIPPY="hosttools/lib/clippy"
  88
  89 dnl case 3: normal build internal clippy
  90 else
  91   CLIPPY="lib/clippy\$(EXEEXT)"
  92 fi
  93 AC_SUBST([CLIPPY])
  94 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  95 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
  96 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
  97
  98 # Disable portability warnings -- our automake code (in particular
  99 # common.am) uses some constructs specific to gmake.
 100 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 101 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 102 AM_SILENT_RULES([yes])
 103 AC_CONFIG_HEADERS([config.h])
 104
 105 AC_PATH_PROG([PERL], [perl])
 106 PKG_PROG_PKG_CONFIG
 107
 108 dnl default is to match previous behavior
 109 exampledir=${sysconfdir}
 110 AC_ARG_ENABLE([exampledir],
 111           AS_HELP_STRING([--enable-exampledir],
 112                          [specify alternate directory for examples]),
 113                          exampledir="$enableval",)
 114 dnl XXX add --exampledir to autoconf standard directory list somehow
 115 AC_SUBST([exampledir])
 116
 117 dnl default is to match previous behavior
 118 pkgsrcrcdir=""
 119 AC_ARG_ENABLE([pkgsrcrcdir],
 120           AS_HELP_STRING([--enable-pkgsrcrcdir],
 121                          [specify directory for rc.d scripts]),
 122                          pkgsrcrcdir="$enableval",)
 123 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 124 AC_SUBST([pkgsrcrcdir])
 125 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
 126
 127 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 128         moduledir="$withval"
 129 ], [
 130         moduledir="\${libdir}/frr/modules"
 131 ])
 132 AC_SUBST([moduledir], [$moduledir])
 133
 134
 135 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 136         yangmodelsdir="$withval"
 137 ], [
 138         yangmodelsdir="\${datarootdir}/yang"
 139 ])
 140 AC_SUBST([yangmodelsdir])
 141
 142 AC_ARG_ENABLE(tcmalloc,
 143         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 144 [case "${enableval}" in
 145   yes) tcmalloc_enabled=true
 146 LIBS="$LIBS -ltcmalloc_minimal"
 147  ;;
 148   no)  tcmalloc_enabled=false ;;
 149   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 150 esac],[tcmalloc_enabled=false])
 151
 152
 153 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 154 dnl flag determination logic.
 155 CFLAGS="${CFLAGS:-}"
 156
 157 dnl --------------------
 158 dnl Check CC and friends
 159 dnl --------------------
 160 dnl note orig_cflags is also used further down
 161 orig_cflags="$CFLAGS"
 162 orig_cxxflags="$CXXFLAGS"
 163 AC_LANG([C])
 164 AC_PROG_CC
 165 AC_PROG_CPP
 166 AC_PROG_CXX
 167 AM_PROG_CC_C_O
 168 dnl remove autoconf default "-g -O2"
 169 CFLAGS="$orig_cflags"
 170 CXXFLAGS="$orig_cxxflags"
 171 AC_PROG_CC_C99
 172 dnl NB: see C11 below
 173
 174 PKG_PROG_PKG_CONFIG
 175
 176 dnl it's 2019, sed is sed.
 177 SED=sed
 178 AC_SUBST([SED])
 179
 180 dnl try and enable CFLAGS that are useful for FRR
 181 dnl - specifically, options to control warnings
 182
 183 AC_USE_SYSTEM_EXTENSIONS
 184 AC_DEFUN([AC_C_FLAG], [{
 185     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+],[____])])
 186     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 187         AC_LANG_PUSH([C])
 188         ac_c_flag_save="$CFLAGS"
 189         CFLAGS="$CFLAGS $1"
 190         AC_COMPILE_IFELSE(
 191                 [AC_LANG_PROGRAM([[]])],
 192                 [
 193                         cachename=yes
 194                 ], [
 195                         cachename=no
 196                 ])
 197         CFLAGS="$ac_c_flag_save"
 198         AC_LANG_POP([C])
 199     ])
 200     if test "${cachename}" = yes; then
 201         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 202     else
 203         :
 204         $2
 205     fi
 206     m4_popdef([cachename])
 207 }])
 208
 209 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 210         AC_LANG_PUSH([C])
 211         ac_cflags_save="$CFLAGS"
 212         ac_libs_save="$LIBS"
 213         CFLAGS="$CFLAGS $1"
 214         LIBS="$LIBS $2"
 215         AC_LINK_IFELSE(
 216                 [$3],
 217                 [
 218                         CFLAGS="$ac_cflags_save"
 219                         LIBS="$ac_libs_save"
 220                         m4_default([$5], [
 221                                 AC_MSG_RESULT([yes])
 222                         ])
 223                 ], [
 224                         CFLAGS="$ac_cflags_save"
 225                         LIBS="$ac_libs_save"
 226                         m4_default([$4], [
 227                                 AC_MSG_RESULT([no])
 228                         ])
 229                 ])
 230         AC_LANG_POP([C])
 231         }])
 232
 233 dnl ICC won't bail on unknown options without -diag-error 10006
 234 dnl need to do this first so we get useful results for the other options
 235 AC_C_FLAG([-diag-error 10006])
 236
 237 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 238 ac_cc="$CC"
 239 CC="${CC% -std=gnu99}"
 240 CC="${CC% -std=c99}"
 241
 242 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 243
 244 dnl if the user has specified any CFLAGS, override our settings
 245 if test "x${enable_gcov}" = "xyes"; then
 246    if test "z$orig_cflags" = "z"; then
 247       AC_C_FLAG([-coverage])
 248       AC_C_FLAG([-O0])
 249    fi
 250
 251    LDFLAGS="${LDFLAGS} -lgcov"
 252 elif test "x${enable_dev_build}" = "xyes"; then
 253    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 254    if test "z$orig_cflags" = "z"; then
 255       AC_C_FLAG([-g3])
 256       AC_C_FLAG([-O0])
 257    fi
 258    if test "x${enable_lua}" = "xyes"; then
 259       AX_PROG_LUA([5.3])
 260       AX_LUA_HEADERS
 261       AX_LUA_LIBS([
 262          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 263          LIBS="$LIBS $LUA_LIB"
 264       ])
 265    fi
 266 else
 267    if test "x${enable_lua}" = "xyes"; then
 268       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 269    fi
 270    if test "z$orig_cflags" = "z"; then
 271       AC_C_FLAG([-g])
 272       AC_C_FLAG([-O2])
 273    fi
 274 fi
 275 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 276
 277 dnl always want these CFLAGS
 278 AC_C_FLAG([-fno-omit-frame-pointer])
 279 AC_C_FLAG([-funwind-tables])
 280 AC_C_FLAG([-Wall])
 281 AC_C_FLAG([-Wextra])
 282 AC_C_FLAG([-Wmissing-prototypes])
 283 AC_C_FLAG([-Wmissing-declarations])
 284 AC_C_FLAG([-Wpointer-arith])
 285 AC_C_FLAG([-Wbad-function-cast])
 286 AC_C_FLAG([-Wwrite-strings])
 287 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 288   AC_C_FLAG([-Wcast-qual])
 289   AC_C_FLAG([-Wstrict-prototypes])
 290   AC_C_FLAG([-Wmissing-noreturn])
 291   AC_C_FLAG([-Wmissing-format-attribute])
 292   AC_C_FLAG([-Wunreachable-code])
 293   AC_C_FLAG([-Wpacked])
 294   AC_C_FLAG([-Wpadded])
 295   AC_C_FLAG([-Wshadow])
 296 else
 297   AC_C_FLAG([-Wno-unused-result])
 298 fi
 299 AC_C_FLAG([-Wno-unused-parameter])
 300 AC_C_FLAG([-Wno-missing-field-initializers])
 301
 302 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 303 AC_SUBST([CXX_COMPAT_CFLAGS])
 304
 305 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 306 dnl for some reason the string consts get 'promoted' to char *,
 307 dnl triggering a const to non-const conversion warning.
 308 AC_C_FLAG([-diag-disable 3179])
 309
 310 if test x"${enable_werror}" = x"yes" ; then
 311   WERROR="-Werror"
 312 fi
 313 AC_SUBST([WERROR])
 314
 315 SAN_FLAGS=""
 316 if test "$enable_address_sanitizer" = "yes"; then
 317   AC_C_FLAG([-fsanitize=address], [
 318     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 319   ], [
 320     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 321   ])
 322 fi
 323 if test "$enable_thread_sanitizer" = "yes"; then
 324   AC_C_FLAG([-fsanitize=thread], [
 325     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 326   ], [
 327     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 328   ])
 329 fi
 330 if test "$enable_memory_sanitizer" = "yes"; then
 331   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 332     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 333   ], [
 334     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 335   ])
 336 fi
 337 AC_SUBST([SAN_FLAGS])
 338
 339 dnl ----------
 340 dnl Essentials
 341 dnl ----------
 342
 343 AX_PTHREAD([
 344   CC="$PTHREAD_CC"
 345   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 346   LIBS="$PTHREAD_LIBS $LIBS"
 347 ], [
 348   AC_MSG_FAILURE([This FRR version needs pthreads])
 349 ])
 350
 351 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 352                 [frr_cv_pthread_condattr_setclock=yes],
 353                 [frr_cv_pthread_condattr_setclock=no])
 354 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 355   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 356 fi
 357
 358 dnl --------------
 359 dnl Check programs
 360 dnl --------------
 361 AC_PROG_INSTALL
 362 AC_PROG_LN_S
 363 AC_CHECK_TOOL([AR], [ar])
 364
 365 dnl -------
 366 dnl libtool
 367 dnl -------
 368 AC_ARG_ENABLE([static-bin],
 369   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 370 LT_INIT
 371 _LT_CONFIG_LIBTOOL([
 372   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 373     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 374 ])
 375 if test "$enable_static_bin" = "yes"; then
 376   AC_LDFLAGS="-static"
 377   if test "$enable_static" != "yes"; then
 378     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 379   fi
 380 fi
 381 if test "$enable_shared" != "yes"; then
 382   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 383 fi
 384 AC_SUBST([AC_LDFLAGS])
 385 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 386
 387 dnl $AR and $RANLIB are set by LT_INIT above
 388 AC_MSG_CHECKING([whether $AR supports D option])
 389 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 390   AC_MSG_RESULT([yes])
 391   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 392   ARFLAGS="crD"
 393   AR_FLAGS="crD"
 394 else
 395   AC_MSG_RESULT([no])
 396   ARFLAGS="cru"
 397   AR_FLAGS="cru"
 398 fi
 399 AC_SUBST([ARFLAGS])
 400 AC_SUBST([AR_FLAGS])
 401
 402 AC_MSG_CHECKING([whether $RANLIB supports D option])
 403 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 404   if grep -q -- '-D' conftest.err; then
 405     AC_MSG_RESULT([no])
 406   else
 407     AC_MSG_RESULT([yes])
 408     RANLIB="$RANLIB -D"
 409   fi
 410 else
 411   AC_MSG_RESULT([no])
 412 fi
 413 AC_SUBST([RANLIB])
 414
 415 test -f conftest.err && rm conftest.err
 416 test -f conftest.a && rm conftest.a
 417
 418 dnl ----------------------
 419 dnl Packages configuration
 420 dnl ----------------------
 421 if test -f config.version; then
 422   . ./config.version
 423 elif test -f "${srcdir}/config.version"; then
 424   . "${srcdir}/config.version"
 425 fi
 426 AC_ARG_WITH([pkg-extra-version],
 427   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 428   if test "$withval" = "no"; then
 429     EXTRAVERSION=
 430   else
 431     EXTRAVERSION=$withval
 432   fi
 433 ], [])
 434 AC_ARG_WITH([pkg-git-version],
 435         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 436         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 437 AC_ARG_WITH([clippy],
 438   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 439 AC_ARG_WITH([vtysh_pager],
 440         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 441         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 442 AC_ARG_ENABLE([vtysh],
 443   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 444 AC_ARG_ENABLE([doc],
 445   AS_HELP_STRING([--disable-doc], [do not build docs]))
 446 AC_ARG_ENABLE([doc-html],
 447   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 448 AC_ARG_ENABLE([zebra],
 449   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 450 AC_ARG_ENABLE([bgpd],
 451   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 452 AC_ARG_ENABLE([ripd],
 453   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 454 AC_ARG_ENABLE([ripngd],
 455   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 456 AC_ARG_ENABLE([ospfd],
 457   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 458 AC_ARG_ENABLE([ospf6d],
 459   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 460 AC_ARG_ENABLE([ldpd],
 461   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 462 AC_ARG_ENABLE([nhrpd],
 463   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 464 AC_ARG_ENABLE([eigrpd],
 465   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 466 AC_ARG_ENABLE([babeld],
 467   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 468 AC_ARG_ENABLE([watchfrr],
 469   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 470 AC_ARG_ENABLE([isisd],
 471   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 472 AC_ARG_ENABLE([pimd],
 473   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 474 AC_ARG_ENABLE([pbrd],
 475   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 476 AC_ARG_ENABLE([sharpd],
 477   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 478 AC_ARG_ENABLE([staticd],
 479   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 480 AC_ARG_ENABLE([fabricd],
 481   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 482 AC_ARG_ENABLE([vrrpd],
 483   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 484 AC_ARG_ENABLE([bgp-announce],
 485   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 486 AC_ARG_ENABLE([bgp-vnc],
 487   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 488 AC_ARG_ENABLE([bgp-bmp],
 489   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 490 AC_ARG_ENABLE([snmp],
 491   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 492 AC_ARG_ENABLE([config_rollbacks],
 493   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 494 AC_ARG_ENABLE([confd],
 495   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 496 AC_ARG_ENABLE([sysrepo],
 497   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 498 AC_ARG_ENABLE([grpc],
 499   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 500 AC_ARG_ENABLE([zeromq],
 501   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 502 AC_ARG_WITH([libpam],
 503   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 504 AC_ARG_ENABLE([ospfapi],
 505   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 506 AC_ARG_ENABLE([ospfclient],
 507   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 508                           (this is the default if --disable-ospfapi is set)]))
 509 AC_ARG_ENABLE([multipath],
 510   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 511 AC_ARG_ENABLE([user],
 512   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 513 AC_ARG_ENABLE([group],
 514   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 515 AC_ARG_ENABLE([vty_group],
 516   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 517 AC_ARG_ENABLE([configfile_mask],
 518   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 519 AC_ARG_ENABLE([logfile_mask],
 520   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 521 AC_ARG_ENABLE([shell_access],
 522   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 523 AC_ARG_ENABLE([realms],
 524   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 525 AC_ARG_ENABLE([rtadv],
 526   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 527 AC_ARG_ENABLE([irdp],
 528   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 529 AC_ARG_ENABLE([capabilities],
 530   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 531 AC_ARG_ENABLE([rusage],
 532   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 533 AC_ARG_ENABLE([gcc_ultra_verbose],
 534   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 535 AC_ARG_ENABLE([backtrace],
 536   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 537 AC_ARG_ENABLE([time-check],
 538   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 539 AC_ARG_ENABLE([cpu-time],
 540   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 541 AC_ARG_ENABLE([pcreposix],
 542   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 543 AC_ARG_ENABLE([fpm],
 544   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 545 AC_ARG_ENABLE([systemd],
 546   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 547 AC_ARG_ENABLE([werror],
 548   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 549 AC_ARG_ENABLE([cumulus],
 550   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 551 AC_ARG_ENABLE([datacenter],
 552   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 553 AC_ARG_ENABLE([fuzzing],
 554   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 555 AC_ARG_ENABLE([netlink_fuzzing],
 556   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 557 AC_ARG_ENABLE([rr-semantics],
 558   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 559 AC_ARG_ENABLE([protobuf],
 560   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 561 AC_ARG_ENABLE([oldvpn_commands],
 562   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 563 AC_ARG_ENABLE([rpki],
 564   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 565 AC_ARG_ENABLE([clippy-only],
 566   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 567 AC_ARG_ENABLE([numeric_version],
 568   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 569 AC_ARG_ENABLE([gcov],
 570   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 571 AC_ARG_ENABLE([bfdd],
 572   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 573 AC_ARG_ENABLE([address-sanitizer],
 574   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 575 AC_ARG_ENABLE([thread-sanitizer],
 576   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 577 AC_ARG_ENABLE([memory-sanitizer],
 578   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 579 AC_ARG_WITH([crypto],
 580   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 581
 582 #if openssl, else use the internal
 583 AS_IF([test x"${with_crypto}" = x"openssl"], [
 584 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 585 if test $ac_cv_lib_crypto_EVP_DigestInit = no; then
 586   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 587 else
 588   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 589 fi
 590 ], [test x"${with_crypto}" = x"internal" || test x"${with_crypto}" = x"" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 591 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 592 )
 593
 594 AS_IF([test "${enable_clippy_only}" != "yes"], [
 595 AC_CHECK_HEADERS([json-c/json.h])
 596 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 597 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 598   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 599   if test "$ac_cv_lib_json_json_object_get" = no; then
 600       AC_MSG_ERROR([libjson is needed to compile])
 601   fi
 602 fi
 603 ])
 604
 605 AC_ARG_ENABLE([dev_build],
 606     AS_HELP_STRING([--enable-dev-build], [build for development]))
 607
 608 AC_ARG_ENABLE([lua],
 609     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 610
 611 if test x"${enable_time_check}" != x"no" ; then
 612   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 613     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 614   else
 615     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 616   fi
 617 fi
 618
 619 case "${enable_cpu_time}" in
 620   "no")
 621   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 622   ;;
 623   "*")
 624   ;;
 625 esac
 626
 627 case "${enable_systemd}" in
 628   "no") ;;
 629   "yes")
 630   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 631   if test $ac_cv_lib_systemd_sd_notify = no; then
 632     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 633   else
 634     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 635   fi
 636   ;;
 637   "*") ;;
 638 esac
 639
 640 if test "${enable_rr_semantics}" != "no" ; then
 641   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 642 fi
 643
 644 if test "${enable_datacenter}" = "yes" ; then
 645   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 646   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 647   DFLT_NAME="datacenter"
 648 else
 649   DFLT_NAME="traditional"
 650 fi
 651
 652 if test "${enable_fuzzing}" = "yes" ; then
 653   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 654 fi
 655
 656 if test "${enable_netlink_fuzzing}" = "yes" ; then
 657   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 658 fi
 659
 660 if test "${enable_cumulus}" = "yes" ; then
 661   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 662 fi
 663
 664 AC_SUBST([DFLT_NAME])
 665 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 666
 667 if test "${enable_shell_access}" = "yes"; then
 668    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 669 fi
 670
 671 #
 672 # Python for clippy
 673 #
 674
 675 AS_IF([test "$host" = "$build"], [
 676   FRR_PYTHON_DEV
 677 ], [
 678   FRR_PYTHON
 679 ])
 680
 681 FRR_PYTHON_MODULES([pytest])
 682
 683 if test "${enable_doc}" != "no"; then
 684   FRR_PYTHON_MODULES([sphinx], , [
 685     if test "${enable_doc}" = "yes"; then
 686       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 687     fi
 688   ])
 689 fi
 690 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" != "false"])
 691 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
 692
 693 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 694   PYSPHINX="-m sphinx"
 695 ], [
 696   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 697 ])
 698 AC_SUBST([PYSPHINX])
 699
 700 #
 701 # Logic for old vpn commands support.
 702 #
 703 if test "$enable_oldvpn_commands" = "yes"; then
 704    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 705 fi
 706
 707 #
 708 # End of logic for protobuf support.
 709 #
 710
 711 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 712 if test "${enable_rtadv}" != "no"; then
 713   AC_MSG_RESULT([yes])
 714   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 715 else
 716   AC_MSG_RESULT([no])
 717 fi
 718
 719 if test x"${enable_user}" = x"no"; then
 720   enable_user=""
 721 else
 722   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 723     enable_user="frr"
 724   fi
 725   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 726 fi
 727
 728 if test x"${enable_group}" = x"no"; then
 729   enable_group=""
 730 else
 731   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 732     enable_group="frr"
 733   fi
 734   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 735 fi
 736
 737 if test x"${enable_vty_group}" = x"yes" ; then
 738   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 739 elif test x"${enable_vty_group}" != x""; then
 740   if test x"${enable_vty_group}" != x"no"; then
 741     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 742   fi
 743 fi
 744 AC_SUBST([enable_user])
 745 AC_SUBST([enable_group])
 746 AC_SUBST([enable_vty_group])
 747
 748 enable_configfile_mask=${enable_configfile_mask:-0600}
 749 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 750
 751 enable_logfile_mask=${enable_logfile_mask:-0600}
 752 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 753
 754 MPATH_NUM=16
 755
 756 case "${enable_multipath}" in
 757   0)
 758     MPATH_NUM=64
 759     ;;
 760   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 761     MPATH_NUM="${enable_multipath}"
 762     ;;
 763   "")
 764     ;;
 765   *)
 766     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 767     ;;
 768 esac
 769
 770 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 771
 772 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 773
 774 dnl --------------------
 775 dnl Enable code coverage
 776 dnl --------------------
 777 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 778
 779 dnl ------------------------------------
 780 dnl Alpine only accepts numeric versions
 781 dnl ------------------------------------
 782 if test "x${enable_numeric_version}" != "x" ; then
 783   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 784   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 785 fi
 786
 787 dnl -----------------------------------
 788 dnl Add extra version string to package
 789 dnl name, string and version fields.
 790 dnl -----------------------------------
 791 if test "x${EXTRAVERSION}" != "x" ; then
 792   VERSION="${VERSION}${EXTRAVERSION}"
 793   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 794   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 795   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 796 fi
 797 AC_SUBST([EXTRAVERSION])
 798
 799 if test "x$with_pkg_git_version" = "xyes"; then
 800         if test -d "${srcdir}/.git"; then
 801                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 802         else    with_pkg_git_version="no"
 803                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 804         fi
 805 fi
 806 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 807
 808 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 809 if test "x${OBJCOPY}" != "x:"; then
 810   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 811     frr_cv_interp=""
 812     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 813       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 814         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 815       fi
 816       test -f conftest.interp && rm conftest.interp
 817     ])
 818   ])
 819 fi
 820 if test -n "$frr_cv_interp"; then
 821   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 822 fi
 823
 824 dnl -------------------------
 825 dnl Check other header files.
 826 dnl -------------------------
 827 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 828         linux/version.h asm/types.h])
 829
 830 ac_stdatomic_ok=false
 831 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 832 AC_CHECK_HEADER([stdatomic.h],[
 833
 834   AC_MSG_CHECKING([whether _Atomic qualifier works])
 835   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 836 #include <stdatomic.h>
 837 int main(int argc, char **argv) {
 838   _Atomic int i = 0;
 839   return i;
 840 }
 841 ]])], [
 842     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 843     AC_MSG_RESULT([yes])
 844     ac_stdatomic_ok=true
 845   ], [
 846     AC_MSG_RESULT([no])
 847   ])
 848 ])
 849
 850 AS_IF([$ac_stdatomic_ok], [true], [
 851   AC_MSG_CHECKING([for __atomic_* builtins])
 852   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 853 int main(int argc, char **argv) {
 854   volatile int i = 1;
 855   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 856   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 857 }
 858 ]])], [
 859     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 860     AC_MSG_RESULT([yes])
 861   ], [
 862     AC_MSG_RESULT([no])
 863
 864     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 865     AC_MSG_CHECKING([for __sync_* builtins])
 866     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 867 int main(int argc, char **argv) {
 868   volatile int i = 1;
 869   __sync_fetch_and_sub (&i, 1);
 870   return __sync_val_compare_and_swap (&i, 0, 1);
 871 }
 872 ]])], [
 873       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 874       AC_MSG_RESULT([yes])
 875
 876       AC_MSG_CHECKING([for __sync_swap builtin])
 877       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 878 int main(int argc, char **argv) {
 879   volatile int i = 1;
 880   return __sync_swap (&i, 2);
 881 }
 882 ]])], [
 883         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 884         AC_MSG_RESULT([yes])
 885       ], [
 886         AC_MSG_RESULT([no])
 887       ])
 888
 889     ], [
 890       AC_MSG_RESULT([no])
 891       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 892     ])
 893   ])
 894 ])
 895
 896 AC_CHECK_HEADERS([pthread_np.h],,, [
 897 #include <pthread.h>
 898 ])
 899 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 900
 901 needsync=true
 902
 903 AS_IF([$needsync], [
 904   dnl Linux
 905   AC_MSG_CHECKING([for Linux futex() support])
 906   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 907 #ifndef _GNU_SOURCE
 908 #define _GNU_SOURCE
 909 #endif
 910 #include <unistd.h>
 911 #include <limits.h>
 912 #include <sys/time.h>
 913 #include <sys/syscall.h>
 914 #include <linux/futex.h>
 915
 916 int main(void);
 917 ],
 918 [
 919 {
 920   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 921 }
 922 ])], [
 923     AC_MSG_RESULT([yes])
 924     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 925     needsync=false
 926   ], [
 927     AC_MSG_RESULT([no])
 928   ])
 929 ])
 930
 931 AS_IF([$needsync], [
 932   dnl FreeBSD
 933   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 934   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 935 #include <errno.h>
 936 #include <stdlib.h>
 937 #include <sys/types.h>
 938 #include <sys/umtx.h>
 939 int main(void);
 940 ],
 941 [
 942 {
 943   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
 944 }
 945 ])], [
 946     AC_MSG_RESULT([yes])
 947     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
 948     needsync=false
 949   ], [
 950     AC_MSG_RESULT([no])
 951   ])
 952 ])
 953
 954 AS_IF([$needsync], [
 955   dnl OpenBSD patch (not upstream at the time of writing this)
 956   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
 957   AC_MSG_CHECKING([for OpenBSD futex() support])
 958   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 959 #include <sys/futex.h>
 960 int main(void);
 961 ],
 962 [
 963 {
 964   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 965 }
 966 ])], [
 967     AC_MSG_RESULT([yes])
 968     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
 969     needsync=false
 970   ], [
 971     AC_MSG_RESULT([no])
 972   ])
 973 ])
 974
 975 dnl Utility macro to avoid retyping includes all the time
 976 m4_define([FRR_INCLUDES],
 977 [#ifdef SUNOS_5
 978 #define _POSIX_C_SOURCE 200809L
 979 #define __EXTENSIONS__
 980 #endif
 981 #include <stdio.h>
 982 #include <stdlib.h>
 983 #include <stddef.h>
 984 #include <sys/types.h>
 985 /* sys/conf.h depends on param.h on FBSD at least */
 986 #include <sys/param.h>
 987 /* Required for MAXSIG */
 988 #include <signal.h>
 989 #include <sys/socket.h>
 990 #ifdef __APPLE__
 991 # define __APPLE_USE_RFC_3542
 992 #endif
 993 #include <netinet/in.h>
 994 #include <sys/time.h>
 995 #include <time.h>
 996 #include <net/if.h>
 997 ])dnl
 998
 999 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1000 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1001 dnl an additional round for it.
1002
1003 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1004
1005 m4_define([FRR_INCLUDES],
1006 FRR_INCLUDES
1007 [#if HAVE_NET_IF_VAR_H
1008 # include <net/if_var.h>
1009 #endif
1010 ])dnl
1011
1012 AC_CHECK_HEADERS([netinet/in_var.h \
1013         net/if_dl.h net/netopt.h \
1014         inet/nd.h netinet/ip_icmp.h \
1015         sys/sysctl.h sys/sockio.h sys/conf.h],
1016         [], [], [FRR_INCLUDES])
1017
1018 AC_CHECK_HEADERS([ucontext.h], [], [],
1019 [#ifndef __USE_GNU
1020 #define __USE_GNU
1021 #endif /* __USE_GNU */
1022 FRR_INCLUDES
1023 ])
1024
1025 m4_define([UCONTEXT_INCLUDES],
1026 [#include <ucontext.h>])dnl
1027
1028 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1029   [], [], [UCONTEXT_INCLUDES])
1030 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1031   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1032    [], [], [UCONTEXT_INCLUDES])],
1033   [], [UCONTEXT_INCLUDES])
1034 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1035   [], [], [UCONTEXT_INCLUDES])
1036
1037 m4_define([FRR_INCLUDES],
1038 FRR_INCLUDES
1039 [
1040 #include <sys/un.h>
1041 #include <netinet/in_systm.h>
1042 #if HAVE_NETINET_IN_VAR_H
1043 # include <netinet/in_var.h>
1044 #endif
1045 #if HAVE_NET_IF_DL_H
1046 # include <net/if_dl.h>
1047 #endif
1048 #if HAVE_NET_NETOPT_H
1049 # include <net/netopt.h>
1050 #endif
1051 #include <net/route.h>
1052 #if HAVE_INET_ND_H
1053 # include <inet/nd.h>
1054 #endif
1055 #include <arpa/inet.h>
1056 /* Required for IDRP */
1057 #if HAVE_NETINET_IP_ICMP_H
1058 # include <netinet/ip_icmp.h>
1059 #endif
1060 ])dnl
1061
1062 dnl V6 headers are checked below, after we check for v6
1063
1064 AC_MSG_CHECKING([which operating system interface to use])
1065 case "$host_os" in
1066   sunos* | solaris2*)
1067     AC_MSG_RESULT([Solaris])
1068
1069     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1070     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1071     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1072
1073     AC_CHECK_LIB([socket], [main])
1074     AC_CHECK_LIB([nsl], [main])
1075     AC_CHECK_LIB([umem], [main])
1076     SOLARIS="solaris"
1077     AC_MSG_WARN([--Solaris support is being considered for deprecation, please let us know if you are still using this--])
1078     ;;
1079   linux*)
1080     AC_MSG_RESULT([Linux])
1081
1082     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1083     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1084     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1085
1086     dnl Linux has a compilation problem with mixing
1087     dnl netinet/in.h and linux/in6.h they are not
1088     dnl compatible.  There has been discussion on
1089     dnl how to fix it but no real progress on implementation
1090     dnl when they fix it, remove this
1091     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1092     ;;
1093   openbsd*)
1094     AC_MSG_RESULT([OpenBSD])
1095
1096     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1097     AC_DEFINE([KAME], [1], [KAME IPv6])
1098     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1099
1100     if test "x${enable_pimd}" != "xno"; then
1101       case "$host_os" in
1102       openbsd6.0)
1103         ;;
1104       openbsd[6-9]*)
1105         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1106         ;;
1107       esac
1108     fi
1109     ;;
1110   *)
1111     AC_MSG_RESULT([BSD])
1112
1113     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1114     AC_DEFINE([KAME], [1], [KAME IPv6])
1115     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1116     ;;
1117 esac
1118 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1119
1120 AC_SYS_LARGEFILE
1121
1122 dnl ------------------------
1123 dnl Integrated REALMS option
1124 dnl ------------------------
1125 if test "${enable_realms}" = "yes"; then
1126     case "$host_os" in
1127       linux*)
1128        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1129        ;;
1130       *)
1131        echo "Sorry, only Linux has REALMS support"
1132        exit 1
1133        ;;
1134     esac
1135 fi
1136
1137 dnl -------------------------------
1138 dnl Endian-ness check
1139 dnl -------------------------------
1140 AC_WORDS_BIGENDIAN
1141
1142 dnl ---------------
1143 dnl other functions
1144 dnl ---------------
1145 AC_CHECK_FUNCS([ \
1146         strlcat strlcpy \
1147         getgrouplist])
1148
1149 dnl ##########################################################################
1150 dnl LARGE if block spans a lot of "configure"!
1151 if test "${enable_clippy_only}" != "yes"; then
1152 dnl ##########################################################################
1153
1154 #
1155 # Logic for protobuf support.
1156 #
1157 if test "$enable_protobuf" = "yes"; then
1158   # Check for protoc & protoc-c
1159
1160   # protoc is not required, it's only for a "be nice" helper target
1161   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1162
1163   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1164   if test "$PROTOC_C" = "/bin/false"; then
1165     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1166   fi
1167
1168   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1169     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1170   ])
1171   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
1172     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
1173   ])
1174
1175   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1176 fi
1177
1178
1179 dnl ---------------------
1180 dnl Integrated VTY option
1181 dnl ---------------------
1182 case "${enable_vtysh}" in
1183 "no")
1184   VTYSH="";;
1185 *)
1186   VTYSH="vtysh";
1187   AC_DEFINE([VTYSH], [1], [VTY shell])
1188
1189   prev_libs="$LIBS"
1190   AC_CHECK_LIB([readline], [main], [
1191     LIBREADLINE="-lreadline"
1192   ], [
1193     dnl readline failed - it might be incorrectly linked and missing its
1194     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1195     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1196       LIBREADLINE="$ac_cv_search_tputs"
1197     ], [
1198       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1199     ])
1200
1201     dnl re-try with the lib we found above
1202     unset ac_cv_lib_readline_main
1203     AC_CHECK_LIB([readline], [main], [
1204       LIBREADLINE="-lreadline $LIBREADLINE"
1205     ], [
1206       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1207     ], [$LIBREADLINE])
1208   ], [])
1209   LIBS="$prev_libs"
1210
1211   AC_CHECK_HEADER([readline/history.h])
1212   if test $ac_cv_header_readline_history_h = no;then
1213     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1214   fi
1215   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1216   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1217     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1218   fi
1219   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1220   if test "$frr_cv_append_history" = yes; then
1221     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1222   fi
1223   ;;
1224 esac
1225 AC_SUBST([LIBREADLINE])
1226
1227 dnl ----------
1228 dnl PAM module
1229 dnl
1230 dnl FRR detects the PAM library it is built against by checking for a
1231 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1232 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1233 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1234 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1235 dnl of OpenPAM.
1236 dnl ----------
1237 if test "$with_libpam" = "yes"; then
1238   AC_CHECK_HEADER([security/pam_misc.h],
1239     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1240      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1241      pam_conv_func="misc_conv"
1242     ],
1243     [], FRR_INCLUDES)
1244   AC_CHECK_HEADER([security/openpam.h],
1245     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1246      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1247      pam_conv_func="openpam_ttyconv"
1248     ],
1249     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1250   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1251     AC_MSG_WARN([*** pam support will not be built ***])
1252     with_libpam="no"
1253   fi
1254 fi
1255
1256 if test "$with_libpam" = "yes"; then
1257 dnl took this test from proftpds configure.in and suited to our needs
1258 dnl -------------------------------------------------------------------------
1259 dnl
1260 dnl This next check looks funky due to a linker problem with some versions
1261 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1262 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1263 dnl with RedHat 6.2 and Debian 2.2 or better.
1264 AC_CHECK_LIB([pam], [pam_start],
1265   [AC_CHECK_LIB([pam], [$pam_conv_func],
1266     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1267      LIBPAM="-lpam"],
1268     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1269      LIBPAM="-lpam -lpam_misc"]
1270     )
1271   ],
1272
1273   [AC_CHECK_LIB([pam], [pam_end],
1274     [AC_CHECK_LIB([pam], [$pam_conv_func],
1275       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1276        LIBPAM="-lpam -ldl"],
1277       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1278        LIBPAM="-lpam -ldl -lpam_misc"]
1279      )
1280   ],AC_MSG_WARN([*** pam support will not be built ***]),
1281   [-ldl])
1282   ]
1283 )
1284 fi
1285 AC_SUBST([LIBPAM])
1286
1287 dnl -------------------------------
1288 dnl bgpd needs pow() and hence libm
1289 dnl -------------------------------
1290 TMPLIBS="$LIBS"
1291 LIBS=""
1292 AC_SEARCH_LIBS([pow], [m], [
1293   LIBM="$LIBS"
1294 ], [
1295   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1296 ])
1297 LIBS="$TMPLIBS"
1298 AC_SUBST([LIBM])
1299
1300 AC_CHECK_FUNCS([ppoll], [
1301   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1302 ])
1303 AC_CHECK_FUNCS([pollts], [
1304   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1305 ])
1306
1307 AC_CHECK_HEADER([asm-generic/unistd.h],
1308                 [AC_CHECK_DECL(__NR_setns,
1309                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1310                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1311                                ])
1312                  AC_CHECK_FUNCS([setns])]
1313                )
1314
1315 dnl --------------------------
1316 dnl Determine IS-IS I/O method
1317 dnl --------------------------
1318 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1319 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1320 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1321 AC_CHECK_HEADER([net/bpf.h])
1322 AC_CHECK_HEADER([sys/dlpi.h])
1323 AC_MSG_CHECKING([zebra IS-IS I/O method])
1324
1325 case "$host_os" in
1326   linux*)
1327     AC_MSG_RESULT([pfpacket])
1328     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1329     ;;
1330   solaris* | sunos*)
1331     AC_MSG_RESULT([DLPI])
1332     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1333     ;;
1334   *)
1335     if test $ac_cv_header_net_bpf_h = no; then
1336       if test $ac_cv_header_sys_dlpi_h = no; then
1337         AC_MSG_RESULT([none])
1338         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1339           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1340         fi
1341         AC_MSG_WARN([*** IS-IS support will not be built ***])
1342         enable_isisd="no"
1343         enable_fabricd="no"
1344       else
1345         AC_MSG_RESULT([DLPI])
1346       fi
1347       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1348     else
1349       AC_MSG_RESULT([BPF])
1350       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1351     fi
1352     ;;
1353 esac
1354 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1355
1356 dnl ---------------------------------------------------------------
1357 dnl figure out how to specify an interface in multicast sockets API
1358 dnl ---------------------------------------------------------------
1359 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1360
1361 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1362         #include <sys/socket.h>
1363         #include <netinet/in.h>
1364         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1365         #include <linux/types.h>
1366 ])
1367
1368 m4_define([FRR_INCLUDES],
1369 FRR_INCLUDES
1370 [#if HAVE_LINUX_MROUTE_H
1371 # include <linux/mroute.h>
1372 #endif
1373 ])dnl
1374
1375 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1376         #include <sys/socket.h>
1377         #include <sys/types.h>
1378         #include <netinet/in.h>
1379         #include <net/route.h>
1380 ])
1381
1382 m4_define([FRR_INCLUDES],
1383 FRR_INCLUDES
1384 [#if HAVE_NETINET_IP_MROUTE_H
1385 # include <netinet/ip_mroute.h>
1386 #endif
1387 ])dnl
1388
1389 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1390 AC_TRY_COMPILE([#include <sys/param.h>],
1391 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1392   return (0);
1393 #else
1394   #error No support for BSD struct ip_mreq hack detected
1395 #endif],[AC_MSG_RESULT([yes])
1396 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1397 AC_MSG_RESULT([no]))
1398
1399 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1400 AC_TRY_COMPILE([
1401 #include <sys/types.h>
1402 #include <netinet/in.h>
1403 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1404 ], [AC_MSG_RESULT([yes])
1405 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1406 AC_MSG_RESULT([no]))
1407
1408 dnl ---------------------------------------------------------------
1409 dnl figure out how to check link-state
1410 dnl ---------------------------------------------------------------
1411 AC_CHECK_HEADER([net/if_media.h],
1412   [m4_define([LINK_DETECT_INCLUDES],
1413     FRR_INCLUDES
1414     [#include <net/if_media.h>
1415   ])
1416   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1417     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1418     [], LINK_DETECT_INCLUDES)],
1419   [],
1420   FRR_INCLUDES)
1421
1422 dnl ---------------------------------------------------------------
1423 dnl Additional, newer way to check link-state using ifi_link_state.
1424 dnl Not available in all BSD's when ifmediareq available
1425 dnl ---------------------------------------------------------------
1426 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1427   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1428   [], FRR_INCLUDES)
1429
1430 dnl ------------------------
1431 dnl TCP_MD5SIG socket option
1432 dnl ------------------------
1433
1434 AC_CHECK_HEADER([netinet/tcp.h],
1435    [m4_define([MD5_INCLUDES],
1436       FRR_INCLUDES
1437       [#include <netinet/tcp.h>
1438     ])
1439     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1440    [],
1441    FRR_INCLUDES)
1442 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1443   AC_CHECK_HEADER([linux/tcp.h],
1444        [m4_define([MD5_INCLUDES],
1445           FRR_INCLUDES
1446           [#include <linux/tcp.h>
1447         ])
1448        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1449 fi
1450
1451 AC_SUBST([SOLARIS])
1452 AC_CHECK_LIB([crypt], [crypt], [],
1453                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1454 AC_CHECK_LIB([resolv], [res_init])
1455
1456 dnl ---------------------------
1457 dnl check system has PCRE regexp
1458 dnl ---------------------------
1459 if test "x$enable_pcreposix" = "xyes"; then
1460   AC_CHECK_LIB([pcreposix], [regexec], [], [
1461     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1462   ])
1463 fi
1464 AC_SUBST([HAVE_LIBPCREPOSIX])
1465
1466 dnl ##########################################################################
1467 dnl test "${enable_clippy_only}" != "yes"
1468 fi
1469 dnl END OF LARGE if block
1470 dnl ##########################################################################
1471
1472 dnl ------------------
1473 dnl check C-Ares library
1474 dnl ------------------
1475 PKG_CHECK_MODULES([CARES], [libcares], [
1476   c_ares_found=true
1477 ],[
1478   c_ares_found=false
1479 ])
1480 AM_CONDITIONAL([CARES], [$c_ares_found])
1481
1482
1483 dnl ----------------------------------------------------------------------------
1484 dnl figure out if domainname is available in the utsname struct (GNU extension).
1485 dnl ----------------------------------------------------------------------------
1486 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1487
1488 dnl ------------------
1489 dnl IPv6 header checks
1490 dnl ------------------
1491 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1492         netinet6/in6_var.h netinet6/nd6.h], [], [],
1493         FRR_INCLUDES)
1494
1495 m4_define([FRR_INCLUDES],dnl
1496 FRR_INCLUDES
1497 [#if HAVE_NETINET6_IN6_H
1498 #include <netinet6/in6.h>
1499 #endif
1500 #if HAVE_NETINET_IN6_VAR_H
1501 #include <netinet/in6_var.h>
1502 #endif
1503 #include <netinet/icmp6.h>
1504 #if HAVE_NETINET6_IN6_VAR_H
1505 # include <netinet6/in6_var.h>
1506 #endif
1507 #if HAVE_NETINET6_ND6_H
1508 # include <netinet6/nd6.h>
1509 #endif
1510 ])dnl
1511
1512 dnl --------------------
1513 dnl Daemon disable check
1514 dnl --------------------
1515
1516 AS_IF([test "${enable_ldpd}" != "no"], [
1517   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1518 ])
1519
1520 if test "$enable_bfdd" = "no"; then
1521   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1522   BFDD=""
1523 else
1524   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1525   BFDD="bfdd"
1526
1527   case $host_os in
1528     linux*)
1529       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1530       ;;
1531
1532     *)
1533       AC_DEFINE([BFD_BSD], [1], [bfdd])
1534       ;;
1535   esac
1536 fi
1537
1538 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1539   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1540 fi
1541
1542 NHRPD=""
1543 case "$host_os" in
1544   linux*)
1545     case "${enable_nhrpd}" in
1546       no)
1547         ;;
1548       yes)
1549         if test "${enable_clippy_only}" != "yes"; then
1550         if test "$c_ares_found" != "true" ; then
1551           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1552         fi
1553         fi
1554         NHRPD="nhrpd"
1555         ;;
1556       *)
1557         if test "$c_ares_found" = "true" ; then
1558           NHRPD="nhrpd"
1559         fi
1560         ;;
1561     esac
1562     ;;
1563   *)
1564     if test "${enable_nhrpd}" = "yes"; then
1565       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1566     fi
1567     ;;
1568 esac
1569
1570 if test "${enable_watchfrr}" = "no";then
1571   WATCHFRR=""
1572 else
1573   WATCHFRR="watchfrr"
1574 fi
1575
1576 OSPFCLIENT=""
1577 if test "${enable_ospfapi}" != "no";then
1578     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1579
1580   if test "${enable_ospfclient}" != "no";then
1581       OSPFCLIENT="ospfclient"
1582   fi
1583 fi
1584
1585 if test "${enable_bgp_announce}" = "no";then
1586   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1587 else
1588   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1589 fi
1590
1591 if test "${enable_bgp_vnc}" != "no";then
1592   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1593 fi
1594
1595 bgpd_bmp=false
1596 case "${enable_bmp}" in
1597   no)
1598     ;;
1599   yes)
1600     if test "$c_ares_found" != "true" ; then
1601       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1602     fi
1603     bgpd_bmp=true
1604     ;;
1605   *)
1606     if test "$c_ares_found" = "true" ; then
1607       bgpd_bmp=true
1608     fi
1609     ;;
1610 esac
1611
1612 dnl ##########################################################################
1613 dnl LARGE if block
1614 if test "${enable_clippy_only}" != "yes"; then
1615 dnl ##########################################################################
1616
1617 dnl ------------------
1618 dnl check Net-SNMP library
1619 dnl ------------------
1620 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1621    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1622    if test x"$NETSNMP_CONFIG" = x"no"; then
1623       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1624    fi
1625    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1626    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1627    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1628    # among other things we avoid a GPL vs. OpenSSL license conflict here
1629    for removelib in crypto ssl sensors pci wrap; do
1630      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1631    done
1632    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1633    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1634 int main(void);
1635 ],
1636 [
1637 {
1638   return 0;
1639 }
1640 ])], [
1641      AC_MSG_RESULT([no])
1642      AC_MSG_ERROR([--enable-snmp given but not usable])])
1643    case "${enable_snmp}" in
1644      yes)
1645       SNMP_METHOD=agentx
1646       ;;
1647      agentx)
1648       SNMP_METHOD="${enable_snmp}"
1649       ;;
1650      *)
1651       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1652       ;;
1653    esac
1654    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1655    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1656 fi
1657 AC_SUBST([SNMP_LIBS])
1658 AC_SUBST([SNMP_CFLAGS])
1659
1660 dnl ---------------
1661 dnl libyang
1662 dnl ---------------
1663 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.105], , [
1664   AC_MSG_ERROR([libyang (>= 0.16.105) was not found on your system.])
1665 ])
1666 ac_cflags_save="$CFLAGS"
1667 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1668 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1669   AC_MSG_ERROR([m4_normalize([
1670     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1671     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1672   ])
1673 ], [[#include <libyang/libyang.h>]])
1674 CFLAGS="$ac_cflags_save"
1675
1676 dnl ---------------
1677 dnl configuration rollbacks
1678 dnl ---------------
1679 SQLITE3=false
1680 if test "$enable_config_rollbacks" = "yes"; then
1681   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1682     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1683     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1684     SQLITE3=true
1685   ], [
1686     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1687   ])
1688 fi
1689
1690 dnl ---------------
1691 dnl confd
1692 dnl ---------------
1693 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1694    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1695    if test "x$CONFD" = "x/bin/false"; then
1696       AC_MSG_ERROR([confd was not found on your system.])]
1697    fi
1698    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1699    AC_SUBST([CONFD_CFLAGS])
1700    CONFD_LIBS="-lconfd"
1701    AC_SUBST([CONFD_LIBS])
1702    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1703 fi
1704
1705 dnl ---------------
1706 dnl sysrepo
1707 dnl ---------------
1708 if test "$enable_sysrepo" = "yes"; then
1709   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1710       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1711       SYSREPO=true],
1712       [SYSREPO=false
1713       AC_MSG_ERROR([sysrepo was not found on your system.])]
1714   )
1715 fi
1716
1717 dnl ---------------
1718 dnl gRPC
1719 dnl ---------------
1720 if test "$enable_grpc" = "yes"; then
1721   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1722     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1723     if test "$PROTOC" = "/bin/false"; then
1724       AC_MSG_FAILURE([grpc requested but protoc not found.])
1725     fi
1726
1727     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1728     GRPC=true
1729   ], [
1730     GRPC=false
1731     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1732   ])
1733 fi
1734
1735 dnl ------
1736 dnl ZeroMQ
1737 dnl ------
1738 if test "x$enable_zeromq" != "xno"; then
1739   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1740     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1741     ZEROMQ=true
1742   ], [
1743     if test "x$enable_zeromq" = "xyes"; then
1744       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1745     fi
1746   ])
1747 fi
1748
1749 dnl ------------------------------------
1750 dnl Enable RPKI and add librtr to libs
1751 dnl ------------------------------------
1752 if test "${enable_rpki}" = "yes"; then
1753   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1754       [RPKI=true],
1755       [RPKI=false
1756       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1757   )
1758 fi
1759
1760 dnl ------------------------------------------
1761 dnl Check whether rtrlib was build with ssh support
1762 dnl ------------------------------------------
1763 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1764 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1765                         [[struct tr_ssh_config config;]])],
1766         [AC_MSG_RESULT([yes])
1767         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1768         AC_MSG_RESULT([no])
1769 )
1770
1771 dnl ---------------
1772 dnl dlopen & dlinfo
1773 dnl ---------------
1774 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1775   AC_MSG_ERROR([unable to find the dlopen()])
1776 ])
1777
1778 AC_CHECK_HEADERS([link.h])
1779
1780 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1781   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1782 #include <stdlib.h>
1783 #ifdef HAVE_LINK_H
1784 #include <link.h>
1785 #endif
1786 #include <dlfcn.h>
1787 ]], [[
1788   char origin[1];
1789   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1790 ]])], [
1791     frr_cv_rtld_di_origin=yes
1792   ], [
1793     frr_cv_rtld_di_origin=no
1794   ])
1795 ])
1796 if test "$frr_cv_rtld_di_origin" = yes; then
1797   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1798 fi
1799
1800 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1801   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1802 #include <stdlib.h>
1803 #ifdef HAVE_LINK_H
1804 #include <link.h>
1805 #endif
1806 #include <dlfcn.h>
1807 ]], [[
1808   struct link_map *lm = NULL;
1809   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1810 ]])], [
1811     frr_cv_rtld_di_linkmap=yes
1812   ], [
1813     frr_cv_rtld_di_linkmap=no
1814   ])
1815 ])
1816 if test "$frr_cv_rtld_di_linkmap" = yes; then
1817   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1818 fi
1819
1820 dnl ##########################################################################
1821 dnl test "${enable_clippy_only}" != "yes"
1822 fi
1823 dnl END OF LARGE if block
1824 dnl ##########################################################################
1825
1826 dnl ---------------------------
1827 dnl sockaddr and netinet checks
1828 dnl ---------------------------
1829 AC_CHECK_TYPES([
1830         struct sockaddr_dl,
1831         struct vifctl, struct mfcctl, struct sioc_sg_req,
1832         vifi_t, struct sioc_vif_req, struct igmpmsg,
1833         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1834         struct nd_opt_adv_interval,
1835         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1836         struct nd_opt_rdnss, struct nd_opt_dnssl],
1837         [], [], FRR_INCLUDES)
1838
1839 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1840         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1841         struct sockaddr_dl.sdl_len,
1842         struct if6_aliasreq.ifra_lifetime,
1843         struct nd_opt_adv_interval.nd_opt_ai_type],
1844         [], [], FRR_INCLUDES)
1845
1846 dnl ---------------------------
1847 dnl IRDP/pktinfo/icmphdr checks
1848 dnl ---------------------------
1849
1850 AC_CHECK_TYPES([struct in_pktinfo], [
1851   AC_CHECK_TYPES([struct icmphdr], [
1852     IRDP=true
1853   ], [
1854     IRDP=false
1855   ], [FRR_INCLUDES])
1856 ], [
1857   IRDP=false
1858 ], [FRR_INCLUDES])
1859
1860 case "${enable_irdp}" in
1861 yes)
1862   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1863   ;;
1864 no)
1865   IRDP=false
1866   ;;
1867 esac
1868
1869
1870 dnl -----------------------
1871 dnl checking for IP_PKTINFO
1872 dnl -----------------------
1873 AC_MSG_CHECKING([for IP_PKTINFO])
1874 AC_TRY_COMPILE([#include <netdb.h>], [
1875   int opt = IP_PKTINFO;
1876 ], [
1877   AC_MSG_RESULT([yes])
1878   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1879 ], [
1880   AC_MSG_RESULT([no])
1881 ])
1882
1883 dnl ---------------------------
1884 dnl checking for IP_RECVDSTADDR
1885 dnl ---------------------------
1886 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1887 AC_TRY_COMPILE([#include <netinet/in.h>], [
1888   int opt = IP_RECVDSTADDR;
1889 ], [
1890   AC_MSG_RESULT([yes])
1891   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1892 ], [
1893   AC_MSG_RESULT([no])
1894 ])
1895
1896 dnl ----------------------
1897 dnl checking for IP_RECVIF
1898 dnl ----------------------
1899 AC_MSG_CHECKING([for IP_RECVIF])
1900 AC_TRY_COMPILE([#include <netinet/in.h>], [
1901   int opt = IP_RECVIF;
1902 ], [
1903   AC_MSG_RESULT([yes])
1904   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1905 ], [
1906   AC_MSG_RESULT([no])
1907 ])
1908
1909 dnl ----------------------
1910 dnl checking for SO_BINDANY
1911 dnl ----------------------
1912 AC_MSG_CHECKING([for SO_BINDANY])
1913 AC_TRY_COMPILE([#include <sys/socket.h>], [
1914   int opt = SO_BINDANY;
1915 ], [
1916   AC_MSG_RESULT([yes])
1917   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1918 ], [
1919   AC_MSG_RESULT([no])
1920 ])
1921
1922 dnl ----------------------
1923 dnl checking for IP_FREEBIND
1924 dnl ----------------------
1925 AC_MSG_CHECKING([for IP_FREEBIND])
1926 AC_TRY_COMPILE([#include <netinet/in.h>], [
1927   int opt = IP_FREEBIND;
1928 ], [
1929   AC_MSG_RESULT([yes])
1930   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1931 ], [
1932   AC_MSG_RESULT([no])
1933 ])
1934
1935 dnl --------------------------------------
1936 dnl checking for be32dec existence or not
1937 dnl --------------------------------------
1938 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1939                [#include <sys/endian.h>])
1940
1941 dnl --------------------------------------
1942 dnl checking for clock_time monotonic struct and call
1943 dnl --------------------------------------
1944 AC_CHECK_DECL([CLOCK_MONOTONIC],
1945         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1946          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1947 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1948
1949 dnl --------------------------------------
1950 dnl checking for flex and bison
1951 dnl --------------------------------------
1952
1953 AM_PROG_LEX
1954 AC_MSG_CHECKING([version of flex])
1955 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1956 frr_ac_flex_version="${frr_ac_flex_version##* }"
1957 AC_MSG_RESULT([$frr_ac_flex_version])
1958 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1959   LEX="$SHELL $missing_dir/missing flex"
1960   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1961     AC_MSG_WARN([using pregenerated flex output files])
1962   else
1963     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1964   fi
1965   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1966   AC_SUBST([LEXLIB], [''])
1967 ])
1968
1969 AC_PROG_YACC
1970 dnl thanks GNU bison for this b*llshit...
1971 AC_MSG_CHECKING([version of bison])
1972 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1973 frr_ac_bison_version="${frr_ac_bison_version##* }"
1974 frr_ac_bison_missing="false"
1975 case "x${frr_ac_bison_version}x" in
1976   x2.7*)
1977     BISON_OPENBRACE='"'
1978     BISON_CLOSEBRACE='"'
1979     BISON_VERBOSE=''
1980     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1981     ;;
1982   x2.*|x1.*)
1983     AC_MSG_RESULT([$frr_ac_bison_version])
1984     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1985     frr_ac_bison_missing="true"
1986     ;;
1987   x)
1988     AC_MSG_RESULT([none])
1989     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1990     frr_ac_bison_missing="true"
1991     ;;
1992   x3.[012][^0-9]*)
1993     BISON_OPENBRACE='{'
1994     BISON_CLOSEBRACE='}'
1995     BISON_VERBOSE='-Dparse.error=verbose'
1996     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
1997     ;;
1998   *)
1999     BISON_OPENBRACE='{'
2000     BISON_CLOSEBRACE='}'
2001     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2002     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2003     ;;
2004 esac
2005 AC_SUBST([BISON_OPENBRACE])
2006 AC_SUBST([BISON_CLOSEBRACE])
2007 AC_SUBST([BISON_VERBOSE])
2008
2009 if $frr_ac_bison_missing; then
2010   YACC="$SHELL $missing_dir/missing bison -y"
2011   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2012     AC_MSG_WARN([using pregenerated bison output files])
2013   else
2014     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2015   fi
2016 fi
2017
2018 dnl -------------------
2019 dnl capabilities checks
2020 dnl -------------------
2021 if test "${enable_capabilities}" != "no"; then
2022   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2023   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2024     [AC_MSG_RESULT([yes])
2025      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2026      frr_ac_keepcaps="yes"],
2027      AC_MSG_RESULT([no])
2028   )
2029   if test x"${frr_ac_keepcaps}" = x"yes"; then
2030     AC_CHECK_HEADERS([sys/capability.h])
2031   fi
2032   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
2033     AC_CHECK_LIB([cap], [cap_init],
2034       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2035        LIBCAP="-lcap"
2036        frr_ac_lcaps="yes"]
2037     )
2038   else
2039     AC_CHECK_HEADERS([priv.h],
2040      [AC_MSG_CHECKING([Solaris style privileges are available])
2041       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
2042           [AC_MSG_RESULT([yes])
2043            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
2044            frr_ac_scaps="yes"],
2045            AC_MSG_RESULT(no)
2046       )
2047      ]
2048    )
2049   fi
2050   if test x"${frr_ac_scaps}" = x"yes" \
2051        -o x"${frr_ac_lcaps}" = x"yes"; then
2052     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2053   fi
2054
2055   case "$host_os" in
2056   linux*)
2057     if test "${enable_clippy_only}" != "yes"; then
2058     if test "$frr_ac_lcaps" != "yes"; then
2059       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2060     fi
2061     fi
2062     ;;
2063   esac
2064 else
2065   case "$host_os" in
2066   linux*)
2067     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2068     ;;
2069   esac
2070 fi
2071 AC_SUBST([LIBCAP])
2072
2073 dnl ---------------------------
2074 dnl check for glibc 'backtrace'
2075 dnl ---------------------------
2076 if test x"${enable_backtrace}" != x"no" ; then
2077   backtrace_ok=no
2078   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2079     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2080     backtrace_ok=yes
2081   ], [
2082     case "$host_os" in
2083     sunos* | solaris2*)
2084       AC_CHECK_FUNCS([printstack], [
2085         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
2086         backtrace_ok=yes
2087       ])
2088       ;;
2089     esac
2090     if test "$backtrace_ok" = no; then
2091       AC_CHECK_HEADER([execinfo.h], [
2092         AC_SEARCH_LIBS([backtrace], [execinfo], [
2093           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2094           backtrace_ok=yes
2095         ],, [-lm])
2096       ])
2097     fi
2098   ])
2099
2100   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
2101     dnl user explicitly requested backtrace but we failed to find support
2102     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2103   fi
2104 fi
2105
2106 dnl -----------------------------------------
2107 dnl check for malloc mallinfo struct and call
2108 dnl this must try and link using LIBS, in
2109 dnl order to check no alternative allocator
2110 dnl has been specified, which might not provide
2111 dnl mallinfo, e.g. such as Umem on Solaris.
2112 dnl -----------------------------------------
2113 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2114
2115 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2116   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2117 #ifdef HAVE_MALLOC_H
2118 #include <malloc.h>
2119 #endif
2120 #ifdef HAVE_MALLOC_NP_H
2121 #include <malloc_np.h>
2122 #endif
2123 #ifdef HAVE_MALLOC_MALLOC_H
2124 #include <malloc/malloc.h>
2125 #endif
2126 ]], [[
2127 struct mallinfo ac_x; ac_x = mallinfo ();
2128 ]])], [
2129     frr_cv_mallinfo=yes
2130   ], [
2131     frr_cv_mallinfo=no
2132   ])
2133 ])
2134 if test "$frr_cv_mallinfo" = yes; then
2135   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2136 fi
2137
2138 AC_MSG_CHECKING([whether malloc_usable_size is available])
2139 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2140 #ifdef HAVE_MALLOC_H
2141 #include <malloc.h>
2142 #endif
2143 #ifdef HAVE_MALLOC_MALLOC_H
2144 #include <malloc/malloc.h>
2145 #endif
2146 ]], [[
2147 size_t ac_x; ac_x = malloc_usable_size(NULL);
2148 ]])], [
2149   AC_MSG_RESULT([yes])
2150   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2151 ], [
2152   AC_MSG_RESULT([no])
2153
2154   AC_MSG_CHECKING([whether malloc_size is available])
2155   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2156 #ifdef HAVE_MALLOC_H
2157 #include <malloc.h>
2158 #endif
2159 #ifdef HAVE_MALLOC_MALLOC_H
2160 #include <malloc/malloc.h>
2161 #endif
2162 ]], [[
2163 size_t ac_x; ac_x = malloc_size(NULL);
2164 ]])], [
2165     AC_MSG_RESULT([yes])
2166     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2167   ], [
2168     AC_MSG_RESULT([no])
2169   ])
2170 ])
2171
2172 dnl ----------
2173 dnl configure date
2174 dnl ----------
2175 dev_version=`echo $VERSION | grep dev`
2176 #don't expire deprecated code in non 'dev' branch
2177 if test "${dev_version}" = ""; then
2178    CONFDATE=0
2179 else
2180    CONFDATE=`date '+%Y%m%d'`
2181 fi
2182 AC_SUBST([CONFDATE])
2183
2184 dnl ------------------------------
2185 dnl set paths for state directory
2186 dnl ------------------------------
2187 AC_MSG_CHECKING([directory to use for state file])
2188 if test "${prefix}" = "NONE"; then
2189   frr_statedir_prefix="";
2190 else
2191   frr_statedir_prefix=${prefix}
2192 fi
2193 if test "${localstatedir}" = '${prefix}/var'; then
2194   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2195                         ${frr_statedir_prefix}/var/adm dnl
2196                         ${frr_statedir_prefix}/etc dnl
2197                         /var/run        dnl
2198                         /var/adm        dnl
2199                         /etc            dnl
2200                         /dev/null;
2201   do
2202     test -d $FRR_STATE_DIR && break
2203   done
2204   frr_statedir=$FRR_STATE_DIR
2205 else
2206   frr_statedir=${localstatedir}
2207 fi
2208 if test $frr_statedir = "/dev/null"; then
2209     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2210 fi
2211 AC_MSG_RESULT([${frr_statedir}])
2212 AC_SUBST([frr_statedir])
2213
2214 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2215 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2216 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2217 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2218 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2219
2220 dnl autoconf does this, but it does it too late...
2221 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2222 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2223
2224 dnl get the full path, recursing through variables...
2225 vtysh_bin="$bindir/vtysh"
2226 for I in 1 2 3 4 5 6 7 8 9 10; do
2227         eval vtysh_bin="\"$vtysh_bin\""
2228 done
2229 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2230 AC_SUBST([vtysh_bin])
2231
2232 CFG_SYSCONF="$sysconfdir"
2233 CFG_SBIN="$sbindir"
2234 CFG_STATE="$frr_statedir"
2235 CFG_MODULE="$moduledir"
2236 CFG_YANGMODELS="$yangmodelsdir"
2237 for I in 1 2 3 4 5 6 7 8 9 10; do
2238         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2239         eval CFG_SBIN="\"$CFG_SBIN\""
2240         eval CFG_STATE="\"$CFG_STATE\""
2241         eval CFG_MODULE="\"$CFG_MODULE\""
2242         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2243 done
2244 AC_SUBST([CFG_SYSCONF])
2245 AC_SUBST([CFG_SBIN])
2246 AC_SUBST([CFG_STATE])
2247 AC_SUBST([CFG_MODULE])
2248 AC_SUBST([CFG_YANGMODELS])
2249 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2250 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2251 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2252
2253 dnl various features
2254 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
2255 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
2256 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2257 dnl northbound
2258 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2259 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
2260 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
2261 AM_CONDITIONAL([GRPC], [test "x$enable_grpc" = "xyes"])
2262 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2263 dnl plugins
2264 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2265 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
2266 AM_CONDITIONAL([IRDP], [$IRDP])
2267 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
2268 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
2269 dnl daemons
2270 AM_CONDITIONAL([VTYSH], [test "x$VTYSH" = "xvtysh"])
2271 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
2272 AM_CONDITIONAL([BGPD], [test "x${enable_bgpd}" != "no"])
2273 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
2274 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
2275 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
2276 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
2277 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
2278 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
2279 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
2280 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
2281 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
2282 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
2283 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
2284 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
2285 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
2286 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
2287 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
2288 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
2289 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
2290 AM_CONDITIONAL([VRRPD], [test "${enable_vrrpd}" != "no"])
2291
2292 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2293
2294 AC_CONFIG_FILES([
2295           config.version
2296           changelog-auto
2297           redhat/frr.spec
2298           solaris/Makefile
2299           alpine/APKBUILD
2300           snapcraft/snapcraft.yaml
2301           lib/version.h
2302           tests/lib/cli/test_cli.refout
2303           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2304           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2305           pkgsrc/eigrpd.sh])
2306
2307 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2308 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2309 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2310 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2311 AC_CONFIG_FILES([tools/frrcommon.sh])
2312
2313 AC_CONFIG_COMMANDS([lib/route_types.h], [
2314         dst="${ac_abs_top_builddir}/lib/route_types.h"
2315         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2316                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2317                 > "${dst}.tmp"
2318         test -f "${dst}" \
2319                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2320                 && rm "${dst}.tmp" \
2321                 || mv "${dst}.tmp" "${dst}"
2322 ], [
2323         PERL="$PERL"
2324 ])
2325
2326 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2327     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2328         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2329         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2330                 "${ac_abs_top_srcdir}" \
2331                 > "${dst}.tmp"
2332         test -f "${dst}" \
2333                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2334                 && rm "${dst}.tmp" \
2335                 || mv "${dst}.tmp" "${dst}"
2336     ], [
2337         PERL="$PERL"
2338     ])
2339 ])
2340
2341 ## Hack, but working solution to avoid rebuilding of frr.info.
2342 ## It's already in CVS until texinfo 4.7 is more common.
2343 AC_OUTPUT
2344
2345 echo "
2346 FRRouting configuration
2347 ------------------------------
2348 FRR version             : ${PACKAGE_VERSION}
2349 host operating system   : ${host_os}
2350 source code location    : ${srcdir}
2351 compiler                : ${CC}
2352 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2353 make                    : ${MAKE-make}
2354 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2355 state file directory    : ${frr_statedir}
2356 config file directory   : `eval echo \`echo ${sysconfdir}\``
2357 example directory       : `eval echo \`echo ${exampledir}\``
2358 module directory        : ${CFG_MODULE}
2359 user to run as          : ${enable_user}
2360 group to run as         : ${enable_group}
2361 group for vty sockets   : ${enable_vty_group}
2362 config file mask        : ${enable_configfile_mask}
2363 log file mask           : ${enable_logfile_mask}
2364 zebra protobuf enabled  : ${enable_protobuf:-no}
2365
2366 The above user and group must have read/write access to the state file
2367 directory and to the config files in the config file directory."
2368
2369 if test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" = false; then
2370   AC_MSG_WARN([sphinx is missing but required to build documentation])
2371 fi
2372 if test "$frr_py_mod_pytest" = false; then
2373   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2374 fi