configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.0, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl if the user has specified any CFLAGS, override our settings
 193 if test "x${enable_gcov}" = "xyes"; then
 194    if test "z$orig_cflags" = "z"; then
 195       AC_C_FLAG([-coverage])
 196       AC_C_FLAG([-O0])
 197    fi
 198
 199    LDFLAGS="${LDFLAGS} -lgcov"
 200 elif test "x${enable_dev_build}" = "xyes"; then
 201    AC_DEFINE(DEV_BUILD,,Build for development)
 202    if test "z$orig_cflags" = "z"; then
 203       AC_C_FLAG([-g3])
 204       AC_C_FLAG([-O0])
 205    fi
 206 else
 207    if test "z$orig_cflags" = "z"; then
 208       AC_C_FLAG([-g])
 209       AC_C_FLAG([-Os], [
 210         AC_C_FLAG([-O2])
 211       ])
 212    fi
 213 fi
 214 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 215
 216 dnl always want these CFLAGS
 217 AC_C_FLAG([-fno-omit-frame-pointer])
 218 AC_C_FLAG([-funwind-tables])
 219 AC_C_FLAG([-Wall])
 220 AC_C_FLAG([-Wextra])
 221 AC_C_FLAG([-Wmissing-prototypes])
 222 AC_C_FLAG([-Wmissing-declarations])
 223 AC_C_FLAG([-Wpointer-arith])
 224 AC_C_FLAG([-Wbad-function-cast])
 225 AC_C_FLAG([-Wwrite-strings])
 226 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 227   AC_C_FLAG([-Wcast-qual])
 228   AC_C_FLAG([-Wstrict-prototypes])
 229   AC_C_FLAG([-Wmissing-noreturn])
 230   AC_C_FLAG([-Wmissing-format-attribute])
 231   AC_C_FLAG([-Wunreachable-code])
 232   AC_C_FLAG([-Wpacked])
 233   AC_C_FLAG([-Wpadded])
 234 else
 235   AC_C_FLAG([-Wno-unused-result])
 236 fi
 237 AC_C_FLAG([-Wno-unused-parameter])
 238 AC_C_FLAG([-Wno-missing-field-initializers])
 239
 240 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 241 dnl for some reason the string consts get 'promoted' to char *,
 242 dnl triggering a const to non-const conversion warning.
 243 AC_C_FLAG([-diag-disable 3179])
 244
 245 if test x"${enable_werror}" = x"yes" ; then
 246   WERROR="-Werror"
 247 fi
 248 AC_SUBST(WERROR)
 249
 250 SAN_FLAGS=""
 251 if test "$enable_address_sanitizer" = "yes"; then
 252   AC_C_FLAG([-fsanitize=address], [
 253     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 254   ], [
 255     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 256   ])
 257 fi
 258 if test "$enable_thread_sanitizer" = "yes"; then
 259   AC_C_FLAG([-fsanitize=thread], [
 260     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 261   ], [
 262     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 263   ])
 264 fi
 265 if test "$enable_memory_sanitizer" = "yes"; then
 266   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 267     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 268   ], [
 269     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 270   ])
 271 fi
 272 AC_SUBST([SAN_FLAGS])
 273
 274 dnl ----------
 275 dnl Essentials
 276 dnl ----------
 277
 278 AX_PTHREAD([
 279   CC="$PTHREAD_CC"
 280   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 281   LIBS="$PTHREAD_LIBS $LIBS"
 282 ], [
 283   AC_MSG_FAILURE([This FRR version needs pthreads])
 284 ])
 285
 286 dnl --------------
 287 dnl Check programs
 288 dnl --------------
 289 AC_PROG_INSTALL
 290 AC_PROG_LN_S
 291 AC_PROG_MAKE_SET
 292 AC_CHECK_TOOL(AR, ar)
 293
 294 dnl -----------------
 295 dnl System extensions
 296 dnl -----------------
 297 AC_GNU_SOURCE
 298
 299 dnl -------
 300 dnl libtool
 301 dnl -------
 302 LT_INIT
 303
 304 dnl ----------------------
 305 dnl Packages configuration
 306 dnl ----------------------
 307 AC_ARG_WITH(pkg-extra-version,
 308         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 309         [EXTRAVERSION=$withval],)
 310 AC_ARG_WITH(pkg-git-version,
 311         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 312         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 313 AC_ARG_WITH(vtysh_pager,
 314         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 315         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 316 AC_ARG_ENABLE(vtysh,
 317   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 318 AC_ARG_ENABLE(doc,
 319   AS_HELP_STRING([--disable-doc], [do not build docs]))
 320 AC_ARG_ENABLE(doc-html,
 321   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 322 AC_ARG_ENABLE(zebra,
 323   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 324 AC_ARG_ENABLE(bgpd,
 325   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 326 AC_ARG_ENABLE(ripd,
 327   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 328 AC_ARG_ENABLE(ripngd,
 329   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 330 AC_ARG_ENABLE(ospfd,
 331   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 332 AC_ARG_ENABLE(ospf6d,
 333   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 334 AC_ARG_ENABLE(ldpd,
 335   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 336 AC_ARG_ENABLE(nhrpd,
 337   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 338 AC_ARG_ENABLE(eigrpd,
 339   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 340 AC_ARG_ENABLE(babeld,
 341   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 342 AC_ARG_ENABLE(watchfrr,
 343   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 344 AC_ARG_ENABLE(isisd,
 345   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 346 AC_ARG_ENABLE(pimd,
 347   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 348 AC_ARG_ENABLE(pbrd,
 349   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 350 AC_ARG_ENABLE(sharpd,
 351   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 352 AC_ARG_ENABLE(staticd,
 353   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 354 AC_ARG_ENABLE(bgp-announce,
 355   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 356 AC_ARG_ENABLE(bgp-vnc,
 357   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 358 AC_ARG_ENABLE(snmp,
 359   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 360 AC_ARG_ENABLE(zeromq,
 361   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 362 AC_ARG_WITH(libpam,
 363   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 364 AC_ARG_ENABLE(ospfapi,
 365   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 366 AC_ARG_ENABLE(ospfclient,
 367   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 368                           (this is the default if --disable-ospfapi is set)]))
 369 AC_ARG_ENABLE(multipath,
 370   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 371 AC_ARG_ENABLE(user,
 372   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 373 AC_ARG_ENABLE(group,
 374   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 375 AC_ARG_ENABLE(vty_group,
 376   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 377 AC_ARG_ENABLE(configfile_mask,
 378   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 379 AC_ARG_ENABLE(logfile_mask,
 380   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 381 AC_ARG_ENABLE(shell_access,
 382   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 383 AC_ARG_ENABLE(realms,
 384   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 385 AC_ARG_ENABLE(rtadv,
 386   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 387 AC_ARG_ENABLE(irdp,
 388   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 389 AC_ARG_ENABLE(capabilities,
 390   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 391 AC_ARG_ENABLE(rusage,
 392   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 393 AC_ARG_ENABLE(gcc_ultra_verbose,
 394   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 395 AC_ARG_ENABLE(backtrace,
 396   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 397 AC_ARG_ENABLE(time-check,
 398   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 399 AC_ARG_ENABLE(pcreposix,
 400   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 401 AC_ARG_ENABLE(fpm,
 402   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 403 AC_ARG_ENABLE(systemd,
 404   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 405 AC_ARG_ENABLE(werror,
 406   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 407 AC_ARG_ENABLE(cumulus,
 408   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 409 AC_ARG_ENABLE(datacenter,
 410   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 411 AC_ARG_ENABLE(fuzzing,
 412   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 413 AC_ARG_ENABLE(netlink_fuzzing,
 414   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 415 AC_ARG_ENABLE(rr-semantics,
 416   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 417 AC_ARG_ENABLE([protobuf],
 418   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 419 AC_ARG_ENABLE([oldvpn_commands],
 420   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 421 AC_ARG_ENABLE(rpki,
 422   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 423 AC_ARG_ENABLE([clippy-only],
 424   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 425 AC_ARG_ENABLE([numeric_version],
 426   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 427 AC_ARG_ENABLE([gcov],
 428   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 429 AC_ARG_ENABLE(bfdd,
 430   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 431 AC_ARG_ENABLE([address-sanitizer],
 432   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 433 AC_ARG_ENABLE([thread-sanitizer],
 434   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 435 AC_ARG_ENABLE([memory-sanitizer],
 436   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 437
 438 AS_IF([test "${enable_clippy_only}" != "yes"], [
 439 AC_CHECK_HEADERS(json-c/json.h)
 440 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 441 if test $ac_cv_lib_json_c_json_object_get = no; then
 442   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 443   if test $ac_cv_lib_json_json_object_get = no; then
 444       AC_MSG_ERROR([lib json is needed to compile])
 445   fi
 446 fi
 447 ])
 448
 449 AC_ARG_ENABLE([dev_build],
 450     AS_HELP_STRING([--enable-dev-build], [build for development]))
 451
 452 if test x"${enable_time_check}" != x"no" ; then
 453   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 454     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 455   else
 456     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 457   fi
 458 fi
 459
 460 case "${enable_systemd}" in
 461   "no") ;;
 462   "yes")
 463   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 464   if test $ac_cv_lib_systemd_sd_notify = no; then
 465     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 466   else
 467     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 468   fi
 469   ;;
 470   "*") ;;
 471 esac
 472
 473 if test "${enable_rr_semantics}" != "no" ; then
 474   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 475 fi
 476
 477 if test "${enable_datacenter}" = "yes" ; then
 478   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 479   DFLT_NAME="datacenter"
 480 else
 481   DFLT_NAME="traditional"
 482 fi
 483
 484 if test "${enable_fuzzing}" = "yes" ; then
 485   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 486 fi
 487
 488 if test "${enable_netlink_fuzzing}" = "yes" ; then
 489   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 490 fi
 491
 492 if test "${enable_cumulus}" = "yes" ; then
 493   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 494 fi
 495
 496 AC_SUBST(DFLT_NAME)
 497 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 498
 499 if test "${enable_shell_access}" = "yes"; then
 500    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 501 fi
 502
 503 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 504
 505 #
 506 # Python for clippy
 507 #
 508
 509 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 510   AC_MSG_CHECKING([whether we found a working Python version])
 511   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 512 #include <Python.h>
 513 #if PY_VERSION_HEX < 0x02070000
 514 #error python too old
 515 #endif
 516 int main(void);
 517 ],
 518 [
 519 {
 520   Py_Initialize();
 521   return 0;
 522 }
 523 ])], [
 524     # some python installs are missing the zlib dependency...
 525     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 526     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 527 #include <Python.h>
 528 #if PY_VERSION_HEX < 0x02070000
 529 #error python too old
 530 #endif
 531 int main(void);
 532 ],
 533 [
 534 {
 535   Py_Initialize();
 536   return 0;
 537 }
 538 ])], [
 539       m4_if([$1], [], [
 540         PYTHONCONFIG=""
 541         unset PYTHON_LIBS
 542         unset PYTHON_CFLAGS
 543       ], [$1])
 544     ])
 545   ])
 546 ])
 547
 548 AS_IF([test "$host" = "$build"], [
 549   PYTHONCONFIG=""
 550
 551   # ordering:
 552   # 1.  try python3, but respect the user's preference on which minor ver
 553   # 2.  try python, which might be py3 or py2 again on the user's preference
 554   # 3.  try python2 (can really only be 2.7 but eh)
 555   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 556   #
 557   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 558   # (AX_PYTHON does not do what we need)
 559
 560   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 561         python3-config \
 562         python-config \
 563         python2-config \
 564         python3.6-config \
 565         python3.5-config \
 566         python3.4-config \
 567         python3.3-config \
 568         python3.2-config \
 569         python2.7-config ])
 570   if test -n "$PYTHONCONFIG"; then
 571     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 572     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 573
 574     FRR_PYTHON_CHECK_WORKING([])
 575   fi
 576
 577   if test -z "$PYTHONCONFIG"; then
 578     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 579       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 580         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 581           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 582             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 583               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 584                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 585                 ])])])])])])
 586
 587
 588     FRR_PYTHON_CHECK_WORKING([
 589       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 590     ])
 591   fi
 592 ])
 593 AC_SUBST(PYTHON_CFLAGS)
 594 AC_SUBST(PYTHON_LIBS)
 595
 596 #
 597 # Logic for protobuf support.
 598 #
 599 if test "$enable_protobuf" = "yes"; then
 600   # Check for protoc & protoc-c
 601
 602   # protoc is not required, it's only for a "be nice" helper target
 603   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 604
 605   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 606   if test "$PROTOC_C" = "/bin/false"; then
 607     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 608   fi
 609
 610   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 611     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 612   ])
 613   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 614     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 615   ])
 616
 617   AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 618 fi
 619 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 620
 621 #
 622 # Logic for old vpn commans support.
 623 #
 624 if test "$enable_oldvpn_commands" = "yes"; then
 625    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 626 fi
 627
 628 #
 629 # End of logic for protobuf support.
 630 #
 631
 632 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 633 if test "${enable_rtadv}" != "no"; then
 634   AC_MSG_RESULT(yes)
 635   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 636 else
 637   AC_MSG_RESULT(no)
 638 fi
 639
 640 if test x"${enable_user}" = x"no"; then
 641   enable_user=""
 642 else
 643   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 644     enable_user="frr"
 645   fi
 646   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 647 fi
 648
 649 if test x"${enable_group}" = x"no"; then
 650   enable_group=""
 651 else
 652   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 653     enable_group="frr"
 654   fi
 655   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 656 fi
 657
 658 if test x"${enable_vty_group}" = x"yes" ; then
 659   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 660 elif test x"${enable_vty_group}" != x""; then
 661   if test x"${enable_vty_group}" != x"no"; then
 662     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 663   fi
 664 fi
 665 AC_SUBST([enable_user])
 666 AC_SUBST([enable_group])
 667 AC_SUBST([enable_vty_group])
 668
 669 enable_configfile_mask=${enable_configfile_mask:-0600}
 670 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 671
 672 enable_logfile_mask=${enable_logfile_mask:-0600}
 673 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 674
 675 MPATH_NUM=1
 676
 677 case "${enable_multipath}" in
 678   0)
 679     MPATH_NUM=64
 680     ;;
 681   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 682     MPATH_NUM="${enable_multipath}"
 683     ;;
 684   "")
 685     ;;
 686   *)
 687     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 688     ;;
 689 esac
 690
 691 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 692
 693 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 694
 695 dnl --------------------
 696 dnl Enable code coverage
 697 dnl --------------------
 698 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 699
 700 dnl ------------------------------------
 701 dnl Alpine only accepts numeric versions
 702 dnl ------------------------------------
 703 if test "x${enable_numeric_version}" != "x" ; then
 704   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 705   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 706 fi
 707
 708 dnl -----------------------------------
 709 dnl Add extra version string to package
 710 dnl name, string and version fields.
 711 dnl -----------------------------------
 712 if test "x${EXTRAVERSION}" != "x" ; then
 713   VERSION="${VERSION}${EXTRAVERSION}"
 714   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 715   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 716   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 717 fi
 718
 719 if test "x$with_pkg_git_version" = "xyes"; then
 720         if test -d "${srcdir}/.git"; then
 721                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 722         else    with_pkg_git_version="no"
 723                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 724         fi
 725 fi
 726 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 727
 728 dnl ------------------------------------
 729 dnl Check C keywords and standard  types
 730 dnl ------------------------------------
 731 AC_C_CONST
 732 AC_C_INLINE
 733 AC_C_VOLATILE
 734 AC_HEADER_STDC
 735 dnl AC_TYPE_PID_T
 736 AC_TYPE_UID_T
 737 AC_TYPE_MODE_T
 738 AC_TYPE_SIZE_T
 739 AC_STRUCT_TM
 740
 741 dnl -------------------------
 742 dnl Check other header files.
 743 dnl -------------------------
 744 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 745         linux/version.h asm/types.h \
 746         sys/cdefs.h])
 747
 748 ac_stdatomic_ok=false
 749 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 750 AC_CHECK_HEADER([stdatomic.h],[
 751
 752   AC_MSG_CHECKING([whether _Atomic qualifier works])
 753   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 754 #include <stdatomic.h>
 755 int main(int argc, char **argv) {
 756   _Atomic int i = 0;
 757   return i;
 758 }
 759 ]])], [
 760     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 761     AC_MSG_RESULT([yes])
 762     ac_stdatomic_ok=true
 763   ], [
 764     AC_MSG_RESULT([no])
 765   ])
 766 ])
 767
 768 AS_IF([$ac_stdatomic_ok], [true], [
 769   AC_MSG_CHECKING([for __atomic_* builtins])
 770   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 771 int main(int argc, char **argv) {
 772   volatile int i = 1;
 773   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 774   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 775 }
 776 ]])], [
 777     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 778     AC_MSG_RESULT([yes])
 779   ], [
 780     AC_MSG_RESULT([no])
 781
 782     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 783     AC_MSG_CHECKING([for __sync_* builtins])
 784     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 785 int main(int argc, char **argv) {
 786   volatile int i = 1;
 787   __sync_fetch_and_sub (&i, 1);
 788   return __sync_val_compare_and_swap (&i, 0, 1);
 789 }
 790 ]])], [
 791       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 792       AC_MSG_RESULT([yes])
 793
 794       AC_MSG_CHECKING([for __sync_swap builtin])
 795       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 796 int main(int argc, char **argv) {
 797   volatile int i = 1;
 798   return __sync_swap (&i, 2);
 799 }
 800 ]])], [
 801         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 802         AC_MSG_RESULT([yes])
 803       ], [
 804         AC_MSG_RESULT([no])
 805       ])
 806
 807     ], [
 808       AC_MSG_RESULT([no])
 809       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 810     ])
 811   ])
 812 ])
 813
 814 dnl Utility macro to avoid retyping includes all the time
 815 m4_define([FRR_INCLUDES],
 816 [#ifdef SUNOS_5
 817 #define _XPG4_2
 818 #define __EXTENSIONS__
 819 #endif
 820 #include <stdio.h>
 821 #include <stdlib.h>
 822 #include <stddef.h>
 823 #include <sys/types.h>
 824 /* sys/conf.h depends on param.h on FBSD at least */
 825 #include <sys/param.h>
 826 /* Required for MAXSIG */
 827 #include <signal.h>
 828 #include <sys/socket.h>
 829 #ifdef __APPLE__
 830 # define __APPLE_USE_RFC_3542
 831 #endif
 832 #include <netinet/in.h>
 833 #include <sys/time.h>
 834 #include <time.h>
 835 #include <net/if.h>
 836 ])dnl
 837
 838 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 839 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 840 dnl an additional round for it.
 841
 842 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 843
 844 m4_define([FRR_INCLUDES],
 845 FRR_INCLUDES
 846 [#if HAVE_NET_IF_VAR_H
 847 # include <net/if_var.h>
 848 #endif
 849 ])dnl
 850
 851 AC_CHECK_HEADERS([netinet/in_var.h \
 852         net/if_dl.h net/netopt.h \
 853         inet/nd.h netinet/ip_icmp.h \
 854         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 855         [], [], FRR_INCLUDES)
 856
 857 AC_CHECK_HEADERS([ucontext.h], [], [],
 858 [#ifndef __USE_GNU
 859 #define __USE_GNU
 860 #endif /* __USE_GNU */
 861 FRR_INCLUDES
 862 ])
 863
 864 m4_define([UCONTEXT_INCLUDES],
 865 [#include <ucontext.h>])dnl
 866
 867 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 868   [], [], [UCONTEXT_INCLUDES])
 869 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 870   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 871    [], [], [UCONTEXT_INCLUDES])],
 872   [], [UCONTEXT_INCLUDES])
 873 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 874   [], [], [UCONTEXT_INCLUDES])
 875
 876 m4_define([FRR_INCLUDES],
 877 FRR_INCLUDES
 878 [
 879 #include <sys/un.h>
 880 #include <netinet/in_systm.h>
 881 #if HAVE_NETINET_IN_VAR_H
 882 # include <netinet/in_var.h>
 883 #endif
 884 #if HAVE_NET_IF_DL_H
 885 # include <net/if_dl.h>
 886 #endif
 887 #if HAVE_NET_NETOPT_H
 888 # include <net/netopt.h>
 889 #endif
 890 #include <net/route.h>
 891 #if HAVE_INET_ND_H
 892 # include <inet/nd.h>
 893 #endif
 894 #include <arpa/inet.h>
 895 /* Required for IDRP */
 896 #if HAVE_NETINET_IP_ICMP_H
 897 # include <netinet/ip_icmp.h>
 898 #endif
 899 ])dnl
 900
 901 dnl V6 headers are checked below, after we check for v6
 902
 903 AC_MSG_CHECKING([which operating system interface to use])
 904 case "$host_os" in
 905   sunos* | solaris2*)
 906     AC_MSG_RESULT([Solaris])
 907
 908     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 909     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 910
 911     AC_CHECK_LIB(socket, main)
 912     AC_CHECK_LIB(nsl, main)
 913     AC_CHECK_LIB(umem, main)
 914     AC_CHECK_FUNCS([printstack], [
 915       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 916       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 917     ])
 918     CURSES=-lcurses
 919     SOLARIS="solaris"
 920     ;;
 921   linux*)
 922     AC_MSG_RESULT([Linux])
 923
 924     AC_DEFINE(GNU_LINUX,,GNU Linux)
 925     AC_DEFINE(HAVE_NETLINK,,netlink)
 926     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 927
 928     dnl Linux has a compilation problem with mixing
 929     dnl netinet/in.h and linux/in6.h they are not
 930     dnl compatible.  There has been discussion on
 931     dnl how to fix it but no real progress on implementation
 932     dnl when they fix it, remove this
 933     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 934     ;;
 935   openbsd*)
 936     AC_MSG_RESULT([OpenBSD])
 937
 938     AC_DEFINE(OPEN_BSD,,OpenBSD)
 939     AC_DEFINE(KAME,1,KAME IPv6)
 940     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 941
 942     if test "x${enable_pimd}" != "xno"; then
 943       case "$host_os" in
 944       openbsd6.0)
 945         ;;
 946       openbsd[6-9]*)
 947         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 948         ;;
 949       esac
 950     fi
 951     ;;
 952   *)
 953     AC_MSG_RESULT([BSD])
 954
 955     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 956     AC_DEFINE(KAME,1,KAME IPv6)
 957     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 958     ;;
 959 esac
 960 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 961
 962 AC_SYS_LARGEFILE
 963
 964 dnl ------------------------
 965 dnl Integrated REALMS option
 966 dnl ------------------------
 967 if test "${enable_realms}" = "yes"; then
 968     case "$host_os" in
 969       linux*)
 970        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 971        ;;
 972       *)
 973        echo "Sorry, only Linux has REALMS support"
 974        exit 1
 975        ;;
 976     esac
 977 fi
 978 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 979
 980 dnl ---------------------
 981 dnl Integrated VTY option
 982 dnl ---------------------
 983 case "${enable_vtysh}" in
 984   "no") VTYSH="";;
 985   *)    VTYSH="vtysh";
 986          AC_DEFINE(VTYSH,,VTY shell)
 987 dnl      Vtysh uses libreadline, which looks for termcap functions at
 988 dnl      configure time.  We follow readlines search order.
 989 dnl      The required procedures are in libtermcap on NetBSD, in
 990 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 991          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 992            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 993              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 994                [AC_CHECK_LIB(ncurses, tputs,
 995                              LIBREADLINE="$LIBREADLINE -lncurses")]
 996               )]
 997             )]
 998           )
 999          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1000                       "$LIBREADLINE")
1001          if test $ac_cv_lib_readline_main = no; then
1002            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1003          fi
1004          AC_CHECK_HEADER(readline/history.h)
1005          if test $ac_cv_header_readline_history_h = no;then
1006            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1007          fi
1008          AC_CHECK_LIB(readline, rl_completion_matches,
1009                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1010          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1011            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1012          fi
1013          ;;
1014 esac
1015 AC_SUBST(LIBREADLINE)
1016 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1017
1018 dnl ----------
1019 dnl PAM module
1020 dnl
1021 dnl FRR detects the PAM library it is built against by checking for a
1022 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1023 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1024 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1025 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1026 dnl of OpenPAM.
1027 dnl ----------
1028 if test "$with_libpam" = "yes"; then
1029   AC_CHECK_HEADER([security/pam_misc.h],
1030     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1031      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1032      pam_conv_func="misc_conv"
1033     ],
1034     [], FRR_INCLUDES)
1035   AC_CHECK_HEADER([security/openpam.h],
1036     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1037      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1038      pam_conv_func="openpam_ttyconv"
1039     ],
1040     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1041   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1042     AC_MSG_WARN([*** pam support will not be built ***])
1043     with_libpam="no"
1044   fi
1045 fi
1046
1047 if test "$with_libpam" = "yes"; then
1048 dnl took this test from proftpds configure.in and suited to our needs
1049 dnl -------------------------------------------------------------------------
1050 dnl
1051 dnl This next check looks funky due to a linker problem with some versions
1052 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1053 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1054 dnl with RedHat 6.2 and Debian 2.2 or better.
1055 AC_CHECK_LIB(pam, pam_start,
1056   [AC_CHECK_LIB(pam, $pam_conv_func,
1057     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1058      LIBPAM="-lpam"],
1059     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1060      LIBPAM="-lpam -lpam_misc"]
1061     )
1062   ],
1063
1064   [AC_CHECK_LIB(pam, pam_end,
1065     [AC_CHECK_LIB(pam, $pam_conv_func,
1066       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1067        LIBPAM="-lpam -ldl"],
1068       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1069        LIBPAM="-lpam -ldl -lpam_misc"]
1070      )
1071   ],AC_MSG_WARN([*** pam support will not be built ***]),
1072   [-ldl])
1073   ]
1074 )
1075 fi
1076 AC_SUBST(LIBPAM)
1077
1078 dnl -------------------------------
1079 dnl Endian-ness check
1080 dnl -------------------------------
1081 AC_WORDS_BIGENDIAN
1082
1083 dnl -------------------------------
1084 dnl check the size in byte of the C
1085 dnl -------------------------------
1086 dnl AC_CHECK_SIZEOF(char)
1087 dnl AC_CHECK_SIZEOF(int)
1088 dnl AC_CHECK_SIZEOF(short)
1089 dnl AC_CHECK_SIZEOF(long)
1090
1091 dnl ----------------------------
1092 dnl check existance of functions
1093 dnl ----------------------------
1094 AC_FUNC_FNMATCH
1095 AC_FUNC_FORK
1096 AC_FUNC_MKTIME
1097 AC_FUNC_STAT
1098
1099 dnl -------------------------------
1100 dnl bgpd needs pow() and hence libm
1101 dnl -------------------------------
1102 TMPLIBS="$LIBS"
1103 AC_CHECK_HEADER([math.h],
1104   [AC_CHECK_LIB([m], [pow],
1105     [LIBM="-lm"
1106      LIBS="$LIBS $LIBM"
1107      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1108     ])
1109 ])
1110 if test x"$LIBM" = x ; then
1111   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1112 fi
1113 LIBS="$TMPLIBS"
1114 AC_SUBST(LIBM)
1115
1116 AC_CHECK_FUNCS([ppoll], [
1117   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1118 ])
1119 AC_CHECK_FUNCS([pollts], [
1120   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1121 ])
1122
1123 dnl ---------------
1124 dnl other functions
1125 dnl ---------------
1126 AC_CHECK_FUNCS([ \
1127         strlcat strlcpy \
1128         getgrouplist])
1129
1130 AC_CHECK_HEADER([asm-generic/unistd.h],
1131                 [AC_CHECK_DECL(__NR_setns,
1132                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1133                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1134                                ])
1135                  AC_CHECK_FUNCS(setns)]
1136                )
1137
1138 dnl --------------------------
1139 dnl Determine IS-IS I/O method
1140 dnl --------------------------
1141 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1142 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1143 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1144 AC_CHECK_HEADER(net/bpf.h)
1145 AC_CHECK_HEADER(sys/dlpi.h)
1146 AC_MSG_CHECKING(zebra IS-IS I/O method)
1147
1148 case "$host_os" in
1149   linux*)
1150     AC_MSG_RESULT(pfpacket)
1151     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1152     ;;
1153   solaris* | sunos*)
1154     AC_MSG_RESULT(DLPI)
1155     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1156     ;;
1157   *)
1158     if test $ac_cv_header_net_bpf_h = no; then
1159       if test $ac_cv_header_sys_dlpi_h = no; then
1160         AC_MSG_RESULT(none)
1161         if test "${enable_isisd}" = yes; then
1162           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1163         fi
1164         AC_MSG_WARN([*** IS-IS support will not be built ***])
1165         enable_isisd="no"
1166       else
1167         AC_MSG_RESULT(DLPI)
1168       fi
1169       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1170     else
1171       AC_MSG_RESULT(BPF)
1172       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1173     fi
1174     ;;
1175 esac
1176 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1177
1178 dnl ---------------------------------------------------------------
1179 dnl figure out how to specify an interface in multicast sockets API
1180 dnl ---------------------------------------------------------------
1181 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1182
1183 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1184         #include <sys/socket.h>
1185         #include <netinet/in.h>
1186         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1187         #include <linux/types.h>
1188 ])
1189
1190 m4_define([FRR_INCLUDES],
1191 FRR_INCLUDES
1192 [#if HAVE_LINUX_MROUTE_H
1193 # include <linux/mroute.h>
1194 #endif
1195 ])dnl
1196
1197 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1198         #include <sys/socket.h>
1199         #include <sys/types.h>
1200         #include <netinet/in.h>
1201         #include <net/route.h>
1202 ])
1203
1204 m4_define([FRR_INCLUDES],
1205 FRR_INCLUDES
1206 [#if HAVE_NETINET_IP_MROUTE_H
1207 # include <netinet/ip_mroute.h>
1208 #endif
1209 ])dnl
1210
1211 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1212 AC_TRY_COMPILE([#include <sys/param.h>],
1213 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1214   return (0);
1215 #else
1216   #error No support for BSD struct ip_mreq hack detected
1217 #endif],[AC_MSG_RESULT(yes)
1218 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1219 AC_MSG_RESULT(no))
1220
1221 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1222 AC_TRY_COMPILE([
1223 #include <sys/types.h>
1224 #include <netinet/in.h>
1225 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1226 ], [AC_MSG_RESULT(yes)
1227 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1228 AC_MSG_RESULT(no))
1229
1230 dnl ---------------------------------------------------------------
1231 dnl figure out how to check link-state
1232 dnl ---------------------------------------------------------------
1233 AC_CHECK_HEADER( [net/if_media.h],
1234   [m4_define([LINK_DETECT_INCLUDES],
1235     FRR_INCLUDES
1236     [#include <net/if_media.h>
1237   ])
1238   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1239     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1240     [], LINK_DETECT_INCLUDES)],
1241   [],
1242   FRR_INCLUDES)
1243
1244 dnl ---------------------------------------------------------------
1245 dnl Additional, newer way to check link-state using ifi_link_state.
1246 dnl Not available in all BSD's when ifmediareq available
1247 dnl ---------------------------------------------------------------
1248 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1249   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1250   [], FRR_INCLUDES)
1251
1252 dnl ------------------------
1253 dnl TCP_MD5SIG socket option
1254 dnl ------------------------
1255
1256 AC_CHECK_HEADER([netinet/tcp.h],
1257    [m4_define([MD5_INCLUDES],
1258       FRR_INCLUDES
1259       [#include <netinet/tcp.h>
1260     ])
1261     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1262    [],
1263    FRR_INCLUDES)
1264 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1265   AC_CHECK_HEADER([linux/tcp.h],
1266        [m4_define([MD5_INCLUDES],
1267           FRR_INCLUDES
1268           [#include <linux/tcp.h>
1269         ])
1270        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1271 fi
1272
1273 dnl ----------------------------------------------------------------------------
1274 dnl figure out if domainname is available in the utsname struct (GNU extension).
1275 dnl ----------------------------------------------------------------------------
1276 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1277
1278 dnl ------------------
1279 dnl IPv6 header checks
1280 dnl ------------------
1281 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1282         netinet6/in6_var.h netinet6/nd6.h], [], [],
1283         FRR_INCLUDES)
1284
1285 m4_define([FRR_INCLUDES],dnl
1286 FRR_INCLUDES
1287 [#if HAVE_NETINET6_IN6_H
1288 #include <netinet6/in6.h>
1289 #endif
1290 #if HAVE_NETINET_IN6_VAR_H
1291 #include <netinet/in6_var.h>
1292 #endif
1293 #include <netinet/icmp6.h>
1294 #if HAVE_NETINET6_IN6_VAR_H
1295 # include <netinet6/in6_var.h>
1296 #endif
1297 #if HAVE_NETINET6_ND6_H
1298 # include <netinet6/nd6.h>
1299 #endif
1300 ])dnl
1301
1302 dnl disable doc check
1303 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1304 if test "$SPHINXBUILD" = "/bin/false"; then
1305   if test "${enable_doc}" = "yes"; then
1306     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1307   fi
1308 fi
1309 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false")
1310 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1311
1312 dnl --------------------
1313 dnl Daemon disable check
1314 dnl --------------------
1315 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1316
1317 if test "${enable_bgpd}" = "no";then
1318   BGPD=""
1319 else
1320   BGPD="bgpd"
1321 fi
1322 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1323
1324 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1325 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1326 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1327
1328 AS_IF([test "${enable_ldpd}" != "no"], [
1329   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1330 ])
1331
1332 if test "$enable_bfdd" = "no"; then
1333   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1334   BFDD=""
1335 else
1336   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1337   BFDD="bfdd"
1338
1339   case $host_os in
1340     linux*)
1341       AC_DEFINE(BFD_LINUX, 1, bfdd)
1342       ;;
1343
1344     *)
1345       AC_DEFINE(BFD_BSD, 1, bfdd)
1346       ;;
1347   esac
1348 fi
1349
1350 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1351
1352 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1353   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1354 fi
1355
1356 NHRPD=""
1357 case "$host_os" in
1358   linux*)
1359     if test "${enable_nhrpd}" != "no"; then
1360       NHRPD="nhrpd"
1361     fi
1362     ;;
1363   *)
1364     if test "${enable_nhrpd}" = "yes"; then
1365       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1366     fi
1367     ;;
1368 esac
1369 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1370
1371 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1372
1373 if test "${enable_watchfrr}" = "no";then
1374   WATCHFRR=""
1375 else
1376   WATCHFRR="watchfrr"
1377 fi
1378 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1379
1380 OSPFCLIENT=""
1381 if test "${enable_ospfapi}" != "no";then
1382     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1383
1384   if test "${enable_ospfclient}" != "no";then
1385       OSPFCLIENT="ospfclient"
1386   fi
1387 fi
1388
1389 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1390 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1391 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1392 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1393 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1394 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1395 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1396 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1397 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1398
1399 if test "${enable_bgp_announce}" = "no";then
1400   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1401 else
1402   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1403 fi
1404
1405 if test "${enable_bgp_vnc}" != "no";then
1406   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1407 fi
1408 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1409
1410 AC_SUBST(SOLARIS)
1411 AC_SUBST(CURSES)
1412 AC_CHECK_LIB(crypt, crypt, [],
1413                     [AC_CHECK_LIB(crypto, DES_crypt)])
1414 AC_CHECK_LIB(resolv, res_init)
1415
1416 dnl ---------------------------
1417 dnl check system has PCRE regexp
1418 dnl ---------------------------
1419 if test "x$enable_pcreposix" = "xyes"; then
1420   AC_CHECK_LIB(pcreposix, regexec, [], [
1421     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1422   ])
1423 fi
1424 AC_SUBST(HAVE_LIBPCREPOSIX)
1425
1426 dnl ------------------
1427 dnl check C-Ares library
1428 dnl ------------------
1429 if test "${NHRPD}" != ""; then
1430   PKG_CHECK_MODULES([CARES], [libcares], , [
1431     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1432   ])
1433 fi
1434
1435
1436 dnl ------------------
1437 dnl check Net-SNMP library
1438 dnl ------------------
1439 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1440    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1441    if test x"$NETSNMP_CONFIG" = x"no"; then
1442       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1443    fi
1444    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1445    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1446    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1447    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1448 int main(void);
1449 ],
1450 [
1451 {
1452   return 0;
1453 }
1454 ])], [
1455      AC_MSG_ERROR([--enable-snmp given but not usable])])
1456    case "${enable_snmp}" in
1457      yes)
1458       SNMP_METHOD=agentx
1459       ;;
1460      agentx)
1461       SNMP_METHOD="${enable_snmp}"
1462       ;;
1463      *)
1464       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1465       ;;
1466    esac
1467    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1468    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1469 fi
1470 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1471 AC_SUBST(SNMP_LIBS)
1472 AC_SUBST(SNMP_CFLAGS)
1473
1474 dnl ---------------
1475 dnl math
1476 dnl ---------------
1477 AC_SEARCH_LIBS([sqrt], [m])
1478
1479 dnl ---------------
1480 dnl dlopen & dlinfo
1481 dnl ---------------
1482 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1483   AC_MSG_ERROR([unable to find the dlopen()])
1484 ])
1485
1486 AC_CHECK_HEADERS([link.h])
1487
1488 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1489   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1490 #include <stdlib.h>
1491 #ifdef HAVE_LINK_H
1492 #include <link.h>
1493 #endif
1494 #include <dlfcn.h>
1495 ]], [[
1496   char origin[1];
1497   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1498 ]])], [
1499     frr_cv_rtld_di_origin=yes
1500   ], [
1501     frr_cv_rtld_di_origin=no
1502   ])
1503 ])
1504 if test "$frr_cv_rtld_di_origin" = yes; then
1505   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1506 fi
1507
1508 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1509   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1510 #include <stdlib.h>
1511 #ifdef HAVE_LINK_H
1512 #include <link.h>
1513 #endif
1514 #include <dlfcn.h>
1515 ]], [[
1516   struct link_map *lm = NULL;
1517   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1518 ]])], [
1519     frr_cv_rtld_di_linkmap=yes
1520   ], [
1521     frr_cv_rtld_di_linkmap=no
1522   ])
1523 ])
1524 if test "$frr_cv_rtld_di_linkmap" = yes; then
1525   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1526 fi
1527
1528 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1529
1530 dnl ---------------------------
1531 dnl sockaddr and netinet checks
1532 dnl ---------------------------
1533 AC_CHECK_TYPES([
1534         struct sockaddr_dl,
1535         struct vifctl, struct mfcctl, struct sioc_sg_req,
1536         vifi_t, struct sioc_vif_req, struct igmpmsg,
1537         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1538         struct nd_opt_adv_interval, struct rt_addrinfo,
1539         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1540         [], [], FRR_INCLUDES)
1541
1542 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1543         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1544         struct sockaddr_dl.sdl_len,
1545         struct if6_aliasreq.ifra_lifetime,
1546         struct nd_opt_adv_interval.nd_opt_ai_type],
1547         [], [], FRR_INCLUDES)
1548
1549 dnl ---------------------------
1550 dnl IRDP/pktinfo/icmphdr checks
1551 dnl ---------------------------
1552
1553 AC_CHECK_TYPES([struct in_pktinfo], [
1554   AC_CHECK_TYPES([struct icmphdr], [
1555     IRDP=true
1556   ], [
1557     IRDP=false
1558   ], [FRR_INCLUDES])
1559 ], [
1560   IRDP=false
1561 ], [FRR_INCLUDES])
1562
1563 case "${enable_irdp}" in
1564 yes)
1565   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1566   ;;
1567 no)
1568   IRDP=false
1569   ;;
1570 esac
1571
1572 AM_CONDITIONAL(IRDP, $IRDP)
1573
1574 dnl -----------------------
1575 dnl checking for IP_PKTINFO
1576 dnl -----------------------
1577 AC_MSG_CHECKING(for IP_PKTINFO)
1578 AC_TRY_COMPILE([#include <netdb.h>], [
1579   int opt = IP_PKTINFO;
1580 ], [
1581   AC_MSG_RESULT(yes)
1582   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1583 ], [
1584   AC_MSG_RESULT(no)
1585 ])
1586
1587 dnl ---------------------------
1588 dnl checking for IP_RECVDSTADDR
1589 dnl ---------------------------
1590 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1591 AC_TRY_COMPILE([#include <netinet/in.h>], [
1592   int opt = IP_RECVDSTADDR;
1593 ], [
1594   AC_MSG_RESULT(yes)
1595   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1596 ], [
1597   AC_MSG_RESULT(no)
1598 ])
1599
1600 dnl ----------------------
1601 dnl checking for IP_RECVIF
1602 dnl ----------------------
1603 AC_MSG_CHECKING(for IP_RECVIF)
1604 AC_TRY_COMPILE([#include <netinet/in.h>], [
1605   int opt = IP_RECVIF;
1606 ], [
1607   AC_MSG_RESULT(yes)
1608   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1609 ], [
1610   AC_MSG_RESULT(no)
1611 ])
1612
1613 dnl ----------------------
1614 dnl checking for SO_BINDANY
1615 dnl ----------------------
1616 AC_MSG_CHECKING(for SO_BINDANY)
1617 AC_TRY_COMPILE([#include <sys/socket.h>], [
1618   int opt = SO_BINDANY;
1619 ], [
1620   AC_MSG_RESULT(yes)
1621   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1622 ], [
1623   AC_MSG_RESULT(no)
1624 ])
1625
1626 dnl ----------------------
1627 dnl checking for IP_FREEBIND
1628 dnl ----------------------
1629 AC_MSG_CHECKING(for IP_FREEBIND)
1630 AC_TRY_COMPILE([#include <netinet/in.h>], [
1631   int opt = IP_FREEBIND;
1632 ], [
1633   AC_MSG_RESULT(yes)
1634   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1635 ], [
1636   AC_MSG_RESULT(no)
1637 ])
1638
1639 dnl --------------------------------------
1640 dnl checking for be32dec existence or not
1641 dnl --------------------------------------
1642 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1643                [#include <sys/endian.h>])
1644
1645 dnl --------------------------------------
1646 dnl checking for clock_time monotonic struct and call
1647 dnl --------------------------------------
1648 AC_CHECK_DECL(CLOCK_MONOTONIC,
1649         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1650          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1651 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1652
1653 dnl --------------------------------------
1654 dnl checking for flex and bison
1655 dnl --------------------------------------
1656
1657 AM_PROG_LEX
1658 AC_MSG_CHECKING(version of flex)
1659 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1660 frr_ac_flex_version="${frr_ac_flex_version##* }"
1661 AC_MSG_RESULT([$frr_ac_flex_version])
1662 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1663   LEX="$SHELL $missing_dir/missing flex"
1664   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1665     AC_MSG_WARN([using pregenerated flex output files])
1666   else
1667     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1668   fi
1669   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1670   AC_SUBST([LEXLIB], [''])
1671 ])
1672
1673 AC_PROG_YACC
1674 dnl thanks GNU bison for this b*llshit...
1675 AC_MSG_CHECKING(version of bison)
1676 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1677 frr_ac_bison_version="${frr_ac_bison_version##* }"
1678 frr_ac_bison_missing="false"
1679 case "x${frr_ac_bison_version}" in
1680   x2.7*)
1681     BISON_OPENBRACE='"'
1682     BISON_CLOSEBRACE='"'
1683     BISON_VERBOSE=''
1684     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1685     ;;
1686   x2.*|x1.*)
1687     AC_MSG_RESULT([$frr_ac_bison_version])
1688     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1689     frr_ac_bison_missing="true"
1690     ;;
1691   x)
1692     AC_MSG_RESULT([none])
1693     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1694     frr_ac_bison_missing="true"
1695     ;;
1696   *)
1697     BISON_OPENBRACE='{'
1698     BISON_CLOSEBRACE='}'
1699     BISON_VERBOSE='-Dparse.error=verbose'
1700     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1701     ;;
1702 esac
1703 AC_SUBST(BISON_OPENBRACE)
1704 AC_SUBST(BISON_CLOSEBRACE)
1705 AC_SUBST(BISON_VERBOSE)
1706
1707 if $frr_ac_bison_missing; then
1708   YACC="$SHELL $missing_dir/missing bison -y"
1709   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1710     AC_MSG_WARN([using pregenerated bison output files])
1711   else
1712     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1713   fi
1714 fi
1715
1716 dnl -------------------
1717 dnl capabilities checks
1718 dnl -------------------
1719 if test "${enable_capabilities}" != "no"; then
1720   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1721   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1722     [AC_MSG_RESULT(yes)
1723      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1724      frr_ac_keepcaps="yes"],
1725      AC_MSG_RESULT(no)
1726   )
1727   if test x"${frr_ac_keepcaps}" = x"yes"; then
1728     AC_CHECK_HEADERS(sys/capability.h)
1729   fi
1730   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1731     AC_CHECK_LIB(cap, cap_init,
1732       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1733        LIBCAP="-lcap"
1734        frr_ac_lcaps="yes"]
1735     )
1736   else
1737     AC_CHECK_HEADERS(priv.h,
1738      [AC_MSG_CHECKING(Solaris style privileges are available)
1739       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1740           [AC_MSG_RESULT(yes)
1741            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1742            frr_ac_scaps="yes"],
1743            AC_MSG_RESULT(no)
1744       )
1745      ]
1746    )
1747   fi
1748   if test x"${frr_ac_scaps}" = x"yes" \
1749        -o x"${frr_ac_lcaps}" = x"yes"; then
1750     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1751   fi
1752 fi
1753 AC_SUBST(LIBCAP)
1754
1755 dnl ---------------------------
1756 dnl check for glibc 'backtrace'
1757 dnl ---------------------------
1758 if test x"${enable_backtrace}" != x"no" ; then
1759   backtrace_ok=no
1760   AC_CHECK_HEADER([execinfo.h], [
1761     AC_SEARCH_LIBS([backtrace], [execinfo], [
1762       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1763       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1764       backtrace_ok=yes
1765     ],, [-lm])
1766   ])
1767
1768   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1769     dnl user explicitly requested backtrace but we failed to find support
1770     AC_MSG_FAILURE([failed to find backtrace support])
1771   fi
1772 fi
1773
1774 dnl -----------------------------------------
1775 dnl check for malloc mallinfo struct and call
1776 dnl this must try and link using LIBS, in
1777 dnl order to check no alternative allocator
1778 dnl has been specified, which might not provide
1779 dnl mallinfo, e.g. such as Umem on Solaris.
1780 dnl -----------------------------------------
1781 AC_CHECK_HEADERS([malloc.h malloc/malloc.h],,, [FRR_INCLUDES])
1782
1783 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1784   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1785 #ifdef HAVE_MALLOC_H
1786 #include <malloc.h>
1787 #endif
1788 #ifdef HAVE_MALLOC_MALLOC_H
1789 #include <malloc/malloc.h>
1790 #endif
1791 ]], [[
1792 struct mallinfo ac_x; ac_x = mallinfo ();
1793 ]])], [
1794     frr_cv_mallinfo=yes
1795   ], [
1796     frr_cv_mallinfo=no
1797   ])
1798 ])
1799 if test "$frr_cv_mallinfo" = yes; then
1800   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1801 fi
1802
1803 AC_MSG_CHECKING(whether malloc_usable_size is available)
1804 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1805 #ifdef HAVE_MALLOC_H
1806 #include <malloc.h>
1807 #endif
1808 #ifdef HAVE_MALLOC_MALLOC_H
1809 #include <malloc/malloc.h>
1810 #endif
1811 ]], [[
1812 size_t ac_x; ac_x = malloc_usable_size(NULL);
1813 ]])], [
1814   AC_MSG_RESULT(yes)
1815   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1816 ], [
1817   AC_MSG_RESULT(no)
1818
1819   AC_MSG_CHECKING(whether malloc_size is available)
1820   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1821 #ifdef HAVE_MALLOC_H
1822 #include <malloc.h>
1823 #endif
1824 #ifdef HAVE_MALLOC_MALLOC_H
1825 #include <malloc/malloc.h>
1826 #endif
1827 ]], [[
1828 size_t ac_x; ac_x = malloc_size(NULL);
1829 ]])], [
1830     AC_MSG_RESULT(yes)
1831     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1832   ], [
1833     AC_MSG_RESULT(no)
1834   ])
1835 ])
1836
1837 dnl ------
1838 dnl ZeroMQ
1839 dnl ------
1840 if test "x$enable_zeromq" != "xno"; then
1841   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1842     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1843     ZEROMQ=true
1844   ], [
1845     if test "x$enable_zeromq" = "xyes"; then
1846       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1847     fi
1848   ])
1849 fi
1850 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1851
1852 dnl ----------
1853 dnl configure date
1854 dnl ----------
1855 dev_version=`echo $VERSION | grep dev`
1856 #don't expire deprecated code in non 'dev' branch
1857 if test "${dev_version}" = ""; then
1858    CONFDATE=0
1859 else
1860    CONFDATE=`date '+%Y%m%d'`
1861 fi
1862 AC_SUBST(CONFDATE)
1863
1864 dnl ------------------------------
1865 dnl set paths for state directory
1866 dnl ------------------------------
1867 AC_MSG_CHECKING(directory to use for state file)
1868 if test "${prefix}" = "NONE"; then
1869   frr_statedir_prefix="";
1870 else
1871   frr_statedir_prefix=${prefix}
1872 fi
1873 if test "${localstatedir}" = '${prefix}/var'; then
1874   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1875                         ${frr_statedir_prefix}/var/adm dnl
1876                         ${frr_statedir_prefix}/etc dnl
1877                         /var/run        dnl
1878                         /var/adm        dnl
1879                         /etc            dnl
1880                         /dev/null;
1881   do
1882     test -d $FRR_STATE_DIR && break
1883   done
1884   frr_statedir=$FRR_STATE_DIR
1885 else
1886   frr_statedir=${localstatedir}
1887 fi
1888 if test $frr_statedir = "/dev/null"; then
1889     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1890 fi
1891 AC_MSG_RESULT(${frr_statedir})
1892 AC_SUBST(frr_statedir)
1893
1894 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1895 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1896 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1897 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1898
1899 dnl autoconf does this, but it does it too late...
1900 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1901 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1902
1903 dnl get the full path, recursing through variables...
1904 vtysh_bin="$bindir/vtysh"
1905 for I in 1 2 3 4 5 6 7 8 9 10; do
1906         eval vtysh_bin="\"$vtysh_bin\""
1907 done
1908 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1909
1910 CFG_SYSCONF="$sysconfdir"
1911 CFG_SBIN="$sbindir"
1912 CFG_STATE="$frr_statedir"
1913 CFG_MODULE="$moduledir"
1914 for I in 1 2 3 4 5 6 7 8 9 10; do
1915         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1916         eval CFG_SBIN="\"$CFG_SBIN\""
1917         eval CFG_STATE="\"$CFG_STATE\""
1918         eval CFG_MODULE="\"$CFG_MODULE\""
1919 done
1920 AC_SUBST(CFG_SYSCONF)
1921 AC_SUBST(CFG_SBIN)
1922 AC_SUBST(CFG_STATE)
1923 AC_SUBST(CFG_MODULE)
1924 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1925
1926 dnl ------------------------------------
1927 dnl Enable RPKI and add librtr to libs
1928 dnl ------------------------------------
1929 if test "${enable_rpki}" = "yes"; then
1930   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1931       [RPKI=true],
1932       [RPKI=false
1933       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1934   )
1935 fi
1936 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1937
1938 dnl ------------------------------------------
1939 dnl Check whether rtrlib was build with ssh support
1940 dnl ------------------------------------------
1941 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1942 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1943                         [[struct tr_ssh_config config;]])],
1944         [AC_MSG_RESULT(yes)
1945         AC_DEFINE(FOUND_SSH,,found_ssh)],
1946         AC_MSG_RESULT(no)
1947 )
1948
1949 dnl ---------------------------
1950 dnl Check htonl works correctly
1951 dnl ---------------------------
1952 AC_MSG_CHECKING(for working htonl)
1953 AC_CACHE_VAL(ac_cv_htonl_works,
1954  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1955                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1956  ]
1957 )
1958 AC_MSG_RESULT($ac_cv_htonl_works)
1959
1960 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
1961
1962 AC_CONFIG_FILES([
1963           redhat/frr.spec
1964           solaris/Makefile
1965           debianpkg/changelog
1966           alpine/APKBUILD
1967           snapcraft/snapcraft.yaml
1968           lib/version.h
1969           tests/lib/cli/test_cli.refout
1970           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1971           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1972           pkgsrc/eigrpd.sh])
1973
1974 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1975
1976 AC_CONFIG_COMMANDS([lib/route_types.h], [
1977         dst="${ac_abs_top_builddir}/lib/route_types.h"
1978         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1979                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1980                 > "${dst}.tmp"
1981         test -f "${dst}" \
1982                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1983                 && rm "${dst}.tmp" \
1984                 || mv "${dst}.tmp" "${dst}"
1985 ], [
1986         PERL="$PERL"
1987 ])
1988
1989 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
1990     AC_CONFIG_COMMANDS([lib/gitversion.h], [
1991         dst="${ac_abs_top_builddir}/lib/gitversion.h"
1992         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
1993                 "${ac_abs_top_srcdir}" \
1994                 > "${dst}.tmp"
1995         test -f "${dst}" \
1996                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1997                 && rm "${dst}.tmp" \
1998                 || mv "${dst}.tmp" "${dst}"
1999     ], [
2000         PERL="$PERL"
2001     ])
2002 ])
2003
2004 ## Hack, but working solution to avoid rebuilding of frr.info.
2005 ## It's already in CVS until texinfo 4.7 is more common.
2006 AC_OUTPUT
2007
2008 echo "
2009 FRRouting configuration
2010 ------------------------------
2011 FRR version             : ${PACKAGE_VERSION}
2012 host operating system   : ${host_os}
2013 source code location    : ${srcdir}
2014 compiler                : ${CC}
2015 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2016 make                    : ${MAKE-make}
2017 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2018 state file directory    : ${frr_statedir}
2019 config file directory   : `eval echo \`echo ${sysconfdir}\``
2020 example directory       : `eval echo \`echo ${exampledir}\``
2021 module directory        : ${CFG_MODULE}
2022 user to run as          : ${enable_user}
2023 group to run as         : ${enable_group}
2024 group for vty sockets   : ${enable_vty_group}
2025 config file mask        : ${enable_configfile_mask}
2026 log file mask           : ${enable_logfile_mask}
2027 zebra protobuf enabled  : ${enable_protobuf:-no}
2028
2029 The above user and group must have read/write access to the state file
2030 directory and to the config files in the config file directory."
2031
2032 if test "${enable_doc}" != "no";then
2033   AS_IF([test "$SPHINXBUILD" = /bin/false],
2034      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2035 fi