configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_devel], 0)
   5 m4_define([lxc_version_major], 3)
   6 m4_define([lxc_version_minor], 0)
   7 m4_define([lxc_version_micro], 0)
   8 m4_define([lxc_version_beta], [])
   9
  10 m4_define([lxc_abi_major], 1)
  11 m4_define([lxc_abi_minor], 4)
  12 m4_define([lxc_abi_micro], 0)
  13 m4_define([lxc_abi], [lxc_abi_major.lxc_abi_minor.lxc_abi_micro])
  14
  15 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  16 m4_define([lxc_version],
  17           [ifelse(lxc_devel, 1,
  18         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])-devel,
  19         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta]))])
  20
  21 AC_INIT([lxc], [lxc_version])
  22
  23 # We need pkg-config
  24 PKG_PROG_PKG_CONFIG
  25
  26 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  27 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  28
  29 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  30 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  31 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  32 AC_SUBST([LXC_VERSION], [lxc_version])
  33 AC_SUBST([LXC_DEVEL], [lxc_devel])
  34
  35 AC_SUBST([LXC_ABI_MAJOR], [lxc_abi_major])
  36 AC_SUBST([LXC_ABI_MINOR], [lxc_abi_minor])
  37 AC_SUBST([LXC_ABI_MICRO], [lxc_abi_micro])
  38 AC_SUBST([LXC_ABI], [lxc_abi])
  39
  40 AC_CONFIG_SRCDIR([configure.ac])
  41 AC_CONFIG_AUX_DIR([config])
  42 AC_CONFIG_HEADERS([src/config.h])
  43 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  44 AC_CANONICAL_HOST
  45 AM_PROG_CC_C_O
  46 AC_GNU_SOURCE
  47
  48 # libtool
  49 LT_INIT
  50 AC_SUBST([LIBTOOL_DEPS])
  51
  52 # Detect the distribution. This is used for the default configuration and
  53 # for some distro-specific build options.
  54 AC_MSG_CHECKING([host distribution])
  55 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, redhatenterpriseserver, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva, pardus, sparclinux, altlinux.]))
  56 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  57         with_distro=`lsb_release -is`
  58 fi
  59 if test "z$with_distro" = "z"; then
  60         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  61         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  62         AC_CHECK_FILE(/etc/sparclinux-release,with_distro="sparclinux")
  63         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  64         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  65         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  66         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  67         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  68         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  69         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  70         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
  71         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  72         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  73         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  74         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  75         AC_CHECK_FILE(/etc/altlinux-release,with_distro="altlinux")
  76         AC_CHECK_FILE(/etc/pld-release,with_distro="pld")
  77 fi
  78 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  79
  80 if test "z$with_distro" = "zforsparc"; then
  81         with_distro="sparclinux"
  82 fi
  83
  84 if test "z$with_distro" = "z"; then
  85         with_distro="unknown"
  86 fi
  87 case $with_distro in
  88         ubuntu|raspbian)
  89                 distroconf=default.conf.lxcbr
  90                 distrosysconf="$sysconfdir/default"
  91                 ;;
  92         redhat|redhatenterpriseserver|centos|fedora|oracle|oracleserver|sparclinux|altlinux|suse|opensuse*|plamo|pld)
  93                 distroconf=default.conf.lxcbr
  94                 distrosysconf="$sysconfdir/sysconfig"
  95                 ;;
  96         *)
  97                 distroconf=default.conf.unknown
  98                 distrosysconf="$sysconfdir/default"
  99                 ;;
 100 esac
 101 AC_MSG_RESULT([$with_distro])
 102 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
 103 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
 104
 105 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
 106
 107 # Check for init system type
 108 AC_MSG_CHECKING([for init system type])
 109 AC_ARG_WITH([init-script],
 110             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
 111                             [Type(s) of init script to install: sysvinit, systemd, upstart,
 112                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
 113 case "$with_init_script" in
 114         distro)
 115                 case $with_distro in
 116                         fedora|altlinux|opensuse*)
 117                                 init_script=systemd
 118                                 ;;
 119                         redhat|redhatenterpriseserver|oracle|oracleserver|sparclinux|plamo)
 120                                 init_script=sysvinit
 121                                 ;;
 122                         centos)
 123                                 init_script=sysvinit,systemd
 124                                 ;;
 125                         debian|raspbian|ubuntu)
 126                                 init_script=upstart,systemd
 127                                 ;;
 128                         pld)
 129                                 init_script=sysvinit,upstart,systemd
 130                                 ;;
 131                         *)
 132                                 echo -n "Linux distribution init system unknown."
 133                                 init_script=
 134                                 ;;
 135                 esac
 136                 ;;
 137         *)
 138                 init_script=$with_init_script
 139                 ;;
 140 esac
 141
 142 # Check valid init systems were given, run in subshell so we don't mess up IFS
 143 (IFS="," ; for init_sys in $init_script;
 144 do
 145         case "$init_sys" in
 146                 none|sysvinit|systemd|upstart)
 147                         ;;
 148                 *)
 149                         exit 1
 150                         ;;
 151         esac
 152 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 153
 154 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 155 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 156 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 157 AC_MSG_RESULT($init_script)
 158
 159 # systemd unit dir
 160 AC_ARG_WITH([systemdsystemunitdir],
 161             AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 162             [],
 163             [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 164 if test -z "$with_systemdsystemunitdir"; then
 165   with_systemdsystemunitdir=/lib/systemd/system
 166 fi
 167 if test "x$with_systemdsystemunitdir" != "xno"; then
 168   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 169 fi
 170
 171 AC_ARG_ENABLE([werror],
 172         [AC_HELP_STRING([--disable-werror],
 173         [do not treat warnings as errors])],
 174         [], [enable_werror=yes])
 175
 176 # Allow disabling rpath
 177 AC_ARG_ENABLE([rpath],
 178         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 179         [], [enable_rpath=no])
 180 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 181
 182 # Documentation (manpages)
 183 AC_ARG_ENABLE([doc],
 184         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 185         [], [enable_doc=auto])
 186
 187 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 188         db2xman=""
 189         dbparsers="docbook2X2man docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 190
 191         AC_MSG_CHECKING(for docbook2x-man)
 192         for name in ${dbparsers}; do
 193                 if "$name" --help >/dev/null 2>&1; then
 194                         db2xman="$name"
 195                         break;
 196                 fi
 197         done
 198
 199         if test -n "${db2xman}"; then
 200                 AC_MSG_RESULT([${db2xman}])
 201                 enable_doc="yes"
 202         else
 203                 AC_MSG_RESULT([no])
 204                 if test "x$enable_doc" = "xyes"; then
 205                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 206                 fi
 207                 enable_doc="no"
 208         fi
 209
 210         AC_SUBST(db2xman)
 211 fi
 212 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 213 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 214
 215 if test "x$db2xman" = "xdocbook2man"; then
 216         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 217 else
 218         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 219 fi
 220 AC_SUBST(docdtd)
 221
 222 # Documentation (API)
 223 AC_ARG_ENABLE([api-docs],
 224         [AC_HELP_STRING([--enable-api-docs],
 225         [make API documentation [default=auto]])],
 226         [], [enable_api_docs=auto])
 227
 228 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 229         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 230         AC_SUBST([HAVE_DOXYGEN])
 231
 232         if test "x$HAVE_DOXYGEN" != "x"; then
 233                 enable_api_docs="yes"
 234         else
 235                 if test "x$enable_api_docs" = "xyes"; then
 236                         AC_MSG_ERROR([doxygen is required, but could not be found])
 237                 fi
 238                 enable_api_docs="no"
 239         fi
 240 fi
 241
 242 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 243
 244 # Apparmor
 245 AC_ARG_ENABLE([apparmor],
 246         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 247         [], [enable_apparmor=auto])
 248
 249 if test "$enable_apparmor" = "auto" ; then
 250         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 251 fi
 252 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 253
 254 # GnuTLS
 255 AC_ARG_ENABLE([gnutls],
 256         [AC_HELP_STRING([--enable-gnutls], [enable GnuTLS support [default=auto]])],
 257         [], [enable_gnutls=auto])
 258
 259 if test "$enable_gnutls" = "auto" ; then
 260         AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 261 fi
 262 AM_CONDITIONAL([ENABLE_GNUTLS], [test "x$enable_gnutls" = "xyes"])
 263
 264 AM_COND_IF([ENABLE_GNUTLS],
 265         [AC_CHECK_HEADER([gnutls/gnutls.h],[],[AC_MSG_ERROR([You must install the GnuTLS development package in order to compile lxc])])
 266         AC_CHECK_LIB([gnutls], [gnutls_hash_fast],[],[AC_MSG_ERROR([You must install the GnuTLS development package in order to compile lxc])])
 267         AC_SUBST([GNUTLS_LIBS], [-lgnutls])])
 268
 269 # SELinux
 270 AC_ARG_ENABLE([selinux],
 271         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 272         [], [enable_selinux=auto])
 273
 274 if test "x$enable_selinux" = xauto; then
 275         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 276 fi
 277 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 278 AM_COND_IF([ENABLE_SELINUX],
 279         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 280         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 281         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 282
 283 # Seccomp syscall filter
 284 AC_ARG_ENABLE([seccomp],
 285         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 286         [], [enable_seccomp=auto])
 287
 288 if test "x$enable_seccomp" = "xauto" ; then
 289         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 290 fi
 291 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 292
 293 AM_COND_IF([ENABLE_SECCOMP],
 294         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 295                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 296                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 297                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 298                 ])
 299         ])
 300
 301 AC_MSG_CHECKING(for static libcap)
 302 # Check for static libcap, make sure the function checked for differs from the
 303 # the one checked below so the cache doesn't give a wrong answer
 304 OLD_CFLAGS="$CFLAGS"
 305 OLD_CPPFLAGS="$CPPFLAGS"
 306 OLD_LDFLAGS="$LDFLAGS"
 307 OLD_LIBS="$LIBS"
 308 CFLAGS=""
 309 CPPFLAGS=""
 310 LDFLAGS="-static"
 311 LIBS="-lcap"
 312 AC_LINK_IFELSE([
 313   AC_LANG_SOURCE(
 314     [[int main() { return 0; }]]
 315   )],[have_static_libcap=yes],[have_static_libcap=no])
 316 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 317 if test "x$have_static_libcap" = "xyes"; then
 318         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 319         AC_MSG_RESULT([yes])
 320 else
 321         AC_MSG_RESULT([no])
 322 fi
 323 CPPFLAGS="$OLD_CPPFLAGS"
 324 CFLAGS="$OLD_CFLAGS"
 325 LDFLAGS="$OLD_LDFLAGS"
 326 LIBS="$OLD_LIBS"
 327
 328
 329 # Linux capabilities
 330 AC_ARG_ENABLE([capabilities],
 331         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 332         [], [enable_capabilities=auto])
 333
 334 if test "x$enable_capabilities" = "xauto"; then
 335         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 336 fi
 337 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 338
 339 AM_COND_IF([ENABLE_CAP],
 340         [AC_CHECK_HEADER([sys/capability.h],[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 341         AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 342         # Test whether we support getting file capabilities via cap_get_file().
 343         AC_CHECK_LIB(cap,cap_get_file, AC_DEFINE(LIBCAP_SUPPORTS_FILE_CAPABILITIES,1,[Have cap_get_file]),[],[])
 344         AC_SUBST([CAP_LIBS], [-lcap])])
 345
 346 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 347 OLD_CFLAGS="$CFLAGS"
 348 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 349 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 350 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 351 CFLAGS="$OLD_CFLAGS"
 352
 353 # Configuration examples
 354 AC_ARG_ENABLE([examples],
 355         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 356         [], [enable_examples=yes])
 357 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 358
 359 # Enable dumping stack traces
 360 AC_ARG_ENABLE([mutex-debugging],
 361         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 362         [], [enable_mutex_debugging=no])
 363 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 364
 365 AM_COND_IF([MUTEX_DEBUGGING],
 366         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 367
 368 # Not in older autoconf versions
 369 # AS_VAR_COPY(DEST, SOURCE)
 370 # -------------------------
 371 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 372 # shell variable SOURCE.
 373 m4_ifdef([AS_VAR_COPY], [],
 374 [AC_DEFUN([AS_VAR_COPY],
 375     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 376 ])
 377
 378 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 379 m4_ifdef([PKG_CHECK_VAR], [],
 380 [AC_DEFUN([PKG_CHECK_VAR],
 381     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 382      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 383      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 384      AS_VAR_COPY([$1], [pkg_cv_][$1])
 385      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 386     ])# PKG_CHECK_VAR
 387 ])
 388
 389 # Optional bash integration
 390 AC_ARG_ENABLE([bash],
 391         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 392         [], [enable_bash=yes])
 393 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 394
 395 AM_COND_IF([ENABLE_BASH],
 396         [AC_MSG_CHECKING([bash completion directory])
 397         PKG_CHECK_VAR(bashcompdir, [bash-completion], [completionsdir], ,
 398                 bashcompdir="${sysconfdir}/bash_completion.d")
 399         AC_MSG_RESULT([$bashcompdir])
 400         AC_SUBST(bashcompdir)
 401         ])
 402
 403 # Build the command line tools
 404 AC_ARG_ENABLE([tools],
 405         [AC_HELP_STRING([--enable-tools], [build the command line tools [default=yes]])],
 406         [], [enable_tools=yes])
 407 AM_CONDITIONAL([ENABLE_TOOLS], [test "x$enable_tools" = "xyes"])
 408
 409 # Build the liblxc commands
 410 AC_ARG_ENABLE([commands],
 411         [AC_HELP_STRING([--enable-commands], [build the liblxc commands [default=yes]])],
 412         [], [enable_commands=yes])
 413 AM_CONDITIONAL([ENABLE_COMMANDS], [test "x$enable_commands" = "xyes"])
 414
 415 # Optional test binaries
 416 AC_ARG_ENABLE([tests],
 417         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 418         [], [enable_tests=no])
 419 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 420
 421 # Allow overriding the default runtime dir (/run)
 422 AC_ARG_WITH([runtime-path],
 423         [AC_HELP_STRING(
 424                 [--with-runtime-path=dir],
 425                 [runtime directory (default: /run)]
 426         )], [], [with_runtime_path=['/run']])
 427
 428 # LXC container path, where the containers are actually stored
 429 # This is overridden by an entry in the file called LXCCONF
 430 # (i.e. /etc/lxc/lxc.conf)
 431 AC_ARG_WITH([config-path],
 432         [AC_HELP_STRING(
 433                 [--with-config-path=dir],
 434                 [lxc configuration repository path]
 435         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 436
 437 # The path of the global lxc configuration file.
 438 AC_ARG_WITH([global-conf],
 439         [AC_HELP_STRING(
 440                 [--with-global-conf=dir],
 441                 [global lxc configuration file]
 442         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 443
 444 # The path of the userns network configuration file
 445 AC_ARG_WITH([usernic-conf],
 446         [AC_HELP_STRING(
 447                 [--with-usernic-conf],
 448                 [user network interface configuration file]
 449         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 450
 451 # The path of the runtime usernic database
 452 AC_ARG_WITH([usernic-db],
 453         [AC_HELP_STRING(
 454                 [--with-usernic-db],
 455                 [lxc user nic database]
 456         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 457
 458 # Rootfs path, where the container mount structure is assembled
 459 AC_ARG_WITH([rootfs-path],
 460         [AC_HELP_STRING(
 461                 [--with-rootfs-path=dir],
 462                 [lxc rootfs mount point]
 463         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 464
 465 # cgroup pattern specification
 466 AC_ARG_WITH([cgroup-pattern],
 467         [AC_HELP_STRING(
 468                 [--with-cgroup-pattern=pattern],
 469                 [pattern for container cgroups]
 470         )], [], [with_cgroup_pattern=['lxc/%n']])
 471
 472 # Container log path.  By default, use $lxcpath.
 473 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 474 AC_ARG_ENABLE([configpath-log],
 475         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 476         [], [enable_configpath_log=no])
 477 AC_MSG_RESULT([$enable_configpath_log])
 478 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 479
 480 if test "$enable_configpath_log" = "yes"; then
 481         default_log_path="${with_config_path}"
 482 else
 483         default_log_path="${localstatedir}/log/lxc"
 484 fi
 485
 486 AC_ARG_WITH([log-path],
 487         [AC_HELP_STRING(
 488                 [--with-log-path=dir],
 489                 [per container log path]
 490         )], [], [with_log_path=['${default_log_path}']])
 491
 492 # Expand some useful variables
 493 AS_AC_EXPAND(PREFIX, "$prefix")
 494 AS_AC_EXPAND(LIBDIR, "$libdir")
 495 AS_AC_EXPAND(BINDIR, "$bindir")
 496 AS_AC_EXPAND(SBINDIR, "$sbindir")
 497 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 498 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 499 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 500 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 501 AS_AC_EXPAND(DATADIR, "$datadir")
 502 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 503 AS_AC_EXPAND(DOCDIR, "$docdir")
 504 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date --utc --date=@${SOURCE_DATE_EPOCH:-$(date +%s)} '+%Y-%m-%d')")
 505 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 506 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 507 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 508 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 509 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 510 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 511 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 512 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 513 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 514 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 515 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 516 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 517 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 518 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 519
 520 # We need the install path so criu knows where to reference the hook scripts.
 521 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 522
 523 # Check for some standard kernel headers
 524 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 525                                 [],
 526                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 527                                 [#include <sys/socket.h>])
 528
 529 # Check for alternate C libraries
 530 AC_MSG_CHECKING(for bionic libc)
 531 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 532         [[#ifndef __ANDROID__
 533 error: Not bionic!
 534 #endif]])],
 535         [is_bionic=yes],
 536         [is_bionic=no])
 537 if test "x$is_bionic" = "xyes"; then
 538         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 539         AC_MSG_RESULT([yes])
 540 else
 541         AC_MSG_RESULT([no])
 542 fi
 543 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 544
 545 # Configuration examples
 546 AC_ARG_ENABLE([pam],
 547         [AC_HELP_STRING([--enable-pam], [enable pam module [default=no]])],
 548         [], [enable_pam=no])
 549 AM_CONDITIONAL([ENABLE_PAM], [test "x$enable_pam" = "xyes"])
 550
 551 AM_COND_IF([ENABLE_PAM],
 552         [AC_ARG_WITH(
 553                 [pamdir],
 554                 [AS_HELP_STRING([--with-pamdir=PATH],[Specify the directory where PAM modules are stored,
 555                                                         or "none" if PAM modules are not to be built])],
 556                 [pamdir="${withval}"],
 557                 [
 558                         if test "${prefix}" = "/usr"; then
 559                                 pamdir="/lib${libdir##*/lib}/security"
 560                         else
 561                                 pamdir="\$(libdir)/security"
 562                         fi
 563                 ]
 564         )])
 565
 566 AM_CONDITIONAL([HAVE_PAM], [test x"$pamdir" != "xnone"])
 567 AM_COND_IF([ENABLE_PAM],
 568         [if test "z$pamdir" != "znone"; then
 569                 AC_ARG_VAR([PAM_CFLAGS], [C compiler flags for pam])
 570                 AC_ARG_VAR([PAM_LIBS], [linker flags for pam])
 571                 AC_CHECK_LIB(
 572                         [pam],
 573                         [pam_authenticate],
 574                         [PAM_LIBS="-lpam"],
 575                         [AC_MSG_ERROR([*** libpam not found.])
 576                         ])
 577
 578                 AC_SUBST(PAM_LIBS)
 579                 AC_SUBST([pamdir])
 580         fi])
 581
 582 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 583 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 584
 585 # Some systems lack PR_{G,S}ET_NO_NEW_PRIVS definition => HAVE_DECL_PR_{G,S}ET_NO_NEW_PRIVS
 586 AC_CHECK_DECLS([PR_SET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 587 AC_CHECK_DECLS([PR_GET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 588
 589 # Check for some headers
 590 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/memfd.h sys/personality.h utmpx.h sys/timerfd.h sys/resource.h])
 591
 592 # lookup major()/minor()/makedev()
 593 AC_HEADER_MAJOR
 594
 595 # Check for some syscalls functions
 596 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat gettid memfd_create])
 597
 598 # Check for some functions
 599 AC_CHECK_LIB(pthread, main)
 600 AC_CHECK_FUNCS(statvfs)
 601 AC_CHECK_LIB(util, openpty)
 602 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 603 AC_CHECK_FUNCS([getline],
 604         AM_CONDITIONAL(HAVE_GETLINE, true)
 605         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 606         AM_CONDITIONAL(HAVE_GETLINE, false))
 607 AC_CHECK_FUNCS([getsubopt],
 608         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 609         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 610         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 611 AC_CHECK_FUNCS([fgetln],
 612         AM_CONDITIONAL(HAVE_FGETLN, true)
 613         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 614         AM_CONDITIONAL(HAVE_FGETLN, false))
 615 AC_CHECK_FUNCS([prlimit],
 616         AM_CONDITIONAL(HAVE_PRLIMIT, true)
 617         AC_DEFINE(HAVE_PRLIMIT,1,[Have prlimit]),
 618         AM_CONDITIONAL(HAVE_PRLIMIT, false))
 619 AC_CHECK_FUNCS([prlimit64],
 620         AM_CONDITIONAL(HAVE_PRLIMIT64, true)
 621         AC_DEFINE(HAVE_PRLIMIT64,1,[Have prlimit64]),
 622         AM_CONDITIONAL(HAVE_PRLIMIT64, false))
 623
 624 # Check for some libraries
 625 AX_PTHREAD
 626 AC_SEARCH_LIBS(clock_gettime, [rt])
 627
 628 # Check for some standard binaries
 629 AC_PROG_GCC_TRADITIONAL
 630 AC_PROG_SED
 631
 632 # See if we support thread-local storage.
 633 LXC_CHECK_TLS
 634
 635 if test "x$GCC" = "xyes"; then
 636         CFLAGS="$CFLAGS -Wall"
 637         if test "x$enable_werror" = "xyes"; then
 638                 CFLAGS="$CFLAGS -Werror"
 639         fi
 640 fi
 641
 642 # Files requiring some variable expansion
 643 AC_CONFIG_FILES([
 644         Makefile
 645         lxc.pc
 646         lxc.spec
 647
 648         config/Makefile
 649         config/apparmor/Makefile
 650         config/selinux/Makefile
 651         config/bash/Makefile
 652         config/bash/lxc
 653         config/init/Makefile
 654         config/init/common/Makefile
 655         config/init/common/lxc-containers
 656         config/init/common/lxc-net
 657         config/init/systemd/Makefile
 658         config/init/systemd/lxc.service
 659         config/init/systemd/lxc@.service
 660         config/init/systemd/lxc-net.service
 661         config/init/sysvinit/Makefile
 662         config/init/sysvinit/lxc-containers
 663         config/init/sysvinit/lxc-net
 664         config/init/upstart/lxc.conf
 665         config/init/upstart/lxc-net.conf
 666         config/init/upstart/Makefile
 667         config/etc/Makefile
 668         config/templates/Makefile
 669         config/templates/common.conf
 670         config/templates/common.conf.d/Makefile
 671         config/templates/nesting.conf
 672         config/templates/oci.common.conf
 673         config/templates/userns.conf
 674         config/yum/Makefile
 675         config/sysconfig/Makefile
 676         config/sysconfig/lxc
 677
 678         doc/Makefile
 679         doc/api/Makefile
 680         doc/lxc-attach.sgml
 681         doc/lxc-autostart.sgml
 682         doc/lxc-cgroup.sgml
 683         doc/lxc-checkconfig.sgml
 684         doc/lxc-checkpoint.sgml
 685         doc/lxc-config.sgml
 686         doc/lxc-console.sgml
 687         doc/lxc-copy.sgml
 688         doc/lxc-create.sgml
 689         doc/lxc-destroy.sgml
 690         doc/lxc-device.sgml
 691         doc/lxc-execute.sgml
 692         doc/lxc-freeze.sgml
 693         doc/lxc-info.sgml
 694         doc/lxc-ls.sgml
 695         doc/lxc-monitor.sgml
 696         doc/lxc-snapshot.sgml
 697         doc/lxc-start.sgml
 698         doc/lxc-stop.sgml
 699         doc/lxc-top.sgml
 700         doc/lxc-unfreeze.sgml
 701         doc/lxc-unshare.sgml
 702         doc/lxc-update-config.sgml
 703         doc/lxc-user-nic.sgml
 704         doc/lxc-usernsexec.sgml
 705         doc/lxc-wait.sgml
 706
 707         doc/lxc.conf.sgml
 708         doc/lxc.container.conf.sgml
 709         doc/lxc.system.conf.sgml
 710         doc/lxc-usernet.sgml
 711         doc/lxc.sgml
 712         doc/common_options.sgml
 713         doc/see_also.sgml
 714
 715         doc/rootfs/Makefile
 716
 717         doc/examples/Makefile
 718         doc/examples/lxc-macvlan.conf
 719         doc/examples/lxc-vlan.conf
 720         doc/examples/lxc-no-netns.conf
 721         doc/examples/lxc-empty-netns.conf
 722         doc/examples/lxc-phys.conf
 723         doc/examples/lxc-veth.conf
 724         doc/examples/lxc-complex.conf
 725
 726         doc/ja/Makefile
 727         doc/ja/lxc-attach.sgml
 728         doc/ja/lxc-autostart.sgml
 729         doc/ja/lxc-cgroup.sgml
 730         doc/ja/lxc-checkconfig.sgml
 731         doc/ja/lxc-checkpoint.sgml
 732         doc/ja/lxc-config.sgml
 733         doc/ja/lxc-console.sgml
 734         doc/ja/lxc-copy.sgml
 735         doc/ja/lxc-create.sgml
 736         doc/ja/lxc-destroy.sgml
 737         doc/ja/lxc-device.sgml
 738         doc/ja/lxc-execute.sgml
 739         doc/ja/lxc-freeze.sgml
 740         doc/ja/lxc-info.sgml
 741         doc/ja/lxc-ls.sgml
 742         doc/ja/lxc-monitor.sgml
 743         doc/ja/lxc-snapshot.sgml
 744         doc/ja/lxc-start.sgml
 745         doc/ja/lxc-stop.sgml
 746         doc/ja/lxc-top.sgml
 747         doc/ja/lxc-unfreeze.sgml
 748         doc/ja/lxc-unshare.sgml
 749         doc/ja/lxc-update-config.sgml
 750         doc/ja/lxc-user-nic.sgml
 751         doc/ja/lxc-usernsexec.sgml
 752         doc/ja/lxc-wait.sgml
 753
 754         doc/ja/lxc.conf.sgml
 755         doc/ja/lxc.container.conf.sgml
 756         doc/ja/lxc.system.conf.sgml
 757         doc/ja/lxc-usernet.sgml
 758         doc/ja/lxc.sgml
 759         doc/ja/common_options.sgml
 760         doc/ja/see_also.sgml
 761
 762         doc/ko/Makefile
 763         doc/ko/lxc-attach.sgml
 764         doc/ko/lxc-autostart.sgml
 765         doc/ko/lxc-cgroup.sgml
 766         doc/ko/lxc-checkconfig.sgml
 767         doc/ko/lxc-checkpoint.sgml
 768         doc/ko/lxc-config.sgml
 769         doc/ko/lxc-console.sgml
 770         doc/ko/lxc-copy.sgml
 771         doc/ko/lxc-create.sgml
 772         doc/ko/lxc-destroy.sgml
 773         doc/ko/lxc-device.sgml
 774         doc/ko/lxc-execute.sgml
 775         doc/ko/lxc-freeze.sgml
 776         doc/ko/lxc-info.sgml
 777         doc/ko/lxc-ls.sgml
 778         doc/ko/lxc-monitor.sgml
 779         doc/ko/lxc-snapshot.sgml
 780         doc/ko/lxc-start.sgml
 781         doc/ko/lxc-stop.sgml
 782         doc/ko/lxc-top.sgml
 783         doc/ko/lxc-unfreeze.sgml
 784         doc/ko/lxc-unshare.sgml
 785         doc/ko/lxc-user-nic.sgml
 786         doc/ko/lxc-usernsexec.sgml
 787         doc/ko/lxc-wait.sgml
 788
 789         doc/ko/lxc.conf.sgml
 790         doc/ko/lxc.container.conf.sgml
 791         doc/ko/lxc.system.conf.sgml
 792         doc/ko/lxc-usernet.sgml
 793         doc/ko/lxc.sgml
 794         doc/ko/common_options.sgml
 795         doc/ko/see_also.sgml
 796
 797         hooks/Makefile
 798         hooks/dhclient
 799
 800         templates/Makefile
 801         templates/lxc-busybox
 802         templates/lxc-download
 803         templates/lxc-local
 804         templates/lxc-oci
 805
 806         src/Makefile
 807         src/lxc/Makefile
 808         src/lxc/lxc.functions
 809         src/lxc/cmd/lxc-checkconfig
 810         src/lxc/cmd/lxc-update-config
 811         src/lxc/version.h
 812
 813         src/tests/Makefile
 814         src/tests/lxc-test-usernic
 815 ])
 816 AC_CONFIG_COMMANDS([default],[[]],[[]])
 817 AC_OUTPUT
 818
 819 # Configuration overview
 820 cat << EOF
 821
 822 ----------------------------
 823 Binaries
 824  - Command Line Tools:
 825    - lxc-attach:     $enable_tools
 826    - lxc-autostart:  $enable_tools
 827    - lxc-cgroup:     $enable_tools
 828    - lxc-checkpoint: $enable_tools
 829    - lxc-config:     $enable_tools
 830    - lxc-console:    $enable_tools
 831    - lxc-copy:       $enable_tools
 832    - lxc-create:     $enable_tools
 833    - lxc-destroy:    $enable_tools
 834    - lxc-device:     $enable_tools
 835    - lxc-execute:    $enable_tools
 836    - lxc-freeze:     $enable_tools
 837    - lxc-info:       $enable_tools
 838    - lxc-ls:         $enable_tools
 839    - lxc-monitor:    $enable_tools
 840    - lxc-snapshot:   $enable_tools
 841    - lxc-start:      $enable_tools
 842    - lxc-stop:       $enable_tools
 843    - lxc-top:        $enable_tools
 844    - lxc-unfreeze:   $enable_tools
 845    - lxc-unshare:    $enable_tools
 846    - lxc-wait:       $enable_tools
 847
 848  - liblxc Commands:
 849    - lxc-checkconfig:   $enable_commands
 850    - lxc-update-config: $enable_commands
 851    - lxc-init:          $enable_commands
 852    - lxc-monitord:      $enable_commands
 853    - lxc-user-nic:      $enable_commands
 854    - lxc-usernsexec:    $enable_commands
 855
 856 Environment:
 857  - compiler: $CC
 858  - distribution: $with_distro
 859  - init script type(s): $init_script
 860  - rpath: $enable_rpath
 861  - GnuTLS: $enable_gnutls
 862  - Bash integration: $enable_bash
 863
 864 Security features:
 865  - Apparmor: $enable_apparmor
 866  - Linux capabilities: $enable_capabilities
 867  - seccomp: $enable_seccomp
 868  - SELinux: $enable_selinux
 869
 870 PAM:
 871  - PAM module: $enable_pam
 872  - cgroup PAM module: $pamdir
 873
 874 Documentation:
 875  - examples: $enable_examples
 876  - API documentation: $enable_api_docs
 877  - user documentation: $enable_doc
 878
 879 Debugging:
 880  - tests: $enable_tests
 881  - mutex debugging: $enable_mutex_debugging
 882
 883 Paths:
 884  - Logs in configpath: $enable_configpath_log
 885 EOF