configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl if the user has specified any CFLAGS, override our settings
 193 if test "x${enable_gcov}" = "xyes"; then
 194    if test "z$orig_cflags" = "z"; then
 195       AC_C_FLAG([-coverage])
 196       AC_C_FLAG([-O0])
 197    fi
 198
 199    LDFLAGS="${LDFLAGS} -lgcov"
 200 elif test "x${enable_dev_build}" = "xyes"; then
 201    AC_DEFINE(DEV_BUILD,,Build for development)
 202    if test "z$orig_cflags" = "z"; then
 203       AC_C_FLAG([-g3])
 204       AC_C_FLAG([-O0])
 205    fi
 206    if test "x${enable_lua}" = "xyes"; then
 207       AC_CHECK_LIB([lua], [lua_newstate],
 208       [LIBS="$LIBS -llua"])
 209       AC_DEFINE(HAVE_LUA,,Lua enabled for development)
 210    fi
 211 else
 212    if test "x${enable_lua}" = "xyes"; then
 213       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 214    fi
 215    if test "z$orig_cflags" = "z"; then
 216       AC_C_FLAG([-g])
 217       AC_C_FLAG([-Os], [
 218         AC_C_FLAG([-O2])
 219       ])
 220    fi
 221 fi
 222 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 223
 224 dnl always want these CFLAGS
 225 AC_C_FLAG([-fno-omit-frame-pointer])
 226 AC_C_FLAG([-funwind-tables])
 227 AC_C_FLAG([-Wall])
 228 AC_C_FLAG([-Wextra])
 229 AC_C_FLAG([-Wmissing-prototypes])
 230 AC_C_FLAG([-Wmissing-declarations])
 231 AC_C_FLAG([-Wpointer-arith])
 232 AC_C_FLAG([-Wbad-function-cast])
 233 AC_C_FLAG([-Wwrite-strings])
 234 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 235   AC_C_FLAG([-Wcast-qual])
 236   AC_C_FLAG([-Wstrict-prototypes])
 237   AC_C_FLAG([-Wmissing-noreturn])
 238   AC_C_FLAG([-Wmissing-format-attribute])
 239   AC_C_FLAG([-Wunreachable-code])
 240   AC_C_FLAG([-Wpacked])
 241   AC_C_FLAG([-Wpadded])
 242   AC_C_FLAG([-Wshadow])
 243 else
 244   AC_C_FLAG([-Wno-unused-result])
 245 fi
 246 AC_C_FLAG([-Wno-unused-parameter])
 247 AC_C_FLAG([-Wno-missing-field-initializers])
 248
 249 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 250 dnl for some reason the string consts get 'promoted' to char *,
 251 dnl triggering a const to non-const conversion warning.
 252 AC_C_FLAG([-diag-disable 3179])
 253
 254 if test x"${enable_werror}" = x"yes" ; then
 255   WERROR="-Werror"
 256 fi
 257 AC_SUBST(WERROR)
 258
 259 SAN_FLAGS=""
 260 if test "$enable_address_sanitizer" = "yes"; then
 261   AC_C_FLAG([-fsanitize=address], [
 262     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 263   ], [
 264     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 265   ])
 266 fi
 267 if test "$enable_thread_sanitizer" = "yes"; then
 268   AC_C_FLAG([-fsanitize=thread], [
 269     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 270   ], [
 271     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 272   ])
 273 fi
 274 if test "$enable_memory_sanitizer" = "yes"; then
 275   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 276     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 277   ], [
 278     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 279   ])
 280 fi
 281 AC_SUBST([SAN_FLAGS])
 282
 283 dnl ----------
 284 dnl Essentials
 285 dnl ----------
 286
 287 AX_PTHREAD([
 288   CC="$PTHREAD_CC"
 289   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 290   LIBS="$PTHREAD_LIBS $LIBS"
 291 ], [
 292   AC_MSG_FAILURE([This FRR version needs pthreads])
 293 ])
 294
 295 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 296                 [frr_cv_pthread_condattr_setclock=yes],
 297                 [frr_cv_pthread_condattr_setclock=no])
 298 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 299   AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK, 1, [Have pthread.h pthread_condattr_setclock])
 300 fi
 301
 302 dnl --------------
 303 dnl Check programs
 304 dnl --------------
 305 AC_PROG_INSTALL
 306 AC_PROG_LN_S
 307 AC_PROG_MAKE_SET
 308 AC_CHECK_TOOL(AR, ar)
 309
 310 dnl -------
 311 dnl libtool
 312 dnl -------
 313 AC_ARG_ENABLE(static-bin,
 314   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 315 LT_INIT
 316 _LT_CONFIG_LIBTOOL([
 317   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 318     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 319 ])
 320 if test "$enable_static_bin" = "yes"; then
 321   AC_LDFLAGS="-static"
 322 fi
 323 AC_SUBST(AC_LDFLAGS)
 324 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 325
 326 dnl ----------------------
 327 dnl Packages configuration
 328 dnl ----------------------
 329 AC_ARG_WITH(pkg-extra-version,
 330         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 331         [EXTRAVERSION=$withval],)
 332 AC_ARG_WITH(pkg-git-version,
 333         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 334         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 335 AC_ARG_WITH(vtysh_pager,
 336         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 337         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 338 AC_ARG_ENABLE(vtysh,
 339   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 340 AC_ARG_ENABLE(doc,
 341   AS_HELP_STRING([--disable-doc], [do not build docs]))
 342 AC_ARG_ENABLE(doc-html,
 343   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 344 AC_ARG_ENABLE(zebra,
 345   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 346 AC_ARG_ENABLE(bgpd,
 347   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 348 AC_ARG_ENABLE(ripd,
 349   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 350 AC_ARG_ENABLE(ripngd,
 351   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 352 AC_ARG_ENABLE(ospfd,
 353   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 354 AC_ARG_ENABLE(ospf6d,
 355   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 356 AC_ARG_ENABLE(ldpd,
 357   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 358 AC_ARG_ENABLE(nhrpd,
 359   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 360 AC_ARG_ENABLE(eigrpd,
 361   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 362 AC_ARG_ENABLE(babeld,
 363   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 364 AC_ARG_ENABLE(watchfrr,
 365   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 366 AC_ARG_ENABLE(isisd,
 367   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 368 AC_ARG_ENABLE(pimd,
 369   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 370 AC_ARG_ENABLE(pbrd,
 371   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 372 AC_ARG_ENABLE(sharpd,
 373   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 374 AC_ARG_ENABLE(staticd,
 375   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 376 AC_ARG_ENABLE(fabricd,
 377   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 378 AC_ARG_ENABLE(bgp-announce,
 379   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 380 AC_ARG_ENABLE(bgp-vnc,
 381   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 382 AC_ARG_ENABLE(snmp,
 383   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 384 AC_ARG_ENABLE(zeromq,
 385   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 386 AC_ARG_WITH(libpam,
 387   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 388 AC_ARG_ENABLE(ospfapi,
 389   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 390 AC_ARG_ENABLE(ospfclient,
 391   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 392                           (this is the default if --disable-ospfapi is set)]))
 393 AC_ARG_ENABLE(multipath,
 394   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 395 AC_ARG_ENABLE(user,
 396   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 397 AC_ARG_ENABLE(group,
 398   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 399 AC_ARG_ENABLE(vty_group,
 400   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 401 AC_ARG_ENABLE(configfile_mask,
 402   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 403 AC_ARG_ENABLE(logfile_mask,
 404   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 405 AC_ARG_ENABLE(shell_access,
 406   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 407 AC_ARG_ENABLE(realms,
 408   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 409 AC_ARG_ENABLE(rtadv,
 410   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 411 AC_ARG_ENABLE(irdp,
 412   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 413 AC_ARG_ENABLE(capabilities,
 414   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 415 AC_ARG_ENABLE(rusage,
 416   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 417 AC_ARG_ENABLE(gcc_ultra_verbose,
 418   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 419 AC_ARG_ENABLE(backtrace,
 420   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 421 AC_ARG_ENABLE(time-check,
 422   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 423 AC_ARG_ENABLE(pcreposix,
 424   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 425 AC_ARG_ENABLE(fpm,
 426   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 427 AC_ARG_ENABLE(systemd,
 428   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 429 AC_ARG_ENABLE(werror,
 430   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 431 AC_ARG_ENABLE(cumulus,
 432   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 433 AC_ARG_ENABLE(datacenter,
 434   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 435 AC_ARG_ENABLE(fuzzing,
 436   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 437 AC_ARG_ENABLE(netlink_fuzzing,
 438   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 439 AC_ARG_ENABLE(rr-semantics,
 440   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 441 AC_ARG_ENABLE([protobuf],
 442   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 443 AC_ARG_ENABLE([oldvpn_commands],
 444   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 445 AC_ARG_ENABLE(rpki,
 446   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 447 AC_ARG_ENABLE([clippy-only],
 448   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 449 AC_ARG_ENABLE([numeric_version],
 450   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 451 AC_ARG_ENABLE([gcov],
 452   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 453 AC_ARG_ENABLE(bfdd,
 454   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 455 AC_ARG_ENABLE([address-sanitizer],
 456   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 457 AC_ARG_ENABLE([thread-sanitizer],
 458   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 459 AC_ARG_ENABLE([memory-sanitizer],
 460   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 461
 462 AS_IF([test "${enable_clippy_only}" != "yes"], [
 463 AC_CHECK_HEADERS(json-c/json.h)
 464 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 465 if test $ac_cv_lib_json_c_json_object_get = no; then
 466   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 467   if test $ac_cv_lib_json_json_object_get = no; then
 468       AC_MSG_ERROR([lib json is needed to compile])
 469   fi
 470 fi
 471 ])
 472
 473 AC_ARG_ENABLE([dev_build],
 474     AS_HELP_STRING([--enable-dev-build], [build for development]))
 475
 476 AC_ARG_ENABLE([lua],
 477     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 478
 479 if test x"${enable_time_check}" != x"no" ; then
 480   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 481     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 482   else
 483     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 484   fi
 485 fi
 486
 487 case "${enable_systemd}" in
 488   "no") ;;
 489   "yes")
 490   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 491   if test $ac_cv_lib_systemd_sd_notify = no; then
 492     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 493   else
 494     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 495   fi
 496   ;;
 497   "*") ;;
 498 esac
 499
 500 if test "${enable_rr_semantics}" != "no" ; then
 501   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 502 fi
 503
 504 if test "${enable_datacenter}" = "yes" ; then
 505   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 506   DFLT_NAME="datacenter"
 507 else
 508   DFLT_NAME="traditional"
 509 fi
 510
 511 if test "${enable_fuzzing}" = "yes" ; then
 512   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 513 fi
 514
 515 if test "${enable_netlink_fuzzing}" = "yes" ; then
 516   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 517 fi
 518
 519 if test "${enable_cumulus}" = "yes" ; then
 520   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 521 fi
 522
 523 AC_SUBST(DFLT_NAME)
 524 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 525
 526 if test "${enable_shell_access}" = "yes"; then
 527    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 528 fi
 529
 530 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 531
 532 #
 533 # Python for clippy
 534 #
 535
 536 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 537   AC_MSG_CHECKING([whether we found a working Python version])
 538   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 539 #include <Python.h>
 540 #if PY_VERSION_HEX < 0x02070000
 541 #error python too old
 542 #endif
 543 int main(void);
 544 ],
 545 [
 546 {
 547   Py_Initialize();
 548   return 0;
 549 }
 550 ])], [
 551     # some python installs are missing the zlib dependency...
 552     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 553     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 554 #include <Python.h>
 555 #if PY_VERSION_HEX < 0x02070000
 556 #error python too old
 557 #endif
 558 int main(void);
 559 ],
 560 [
 561 {
 562   Py_Initialize();
 563   return 0;
 564 }
 565 ])], [
 566       m4_if([$1], [], [
 567         PYTHONCONFIG=""
 568         unset PYTHON_LIBS
 569         unset PYTHON_CFLAGS
 570       ], [$1])
 571     ])
 572   ])
 573 ])
 574
 575 AS_IF([test "$host" = "$build"], [
 576   PYTHONCONFIG=""
 577
 578   # ordering:
 579   # 1.  try python3, but respect the user's preference on which minor ver
 580   # 2.  try python, which might be py3 or py2 again on the user's preference
 581   # 3.  try python2 (can really only be 2.7 but eh)
 582   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 583   #
 584   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 585   # (AX_PYTHON does not do what we need)
 586
 587   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 588         python3-config \
 589         python-config \
 590         python2-config \
 591         python3.6-config \
 592         python3.5-config \
 593         python3.4-config \
 594         python3.3-config \
 595         python3.2-config \
 596         python2.7-config ])
 597   if test -n "$PYTHONCONFIG"; then
 598     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 599     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 600
 601     FRR_PYTHON_CHECK_WORKING([])
 602   fi
 603
 604   if test -z "$PYTHONCONFIG"; then
 605     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 606       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 607         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 608           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 609             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 610               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 611                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 612                 ])])])])])])
 613
 614
 615     FRR_PYTHON_CHECK_WORKING([
 616       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 617     ])
 618   fi
 619 ])
 620 AC_SUBST(PYTHON_CFLAGS)
 621 AC_SUBST(PYTHON_LIBS)
 622
 623 #
 624 # Logic for protobuf support.
 625 #
 626 if test "$enable_protobuf" = "yes"; then
 627   # Check for protoc & protoc-c
 628
 629   # protoc is not required, it's only for a "be nice" helper target
 630   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 631
 632   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 633   if test "$PROTOC_C" = "/bin/false"; then
 634     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 635   fi
 636
 637   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 638     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 639   ])
 640   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 641     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 642   ])
 643
 644   AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 645 fi
 646 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 647
 648 #
 649 # Logic for old vpn commans support.
 650 #
 651 if test "$enable_oldvpn_commands" = "yes"; then
 652    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 653 fi
 654
 655 #
 656 # End of logic for protobuf support.
 657 #
 658
 659 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 660 if test "${enable_rtadv}" != "no"; then
 661   AC_MSG_RESULT(yes)
 662   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 663 else
 664   AC_MSG_RESULT(no)
 665 fi
 666
 667 if test x"${enable_user}" = x"no"; then
 668   enable_user=""
 669 else
 670   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 671     enable_user="frr"
 672   fi
 673   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 674 fi
 675
 676 if test x"${enable_group}" = x"no"; then
 677   enable_group=""
 678 else
 679   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 680     enable_group="frr"
 681   fi
 682   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 683 fi
 684
 685 if test x"${enable_vty_group}" = x"yes" ; then
 686   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 687 elif test x"${enable_vty_group}" != x""; then
 688   if test x"${enable_vty_group}" != x"no"; then
 689     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 690   fi
 691 fi
 692 AC_SUBST([enable_user])
 693 AC_SUBST([enable_group])
 694 AC_SUBST([enable_vty_group])
 695
 696 enable_configfile_mask=${enable_configfile_mask:-0600}
 697 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 698
 699 enable_logfile_mask=${enable_logfile_mask:-0600}
 700 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 701
 702 MPATH_NUM=1
 703
 704 case "${enable_multipath}" in
 705   0)
 706     MPATH_NUM=64
 707     ;;
 708   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 709     MPATH_NUM="${enable_multipath}"
 710     ;;
 711   "")
 712     ;;
 713   *)
 714     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 715     ;;
 716 esac
 717
 718 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 719
 720 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 721
 722 dnl --------------------
 723 dnl Enable code coverage
 724 dnl --------------------
 725 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 726
 727 dnl ------------------------------------
 728 dnl Alpine only accepts numeric versions
 729 dnl ------------------------------------
 730 if test "x${enable_numeric_version}" != "x" ; then
 731   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 732   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 733 fi
 734
 735 dnl -----------------------------------
 736 dnl Add extra version string to package
 737 dnl name, string and version fields.
 738 dnl -----------------------------------
 739 if test "x${EXTRAVERSION}" != "x" ; then
 740   VERSION="${VERSION}${EXTRAVERSION}"
 741   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 742   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 743   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 744 fi
 745
 746 if test "x$with_pkg_git_version" = "xyes"; then
 747         if test -d "${srcdir}/.git"; then
 748                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 749         else    with_pkg_git_version="no"
 750                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 751         fi
 752 fi
 753 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 754
 755 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 756 AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 757   frr_cv_interp=""
 758   AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 759     if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 760       frr_cv_interp="`xargs -0 echo < conftest.interp`"
 761     fi
 762     test -f conftest.interp && rm conftest.interp
 763   ])
 764 ])
 765 if test -n "$frr_cv_interp"; then
 766   AC_DEFINE_UNQUOTED(INTERP, ["$frr_cv_interp"], [.interp value])
 767 fi
 768
 769 dnl ------------------------------------
 770 dnl Check C keywords and standard  types
 771 dnl ------------------------------------
 772 AC_C_CONST
 773 AC_C_INLINE
 774 AC_C_VOLATILE
 775 AC_HEADER_STDC
 776 dnl AC_TYPE_PID_T
 777 AC_TYPE_UID_T
 778 AC_TYPE_MODE_T
 779 AC_TYPE_SIZE_T
 780 AC_STRUCT_TM
 781
 782 dnl -------------------------
 783 dnl Check other header files.
 784 dnl -------------------------
 785 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 786         linux/version.h asm/types.h \
 787         sys/cdefs.h])
 788
 789 ac_stdatomic_ok=false
 790 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 791 AC_CHECK_HEADER([stdatomic.h],[
 792
 793   AC_MSG_CHECKING([whether _Atomic qualifier works])
 794   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 795 #include <stdatomic.h>
 796 int main(int argc, char **argv) {
 797   _Atomic int i = 0;
 798   return i;
 799 }
 800 ]])], [
 801     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 802     AC_MSG_RESULT([yes])
 803     ac_stdatomic_ok=true
 804   ], [
 805     AC_MSG_RESULT([no])
 806   ])
 807 ])
 808
 809 AS_IF([$ac_stdatomic_ok], [true], [
 810   AC_MSG_CHECKING([for __atomic_* builtins])
 811   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 812 int main(int argc, char **argv) {
 813   volatile int i = 1;
 814   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 815   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 816 }
 817 ]])], [
 818     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 819     AC_MSG_RESULT([yes])
 820   ], [
 821     AC_MSG_RESULT([no])
 822
 823     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 824     AC_MSG_CHECKING([for __sync_* builtins])
 825     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 826 int main(int argc, char **argv) {
 827   volatile int i = 1;
 828   __sync_fetch_and_sub (&i, 1);
 829   return __sync_val_compare_and_swap (&i, 0, 1);
 830 }
 831 ]])], [
 832       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 833       AC_MSG_RESULT([yes])
 834
 835       AC_MSG_CHECKING([for __sync_swap builtin])
 836       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 837 int main(int argc, char **argv) {
 838   volatile int i = 1;
 839   return __sync_swap (&i, 2);
 840 }
 841 ]])], [
 842         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 843         AC_MSG_RESULT([yes])
 844       ], [
 845         AC_MSG_RESULT([no])
 846       ])
 847
 848     ], [
 849       AC_MSG_RESULT([no])
 850       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 851     ])
 852   ])
 853 ])
 854
 855 AC_CHECK_HEADERS([pthread_np.h],,, [
 856 #include <pthread.h>
 857 ])
 858 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 859
 860 dnl Utility macro to avoid retyping includes all the time
 861 m4_define([FRR_INCLUDES],
 862 [#ifdef SUNOS_5
 863 #define _POSIX_C_SOURCE 200809L
 864 #define __EXTENSIONS__
 865 #endif
 866 #include <stdio.h>
 867 #include <stdlib.h>
 868 #include <stddef.h>
 869 #include <sys/types.h>
 870 /* sys/conf.h depends on param.h on FBSD at least */
 871 #include <sys/param.h>
 872 /* Required for MAXSIG */
 873 #include <signal.h>
 874 #include <sys/socket.h>
 875 #ifdef __APPLE__
 876 # define __APPLE_USE_RFC_3542
 877 #endif
 878 #include <netinet/in.h>
 879 #include <sys/time.h>
 880 #include <time.h>
 881 #include <net/if.h>
 882 ])dnl
 883
 884 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 885 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 886 dnl an additional round for it.
 887
 888 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 889
 890 m4_define([FRR_INCLUDES],
 891 FRR_INCLUDES
 892 [#if HAVE_NET_IF_VAR_H
 893 # include <net/if_var.h>
 894 #endif
 895 ])dnl
 896
 897 AC_CHECK_HEADERS([netinet/in_var.h \
 898         net/if_dl.h net/netopt.h \
 899         inet/nd.h netinet/ip_icmp.h \
 900         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 901         [], [], FRR_INCLUDES)
 902
 903 AC_CHECK_HEADERS([ucontext.h], [], [],
 904 [#ifndef __USE_GNU
 905 #define __USE_GNU
 906 #endif /* __USE_GNU */
 907 FRR_INCLUDES
 908 ])
 909
 910 m4_define([UCONTEXT_INCLUDES],
 911 [#include <ucontext.h>])dnl
 912
 913 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 914   [], [], [UCONTEXT_INCLUDES])
 915 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 916   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 917    [], [], [UCONTEXT_INCLUDES])],
 918   [], [UCONTEXT_INCLUDES])
 919 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 920   [], [], [UCONTEXT_INCLUDES])
 921
 922 m4_define([FRR_INCLUDES],
 923 FRR_INCLUDES
 924 [
 925 #include <sys/un.h>
 926 #include <netinet/in_systm.h>
 927 #if HAVE_NETINET_IN_VAR_H
 928 # include <netinet/in_var.h>
 929 #endif
 930 #if HAVE_NET_IF_DL_H
 931 # include <net/if_dl.h>
 932 #endif
 933 #if HAVE_NET_NETOPT_H
 934 # include <net/netopt.h>
 935 #endif
 936 #include <net/route.h>
 937 #if HAVE_INET_ND_H
 938 # include <inet/nd.h>
 939 #endif
 940 #include <arpa/inet.h>
 941 /* Required for IDRP */
 942 #if HAVE_NETINET_IP_ICMP_H
 943 # include <netinet/ip_icmp.h>
 944 #endif
 945 ])dnl
 946
 947 dnl V6 headers are checked below, after we check for v6
 948
 949 AC_MSG_CHECKING([which operating system interface to use])
 950 case "$host_os" in
 951   sunos* | solaris2*)
 952     AC_MSG_RESULT([Solaris])
 953
 954     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 955     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 956     AC_DEFINE(_POSIX_C_SOURCE, 200809L, [enable POSIX.1-2008 and XPG7/SUSv4])
 957
 958     AC_CHECK_LIB(socket, main)
 959     AC_CHECK_LIB(nsl, main)
 960     AC_CHECK_LIB(umem, main)
 961     CURSES=-lcurses
 962     SOLARIS="solaris"
 963     ;;
 964   linux*)
 965     AC_MSG_RESULT([Linux])
 966
 967     AC_DEFINE(GNU_LINUX,,GNU Linux)
 968     AC_DEFINE(HAVE_NETLINK,,netlink)
 969     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 970
 971     dnl Linux has a compilation problem with mixing
 972     dnl netinet/in.h and linux/in6.h they are not
 973     dnl compatible.  There has been discussion on
 974     dnl how to fix it but no real progress on implementation
 975     dnl when they fix it, remove this
 976     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 977     ;;
 978   openbsd*)
 979     AC_MSG_RESULT([OpenBSD])
 980
 981     AC_DEFINE(OPEN_BSD,,OpenBSD)
 982     AC_DEFINE(KAME,1,KAME IPv6)
 983     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 984
 985     if test "x${enable_pimd}" != "xno"; then
 986       case "$host_os" in
 987       openbsd6.0)
 988         ;;
 989       openbsd[6-9]*)
 990         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 991         ;;
 992       esac
 993     fi
 994     ;;
 995   *)
 996     AC_MSG_RESULT([BSD])
 997
 998     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 999     AC_DEFINE(KAME,1,KAME IPv6)
1000     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
1001     ;;
1002 esac
1003 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
1004
1005 AC_SYS_LARGEFILE
1006
1007 dnl ------------------------
1008 dnl Integrated REALMS option
1009 dnl ------------------------
1010 if test "${enable_realms}" = "yes"; then
1011     case "$host_os" in
1012       linux*)
1013        AC_DEFINE(SUPPORT_REALMS,, Realms support)
1014        ;;
1015       *)
1016        echo "Sorry, only Linux has REALMS support"
1017        exit 1
1018        ;;
1019     esac
1020 fi
1021 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1022
1023 dnl ---------------------
1024 dnl Integrated VTY option
1025 dnl ---------------------
1026 case "${enable_vtysh}" in
1027   "no") VTYSH="";;
1028   *)    VTYSH="vtysh";
1029          AC_DEFINE(VTYSH,,VTY shell)
1030 dnl      Vtysh uses libreadline, which looks for termcap functions at
1031 dnl      configure time.  We follow readlines search order.
1032 dnl      The required procedures are in libtermcap on NetBSD, in
1033 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1034          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1035            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1036              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1037                [AC_CHECK_LIB(ncurses, tputs,
1038                              LIBREADLINE="$LIBREADLINE -lncurses")]
1039               )]
1040             )]
1041           )
1042          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1043                       "$LIBREADLINE")
1044          if test $ac_cv_lib_readline_main = no; then
1045            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1046          fi
1047          AC_CHECK_HEADER(readline/history.h)
1048          if test $ac_cv_header_readline_history_h = no;then
1049            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1050          fi
1051          AC_CHECK_LIB(readline, rl_completion_matches,
1052                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1053          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1054            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1055          fi
1056          AC_SEARCH_LIBS([append_history], [readline], [frr_cv_append_history=yes], [frr_cv_append_history=no])
1057          if test "$frr_cv_append_history" = yes; then
1058            AC_DEFINE(HAVE_APPEND_HISTORY, 1, [Have history.h append_history])
1059          fi
1060          ;;
1061 esac
1062 AC_SUBST(LIBREADLINE)
1063 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1064
1065 dnl ----------
1066 dnl PAM module
1067 dnl
1068 dnl FRR detects the PAM library it is built against by checking for a
1069 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1070 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1071 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1072 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1073 dnl of OpenPAM.
1074 dnl ----------
1075 if test "$with_libpam" = "yes"; then
1076   AC_CHECK_HEADER([security/pam_misc.h],
1077     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1078      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1079      pam_conv_func="misc_conv"
1080     ],
1081     [], FRR_INCLUDES)
1082   AC_CHECK_HEADER([security/openpam.h],
1083     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1084      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1085      pam_conv_func="openpam_ttyconv"
1086     ],
1087     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1088   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1089     AC_MSG_WARN([*** pam support will not be built ***])
1090     with_libpam="no"
1091   fi
1092 fi
1093
1094 if test "$with_libpam" = "yes"; then
1095 dnl took this test from proftpds configure.in and suited to our needs
1096 dnl -------------------------------------------------------------------------
1097 dnl
1098 dnl This next check looks funky due to a linker problem with some versions
1099 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1100 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1101 dnl with RedHat 6.2 and Debian 2.2 or better.
1102 AC_CHECK_LIB(pam, pam_start,
1103   [AC_CHECK_LIB(pam, $pam_conv_func,
1104     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1105      LIBPAM="-lpam"],
1106     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1107      LIBPAM="-lpam -lpam_misc"]
1108     )
1109   ],
1110
1111   [AC_CHECK_LIB(pam, pam_end,
1112     [AC_CHECK_LIB(pam, $pam_conv_func,
1113       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1114        LIBPAM="-lpam -ldl"],
1115       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1116        LIBPAM="-lpam -ldl -lpam_misc"]
1117      )
1118   ],AC_MSG_WARN([*** pam support will not be built ***]),
1119   [-ldl])
1120   ]
1121 )
1122 fi
1123 AC_SUBST(LIBPAM)
1124
1125 dnl -------------------------------
1126 dnl Endian-ness check
1127 dnl -------------------------------
1128 AC_WORDS_BIGENDIAN
1129
1130 dnl -------------------------------
1131 dnl check the size in byte of the C
1132 dnl -------------------------------
1133 dnl AC_CHECK_SIZEOF(char)
1134 dnl AC_CHECK_SIZEOF(int)
1135 dnl AC_CHECK_SIZEOF(short)
1136 dnl AC_CHECK_SIZEOF(long)
1137
1138 dnl ----------------------------
1139 dnl check existance of functions
1140 dnl ----------------------------
1141 AC_FUNC_FNMATCH
1142 AC_FUNC_FORK
1143 AC_FUNC_MKTIME
1144 AC_FUNC_STAT
1145
1146 dnl -------------------------------
1147 dnl bgpd needs pow() and hence libm
1148 dnl -------------------------------
1149 TMPLIBS="$LIBS"
1150 AC_CHECK_HEADER([math.h],
1151   [AC_CHECK_LIB([m], [pow],
1152     [LIBM="-lm"
1153      LIBS="$LIBS $LIBM"
1154      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1155     ])
1156 ])
1157 if test x"$LIBM" = x ; then
1158   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1159 fi
1160 LIBS="$TMPLIBS"
1161
1162 AC_SUBST(LIBM)
1163
1164 AC_CHECK_FUNCS([ppoll], [
1165   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1166 ])
1167 AC_CHECK_FUNCS([pollts], [
1168   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1169 ])
1170
1171 dnl ---------------
1172 dnl other functions
1173 dnl ---------------
1174 AC_CHECK_FUNCS([ \
1175         strlcat strlcpy \
1176         getgrouplist])
1177
1178 AC_CHECK_HEADER([asm-generic/unistd.h],
1179                 [AC_CHECK_DECL(__NR_setns,
1180                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1181                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1182                                ])
1183                  AC_CHECK_FUNCS(setns)]
1184                )
1185
1186 dnl --------------------------
1187 dnl Determine IS-IS I/O method
1188 dnl --------------------------
1189 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1190 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1191 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1192 AC_CHECK_HEADER(net/bpf.h)
1193 AC_CHECK_HEADER(sys/dlpi.h)
1194 AC_MSG_CHECKING(zebra IS-IS I/O method)
1195
1196 case "$host_os" in
1197   linux*)
1198     AC_MSG_RESULT(pfpacket)
1199     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1200     ;;
1201   solaris* | sunos*)
1202     AC_MSG_RESULT(DLPI)
1203     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1204     ;;
1205   *)
1206     if test $ac_cv_header_net_bpf_h = no; then
1207       if test $ac_cv_header_sys_dlpi_h = no; then
1208         AC_MSG_RESULT(none)
1209         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1210           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1211         fi
1212         AC_MSG_WARN([*** IS-IS support will not be built ***])
1213         enable_isisd="no"
1214         enable_fabricd="no"
1215       else
1216         AC_MSG_RESULT(DLPI)
1217       fi
1218       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1219     else
1220       AC_MSG_RESULT(BPF)
1221       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1222     fi
1223     ;;
1224 esac
1225 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1226
1227 dnl ---------------------------------------------------------------
1228 dnl figure out how to specify an interface in multicast sockets API
1229 dnl ---------------------------------------------------------------
1230 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1231
1232 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1233         #include <sys/socket.h>
1234         #include <netinet/in.h>
1235         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1236         #include <linux/types.h>
1237 ])
1238
1239 m4_define([FRR_INCLUDES],
1240 FRR_INCLUDES
1241 [#if HAVE_LINUX_MROUTE_H
1242 # include <linux/mroute.h>
1243 #endif
1244 ])dnl
1245
1246 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1247         #include <sys/socket.h>
1248         #include <sys/types.h>
1249         #include <netinet/in.h>
1250         #include <net/route.h>
1251 ])
1252
1253 m4_define([FRR_INCLUDES],
1254 FRR_INCLUDES
1255 [#if HAVE_NETINET_IP_MROUTE_H
1256 # include <netinet/ip_mroute.h>
1257 #endif
1258 ])dnl
1259
1260 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1261 AC_TRY_COMPILE([#include <sys/param.h>],
1262 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1263   return (0);
1264 #else
1265   #error No support for BSD struct ip_mreq hack detected
1266 #endif],[AC_MSG_RESULT(yes)
1267 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1268 AC_MSG_RESULT(no))
1269
1270 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1271 AC_TRY_COMPILE([
1272 #include <sys/types.h>
1273 #include <netinet/in.h>
1274 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1275 ], [AC_MSG_RESULT(yes)
1276 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1277 AC_MSG_RESULT(no))
1278
1279 dnl ---------------------------------------------------------------
1280 dnl figure out how to check link-state
1281 dnl ---------------------------------------------------------------
1282 AC_CHECK_HEADER( [net/if_media.h],
1283   [m4_define([LINK_DETECT_INCLUDES],
1284     FRR_INCLUDES
1285     [#include <net/if_media.h>
1286   ])
1287   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1288     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1289     [], LINK_DETECT_INCLUDES)],
1290   [],
1291   FRR_INCLUDES)
1292
1293 dnl ---------------------------------------------------------------
1294 dnl Additional, newer way to check link-state using ifi_link_state.
1295 dnl Not available in all BSD's when ifmediareq available
1296 dnl ---------------------------------------------------------------
1297 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1298   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1299   [], FRR_INCLUDES)
1300
1301 dnl ------------------------
1302 dnl TCP_MD5SIG socket option
1303 dnl ------------------------
1304
1305 AC_CHECK_HEADER([netinet/tcp.h],
1306    [m4_define([MD5_INCLUDES],
1307       FRR_INCLUDES
1308       [#include <netinet/tcp.h>
1309     ])
1310     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1311    [],
1312    FRR_INCLUDES)
1313 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1314   AC_CHECK_HEADER([linux/tcp.h],
1315        [m4_define([MD5_INCLUDES],
1316           FRR_INCLUDES
1317           [#include <linux/tcp.h>
1318         ])
1319        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1320 fi
1321
1322 dnl ----------------------------------------------------------------------------
1323 dnl figure out if domainname is available in the utsname struct (GNU extension).
1324 dnl ----------------------------------------------------------------------------
1325 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1326
1327 dnl ------------------
1328 dnl IPv6 header checks
1329 dnl ------------------
1330 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1331         netinet6/in6_var.h netinet6/nd6.h], [], [],
1332         FRR_INCLUDES)
1333
1334 m4_define([FRR_INCLUDES],dnl
1335 FRR_INCLUDES
1336 [#if HAVE_NETINET6_IN6_H
1337 #include <netinet6/in6.h>
1338 #endif
1339 #if HAVE_NETINET_IN6_VAR_H
1340 #include <netinet/in6_var.h>
1341 #endif
1342 #include <netinet/icmp6.h>
1343 #if HAVE_NETINET6_IN6_VAR_H
1344 # include <netinet6/in6_var.h>
1345 #endif
1346 #if HAVE_NETINET6_ND6_H
1347 # include <netinet6/nd6.h>
1348 #endif
1349 ])dnl
1350
1351 dnl disable doc check
1352 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1353 if test "$SPHINXBUILD" = "/bin/false"; then
1354   if test "${enable_doc}" = "yes"; then
1355     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1356   fi
1357 fi
1358 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false")
1359 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1360
1361 dnl --------------------
1362 dnl Daemon disable check
1363 dnl --------------------
1364 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1365
1366 if test "${enable_bgpd}" = "no";then
1367   BGPD=""
1368 else
1369   BGPD="bgpd"
1370 fi
1371 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1372
1373 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1374 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1375 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1376
1377 AS_IF([test "${enable_ldpd}" != "no"], [
1378   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1379 ])
1380
1381 if test "$enable_bfdd" = "no"; then
1382   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1383   BFDD=""
1384 else
1385   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1386   BFDD="bfdd"
1387
1388   case $host_os in
1389     linux*)
1390       AC_DEFINE(BFD_LINUX, 1, bfdd)
1391       ;;
1392
1393     *)
1394       AC_DEFINE(BFD_BSD, 1, bfdd)
1395       ;;
1396   esac
1397 fi
1398
1399 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1400
1401 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1402   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1403 fi
1404
1405 NHRPD=""
1406 case "$host_os" in
1407   linux*)
1408     if test "${enable_nhrpd}" != "no"; then
1409       NHRPD="nhrpd"
1410     fi
1411     ;;
1412   *)
1413     if test "${enable_nhrpd}" = "yes"; then
1414       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1415     fi
1416     ;;
1417 esac
1418 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1419
1420 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1421
1422 if test "${enable_watchfrr}" = "no";then
1423   WATCHFRR=""
1424 else
1425   WATCHFRR="watchfrr"
1426 fi
1427 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1428
1429 OSPFCLIENT=""
1430 if test "${enable_ospfapi}" != "no";then
1431     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1432
1433   if test "${enable_ospfclient}" != "no";then
1434       OSPFCLIENT="ospfclient"
1435   fi
1436 fi
1437
1438 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1439 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1440 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1441 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1442 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1443 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1444 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1445 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1446 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1447 AM_CONDITIONAL(FABRICD, test "${enable_fabricd}" != "no")
1448
1449 if test "${enable_bgp_announce}" = "no";then
1450   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1451 else
1452   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1453 fi
1454
1455 if test "${enable_bgp_vnc}" != "no";then
1456   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1457 fi
1458 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1459
1460 AC_SUBST(SOLARIS)
1461 AC_SUBST(CURSES)
1462 AC_CHECK_LIB(crypt, crypt, [],
1463                     [AC_CHECK_LIB(crypto, DES_crypt)])
1464 AC_CHECK_LIB(resolv, res_init)
1465
1466 dnl ---------------------------
1467 dnl check system has PCRE regexp
1468 dnl ---------------------------
1469 if test "x$enable_pcreposix" = "xyes"; then
1470   AC_CHECK_LIB(pcreposix, regexec, [], [
1471     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1472   ])
1473 fi
1474 AC_SUBST(HAVE_LIBPCREPOSIX)
1475
1476 dnl ------------------
1477 dnl check C-Ares library
1478 dnl ------------------
1479 if test "${NHRPD}" != ""; then
1480   PKG_CHECK_MODULES([CARES], [libcares], , [
1481     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1482   ])
1483 fi
1484
1485
1486 dnl ------------------
1487 dnl check Net-SNMP library
1488 dnl ------------------
1489 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1490    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1491    if test x"$NETSNMP_CONFIG" = x"no"; then
1492       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1493    fi
1494    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1495    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1496    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1497    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1498 int main(void);
1499 ],
1500 [
1501 {
1502   return 0;
1503 }
1504 ])], [
1505      AC_MSG_ERROR([--enable-snmp given but not usable])])
1506    case "${enable_snmp}" in
1507      yes)
1508       SNMP_METHOD=agentx
1509       ;;
1510      agentx)
1511       SNMP_METHOD="${enable_snmp}"
1512       ;;
1513      *)
1514       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1515       ;;
1516    esac
1517    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1518    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1519 fi
1520 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1521 AC_SUBST(SNMP_LIBS)
1522 AC_SUBST(SNMP_CFLAGS)
1523
1524 dnl ---------------
1525 dnl math
1526 dnl ---------------
1527 AC_SEARCH_LIBS([sqrt], [m])
1528
1529 dnl ---------------
1530 dnl dlopen & dlinfo
1531 dnl ---------------
1532 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1533   AC_MSG_ERROR([unable to find the dlopen()])
1534 ])
1535
1536 AC_CHECK_HEADERS([link.h])
1537
1538 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1539   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1540 #include <stdlib.h>
1541 #ifdef HAVE_LINK_H
1542 #include <link.h>
1543 #endif
1544 #include <dlfcn.h>
1545 ]], [[
1546   char origin[1];
1547   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1548 ]])], [
1549     frr_cv_rtld_di_origin=yes
1550   ], [
1551     frr_cv_rtld_di_origin=no
1552   ])
1553 ])
1554 if test "$frr_cv_rtld_di_origin" = yes; then
1555   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1556 fi
1557
1558 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1559   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1560 #include <stdlib.h>
1561 #ifdef HAVE_LINK_H
1562 #include <link.h>
1563 #endif
1564 #include <dlfcn.h>
1565 ]], [[
1566   struct link_map *lm = NULL;
1567   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1568 ]])], [
1569     frr_cv_rtld_di_linkmap=yes
1570   ], [
1571     frr_cv_rtld_di_linkmap=no
1572   ])
1573 ])
1574 if test "$frr_cv_rtld_di_linkmap" = yes; then
1575   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1576 fi
1577
1578 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1579
1580 dnl ---------------------------
1581 dnl sockaddr and netinet checks
1582 dnl ---------------------------
1583 AC_CHECK_TYPES([
1584         struct sockaddr_dl,
1585         struct vifctl, struct mfcctl, struct sioc_sg_req,
1586         vifi_t, struct sioc_vif_req, struct igmpmsg,
1587         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1588         struct nd_opt_adv_interval, struct rt_addrinfo,
1589         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1590         [], [], FRR_INCLUDES)
1591
1592 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1593         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1594         struct sockaddr_dl.sdl_len,
1595         struct if6_aliasreq.ifra_lifetime,
1596         struct nd_opt_adv_interval.nd_opt_ai_type],
1597         [], [], FRR_INCLUDES)
1598
1599 dnl ---------------------------
1600 dnl IRDP/pktinfo/icmphdr checks
1601 dnl ---------------------------
1602
1603 AC_CHECK_TYPES([struct in_pktinfo], [
1604   AC_CHECK_TYPES([struct icmphdr], [
1605     IRDP=true
1606   ], [
1607     IRDP=false
1608   ], [FRR_INCLUDES])
1609 ], [
1610   IRDP=false
1611 ], [FRR_INCLUDES])
1612
1613 case "${enable_irdp}" in
1614 yes)
1615   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1616   ;;
1617 no)
1618   IRDP=false
1619   ;;
1620 esac
1621
1622 AM_CONDITIONAL(IRDP, $IRDP)
1623
1624 dnl -----------------------
1625 dnl checking for IP_PKTINFO
1626 dnl -----------------------
1627 AC_MSG_CHECKING(for IP_PKTINFO)
1628 AC_TRY_COMPILE([#include <netdb.h>], [
1629   int opt = IP_PKTINFO;
1630 ], [
1631   AC_MSG_RESULT(yes)
1632   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1633 ], [
1634   AC_MSG_RESULT(no)
1635 ])
1636
1637 dnl ---------------------------
1638 dnl checking for IP_RECVDSTADDR
1639 dnl ---------------------------
1640 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1641 AC_TRY_COMPILE([#include <netinet/in.h>], [
1642   int opt = IP_RECVDSTADDR;
1643 ], [
1644   AC_MSG_RESULT(yes)
1645   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1646 ], [
1647   AC_MSG_RESULT(no)
1648 ])
1649
1650 dnl ----------------------
1651 dnl checking for IP_RECVIF
1652 dnl ----------------------
1653 AC_MSG_CHECKING(for IP_RECVIF)
1654 AC_TRY_COMPILE([#include <netinet/in.h>], [
1655   int opt = IP_RECVIF;
1656 ], [
1657   AC_MSG_RESULT(yes)
1658   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1659 ], [
1660   AC_MSG_RESULT(no)
1661 ])
1662
1663 dnl ----------------------
1664 dnl checking for SO_BINDANY
1665 dnl ----------------------
1666 AC_MSG_CHECKING(for SO_BINDANY)
1667 AC_TRY_COMPILE([#include <sys/socket.h>], [
1668   int opt = SO_BINDANY;
1669 ], [
1670   AC_MSG_RESULT(yes)
1671   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1672 ], [
1673   AC_MSG_RESULT(no)
1674 ])
1675
1676 dnl ----------------------
1677 dnl checking for IP_FREEBIND
1678 dnl ----------------------
1679 AC_MSG_CHECKING(for IP_FREEBIND)
1680 AC_TRY_COMPILE([#include <netinet/in.h>], [
1681   int opt = IP_FREEBIND;
1682 ], [
1683   AC_MSG_RESULT(yes)
1684   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1685 ], [
1686   AC_MSG_RESULT(no)
1687 ])
1688
1689 dnl --------------------------------------
1690 dnl checking for be32dec existence or not
1691 dnl --------------------------------------
1692 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1693                [#include <sys/endian.h>])
1694
1695 dnl --------------------------------------
1696 dnl checking for clock_time monotonic struct and call
1697 dnl --------------------------------------
1698 AC_CHECK_DECL(CLOCK_MONOTONIC,
1699         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1700          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1701 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1702
1703 dnl --------------------------------------
1704 dnl checking for flex and bison
1705 dnl --------------------------------------
1706
1707 AM_PROG_LEX
1708 AC_MSG_CHECKING(version of flex)
1709 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1710 frr_ac_flex_version="${frr_ac_flex_version##* }"
1711 AC_MSG_RESULT([$frr_ac_flex_version])
1712 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1713   LEX="$SHELL $missing_dir/missing flex"
1714   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1715     AC_MSG_WARN([using pregenerated flex output files])
1716   else
1717     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1718   fi
1719   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1720   AC_SUBST([LEXLIB], [''])
1721 ])
1722
1723 AC_PROG_YACC
1724 dnl thanks GNU bison for this b*llshit...
1725 AC_MSG_CHECKING(version of bison)
1726 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1727 frr_ac_bison_version="${frr_ac_bison_version##* }"
1728 frr_ac_bison_missing="false"
1729 case "x${frr_ac_bison_version}" in
1730   x2.7*)
1731     BISON_OPENBRACE='"'
1732     BISON_CLOSEBRACE='"'
1733     BISON_VERBOSE=''
1734     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1735     ;;
1736   x2.*|x1.*)
1737     AC_MSG_RESULT([$frr_ac_bison_version])
1738     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1739     frr_ac_bison_missing="true"
1740     ;;
1741   x)
1742     AC_MSG_RESULT([none])
1743     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1744     frr_ac_bison_missing="true"
1745     ;;
1746   *)
1747     BISON_OPENBRACE='{'
1748     BISON_CLOSEBRACE='}'
1749     BISON_VERBOSE='-Dparse.error=verbose'
1750     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1751     ;;
1752 esac
1753 AC_SUBST(BISON_OPENBRACE)
1754 AC_SUBST(BISON_CLOSEBRACE)
1755 AC_SUBST(BISON_VERBOSE)
1756
1757 if $frr_ac_bison_missing; then
1758   YACC="$SHELL $missing_dir/missing bison -y"
1759   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1760     AC_MSG_WARN([using pregenerated bison output files])
1761   else
1762     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1763   fi
1764 fi
1765
1766 dnl -------------------
1767 dnl capabilities checks
1768 dnl -------------------
1769 if test "${enable_capabilities}" != "no"; then
1770   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1771   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1772     [AC_MSG_RESULT(yes)
1773      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1774      frr_ac_keepcaps="yes"],
1775      AC_MSG_RESULT(no)
1776   )
1777   if test x"${frr_ac_keepcaps}" = x"yes"; then
1778     AC_CHECK_HEADERS(sys/capability.h)
1779   fi
1780   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1781     AC_CHECK_LIB(cap, cap_init,
1782       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1783        LIBCAP="-lcap"
1784        frr_ac_lcaps="yes"]
1785     )
1786   else
1787     AC_CHECK_HEADERS(priv.h,
1788      [AC_MSG_CHECKING(Solaris style privileges are available)
1789       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1790           [AC_MSG_RESULT(yes)
1791            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1792            frr_ac_scaps="yes"],
1793            AC_MSG_RESULT(no)
1794       )
1795      ]
1796    )
1797   fi
1798   if test x"${frr_ac_scaps}" = x"yes" \
1799        -o x"${frr_ac_lcaps}" = x"yes"; then
1800     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1801   fi
1802 fi
1803 AC_SUBST(LIBCAP)
1804
1805 dnl ---------------------------
1806 dnl check for glibc 'backtrace'
1807 dnl ---------------------------
1808 if test x"${enable_backtrace}" != x"no" ; then
1809   backtrace_ok=no
1810   PKG_CHECK_MODULES([UNWIND], [libunwind], [
1811     AC_DEFINE(HAVE_LIBUNWIND, 1, [libunwind])
1812     backtrace_ok=yes
1813   ], [
1814     case "$host_os" in
1815     sunos* | solaris2*)
1816       AC_CHECK_FUNCS([printstack], [
1817         AC_DEFINE([HAVE_PRINTSTACK], 1, [Solaris printstack])
1818         backtrace_ok=yes
1819       ])
1820       ;;
1821     esac
1822     if test "$backtrace_ok" = no; then
1823       AC_CHECK_HEADER([execinfo.h], [
1824         AC_SEARCH_LIBS([backtrace], [execinfo], [
1825           AC_DEFINE(HAVE_GLIBC_BACKTRACE, 1, [Glibc backtrace])
1826           backtrace_ok=yes
1827         ],, [-lm])
1828       ])
1829     fi
1830   ])
1831
1832   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1833     dnl user explicitly requested backtrace but we failed to find support
1834     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
1835   fi
1836 fi
1837
1838 dnl -----------------------------------------
1839 dnl check for malloc mallinfo struct and call
1840 dnl this must try and link using LIBS, in
1841 dnl order to check no alternative allocator
1842 dnl has been specified, which might not provide
1843 dnl mallinfo, e.g. such as Umem on Solaris.
1844 dnl -----------------------------------------
1845 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
1846
1847 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1848   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1849 #ifdef HAVE_MALLOC_H
1850 #include <malloc.h>
1851 #endif
1852 #ifdef HAVE_MALLOC_NP_H
1853 #include <malloc_np.h>
1854 #endif
1855 #ifdef HAVE_MALLOC_MALLOC_H
1856 #include <malloc/malloc.h>
1857 #endif
1858 ]], [[
1859 struct mallinfo ac_x; ac_x = mallinfo ();
1860 ]])], [
1861     frr_cv_mallinfo=yes
1862   ], [
1863     frr_cv_mallinfo=no
1864   ])
1865 ])
1866 if test "$frr_cv_mallinfo" = yes; then
1867   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1868 fi
1869
1870 AC_MSG_CHECKING(whether malloc_usable_size is available)
1871 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1872 #ifdef HAVE_MALLOC_H
1873 #include <malloc.h>
1874 #endif
1875 #ifdef HAVE_MALLOC_MALLOC_H
1876 #include <malloc/malloc.h>
1877 #endif
1878 ]], [[
1879 size_t ac_x; ac_x = malloc_usable_size(NULL);
1880 ]])], [
1881   AC_MSG_RESULT(yes)
1882   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1883 ], [
1884   AC_MSG_RESULT(no)
1885
1886   AC_MSG_CHECKING(whether malloc_size is available)
1887   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1888 #ifdef HAVE_MALLOC_H
1889 #include <malloc.h>
1890 #endif
1891 #ifdef HAVE_MALLOC_MALLOC_H
1892 #include <malloc/malloc.h>
1893 #endif
1894 ]], [[
1895 size_t ac_x; ac_x = malloc_size(NULL);
1896 ]])], [
1897     AC_MSG_RESULT(yes)
1898     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1899   ], [
1900     AC_MSG_RESULT(no)
1901   ])
1902 ])
1903
1904 dnl ------
1905 dnl ZeroMQ
1906 dnl ------
1907 if test "x$enable_zeromq" != "xno"; then
1908   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1909     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1910     ZEROMQ=true
1911   ], [
1912     if test "x$enable_zeromq" = "xyes"; then
1913       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1914     fi
1915   ])
1916 fi
1917 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1918
1919 dnl ----------
1920 dnl configure date
1921 dnl ----------
1922 dev_version=`echo $VERSION | grep dev`
1923 #don't expire deprecated code in non 'dev' branch
1924 if test "${dev_version}" = ""; then
1925    CONFDATE=0
1926 else
1927    CONFDATE=`date '+%Y%m%d'`
1928 fi
1929 AC_SUBST(CONFDATE)
1930
1931 dnl ------------------------------
1932 dnl set paths for state directory
1933 dnl ------------------------------
1934 AC_MSG_CHECKING(directory to use for state file)
1935 if test "${prefix}" = "NONE"; then
1936   frr_statedir_prefix="";
1937 else
1938   frr_statedir_prefix=${prefix}
1939 fi
1940 if test "${localstatedir}" = '${prefix}/var'; then
1941   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1942                         ${frr_statedir_prefix}/var/adm dnl
1943                         ${frr_statedir_prefix}/etc dnl
1944                         /var/run        dnl
1945                         /var/adm        dnl
1946                         /etc            dnl
1947                         /dev/null;
1948   do
1949     test -d $FRR_STATE_DIR && break
1950   done
1951   frr_statedir=$FRR_STATE_DIR
1952 else
1953   frr_statedir=${localstatedir}
1954 fi
1955 if test $frr_statedir = "/dev/null"; then
1956     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1957 fi
1958 AC_MSG_RESULT(${frr_statedir})
1959 AC_SUBST(frr_statedir)
1960
1961 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1962 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1963 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1964 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1965
1966 dnl autoconf does this, but it does it too late...
1967 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1968 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1969
1970 dnl get the full path, recursing through variables...
1971 vtysh_bin="$bindir/vtysh"
1972 for I in 1 2 3 4 5 6 7 8 9 10; do
1973         eval vtysh_bin="\"$vtysh_bin\""
1974 done
1975 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1976 AC_SUBST(vtysh_bin)
1977
1978 CFG_SYSCONF="$sysconfdir"
1979 CFG_SBIN="$sbindir"
1980 CFG_STATE="$frr_statedir"
1981 CFG_MODULE="$moduledir"
1982 for I in 1 2 3 4 5 6 7 8 9 10; do
1983         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1984         eval CFG_SBIN="\"$CFG_SBIN\""
1985         eval CFG_STATE="\"$CFG_STATE\""
1986         eval CFG_MODULE="\"$CFG_MODULE\""
1987 done
1988 AC_SUBST(CFG_SYSCONF)
1989 AC_SUBST(CFG_SBIN)
1990 AC_SUBST(CFG_STATE)
1991 AC_SUBST(CFG_MODULE)
1992 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1993
1994 dnl ------------------------------------
1995 dnl Enable RPKI and add librtr to libs
1996 dnl ------------------------------------
1997 if test "${enable_rpki}" = "yes"; then
1998   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1999       [RPKI=true],
2000       [RPKI=false
2001       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2002   )
2003 fi
2004 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
2005
2006 dnl ------------------------------------------
2007 dnl Check whether rtrlib was build with ssh support
2008 dnl ------------------------------------------
2009 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2010 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2011                         [[struct tr_ssh_config config;]])],
2012         [AC_MSG_RESULT(yes)
2013         AC_DEFINE(FOUND_SSH,,found_ssh)],
2014         AC_MSG_RESULT(no)
2015 )
2016
2017 dnl ---------------------------
2018 dnl Check htonl works correctly
2019 dnl ---------------------------
2020 AC_MSG_CHECKING(for working htonl)
2021 AC_CACHE_VAL(ac_cv_htonl_works,
2022  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2023                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2024  ]
2025 )
2026 AC_MSG_RESULT($ac_cv_htonl_works)
2027
2028 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2029
2030 AC_CONFIG_FILES([
2031           redhat/frr.spec
2032           solaris/Makefile
2033           debianpkg/changelog
2034           alpine/APKBUILD
2035           snapcraft/snapcraft.yaml
2036           lib/version.h
2037           tests/lib/cli/test_cli.refout
2038           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2039           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2040           pkgsrc/eigrpd.sh])
2041
2042 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2043 AC_CONFIG_FILES([tools/frr],[chmod +x tools/frr])
2044
2045 AC_CONFIG_COMMANDS([lib/route_types.h], [
2046         dst="${ac_abs_top_builddir}/lib/route_types.h"
2047         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2048                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2049                 > "${dst}.tmp"
2050         test -f "${dst}" \
2051                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2052                 && rm "${dst}.tmp" \
2053                 || mv "${dst}.tmp" "${dst}"
2054 ], [
2055         PERL="$PERL"
2056 ])
2057
2058 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2059     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2060         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2061         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2062                 "${ac_abs_top_srcdir}" \
2063                 > "${dst}.tmp"
2064         test -f "${dst}" \
2065                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2066                 && rm "${dst}.tmp" \
2067                 || mv "${dst}.tmp" "${dst}"
2068     ], [
2069         PERL="$PERL"
2070     ])
2071 ])
2072
2073 ## Hack, but working solution to avoid rebuilding of frr.info.
2074 ## It's already in CVS until texinfo 4.7 is more common.
2075 AC_OUTPUT
2076
2077 echo "
2078 FRRouting configuration
2079 ------------------------------
2080 FRR version             : ${PACKAGE_VERSION}
2081 host operating system   : ${host_os}
2082 source code location    : ${srcdir}
2083 compiler                : ${CC}
2084 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2085 make                    : ${MAKE-make}
2086 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2087 state file directory    : ${frr_statedir}
2088 config file directory   : `eval echo \`echo ${sysconfdir}\``
2089 example directory       : `eval echo \`echo ${exampledir}\``
2090 module directory        : ${CFG_MODULE}
2091 user to run as          : ${enable_user}
2092 group to run as         : ${enable_group}
2093 group for vty sockets   : ${enable_vty_group}
2094 config file mask        : ${enable_configfile_mask}
2095 log file mask           : ${enable_logfile_mask}
2096 zebra protobuf enabled  : ${enable_protobuf:-no}
2097
2098 The above user and group must have read/write access to the state file
2099 directory and to the config files in the config file directory."
2100
2101 if test "${enable_doc}" != "no";then
2102   AS_IF([test "$SPHINXBUILD" = /bin/false],
2103      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2104 fi