configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl if the user has specified any CFLAGS, override our settings
 193 if test "x${enable_gcov}" = "xyes"; then
 194    if test "z$orig_cflags" = "z"; then
 195       AC_C_FLAG([-coverage])
 196       AC_C_FLAG([-O0])
 197    fi
 198
 199    LDFLAGS="${LDFLAGS} -lgcov"
 200 elif test "x${enable_dev_build}" = "xyes"; then
 201    AC_DEFINE(DEV_BUILD,,Build for development)
 202    if test "z$orig_cflags" = "z"; then
 203       AC_C_FLAG([-g3])
 204       AC_C_FLAG([-O0])
 205    fi
 206    if test "x${enable_lua}" = "xyes"; then
 207       AC_CHECK_LIB([lua], [lua_newstate],
 208       [LIBS="$LIBS -llua"])
 209       AC_DEFINE(HAVE_LUA,,Lua enabled for development)
 210    fi
 211 else
 212    if test "x${enable_lua}" = "xyes"; then
 213       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 214    fi
 215    if test "z$orig_cflags" = "z"; then
 216       AC_C_FLAG([-g])
 217       AC_C_FLAG([-Os], [
 218         AC_C_FLAG([-O2])
 219       ])
 220    fi
 221 fi
 222 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 223
 224 dnl always want these CFLAGS
 225 AC_C_FLAG([-fno-omit-frame-pointer])
 226 AC_C_FLAG([-funwind-tables])
 227 AC_C_FLAG([-Wall])
 228 AC_C_FLAG([-Wextra])
 229 AC_C_FLAG([-Wmissing-prototypes])
 230 AC_C_FLAG([-Wmissing-declarations])
 231 AC_C_FLAG([-Wpointer-arith])
 232 AC_C_FLAG([-Wbad-function-cast])
 233 AC_C_FLAG([-Wwrite-strings])
 234 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 235   AC_C_FLAG([-Wcast-qual])
 236   AC_C_FLAG([-Wstrict-prototypes])
 237   AC_C_FLAG([-Wmissing-noreturn])
 238   AC_C_FLAG([-Wmissing-format-attribute])
 239   AC_C_FLAG([-Wunreachable-code])
 240   AC_C_FLAG([-Wpacked])
 241   AC_C_FLAG([-Wpadded])
 242   AC_C_FLAG([-Wshadow])
 243 else
 244   AC_C_FLAG([-Wno-unused-result])
 245 fi
 246 AC_C_FLAG([-Wno-unused-parameter])
 247 AC_C_FLAG([-Wno-missing-field-initializers])
 248
 249 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 250 dnl for some reason the string consts get 'promoted' to char *,
 251 dnl triggering a const to non-const conversion warning.
 252 AC_C_FLAG([-diag-disable 3179])
 253
 254 if test x"${enable_werror}" = x"yes" ; then
 255   WERROR="-Werror"
 256 fi
 257 AC_SUBST(WERROR)
 258
 259 SAN_FLAGS=""
 260 if test "$enable_address_sanitizer" = "yes"; then
 261   AC_C_FLAG([-fsanitize=address], [
 262     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 263   ], [
 264     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 265   ])
 266 fi
 267 if test "$enable_thread_sanitizer" = "yes"; then
 268   AC_C_FLAG([-fsanitize=thread], [
 269     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 270   ], [
 271     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 272   ])
 273 fi
 274 if test "$enable_memory_sanitizer" = "yes"; then
 275   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 276     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 277   ], [
 278     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 279   ])
 280 fi
 281 AC_SUBST([SAN_FLAGS])
 282
 283 dnl ----------
 284 dnl Essentials
 285 dnl ----------
 286
 287 AX_PTHREAD([
 288   CC="$PTHREAD_CC"
 289   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 290   LIBS="$PTHREAD_LIBS $LIBS"
 291 ], [
 292   AC_MSG_FAILURE([This FRR version needs pthreads])
 293 ])
 294
 295 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 296                 [frr_cv_pthread_condattr_setclock=yes],
 297                 [frr_cv_pthread_condattr_setclock=no])
 298 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 299   AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK, 1, [Have pthread.h pthread_condattr_setclock])
 300 fi
 301
 302 dnl --------------
 303 dnl Check programs
 304 dnl --------------
 305 AC_PROG_INSTALL
 306 AC_PROG_LN_S
 307 AC_PROG_MAKE_SET
 308 AC_CHECK_TOOL(AR, ar)
 309
 310 dnl -------
 311 dnl libtool
 312 dnl -------
 313 AC_ARG_ENABLE(static-bin,
 314   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 315 LT_INIT
 316 _LT_CONFIG_LIBTOOL([
 317   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 318     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 319 ])
 320 if test "$enable_static_bin" = "yes"; then
 321   AC_LDFLAGS="-static"
 322 fi
 323 AC_SUBST(AC_LDFLAGS)
 324 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 325
 326 dnl ----------------------
 327 dnl Packages configuration
 328 dnl ----------------------
 329 AC_ARG_WITH(pkg-extra-version,
 330         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 331         [EXTRAVERSION=$withval],)
 332 AC_ARG_WITH(pkg-git-version,
 333         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 334         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 335 AC_ARG_WITH(vtysh_pager,
 336         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 337         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 338 AC_ARG_ENABLE(vtysh,
 339   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 340 AC_ARG_ENABLE(doc,
 341   AS_HELP_STRING([--disable-doc], [do not build docs]))
 342 AC_ARG_ENABLE(doc-html,
 343   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 344 AC_ARG_ENABLE(zebra,
 345   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 346 AC_ARG_ENABLE(bgpd,
 347   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 348 AC_ARG_ENABLE(ripd,
 349   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 350 AC_ARG_ENABLE(ripngd,
 351   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 352 AC_ARG_ENABLE(ospfd,
 353   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 354 AC_ARG_ENABLE(ospf6d,
 355   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 356 AC_ARG_ENABLE(ldpd,
 357   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 358 AC_ARG_ENABLE(nhrpd,
 359   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 360 AC_ARG_ENABLE(eigrpd,
 361   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 362 AC_ARG_ENABLE(babeld,
 363   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 364 AC_ARG_ENABLE(watchfrr,
 365   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 366 AC_ARG_ENABLE(isisd,
 367   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 368 AC_ARG_ENABLE(pimd,
 369   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 370 AC_ARG_ENABLE(pbrd,
 371   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 372 AC_ARG_ENABLE(sharpd,
 373   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 374 AC_ARG_ENABLE(staticd,
 375   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 376 AC_ARG_ENABLE(fabricd,
 377   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 378 AC_ARG_ENABLE(bgp-announce,
 379   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 380 AC_ARG_ENABLE(bgp-vnc,
 381   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 382 AC_ARG_ENABLE(snmp,
 383   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 384 AC_ARG_ENABLE(zeromq,
 385   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 386 AC_ARG_WITH(libpam,
 387   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 388 AC_ARG_ENABLE(ospfapi,
 389   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 390 AC_ARG_ENABLE(ospfclient,
 391   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 392                           (this is the default if --disable-ospfapi is set)]))
 393 AC_ARG_ENABLE(multipath,
 394   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 395 AC_ARG_ENABLE(user,
 396   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 397 AC_ARG_ENABLE(group,
 398   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 399 AC_ARG_ENABLE(vty_group,
 400   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 401 AC_ARG_ENABLE(configfile_mask,
 402   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 403 AC_ARG_ENABLE(logfile_mask,
 404   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 405 AC_ARG_ENABLE(shell_access,
 406   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 407 AC_ARG_ENABLE(realms,
 408   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 409 AC_ARG_ENABLE(rtadv,
 410   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 411 AC_ARG_ENABLE(irdp,
 412   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 413 AC_ARG_ENABLE(capabilities,
 414   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 415 AC_ARG_ENABLE(rusage,
 416   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 417 AC_ARG_ENABLE(gcc_ultra_verbose,
 418   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 419 AC_ARG_ENABLE(backtrace,
 420   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 421 AC_ARG_ENABLE(time-check,
 422   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 423 AC_ARG_ENABLE(pcreposix,
 424   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 425 AC_ARG_ENABLE(fpm,
 426   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 427 AC_ARG_ENABLE(systemd,
 428   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 429 AC_ARG_ENABLE(werror,
 430   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 431 AC_ARG_ENABLE(cumulus,
 432   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 433 AC_ARG_ENABLE(datacenter,
 434   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 435 AC_ARG_ENABLE(fuzzing,
 436   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 437 AC_ARG_ENABLE(netlink_fuzzing,
 438   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 439 AC_ARG_ENABLE(rr-semantics,
 440   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 441 AC_ARG_ENABLE([protobuf],
 442   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 443 AC_ARG_ENABLE([oldvpn_commands],
 444   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 445 AC_ARG_ENABLE(rpki,
 446   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 447 AC_ARG_ENABLE([clippy-only],
 448   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 449 AC_ARG_ENABLE([numeric_version],
 450   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 451 AC_ARG_ENABLE([gcov],
 452   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 453 AC_ARG_ENABLE(bfdd,
 454   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 455 AC_ARG_ENABLE([address-sanitizer],
 456   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 457 AC_ARG_ENABLE([thread-sanitizer],
 458   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 459 AC_ARG_ENABLE([memory-sanitizer],
 460   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 461
 462 AS_IF([test "${enable_clippy_only}" != "yes"], [
 463 AC_CHECK_HEADERS(json-c/json.h)
 464 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 465 if test $ac_cv_lib_json_c_json_object_get = no; then
 466   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 467   if test $ac_cv_lib_json_json_object_get = no; then
 468       AC_MSG_ERROR([lib json is needed to compile])
 469   fi
 470 fi
 471 ])
 472
 473 AC_ARG_ENABLE([dev_build],
 474     AS_HELP_STRING([--enable-dev-build], [build for development]))
 475
 476 AC_ARG_ENABLE([lua],
 477     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 478
 479 if test x"${enable_time_check}" != x"no" ; then
 480   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 481     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 482   else
 483     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 484   fi
 485 fi
 486
 487 case "${enable_systemd}" in
 488   "no") ;;
 489   "yes")
 490   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 491   if test $ac_cv_lib_systemd_sd_notify = no; then
 492     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 493   else
 494     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 495   fi
 496   ;;
 497   "*") ;;
 498 esac
 499
 500 if test "${enable_rr_semantics}" != "no" ; then
 501   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 502 fi
 503
 504 if test "${enable_datacenter}" = "yes" ; then
 505   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 506   DFLT_NAME="datacenter"
 507 else
 508   DFLT_NAME="traditional"
 509 fi
 510
 511 if test "${enable_fuzzing}" = "yes" ; then
 512   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 513 fi
 514
 515 if test "${enable_netlink_fuzzing}" = "yes" ; then
 516   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 517 fi
 518
 519 if test "${enable_cumulus}" = "yes" ; then
 520   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 521 fi
 522
 523 AC_SUBST(DFLT_NAME)
 524 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 525
 526 if test "${enable_shell_access}" = "yes"; then
 527    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 528 fi
 529
 530 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 531
 532 #
 533 # Python for clippy
 534 #
 535
 536 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 537   AC_MSG_CHECKING([whether we found a working Python version])
 538   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 539 #include <Python.h>
 540 #if PY_VERSION_HEX < 0x02070000
 541 #error python too old
 542 #endif
 543 int main(void);
 544 ],
 545 [
 546 {
 547   Py_Initialize();
 548   return 0;
 549 }
 550 ])], [
 551     # some python installs are missing the zlib dependency...
 552     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 553     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 554 #include <Python.h>
 555 #if PY_VERSION_HEX < 0x02070000
 556 #error python too old
 557 #endif
 558 int main(void);
 559 ],
 560 [
 561 {
 562   Py_Initialize();
 563   return 0;
 564 }
 565 ])], [
 566       m4_if([$1], [], [
 567         PYTHONCONFIG=""
 568         unset PYTHON_LIBS
 569         unset PYTHON_CFLAGS
 570       ], [$1])
 571     ])
 572   ])
 573 ])
 574
 575 AS_IF([test "$host" = "$build"], [
 576   PYTHONCONFIG=""
 577
 578   # ordering:
 579   # 1.  try python3, but respect the user's preference on which minor ver
 580   # 2.  try python, which might be py3 or py2 again on the user's preference
 581   # 3.  try python2 (can really only be 2.7 but eh)
 582   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 583   #
 584   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 585   # (AX_PYTHON does not do what we need)
 586
 587   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 588         python3-config \
 589         python-config \
 590         python2-config \
 591         python3.6-config \
 592         python3.5-config \
 593         python3.4-config \
 594         python3.3-config \
 595         python3.2-config \
 596         python2.7-config ])
 597   if test -n "$PYTHONCONFIG"; then
 598     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 599     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 600
 601     FRR_PYTHON_CHECK_WORKING([])
 602   fi
 603
 604   if test -z "$PYTHONCONFIG"; then
 605     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 606       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 607         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 608           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 609             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 610               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 611                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 612                 ])])])])])])
 613
 614
 615     FRR_PYTHON_CHECK_WORKING([
 616       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 617     ])
 618   fi
 619 ])
 620 AC_SUBST(PYTHON_CFLAGS)
 621 AC_SUBST(PYTHON_LIBS)
 622
 623 #
 624 # Logic for protobuf support.
 625 #
 626 if test "$enable_protobuf" = "yes"; then
 627   # Check for protoc & protoc-c
 628
 629   # protoc is not required, it's only for a "be nice" helper target
 630   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 631
 632   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 633   if test "$PROTOC_C" = "/bin/false"; then
 634     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 635   fi
 636
 637   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 638     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 639   ])
 640   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 641     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 642   ])
 643
 644   AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 645 fi
 646 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 647
 648 #
 649 # Logic for old vpn commans support.
 650 #
 651 if test "$enable_oldvpn_commands" = "yes"; then
 652    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 653 fi
 654
 655 #
 656 # End of logic for protobuf support.
 657 #
 658
 659 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 660 if test "${enable_rtadv}" != "no"; then
 661   AC_MSG_RESULT(yes)
 662   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 663 else
 664   AC_MSG_RESULT(no)
 665 fi
 666
 667 if test x"${enable_user}" = x"no"; then
 668   enable_user=""
 669 else
 670   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 671     enable_user="frr"
 672   fi
 673   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 674 fi
 675
 676 if test x"${enable_group}" = x"no"; then
 677   enable_group=""
 678 else
 679   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 680     enable_group="frr"
 681   fi
 682   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 683 fi
 684
 685 if test x"${enable_vty_group}" = x"yes" ; then
 686   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 687 elif test x"${enable_vty_group}" != x""; then
 688   if test x"${enable_vty_group}" != x"no"; then
 689     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 690   fi
 691 fi
 692 AC_SUBST([enable_user])
 693 AC_SUBST([enable_group])
 694 AC_SUBST([enable_vty_group])
 695
 696 enable_configfile_mask=${enable_configfile_mask:-0600}
 697 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 698
 699 enable_logfile_mask=${enable_logfile_mask:-0600}
 700 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 701
 702 MPATH_NUM=1
 703
 704 case "${enable_multipath}" in
 705   0)
 706     MPATH_NUM=64
 707     ;;
 708   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 709     MPATH_NUM="${enable_multipath}"
 710     ;;
 711   "")
 712     ;;
 713   *)
 714     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 715     ;;
 716 esac
 717
 718 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 719
 720 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 721
 722 dnl --------------------
 723 dnl Enable code coverage
 724 dnl --------------------
 725 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 726
 727 dnl ------------------------------------
 728 dnl Alpine only accepts numeric versions
 729 dnl ------------------------------------
 730 if test "x${enable_numeric_version}" != "x" ; then
 731   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 732   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 733 fi
 734
 735 dnl -----------------------------------
 736 dnl Add extra version string to package
 737 dnl name, string and version fields.
 738 dnl -----------------------------------
 739 if test "x${EXTRAVERSION}" != "x" ; then
 740   VERSION="${VERSION}${EXTRAVERSION}"
 741   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 742   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 743   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 744 fi
 745
 746 if test "x$with_pkg_git_version" = "xyes"; then
 747         if test -d "${srcdir}/.git"; then
 748                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 749         else    with_pkg_git_version="no"
 750                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 751         fi
 752 fi
 753 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 754
 755 dnl ------------------------------------
 756 dnl Check C keywords and standard  types
 757 dnl ------------------------------------
 758 AC_C_CONST
 759 AC_C_INLINE
 760 AC_C_VOLATILE
 761 AC_HEADER_STDC
 762 dnl AC_TYPE_PID_T
 763 AC_TYPE_UID_T
 764 AC_TYPE_MODE_T
 765 AC_TYPE_SIZE_T
 766 AC_STRUCT_TM
 767
 768 dnl -------------------------
 769 dnl Check other header files.
 770 dnl -------------------------
 771 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 772         linux/version.h asm/types.h \
 773         sys/cdefs.h])
 774
 775 ac_stdatomic_ok=false
 776 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 777 AC_CHECK_HEADER([stdatomic.h],[
 778
 779   AC_MSG_CHECKING([whether _Atomic qualifier works])
 780   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 781 #include <stdatomic.h>
 782 int main(int argc, char **argv) {
 783   _Atomic int i = 0;
 784   return i;
 785 }
 786 ]])], [
 787     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 788     AC_MSG_RESULT([yes])
 789     ac_stdatomic_ok=true
 790   ], [
 791     AC_MSG_RESULT([no])
 792   ])
 793 ])
 794
 795 AS_IF([$ac_stdatomic_ok], [true], [
 796   AC_MSG_CHECKING([for __atomic_* builtins])
 797   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 798 int main(int argc, char **argv) {
 799   volatile int i = 1;
 800   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 801   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 802 }
 803 ]])], [
 804     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 805     AC_MSG_RESULT([yes])
 806   ], [
 807     AC_MSG_RESULT([no])
 808
 809     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 810     AC_MSG_CHECKING([for __sync_* builtins])
 811     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 812 int main(int argc, char **argv) {
 813   volatile int i = 1;
 814   __sync_fetch_and_sub (&i, 1);
 815   return __sync_val_compare_and_swap (&i, 0, 1);
 816 }
 817 ]])], [
 818       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 819       AC_MSG_RESULT([yes])
 820
 821       AC_MSG_CHECKING([for __sync_swap builtin])
 822       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 823 int main(int argc, char **argv) {
 824   volatile int i = 1;
 825   return __sync_swap (&i, 2);
 826 }
 827 ]])], [
 828         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 829         AC_MSG_RESULT([yes])
 830       ], [
 831         AC_MSG_RESULT([no])
 832       ])
 833
 834     ], [
 835       AC_MSG_RESULT([no])
 836       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 837     ])
 838   ])
 839 ])
 840
 841 AC_CHECK_HEADERS([pthread_np.h],,, [
 842 #include <pthread.h>
 843 ])
 844 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 845
 846 dnl Utility macro to avoid retyping includes all the time
 847 m4_define([FRR_INCLUDES],
 848 [#ifdef SUNOS_5
 849 #define _POSIX_C_SOURCE 200809L
 850 #define __EXTENSIONS__
 851 #endif
 852 #include <stdio.h>
 853 #include <stdlib.h>
 854 #include <stddef.h>
 855 #include <sys/types.h>
 856 /* sys/conf.h depends on param.h on FBSD at least */
 857 #include <sys/param.h>
 858 /* Required for MAXSIG */
 859 #include <signal.h>
 860 #include <sys/socket.h>
 861 #ifdef __APPLE__
 862 # define __APPLE_USE_RFC_3542
 863 #endif
 864 #include <netinet/in.h>
 865 #include <sys/time.h>
 866 #include <time.h>
 867 #include <net/if.h>
 868 ])dnl
 869
 870 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 871 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 872 dnl an additional round for it.
 873
 874 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 875
 876 m4_define([FRR_INCLUDES],
 877 FRR_INCLUDES
 878 [#if HAVE_NET_IF_VAR_H
 879 # include <net/if_var.h>
 880 #endif
 881 ])dnl
 882
 883 AC_CHECK_HEADERS([netinet/in_var.h \
 884         net/if_dl.h net/netopt.h \
 885         inet/nd.h netinet/ip_icmp.h \
 886         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 887         [], [], FRR_INCLUDES)
 888
 889 AC_CHECK_HEADERS([ucontext.h], [], [],
 890 [#ifndef __USE_GNU
 891 #define __USE_GNU
 892 #endif /* __USE_GNU */
 893 FRR_INCLUDES
 894 ])
 895
 896 m4_define([UCONTEXT_INCLUDES],
 897 [#include <ucontext.h>])dnl
 898
 899 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 900   [], [], [UCONTEXT_INCLUDES])
 901 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 902   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 903    [], [], [UCONTEXT_INCLUDES])],
 904   [], [UCONTEXT_INCLUDES])
 905 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 906   [], [], [UCONTEXT_INCLUDES])
 907
 908 m4_define([FRR_INCLUDES],
 909 FRR_INCLUDES
 910 [
 911 #include <sys/un.h>
 912 #include <netinet/in_systm.h>
 913 #if HAVE_NETINET_IN_VAR_H
 914 # include <netinet/in_var.h>
 915 #endif
 916 #if HAVE_NET_IF_DL_H
 917 # include <net/if_dl.h>
 918 #endif
 919 #if HAVE_NET_NETOPT_H
 920 # include <net/netopt.h>
 921 #endif
 922 #include <net/route.h>
 923 #if HAVE_INET_ND_H
 924 # include <inet/nd.h>
 925 #endif
 926 #include <arpa/inet.h>
 927 /* Required for IDRP */
 928 #if HAVE_NETINET_IP_ICMP_H
 929 # include <netinet/ip_icmp.h>
 930 #endif
 931 ])dnl
 932
 933 dnl V6 headers are checked below, after we check for v6
 934
 935 AC_MSG_CHECKING([which operating system interface to use])
 936 case "$host_os" in
 937   sunos* | solaris2*)
 938     AC_MSG_RESULT([Solaris])
 939
 940     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 941     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 942     AC_DEFINE(_POSIX_C_SOURCE, 200809L, [enable POSIX.1-2008 and XPG7/SUSv4])
 943
 944     AC_CHECK_LIB(socket, main)
 945     AC_CHECK_LIB(nsl, main)
 946     AC_CHECK_LIB(umem, main)
 947     AC_CHECK_FUNCS([printstack], [
 948       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 949       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 950     ])
 951     CURSES=-lcurses
 952     SOLARIS="solaris"
 953     ;;
 954   linux*)
 955     AC_MSG_RESULT([Linux])
 956
 957     AC_DEFINE(GNU_LINUX,,GNU Linux)
 958     AC_DEFINE(HAVE_NETLINK,,netlink)
 959     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 960
 961     dnl Linux has a compilation problem with mixing
 962     dnl netinet/in.h and linux/in6.h they are not
 963     dnl compatible.  There has been discussion on
 964     dnl how to fix it but no real progress on implementation
 965     dnl when they fix it, remove this
 966     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 967     ;;
 968   openbsd*)
 969     AC_MSG_RESULT([OpenBSD])
 970
 971     AC_DEFINE(OPEN_BSD,,OpenBSD)
 972     AC_DEFINE(KAME,1,KAME IPv6)
 973     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 974
 975     if test "x${enable_pimd}" != "xno"; then
 976       case "$host_os" in
 977       openbsd6.0)
 978         ;;
 979       openbsd[6-9]*)
 980         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 981         ;;
 982       esac
 983     fi
 984     ;;
 985   *)
 986     AC_MSG_RESULT([BSD])
 987
 988     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 989     AC_DEFINE(KAME,1,KAME IPv6)
 990     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 991     ;;
 992 esac
 993 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 994
 995 AC_SYS_LARGEFILE
 996
 997 dnl ------------------------
 998 dnl Integrated REALMS option
 999 dnl ------------------------
1000 if test "${enable_realms}" = "yes"; then
1001     case "$host_os" in
1002       linux*)
1003        AC_DEFINE(SUPPORT_REALMS,, Realms support)
1004        ;;
1005       *)
1006        echo "Sorry, only Linux has REALMS support"
1007        exit 1
1008        ;;
1009     esac
1010 fi
1011 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1012
1013 dnl ---------------------
1014 dnl Integrated VTY option
1015 dnl ---------------------
1016 case "${enable_vtysh}" in
1017   "no") VTYSH="";;
1018   *)    VTYSH="vtysh";
1019          AC_DEFINE(VTYSH,,VTY shell)
1020 dnl      Vtysh uses libreadline, which looks for termcap functions at
1021 dnl      configure time.  We follow readlines search order.
1022 dnl      The required procedures are in libtermcap on NetBSD, in
1023 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1024          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1025            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1026              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1027                [AC_CHECK_LIB(ncurses, tputs,
1028                              LIBREADLINE="$LIBREADLINE -lncurses")]
1029               )]
1030             )]
1031           )
1032          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1033                       "$LIBREADLINE")
1034          if test $ac_cv_lib_readline_main = no; then
1035            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1036          fi
1037          AC_CHECK_HEADER(readline/history.h)
1038          if test $ac_cv_header_readline_history_h = no;then
1039            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1040          fi
1041          AC_CHECK_LIB(readline, rl_completion_matches,
1042                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1043          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1044            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1045          fi
1046          AC_SEARCH_LIBS([append_history], [readline], [frr_cv_append_history=yes], [frr_cv_append_history=no])
1047          if test "$frr_cv_append_history" = yes; then
1048            AC_DEFINE(HAVE_APPEND_HISTORY, 1, [Have history.h append_history])
1049          fi
1050          ;;
1051 esac
1052 AC_SUBST(LIBREADLINE)
1053 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1054
1055 dnl ----------
1056 dnl PAM module
1057 dnl
1058 dnl FRR detects the PAM library it is built against by checking for a
1059 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1060 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1061 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1062 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1063 dnl of OpenPAM.
1064 dnl ----------
1065 if test "$with_libpam" = "yes"; then
1066   AC_CHECK_HEADER([security/pam_misc.h],
1067     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1068      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1069      pam_conv_func="misc_conv"
1070     ],
1071     [], FRR_INCLUDES)
1072   AC_CHECK_HEADER([security/openpam.h],
1073     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1074      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1075      pam_conv_func="openpam_ttyconv"
1076     ],
1077     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1078   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1079     AC_MSG_WARN([*** pam support will not be built ***])
1080     with_libpam="no"
1081   fi
1082 fi
1083
1084 if test "$with_libpam" = "yes"; then
1085 dnl took this test from proftpds configure.in and suited to our needs
1086 dnl -------------------------------------------------------------------------
1087 dnl
1088 dnl This next check looks funky due to a linker problem with some versions
1089 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1090 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1091 dnl with RedHat 6.2 and Debian 2.2 or better.
1092 AC_CHECK_LIB(pam, pam_start,
1093   [AC_CHECK_LIB(pam, $pam_conv_func,
1094     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1095      LIBPAM="-lpam"],
1096     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1097      LIBPAM="-lpam -lpam_misc"]
1098     )
1099   ],
1100
1101   [AC_CHECK_LIB(pam, pam_end,
1102     [AC_CHECK_LIB(pam, $pam_conv_func,
1103       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1104        LIBPAM="-lpam -ldl"],
1105       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1106        LIBPAM="-lpam -ldl -lpam_misc"]
1107      )
1108   ],AC_MSG_WARN([*** pam support will not be built ***]),
1109   [-ldl])
1110   ]
1111 )
1112 fi
1113 AC_SUBST(LIBPAM)
1114
1115 dnl -------------------------------
1116 dnl Endian-ness check
1117 dnl -------------------------------
1118 AC_WORDS_BIGENDIAN
1119
1120 dnl -------------------------------
1121 dnl check the size in byte of the C
1122 dnl -------------------------------
1123 dnl AC_CHECK_SIZEOF(char)
1124 dnl AC_CHECK_SIZEOF(int)
1125 dnl AC_CHECK_SIZEOF(short)
1126 dnl AC_CHECK_SIZEOF(long)
1127
1128 dnl ----------------------------
1129 dnl check existance of functions
1130 dnl ----------------------------
1131 AC_FUNC_FNMATCH
1132 AC_FUNC_FORK
1133 AC_FUNC_MKTIME
1134 AC_FUNC_STAT
1135
1136 dnl -------------------------------
1137 dnl bgpd needs pow() and hence libm
1138 dnl -------------------------------
1139 TMPLIBS="$LIBS"
1140 AC_CHECK_HEADER([math.h],
1141   [AC_CHECK_LIB([m], [pow],
1142     [LIBM="-lm"
1143      LIBS="$LIBS $LIBM"
1144      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1145     ])
1146 ])
1147 if test x"$LIBM" = x ; then
1148   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1149 fi
1150 LIBS="$TMPLIBS"
1151
1152 AC_SUBST(LIBM)
1153
1154 AC_CHECK_FUNCS([ppoll], [
1155   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1156 ])
1157 AC_CHECK_FUNCS([pollts], [
1158   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1159 ])
1160
1161 dnl ---------------
1162 dnl other functions
1163 dnl ---------------
1164 AC_CHECK_FUNCS([ \
1165         strlcat strlcpy \
1166         getgrouplist])
1167
1168 AC_CHECK_HEADER([asm-generic/unistd.h],
1169                 [AC_CHECK_DECL(__NR_setns,
1170                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1171                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1172                                ])
1173                  AC_CHECK_FUNCS(setns)]
1174                )
1175
1176 dnl --------------------------
1177 dnl Determine IS-IS I/O method
1178 dnl --------------------------
1179 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1180 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1181 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1182 AC_CHECK_HEADER(net/bpf.h)
1183 AC_CHECK_HEADER(sys/dlpi.h)
1184 AC_MSG_CHECKING(zebra IS-IS I/O method)
1185
1186 case "$host_os" in
1187   linux*)
1188     AC_MSG_RESULT(pfpacket)
1189     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1190     ;;
1191   solaris* | sunos*)
1192     AC_MSG_RESULT(DLPI)
1193     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1194     ;;
1195   *)
1196     if test $ac_cv_header_net_bpf_h = no; then
1197       if test $ac_cv_header_sys_dlpi_h = no; then
1198         AC_MSG_RESULT(none)
1199         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1200           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1201         fi
1202         AC_MSG_WARN([*** IS-IS support will not be built ***])
1203         enable_isisd="no"
1204         enable_fabricd="no"
1205       else
1206         AC_MSG_RESULT(DLPI)
1207       fi
1208       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1209     else
1210       AC_MSG_RESULT(BPF)
1211       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1212     fi
1213     ;;
1214 esac
1215 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1216
1217 dnl ---------------------------------------------------------------
1218 dnl figure out how to specify an interface in multicast sockets API
1219 dnl ---------------------------------------------------------------
1220 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1221
1222 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1223         #include <sys/socket.h>
1224         #include <netinet/in.h>
1225         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1226         #include <linux/types.h>
1227 ])
1228
1229 m4_define([FRR_INCLUDES],
1230 FRR_INCLUDES
1231 [#if HAVE_LINUX_MROUTE_H
1232 # include <linux/mroute.h>
1233 #endif
1234 ])dnl
1235
1236 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1237         #include <sys/socket.h>
1238         #include <sys/types.h>
1239         #include <netinet/in.h>
1240         #include <net/route.h>
1241 ])
1242
1243 m4_define([FRR_INCLUDES],
1244 FRR_INCLUDES
1245 [#if HAVE_NETINET_IP_MROUTE_H
1246 # include <netinet/ip_mroute.h>
1247 #endif
1248 ])dnl
1249
1250 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1251 AC_TRY_COMPILE([#include <sys/param.h>],
1252 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1253   return (0);
1254 #else
1255   #error No support for BSD struct ip_mreq hack detected
1256 #endif],[AC_MSG_RESULT(yes)
1257 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1258 AC_MSG_RESULT(no))
1259
1260 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1261 AC_TRY_COMPILE([
1262 #include <sys/types.h>
1263 #include <netinet/in.h>
1264 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1265 ], [AC_MSG_RESULT(yes)
1266 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1267 AC_MSG_RESULT(no))
1268
1269 dnl ---------------------------------------------------------------
1270 dnl figure out how to check link-state
1271 dnl ---------------------------------------------------------------
1272 AC_CHECK_HEADER( [net/if_media.h],
1273   [m4_define([LINK_DETECT_INCLUDES],
1274     FRR_INCLUDES
1275     [#include <net/if_media.h>
1276   ])
1277   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1278     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1279     [], LINK_DETECT_INCLUDES)],
1280   [],
1281   FRR_INCLUDES)
1282
1283 dnl ---------------------------------------------------------------
1284 dnl Additional, newer way to check link-state using ifi_link_state.
1285 dnl Not available in all BSD's when ifmediareq available
1286 dnl ---------------------------------------------------------------
1287 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1288   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1289   [], FRR_INCLUDES)
1290
1291 dnl ------------------------
1292 dnl TCP_MD5SIG socket option
1293 dnl ------------------------
1294
1295 AC_CHECK_HEADER([netinet/tcp.h],
1296    [m4_define([MD5_INCLUDES],
1297       FRR_INCLUDES
1298       [#include <netinet/tcp.h>
1299     ])
1300     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1301    [],
1302    FRR_INCLUDES)
1303 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1304   AC_CHECK_HEADER([linux/tcp.h],
1305        [m4_define([MD5_INCLUDES],
1306           FRR_INCLUDES
1307           [#include <linux/tcp.h>
1308         ])
1309        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1310 fi
1311
1312 dnl ----------------------------------------------------------------------------
1313 dnl figure out if domainname is available in the utsname struct (GNU extension).
1314 dnl ----------------------------------------------------------------------------
1315 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1316
1317 dnl ------------------
1318 dnl IPv6 header checks
1319 dnl ------------------
1320 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1321         netinet6/in6_var.h netinet6/nd6.h], [], [],
1322         FRR_INCLUDES)
1323
1324 m4_define([FRR_INCLUDES],dnl
1325 FRR_INCLUDES
1326 [#if HAVE_NETINET6_IN6_H
1327 #include <netinet6/in6.h>
1328 #endif
1329 #if HAVE_NETINET_IN6_VAR_H
1330 #include <netinet/in6_var.h>
1331 #endif
1332 #include <netinet/icmp6.h>
1333 #if HAVE_NETINET6_IN6_VAR_H
1334 # include <netinet6/in6_var.h>
1335 #endif
1336 #if HAVE_NETINET6_ND6_H
1337 # include <netinet6/nd6.h>
1338 #endif
1339 ])dnl
1340
1341 dnl disable doc check
1342 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1343 if test "$SPHINXBUILD" = "/bin/false"; then
1344   if test "${enable_doc}" = "yes"; then
1345     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1346   fi
1347 fi
1348 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false")
1349 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1350
1351 dnl --------------------
1352 dnl Daemon disable check
1353 dnl --------------------
1354 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1355
1356 if test "${enable_bgpd}" = "no";then
1357   BGPD=""
1358 else
1359   BGPD="bgpd"
1360 fi
1361 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1362
1363 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1364 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1365 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1366
1367 AS_IF([test "${enable_ldpd}" != "no"], [
1368   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1369 ])
1370
1371 if test "$enable_bfdd" = "no"; then
1372   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1373   BFDD=""
1374 else
1375   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1376   BFDD="bfdd"
1377
1378   case $host_os in
1379     linux*)
1380       AC_DEFINE(BFD_LINUX, 1, bfdd)
1381       ;;
1382
1383     *)
1384       AC_DEFINE(BFD_BSD, 1, bfdd)
1385       ;;
1386   esac
1387 fi
1388
1389 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1390
1391 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1392   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1393 fi
1394
1395 NHRPD=""
1396 case "$host_os" in
1397   linux*)
1398     if test "${enable_nhrpd}" != "no"; then
1399       NHRPD="nhrpd"
1400     fi
1401     ;;
1402   *)
1403     if test "${enable_nhrpd}" = "yes"; then
1404       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1405     fi
1406     ;;
1407 esac
1408 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1409
1410 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1411
1412 if test "${enable_watchfrr}" = "no";then
1413   WATCHFRR=""
1414 else
1415   WATCHFRR="watchfrr"
1416 fi
1417 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1418
1419 OSPFCLIENT=""
1420 if test "${enable_ospfapi}" != "no";then
1421     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1422
1423   if test "${enable_ospfclient}" != "no";then
1424       OSPFCLIENT="ospfclient"
1425   fi
1426 fi
1427
1428 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1429 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1430 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1431 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1432 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1433 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1434 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1435 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1436 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1437 AM_CONDITIONAL(FABRICD, test "${enable_fabricd}" != "no")
1438
1439 if test "${enable_bgp_announce}" = "no";then
1440   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1441 else
1442   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1443 fi
1444
1445 if test "${enable_bgp_vnc}" != "no";then
1446   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1447 fi
1448 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1449
1450 AC_SUBST(SOLARIS)
1451 AC_SUBST(CURSES)
1452 AC_CHECK_LIB(crypt, crypt, [],
1453                     [AC_CHECK_LIB(crypto, DES_crypt)])
1454 AC_CHECK_LIB(resolv, res_init)
1455
1456 dnl ---------------------------
1457 dnl check system has PCRE regexp
1458 dnl ---------------------------
1459 if test "x$enable_pcreposix" = "xyes"; then
1460   AC_CHECK_LIB(pcreposix, regexec, [], [
1461     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1462   ])
1463 fi
1464 AC_SUBST(HAVE_LIBPCREPOSIX)
1465
1466 dnl ------------------
1467 dnl check C-Ares library
1468 dnl ------------------
1469 if test "${NHRPD}" != ""; then
1470   PKG_CHECK_MODULES([CARES], [libcares], , [
1471     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1472   ])
1473 fi
1474
1475
1476 dnl ------------------
1477 dnl check Net-SNMP library
1478 dnl ------------------
1479 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1480    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1481    if test x"$NETSNMP_CONFIG" = x"no"; then
1482       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1483    fi
1484    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1485    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1486    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1487    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1488 int main(void);
1489 ],
1490 [
1491 {
1492   return 0;
1493 }
1494 ])], [
1495      AC_MSG_ERROR([--enable-snmp given but not usable])])
1496    case "${enable_snmp}" in
1497      yes)
1498       SNMP_METHOD=agentx
1499       ;;
1500      agentx)
1501       SNMP_METHOD="${enable_snmp}"
1502       ;;
1503      *)
1504       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1505       ;;
1506    esac
1507    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1508    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1509 fi
1510 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1511 AC_SUBST(SNMP_LIBS)
1512 AC_SUBST(SNMP_CFLAGS)
1513
1514 dnl ---------------
1515 dnl math
1516 dnl ---------------
1517 AC_SEARCH_LIBS([sqrt], [m])
1518
1519 dnl ---------------
1520 dnl dlopen & dlinfo
1521 dnl ---------------
1522 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1523   AC_MSG_ERROR([unable to find the dlopen()])
1524 ])
1525
1526 AC_CHECK_HEADERS([link.h])
1527
1528 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1529   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1530 #include <stdlib.h>
1531 #ifdef HAVE_LINK_H
1532 #include <link.h>
1533 #endif
1534 #include <dlfcn.h>
1535 ]], [[
1536   char origin[1];
1537   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1538 ]])], [
1539     frr_cv_rtld_di_origin=yes
1540   ], [
1541     frr_cv_rtld_di_origin=no
1542   ])
1543 ])
1544 if test "$frr_cv_rtld_di_origin" = yes; then
1545   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1546 fi
1547
1548 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1549   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1550 #include <stdlib.h>
1551 #ifdef HAVE_LINK_H
1552 #include <link.h>
1553 #endif
1554 #include <dlfcn.h>
1555 ]], [[
1556   struct link_map *lm = NULL;
1557   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1558 ]])], [
1559     frr_cv_rtld_di_linkmap=yes
1560   ], [
1561     frr_cv_rtld_di_linkmap=no
1562   ])
1563 ])
1564 if test "$frr_cv_rtld_di_linkmap" = yes; then
1565   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1566 fi
1567
1568 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1569
1570 dnl ---------------------------
1571 dnl sockaddr and netinet checks
1572 dnl ---------------------------
1573 AC_CHECK_TYPES([
1574         struct sockaddr_dl,
1575         struct vifctl, struct mfcctl, struct sioc_sg_req,
1576         vifi_t, struct sioc_vif_req, struct igmpmsg,
1577         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1578         struct nd_opt_adv_interval, struct rt_addrinfo,
1579         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1580         [], [], FRR_INCLUDES)
1581
1582 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1583         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1584         struct sockaddr_dl.sdl_len,
1585         struct if6_aliasreq.ifra_lifetime,
1586         struct nd_opt_adv_interval.nd_opt_ai_type],
1587         [], [], FRR_INCLUDES)
1588
1589 dnl ---------------------------
1590 dnl IRDP/pktinfo/icmphdr checks
1591 dnl ---------------------------
1592
1593 AC_CHECK_TYPES([struct in_pktinfo], [
1594   AC_CHECK_TYPES([struct icmphdr], [
1595     IRDP=true
1596   ], [
1597     IRDP=false
1598   ], [FRR_INCLUDES])
1599 ], [
1600   IRDP=false
1601 ], [FRR_INCLUDES])
1602
1603 case "${enable_irdp}" in
1604 yes)
1605   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1606   ;;
1607 no)
1608   IRDP=false
1609   ;;
1610 esac
1611
1612 AM_CONDITIONAL(IRDP, $IRDP)
1613
1614 dnl -----------------------
1615 dnl checking for IP_PKTINFO
1616 dnl -----------------------
1617 AC_MSG_CHECKING(for IP_PKTINFO)
1618 AC_TRY_COMPILE([#include <netdb.h>], [
1619   int opt = IP_PKTINFO;
1620 ], [
1621   AC_MSG_RESULT(yes)
1622   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1623 ], [
1624   AC_MSG_RESULT(no)
1625 ])
1626
1627 dnl ---------------------------
1628 dnl checking for IP_RECVDSTADDR
1629 dnl ---------------------------
1630 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1631 AC_TRY_COMPILE([#include <netinet/in.h>], [
1632   int opt = IP_RECVDSTADDR;
1633 ], [
1634   AC_MSG_RESULT(yes)
1635   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1636 ], [
1637   AC_MSG_RESULT(no)
1638 ])
1639
1640 dnl ----------------------
1641 dnl checking for IP_RECVIF
1642 dnl ----------------------
1643 AC_MSG_CHECKING(for IP_RECVIF)
1644 AC_TRY_COMPILE([#include <netinet/in.h>], [
1645   int opt = IP_RECVIF;
1646 ], [
1647   AC_MSG_RESULT(yes)
1648   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1649 ], [
1650   AC_MSG_RESULT(no)
1651 ])
1652
1653 dnl ----------------------
1654 dnl checking for SO_BINDANY
1655 dnl ----------------------
1656 AC_MSG_CHECKING(for SO_BINDANY)
1657 AC_TRY_COMPILE([#include <sys/socket.h>], [
1658   int opt = SO_BINDANY;
1659 ], [
1660   AC_MSG_RESULT(yes)
1661   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1662 ], [
1663   AC_MSG_RESULT(no)
1664 ])
1665
1666 dnl ----------------------
1667 dnl checking for IP_FREEBIND
1668 dnl ----------------------
1669 AC_MSG_CHECKING(for IP_FREEBIND)
1670 AC_TRY_COMPILE([#include <netinet/in.h>], [
1671   int opt = IP_FREEBIND;
1672 ], [
1673   AC_MSG_RESULT(yes)
1674   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1675 ], [
1676   AC_MSG_RESULT(no)
1677 ])
1678
1679 dnl --------------------------------------
1680 dnl checking for be32dec existence or not
1681 dnl --------------------------------------
1682 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1683                [#include <sys/endian.h>])
1684
1685 dnl --------------------------------------
1686 dnl checking for clock_time monotonic struct and call
1687 dnl --------------------------------------
1688 AC_CHECK_DECL(CLOCK_MONOTONIC,
1689         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1690          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1691 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1692
1693 dnl --------------------------------------
1694 dnl checking for flex and bison
1695 dnl --------------------------------------
1696
1697 AM_PROG_LEX
1698 AC_MSG_CHECKING(version of flex)
1699 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1700 frr_ac_flex_version="${frr_ac_flex_version##* }"
1701 AC_MSG_RESULT([$frr_ac_flex_version])
1702 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1703   LEX="$SHELL $missing_dir/missing flex"
1704   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1705     AC_MSG_WARN([using pregenerated flex output files])
1706   else
1707     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1708   fi
1709   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1710   AC_SUBST([LEXLIB], [''])
1711 ])
1712
1713 AC_PROG_YACC
1714 dnl thanks GNU bison for this b*llshit...
1715 AC_MSG_CHECKING(version of bison)
1716 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1717 frr_ac_bison_version="${frr_ac_bison_version##* }"
1718 frr_ac_bison_missing="false"
1719 case "x${frr_ac_bison_version}" in
1720   x2.7*)
1721     BISON_OPENBRACE='"'
1722     BISON_CLOSEBRACE='"'
1723     BISON_VERBOSE=''
1724     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1725     ;;
1726   x2.*|x1.*)
1727     AC_MSG_RESULT([$frr_ac_bison_version])
1728     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1729     frr_ac_bison_missing="true"
1730     ;;
1731   x)
1732     AC_MSG_RESULT([none])
1733     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1734     frr_ac_bison_missing="true"
1735     ;;
1736   *)
1737     BISON_OPENBRACE='{'
1738     BISON_CLOSEBRACE='}'
1739     BISON_VERBOSE='-Dparse.error=verbose'
1740     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1741     ;;
1742 esac
1743 AC_SUBST(BISON_OPENBRACE)
1744 AC_SUBST(BISON_CLOSEBRACE)
1745 AC_SUBST(BISON_VERBOSE)
1746
1747 if $frr_ac_bison_missing; then
1748   YACC="$SHELL $missing_dir/missing bison -y"
1749   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1750     AC_MSG_WARN([using pregenerated bison output files])
1751   else
1752     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1753   fi
1754 fi
1755
1756 dnl -------------------
1757 dnl capabilities checks
1758 dnl -------------------
1759 if test "${enable_capabilities}" != "no"; then
1760   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1761   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1762     [AC_MSG_RESULT(yes)
1763      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1764      frr_ac_keepcaps="yes"],
1765      AC_MSG_RESULT(no)
1766   )
1767   if test x"${frr_ac_keepcaps}" = x"yes"; then
1768     AC_CHECK_HEADERS(sys/capability.h)
1769   fi
1770   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1771     AC_CHECK_LIB(cap, cap_init,
1772       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1773        LIBCAP="-lcap"
1774        frr_ac_lcaps="yes"]
1775     )
1776   else
1777     AC_CHECK_HEADERS(priv.h,
1778      [AC_MSG_CHECKING(Solaris style privileges are available)
1779       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1780           [AC_MSG_RESULT(yes)
1781            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1782            frr_ac_scaps="yes"],
1783            AC_MSG_RESULT(no)
1784       )
1785      ]
1786    )
1787   fi
1788   if test x"${frr_ac_scaps}" = x"yes" \
1789        -o x"${frr_ac_lcaps}" = x"yes"; then
1790     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1791   fi
1792 fi
1793 AC_SUBST(LIBCAP)
1794
1795 dnl ---------------------------
1796 dnl check for glibc 'backtrace'
1797 dnl ---------------------------
1798 if test x"${enable_backtrace}" != x"no" ; then
1799   backtrace_ok=no
1800   AC_CHECK_HEADER([execinfo.h], [
1801     AC_SEARCH_LIBS([backtrace], [execinfo], [
1802       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1803       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1804       backtrace_ok=yes
1805     ],, [-lm])
1806   ])
1807
1808   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1809     dnl user explicitly requested backtrace but we failed to find support
1810     AC_MSG_FAILURE([failed to find backtrace support])
1811   fi
1812 fi
1813
1814 dnl -----------------------------------------
1815 dnl check for malloc mallinfo struct and call
1816 dnl this must try and link using LIBS, in
1817 dnl order to check no alternative allocator
1818 dnl has been specified, which might not provide
1819 dnl mallinfo, e.g. such as Umem on Solaris.
1820 dnl -----------------------------------------
1821 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
1822
1823 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1824   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1825 #ifdef HAVE_MALLOC_H
1826 #include <malloc.h>
1827 #endif
1828 #ifdef HAVE_MALLOC_NP_H
1829 #include <malloc_np.h>
1830 #endif
1831 #ifdef HAVE_MALLOC_MALLOC_H
1832 #include <malloc/malloc.h>
1833 #endif
1834 ]], [[
1835 struct mallinfo ac_x; ac_x = mallinfo ();
1836 ]])], [
1837     frr_cv_mallinfo=yes
1838   ], [
1839     frr_cv_mallinfo=no
1840   ])
1841 ])
1842 if test "$frr_cv_mallinfo" = yes; then
1843   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1844 fi
1845
1846 AC_MSG_CHECKING(whether malloc_usable_size is available)
1847 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1848 #ifdef HAVE_MALLOC_H
1849 #include <malloc.h>
1850 #endif
1851 #ifdef HAVE_MALLOC_MALLOC_H
1852 #include <malloc/malloc.h>
1853 #endif
1854 ]], [[
1855 size_t ac_x; ac_x = malloc_usable_size(NULL);
1856 ]])], [
1857   AC_MSG_RESULT(yes)
1858   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1859 ], [
1860   AC_MSG_RESULT(no)
1861
1862   AC_MSG_CHECKING(whether malloc_size is available)
1863   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1864 #ifdef HAVE_MALLOC_H
1865 #include <malloc.h>
1866 #endif
1867 #ifdef HAVE_MALLOC_MALLOC_H
1868 #include <malloc/malloc.h>
1869 #endif
1870 ]], [[
1871 size_t ac_x; ac_x = malloc_size(NULL);
1872 ]])], [
1873     AC_MSG_RESULT(yes)
1874     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1875   ], [
1876     AC_MSG_RESULT(no)
1877   ])
1878 ])
1879
1880 dnl ------
1881 dnl ZeroMQ
1882 dnl ------
1883 if test "x$enable_zeromq" != "xno"; then
1884   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1885     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1886     ZEROMQ=true
1887   ], [
1888     if test "x$enable_zeromq" = "xyes"; then
1889       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1890     fi
1891   ])
1892 fi
1893 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1894
1895 dnl ----------
1896 dnl configure date
1897 dnl ----------
1898 dev_version=`echo $VERSION | grep dev`
1899 #don't expire deprecated code in non 'dev' branch
1900 if test "${dev_version}" = ""; then
1901    CONFDATE=0
1902 else
1903    CONFDATE=`date '+%Y%m%d'`
1904 fi
1905 AC_SUBST(CONFDATE)
1906
1907 dnl ------------------------------
1908 dnl set paths for state directory
1909 dnl ------------------------------
1910 AC_MSG_CHECKING(directory to use for state file)
1911 if test "${prefix}" = "NONE"; then
1912   frr_statedir_prefix="";
1913 else
1914   frr_statedir_prefix=${prefix}
1915 fi
1916 if test "${localstatedir}" = '${prefix}/var'; then
1917   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1918                         ${frr_statedir_prefix}/var/adm dnl
1919                         ${frr_statedir_prefix}/etc dnl
1920                         /var/run        dnl
1921                         /var/adm        dnl
1922                         /etc            dnl
1923                         /dev/null;
1924   do
1925     test -d $FRR_STATE_DIR && break
1926   done
1927   frr_statedir=$FRR_STATE_DIR
1928 else
1929   frr_statedir=${localstatedir}
1930 fi
1931 if test $frr_statedir = "/dev/null"; then
1932     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1933 fi
1934 AC_MSG_RESULT(${frr_statedir})
1935 AC_SUBST(frr_statedir)
1936
1937 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1938 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1939 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1940 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1941
1942 dnl autoconf does this, but it does it too late...
1943 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1944 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1945
1946 dnl get the full path, recursing through variables...
1947 vtysh_bin="$bindir/vtysh"
1948 for I in 1 2 3 4 5 6 7 8 9 10; do
1949         eval vtysh_bin="\"$vtysh_bin\""
1950 done
1951 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1952 AC_SUBST(vtysh_bin)
1953
1954 CFG_SYSCONF="$sysconfdir"
1955 CFG_SBIN="$sbindir"
1956 CFG_STATE="$frr_statedir"
1957 CFG_MODULE="$moduledir"
1958 for I in 1 2 3 4 5 6 7 8 9 10; do
1959         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1960         eval CFG_SBIN="\"$CFG_SBIN\""
1961         eval CFG_STATE="\"$CFG_STATE\""
1962         eval CFG_MODULE="\"$CFG_MODULE\""
1963 done
1964 AC_SUBST(CFG_SYSCONF)
1965 AC_SUBST(CFG_SBIN)
1966 AC_SUBST(CFG_STATE)
1967 AC_SUBST(CFG_MODULE)
1968 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1969
1970 dnl ------------------------------------
1971 dnl Enable RPKI and add librtr to libs
1972 dnl ------------------------------------
1973 if test "${enable_rpki}" = "yes"; then
1974   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1975       [RPKI=true],
1976       [RPKI=false
1977       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1978   )
1979 fi
1980 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1981
1982 dnl ------------------------------------------
1983 dnl Check whether rtrlib was build with ssh support
1984 dnl ------------------------------------------
1985 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1986 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1987                         [[struct tr_ssh_config config;]])],
1988         [AC_MSG_RESULT(yes)
1989         AC_DEFINE(FOUND_SSH,,found_ssh)],
1990         AC_MSG_RESULT(no)
1991 )
1992
1993 dnl ---------------------------
1994 dnl Check htonl works correctly
1995 dnl ---------------------------
1996 AC_MSG_CHECKING(for working htonl)
1997 AC_CACHE_VAL(ac_cv_htonl_works,
1998  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1999                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2000  ]
2001 )
2002 AC_MSG_RESULT($ac_cv_htonl_works)
2003
2004 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2005
2006 AC_CONFIG_FILES([
2007           redhat/frr.spec
2008           solaris/Makefile
2009           debianpkg/changelog
2010           alpine/APKBUILD
2011           snapcraft/snapcraft.yaml
2012           lib/version.h
2013           tests/lib/cli/test_cli.refout
2014           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2015           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2016           pkgsrc/eigrpd.sh])
2017
2018 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2019 AC_CONFIG_FILES([tools/frr],[chmod +x tools/frr])
2020
2021 AC_CONFIG_COMMANDS([lib/route_types.h], [
2022         dst="${ac_abs_top_builddir}/lib/route_types.h"
2023         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2024                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2025                 > "${dst}.tmp"
2026         test -f "${dst}" \
2027                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2028                 && rm "${dst}.tmp" \
2029                 || mv "${dst}.tmp" "${dst}"
2030 ], [
2031         PERL="$PERL"
2032 ])
2033
2034 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2035     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2036         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2037         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2038                 "${ac_abs_top_srcdir}" \
2039                 > "${dst}.tmp"
2040         test -f "${dst}" \
2041                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2042                 && rm "${dst}.tmp" \
2043                 || mv "${dst}.tmp" "${dst}"
2044     ], [
2045         PERL="$PERL"
2046     ])
2047 ])
2048
2049 ## Hack, but working solution to avoid rebuilding of frr.info.
2050 ## It's already in CVS until texinfo 4.7 is more common.
2051 AC_OUTPUT
2052
2053 echo "
2054 FRRouting configuration
2055 ------------------------------
2056 FRR version             : ${PACKAGE_VERSION}
2057 host operating system   : ${host_os}
2058 source code location    : ${srcdir}
2059 compiler                : ${CC}
2060 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2061 make                    : ${MAKE-make}
2062 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2063 state file directory    : ${frr_statedir}
2064 config file directory   : `eval echo \`echo ${sysconfdir}\``
2065 example directory       : `eval echo \`echo ${exampledir}\``
2066 module directory        : ${CFG_MODULE}
2067 user to run as          : ${enable_user}
2068 group to run as         : ${enable_group}
2069 group for vty sockets   : ${enable_vty_group}
2070 config file mask        : ${enable_configfile_mask}
2071 log file mask           : ${enable_logfile_mask}
2072 zebra protobuf enabled  : ${enable_protobuf:-no}
2073
2074 The above user and group must have read/write access to the state file
2075 directory and to the config files in the config file directory."
2076
2077 if test "${enable_doc}" != "no";then
2078   AS_IF([test "$SPHINXBUILD" = /bin/false],
2079      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2080 fi