configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.0, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl AddressSanitizer support
 189 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 190               [enabled AddressSanitizer support for detecting a wide variety of \
 191                memory allocation and deallocation errors]), \
 192               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 193               ASAN_FLAGS="-fsanitize=address"
 194               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 195               AC_SUBST([ASAN_FLAGS])
 196               AC_SUBST([SAN_CLIPPY_FLAGS])
 197               LIBS="-ldl $LIBS"
 198               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 199                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 200               ])
 201
 202 dnl ThreadSanitizer support
 203 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 204               [enabled ThreadSanitizer support for detecting data races]), \
 205               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 206               TSAN_FLAGS="-fsanitize=thread"
 207               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 208               AC_SUBST([TSAN_FLAGS])
 209               AC_SUBST([SAN_CLIPPY_FLAGS])
 210               LIBS="-ldl $LIBS"
 211               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 212                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 213               ])
 214
 215 dnl MemorySanitizer support
 216 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 217               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 218               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 219               MSAN_FLAGS="-fsanitize=memory -fPIE -pie"
 220               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 221               AC_SUBST([MSAN_FLAGS])
 222               AC_SUBST([SAN_CLIPPY_FLAGS])
 223               LIBS="-ldl $LIBS"
 224               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 225                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 226               ])
 227
 228 dnl if the user has specified any CFLAGS, override our settings
 229 if test "x${enable_gcov}" = "xyes"; then
 230    if test "z$orig_cflags" = "z"; then
 231       AC_C_FLAG([-coverage])
 232       AC_C_FLAG([-O0])
 233    fi
 234
 235    LDFLAGS="${LDFLAGS} -lgcov"
 236 elif test "x${enable_dev_build}" = "xyes"; then
 237    AC_DEFINE(DEV_BUILD,,Build for development)
 238    if test "z$orig_cflags" = "z"; then
 239       AC_C_FLAG([-g3])
 240       AC_C_FLAG([-O0])
 241    fi
 242 else
 243    if test "z$orig_cflags" = "z"; then
 244       AC_C_FLAG([-g])
 245       AC_C_FLAG([-Os], [
 246         AC_C_FLAG([-O2])
 247       ])
 248    fi
 249 fi
 250 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 251
 252 dnl always want these CFLAGS
 253 AC_C_FLAG([-fno-omit-frame-pointer])
 254 AC_C_FLAG([-funwind-tables])
 255 AC_C_FLAG([-Wall])
 256 AC_C_FLAG([-Wextra])
 257 AC_C_FLAG([-Wmissing-prototypes])
 258 AC_C_FLAG([-Wmissing-declarations])
 259 AC_C_FLAG([-Wpointer-arith])
 260 AC_C_FLAG([-Wbad-function-cast])
 261 AC_C_FLAG([-Wwrite-strings])
 262 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 263   AC_C_FLAG([-Wcast-qual])
 264   AC_C_FLAG([-Wstrict-prototypes])
 265   AC_C_FLAG([-Wmissing-noreturn])
 266   AC_C_FLAG([-Wmissing-format-attribute])
 267   AC_C_FLAG([-Wunreachable-code])
 268   AC_C_FLAG([-Wpacked])
 269   AC_C_FLAG([-Wpadded])
 270 else
 271   AC_C_FLAG([-Wno-unused-result])
 272 fi
 273 AC_C_FLAG([-Wno-unused-parameter])
 274 AC_C_FLAG([-Wno-missing-field-initializers])
 275
 276 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 277 dnl for some reason the string consts get 'promoted' to char *,
 278 dnl triggering a const to non-const conversion warning.
 279 AC_C_FLAG([-diag-disable 3179])
 280
 281 if test x"${enable_werror}" = x"yes" ; then
 282   WERROR="-Werror"
 283 fi
 284 AC_SUBST(WERROR)
 285
 286 dnl need link on this one, not compile
 287 AC_LANG_PUSH(C)
 288 ac_ld_flag_save="$LDFLAGS"
 289 LDFLAGS="$LDFLAGS -rdynamic"
 290 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 291 AC_LINK_IFELSE(
 292         [AC_LANG_PROGRAM([[]])],
 293         [AC_MSG_RESULT([yes])],
 294         [
 295                 LDFLAGS="$ac_ld_flag_save"
 296                 AC_MSG_RESULT([no])
 297         ])
 298 AC_LANG_POP(C)
 299
 300 dnl ----------
 301 dnl Essentials
 302 dnl ----------
 303
 304 AX_PTHREAD([
 305   CC="$PTHREAD_CC"
 306   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 307   LIBS="$PTHREAD_LIBS $LIBS"
 308 ], [
 309   AC_MSG_FAILURE([This FRR version needs pthreads])
 310 ])
 311
 312 dnl --------------
 313 dnl Check programs
 314 dnl --------------
 315 AC_PROG_INSTALL
 316 AC_PROG_LN_S
 317 AC_PROG_MAKE_SET
 318 AC_CHECK_TOOL(AR, ar)
 319
 320 dnl -----------------
 321 dnl System extensions
 322 dnl -----------------
 323 AC_GNU_SOURCE
 324
 325 dnl -------
 326 dnl libtool
 327 dnl -------
 328 LT_INIT
 329
 330 dnl ----------------------
 331 dnl Packages configuration
 332 dnl ----------------------
 333 AC_ARG_WITH(pkg-extra-version,
 334         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 335         [EXTRAVERSION=$withval],)
 336 AC_ARG_WITH(pkg-git-version,
 337         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 338         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 339 AC_ARG_WITH(vtysh_pager,
 340         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 341         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 342 AC_ARG_ENABLE(vtysh,
 343   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 344 AC_ARG_ENABLE(doc,
 345   AS_HELP_STRING([--disable-doc], [do not build docs]))
 346 AC_ARG_ENABLE(doc-html,
 347   AS_HELP_STRING([--disable-doc-html], [do not build HTML docs]))
 348 AC_ARG_ENABLE(zebra,
 349   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 350 AC_ARG_ENABLE(bgpd,
 351   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 352 AC_ARG_ENABLE(ripd,
 353   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 354 AC_ARG_ENABLE(ripngd,
 355   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 356 AC_ARG_ENABLE(ospfd,
 357   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 358 AC_ARG_ENABLE(ospf6d,
 359   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 360 AC_ARG_ENABLE(ldpd,
 361   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 362 AC_ARG_ENABLE(nhrpd,
 363   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 364 AC_ARG_ENABLE(eigrpd,
 365   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 366 AC_ARG_ENABLE(babeld,
 367   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 368 AC_ARG_ENABLE(watchfrr,
 369   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 370 AC_ARG_ENABLE(isisd,
 371   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 372 AC_ARG_ENABLE(pimd,
 373   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 374 AC_ARG_ENABLE(pbrd,
 375   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 376 AC_ARG_ENABLE(sharpd,
 377   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 378 AC_ARG_ENABLE(staticd,
 379   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 380 AC_ARG_ENABLE(bgp-announce,
 381   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 382 AC_ARG_ENABLE(bgp-vnc,
 383   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 384 AC_ARG_WITH(rfp-path,
 385   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 386 AC_ARG_ENABLE(snmp,
 387   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 388 AC_ARG_ENABLE(zeromq,
 389   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 390 AC_ARG_WITH(libpam,
 391   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 392 AC_ARG_ENABLE(ospfapi,
 393   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 394 AC_ARG_ENABLE(ospfclient,
 395   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 396                           (this is the default if --disable-ospfapi is set)]))
 397 AC_ARG_ENABLE(multipath,
 398   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 399 AC_ARG_ENABLE(user,
 400   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 401 AC_ARG_ENABLE(group,
 402   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 403 AC_ARG_ENABLE(vty_group,
 404   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 405 AC_ARG_ENABLE(configfile_mask,
 406   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 407 AC_ARG_ENABLE(logfile_mask,
 408   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 409 AC_ARG_ENABLE(shell_access,
 410   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 411 AC_ARG_ENABLE(realms,
 412   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 413 AC_ARG_ENABLE(rtadv,
 414   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 415 AC_ARG_ENABLE(irdp,
 416   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 417 AC_ARG_ENABLE(capabilities,
 418   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 419 AC_ARG_ENABLE(rusage,
 420   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 421 AC_ARG_ENABLE(gcc_ultra_verbose,
 422   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 423 AC_ARG_ENABLE(backtrace,
 424   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 425 AC_ARG_ENABLE(time-check,
 426   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 427 AC_ARG_ENABLE(pcreposix,
 428   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 429 AC_ARG_ENABLE(fpm,
 430   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 431 AC_ARG_ENABLE(systemd,
 432   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 433 AC_ARG_ENABLE(werror,
 434   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 435 AC_ARG_ENABLE(cumulus,
 436   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 437 AC_ARG_ENABLE(datacenter,
 438   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 439 AC_ARG_ENABLE(fuzzing,
 440   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 441 AC_ARG_ENABLE(netlink_fuzzing,
 442   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 443 AC_ARG_ENABLE(rr-semantics,
 444   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 445 AC_ARG_ENABLE([protobuf],
 446   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 447 AC_ARG_ENABLE([oldvpn_commands],
 448   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 449 AC_ARG_ENABLE(rpki,
 450   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 451 AC_ARG_ENABLE([clippy-only],
 452   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 453 AC_ARG_ENABLE([numeric_version],
 454   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 455 AC_ARG_ENABLE([gcov],
 456   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 457 AC_ARG_ENABLE(bfdd,
 458   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 459
 460 AS_IF([test "${enable_clippy_only}" != "yes"], [
 461 AC_CHECK_HEADERS(json-c/json.h)
 462 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 463 if test $ac_cv_lib_json_c_json_object_get = no; then
 464   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 465   if test $ac_cv_lib_json_json_object_get = no; then
 466       AC_MSG_ERROR([lib json is needed to compile])
 467   fi
 468 fi
 469 ])
 470
 471 AC_ARG_ENABLE([dev_build],
 472     AS_HELP_STRING([--enable-dev-build], [build for development]))
 473
 474 if test x"${enable_time_check}" != x"no" ; then
 475   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 476     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 477   else
 478     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 479   fi
 480 fi
 481
 482 case "${enable_systemd}" in
 483   "no") ;;
 484   "yes")
 485   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 486   if test $ac_cv_lib_systemd_sd_notify = no; then
 487     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 488   else
 489     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 490   fi
 491   ;;
 492   "*") ;;
 493 esac
 494
 495 if test "${enable_rr_semantics}" != "no" ; then
 496   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 497 fi
 498
 499 if test "${enable_datacenter}" = "yes" ; then
 500   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 501   DFLT_NAME="datacenter"
 502 else
 503   DFLT_NAME="traditional"
 504 fi
 505
 506 if test "${enable_fuzzing}" = "yes" ; then
 507   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 508 fi
 509
 510 if test "${enable_netlink_fuzzing}" = "yes" ; then
 511   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 512 fi
 513
 514 if test "${enable_cumulus}" = "yes" ; then
 515   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 516 fi
 517
 518 AC_SUBST(DFLT_NAME)
 519 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 520
 521 if test "${enable_shell_access}" = "yes"; then
 522    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 523 fi
 524
 525 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 526
 527 #
 528 # Python for clippy
 529 #
 530 AS_IF([test "$host" = "$build"], [
 531   PYTHONCONFIG=""
 532
 533   # ordering:
 534   # 1.  try python3, but respect the user's preference on which minor ver
 535   # 2.  try python, which might be py3 or py2 again on the user's preference
 536   # 3.  try python2 (can really only be 2.7 but eh)
 537   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 538   #
 539   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 540   # (AX_PYTHON does not do what we need)
 541
 542   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 543   if test -n "$PYTHONCONFIG"; then
 544     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 545     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 546
 547     AC_MSG_CHECKING([whether we found a working Python version])
 548     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 549 #include <Python.h>
 550 #if PY_VERSION_HEX < 0x02070000
 551 #error python too old
 552 #endif
 553 int main(void);
 554 ],
 555 [
 556 {
 557   Py_Initialize();
 558   return 0;
 559 }
 560 ])], [
 561       PYTHONCONFIG=""
 562       unset PYTHON_LIBS
 563       unset PYTHON_CFLAGS
 564     ])
 565   fi
 566
 567   if test -z "$PYTHONCONFIG"; then
 568     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 569       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 570         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 571           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 572             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 573               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 574               ])])])])])
 575
 576
 577     AC_MSG_CHECKING([whether we found a working Python version])
 578     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 579 #include <Python.h>
 580 #if PY_VERSION_HEX < 0x02070000
 581 #error python too old
 582 #endif
 583 int main(void);
 584 ],
 585 [
 586 {
 587   Py_Initialize();
 588   return 0;
 589 }
 590 ])], [
 591       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 592     ])
 593   fi
 594 ])
 595 AC_SUBST(PYTHON_CFLAGS)
 596 AC_SUBST(PYTHON_LIBS)
 597
 598 #
 599 # Logic for protobuf support.
 600 #
 601 if test "$enable_protobuf" = "yes"; then
 602    have_protobuf=yes
 603
 604    # Check for protoc-c
 605    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 606    if test "x$PROTOC_C" = "x/bin/false"; then
 607       have_protobuf=no
 608    else
 609       found_protobuf_c=no
 610       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 611                      [found_protobuf_c=yes],
 612                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 613
 614       if test "x$found_protobuf_c" = "xyes"; then
 615          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 616          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 617       else
 618         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 619                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 620       fi
 621    fi
 622 fi
 623
 624 #
 625 # Logic for old vpn commans support.
 626 #
 627 if test "$enable_oldvpn_commands" = "yes"; then
 628    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 629 fi
 630
 631 # Fail if the user explicity enabled protobuf support and we couldn't
 632 # find the compiler or libraries.
 633 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 634    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 635 fi
 636
 637 if test "x$have_protobuf" = "xyes"; then
 638    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 639 fi
 640
 641 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 642
 643 #
 644 # End of logic for protobuf support.
 645 #
 646
 647 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 648 if test "${enable_rtadv}" != "no"; then
 649   AC_MSG_RESULT(yes)
 650   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 651 else
 652   AC_MSG_RESULT(no)
 653 fi
 654
 655 if test x"${enable_user}" = x"no"; then
 656   enable_user=""
 657 else
 658   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 659     enable_user="frr"
 660   fi
 661   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 662 fi
 663
 664 if test x"${enable_group}" = x"no"; then
 665   enable_group=""
 666 else
 667   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 668     enable_group="frr"
 669   fi
 670   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 671 fi
 672
 673 if test x"${enable_vty_group}" = x"yes" ; then
 674   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 675 elif test x"${enable_vty_group}" != x""; then
 676   if test x"${enable_vty_group}" != x"no"; then
 677     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 678   fi
 679 fi
 680 AC_SUBST([enable_user])
 681 AC_SUBST([enable_group])
 682 AC_SUBST([enable_vty_group])
 683
 684 enable_configfile_mask=${enable_configfile_mask:-0600}
 685 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 686
 687 enable_logfile_mask=${enable_logfile_mask:-0600}
 688 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 689
 690 MPATH_NUM=1
 691
 692 case "${enable_multipath}" in
 693   0)
 694     MPATH_NUM=64
 695     ;;
 696   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 697     MPATH_NUM="${enable_multipath}"
 698     ;;
 699   "")
 700     ;;
 701   *)
 702     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 703     ;;
 704 esac
 705
 706 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 707
 708 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 709
 710 dnl --------------------
 711 dnl Enable code coverage
 712 dnl --------------------
 713 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 714
 715 dnl ------------------------------------
 716 dnl Alpine only accepts numeric versions
 717 dnl ------------------------------------
 718 if test "x${enable_numeric_version}" != "x" ; then
 719   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 720   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 721 fi
 722
 723 dnl -----------------------------------
 724 dnl Add extra version string to package
 725 dnl name, string and version fields.
 726 dnl -----------------------------------
 727 if test "x${EXTRAVERSION}" != "x" ; then
 728   VERSION="${VERSION}${EXTRAVERSION}"
 729   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 730   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 731   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 732 fi
 733
 734 if test "x$with_pkg_git_version" = "xyes"; then
 735         if test -d "${srcdir}/.git"; then
 736                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 737         else    with_pkg_git_version="no"
 738                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 739         fi
 740 fi
 741 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 742
 743 dnl ------------------------------------
 744 dnl Check C keywords and standard  types
 745 dnl ------------------------------------
 746 AC_C_CONST
 747 AC_C_INLINE
 748 AC_C_VOLATILE
 749 AC_HEADER_STDC
 750 dnl AC_TYPE_PID_T
 751 AC_TYPE_UID_T
 752 AC_TYPE_MODE_T
 753 AC_TYPE_SIZE_T
 754 AC_STRUCT_TM
 755
 756 dnl -------------------------
 757 dnl Check other header files.
 758 dnl -------------------------
 759 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 760         linux/version.h asm/types.h \
 761         sys/cdefs.h])
 762
 763 ac_stdatomic_ok=false
 764 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 765 AC_CHECK_HEADER([stdatomic.h],[
 766
 767   AC_MSG_CHECKING([whether _Atomic qualifier works])
 768   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 769 #include <stdatomic.h>
 770 int main(int argc, char **argv) {
 771   _Atomic int i = 0;
 772   return i;
 773 }
 774 ]])], [
 775     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 776     AC_MSG_RESULT([yes])
 777     ac_stdatomic_ok=true
 778   ], [
 779     AC_MSG_RESULT([no])
 780   ])
 781 ])
 782
 783 AS_IF([$ac_stdatomic_ok], [true], [
 784   AC_MSG_CHECKING([for __atomic_* builtins])
 785   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 786 int main(int argc, char **argv) {
 787   volatile int i = 1;
 788   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 789   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 790 }
 791 ]])], [
 792     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 793     AC_MSG_RESULT([yes])
 794   ], [
 795     AC_MSG_RESULT([no])
 796
 797     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 798     AC_MSG_CHECKING([for __sync_* builtins])
 799     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 800 int main(int argc, char **argv) {
 801   volatile int i = 1;
 802   __sync_fetch_and_sub (&i, 1);
 803   return __sync_val_compare_and_swap (&i, 0, 1);
 804 }
 805 ]])], [
 806       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 807       AC_MSG_RESULT([yes])
 808
 809       AC_MSG_CHECKING([for __sync_swap builtin])
 810       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 811 int main(int argc, char **argv) {
 812   volatile int i = 1;
 813   return __sync_swap (&i, 2);
 814 }
 815 ]])], [
 816         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 817         AC_MSG_RESULT([yes])
 818       ], [
 819         AC_MSG_RESULT([no])
 820       ])
 821
 822     ], [
 823       AC_MSG_RESULT([no])
 824       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 825     ])
 826   ])
 827 ])
 828
 829 dnl Utility macro to avoid retyping includes all the time
 830 m4_define([FRR_INCLUDES],
 831 [#ifdef SUNOS_5
 832 #define _XPG4_2
 833 #define __EXTENSIONS__
 834 #endif
 835 #include <stdio.h>
 836 #include <stdlib.h>
 837 #include <stddef.h>
 838 #include <sys/types.h>
 839 /* sys/conf.h depends on param.h on FBSD at least */
 840 #include <sys/param.h>
 841 /* Required for MAXSIG */
 842 #include <signal.h>
 843 #include <sys/socket.h>
 844 #ifdef __APPLE__
 845 # define __APPLE_USE_RFC_3542
 846 #endif
 847 #include <netinet/in.h>
 848 #include <sys/time.h>
 849 #include <time.h>
 850 #include <net/if.h>
 851 ])dnl
 852
 853 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 854 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 855 dnl an additional round for it.
 856
 857 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 858
 859 m4_define([FRR_INCLUDES],
 860 FRR_INCLUDES
 861 [#if HAVE_NET_IF_VAR_H
 862 # include <net/if_var.h>
 863 #endif
 864 ])dnl
 865
 866 AC_CHECK_HEADERS([netinet/in_var.h \
 867         net/if_dl.h net/netopt.h \
 868         inet/nd.h netinet/ip_icmp.h \
 869         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 870         [], [], FRR_INCLUDES)
 871
 872 AC_CHECK_HEADERS([ucontext.h], [], [],
 873 [#ifndef __USE_GNU
 874 #define __USE_GNU
 875 #endif /* __USE_GNU */
 876 FRR_INCLUDES
 877 ])
 878
 879 m4_define([UCONTEXT_INCLUDES],
 880 [#include <ucontext.h>])dnl
 881
 882 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 883   [], [], [UCONTEXT_INCLUDES])
 884 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 885   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 886    [], [], [UCONTEXT_INCLUDES])],
 887   [], [UCONTEXT_INCLUDES])
 888 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 889   [], [], [UCONTEXT_INCLUDES])
 890
 891 m4_define([FRR_INCLUDES],
 892 FRR_INCLUDES
 893 [
 894 #include <sys/un.h>
 895 #include <netinet/in_systm.h>
 896 #if HAVE_NETINET_IN_VAR_H
 897 # include <netinet/in_var.h>
 898 #endif
 899 #if HAVE_NET_IF_DL_H
 900 # include <net/if_dl.h>
 901 #endif
 902 #if HAVE_NET_NETOPT_H
 903 # include <net/netopt.h>
 904 #endif
 905 #include <net/route.h>
 906 #if HAVE_INET_ND_H
 907 # include <inet/nd.h>
 908 #endif
 909 #include <arpa/inet.h>
 910 /* Required for IDRP */
 911 #if HAVE_NETINET_IP_ICMP_H
 912 # include <netinet/ip_icmp.h>
 913 #endif
 914 ])dnl
 915
 916 dnl V6 headers are checked below, after we check for v6
 917
 918 AC_MSG_CHECKING([which operating system interface to use])
 919 case "$host_os" in
 920   sunos* | solaris2*)
 921     AC_MSG_RESULT([Solaris])
 922
 923     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 924     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 925
 926     AC_CHECK_LIB(socket, main)
 927     AC_CHECK_LIB(nsl, main)
 928     AC_CHECK_LIB(umem, main)
 929     AC_CHECK_FUNCS([printstack], [
 930       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 931       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 932     ])
 933     CURSES=-lcurses
 934     SOLARIS="solaris"
 935     ;;
 936   linux*)
 937     AC_MSG_RESULT([Linux])
 938
 939     AC_DEFINE(GNU_LINUX,,GNU Linux)
 940     AC_DEFINE(HAVE_NETLINK,,netlink)
 941     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 942
 943     dnl Linux has a compilation problem with mixing
 944     dnl netinet/in.h and linux/in6.h they are not
 945     dnl compatible.  There has been discussion on
 946     dnl how to fix it but no real progress on implementation
 947     dnl when they fix it, remove this
 948     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 949     ;;
 950   openbsd*)
 951     AC_MSG_RESULT([OpenBSD])
 952
 953     AC_DEFINE(OPEN_BSD,,OpenBSD)
 954     AC_DEFINE(KAME,1,KAME IPv6)
 955     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 956
 957     if test "x${enable_pimd}" != "xno"; then
 958       case "$host_os" in
 959       openbsd6.0)
 960         ;;
 961       openbsd[6-9]*)
 962         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 963         ;;
 964       esac
 965     fi
 966     ;;
 967   *)
 968     AC_MSG_RESULT([BSD])
 969
 970     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 971     AC_DEFINE(KAME,1,KAME IPv6)
 972     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 973     ;;
 974 esac
 975 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 976
 977 AC_SYS_LARGEFILE
 978
 979 dnl ------------------------
 980 dnl Integrated REALMS option
 981 dnl ------------------------
 982 if test "${enable_realms}" = "yes"; then
 983     case "$host_os" in
 984       linux*)
 985        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 986        ;;
 987       *)
 988        echo "Sorry, only Linux has REALMS support"
 989        exit 1
 990        ;;
 991     esac
 992 fi
 993 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 994
 995 dnl ---------------------
 996 dnl Integrated VTY option
 997 dnl ---------------------
 998 case "${enable_vtysh}" in
 999   "no") VTYSH="";;
1000   *)    VTYSH="vtysh";
1001          AC_DEFINE(VTYSH,,VTY shell)
1002 dnl      Vtysh uses libreadline, which looks for termcap functions at
1003 dnl      configure time.  We follow readlines search order.
1004 dnl      The required procedures are in libtermcap on NetBSD, in
1005 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1006          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1007            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1008              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1009                [AC_CHECK_LIB(ncurses, tputs,
1010                              LIBREADLINE="$LIBREADLINE -lncurses")]
1011               )]
1012             )]
1013           )
1014          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1015                       "$LIBREADLINE")
1016          if test $ac_cv_lib_readline_main = no; then
1017            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1018          fi
1019          AC_CHECK_HEADER(readline/history.h)
1020          if test $ac_cv_header_readline_history_h = no;then
1021            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1022          fi
1023          AC_CHECK_LIB(readline, rl_completion_matches,
1024                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1025          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1026            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1027          fi
1028          ;;
1029 esac
1030 AC_SUBST(LIBREADLINE)
1031 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1032
1033 dnl ----------
1034 dnl PAM module
1035 dnl
1036 dnl FRR detects the PAM library it is built against by checking for a
1037 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1038 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1039 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1040 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1041 dnl of OpenPAM.
1042 dnl ----------
1043 if test "$with_libpam" = "yes"; then
1044   AC_CHECK_HEADER([security/pam_misc.h],
1045     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1046      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1047      pam_conv_func="misc_conv"
1048     ],
1049     [], FRR_INCLUDES)
1050   AC_CHECK_HEADER([security/openpam.h],
1051     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1052      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1053      pam_conv_func="openpam_ttyconv"
1054     ],
1055     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1056   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1057     AC_MSG_WARN([*** pam support will not be built ***])
1058     with_libpam="no"
1059   fi
1060 fi
1061
1062 if test "$with_libpam" = "yes"; then
1063 dnl took this test from proftpds configure.in and suited to our needs
1064 dnl -------------------------------------------------------------------------
1065 dnl
1066 dnl This next check looks funky due to a linker problem with some versions
1067 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1068 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1069 dnl with RedHat 6.2 and Debian 2.2 or better.
1070 AC_CHECK_LIB(pam, pam_start,
1071   [AC_CHECK_LIB(pam, $pam_conv_func,
1072     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1073      LIBPAM="-lpam"],
1074     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1075      LIBPAM="-lpam -lpam_misc"]
1076     )
1077   ],
1078
1079   [AC_CHECK_LIB(pam, pam_end,
1080     [AC_CHECK_LIB(pam, $pam_conv_func,
1081       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1082        LIBPAM="-lpam -ldl"],
1083       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1084        LIBPAM="-lpam -ldl -lpam_misc"]
1085      )
1086   ],AC_MSG_WARN([*** pam support will not be built ***]),
1087   [-ldl])
1088   ]
1089 )
1090 fi
1091 AC_SUBST(LIBPAM)
1092
1093 dnl -------------------------------
1094 dnl Endian-ness check
1095 dnl -------------------------------
1096 AC_WORDS_BIGENDIAN
1097
1098 dnl -------------------------------
1099 dnl check the size in byte of the C
1100 dnl -------------------------------
1101 dnl AC_CHECK_SIZEOF(char)
1102 dnl AC_CHECK_SIZEOF(int)
1103 dnl AC_CHECK_SIZEOF(short)
1104 dnl AC_CHECK_SIZEOF(long)
1105
1106 dnl ----------------------------
1107 dnl check existance of functions
1108 dnl ----------------------------
1109 AC_FUNC_FNMATCH
1110 AC_FUNC_FORK
1111 AC_FUNC_MKTIME
1112 AC_FUNC_STAT
1113
1114 dnl -------------------------------
1115 dnl bgpd needs pow() and hence libm
1116 dnl -------------------------------
1117 TMPLIBS="$LIBS"
1118 AC_CHECK_HEADER([math.h],
1119   [AC_CHECK_LIB([m], [pow],
1120     [LIBM="-lm"
1121      LIBS="$LIBS $LIBM"
1122      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1123     ])
1124 ])
1125 if test x"$LIBM" = x ; then
1126   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1127 fi
1128 LIBS="$TMPLIBS"
1129 AC_SUBST(LIBM)
1130
1131 AC_CHECK_FUNCS([ppoll], [
1132   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1133 ])
1134 AC_CHECK_FUNCS([pollts], [
1135   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1136 ])
1137
1138 dnl ---------------
1139 dnl other functions
1140 dnl ---------------
1141 AC_CHECK_FUNCS([ \
1142         strlcat strlcpy \
1143         getgrouplist])
1144
1145 AC_CHECK_HEADER([asm-generic/unistd.h],
1146                 [AC_CHECK_DECL(__NR_setns,
1147                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1148                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1149                                ])
1150                  AC_CHECK_FUNCS(setns)]
1151                )
1152
1153 dnl --------------------------
1154 dnl Determine IS-IS I/O method
1155 dnl --------------------------
1156 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1157 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1158 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1159 AC_CHECK_HEADER(net/bpf.h)
1160 AC_CHECK_HEADER(sys/dlpi.h)
1161 AC_MSG_CHECKING(zebra IS-IS I/O method)
1162
1163 case "$host_os" in
1164   linux*)
1165     AC_MSG_RESULT(pfpacket)
1166     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1167     ;;
1168   solaris* | sunos*)
1169     AC_MSG_RESULT(DLPI)
1170     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1171     ;;
1172   *)
1173     if test $ac_cv_header_net_bpf_h = no; then
1174       if test $ac_cv_header_sys_dlpi_h = no; then
1175         AC_MSG_RESULT(none)
1176         if test "${enable_isisd}" = yes; then
1177           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1178         fi
1179         AC_MSG_WARN([*** IS-IS support will not be built ***])
1180         enable_isisd="no"
1181       else
1182         AC_MSG_RESULT(DLPI)
1183       fi
1184       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1185     else
1186       AC_MSG_RESULT(BPF)
1187       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1188     fi
1189     ;;
1190 esac
1191 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1192
1193 dnl ---------------------------------------------------------------
1194 dnl figure out how to specify an interface in multicast sockets API
1195 dnl ---------------------------------------------------------------
1196 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1197
1198 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1199         #include <sys/socket.h>
1200         #include <netinet/in.h>
1201         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1202         #include <linux/types.h>
1203 ])
1204
1205 m4_define([FRR_INCLUDES],
1206 FRR_INCLUDES
1207 [#if HAVE_LINUX_MROUTE_H
1208 # include <linux/mroute.h>
1209 #endif
1210 ])dnl
1211
1212 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1213         #include <sys/socket.h>
1214         #include <sys/types.h>
1215         #include <netinet/in.h>
1216         #include <net/route.h>
1217 ])
1218
1219 m4_define([FRR_INCLUDES],
1220 FRR_INCLUDES
1221 [#if HAVE_NETINET_IP_MROUTE_H
1222 # include <netinet/ip_mroute.h>
1223 #endif
1224 ])dnl
1225
1226 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1227 AC_TRY_COMPILE([#include <sys/param.h>],
1228 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1229   return (0);
1230 #else
1231   #error No support for BSD struct ip_mreq hack detected
1232 #endif],[AC_MSG_RESULT(yes)
1233 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1234 AC_MSG_RESULT(no))
1235
1236 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1237 AC_TRY_COMPILE([
1238 #include <sys/types.h>
1239 #include <netinet/in.h>
1240 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1241 ], [AC_MSG_RESULT(yes)
1242 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1243 AC_MSG_RESULT(no))
1244
1245 dnl ---------------------------------------------------------------
1246 dnl figure out how to check link-state
1247 dnl ---------------------------------------------------------------
1248 AC_CHECK_HEADER( [net/if_media.h],
1249   [m4_define([LINK_DETECT_INCLUDES],
1250     FRR_INCLUDES
1251     [#include <net/if_media.h>
1252   ])
1253   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1254     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1255     [], LINK_DETECT_INCLUDES)],
1256   [],
1257   FRR_INCLUDES)
1258
1259 dnl ---------------------------------------------------------------
1260 dnl Additional, newer way to check link-state using ifi_link_state.
1261 dnl Not available in all BSD's when ifmediareq available
1262 dnl ---------------------------------------------------------------
1263 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1264   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1265   [], FRR_INCLUDES)
1266
1267 dnl ------------------------
1268 dnl TCP_MD5SIG socket option
1269 dnl ------------------------
1270
1271 AC_CHECK_HEADER([netinet/tcp.h],
1272    [m4_define([MD5_INCLUDES],
1273       FRR_INCLUDES
1274       [#include <netinet/tcp.h>
1275     ])
1276     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1277    [],
1278    FRR_INCLUDES)
1279 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1280   AC_CHECK_HEADER([linux/tcp.h],
1281        [m4_define([MD5_INCLUDES],
1282           FRR_INCLUDES
1283           [#include <linux/tcp.h>
1284         ])
1285        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1286 fi
1287
1288 dnl ----------------------------------------------------------------------------
1289 dnl figure out if domainname is available in the utsname struct (GNU extension).
1290 dnl ----------------------------------------------------------------------------
1291 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1292
1293 dnl ------------------
1294 dnl IPv6 header checks
1295 dnl ------------------
1296 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1297         netinet6/in6_var.h netinet6/nd6.h], [], [],
1298         FRR_INCLUDES)
1299
1300 m4_define([FRR_INCLUDES],dnl
1301 FRR_INCLUDES
1302 [#if HAVE_NETINET6_IN6_H
1303 #include <netinet6/in6.h>
1304 #endif
1305 #if HAVE_NETINET_IN6_VAR_H
1306 #include <netinet/in6_var.h>
1307 #endif
1308 #include <netinet/icmp6.h>
1309 #if HAVE_NETINET6_IN6_VAR_H
1310 # include <netinet6/in6_var.h>
1311 #endif
1312 #if HAVE_NETINET6_ND6_H
1313 # include <netinet6/nd6.h>
1314 #endif
1315 ])dnl
1316
1317 dnl disable doc check
1318 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [no])
1319 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no")
1320 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" != "no")
1321
1322 dnl --------------------
1323 dnl Daemon disable check
1324 dnl --------------------
1325 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1326
1327 if test "${enable_bgpd}" = "no";then
1328   BGPD=""
1329 else
1330   BGPD="bgpd"
1331 fi
1332 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1333
1334 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1335 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1336 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1337
1338 AS_IF([test "${enable_ldpd}" != "no"], [
1339   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1340 ])
1341
1342 if test "$enable_bfdd" = "no"; then
1343   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1344   BFDD=""
1345 else
1346   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1347   BFDD="bfdd"
1348
1349   case $host_os in
1350     linux*)
1351       AC_DEFINE(BFD_LINUX, 1, bfdd)
1352       ;;
1353
1354     *)
1355       AC_DEFINE(BFD_BSD, 1, bfdd)
1356       ;;
1357   esac
1358 fi
1359
1360 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1361
1362 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1363   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1364 fi
1365
1366 NHRPD=""
1367 case "$host_os" in
1368   linux*)
1369     if test "${enable_nhrpd}" != "no"; then
1370       NHRPD="nhrpd"
1371     fi
1372     ;;
1373   *)
1374     if test "${enable_nhrpd}" = "yes"; then
1375       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1376     fi
1377     ;;
1378 esac
1379 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1380
1381 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1382
1383 if test "${enable_watchfrr}" = "no";then
1384   WATCHFRR=""
1385 else
1386   WATCHFRR="watchfrr"
1387 fi
1388 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1389
1390 OSPFCLIENT=""
1391 if test "${enable_ospfapi}" != "no";then
1392     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1393
1394   if test "${enable_ospfclient}" != "no";then
1395       OSPFCLIENT="ospfclient"
1396   fi
1397 fi
1398
1399 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1400 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1401 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1402 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1403 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1404 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1405 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1406 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1407 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1408
1409 if test "${enable_bgp_announce}" = "no";then
1410   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1411 else
1412   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1413 fi
1414
1415 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1416   with_rfp_path="bgpd/rfp-example"
1417 fi
1418 if test "${with_rfp_path}" != "no"; then
1419   VNC_RFP_PATH="${with_rfp_path}"
1420   AC_SUBST(VNC_RFP_PATH)
1421 fi
1422
1423 if test "${enable_bgp_vnc}" != "no";then
1424   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1425   RFPTEST="${with_rfp_path}/rfptest"
1426   LIBRFP="${with_rfp_path}/librfp"
1427   RFPINC="${with_rfp_path}/librfp"
1428 else
1429   RFPTEST=
1430   LIBRFP=
1431   RFPINC="bgpd/rfp-example/librfp"
1432 fi
1433 # set
1434 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1435
1436 AC_SUBST(RFPTEST)
1437 AC_SUBST(LIBRFP)
1438 AC_SUBST(RFPINC)
1439 AC_SUBST(BGPD)
1440 AC_SUBST(SOLARIS)
1441 AC_SUBST(VTYSH)
1442 AC_SUBST(CURSES)
1443 AC_CHECK_LIB(crypt, crypt, [],
1444                     [AC_CHECK_LIB(crypto, DES_crypt)])
1445 AC_CHECK_LIB(resolv, res_init)
1446
1447 dnl ---------------------------
1448 dnl check system has PCRE regexp
1449 dnl ---------------------------
1450 if test "x$enable_pcreposix" = "xyes"; then
1451   AC_CHECK_LIB(pcreposix, regexec, [], [
1452     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1453   ])
1454 fi
1455 AC_SUBST(HAVE_LIBPCREPOSIX)
1456
1457 dnl ------------------
1458 dnl check C-Ares library
1459 dnl ------------------
1460 if test "${NHRPD}" != ""; then
1461   PKG_CHECK_MODULES([CARES], [libcares], , [
1462     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1463   ])
1464 fi
1465
1466
1467 dnl ------------------
1468 dnl check Net-SNMP library
1469 dnl ------------------
1470 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1471    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1472    if test x"$NETSNMP_CONFIG" = x"no"; then
1473       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1474    fi
1475    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1476    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1477    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1478    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1479 int main(void);
1480 ],
1481 [
1482 {
1483   return 0;
1484 }
1485 ])], [
1486      AC_MSG_ERROR([--enable-snmp given but not usable])])
1487    case "${enable_snmp}" in
1488      yes)
1489       SNMP_METHOD=agentx
1490       ;;
1491      agentx)
1492       SNMP_METHOD="${enable_snmp}"
1493       ;;
1494      *)
1495       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1496       ;;
1497    esac
1498    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1499    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1500 fi
1501 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1502 AC_SUBST(SNMP_LIBS)
1503 AC_SUBST(SNMP_CFLAGS)
1504
1505 dnl ---------------
1506 dnl math
1507 dnl ---------------
1508 AC_SEARCH_LIBS([sqrt], [m])
1509
1510 dnl ---------------
1511 dnl dlopen & dlinfo
1512 dnl ---------------
1513 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1514   AC_MSG_ERROR([unable to find the dlopen()])
1515 ])
1516
1517 AC_CHECK_HEADERS([link.h])
1518
1519 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1520 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1521 #include <stdlib.h>
1522 #ifdef HAVE_LINK_H
1523 #include <link.h>
1524 #endif
1525 #include <dlfcn.h>
1526 ]], [[
1527   char origin[1];
1528   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1529 ]])], [
1530   AC_MSG_RESULT(yes)
1531   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1532 ], [
1533   AC_MSG_RESULT(no)
1534 ])
1535
1536 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1537 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1538 #include <stdlib.h>
1539 #ifdef HAVE_LINK_H
1540 #include <link.h>
1541 #endif
1542 #include <dlfcn.h>
1543 ]], [[
1544   struct link_map *lm = NULL;
1545   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1546 ]])], [
1547   AC_MSG_RESULT(yes)
1548   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1549 ], [
1550   AC_MSG_RESULT(no)
1551 ])
1552
1553
1554 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1555
1556 dnl ---------------------------
1557 dnl sockaddr and netinet checks
1558 dnl ---------------------------
1559 AC_CHECK_TYPES([
1560         struct sockaddr_dl,
1561         struct vifctl, struct mfcctl, struct sioc_sg_req,
1562         vifi_t, struct sioc_vif_req, struct igmpmsg,
1563         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1564         struct nd_opt_adv_interval, struct rt_addrinfo,
1565         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1566         [], [], FRR_INCLUDES)
1567
1568 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1569         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1570         struct sockaddr_dl.sdl_len,
1571         struct if6_aliasreq.ifra_lifetime,
1572         struct nd_opt_adv_interval.nd_opt_ai_type],
1573         [], [], FRR_INCLUDES)
1574
1575 dnl ---------------------------
1576 dnl IRDP/pktinfo/icmphdr checks
1577 dnl ---------------------------
1578
1579 AC_CHECK_TYPES([struct in_pktinfo], [
1580   AC_CHECK_TYPES([struct icmphdr], [
1581     IRDP=true
1582   ], [
1583     IRDP=false
1584   ], [FRR_INCLUDES])
1585 ], [
1586   IRDP=false
1587 ], [FRR_INCLUDES])
1588
1589 case "${enable_irdp}" in
1590 yes)
1591   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1592   ;;
1593 no)
1594   IRDP=false
1595   ;;
1596 esac
1597
1598 AM_CONDITIONAL(IRDP, $IRDP)
1599
1600 dnl -----------------------
1601 dnl checking for IP_PKTINFO
1602 dnl -----------------------
1603 AC_MSG_CHECKING(for IP_PKTINFO)
1604 AC_TRY_COMPILE([#include <netdb.h>], [
1605   int opt = IP_PKTINFO;
1606 ], [
1607   AC_MSG_RESULT(yes)
1608   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1609 ], [
1610   AC_MSG_RESULT(no)
1611 ])
1612
1613 dnl ---------------------------
1614 dnl checking for IP_RECVDSTADDR
1615 dnl ---------------------------
1616 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1617 AC_TRY_COMPILE([#include <netinet/in.h>], [
1618   int opt = IP_RECVDSTADDR;
1619 ], [
1620   AC_MSG_RESULT(yes)
1621   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1622 ], [
1623   AC_MSG_RESULT(no)
1624 ])
1625
1626 dnl ----------------------
1627 dnl checking for IP_RECVIF
1628 dnl ----------------------
1629 AC_MSG_CHECKING(for IP_RECVIF)
1630 AC_TRY_COMPILE([#include <netinet/in.h>], [
1631   int opt = IP_RECVIF;
1632 ], [
1633   AC_MSG_RESULT(yes)
1634   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1635 ], [
1636   AC_MSG_RESULT(no)
1637 ])
1638
1639 dnl ----------------------
1640 dnl checking for SO_BINDANY
1641 dnl ----------------------
1642 AC_MSG_CHECKING(for SO_BINDANY)
1643 AC_TRY_COMPILE([#include <sys/socket.h>], [
1644   int opt = SO_BINDANY;
1645 ], [
1646   AC_MSG_RESULT(yes)
1647   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1648 ], [
1649   AC_MSG_RESULT(no)
1650 ])
1651
1652 dnl ----------------------
1653 dnl checking for IP_FREEBIND
1654 dnl ----------------------
1655 AC_MSG_CHECKING(for IP_FREEBIND)
1656 AC_TRY_COMPILE([#include <netinet/in.h>], [
1657   int opt = IP_FREEBIND;
1658 ], [
1659   AC_MSG_RESULT(yes)
1660   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1661 ], [
1662   AC_MSG_RESULT(no)
1663 ])
1664
1665 dnl --------------------------------------
1666 dnl checking for be32dec existence or not
1667 dnl --------------------------------------
1668 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1669                [#include <sys/endian.h>])
1670
1671 dnl --------------------------------------
1672 dnl checking for clock_time monotonic struct and call
1673 dnl --------------------------------------
1674 AC_CHECK_DECL(CLOCK_MONOTONIC,
1675         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1676          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1677 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1678
1679 dnl --------------------------------------
1680 dnl checking for flex and bison
1681 dnl --------------------------------------
1682
1683 AM_PROG_LEX
1684 AC_MSG_CHECKING(version of flex)
1685 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1686 frr_ac_flex_version="${frr_ac_flex_version##* }"
1687 AC_MSG_RESULT([$frr_ac_flex_version])
1688 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1689   LEX="$SHELL $missing_dir/missing flex"
1690   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1691     AC_MSG_WARN([using pregenerated flex output files])
1692   else
1693     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1694   fi
1695   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1696   AC_SUBST([LEXLIB], [''])
1697 ])
1698
1699 AC_PROG_YACC
1700 dnl thanks GNU bison for this b*llshit...
1701 AC_MSG_CHECKING(version of bison)
1702 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1703 frr_ac_bison_version="${frr_ac_bison_version##* }"
1704 frr_ac_bison_missing="false"
1705 case "x${frr_ac_bison_version}" in
1706   x2.7*)
1707     BISON_OPENBRACE='"'
1708     BISON_CLOSEBRACE='"'
1709     BISON_VERBOSE=''
1710     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1711     ;;
1712   x2.*|x1.*)
1713     AC_MSG_RESULT([$frr_ac_bison_version])
1714     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1715     frr_ac_bison_missing="true"
1716     ;;
1717   x)
1718     AC_MSG_RESULT([none])
1719     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1720     frr_ac_bison_missing="true"
1721     ;;
1722   *)
1723     BISON_OPENBRACE='{'
1724     BISON_CLOSEBRACE='}'
1725     BISON_VERBOSE='-Dparse.error=verbose'
1726     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1727     ;;
1728 esac
1729 AC_SUBST(BISON_OPENBRACE)
1730 AC_SUBST(BISON_CLOSEBRACE)
1731 AC_SUBST(BISON_VERBOSE)
1732
1733 if $frr_ac_bison_missing; then
1734   YACC="$SHELL $missing_dir/missing bison -y"
1735   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1736     AC_MSG_WARN([using pregenerated bison output files])
1737   else
1738     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1739   fi
1740 fi
1741
1742 dnl -------------------
1743 dnl capabilities checks
1744 dnl -------------------
1745 if test "${enable_capabilities}" != "no"; then
1746   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1747   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1748     [AC_MSG_RESULT(yes)
1749      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1750      frr_ac_keepcaps="yes"],
1751      AC_MSG_RESULT(no)
1752   )
1753   if test x"${frr_ac_keepcaps}" = x"yes"; then
1754     AC_CHECK_HEADERS(sys/capability.h)
1755   fi
1756   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1757     AC_CHECK_LIB(cap, cap_init,
1758       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1759        LIBCAP="-lcap"
1760        frr_ac_lcaps="yes"]
1761     )
1762   else
1763     AC_CHECK_HEADERS(priv.h,
1764      [AC_MSG_CHECKING(Solaris style privileges are available)
1765       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1766           [AC_MSG_RESULT(yes)
1767            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1768            frr_ac_scaps="yes"],
1769            AC_MSG_RESULT(no)
1770       )
1771      ]
1772    )
1773   fi
1774   if test x"${frr_ac_scaps}" = x"yes" \
1775        -o x"${frr_ac_lcaps}" = x"yes"; then
1776     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1777   fi
1778 fi
1779 AC_SUBST(LIBCAP)
1780
1781 dnl ---------------------------
1782 dnl check for glibc 'backtrace'
1783 dnl ---------------------------
1784 if test x"${enable_backtrace}" != x"no" ; then
1785   backtrace_ok=no
1786   AC_CHECK_HEADER([execinfo.h], [
1787     AC_SEARCH_LIBS([backtrace], [execinfo], [
1788       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1789       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1790       backtrace_ok=yes
1791     ],, [-lm])
1792   ])
1793
1794   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1795     dnl user explicitly requested backtrace but we failed to find support
1796     AC_MSG_FAILURE([failed to find backtrace support])
1797   fi
1798 fi
1799
1800 dnl -----------------------------------------
1801 dnl check for malloc mallinfo struct and call
1802 dnl this must try and link using LIBS, in
1803 dnl order to check no alternative allocator
1804 dnl has been specified, which might not provide
1805 dnl mallinfo, e.g. such as Umem on Solaris.
1806 dnl -----------------------------------------
1807 AC_CHECK_HEADERS([malloc.h malloc/malloc.h],,, [FRR_INCLUDES])
1808
1809 AC_MSG_CHECKING(whether mallinfo is available)
1810 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1811 #ifdef HAVE_MALLOC_H
1812 #include <malloc.h>
1813 #endif
1814 #ifdef HAVE_MALLOC_MALLOC_H
1815 #include <malloc/malloc.h>
1816 #endif
1817 ]], [[
1818 struct mallinfo ac_x; ac_x = mallinfo ();
1819 ]])], [
1820   AC_MSG_RESULT(yes)
1821   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1822 ], [
1823   AC_MSG_RESULT(no)
1824 ])
1825
1826 AC_MSG_CHECKING(whether malloc_usable_size is available)
1827 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1828 #ifdef HAVE_MALLOC_H
1829 #include <malloc.h>
1830 #endif
1831 #ifdef HAVE_MALLOC_MALLOC_H
1832 #include <malloc/malloc.h>
1833 #endif
1834 ]], [[
1835 size_t ac_x; ac_x = malloc_usable_size(NULL);
1836 ]])], [
1837   AC_MSG_RESULT(yes)
1838   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1839 ], [
1840   AC_MSG_RESULT(no)
1841
1842   AC_MSG_CHECKING(whether malloc_size is available)
1843   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1844 #ifdef HAVE_MALLOC_H
1845 #include <malloc.h>
1846 #endif
1847 #ifdef HAVE_MALLOC_MALLOC_H
1848 #include <malloc/malloc.h>
1849 #endif
1850 ]], [[
1851 size_t ac_x; ac_x = malloc_size(NULL);
1852 ]])], [
1853     AC_MSG_RESULT(yes)
1854     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1855   ], [
1856     AC_MSG_RESULT(no)
1857   ])
1858 ])
1859
1860 dnl ------
1861 dnl ZeroMQ
1862 dnl ------
1863 if test "x$enable_zeromq" != "xno"; then
1864   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1865     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1866     ZEROMQ=true
1867   ], [
1868     if test "x$enable_zeromq" = "xyes"; then
1869       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1870     fi
1871   ])
1872 fi
1873 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1874
1875 dnl ----------
1876 dnl configure date
1877 dnl ----------
1878 dev_version=`echo $VERSION | grep dev`
1879 #don't expire deprecated code in non 'dev' branch
1880 if test "${dev_version}" = ""; then
1881    CONFDATE=0
1882 else
1883    CONFDATE=`date '+%Y%m%d'`
1884 fi
1885 AC_SUBST(CONFDATE)
1886
1887 dnl ------------------------------
1888 dnl set paths for state directory
1889 dnl ------------------------------
1890 AC_MSG_CHECKING(directory to use for state file)
1891 if test "${prefix}" = "NONE"; then
1892   frr_statedir_prefix="";
1893 else
1894   frr_statedir_prefix=${prefix}
1895 fi
1896 if test "${localstatedir}" = '${prefix}/var'; then
1897   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1898                         ${frr_statedir_prefix}/var/adm dnl
1899                         ${frr_statedir_prefix}/etc dnl
1900                         /var/run        dnl
1901                         /var/adm        dnl
1902                         /etc            dnl
1903                         /dev/null;
1904   do
1905     test -d $FRR_STATE_DIR && break
1906   done
1907   frr_statedir=$FRR_STATE_DIR
1908 else
1909   frr_statedir=${localstatedir}
1910 fi
1911 if test $frr_statedir = "/dev/null"; then
1912     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1913 fi
1914 AC_MSG_RESULT(${frr_statedir})
1915 AC_SUBST(frr_statedir)
1916
1917 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1918 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1919 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1920 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1921
1922 dnl autoconf does this, but it does it too late...
1923 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1924 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1925
1926 dnl get the full path, recursing through variables...
1927 vtysh_bin="$bindir/vtysh"
1928 for I in 1 2 3 4 5 6 7 8 9 10; do
1929         eval vtysh_bin="\"$vtysh_bin\""
1930 done
1931 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1932
1933 CFG_SYSCONF="$sysconfdir"
1934 CFG_SBIN="$sbindir"
1935 CFG_STATE="$frr_statedir"
1936 CFG_MODULE="$moduledir"
1937 for I in 1 2 3 4 5 6 7 8 9 10; do
1938         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1939         eval CFG_SBIN="\"$CFG_SBIN\""
1940         eval CFG_STATE="\"$CFG_STATE\""
1941         eval CFG_MODULE="\"$CFG_MODULE\""
1942 done
1943 AC_SUBST(CFG_SYSCONF)
1944 AC_SUBST(CFG_SBIN)
1945 AC_SUBST(CFG_STATE)
1946 AC_SUBST(CFG_MODULE)
1947 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1948
1949 dnl ------------------------------------
1950 dnl Enable RPKI and add librtr to libs
1951 dnl ------------------------------------
1952 if test "${enable_rpki}" = "yes"; then
1953   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1954       [AC_DEFINE(HAVE_RPKI,1,Enable RPKI prefix validation for BGP)
1955       RPKI=true],
1956       [RPKI=false
1957       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1958   )
1959 fi
1960 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1961
1962 dnl ------------------------------------------
1963 dnl Check whether rtrlib was build with ssh support
1964 dnl ------------------------------------------
1965 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1966 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1967                         [[struct tr_ssh_config config;]])],
1968         [AC_MSG_RESULT(yes)
1969         AC_DEFINE(FOUND_SSH,,found_ssh)],
1970         AC_MSG_RESULT(no)
1971 )
1972
1973 dnl ---------------------------
1974 dnl Check htonl works correctly
1975 dnl ---------------------------
1976 AC_MSG_CHECKING(for working htonl)
1977 AC_CACHE_VAL(ac_cv_htonl_works,
1978  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1979                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1980  ]
1981 )
1982 AC_MSG_RESULT($ac_cv_htonl_works)
1983
1984 AC_CONFIG_FILES([Makefile
1985           bgpd/Makefile
1986           vtysh/Makefile
1987           tests/Makefile
1988           bgpd/rfp-example/rfptest/Makefile
1989           bgpd/rfp-example/librfp/Makefile
1990           redhat/frr.spec
1991           debianpkg/Makefile
1992           debianpkg/changelog
1993           alpine/APKBUILD
1994           snapcraft/snapcraft.yaml
1995           lib/version.h
1996           tests/lib/cli/test_cli.refout
1997           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1998           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1999           pkgsrc/eigrpd.sh])
2000
2001 if test "${enable_bgp_vnc}" != "no"; then
2002    if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
2003       AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
2004    fi
2005 fi
2006
2007 AC_CONFIG_FILES([solaris/Makefile])
2008
2009 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2010
2011 AC_CONFIG_COMMANDS([lib/route_types.h], [
2012         dst="${ac_abs_top_builddir}/lib/route_types.h"
2013         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2014                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2015                 > "${dst}.tmp"
2016         test -f "${dst}" \
2017                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2018                 && rm "${dst}.tmp" \
2019                 || mv "${dst}.tmp" "${dst}"
2020 ], [
2021         PERL="$PERL"
2022 ])
2023
2024 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2025     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2026         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2027         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2028                 "${ac_abs_top_srcdir}" \
2029                 > "${dst}.tmp"
2030         test -f "${dst}" \
2031                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2032                 && rm "${dst}.tmp" \
2033                 || mv "${dst}.tmp" "${dst}"
2034     ], [
2035         PERL="$PERL"
2036     ])
2037 ])
2038
2039 ## Hack, but working solution to avoid rebuilding of frr.info.
2040 ## It's already in CVS until texinfo 4.7 is more common.
2041 AC_OUTPUT
2042
2043 echo "
2044 FRRouting configuration
2045 ------------------------------
2046 FRR version             : ${PACKAGE_VERSION}
2047 host operating system   : ${host_os}
2048 source code location    : ${srcdir}
2049 compiler                : ${CC}
2050 compiler flags          : ${CFLAGS}
2051 make                    : ${MAKE-make}
2052 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2053 state file directory    : ${frr_statedir}
2054 config file directory   : `eval echo \`echo ${sysconfdir}\``
2055 example directory       : `eval echo \`echo ${exampledir}\``
2056 module directory        : ${CFG_MODULE}
2057 user to run as          : ${enable_user}
2058 group to run as         : ${enable_group}
2059 group for vty sockets   : ${enable_vty_group}
2060 config file mask        : ${enable_configfile_mask}
2061 log file mask           : ${enable_logfile_mask}
2062 zebra protobuf enabled  : ${have_protobuf:-no}
2063
2064 The above user and group must have read/write access to the state file
2065 directory and to the config files in the config file directory."
2066
2067 if test "${enable_doc}" != "no";then
2068   AS_IF([test "x$SPHINXBUILD" = xno],
2069      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2070 fi