configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_devel], 1)
   5 m4_define([lxc_version_major], 3)
   6 m4_define([lxc_version_minor], 1)
   7 m4_define([lxc_version_micro], 0)
   8 m4_define([lxc_version_beta], [])
   9
  10 m4_define([lxc_abi_major], 1)
  11 m4_define([lxc_abi_minor], 5)
  12 m4_define([lxc_abi_micro], 0)
  13 m4_define([lxc_abi], [lxc_abi_major.lxc_abi_minor.lxc_abi_micro])
  14
  15 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  16 m4_define([lxc_version],
  17        [ifelse(lxc_devel, 1,
  18         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])-devel,
  19         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta]))])
  20
  21 AC_INIT([lxc], [lxc_version])
  22
  23 # We need pkg-config
  24 PKG_PROG_PKG_CONFIG
  25
  26 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  27 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  28
  29 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  30 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  31 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  32 AC_SUBST([LXC_VERSION], [lxc_version])
  33 AC_SUBST([LXC_DEVEL], [lxc_devel])
  34
  35 AC_SUBST([LXC_ABI_MAJOR], [lxc_abi_major])
  36 AC_SUBST([LXC_ABI_MINOR], [lxc_abi_minor])
  37 AC_SUBST([LXC_ABI_MICRO], [lxc_abi_micro])
  38 AC_SUBST([LXC_ABI], [lxc_abi])
  39
  40 AC_CONFIG_SRCDIR([configure.ac])
  41 AC_CONFIG_AUX_DIR([config])
  42 AC_CONFIG_HEADERS([src/config.h])
  43 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  44 AC_CANONICAL_HOST
  45 AM_PROG_CC_C_O
  46 AC_GNU_SOURCE
  47
  48 # Test if we have a new enough compiler.
  49 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  50 #define GCC_VERSION \
  51         (__GNUC__ * 10000 + __GNUC_MINOR__ * 100 + __GNUC_PATCHLEVEL__)
  52
  53 #define CLANG_VERSION \
  54         (__clang_major__ * 10000 + __clang_minor__ * 100 + __clang_patchlevel__)
  55
  56 #if GCC_VERSION < 40700 && CLANG_VERSION < 10000
  57 #error Sorry, your compiler is too old - please upgrade it
  58 #endif
  59         ]])], [valid_compiler=yes], [valid_compiler=no])
  60 if test "x$valid_compiler" = "xno"; then
  61         AC_MSG_ERROR([Sorry, your compiler is too old - please upgrade it])
  62 fi
  63
  64 # libtool
  65 LT_INIT
  66 AC_SUBST([LIBTOOL_DEPS])
  67
  68 # Detect the distribution. This is used for the default configuration and
  69 # for some distro-specific build options.
  70 AC_MSG_CHECKING([host distribution])
  71 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, redhatenterpriseserver, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva, pardus, sparclinux, altlinux.]))
  72 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  73         with_distro=`lsb_release -is`
  74 fi
  75 if test "z$with_distro" = "z"; then
  76         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  77         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  78         AC_CHECK_FILE(/etc/sparclinux-release,with_distro="sparclinux")
  79         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  80         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  81         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  82         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  83         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  84         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  85         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  86         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
  87         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  88         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  89         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  90         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  91         AC_CHECK_FILE(/etc/altlinux-release,with_distro="altlinux")
  92         AC_CHECK_FILE(/etc/pld-release,with_distro="pld")
  93 fi
  94 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  95
  96 if test "z$with_distro" = "zforsparc"; then
  97         with_distro="sparclinux"
  98 fi
  99
 100 if test "z$with_distro" = "z"; then
 101         with_distro="unknown"
 102 fi
 103 case $with_distro in
 104         ubuntu|raspbian)
 105                 distroconf=default.conf.lxcbr
 106                 distrosysconf="$sysconfdir/default"
 107                 ;;
 108         redhat|redhatenterpriseserver|centos|fedora|oracle|oracleserver|sparclinux|altlinux|suse|opensuse*|plamo|pld)
 109                 distroconf=default.conf.lxcbr
 110                 distrosysconf="$sysconfdir/sysconfig"
 111                 ;;
 112         *)
 113                 distroconf=default.conf.unknown
 114                 distrosysconf="$sysconfdir/default"
 115                 ;;
 116 esac
 117 AC_MSG_RESULT([$with_distro])
 118 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
 119 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
 120
 121 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
 122
 123 # Check for init system type
 124 AC_MSG_CHECKING([for init system type])
 125 AC_ARG_WITH([init-script],
 126             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
 127                             [Type(s) of init script to install: sysvinit, systemd, upstart,
 128                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
 129 case "$with_init_script" in
 130         distro)
 131                 case $with_distro in
 132                         fedora|altlinux|opensuse*)
 133                                 init_script=systemd
 134                                 ;;
 135                         redhat|redhatenterpriseserver|oracle|oracleserver|sparclinux|plamo)
 136                                 init_script=sysvinit
 137                                 ;;
 138                         centos)
 139                                 init_script=sysvinit,systemd
 140                                 ;;
 141                         debian|raspbian|ubuntu)
 142                                 init_script=upstart,systemd
 143                                 ;;
 144                         pld)
 145                                 init_script=sysvinit,upstart,systemd
 146                                 ;;
 147                         *)
 148                                 echo -n "Linux distribution init system unknown."
 149                                 init_script=
 150                                 ;;
 151                 esac
 152                 ;;
 153         *)
 154                 init_script=$with_init_script
 155                 ;;
 156 esac
 157
 158 # Check valid init systems were given, run in subshell so we don't mess up IFS
 159 (IFS="," ; for init_sys in $init_script;
 160 do
 161         case "$init_sys" in
 162                 none|sysvinit|systemd|upstart)
 163                         ;;
 164                 *)
 165                         exit 1
 166                         ;;
 167         esac
 168 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 169
 170 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 171 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 172 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 173 AC_MSG_RESULT($init_script)
 174
 175 # systemd unit dir
 176 AC_ARG_WITH([systemdsystemunitdir],
 177             AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 178             [],
 179             [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 180 if test -z "$with_systemdsystemunitdir"; then
 181   with_systemdsystemunitdir=/lib/systemd/system
 182 fi
 183 if test "x$with_systemdsystemunitdir" != "xno"; then
 184   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 185 fi
 186
 187 AC_ARG_ENABLE([werror],
 188         [AC_HELP_STRING([--disable-werror],
 189         [do not treat warnings as errors])],
 190         [], [enable_werror=yes])
 191
 192 # Allow disabling rpath
 193 AC_ARG_ENABLE([rpath],
 194         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 195         [], [enable_rpath=no])
 196 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 197
 198 # Documentation (manpages)
 199 AC_ARG_ENABLE([doc],
 200         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 201         [], [enable_doc=auto])
 202
 203 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 204         db2xman=""
 205         dbparsers="docbook2X2man docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 206
 207         AC_MSG_CHECKING(for docbook2x-man)
 208         for name in ${dbparsers}; do
 209                 if "$name" --help >/dev/null 2>&1; then
 210                         db2xman="$name"
 211                         break;
 212                 fi
 213         done
 214
 215         if test -n "${db2xman}"; then
 216                 AC_MSG_RESULT([${db2xman}])
 217                 enable_doc="yes"
 218         else
 219                 AC_MSG_RESULT([no])
 220                 if test "x$enable_doc" = "xyes"; then
 221                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 222                 fi
 223                 enable_doc="no"
 224         fi
 225
 226         AC_SUBST(db2xman)
 227 fi
 228 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 229 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 230
 231 if test "x$db2xman" = "xdocbook2man"; then
 232         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 233 else
 234         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 235 fi
 236 AC_SUBST(docdtd)
 237
 238 # Documentation (API)
 239 AC_ARG_ENABLE([api-docs],
 240         [AC_HELP_STRING([--enable-api-docs],
 241         [make API documentation [default=auto]])],
 242         [], [enable_api_docs=auto])
 243
 244 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 245         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 246         AC_SUBST([HAVE_DOXYGEN])
 247
 248         if test "x$HAVE_DOXYGEN" != "x"; then
 249                 enable_api_docs="yes"
 250         else
 251                 if test "x$enable_api_docs" = "xyes"; then
 252                         AC_MSG_ERROR([doxygen is required, but could not be found])
 253                 fi
 254                 enable_api_docs="no"
 255         fi
 256 fi
 257
 258 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 259
 260 # Apparmor
 261 AC_ARG_ENABLE([apparmor],
 262         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 263         [], [enable_apparmor=auto])
 264
 265 if test "$enable_apparmor" = "auto" ; then
 266         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 267 fi
 268 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 269
 270 # GnuTLS
 271 AC_ARG_ENABLE([gnutls],
 272         [AC_HELP_STRING([--enable-gnutls], [enable GnuTLS support [default=auto]])],
 273         [], [enable_gnutls=auto])
 274
 275 if test "$enable_gnutls" = "auto" ; then
 276         AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 277 fi
 278 AM_CONDITIONAL([ENABLE_GNUTLS], [test "x$enable_gnutls" = "xyes"])
 279
 280 AM_COND_IF([ENABLE_GNUTLS],
 281         [AC_CHECK_HEADER([gnutls/gnutls.h],[],[AC_MSG_ERROR([You must install the GnuTLS development package in order to compile lxc])])
 282         AC_CHECK_LIB([gnutls], [gnutls_hash_fast],[true],[AC_MSG_ERROR([You must install the GnuTLS development package in order to compile lxc])])
 283         AC_SUBST([GNUTLS_LIBS], [-lgnutls])])
 284
 285 # SELinux
 286 AC_ARG_ENABLE([selinux],
 287         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 288         [], [enable_selinux=auto])
 289
 290 if test "x$enable_selinux" = xauto; then
 291         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 292 fi
 293 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 294 AM_COND_IF([ENABLE_SELINUX],
 295         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 296         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 297         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 298
 299 # Seccomp syscall filter
 300 AC_ARG_ENABLE([seccomp],
 301         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 302         [], [enable_seccomp=auto])
 303
 304 if test "x$enable_seccomp" = "xauto" ; then
 305         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 306 fi
 307 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 308
 309 AM_COND_IF([ENABLE_SECCOMP],
 310         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 311                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 312                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 313                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 314                 ])
 315         ])
 316
 317 AC_MSG_CHECKING(for static libcap)
 318 # Check for static libcap, make sure the function checked for differs from the
 319 # the one checked below so the cache doesn't give a wrong answer
 320 OLD_CFLAGS="$CFLAGS"
 321 OLD_CPPFLAGS="$CPPFLAGS"
 322 OLD_LDFLAGS="$LDFLAGS"
 323 OLD_LIBS="$LIBS"
 324 CFLAGS=""
 325 CPPFLAGS=""
 326 LDFLAGS="-static"
 327 LIBS="-lcap"
 328 AC_LINK_IFELSE([
 329   AC_LANG_SOURCE(
 330     [[int main() { return 0; }]]
 331   )],[have_static_libcap=yes],[have_static_libcap=no])
 332 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 333 if test "x$have_static_libcap" = "xyes"; then
 334         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 335         AC_MSG_RESULT([yes])
 336 else
 337         AC_MSG_RESULT([no])
 338 fi
 339 CPPFLAGS="$OLD_CPPFLAGS"
 340 CFLAGS="$OLD_CFLAGS"
 341 LDFLAGS="$OLD_LDFLAGS"
 342 LIBS="$OLD_LIBS"
 343
 344
 345 # Linux capabilities
 346 AC_ARG_ENABLE([capabilities],
 347         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 348         [], [enable_capabilities=auto])
 349
 350 if test "x$enable_capabilities" = "xauto"; then
 351         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 352 fi
 353 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 354
 355 AM_COND_IF([ENABLE_CAP],
 356         [AC_CHECK_HEADER([sys/capability.h],[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 357         AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 358         # Test whether we support getting file capabilities via cap_get_file().
 359         AC_CHECK_LIB(cap,cap_get_file, AC_DEFINE(LIBCAP_SUPPORTS_FILE_CAPABILITIES,1,[Have cap_get_file]),[],[])
 360         AC_SUBST([CAP_LIBS], [-lcap])])
 361
 362 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 363 OLD_CFLAGS="$CFLAGS"
 364 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 365 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 366 AC_CHECK_DECLS([seccomp_notify_fd], [], [], [[#include <seccomp.h>]])
 367 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 368 CFLAGS="$OLD_CFLAGS"
 369
 370 # Configuration examples
 371 AC_ARG_ENABLE([examples],
 372         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 373         [], [enable_examples=yes])
 374 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 375
 376 # Enable dumping stack traces
 377 AC_ARG_ENABLE([mutex-debugging],
 378         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 379         [], [enable_mutex_debugging=no])
 380 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 381
 382 AM_COND_IF([MUTEX_DEBUGGING],
 383         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 384
 385 # Not in older autoconf versions
 386 # AS_VAR_COPY(DEST, SOURCE)
 387 # -------------------------
 388 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 389 # shell variable SOURCE.
 390 m4_ifdef([AS_VAR_COPY], [],
 391 [AC_DEFUN([AS_VAR_COPY],
 392     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 393 ])
 394
 395 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 396 m4_ifdef([PKG_CHECK_VAR], [],
 397 [AC_DEFUN([PKG_CHECK_VAR],
 398     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 399      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 400      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 401      AS_VAR_COPY([$1], [pkg_cv_][$1])
 402      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 403     ])# PKG_CHECK_VAR
 404 ])
 405
 406 # Optional bash integration
 407 AC_ARG_ENABLE([bash],
 408         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 409         [], [enable_bash=yes])
 410 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 411
 412 AM_COND_IF([ENABLE_BASH],
 413         [AC_MSG_CHECKING([bash completion directory])
 414         PKG_CHECK_VAR(bashcompdir, [bash-completion], [completionsdir], ,
 415                 bashcompdir="${sysconfdir}/bash_completion.d")
 416         AC_MSG_RESULT([$bashcompdir])
 417         AC_SUBST(bashcompdir)
 418         ])
 419
 420 # Build the command line tools
 421 AC_ARG_ENABLE([tools],
 422         [AC_HELP_STRING([--enable-tools], [build the command line tools [default=yes]])],
 423         [], [enable_tools=yes])
 424 AM_CONDITIONAL([ENABLE_TOOLS], [test "x$enable_tools" = "xyes"])
 425
 426 # Build the liblxc commands
 427 AC_ARG_ENABLE([commands],
 428         [AC_HELP_STRING([--enable-commands], [build the liblxc commands [default=yes]])],
 429         [], [enable_commands=yes])
 430 AM_CONDITIONAL([ENABLE_COMMANDS], [test "x$enable_commands" = "xyes"])
 431
 432 # Build with ASAN commands
 433 AC_ARG_ENABLE([asan],
 434         [AC_HELP_STRING([--enable-asan], [build with address sanitizer enabled [default=no]])],
 435         [], [enable_asan=no])
 436 AM_CONDITIONAL([ENABLE_ASAN], [test "x$enable_asan" = "xyes"])
 437
 438 # Optional test binaries
 439 AC_ARG_ENABLE([tests],
 440         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 441         [], [enable_tests=no])
 442 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 443
 444 # Allow overriding the default runtime dir (/run)
 445 AC_ARG_WITH([runtime-path],
 446         [AC_HELP_STRING(
 447                 [--with-runtime-path=dir],
 448                 [runtime directory (default: /run)]
 449         )], [], [with_runtime_path=['/run']])
 450
 451 # LXC container path, where the containers are actually stored
 452 # This is overridden by an entry in the file called LXCCONF
 453 # (i.e. /etc/lxc/lxc.conf)
 454 AC_ARG_WITH([config-path],
 455         [AC_HELP_STRING(
 456                 [--with-config-path=dir],
 457                 [lxc configuration repository path]
 458         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 459
 460 # The path of the global lxc configuration file.
 461 AC_ARG_WITH([global-conf],
 462         [AC_HELP_STRING(
 463                 [--with-global-conf=dir],
 464                 [global lxc configuration file]
 465         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 466
 467 # The path of the userns network configuration file
 468 AC_ARG_WITH([usernic-conf],
 469         [AC_HELP_STRING(
 470                 [--with-usernic-conf],
 471                 [user network interface configuration file]
 472         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 473
 474 # The path of the runtime usernic database
 475 AC_ARG_WITH([usernic-db],
 476         [AC_HELP_STRING(
 477                 [--with-usernic-db],
 478                 [lxc user nic database]
 479         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 480
 481 # Rootfs path, where the container mount structure is assembled
 482 AC_ARG_WITH([rootfs-path],
 483         [AC_HELP_STRING(
 484                 [--with-rootfs-path=dir],
 485                 [lxc rootfs mount point]
 486         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 487
 488 # cgroup pattern specification
 489 AC_ARG_WITH([cgroup-pattern],
 490         [AC_HELP_STRING(
 491                 [--with-cgroup-pattern=pattern],
 492                 [pattern for container cgroups]
 493         )], [], [with_cgroup_pattern=['lxc.payload/%n']])
 494
 495 # The path for the apparmor_parser's cache for generated apparmor profiles
 496 AC_ARG_WITH([apparmor-cache-dir],
 497         [AC_HELP_STRING(
 498                 [--with-apparmor-cache-dir=dir],
 499                 [path for apparmor_parser cache]
 500         )], [], [with_apparmor_cache_dir=['${localstatedir}/cache/lxc/apparmor']])
 501
 502 # Container log path.  By default, use $lxcpath.
 503 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 504 AC_ARG_ENABLE([configpath-log],
 505         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 506         [], [enable_configpath_log=no])
 507 AC_MSG_RESULT([$enable_configpath_log])
 508 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 509
 510 if test "$enable_configpath_log" = "yes"; then
 511         default_log_path="${with_config_path}"
 512 else
 513         default_log_path="${localstatedir}/log/lxc"
 514 fi
 515
 516 AC_ARG_WITH([log-path],
 517         [AC_HELP_STRING(
 518                 [--with-log-path=dir],
 519                 [per container log path]
 520         )], [], [with_log_path=['${default_log_path}']])
 521
 522 # Expand some useful variables
 523 AS_AC_EXPAND(PREFIX, "$prefix")
 524 AS_AC_EXPAND(LIBDIR, "$libdir")
 525 AS_AC_EXPAND(BINDIR, "$bindir")
 526 AS_AC_EXPAND(SBINDIR, "$sbindir")
 527 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 528 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 529 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 530 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 531 AS_AC_EXPAND(DATADIR, "$datadir")
 532 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 533 AS_AC_EXPAND(DOCDIR, "$docdir")
 534 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date --utc --date=@${SOURCE_DATE_EPOCH:-$(date +%s)} '+%Y-%m-%d')")
 535 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 536 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 537 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 538 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 539 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 540 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 541 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 542 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 543 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 544 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 545 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 546 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 547 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 548 AS_AC_EXPAND(APPARMOR_CACHE_DIR, "$with_apparmor_cache_dir")
 549 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 550
 551 # We need the install path so criu knows where to reference the hook scripts.
 552 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 553
 554 # Check for some standard kernel headers
 555 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 556                                 [],
 557                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 558                                 [#include <sys/socket.h>])
 559
 560 # Check for alternate C libraries
 561 AC_MSG_CHECKING(for bionic libc)
 562 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 563         [[#ifndef __ANDROID__
 564 error: Not bionic!
 565 #endif]])],
 566         [is_bionic=yes],
 567         [is_bionic=no])
 568 if test "x$is_bionic" = "xyes"; then
 569         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 570         AC_MSG_RESULT([yes])
 571 else
 572         AC_MSG_RESULT([no])
 573 fi
 574 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 575
 576 # Configuration examples
 577 AC_ARG_ENABLE([pam],
 578         [AC_HELP_STRING([--enable-pam], [enable pam module [default=no]])],
 579         [], [enable_pam=no])
 580 AM_CONDITIONAL([ENABLE_PAM], [test "x$enable_pam" = "xyes"])
 581
 582 AM_COND_IF([ENABLE_PAM],
 583         [AC_ARG_WITH(
 584                 [pamdir],
 585                 [AS_HELP_STRING([--with-pamdir=PATH],[Specify the directory where PAM modules are stored,
 586                                                         or "none" if PAM modules are not to be built])],
 587                 [pamdir="${withval}"],
 588                 [
 589                         if test "${prefix}" = "/usr"; then
 590                                 pamdir="/lib${libdir##*/lib}/security"
 591                         else
 592                                 pamdir="\$(libdir)/security"
 593                         fi
 594                 ]
 595         )])
 596
 597 AM_CONDITIONAL([HAVE_PAM], [test x"$pamdir" != "xnone"])
 598 AM_COND_IF([ENABLE_PAM],
 599         [if test "z$pamdir" != "znone"; then
 600                 AC_ARG_VAR([PAM_CFLAGS], [C compiler flags for pam])
 601                 AC_ARG_VAR([PAM_LIBS], [linker flags for pam])
 602                 AC_CHECK_LIB(
 603                         [pam],
 604                         [pam_authenticate],
 605                         [PAM_LIBS="-lpam"],
 606                         [AC_MSG_ERROR([*** libpam not found.])
 607                         ])
 608
 609                 AC_SUBST(PAM_LIBS)
 610                 AC_SUBST([pamdir])
 611         fi])
 612
 613 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 614 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 615
 616 # Some systems lack PR_{G,S}ET_NO_NEW_PRIVS definition => HAVE_DECL_PR_{G,S}ET_NO_NEW_PRIVS
 617 AC_CHECK_DECLS([PR_SET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 618 AC_CHECK_DECLS([PR_GET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 619
 620 # Check for some headers
 621 AC_CHECK_HEADERS([pty.h sys/memfd.h sys/personality.h sys/resource.h sys/signalfd.h sys/timerfd.h utmpx.h])
 622
 623 AC_CHECK_HEADER([ifaddrs.h],
 624         AM_CONDITIONAL(HAVE_IFADDRS_H, true)
 625         AC_DEFINE(HAVE_IFADDRS_H, 1, [Have ifaddrs.h]),
 626         AM_CONDITIONAL(HAVE_IFADDRS_H, false))
 627
 628 # lookup major()/minor()/makedev()
 629 AC_HEADER_MAJOR
 630
 631 # Check for some syscalls functions
 632 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat gettid memfd_create])
 633
 634 # Check for strerror_r() support. Defines:
 635 # - HAVE_STRERROR_R if available
 636 # - HAVE_DECL_STRERROR_R if defined
 637 # - STRERROR_R_CHAR_P if it returns char *
 638 AC_FUNC_STRERROR_R
 639
 640 # Check if "%m" is supported by printf and Co
 641 AC_MSG_CHECKING([%m format])
 642 AC_TRY_RUN([
 643 #include <stdio.h>
 644 int main(void)
 645 {
 646   char msg[256];
 647   int rc;
 648
 649   rc = snprintf(msg, sizeof(msg), "%m\n");
 650   if ((rc > 1) && (msg[0] != '%'))
 651   {
 652     return 0;
 653   }
 654   else
 655   {
 656     return 1;
 657   }
 658 }],
 659 [fmt_m=yes], [fmt_m=no],, [fmt_m=no])
 660 if test "x$fmt_m" = "xyes"; then
 661         AC_DEFINE([HAVE_M_FORMAT], 1, [Have %m format])
 662         AC_MSG_RESULT([yes])
 663 else
 664         AC_MSG_RESULT([no])
 665 fi
 666
 667 # Check for some functions
 668 AC_CHECK_LIB(pthread, main)
 669 AC_CHECK_FUNCS(statvfs)
 670 AC_CHECK_LIB(util, openpty)
 671 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 672 AC_CHECK_FUNCS([getgrgid_r],
 673         AM_CONDITIONAL(HAVE_GETGRGID_R, true)
 674         AC_DEFINE(HAVE_GETGRGID_R,1,[Have getgrgid_r]),
 675         AM_CONDITIONAL(HAVE_GETGRGID_R, false))
 676 AC_CHECK_FUNCS([getline],
 677         AM_CONDITIONAL(HAVE_GETLINE, true)
 678         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 679         AM_CONDITIONAL(HAVE_GETLINE, false))
 680 AC_CHECK_FUNCS([getsubopt],
 681         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 682         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 683         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 684 AC_CHECK_FUNCS([fgetln],
 685         AM_CONDITIONAL(HAVE_FGETLN, true)
 686         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 687         AM_CONDITIONAL(HAVE_FGETLN, false))
 688 AC_CHECK_FUNCS([keyctl],
 689         AM_CONDITIONAL(HAVE_KEYCTL, true)
 690         AC_DEFINE(HAVE_KEYCTL,1,[Have keyctl]),
 691         AM_CONDITIONAL(HAVE_KEYCTL, false))
 692 AC_CHECK_FUNCS([prlimit],
 693         AM_CONDITIONAL(HAVE_PRLIMIT, true)
 694         AC_DEFINE(HAVE_PRLIMIT,1,[Have prlimit]),
 695         AM_CONDITIONAL(HAVE_PRLIMIT, false))
 696 AC_CHECK_FUNCS([prlimit64],
 697         AM_CONDITIONAL(HAVE_PRLIMIT64, true)
 698         AC_DEFINE(HAVE_PRLIMIT64,1,[Have prlimit64]),
 699         AM_CONDITIONAL(HAVE_PRLIMIT64, false))
 700 AC_CHECK_FUNCS([pthread_setcancelstate],
 701         AM_CONDITIONAL(HAVE_PTHREAD_SETCANCELSTATE, true)
 702         AC_DEFINE(HAVE_PTHREAD_SETCANCELSTATE,1,[Have pthread_setcancelstate]),
 703         AM_CONDITIONAL(HAVE_PTHREAD_SETCANCELSTATE, false))
 704 AC_CHECK_FUNCS([strlcpy],
 705         AM_CONDITIONAL(HAVE_STRLCPY, true)
 706         AC_DEFINE(HAVE_STRLCPY,1,[Have strlcpy]),
 707         AM_CONDITIONAL(HAVE_STRLCPY, false))
 708 AC_CHECK_FUNCS([strlcat],
 709         AM_CONDITIONAL(HAVE_STRLCAT, true)
 710         AC_DEFINE(HAVE_STRLCAT,1,[Have strlcat]),
 711         AM_CONDITIONAL(HAVE_STRLCAT, false))
 712
 713 # HAVE_STRUCT_RTNL_LINK_STATS64={0,1}
 714 AC_CHECK_TYPES([struct rtnl_link_stats64], [], [], [[#include <linux/if_link.h>]])
 715
 716 # Check for some libraries
 717 AX_PTHREAD
 718 AC_SEARCH_LIBS(clock_gettime, [rt])
 719
 720 # Check for some standard binaries
 721 AC_PROG_GCC_TRADITIONAL
 722 AC_PROG_SED
 723
 724 # See if we support thread-local storage.
 725 LXC_CHECK_TLS
 726
 727 # Hardening flags
 728 AX_CHECK_COMPILE_FLAG([-fdiagnostics-color], [CFLAGS="$CFLAGS -fdiagnostics-color"],,[-Werror])
 729 AX_CHECK_COMPILE_FLAG([-Wimplicit-fallthrough=5], [CFLAGS="$CFLAGS -Wimplicit-fallthrough=5"],,[-Werror])
 730 AX_CHECK_COMPILE_FLAG([-Wcast-align], [CFLAGS="$CFLAGS -Wcast-align"],,[-Werror])
 731 AX_CHECK_COMPILE_FLAG([-Wstrict-prototypes], [CFLAGS="$CFLAGS -Wstrict-prototypes"],,[-Werror])
 732 AX_CHECK_COMPILE_FLAG([-fno-strict-aliasing], [CFLAGS="$CFLAGS -fno-strict-aliasing"],,[-Werror])
 733 AX_CHECK_COMPILE_FLAG([-fstack-clash-protection], [CFLAGS="$CFLAGS -fstack-clash-protection"],,[-Werror])
 734 AX_CHECK_COMPILE_FLAG([-fstack-protector-strong], [CFLAGS="$CFLAGS -fstack-protector-strong"],,[-Werror])
 735 AX_CHECK_COMPILE_FLAG([--param=ssp-buffer-size=4], [CFLAGS="$CFLAGS --param=ssp-buffer-size=4"],,[-Werror])
 736 AX_CHECK_COMPILE_FLAG([-g], [CFLAGS="$CFLAGS -g"],,[-Werror])
 737 AX_CHECK_COMPILE_FLAG([--mcet -fcf-protection], [CFLAGS="$CFLAGS --mcet -fcf-protection"],,[-Werror])
 738 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"],,[-Werror])
 739 AX_CHECK_COMPILE_FLAG([-Wlogical-op], [CFLAGS="$CFLAGS -Wlogical-op"],,[-Werror])
 740 AX_CHECK_COMPILE_FLAG([-Wmissing-include-dirs], [CFLAGS="$CFLAGS -Wmissing-include-dirs"],,[-Werror])
 741 AX_CHECK_COMPILE_FLAG([-Wold-style-definition], [CFLAGS="$CFLAGS -Wold-style-definition"],,[-Werror])
 742 AX_CHECK_COMPILE_FLAG([-Winit-self], [CFLAGS="$CFLAGS -Winit-self"],,[-Werror])
 743 AX_CHECK_COMPILE_FLAG([-Wfloat-equal], [CFLAGS="$CFLAGS -Wfloat-equal"],,[-Werror])
 744 AX_CHECK_COMPILE_FLAG([-Wsuggest-attribute=noreturn], [CFLAGS="$CFLAGS -Wsuggest-attribute=noreturn"],,[-Werror])
 745 AX_CHECK_COMPILE_FLAG([-Werror=return-type], [CFLAGS="$CFLAGS -Werror=return-type"],,[-Werror])
 746 AX_CHECK_COMPILE_FLAG([-Werror=incompatible-pointer-types], [CFLAGS="$CFLAGS -Werror=incompatible-pointer-types"],,[-Werror])
 747 AX_CHECK_COMPILE_FLAG([-Wformat=2], [CFLAGS="$CFLAGS -Wformat=2"],,[-Werror])
 748 AX_CHECK_COMPILE_FLAG([-Wshadow], [CFLAGS="$CFLAGS -Wshadow"],,[-Werror])
 749 AX_CHECK_COMPILE_FLAG([-Wendif-labels], [CFLAGS="$CFLAGS -Wendif-labels"],,[-Werror])
 750 AX_CHECK_COMPILE_FLAG([-Werror=overflow], [CFLAGS="$CFLAGS -Werror=overflow"],,[-Werror])
 751 AX_CHECK_COMPILE_FLAG([-fdiagnostics-show-option], [CFLAGS="$CFLAGS -fdiagnostics-show-option"],,[-Werror])
 752 AX_CHECK_COMPILE_FLAG([-Werror=shift-count-overflow], [CFLAGS="$CFLAGS -Werror=shift-count-overflow"],,[-Werror])
 753 AX_CHECK_COMPILE_FLAG([-Werror=shift-overflow=2], [CFLAGS="$CFLAGS -Werror=shift-overflow=2"],,[-Werror])
 754 AX_CHECK_COMPILE_FLAG([-Wdate-time], [CFLAGS="$CFLAGS -Wdate-time"],,[-Werror])
 755 AX_CHECK_COMPILE_FLAG([-Wnested-externs], [CFLAGS="$CFLAGS -Wnested-externs"],,[-Werror])
 756 AX_CHECK_COMPILE_FLAG([-fasynchronous-unwind-tables], [CFLAGS="$CFLAGS -fasynchronous-unwind-tables"],,[-Werror])
 757 AX_CHECK_COMPILE_FLAG([-pipe], [CFLAGS="$CFLAGS -pipe"],,[-Werror])
 758 AX_CHECK_COMPILE_FLAG([-fexceptions], [CFLAGS="$CFLAGS -fexceptions"],,[-Werror])
 759
 760 AX_CHECK_LINK_FLAG([-z relro], [LDFLAGS="$LDFLAGS -z relro"],,[])
 761 AX_CHECK_LINK_FLAG([-z now], [LDFLAGS="$LDFLAGS -z now"],,[])
 762
 763 CFLAGS="$CFLAGS -Wvla -std=gnu11"
 764 if test "x$enable_werror" = "xyes"; then
 765         CFLAGS="$CFLAGS -Werror"
 766 fi
 767
 768 AC_ARG_ENABLE([thread-safety],
 769         [AC_HELP_STRING([--enable-thread-safety], [enforce thread-safety otherwise fail the build [default=yes]])],
 770         [], [enable_thread_safety=yes])
 771 AM_CONDITIONAL([ENFORCE_THREAD_SAFETY], [test "x$enable_thread_safety" = "xyes"])
 772
 773 AC_ARG_ENABLE([dlog],
 774         [AC_HELP_STRING([--enable-dlog], [enable dlog support [default=no]])],
 775         [], [enable_dlog=no])
 776 AM_CONDITIONAL([ENABLE_DLOG], [test "x$enable_dlog" = "xyes"])
 777
 778 AM_COND_IF([ENABLE_DLOG],
 779         [PKG_CHECK_MODULES([DLOG],[dlog],[],[
 780                 AC_CHECK_HEADER([dlog.h],[],[AC_MSG_ERROR([You must install the dlog development package in order to compile lxc])])
 781                 AC_CHECK_LIB([dlog], [dlog_print],[],[AC_MSG_ERROR([You must install the dlog development package in order to compile lxc])])
 782                 AC_SUBST([DLOG_LIBS], [-ldlog])
 783                 ])
 784         ])
 785
 786 AC_ARG_ENABLE([memfd-rexec],
 787         [AC_HELP_STRING([--enable-memfd-rexec], [enforce liblxc as a memfd to protect against certain symlink attacks [default=yes]])],
 788         [], [enable_memfd_rexec=yes])
 789 AM_CONDITIONAL([ENFORCE_MEMFD_REXEC], [test "x$enable_memfd_rexec" = "xyes"])
 790 if test "x$enable_memfd_rexec" = "xyes"; then
 791         AC_DEFINE([ENFORCE_MEMFD_REXEC], 1, [Rexec liblxc as memfd])
 792         AC_MSG_RESULT([yes])
 793 else
 794         AC_MSG_RESULT([no])
 795 fi
 796
 797 # Files requiring some variable expansion
 798 AC_CONFIG_FILES([
 799         Makefile
 800         lxc.pc
 801         lxc.spec
 802
 803         config/Makefile
 804         config/apparmor/Makefile
 805         config/apparmor/abstractions/start-container
 806         config/selinux/Makefile
 807         config/bash/Makefile
 808         config/bash/lxc
 809         config/init/Makefile
 810         config/init/common/Makefile
 811         config/init/common/lxc-containers
 812         config/init/common/lxc-net
 813         config/init/systemd/Makefile
 814         config/init/systemd/lxc.service
 815         config/init/systemd/lxc@.service
 816         config/init/systemd/lxc-net.service
 817         config/init/sysvinit/Makefile
 818         config/init/sysvinit/lxc-containers
 819         config/init/sysvinit/lxc-net
 820         config/init/upstart/lxc.conf
 821         config/init/upstart/lxc-net.conf
 822         config/init/upstart/Makefile
 823         config/etc/Makefile
 824         config/templates/Makefile
 825         config/templates/common.conf
 826         config/templates/common.conf.d/Makefile
 827         config/templates/nesting.conf
 828         config/templates/oci.common.conf
 829         config/templates/userns.conf
 830         config/yum/Makefile
 831         config/sysconfig/Makefile
 832         config/sysconfig/lxc
 833
 834         doc/Makefile
 835         doc/api/Makefile
 836         doc/lxc-attach.sgml
 837         doc/lxc-autostart.sgml
 838         doc/lxc-cgroup.sgml
 839         doc/lxc-checkconfig.sgml
 840         doc/lxc-checkpoint.sgml
 841         doc/lxc-config.sgml
 842         doc/lxc-console.sgml
 843         doc/lxc-copy.sgml
 844         doc/lxc-create.sgml
 845         doc/lxc-destroy.sgml
 846         doc/lxc-device.sgml
 847         doc/lxc-execute.sgml
 848         doc/lxc-freeze.sgml
 849         doc/lxc-info.sgml
 850         doc/lxc-ls.sgml
 851         doc/lxc-monitor.sgml
 852         doc/lxc-snapshot.sgml
 853         doc/lxc-start.sgml
 854         doc/lxc-stop.sgml
 855         doc/lxc-top.sgml
 856         doc/lxc-unfreeze.sgml
 857         doc/lxc-unshare.sgml
 858         doc/lxc-update-config.sgml
 859         doc/lxc-user-nic.sgml
 860         doc/lxc-usernsexec.sgml
 861         doc/lxc-wait.sgml
 862
 863         doc/lxc.conf.sgml
 864         doc/lxc.container.conf.sgml
 865         doc/lxc.system.conf.sgml
 866         doc/lxc-usernet.sgml
 867         doc/lxc.sgml
 868         doc/common_options.sgml
 869         doc/see_also.sgml
 870
 871         doc/rootfs/Makefile
 872
 873         doc/examples/Makefile
 874         doc/examples/lxc-macvlan.conf
 875         doc/examples/lxc-vlan.conf
 876         doc/examples/lxc-no-netns.conf
 877         doc/examples/lxc-empty-netns.conf
 878         doc/examples/lxc-phys.conf
 879         doc/examples/lxc-veth.conf
 880         doc/examples/lxc-complex.conf
 881
 882         doc/ja/Makefile
 883         doc/ja/lxc-attach.sgml
 884         doc/ja/lxc-autostart.sgml
 885         doc/ja/lxc-cgroup.sgml
 886         doc/ja/lxc-checkconfig.sgml
 887         doc/ja/lxc-checkpoint.sgml
 888         doc/ja/lxc-config.sgml
 889         doc/ja/lxc-console.sgml
 890         doc/ja/lxc-copy.sgml
 891         doc/ja/lxc-create.sgml
 892         doc/ja/lxc-destroy.sgml
 893         doc/ja/lxc-device.sgml
 894         doc/ja/lxc-execute.sgml
 895         doc/ja/lxc-freeze.sgml
 896         doc/ja/lxc-info.sgml
 897         doc/ja/lxc-ls.sgml
 898         doc/ja/lxc-monitor.sgml
 899         doc/ja/lxc-snapshot.sgml
 900         doc/ja/lxc-start.sgml
 901         doc/ja/lxc-stop.sgml
 902         doc/ja/lxc-top.sgml
 903         doc/ja/lxc-unfreeze.sgml
 904         doc/ja/lxc-unshare.sgml
 905         doc/ja/lxc-update-config.sgml
 906         doc/ja/lxc-user-nic.sgml
 907         doc/ja/lxc-usernsexec.sgml
 908         doc/ja/lxc-wait.sgml
 909
 910         doc/ja/lxc.conf.sgml
 911         doc/ja/lxc.container.conf.sgml
 912         doc/ja/lxc.system.conf.sgml
 913         doc/ja/lxc-usernet.sgml
 914         doc/ja/lxc.sgml
 915         doc/ja/common_options.sgml
 916         doc/ja/see_also.sgml
 917
 918         doc/ko/Makefile
 919         doc/ko/lxc-attach.sgml
 920         doc/ko/lxc-autostart.sgml
 921         doc/ko/lxc-cgroup.sgml
 922         doc/ko/lxc-checkconfig.sgml
 923         doc/ko/lxc-checkpoint.sgml
 924         doc/ko/lxc-config.sgml
 925         doc/ko/lxc-console.sgml
 926         doc/ko/lxc-copy.sgml
 927         doc/ko/lxc-create.sgml
 928         doc/ko/lxc-destroy.sgml
 929         doc/ko/lxc-device.sgml
 930         doc/ko/lxc-execute.sgml
 931         doc/ko/lxc-freeze.sgml
 932         doc/ko/lxc-info.sgml
 933         doc/ko/lxc-ls.sgml
 934         doc/ko/lxc-monitor.sgml
 935         doc/ko/lxc-snapshot.sgml
 936         doc/ko/lxc-start.sgml
 937         doc/ko/lxc-stop.sgml
 938         doc/ko/lxc-top.sgml
 939         doc/ko/lxc-unfreeze.sgml
 940         doc/ko/lxc-unshare.sgml
 941         doc/ko/lxc-user-nic.sgml
 942         doc/ko/lxc-usernsexec.sgml
 943         doc/ko/lxc-wait.sgml
 944
 945         doc/ko/lxc.conf.sgml
 946         doc/ko/lxc.container.conf.sgml
 947         doc/ko/lxc.system.conf.sgml
 948         doc/ko/lxc-usernet.sgml
 949         doc/ko/lxc.sgml
 950         doc/ko/common_options.sgml
 951         doc/ko/see_also.sgml
 952
 953         hooks/Makefile
 954         hooks/dhclient
 955
 956         templates/Makefile
 957         templates/lxc-busybox
 958         templates/lxc-download
 959         templates/lxc-local
 960         templates/lxc-oci
 961
 962         src/Makefile
 963         src/lxc/Makefile
 964         src/lxc/lxc.functions
 965         src/lxc/cmd/lxc-checkconfig
 966         src/lxc/cmd/lxc-update-config
 967         src/lxc/version.h
 968
 969         src/tests/Makefile
 970         src/tests/lxc-test-usernic
 971 ])
 972 AC_CONFIG_COMMANDS([default],[[]],[[]])
 973 AC_OUTPUT
 974
 975 # Configuration overview
 976 cat << EOF
 977
 978 ----------------------------
 979 Binaries
 980  - Command Line Tools:
 981    - lxc-attach:     $enable_tools
 982    - lxc-autostart:  $enable_tools
 983    - lxc-cgroup:     $enable_tools
 984    - lxc-checkpoint: $enable_tools
 985    - lxc-config:     $enable_tools
 986    - lxc-console:    $enable_tools
 987    - lxc-copy:       $enable_tools
 988    - lxc-create:     $enable_tools
 989    - lxc-destroy:    $enable_tools
 990    - lxc-device:     $enable_tools
 991    - lxc-execute:    $enable_tools
 992    - lxc-freeze:     $enable_tools
 993    - lxc-info:       $enable_tools
 994    - lxc-ls:         $enable_tools
 995    - lxc-monitor:    $enable_tools
 996    - lxc-snapshot:   $enable_tools
 997    - lxc-start:      $enable_tools
 998    - lxc-stop:       $enable_tools
 999    - lxc-top:        $enable_tools
1000    - lxc-unfreeze:   $enable_tools
1001    - lxc-unshare:    $enable_tools
1002    - lxc-wait:       $enable_tools
1003
1004  - liblxc Commands:
1005    - lxc-checkconfig:   $enable_commands
1006    - lxc-update-config: $enable_commands
1007    - lxc-init:          $enable_commands
1008    - lxc-monitord:      $enable_commands
1009    - lxc-user-nic:      $enable_commands
1010    - lxc-usernsexec:    $enable_commands
1011
1012 Environment:
1013  - compiler: $CC
1014  - distribution: $with_distro
1015  - init script type(s): $init_script
1016  - rpath: $enable_rpath
1017  - GnuTLS: $enable_gnutls
1018  - Bash integration: $enable_bash
1019
1020 Security features:
1021  - Apparmor: $enable_apparmor
1022  - Linux capabilities: $enable_capabilities
1023  - seccomp: $enable_seccomp
1024  - SELinux: $enable_selinux
1025  - memfd rexec: $enable_memfd_rexec
1026
1027 PAM:
1028  - PAM module: $enable_pam
1029  - cgroup PAM module: $pamdir
1030
1031 Documentation:
1032  - examples: $enable_examples
1033  - API documentation: $enable_api_docs
1034  - user documentation: $enable_doc
1035
1036 Debugging:
1037  - tests: $enable_tests
1038  - ASAN: $enable_asan
1039  - mutex debugging: $enable_mutex_debugging
1040
1041 Paths:
1042  - Logs in configpath: $enable_configpath_log
1043
1044 Thread-safety:
1045  - enforce: $enable_thread_safety
1046
1047 Dlog:
1048  - enable: $enable_dlog
1049 EOF