configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.3-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 hosttools_clippy="false"
  29 build_clippy="true"
  30
  31 dnl case 1: external clippy
  32 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  33   if test "$enable_clippy_only" == "yes"; then
  34     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  35   fi
  36
  37   CLIPPY="$with_clippy"
  38   build_clippy="false"
  39   if test ! -x "$with_clippy"; then
  40     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  41   fi
  42
  43 dnl case 2: cross-compiling internal clippy
  44 elif test "$host" != "$build"; then
  45   if test "$srcdir" = "."; then
  46     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  47   fi
  48   test -d hosttools || mkdir hosttools
  49   abssrc="`cd \"${srcdir}\"; pwd`"
  50
  51   AC_MSG_NOTICE([...])
  52   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  53   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  54   AC_MSG_NOTICE([...])
  55
  56   (
  57     for var in $ac_precious_vars; do
  58       dnl special cases
  59       case "$var" in
  60       YACC|YFLAGS) continue;;
  61       PYTHON*)     retain=true;;
  62       *)           retain=false;
  63       esac
  64
  65       eval "hostvar=\"\${HOST_$var}\""
  66       eval "targetvar=\"\${$var}\""
  67       if test -n "$hostvar"; then
  68         eval "$var='$hostvar'"
  69         _AS_ECHO_LOG([host $var='$hostvar'])
  70       elif $retain; then
  71         _AS_ECHO_LOG([host retain $var='$targetvar'])
  72       else
  73         eval "unset $var"
  74         _AS_ECHO_LOG([host unset $var])
  75       fi
  76     done
  77     cd hosttools
  78     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  79   ) || exit 1
  80
  81   AC_MSG_NOTICE([...])
  82   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  83   AC_MSG_NOTICE([...])
  84
  85   build_clippy="false"
  86   hosttools_clippy="true"
  87   CLIPPY="hosttools/lib/clippy"
  88
  89 dnl case 3: normal build internal clippy
  90 else
  91   CLIPPY="lib/clippy\$(EXEEXT)"
  92 fi
  93 AC_SUBST([CLIPPY])
  94 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  95 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
  96 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
  97
  98 # Disable portability warnings -- our automake code (in particular
  99 # common.am) uses some constructs specific to gmake.
 100 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 101 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 102 AM_SILENT_RULES([yes])
 103 AC_CONFIG_HEADERS([config.h])
 104
 105 AC_PATH_PROG([PERL], [perl])
 106 PKG_PROG_PKG_CONFIG
 107
 108 dnl default is to match previous behavior
 109 exampledir=${sysconfdir}
 110 AC_ARG_ENABLE([exampledir],
 111           AS_HELP_STRING([--enable-exampledir],
 112                          [specify alternate directory for examples]),
 113                          exampledir="$enableval",)
 114 dnl XXX add --exampledir to autoconf standard directory list somehow
 115 AC_SUBST([exampledir])
 116
 117 dnl default is to match previous behavior
 118 pkgsrcrcdir=""
 119 AC_ARG_ENABLE([pkgsrcrcdir],
 120           AS_HELP_STRING([--enable-pkgsrcrcdir],
 121                          [specify directory for rc.d scripts]),
 122                          pkgsrcrcdir="$enableval",)
 123 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 124 AC_SUBST([pkgsrcrcdir])
 125 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
 126
 127 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 128         moduledir="$withval"
 129 ], [
 130         moduledir="\${libdir}/frr/modules"
 131 ])
 132 AC_SUBST([moduledir], [$moduledir])
 133
 134
 135 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 136         yangmodelsdir="$withval"
 137 ], [
 138         yangmodelsdir="\${datarootdir}/yang"
 139 ])
 140 AC_SUBST([yangmodelsdir])
 141
 142 AC_ARG_ENABLE(tcmalloc,
 143         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 144 [case "${enableval}" in
 145   yes) tcmalloc_enabled=true
 146 LIBS="$LIBS -ltcmalloc_minimal"
 147  ;;
 148   no)  tcmalloc_enabled=false ;;
 149   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 150 esac],[tcmalloc_enabled=false])
 151
 152
 153 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 154 dnl flag determination logic.
 155 CFLAGS="${CFLAGS:-}"
 156
 157 dnl --------------------
 158 dnl Check CC and friends
 159 dnl --------------------
 160 dnl note orig_cflags is also used further down
 161 orig_cflags="$CFLAGS"
 162 orig_cxxflags="$CXXFLAGS"
 163 AC_LANG([C])
 164 AC_PROG_CC
 165 AC_PROG_CPP
 166 AC_PROG_CXX
 167 AM_PROG_CC_C_O
 168 dnl remove autoconf default "-g -O2"
 169 CFLAGS="$orig_cflags"
 170 CXXFLAGS="$orig_cxxflags"
 171 AC_PROG_CC_C99
 172 dnl NB: see C11 below
 173
 174 PKG_PROG_PKG_CONFIG
 175
 176 dnl it's 2019, sed is sed.
 177 SED=sed
 178 AC_SUBST([SED])
 179
 180 dnl try and enable CFLAGS that are useful for FRR
 181 dnl - specifically, options to control warnings
 182
 183 AC_USE_SYSTEM_EXTENSIONS
 184 AC_DEFUN([AC_C_FLAG], [{
 185     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+],[____])])
 186     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 187         AC_LANG_PUSH([C])
 188         ac_c_flag_save="$CFLAGS"
 189         CFLAGS="$CFLAGS $1"
 190         AC_COMPILE_IFELSE(
 191                 [AC_LANG_PROGRAM([[]])],
 192                 [
 193                         cachename=yes
 194                 ], [
 195                         cachename=no
 196                 ])
 197         CFLAGS="$ac_c_flag_save"
 198         AC_LANG_POP([C])
 199     ])
 200     if test "${cachename}" = yes; then
 201         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 202     else
 203         :
 204         $2
 205     fi
 206     m4_popdef([cachename])
 207 }])
 208
 209 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 210         AC_LANG_PUSH([C])
 211         ac_cflags_save="$CFLAGS"
 212         ac_libs_save="$LIBS"
 213         CFLAGS="$CFLAGS $1"
 214         LIBS="$LIBS $2"
 215         AC_LINK_IFELSE(
 216                 [$3],
 217                 [
 218                         CFLAGS="$ac_cflags_save"
 219                         LIBS="$ac_libs_save"
 220                         m4_default([$5], [
 221                                 AC_MSG_RESULT([yes])
 222                         ])
 223                 ], [
 224                         CFLAGS="$ac_cflags_save"
 225                         LIBS="$ac_libs_save"
 226                         m4_default([$4], [
 227                                 AC_MSG_RESULT([no])
 228                         ])
 229                 ])
 230         AC_LANG_POP([C])
 231         }])
 232
 233 dnl ICC won't bail on unknown options without -diag-error 10006
 234 dnl need to do this first so we get useful results for the other options
 235 AC_C_FLAG([-diag-error 10006])
 236
 237 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 238 ac_cc="$CC"
 239 CC="${CC% -std=gnu99}"
 240 CC="${CC% -std=c99}"
 241
 242 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 243
 244 dnl if the user has specified any CFLAGS, override our settings
 245 if test "x${enable_gcov}" = "xyes"; then
 246    if test "z$orig_cflags" = "z"; then
 247       AC_C_FLAG([-coverage])
 248       AC_C_FLAG([-O0])
 249    fi
 250
 251    LDFLAGS="${LDFLAGS} -lgcov"
 252 elif test "x${enable_dev_build}" = "xyes"; then
 253    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 254    if test "z$orig_cflags" = "z"; then
 255       AC_C_FLAG([-g3])
 256       AC_C_FLAG([-O0])
 257    fi
 258    if test "x${enable_lua}" = "xyes"; then
 259       AX_PROG_LUA([5.3])
 260       AX_LUA_HEADERS
 261       AX_LUA_LIBS([
 262          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 263          LIBS="$LIBS $LUA_LIB"
 264       ])
 265    fi
 266 else
 267    if test "x${enable_lua}" = "xyes"; then
 268       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 269    fi
 270    if test "z$orig_cflags" = "z"; then
 271       AC_C_FLAG([-g])
 272       AC_C_FLAG([-O2])
 273    fi
 274 fi
 275 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 276
 277 dnl always want these CFLAGS
 278 AC_C_FLAG([-fno-omit-frame-pointer])
 279 AC_C_FLAG([-funwind-tables])
 280 AC_C_FLAG([-Wall])
 281 AC_C_FLAG([-Wextra])
 282 AC_C_FLAG([-Wmissing-prototypes])
 283 AC_C_FLAG([-Wmissing-declarations])
 284 AC_C_FLAG([-Wpointer-arith])
 285 AC_C_FLAG([-Wbad-function-cast])
 286 AC_C_FLAG([-Wwrite-strings])
 287 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 288   AC_C_FLAG([-Wcast-qual])
 289   AC_C_FLAG([-Wstrict-prototypes])
 290   AC_C_FLAG([-Wmissing-noreturn])
 291   AC_C_FLAG([-Wmissing-format-attribute])
 292   AC_C_FLAG([-Wunreachable-code])
 293   AC_C_FLAG([-Wpacked])
 294   AC_C_FLAG([-Wpadded])
 295   AC_C_FLAG([-Wshadow])
 296 else
 297   AC_C_FLAG([-Wno-unused-result])
 298 fi
 299 AC_C_FLAG([-Wno-unused-parameter])
 300 AC_C_FLAG([-Wno-missing-field-initializers])
 301
 302 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 303 AC_SUBST([CXX_COMPAT_CFLAGS])
 304
 305 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 306 dnl for some reason the string consts get 'promoted' to char *,
 307 dnl triggering a const to non-const conversion warning.
 308 AC_C_FLAG([-diag-disable 3179])
 309
 310 if test x"${enable_werror}" = x"yes" ; then
 311   WERROR="-Werror"
 312 fi
 313 AC_SUBST([WERROR])
 314
 315 SAN_FLAGS=""
 316 if test "$enable_address_sanitizer" = "yes"; then
 317   AC_C_FLAG([-fsanitize=address], [
 318     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 319   ], [
 320     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 321   ])
 322 fi
 323 if test "$enable_thread_sanitizer" = "yes"; then
 324   AC_C_FLAG([-fsanitize=thread], [
 325     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 326   ], [
 327     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 328   ])
 329 fi
 330 if test "$enable_memory_sanitizer" = "yes"; then
 331   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 332     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 333   ], [
 334     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 335   ])
 336 fi
 337 if test "$enable_undefined_sanitizer" = "yes"; then
 338   AC_C_FLAG([-fsanitize=undefined], [
 339     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 340   ], [
 341     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 342   ])
 343 fi
 344 AC_SUBST([SAN_FLAGS])
 345
 346 dnl ----------
 347 dnl Essentials
 348 dnl ----------
 349
 350 AX_PTHREAD([
 351   CC="$PTHREAD_CC"
 352   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 353   LIBS="$PTHREAD_LIBS $LIBS"
 354 ], [
 355   AC_MSG_FAILURE([This FRR version needs pthreads])
 356 ])
 357
 358 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 359                 [frr_cv_pthread_condattr_setclock=yes],
 360                 [frr_cv_pthread_condattr_setclock=no])
 361 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 362   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 363 fi
 364
 365 dnl --------------
 366 dnl Check programs
 367 dnl --------------
 368 AC_PROG_INSTALL
 369 AC_PROG_LN_S
 370 AC_CHECK_TOOL([AR], [ar])
 371
 372 dnl -------
 373 dnl libtool
 374 dnl -------
 375 AC_ARG_ENABLE([static-bin],
 376   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 377 LT_INIT
 378 _LT_CONFIG_LIBTOOL([
 379   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 380     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 381 ])
 382 if test "$enable_static_bin" = "yes"; then
 383   AC_LDFLAGS="-static"
 384   if test "$enable_static" != "yes"; then
 385     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 386   fi
 387 fi
 388 if test "$enable_shared" != "yes"; then
 389   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 390 fi
 391 AC_SUBST([AC_LDFLAGS])
 392 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 393
 394 dnl $AR and $RANLIB are set by LT_INIT above
 395 AC_MSG_CHECKING([whether $AR supports D option])
 396 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 397   AC_MSG_RESULT([yes])
 398   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 399   ARFLAGS="crD"
 400   AR_FLAGS="crD"
 401 else
 402   AC_MSG_RESULT([no])
 403   ARFLAGS="cru"
 404   AR_FLAGS="cru"
 405 fi
 406 AC_SUBST([ARFLAGS])
 407 AC_SUBST([AR_FLAGS])
 408
 409 AC_MSG_CHECKING([whether $RANLIB supports D option])
 410 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 411   if grep -q -- '-D' conftest.err; then
 412     AC_MSG_RESULT([no])
 413   else
 414     AC_MSG_RESULT([yes])
 415     RANLIB="$RANLIB -D"
 416   fi
 417 else
 418   AC_MSG_RESULT([no])
 419 fi
 420 AC_SUBST([RANLIB])
 421
 422 test -f conftest.err && rm conftest.err
 423 test -f conftest.a && rm conftest.a
 424
 425 dnl ----------------------
 426 dnl Packages configuration
 427 dnl ----------------------
 428 if test -f config.version; then
 429   . ./config.version
 430 elif test -f "${srcdir}/config.version"; then
 431   . "${srcdir}/config.version"
 432 fi
 433 AC_ARG_WITH([pkg-extra-version],
 434   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 435   if test "$withval" = "no"; then
 436     EXTRAVERSION=
 437   else
 438     EXTRAVERSION=$withval
 439   fi
 440 ], [])
 441 AC_ARG_WITH([pkg-git-version],
 442         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 443         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 444 AC_ARG_WITH([clippy],
 445   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 446 AC_ARG_WITH([vtysh_pager],
 447         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 448         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 449 AC_ARG_ENABLE([vtysh],
 450   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 451 AC_ARG_ENABLE([doc],
 452   AS_HELP_STRING([--disable-doc], [do not build docs]))
 453 AC_ARG_ENABLE([doc-html],
 454   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 455 AC_ARG_ENABLE([zebra],
 456   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 457 AC_ARG_ENABLE([bgpd],
 458   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 459 AC_ARG_ENABLE([ripd],
 460   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 461 AC_ARG_ENABLE([ripngd],
 462   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 463 AC_ARG_ENABLE([ospfd],
 464   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 465 AC_ARG_ENABLE([ospf6d],
 466   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 467 AC_ARG_ENABLE([ldpd],
 468   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 469 AC_ARG_ENABLE([nhrpd],
 470   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 471 AC_ARG_ENABLE([eigrpd],
 472   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 473 AC_ARG_ENABLE([babeld],
 474   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 475 AC_ARG_ENABLE([watchfrr],
 476   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 477 AC_ARG_ENABLE([isisd],
 478   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 479 AC_ARG_ENABLE([pimd],
 480   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 481 AC_ARG_ENABLE([pbrd],
 482   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 483 AC_ARG_ENABLE([sharpd],
 484   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 485 AC_ARG_ENABLE([staticd],
 486   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 487 AC_ARG_ENABLE([fabricd],
 488   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 489 AC_ARG_ENABLE([vrrpd],
 490   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 491 AC_ARG_ENABLE([bgp-announce],
 492   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 493 AC_ARG_ENABLE([bgp-vnc],
 494   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 495 AC_ARG_ENABLE([bgp-bmp],
 496   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 497 AC_ARG_ENABLE([snmp],
 498   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 499 AC_ARG_ENABLE([config_rollbacks],
 500   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 501 AC_ARG_ENABLE([confd],
 502   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 503 AC_ARG_ENABLE([sysrepo],
 504   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 505 AC_ARG_ENABLE([grpc],
 506   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 507 AC_ARG_ENABLE([zeromq],
 508   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 509 AC_ARG_WITH([libpam],
 510   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 511 AC_ARG_ENABLE([ospfapi],
 512   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 513 AC_ARG_ENABLE([ospfclient],
 514   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 515                           (this is the default if --disable-ospfapi is set)]))
 516 AC_ARG_ENABLE([multipath],
 517   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 518 AC_ARG_ENABLE([user],
 519   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 520 AC_ARG_ENABLE([group],
 521   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 522 AC_ARG_ENABLE([vty_group],
 523   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 524 AC_ARG_ENABLE([configfile_mask],
 525   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 526 AC_ARG_ENABLE([logfile_mask],
 527   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 528 AC_ARG_ENABLE([shell_access],
 529   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 530 AC_ARG_ENABLE([realms],
 531   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 532 AC_ARG_ENABLE([rtadv],
 533   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 534 AC_ARG_ENABLE([irdp],
 535   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 536 AC_ARG_ENABLE([capabilities],
 537   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 538 AC_ARG_ENABLE([rusage],
 539   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 540 AC_ARG_ENABLE([gcc_ultra_verbose],
 541   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 542 AC_ARG_ENABLE([backtrace],
 543   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 544 AC_ARG_ENABLE([time-check],
 545   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 546 AC_ARG_ENABLE([cpu-time],
 547   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 548 AC_ARG_ENABLE([pcreposix],
 549   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 550 AC_ARG_ENABLE([fpm],
 551   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 552 AC_ARG_ENABLE([systemd],
 553   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 554 AC_ARG_ENABLE([werror],
 555   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 556 AC_ARG_ENABLE([cumulus],
 557   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 558 AC_ARG_ENABLE([datacenter],
 559   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 560 AC_ARG_ENABLE([fuzzing],
 561   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 562 AC_ARG_ENABLE([netlink_fuzzing],
 563   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 564 AC_ARG_ENABLE([rr-semantics],
 565   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 566 AC_ARG_ENABLE([protobuf],
 567   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 568 AC_ARG_ENABLE([oldvpn_commands],
 569   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 570 AC_ARG_ENABLE([rpki],
 571   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 572 AC_ARG_ENABLE([clippy-only],
 573   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 574 AC_ARG_ENABLE([numeric_version],
 575   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 576 AC_ARG_ENABLE([gcov],
 577   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 578 AC_ARG_ENABLE([bfdd],
 579   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 580 AC_ARG_ENABLE([address-sanitizer],
 581   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 582 AC_ARG_ENABLE([thread-sanitizer],
 583   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 584 AC_ARG_ENABLE([memory-sanitizer],
 585   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 586 AC_ARG_ENABLE([undefined-sanitizer],
 587   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 588 AC_ARG_WITH([crypto],
 589   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 590
 591 #if openssl, else use the internal
 592 AS_IF([test x"${with_crypto}" = x"openssl"], [
 593 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 594 if test $ac_cv_lib_crypto_EVP_DigestInit = no; then
 595   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 596 else
 597   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 598 fi
 599 ], [test x"${with_crypto}" = x"internal" || test x"${with_crypto}" = x"" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 600 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 601 )
 602
 603 AS_IF([test "${enable_clippy_only}" != "yes"], [
 604 AC_CHECK_HEADERS([json-c/json.h])
 605 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 606 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 607   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 608   if test "$ac_cv_lib_json_json_object_get" = no; then
 609       AC_MSG_ERROR([libjson is needed to compile])
 610   fi
 611 fi
 612 ])
 613
 614 AC_ARG_ENABLE([dev_build],
 615     AS_HELP_STRING([--enable-dev-build], [build for development]))
 616
 617 AC_ARG_ENABLE([lua],
 618     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 619
 620 if test x"${enable_time_check}" != x"no" ; then
 621   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 622     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 623   else
 624     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 625   fi
 626 fi
 627
 628 case "${enable_cpu_time}" in
 629   "no")
 630   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 631   ;;
 632   "*")
 633   ;;
 634 esac
 635
 636 case "${enable_systemd}" in
 637   "no") ;;
 638   "yes")
 639   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 640   if test $ac_cv_lib_systemd_sd_notify = no; then
 641     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 642   else
 643     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 644   fi
 645   ;;
 646   "*") ;;
 647 esac
 648
 649 if test "${enable_rr_semantics}" != "no" ; then
 650   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 651 fi
 652
 653 if test "${enable_datacenter}" = "yes" ; then
 654   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 655   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 656   DFLT_NAME="datacenter"
 657 else
 658   DFLT_NAME="traditional"
 659 fi
 660
 661 if test "${enable_fuzzing}" = "yes" ; then
 662   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 663 fi
 664
 665 if test "${enable_netlink_fuzzing}" = "yes" ; then
 666   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 667 fi
 668
 669 if test "${enable_cumulus}" = "yes" ; then
 670   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 671 fi
 672
 673 AC_SUBST([DFLT_NAME])
 674 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 675
 676 if test "${enable_shell_access}" = "yes"; then
 677    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 678 fi
 679
 680 #
 681 # Python for clippy
 682 #
 683
 684 AS_IF([test "$host" = "$build"], [
 685   FRR_PYTHON_DEV
 686 ], [
 687   FRR_PYTHON
 688 ])
 689
 690 FRR_PYTHON_MODULES([pytest])
 691
 692 if test "${enable_doc}" != "no"; then
 693   FRR_PYTHON_MODULES([sphinx], , [
 694     if test "${enable_doc}" = "yes"; then
 695       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 696     fi
 697   ])
 698 fi
 699 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" != "false"])
 700 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
 701
 702 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 703   PYSPHINX="-m sphinx"
 704 ], [
 705   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 706 ])
 707 AC_SUBST([PYSPHINX])
 708
 709 #
 710 # Logic for old vpn commands support.
 711 #
 712 if test "$enable_oldvpn_commands" = "yes"; then
 713    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 714 fi
 715
 716 #
 717 # End of logic for protobuf support.
 718 #
 719
 720 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 721 if test "${enable_rtadv}" != "no"; then
 722   AC_MSG_RESULT([yes])
 723   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 724 else
 725   AC_MSG_RESULT([no])
 726 fi
 727
 728 if test x"${enable_user}" = x"no"; then
 729   enable_user=""
 730 else
 731   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 732     enable_user="frr"
 733   fi
 734   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 735 fi
 736
 737 if test x"${enable_group}" = x"no"; then
 738   enable_group=""
 739 else
 740   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 741     enable_group="frr"
 742   fi
 743   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 744 fi
 745
 746 if test x"${enable_vty_group}" = x"yes" ; then
 747   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 748 elif test x"${enable_vty_group}" != x""; then
 749   if test x"${enable_vty_group}" != x"no"; then
 750     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 751   fi
 752 fi
 753 AC_SUBST([enable_user])
 754 AC_SUBST([enable_group])
 755 AC_SUBST([enable_vty_group])
 756
 757 enable_configfile_mask=${enable_configfile_mask:-0600}
 758 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 759
 760 enable_logfile_mask=${enable_logfile_mask:-0600}
 761 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 762
 763 MPATH_NUM=16
 764
 765 case "${enable_multipath}" in
 766   0)
 767     MPATH_NUM=64
 768     ;;
 769   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 770     MPATH_NUM="${enable_multipath}"
 771     ;;
 772   "")
 773     ;;
 774   *)
 775     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 776     ;;
 777 esac
 778
 779 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 780
 781 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 782
 783 dnl --------------------
 784 dnl Enable code coverage
 785 dnl --------------------
 786 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 787
 788 dnl ------------------------------------
 789 dnl Alpine only accepts numeric versions
 790 dnl ------------------------------------
 791 if test "x${enable_numeric_version}" != "x" ; then
 792   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 793   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 794 fi
 795
 796 dnl -----------------------------------
 797 dnl Add extra version string to package
 798 dnl name, string and version fields.
 799 dnl -----------------------------------
 800 if test "x${EXTRAVERSION}" != "x" ; then
 801   VERSION="${VERSION}${EXTRAVERSION}"
 802   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 803   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 804   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 805 fi
 806 AC_SUBST([EXTRAVERSION])
 807
 808 if test "x$with_pkg_git_version" = "xyes"; then
 809         if test -d "${srcdir}/.git"; then
 810                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 811         else    with_pkg_git_version="no"
 812                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 813         fi
 814 fi
 815 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 816
 817 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 818 if test "x${OBJCOPY}" != "x:"; then
 819   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 820     frr_cv_interp=""
 821     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 822       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 823         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 824       fi
 825       test -f conftest.interp && rm conftest.interp
 826     ])
 827   ])
 828 fi
 829 if test -n "$frr_cv_interp"; then
 830   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 831 fi
 832
 833 dnl -------------------------
 834 dnl Check other header files.
 835 dnl -------------------------
 836 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 837         linux/version.h asm/types.h])
 838
 839 ac_stdatomic_ok=false
 840 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 841 AC_CHECK_HEADER([stdatomic.h],[
 842
 843   AC_MSG_CHECKING([whether _Atomic qualifier works])
 844   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 845 #include <stdatomic.h>
 846 int main(int argc, char **argv) {
 847   _Atomic int i = 0;
 848   return i;
 849 }
 850 ]])], [
 851     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 852     AC_MSG_RESULT([yes])
 853     ac_stdatomic_ok=true
 854   ], [
 855     AC_MSG_RESULT([no])
 856   ])
 857 ])
 858
 859 AS_IF([$ac_stdatomic_ok], [true], [
 860   AC_MSG_CHECKING([for __atomic_* builtins])
 861   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 862 int main(int argc, char **argv) {
 863   volatile int i = 1;
 864   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 865   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 866 }
 867 ]])], [
 868     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 869     AC_MSG_RESULT([yes])
 870   ], [
 871     AC_MSG_RESULT([no])
 872
 873     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 874     AC_MSG_CHECKING([for __sync_* builtins])
 875     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 876 int main(int argc, char **argv) {
 877   volatile int i = 1;
 878   __sync_fetch_and_sub (&i, 1);
 879   return __sync_val_compare_and_swap (&i, 0, 1);
 880 }
 881 ]])], [
 882       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 883       AC_MSG_RESULT([yes])
 884
 885       AC_MSG_CHECKING([for __sync_swap builtin])
 886       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 887 int main(int argc, char **argv) {
 888   volatile int i = 1;
 889   return __sync_swap (&i, 2);
 890 }
 891 ]])], [
 892         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 893         AC_MSG_RESULT([yes])
 894       ], [
 895         AC_MSG_RESULT([no])
 896       ])
 897
 898     ], [
 899       AC_MSG_RESULT([no])
 900       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 901     ])
 902   ])
 903 ])
 904
 905 AC_CHECK_HEADERS([pthread_np.h],,, [
 906 #include <pthread.h>
 907 ])
 908 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 909
 910 needsync=true
 911
 912 AS_IF([$needsync], [
 913   dnl Linux
 914   AC_MSG_CHECKING([for Linux futex() support])
 915   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 916 #ifndef _GNU_SOURCE
 917 #define _GNU_SOURCE
 918 #endif
 919 #include <unistd.h>
 920 #include <limits.h>
 921 #include <sys/time.h>
 922 #include <sys/syscall.h>
 923 #include <linux/futex.h>
 924
 925 int main(void);
 926 ],
 927 [
 928 {
 929   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 930 }
 931 ])], [
 932     AC_MSG_RESULT([yes])
 933     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 934     needsync=false
 935   ], [
 936     AC_MSG_RESULT([no])
 937   ])
 938 ])
 939
 940 AS_IF([$needsync], [
 941   dnl FreeBSD
 942   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 943   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 944 #include <errno.h>
 945 #include <stdlib.h>
 946 #include <sys/types.h>
 947 #include <sys/umtx.h>
 948 int main(void);
 949 ],
 950 [
 951 {
 952   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
 953 }
 954 ])], [
 955     AC_MSG_RESULT([yes])
 956     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
 957     needsync=false
 958   ], [
 959     AC_MSG_RESULT([no])
 960   ])
 961 ])
 962
 963 AS_IF([$needsync], [
 964   dnl OpenBSD patch (not upstream at the time of writing this)
 965   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
 966   AC_MSG_CHECKING([for OpenBSD futex() support])
 967   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 968 #include <sys/futex.h>
 969 int main(void);
 970 ],
 971 [
 972 {
 973   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 974 }
 975 ])], [
 976     AC_MSG_RESULT([yes])
 977     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
 978     needsync=false
 979   ], [
 980     AC_MSG_RESULT([no])
 981   ])
 982 ])
 983
 984 dnl Utility macro to avoid retyping includes all the time
 985 m4_define([FRR_INCLUDES],
 986 [#ifdef SUNOS_5
 987 #define _POSIX_C_SOURCE 200809L
 988 #define __EXTENSIONS__
 989 #endif
 990 #include <stdio.h>
 991 #include <stdlib.h>
 992 #include <stddef.h>
 993 #include <sys/types.h>
 994 /* sys/conf.h depends on param.h on FBSD at least */
 995 #include <sys/param.h>
 996 /* Required for MAXSIG */
 997 #include <signal.h>
 998 #include <sys/socket.h>
 999 #ifdef __APPLE__
1000 # define __APPLE_USE_RFC_3542
1001 #endif
1002 #include <netinet/in.h>
1003 #include <sys/time.h>
1004 #include <time.h>
1005 #include <net/if.h>
1006 ])dnl
1007
1008 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1009 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1010 dnl an additional round for it.
1011
1012 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1013
1014 m4_define([FRR_INCLUDES],
1015 FRR_INCLUDES
1016 [#if HAVE_NET_IF_VAR_H
1017 # include <net/if_var.h>
1018 #endif
1019 ])dnl
1020
1021 AC_CHECK_HEADERS([netinet/in_var.h \
1022         net/if_dl.h net/netopt.h \
1023         inet/nd.h netinet/ip_icmp.h \
1024         sys/sysctl.h sys/sockio.h sys/conf.h],
1025         [], [], [FRR_INCLUDES])
1026
1027 AC_CHECK_HEADERS([ucontext.h], [], [],
1028 [#ifndef __USE_GNU
1029 #define __USE_GNU
1030 #endif /* __USE_GNU */
1031 FRR_INCLUDES
1032 ])
1033
1034 m4_define([UCONTEXT_INCLUDES],
1035 [#include <ucontext.h>])dnl
1036
1037 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1038   [], [], [UCONTEXT_INCLUDES])
1039 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1040   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1041    [], [], [UCONTEXT_INCLUDES])],
1042   [], [UCONTEXT_INCLUDES])
1043 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1044   [], [], [UCONTEXT_INCLUDES])
1045
1046 m4_define([FRR_INCLUDES],
1047 FRR_INCLUDES
1048 [
1049 #include <sys/un.h>
1050 #include <netinet/in_systm.h>
1051 #if HAVE_NETINET_IN_VAR_H
1052 # include <netinet/in_var.h>
1053 #endif
1054 #if HAVE_NET_IF_DL_H
1055 # include <net/if_dl.h>
1056 #endif
1057 #if HAVE_NET_NETOPT_H
1058 # include <net/netopt.h>
1059 #endif
1060 #include <net/route.h>
1061 #if HAVE_INET_ND_H
1062 # include <inet/nd.h>
1063 #endif
1064 #include <arpa/inet.h>
1065 /* Required for IDRP */
1066 #if HAVE_NETINET_IP_ICMP_H
1067 # include <netinet/ip_icmp.h>
1068 #endif
1069 ])dnl
1070
1071 dnl V6 headers are checked below, after we check for v6
1072
1073 is_linux=false
1074
1075 AC_MSG_CHECKING([which operating system interface to use])
1076 case "$host_os" in
1077   sunos* | solaris2*)
1078     AC_MSG_RESULT([Solaris])
1079
1080     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1081     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1082     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1083
1084     AC_CHECK_LIB([socket], [main])
1085     AC_CHECK_LIB([nsl], [main])
1086     AC_CHECK_LIB([umem], [main])
1087     SOLARIS="solaris"
1088     AC_MSG_WARN([--Solaris support is being considered for deprecation, please let us know if you are still using this--])
1089     ;;
1090   linux*)
1091     AC_MSG_RESULT([Linux])
1092
1093     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1094     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1095     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1096
1097     dnl Linux has a compilation problem with mixing
1098     dnl netinet/in.h and linux/in6.h they are not
1099     dnl compatible.  There has been discussion on
1100     dnl how to fix it but no real progress on implementation
1101     dnl when they fix it, remove this
1102     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1103
1104     is_linux=true
1105     ;;
1106   openbsd*)
1107     AC_MSG_RESULT([OpenBSD])
1108
1109     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1110     AC_DEFINE([KAME], [1], [KAME IPv6])
1111     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1112
1113     if test "x${enable_pimd}" != "xno"; then
1114       case "$host_os" in
1115       openbsd6.0)
1116         ;;
1117       openbsd[6-9]*)
1118         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1119         ;;
1120       esac
1121     fi
1122     ;;
1123   *)
1124     AC_MSG_RESULT([BSD])
1125
1126     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1127     AC_DEFINE([KAME], [1], [KAME IPv6])
1128     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1129     ;;
1130 esac
1131 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1132 AM_CONDITIONAL([LINUX], [${is_linux}])
1133
1134 AC_SYS_LARGEFILE
1135
1136 dnl ------------------------
1137 dnl Integrated REALMS option
1138 dnl ------------------------
1139 if test "${enable_realms}" = "yes"; then
1140     case "$host_os" in
1141       linux*)
1142        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1143        ;;
1144       *)
1145        echo "Sorry, only Linux has REALMS support"
1146        exit 1
1147        ;;
1148     esac
1149 fi
1150
1151 dnl -------------------------------
1152 dnl Endian-ness check
1153 dnl -------------------------------
1154 AC_WORDS_BIGENDIAN
1155
1156 dnl ---------------
1157 dnl other functions
1158 dnl ---------------
1159 AC_CHECK_FUNCS([ \
1160         strlcat strlcpy \
1161         getgrouplist])
1162
1163 dnl ##########################################################################
1164 dnl LARGE if block spans a lot of "configure"!
1165 if test "${enable_clippy_only}" != "yes"; then
1166 dnl ##########################################################################
1167
1168 #
1169 # Logic for protobuf support.
1170 #
1171 PROTO3=false
1172 if test "$enable_protobuf" = "yes"; then
1173   # Check for protoc & protoc-c
1174
1175   # protoc is not required, it's only for a "be nice" helper target
1176   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1177
1178   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1179   if test "$PROTOC_C" = "/bin/false"; then
1180     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1181   fi
1182
1183   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1184     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1185   ])
1186
1187   PROTO3=true
1188   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1189                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1190                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1191                                             [1], [Have Protobuf version 3]),
1192                                   [PROTO3=false],
1193                                   [#include <google/protobuf-c/protobuf-c.h>])],
1194                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1195
1196   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1197 fi
1198
1199
1200 dnl ---------------------
1201 dnl Integrated VTY option
1202 dnl ---------------------
1203 case "${enable_vtysh}" in
1204 "no")
1205   VTYSH="";;
1206 *)
1207   VTYSH="vtysh";
1208   AC_DEFINE([VTYSH], [1], [VTY shell])
1209
1210   prev_libs="$LIBS"
1211   AC_CHECK_LIB([readline], [main], [
1212     LIBREADLINE="-lreadline"
1213   ], [
1214     dnl readline failed - it might be incorrectly linked and missing its
1215     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1216     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1217       LIBREADLINE="$ac_cv_search_tputs"
1218     ], [
1219       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1220     ])
1221
1222     dnl re-try with the lib we found above
1223     unset ac_cv_lib_readline_main
1224     AC_CHECK_LIB([readline], [main], [
1225       LIBREADLINE="-lreadline $LIBREADLINE"
1226     ], [
1227       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1228     ], [$LIBREADLINE])
1229   ], [])
1230   LIBS="$prev_libs"
1231
1232   AC_CHECK_HEADER([readline/history.h])
1233   if test $ac_cv_header_readline_history_h = no;then
1234     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1235   fi
1236   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1237   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1238     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1239   fi
1240   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1241   if test "$frr_cv_append_history" = yes; then
1242     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1243   fi
1244   ;;
1245 esac
1246 AC_SUBST([LIBREADLINE])
1247
1248 dnl ----------
1249 dnl PAM module
1250 dnl
1251 dnl FRR detects the PAM library it is built against by checking for a
1252 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1253 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1254 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1255 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1256 dnl of OpenPAM.
1257 dnl ----------
1258 if test "$with_libpam" = "yes"; then
1259   AC_CHECK_HEADER([security/pam_misc.h],
1260     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1261      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1262      pam_conv_func="misc_conv"
1263     ],
1264     [], FRR_INCLUDES)
1265   AC_CHECK_HEADER([security/openpam.h],
1266     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1267      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1268      pam_conv_func="openpam_ttyconv"
1269     ],
1270     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1271   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1272     AC_MSG_WARN([*** pam support will not be built ***])
1273     with_libpam="no"
1274   fi
1275 fi
1276
1277 if test "$with_libpam" = "yes"; then
1278 dnl took this test from proftpds configure.in and suited to our needs
1279 dnl -------------------------------------------------------------------------
1280 dnl
1281 dnl This next check looks funky due to a linker problem with some versions
1282 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1283 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1284 dnl with RedHat 6.2 and Debian 2.2 or better.
1285 AC_CHECK_LIB([pam], [pam_start],
1286   [AC_CHECK_LIB([pam], [$pam_conv_func],
1287     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1288      LIBPAM="-lpam"],
1289     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1290      LIBPAM="-lpam -lpam_misc"]
1291     )
1292   ],
1293
1294   [AC_CHECK_LIB([pam], [pam_end],
1295     [AC_CHECK_LIB([pam], [$pam_conv_func],
1296       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1297        LIBPAM="-lpam -ldl"],
1298       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1299        LIBPAM="-lpam -ldl -lpam_misc"]
1300      )
1301   ],AC_MSG_WARN([*** pam support will not be built ***]),
1302   [-ldl])
1303   ]
1304 )
1305 fi
1306 AC_SUBST([LIBPAM])
1307
1308 dnl -------------------------------
1309 dnl bgpd needs pow() and hence libm
1310 dnl -------------------------------
1311 TMPLIBS="$LIBS"
1312 LIBS=""
1313 AC_SEARCH_LIBS([pow], [m], [
1314   LIBM="$LIBS"
1315 ], [
1316   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1317 ])
1318 LIBS="$TMPLIBS"
1319 AC_SUBST([LIBM])
1320
1321 AC_CHECK_FUNCS([ppoll], [
1322   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1323 ])
1324 AC_CHECK_FUNCS([pollts], [
1325   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1326 ])
1327
1328 AC_CHECK_HEADER([asm-generic/unistd.h],
1329                 [AC_CHECK_DECL(__NR_setns,
1330                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1331                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1332                                ])
1333                  AC_CHECK_FUNCS([setns])]
1334                )
1335
1336 dnl --------------------------
1337 dnl Determine IS-IS I/O method
1338 dnl --------------------------
1339 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1340 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1341 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1342 AC_CHECK_HEADER([net/bpf.h])
1343 AC_CHECK_HEADER([sys/dlpi.h])
1344 AC_MSG_CHECKING([zebra IS-IS I/O method])
1345
1346 case "$host_os" in
1347   linux*)
1348     AC_MSG_RESULT([pfpacket])
1349     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1350     ;;
1351   solaris* | sunos*)
1352     AC_MSG_RESULT([DLPI])
1353     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1354     ;;
1355   *)
1356     if test $ac_cv_header_net_bpf_h = no; then
1357       if test $ac_cv_header_sys_dlpi_h = no; then
1358         AC_MSG_RESULT([none])
1359         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1360           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1361         fi
1362         AC_MSG_WARN([*** IS-IS support will not be built ***])
1363         enable_isisd="no"
1364         enable_fabricd="no"
1365       else
1366         AC_MSG_RESULT([DLPI])
1367       fi
1368       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1369     else
1370       AC_MSG_RESULT([BPF])
1371       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1372     fi
1373     ;;
1374 esac
1375 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1376
1377 dnl ---------------------------------------------------------------
1378 dnl figure out how to specify an interface in multicast sockets API
1379 dnl ---------------------------------------------------------------
1380 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1381
1382 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1383         #include <sys/socket.h>
1384         #include <netinet/in.h>
1385         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1386         #include <linux/types.h>
1387 ])
1388
1389 m4_define([FRR_INCLUDES],
1390 FRR_INCLUDES
1391 [#if HAVE_LINUX_MROUTE_H
1392 # include <linux/mroute.h>
1393 #endif
1394 ])dnl
1395
1396 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1397         #include <sys/socket.h>
1398         #include <sys/types.h>
1399         #include <netinet/in.h>
1400         #include <net/route.h>
1401 ])
1402
1403 m4_define([FRR_INCLUDES],
1404 FRR_INCLUDES
1405 [#if HAVE_NETINET_IP_MROUTE_H
1406 # include <netinet/ip_mroute.h>
1407 #endif
1408 ])dnl
1409
1410 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1411 AC_TRY_COMPILE([#include <sys/param.h>],
1412 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1413   return (0);
1414 #else
1415   #error No support for BSD struct ip_mreq hack detected
1416 #endif],[AC_MSG_RESULT([yes])
1417 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1418 AC_MSG_RESULT([no]))
1419
1420 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1421 AC_TRY_COMPILE([
1422 #include <sys/types.h>
1423 #include <netinet/in.h>
1424 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1425 ], [AC_MSG_RESULT([yes])
1426 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1427 AC_MSG_RESULT([no]))
1428
1429 dnl ---------------------------------------------------------------
1430 dnl figure out how to check link-state
1431 dnl ---------------------------------------------------------------
1432 AC_CHECK_HEADER([net/if_media.h],
1433   [m4_define([LINK_DETECT_INCLUDES],
1434     FRR_INCLUDES
1435     [#include <net/if_media.h>
1436   ])
1437   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1438     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1439     [], LINK_DETECT_INCLUDES)],
1440   [],
1441   FRR_INCLUDES)
1442
1443 dnl ---------------------------------------------------------------
1444 dnl Additional, newer way to check link-state using ifi_link_state.
1445 dnl Not available in all BSD's when ifmediareq available
1446 dnl ---------------------------------------------------------------
1447 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1448   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1449   [], FRR_INCLUDES)
1450
1451 dnl ------------------------
1452 dnl TCP_MD5SIG socket option
1453 dnl ------------------------
1454
1455 AC_CHECK_HEADER([netinet/tcp.h],
1456    [m4_define([MD5_INCLUDES],
1457       FRR_INCLUDES
1458       [#include <netinet/tcp.h>
1459     ])
1460     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1461    [],
1462    FRR_INCLUDES)
1463 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1464   AC_CHECK_HEADER([linux/tcp.h],
1465        [m4_define([MD5_INCLUDES],
1466           FRR_INCLUDES
1467           [#include <linux/tcp.h>
1468         ])
1469        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1470 fi
1471
1472 AC_SUBST([SOLARIS])
1473 AC_CHECK_LIB([crypt], [crypt], [],
1474                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1475 AC_CHECK_LIB([resolv], [res_init])
1476
1477 dnl ---------------------------
1478 dnl check system has PCRE regexp
1479 dnl ---------------------------
1480 if test "x$enable_pcreposix" = "xyes"; then
1481   AC_CHECK_LIB([pcreposix], [regexec], [], [
1482     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1483   ])
1484 fi
1485 AC_SUBST([HAVE_LIBPCREPOSIX])
1486
1487 dnl ##########################################################################
1488 dnl test "${enable_clippy_only}" != "yes"
1489 fi
1490 dnl END OF LARGE if block
1491 dnl ##########################################################################
1492
1493 dnl ------------------
1494 dnl check C-Ares library
1495 dnl ------------------
1496 PKG_CHECK_MODULES([CARES], [libcares], [
1497   c_ares_found=true
1498 ],[
1499   c_ares_found=false
1500 ])
1501 AM_CONDITIONAL([CARES], [$c_ares_found])
1502
1503
1504 dnl ----------------------------------------------------------------------------
1505 dnl figure out if domainname is available in the utsname struct (GNU extension).
1506 dnl ----------------------------------------------------------------------------
1507 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1508
1509 dnl ------------------
1510 dnl IPv6 header checks
1511 dnl ------------------
1512 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1513         netinet6/in6_var.h netinet6/nd6.h], [], [],
1514         FRR_INCLUDES)
1515
1516 m4_define([FRR_INCLUDES],dnl
1517 FRR_INCLUDES
1518 [#if HAVE_NETINET6_IN6_H
1519 #include <netinet6/in6.h>
1520 #endif
1521 #if HAVE_NETINET_IN6_VAR_H
1522 #include <netinet/in6_var.h>
1523 #endif
1524 #include <netinet/icmp6.h>
1525 #if HAVE_NETINET6_IN6_VAR_H
1526 # include <netinet6/in6_var.h>
1527 #endif
1528 #if HAVE_NETINET6_ND6_H
1529 # include <netinet6/nd6.h>
1530 #endif
1531 ])dnl
1532
1533 dnl --------------------
1534 dnl Daemon disable check
1535 dnl --------------------
1536
1537 AS_IF([test "${enable_ldpd}" != "no"], [
1538   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1539 ])
1540
1541 if test "$enable_bfdd" = "no"; then
1542   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1543   BFDD=""
1544 else
1545   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1546   BFDD="bfdd"
1547
1548   case $host_os in
1549     linux*)
1550       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1551       ;;
1552
1553     *)
1554       AC_DEFINE([BFD_BSD], [1], [bfdd])
1555       ;;
1556   esac
1557 fi
1558
1559 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1560   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1561 fi
1562
1563 NHRPD=""
1564 case "$host_os" in
1565   linux*)
1566     case "${enable_nhrpd}" in
1567       no)
1568         ;;
1569       yes)
1570         if test "${enable_clippy_only}" != "yes"; then
1571         if test "$c_ares_found" != "true" ; then
1572           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1573         fi
1574         fi
1575         NHRPD="nhrpd"
1576         ;;
1577       *)
1578         if test "$c_ares_found" = "true" ; then
1579           NHRPD="nhrpd"
1580         fi
1581         ;;
1582     esac
1583     ;;
1584   *)
1585     if test "${enable_nhrpd}" = "yes"; then
1586       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1587     fi
1588     ;;
1589 esac
1590
1591 if test "${enable_watchfrr}" = "no";then
1592   WATCHFRR=""
1593 else
1594   WATCHFRR="watchfrr"
1595 fi
1596
1597 OSPFCLIENT=""
1598 if test "${enable_ospfapi}" != "no";then
1599     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1600
1601   if test "${enable_ospfclient}" != "no";then
1602       OSPFCLIENT="ospfclient"
1603   fi
1604 fi
1605
1606 if test "${enable_bgp_announce}" = "no";then
1607   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1608 else
1609   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1610 fi
1611
1612 if test "${enable_bgp_vnc}" != "no";then
1613   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1614 fi
1615
1616 bgpd_bmp=false
1617 case "${enable_bmp}" in
1618   no)
1619     ;;
1620   yes)
1621     if test "$c_ares_found" != "true" ; then
1622       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1623     fi
1624     bgpd_bmp=true
1625     ;;
1626   *)
1627     if test "$c_ares_found" = "true" ; then
1628       bgpd_bmp=true
1629     fi
1630     ;;
1631 esac
1632
1633 dnl ##########################################################################
1634 dnl LARGE if block
1635 if test "${enable_clippy_only}" != "yes"; then
1636 dnl ##########################################################################
1637
1638 dnl ------------------
1639 dnl check Net-SNMP library
1640 dnl ------------------
1641 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1642    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1643    if test x"$NETSNMP_CONFIG" = x"no"; then
1644       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1645    fi
1646    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1647    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1648    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1649    # among other things we avoid a GPL vs. OpenSSL license conflict here
1650    for removelib in crypto ssl sensors pci wrap; do
1651      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1652    done
1653    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1654    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1655 int main(void);
1656 ],
1657 [
1658 {
1659   return 0;
1660 }
1661 ])], [
1662      AC_MSG_RESULT([no])
1663      AC_MSG_ERROR([--enable-snmp given but not usable])])
1664    case "${enable_snmp}" in
1665      yes)
1666       SNMP_METHOD=agentx
1667       ;;
1668      agentx)
1669       SNMP_METHOD="${enable_snmp}"
1670       ;;
1671      *)
1672       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1673       ;;
1674    esac
1675    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1676    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1677 fi
1678 AC_SUBST([SNMP_LIBS])
1679 AC_SUBST([SNMP_CFLAGS])
1680
1681 dnl ---------------
1682 dnl libyang
1683 dnl ---------------
1684 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.105], , [
1685   AC_MSG_ERROR([libyang (>= 0.16.105) was not found on your system.])
1686 ])
1687 ac_cflags_save="$CFLAGS"
1688 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1689 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1690   AC_MSG_ERROR([m4_normalize([
1691     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1692     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1693   ])
1694 ], [[#include <libyang/libyang.h>]])
1695 CFLAGS="$ac_cflags_save"
1696
1697 dnl ---------------
1698 dnl configuration rollbacks
1699 dnl ---------------
1700 SQLITE3=false
1701 if test "$enable_config_rollbacks" = "yes"; then
1702   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1703     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1704     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1705     SQLITE3=true
1706   ], [
1707     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1708   ])
1709 fi
1710
1711 dnl ---------------
1712 dnl confd
1713 dnl ---------------
1714 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1715    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1716    if test "x$CONFD" = "x/bin/false"; then
1717       AC_MSG_ERROR([confd was not found on your system.])]
1718    fi
1719    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1720    AC_SUBST([CONFD_CFLAGS])
1721    CONFD_LIBS="-lconfd"
1722    AC_SUBST([CONFD_LIBS])
1723    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1724 fi
1725
1726 dnl ---------------
1727 dnl sysrepo
1728 dnl ---------------
1729 if test "$enable_sysrepo" = "yes"; then
1730   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1731       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1732       SYSREPO=true],
1733       [SYSREPO=false
1734       AC_MSG_ERROR([sysrepo was not found on your system.])]
1735   )
1736 fi
1737
1738 dnl ---------------
1739 dnl gRPC
1740 dnl ---------------
1741 if test "$enable_grpc" = "yes"; then
1742   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1743     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1744     if test "$PROTOC" = "/bin/false"; then
1745       AC_MSG_FAILURE([grpc requested but protoc not found.])
1746     fi
1747
1748     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1749     GRPC=true
1750   ], [
1751     GRPC=false
1752     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1753   ])
1754 fi
1755
1756 dnl ------
1757 dnl ZeroMQ
1758 dnl ------
1759 if test "x$enable_zeromq" != "xno"; then
1760   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1761     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1762     ZEROMQ=true
1763   ], [
1764     if test "x$enable_zeromq" = "xyes"; then
1765       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1766     fi
1767   ])
1768 fi
1769
1770 dnl ------------------------------------
1771 dnl Enable RPKI and add librtr to libs
1772 dnl ------------------------------------
1773 if test "${enable_rpki}" = "yes"; then
1774   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1775       [RPKI=true],
1776       [RPKI=false
1777       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1778   )
1779 fi
1780
1781 dnl ------------------------------------------
1782 dnl Check whether rtrlib was build with ssh support
1783 dnl ------------------------------------------
1784 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1785 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1786                         [[struct tr_ssh_config config;]])],
1787         [AC_MSG_RESULT([yes])
1788         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1789         AC_MSG_RESULT([no])
1790 )
1791
1792 dnl ---------------
1793 dnl dlopen & dlinfo
1794 dnl ---------------
1795 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1796   AC_MSG_ERROR([unable to find the dlopen()])
1797 ])
1798
1799 AC_CHECK_HEADERS([link.h])
1800
1801 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1802   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1803 #include <stdlib.h>
1804 #ifdef HAVE_LINK_H
1805 #include <link.h>
1806 #endif
1807 #include <dlfcn.h>
1808 ]], [[
1809   char origin[1];
1810   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1811 ]])], [
1812     frr_cv_rtld_di_origin=yes
1813   ], [
1814     frr_cv_rtld_di_origin=no
1815   ])
1816 ])
1817 if test "$frr_cv_rtld_di_origin" = yes; then
1818   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1819 fi
1820
1821 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1822   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1823 #include <stdlib.h>
1824 #ifdef HAVE_LINK_H
1825 #include <link.h>
1826 #endif
1827 #include <dlfcn.h>
1828 ]], [[
1829   struct link_map *lm = NULL;
1830   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1831 ]])], [
1832     frr_cv_rtld_di_linkmap=yes
1833   ], [
1834     frr_cv_rtld_di_linkmap=no
1835   ])
1836 ])
1837 if test "$frr_cv_rtld_di_linkmap" = yes; then
1838   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1839 fi
1840
1841 dnl ##########################################################################
1842 dnl test "${enable_clippy_only}" != "yes"
1843 fi
1844 dnl END OF LARGE if block
1845 dnl ##########################################################################
1846
1847 dnl ---------------------------
1848 dnl sockaddr and netinet checks
1849 dnl ---------------------------
1850 AC_CHECK_TYPES([
1851         struct sockaddr_dl,
1852         struct vifctl, struct mfcctl, struct sioc_sg_req,
1853         vifi_t, struct sioc_vif_req, struct igmpmsg,
1854         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1855         struct nd_opt_adv_interval,
1856         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1857         struct nd_opt_rdnss, struct nd_opt_dnssl],
1858         [], [], FRR_INCLUDES)
1859
1860 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1861         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1862         struct sockaddr_dl.sdl_len,
1863         struct if6_aliasreq.ifra_lifetime,
1864         struct nd_opt_adv_interval.nd_opt_ai_type],
1865         [], [], FRR_INCLUDES)
1866
1867 dnl ---------------------------
1868 dnl IRDP/pktinfo/icmphdr checks
1869 dnl ---------------------------
1870
1871 AC_CHECK_TYPES([struct in_pktinfo], [
1872   AC_CHECK_TYPES([struct icmphdr], [
1873     IRDP=true
1874   ], [
1875     IRDP=false
1876   ], [FRR_INCLUDES])
1877 ], [
1878   IRDP=false
1879 ], [FRR_INCLUDES])
1880
1881 case "${enable_irdp}" in
1882 yes)
1883   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1884   ;;
1885 no)
1886   IRDP=false
1887   ;;
1888 esac
1889
1890
1891 dnl -----------------------
1892 dnl checking for IP_PKTINFO
1893 dnl -----------------------
1894 AC_MSG_CHECKING([for IP_PKTINFO])
1895 AC_TRY_COMPILE([#include <netdb.h>], [
1896   int opt = IP_PKTINFO;
1897 ], [
1898   AC_MSG_RESULT([yes])
1899   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1900 ], [
1901   AC_MSG_RESULT([no])
1902 ])
1903
1904 dnl ---------------------------
1905 dnl checking for IP_RECVDSTADDR
1906 dnl ---------------------------
1907 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1908 AC_TRY_COMPILE([#include <netinet/in.h>], [
1909   int opt = IP_RECVDSTADDR;
1910 ], [
1911   AC_MSG_RESULT([yes])
1912   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1913 ], [
1914   AC_MSG_RESULT([no])
1915 ])
1916
1917 dnl ----------------------
1918 dnl checking for IP_RECVIF
1919 dnl ----------------------
1920 AC_MSG_CHECKING([for IP_RECVIF])
1921 AC_TRY_COMPILE([#include <netinet/in.h>], [
1922   int opt = IP_RECVIF;
1923 ], [
1924   AC_MSG_RESULT([yes])
1925   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1926 ], [
1927   AC_MSG_RESULT([no])
1928 ])
1929
1930 dnl ----------------------
1931 dnl checking for SO_BINDANY
1932 dnl ----------------------
1933 AC_MSG_CHECKING([for SO_BINDANY])
1934 AC_TRY_COMPILE([#include <sys/socket.h>], [
1935   int opt = SO_BINDANY;
1936 ], [
1937   AC_MSG_RESULT([yes])
1938   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1939 ], [
1940   AC_MSG_RESULT([no])
1941 ])
1942
1943 dnl ----------------------
1944 dnl checking for IP_FREEBIND
1945 dnl ----------------------
1946 AC_MSG_CHECKING([for IP_FREEBIND])
1947 AC_TRY_COMPILE([#include <netinet/in.h>], [
1948   int opt = IP_FREEBIND;
1949 ], [
1950   AC_MSG_RESULT([yes])
1951   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1952 ], [
1953   AC_MSG_RESULT([no])
1954 ])
1955
1956 dnl --------------------------------------
1957 dnl checking for be32dec existence or not
1958 dnl --------------------------------------
1959 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1960                [#include <sys/endian.h>])
1961
1962 dnl --------------------------------------
1963 dnl checking for clock_time monotonic struct and call
1964 dnl --------------------------------------
1965 AC_CHECK_DECL([CLOCK_MONOTONIC],
1966         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1967          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1968 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1969
1970 dnl --------------------------------------
1971 dnl checking for flex and bison
1972 dnl --------------------------------------
1973
1974 AM_PROG_LEX
1975 AC_MSG_CHECKING([version of flex])
1976 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1977 frr_ac_flex_version="${frr_ac_flex_version##* }"
1978 AC_MSG_RESULT([$frr_ac_flex_version])
1979 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1980   LEX="$SHELL $missing_dir/missing flex"
1981   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1982     AC_MSG_WARN([using pregenerated flex output files])
1983   else
1984     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1985   fi
1986   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1987   AC_SUBST([LEXLIB], [''])
1988 ])
1989
1990 AC_PROG_YACC
1991 dnl thanks GNU bison for this b*llshit...
1992 AC_MSG_CHECKING([version of bison])
1993 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1994 frr_ac_bison_version="${frr_ac_bison_version##* }"
1995 frr_ac_bison_missing="false"
1996 case "x${frr_ac_bison_version}x" in
1997   x2.7*)
1998     BISON_OPENBRACE='"'
1999     BISON_CLOSEBRACE='"'
2000     BISON_VERBOSE=''
2001     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2002     ;;
2003   x2.*|x1.*)
2004     AC_MSG_RESULT([$frr_ac_bison_version])
2005     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2006     frr_ac_bison_missing="true"
2007     ;;
2008   x)
2009     AC_MSG_RESULT([none])
2010     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2011     frr_ac_bison_missing="true"
2012     ;;
2013   x3.[012][^0-9]*)
2014     BISON_OPENBRACE='{'
2015     BISON_CLOSEBRACE='}'
2016     BISON_VERBOSE='-Dparse.error=verbose'
2017     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2018     ;;
2019   *)
2020     BISON_OPENBRACE='{'
2021     BISON_CLOSEBRACE='}'
2022     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2023     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2024     ;;
2025 esac
2026 AC_SUBST([BISON_OPENBRACE])
2027 AC_SUBST([BISON_CLOSEBRACE])
2028 AC_SUBST([BISON_VERBOSE])
2029
2030 if $frr_ac_bison_missing; then
2031   YACC="$SHELL $missing_dir/missing bison -y"
2032   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2033     AC_MSG_WARN([using pregenerated bison output files])
2034   else
2035     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2036   fi
2037 fi
2038
2039 dnl -------------------
2040 dnl capabilities checks
2041 dnl -------------------
2042 if test "${enable_capabilities}" != "no"; then
2043   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2044   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2045     [AC_MSG_RESULT([yes])
2046      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2047      frr_ac_keepcaps="yes"],
2048      AC_MSG_RESULT([no])
2049   )
2050   if test x"${frr_ac_keepcaps}" = x"yes"; then
2051     AC_CHECK_HEADERS([sys/capability.h])
2052   fi
2053   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
2054     AC_CHECK_LIB([cap], [cap_init],
2055       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2056        LIBCAP="-lcap"
2057        frr_ac_lcaps="yes"]
2058     )
2059   else
2060     AC_CHECK_HEADERS([priv.h],
2061      [AC_MSG_CHECKING([Solaris style privileges are available])
2062       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
2063           [AC_MSG_RESULT([yes])
2064            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
2065            frr_ac_scaps="yes"],
2066            AC_MSG_RESULT(no)
2067       )
2068      ]
2069    )
2070   fi
2071   if test x"${frr_ac_scaps}" = x"yes" \
2072        -o x"${frr_ac_lcaps}" = x"yes"; then
2073     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2074   fi
2075
2076   case "$host_os" in
2077   linux*)
2078     if test "${enable_clippy_only}" != "yes"; then
2079     if test "$frr_ac_lcaps" != "yes"; then
2080       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2081     fi
2082     fi
2083     ;;
2084   esac
2085 else
2086   case "$host_os" in
2087   linux*)
2088     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2089     ;;
2090   esac
2091 fi
2092 AC_SUBST([LIBCAP])
2093
2094 dnl ---------------------------
2095 dnl check for glibc 'backtrace'
2096 dnl ---------------------------
2097 if test x"${enable_backtrace}" != x"no" ; then
2098   backtrace_ok=no
2099   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2100     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2101     backtrace_ok=yes
2102   ], [
2103     case "$host_os" in
2104     sunos* | solaris2*)
2105       AC_CHECK_FUNCS([printstack], [
2106         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
2107         backtrace_ok=yes
2108       ])
2109       ;;
2110     esac
2111     if test "$backtrace_ok" = no; then
2112       AC_CHECK_HEADER([execinfo.h], [
2113         AC_SEARCH_LIBS([backtrace], [execinfo], [
2114           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2115           backtrace_ok=yes
2116         ],, [-lm])
2117       ])
2118     fi
2119   ])
2120
2121   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
2122     dnl user explicitly requested backtrace but we failed to find support
2123     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2124   fi
2125 fi
2126
2127 dnl -----------------------------------------
2128 dnl check for malloc mallinfo struct and call
2129 dnl this must try and link using LIBS, in
2130 dnl order to check no alternative allocator
2131 dnl has been specified, which might not provide
2132 dnl mallinfo, e.g. such as Umem on Solaris.
2133 dnl -----------------------------------------
2134 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2135
2136 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2137   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2138 #ifdef HAVE_MALLOC_H
2139 #include <malloc.h>
2140 #endif
2141 #ifdef HAVE_MALLOC_NP_H
2142 #include <malloc_np.h>
2143 #endif
2144 #ifdef HAVE_MALLOC_MALLOC_H
2145 #include <malloc/malloc.h>
2146 #endif
2147 ]], [[
2148 struct mallinfo ac_x; ac_x = mallinfo ();
2149 ]])], [
2150     frr_cv_mallinfo=yes
2151   ], [
2152     frr_cv_mallinfo=no
2153   ])
2154 ])
2155 if test "$frr_cv_mallinfo" = yes; then
2156   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2157 fi
2158
2159 AC_MSG_CHECKING([whether malloc_usable_size is available])
2160 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2161 #ifdef HAVE_MALLOC_H
2162 #include <malloc.h>
2163 #endif
2164 #ifdef HAVE_MALLOC_MALLOC_H
2165 #include <malloc/malloc.h>
2166 #endif
2167 ]], [[
2168 size_t ac_x; ac_x = malloc_usable_size(NULL);
2169 ]])], [
2170   AC_MSG_RESULT([yes])
2171   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2172 ], [
2173   AC_MSG_RESULT([no])
2174
2175   AC_MSG_CHECKING([whether malloc_size is available])
2176   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2177 #ifdef HAVE_MALLOC_H
2178 #include <malloc.h>
2179 #endif
2180 #ifdef HAVE_MALLOC_MALLOC_H
2181 #include <malloc/malloc.h>
2182 #endif
2183 ]], [[
2184 size_t ac_x; ac_x = malloc_size(NULL);
2185 ]])], [
2186     AC_MSG_RESULT([yes])
2187     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2188   ], [
2189     AC_MSG_RESULT([no])
2190   ])
2191 ])
2192
2193 dnl ----------
2194 dnl configure date
2195 dnl ----------
2196 dev_version=`echo $VERSION | grep dev`
2197 #don't expire deprecated code in non 'dev' branch
2198 if test "${dev_version}" = ""; then
2199    CONFDATE=0
2200 else
2201    CONFDATE=`date '+%Y%m%d'`
2202 fi
2203 AC_SUBST([CONFDATE])
2204
2205 dnl ------------------------------
2206 dnl set paths for state directory
2207 dnl ------------------------------
2208 AC_MSG_CHECKING([directory to use for state file])
2209 if test "${prefix}" = "NONE"; then
2210   frr_statedir_prefix="";
2211 else
2212   frr_statedir_prefix=${prefix}
2213 fi
2214 if test "${localstatedir}" = '${prefix}/var'; then
2215   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2216                         ${frr_statedir_prefix}/var/adm dnl
2217                         ${frr_statedir_prefix}/etc dnl
2218                         /var/run        dnl
2219                         /var/adm        dnl
2220                         /etc            dnl
2221                         /dev/null;
2222   do
2223     test -d $FRR_STATE_DIR && break
2224   done
2225   frr_statedir=$FRR_STATE_DIR
2226 else
2227   frr_statedir=${localstatedir}
2228 fi
2229 if test $frr_statedir = "/dev/null"; then
2230     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2231 fi
2232 AC_MSG_RESULT([${frr_statedir}])
2233 AC_SUBST([frr_statedir])
2234
2235 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2236 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2237 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2238 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2239 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2240
2241 dnl autoconf does this, but it does it too late...
2242 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2243 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2244
2245 dnl get the full path, recursing through variables...
2246 vtysh_bin="$bindir/vtysh"
2247 for I in 1 2 3 4 5 6 7 8 9 10; do
2248         eval vtysh_bin="\"$vtysh_bin\""
2249 done
2250 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2251 AC_SUBST([vtysh_bin])
2252
2253 CFG_SYSCONF="$sysconfdir"
2254 CFG_SBIN="$sbindir"
2255 CFG_STATE="$frr_statedir"
2256 CFG_MODULE="$moduledir"
2257 CFG_YANGMODELS="$yangmodelsdir"
2258 for I in 1 2 3 4 5 6 7 8 9 10; do
2259         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2260         eval CFG_SBIN="\"$CFG_SBIN\""
2261         eval CFG_STATE="\"$CFG_STATE\""
2262         eval CFG_MODULE="\"$CFG_MODULE\""
2263         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2264 done
2265 AC_SUBST([CFG_SYSCONF])
2266 AC_SUBST([CFG_SBIN])
2267 AC_SUBST([CFG_STATE])
2268 AC_SUBST([CFG_MODULE])
2269 AC_SUBST([CFG_YANGMODELS])
2270 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2271 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2272 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2273
2274 dnl various features
2275 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
2276 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
2277 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2278 dnl northbound
2279 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2280 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
2281 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
2282 AM_CONDITIONAL([GRPC], [test "x$enable_grpc" = "xyes"])
2283 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2284 dnl plugins
2285 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2286 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
2287 AM_CONDITIONAL([IRDP], [$IRDP])
2288 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
2289 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
2290 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2291 dnl daemons
2292 AM_CONDITIONAL([VTYSH], [test "x$VTYSH" = "xvtysh"])
2293 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
2294 AM_CONDITIONAL([BGPD], [test "x${enable_bgpd}" != "no"])
2295 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
2296 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
2297 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
2298 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
2299 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
2300 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
2301 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
2302 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
2303 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
2304 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
2305 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
2306 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
2307 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
2308 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
2309 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
2310 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
2311 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
2312 AM_CONDITIONAL([VRRPD], [test "${enable_vrrpd}" != "no"])
2313
2314 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2315
2316 AC_CONFIG_FILES([
2317           config.version
2318           changelog-auto
2319           redhat/frr.spec
2320           solaris/Makefile
2321           alpine/APKBUILD
2322           snapcraft/snapcraft.yaml
2323           lib/version.h
2324           tests/lib/cli/test_cli.refout
2325           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2326           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2327           pkgsrc/eigrpd.sh])
2328
2329 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2330 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2331 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2332 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2333 AC_CONFIG_FILES([tools/frrcommon.sh])
2334
2335 AC_CONFIG_COMMANDS([lib/route_types.h], [
2336         dst="${ac_abs_top_builddir}/lib/route_types.h"
2337         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2338                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2339                 > "${dst}.tmp"
2340         test -f "${dst}" \
2341                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2342                 && rm "${dst}.tmp" \
2343                 || mv "${dst}.tmp" "${dst}"
2344 ], [
2345         PERL="$PERL"
2346 ])
2347
2348 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2349     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2350         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2351         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2352                 "${ac_abs_top_srcdir}" \
2353                 > "${dst}.tmp"
2354         test -f "${dst}" \
2355                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2356                 && rm "${dst}.tmp" \
2357                 || mv "${dst}.tmp" "${dst}"
2358     ], [
2359         PERL="$PERL"
2360     ])
2361 ])
2362
2363 ## Hack, but working solution to avoid rebuilding of frr.info.
2364 ## It's already in CVS until texinfo 4.7 is more common.
2365 AC_OUTPUT
2366
2367 echo "
2368 FRRouting configuration
2369 ------------------------------
2370 FRR version             : ${PACKAGE_VERSION}
2371 host operating system   : ${host_os}
2372 source code location    : ${srcdir}
2373 compiler                : ${CC}
2374 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2375 make                    : ${MAKE-make}
2376 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2377 state file directory    : ${frr_statedir}
2378 config file directory   : `eval echo \`echo ${sysconfdir}\``
2379 example directory       : `eval echo \`echo ${exampledir}\``
2380 module directory        : ${CFG_MODULE}
2381 user to run as          : ${enable_user}
2382 group to run as         : ${enable_group}
2383 group for vty sockets   : ${enable_vty_group}
2384 config file mask        : ${enable_configfile_mask}
2385 log file mask           : ${enable_logfile_mask}
2386 zebra protobuf enabled  : ${enable_protobuf:-no}
2387
2388 The above user and group must have read/write access to the state file
2389 directory and to the config files in the config file directory."
2390
2391 if test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" = false; then
2392   AC_MSG_WARN([sphinx is missing but required to build documentation])
2393 fi
2394 if test "$frr_py_mod_pytest" = false; then
2395   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2396 fi