configure.ac

   1 AC_PREREQ([2.69])
   2
   3 m4_define([lxc_devel], 1)
   4 m4_define([lxc_version_major], 4)
   5 m4_define([lxc_version_minor], 0)
   6 m4_define([lxc_version_micro], 0)
   7 m4_define([lxc_version_beta], [])
   8
   9 m4_define([lxc_abi_major], 1)
  10 m4_define([lxc_abi_minor], 7)
  11 m4_define([lxc_abi_micro], 0)
  12 m4_define([lxc_abi], [lxc_abi_major.lxc_abi_minor.lxc_abi_micro])
  13
  14 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  15 m4_define([lxc_version],
  16        [ifelse(lxc_devel, 1,
  17         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])-devel,
  18         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta]))])
  19
  20 AC_INIT([lxc],[lxc_version])
  21
  22 # We need pkg-config
  23 PKG_PROG_PKG_CONFIG
  24
  25 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  26 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  27
  28 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  29 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  30 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  31 AC_SUBST([LXC_VERSION], [lxc_version])
  32 AC_SUBST([LXC_DEVEL], [lxc_devel])
  33
  34 AC_SUBST([LXC_ABI_MAJOR], [lxc_abi_major])
  35 AC_SUBST([LXC_ABI_MINOR], [lxc_abi_minor])
  36 AC_SUBST([LXC_ABI_MICRO], [lxc_abi_micro])
  37 AC_SUBST([LXC_ABI], [lxc_abi])
  38
  39 AC_CONFIG_SRCDIR([configure.ac])
  40 AC_CONFIG_AUX_DIR([config])
  41 AC_CONFIG_HEADERS([src/config.h])
  42 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  43 AC_CANONICAL_HOST
  44 AM_PROG_CC_C_O
  45 AC_USE_SYSTEM_EXTENSIONS
  46 AC_SYS_LARGEFILE
  47
  48 # Test if we have a new enough compiler.
  49 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  50 #define GCC_VERSION \
  51         (__GNUC__ * 10000 + __GNUC_MINOR__ * 100 + __GNUC_PATCHLEVEL__)
  52
  53 #define CLANG_VERSION \
  54         (__clang_major__ * 10000 + __clang_minor__ * 100 + __clang_patchlevel__)
  55
  56 #if GCC_VERSION < 40700 && CLANG_VERSION < 10000
  57 #error Sorry, your compiler is too old - please upgrade it
  58 #endif
  59         ]])], [valid_compiler=yes], [valid_compiler=no])
  60 if test "x$valid_compiler" = "xno"; then
  61         AC_MSG_ERROR([Sorry, your compiler is too old - please upgrade it])
  62 fi
  63
  64 AC_PROG_GCC_TRADITIONAL
  65 AC_ENABLE_SHARED
  66 AC_ENABLE_STATIC
  67 # Check binaries
  68 AC_PROG_SED
  69 case $CC in clang*)
  70         AC_CHECK_TOOL([AR], llvm-ar)
  71         AC_CHECK_TOOL([NM], llvm-nm)
  72         AC_CHECK_TOOL([OBJCOPY], llvm-objcopy)
  73         AC_CHECK_TOOL([RANLIB], llvm-ranlib)
  74 esac
  75
  76 # libtool
  77 LT_INIT
  78 AC_SUBST([LIBTOOL_DEPS])
  79
  80 # Detect the distribution. This is used for the default configuration and
  81 # for some distro-specific build options.
  82 AC_MSG_CHECKING([host distribution])
  83 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, redhatenterpriseserver, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva, pardus, sparclinux, altlinux.]))
  84 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  85         with_distro=`lsb_release -is`
  86 fi
  87 if test "z$with_distro" = "z"; then
  88         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  89         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  90         AC_CHECK_FILE(/etc/sparclinux-release,with_distro="sparclinux")
  91         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  92         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  93         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  94         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  95         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  96         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  97         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  98         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
  99         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
 100         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
 101         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
 102         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
 103         AC_CHECK_FILE(/etc/altlinux-release,with_distro="altlinux")
 104         AC_CHECK_FILE(/etc/pld-release,with_distro="pld")
 105 fi
 106 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
 107
 108 if test "z$with_distro" = "zforsparc"; then
 109         with_distro="sparclinux"
 110 fi
 111
 112 if test "z$with_distro" = "z"; then
 113         with_distro="unknown"
 114 fi
 115 case $with_distro in
 116         ubuntu|raspbian)
 117                 distroconf=default.conf.lxcbr
 118                 distrosysconf="$sysconfdir/default"
 119                 ;;
 120         redhat|redhatenterpriseserver|centos|fedora|oracle|oracleserver|sparclinux|altlinux|suse|opensuse*|plamo|pld)
 121                 distroconf=default.conf.lxcbr
 122                 distrosysconf="$sysconfdir/sysconfig"
 123                 ;;
 124         *)
 125                 distroconf=default.conf.unknown
 126                 distrosysconf="$sysconfdir/default"
 127                 ;;
 128 esac
 129 AC_MSG_RESULT([$with_distro])
 130 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
 131 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
 132
 133 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
 134
 135 # Check for init system type
 136 AC_MSG_CHECKING([for init system type])
 137 AC_ARG_WITH([init-script],
 138             [AS_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
 139                             [Type(s) of init script to install: sysvinit, systemd, upstart,
 140                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
 141 case "$with_init_script" in
 142         distro)
 143                 case $with_distro in
 144                         fedora|altlinux|opensuse*)
 145                                 init_script=systemd
 146                                 ;;
 147                         redhat|redhatenterpriseserver|oracle|oracleserver|sparclinux|plamo)
 148                                 init_script=sysvinit
 149                                 ;;
 150                         centos)
 151                                 init_script=sysvinit,systemd
 152                                 ;;
 153                         debian|raspbian|ubuntu)
 154                                 init_script=upstart,systemd
 155                                 ;;
 156                         pld)
 157                                 init_script=sysvinit,upstart,systemd
 158                                 ;;
 159                         *)
 160                                 echo -n "Linux distribution init system unknown."
 161                                 init_script=
 162                                 ;;
 163                 esac
 164                 ;;
 165         *)
 166                 init_script=$with_init_script
 167                 ;;
 168 esac
 169
 170 # Check valid init systems were given, run in subshell so we don't mess up IFS
 171 (IFS="," ; for init_sys in $init_script;
 172 do
 173         case "$init_sys" in
 174                 none|sysvinit|systemd|upstart)
 175                         ;;
 176                 *)
 177                         exit 1
 178                         ;;
 179         esac
 180 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 181
 182 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 183 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 184 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 185 AC_MSG_RESULT($init_script)
 186
 187 # systemd unit dir
 188 AC_ARG_WITH([systemdsystemunitdir],
 189         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 190         [with_systemdsystemunitdir=$withval],
 191         [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 192 if test -z "$with_systemdsystemunitdir"; then
 193   with_systemdsystemunitdir=/lib/systemd/system
 194 fi
 195 if test "x$with_systemdsystemunitdir" != "xno"; then
 196   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 197 fi
 198
 199 AC_ARG_ENABLE([werror],
 200         [AS_HELP_STRING([--disable-werror], [do not treat warnings as errors])],
 201         [enable_werror=$enableval], [enable_werror=yes])
 202
 203 AC_ARG_ENABLE([no_undefined],
 204         [AS_HELP_STRING([--disable-no-undefined], [do not pass -Wl,--no-undefined])],
 205         [enable_no_undefined=$enableval], [enable_no_undefined=yes])
 206 AM_CONDITIONAL([ENABLE_NO_UNDEFINED], [test "x$enable_no_undefined" = "xyes"])
 207
 208 # Allow disabling rpath
 209 AC_ARG_ENABLE([rpath],
 210         [AS_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 211         [enable_rpath=$enableval], [enable_rpath=no])
 212 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 213
 214 # Documentation (manpages)
 215 AC_ARG_ENABLE([doc],
 216         [AS_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 217         [enable_doc=$enableval], [enable_doc=auto])
 218
 219 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 220         db2xman=""
 221         dbparsers="docbook2X2man docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 222
 223         AC_MSG_CHECKING(for docbook2x-man)
 224         for name in ${dbparsers}; do
 225                 if "$name" --help >/dev/null 2>&1; then
 226                         db2xman="$name"
 227                         break;
 228                 fi
 229         done
 230
 231         if test -n "${db2xman}"; then
 232                 AC_MSG_RESULT([${db2xman}])
 233                 enable_doc="yes"
 234         else
 235                 AC_MSG_RESULT([no])
 236                 if test "x$enable_doc" = "xyes"; then
 237                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 238                 fi
 239                 enable_doc="no"
 240         fi
 241
 242         AC_SUBST(db2xman)
 243 fi
 244 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 245 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 246
 247 if test "x$db2xman" = "xdocbook2man"; then
 248         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 249 else
 250         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 251 fi
 252 AC_SUBST(docdtd)
 253
 254 # Documentation (API)
 255 AC_ARG_ENABLE([api-docs],
 256         [AS_HELP_STRING([--enable-api-docs], [make API documentation [default=auto]])],
 257         [enable_api_docs=$enableval], [enable_api_docs=auto])
 258
 259 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 260         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 261         AC_SUBST([HAVE_DOXYGEN])
 262
 263         if test "x$HAVE_DOXYGEN" != "x"; then
 264                 enable_api_docs="yes"
 265         else
 266                 if test "x$enable_api_docs" = "xyes"; then
 267                         AC_MSG_ERROR([doxygen is required, but could not be found])
 268                 fi
 269                 enable_api_docs="no"
 270         fi
 271 fi
 272
 273 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 274
 275 AC_CONFIG_MACRO_DIRS([config])
 276
 277 # Apparmor
 278 AC_ARG_ENABLE([apparmor],
 279         [AS_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 280         [enable_apparmor=$enableval], [enable_apparmor=auto])
 281
 282 if test "$enable_apparmor" = "auto" ; then
 283         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 284 fi
 285 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 286
 287 # OpenSSL
 288 # libssl-dev
 289 AC_ARG_ENABLE([openssl],
 290         [AS_HELP_STRING([--enable-openssl], [enable OpenSSL support [default=auto]])],
 291         [enable_openssl=$enableval], [enable_openssl=auto])
 292
 293 if test "$enable_openssl" = "auto" ; then
 294         AC_CHECK_LIB([ssl], [OPENSSL_init_ssl], [enable_openssl=yes], [enable_openssl=no])
 295
 296 fi
 297 AM_CONDITIONAL([ENABLE_OPENSSL], [test "x$enable_openssl" = "xyes"])
 298
 299 AC_ARG_ENABLE([static-binaries],
 300         [AS_HELP_STRING([--enable-static-binaries], [build all binaries statically [default=no]])],
 301         [enable_static_binaries=$enableval], [enable_static_binaries=no])
 302 AM_CONDITIONAL([ENABLE_STATIC_BINARIES], [test "x$enable_static_binaries" = "xyes"])
 303
 304 AM_COND_IF([ENABLE_OPENSSL],
 305         [AC_CHECK_HEADER([openssl/engine.h],[],[AC_MSG_ERROR([You must install the OpenSSL development package in order to compile lxc])])
 306         AM_COND_IF([ENABLE_STATIC_BINARIES], [AC_SUBST([OPENSSL_LIBS], '-lssl -lcrypto -ldl')], [AC_SUBST([OPENSSL_LIBS], '-lssl -lcrypto')])])
 307
 308 # SELinux
 309 AC_ARG_ENABLE([selinux],
 310         [AS_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 311         [enable_selinux=$enableval], [enable_selinux=auto])
 312
 313 if test "x$enable_selinux" = xauto; then
 314         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 315 fi
 316 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 317 AM_COND_IF([ENABLE_SELINUX],
 318         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 319         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 320         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 321
 322 # Seccomp syscall filter
 323 AC_ARG_ENABLE([seccomp],
 324         [AS_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 325         [enable_seccomp=$enableval], [enable_seccomp=auto])
 326
 327 if test "x$enable_seccomp" = "xauto" ; then
 328         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 329 fi
 330 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 331
 332 AM_COND_IF([ENABLE_SECCOMP],
 333         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 334                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 335                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 336                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 337                 ])
 338         # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 339         OLD_CFLAGS="$CFLAGS"
 340         CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 341         AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 342         AC_CHECK_DECLS([seccomp_notify_fd], [], [], [[#include <seccomp.h>]])
 343         AC_CHECK_TYPES([struct seccomp_notif_sizes], [], [], [[#include <seccomp.h>]])
 344         AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 345         CFLAGS="$OLD_CFLAGS"
 346         ])
 347
 348 AC_MSG_CHECKING(for static libcap)
 349 # Check for static libcap, make sure the function checked for differs from the
 350 # the one checked below so the cache doesn't give a wrong answer
 351 OLD_CFLAGS="$CFLAGS"
 352 OLD_CPPFLAGS="$CPPFLAGS"
 353 OLD_LDFLAGS="$LDFLAGS"
 354 OLD_LIBS="$LIBS"
 355 CFLAGS=""
 356 CPPFLAGS=""
 357 LDFLAGS="-static"
 358 LIBS="-lcap"
 359 AC_LINK_IFELSE([
 360   AC_LANG_SOURCE(
 361     [[int main() { return 0; }]]
 362   )],[have_static_libcap=yes],[have_static_libcap=no])
 363 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 364 if test "x$have_static_libcap" = "xyes"; then
 365         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 366         AC_MSG_RESULT([yes])
 367 else
 368         AC_MSG_RESULT([no])
 369 fi
 370 CPPFLAGS="$OLD_CPPFLAGS"
 371 CFLAGS="$OLD_CFLAGS"
 372 LDFLAGS="$OLD_LDFLAGS"
 373 LIBS="$OLD_LIBS"
 374
 375
 376 # Linux capabilities
 377 AC_ARG_ENABLE([capabilities],
 378         [AS_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 379         [enable_capabilities=$enableval], [enable_capabilities=auto])
 380
 381 if test "x$enable_capabilities" = "xauto"; then
 382         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 383 fi
 384 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 385
 386 AM_COND_IF([ENABLE_CAP],
 387         [AC_CHECK_HEADER([sys/capability.h],[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 388         AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 389         # Test whether we support getting file capabilities via cap_get_file().
 390         AC_CHECK_LIB(cap,cap_get_file, AC_DEFINE(LIBCAP_SUPPORTS_FILE_CAPABILITIES,1,[Have cap_get_file]),[],[])
 391         AC_SUBST([CAP_LIBS], [-lcap])])
 392
 393 # Configuration examples
 394 AC_ARG_ENABLE([examples],
 395         [AS_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 396         [enable_examples=$enableval], [enable_examples=yes])
 397 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 398
 399 # Enable dumping stack traces
 400 AC_ARG_ENABLE([mutex-debugging],
 401         [AS_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 402         [enable_mutex_debugging=$enableval], [enable_mutex_debugging=no])
 403 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 404
 405 AM_COND_IF([MUTEX_DEBUGGING],
 406         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 407
 408 # Not in older autoconf versions
 409 # AS_VAR_COPY(DEST, SOURCE)
 410 # -------------------------
 411 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 412 # shell variable SOURCE.
 413 m4_ifdef([AS_VAR_COPY], [],
 414 [AC_DEFUN([AS_VAR_COPY],
 415     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 416 ])
 417
 418 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 419 m4_ifdef([PKG_CHECK_VAR], [],
 420 [AC_DEFUN([PKG_CHECK_VAR],
 421     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 422      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 423      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 424      AS_VAR_COPY([$1], [pkg_cv_][$1])
 425      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 426     ])# PKG_CHECK_VAR
 427 ])
 428
 429 # Optional bash integration
 430 AC_ARG_ENABLE([bash],
 431         [AS_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 432         [enable_bash=$enableval], [enable_bash=yes])
 433 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 434
 435 AM_COND_IF([ENABLE_BASH],
 436         [AC_MSG_CHECKING([bash completion directory])
 437         PKG_CHECK_VAR(bashcompdir, [bash-completion], [completionsdir], ,
 438                 bashcompdir="${sysconfdir}/bash_completion.d")
 439         AC_MSG_RESULT([$bashcompdir])
 440         AC_SUBST(bashcompdir)
 441         ])
 442
 443 # Build the command line tools
 444 AC_ARG_ENABLE([tools],
 445         [AS_HELP_STRING([--enable-tools], [build the command line tools [default=yes]])],
 446         [enable_tools=$enableval], [enable_tools=yes])
 447 AM_CONDITIONAL([ENABLE_TOOLS], [test "x$enable_tools" = "xyes"])
 448
 449 # Build the liblxc commands
 450 AC_ARG_ENABLE([commands],
 451         [AS_HELP_STRING([--enable-commands], [build the liblxc commands [default=yes]])],
 452         [enable_commands=$enableval], [enable_commands=yes])
 453 AM_CONDITIONAL([ENABLE_COMMANDS], [test "x$enable_commands" = "xyes"])
 454
 455 AC_ARG_ENABLE([static-binaries],
 456         [AS_HELP_STRING([--enable-static-binaries], [build all binaries statically [default=no]])],
 457         [enable_static_binaries=$enableval], [enable_static_binaries=no])
 458 AM_CONDITIONAL([ENABLE_STATIC_BINARIES], [test "x$enable_static_binaries" = "xyes"])
 459
 460 AC_ARG_ENABLE([sanitizers],
 461         [AS_HELP_STRING([--enable-sanitizers], [build with sanitizers enabled [default=no]])],
 462         [enable_sanitizers=$enableval], [enable_sanitizers=no])
 463 AM_CONDITIONAL([ENABLE_SANITIZERS], [test "x$enable_sanitizers" = "xyes"])
 464 if test "x$enable_sanitizers" = "xyes"; then
 465         AC_DEFINE([ENABLE_SANITIZERS], 1, [build with sanitizers enabled])
 466
 467         CC_CHECK_FLAGS_APPEND([AM_CFLAGS],[CFLAGS],[ \
 468                 -fsanitize=address \
 469                 -fsanitize=undefined \
 470                 -fsanitize=memory \
 471                 -fno-omit-frame-pointer])
 472         AC_SUBST(AM_CFLAGS)
 473
 474         AC_MSG_RESULT([yes])
 475 else
 476         AC_MSG_RESULT([no])
 477 fi
 478
 479 # Optional test binaries
 480 AC_ARG_ENABLE([tests],
 481         [AS_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 482         [enable_tests=$enableval], [enable_tests=no])
 483 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 484
 485 # Allow overriding the default runtime dir (/run)
 486 AC_ARG_WITH([runtime-path],
 487         [AS_HELP_STRING([--with-runtime-path=dir], [runtime directory (default: /run)])],
 488         [with_runtime_path=$withval], [with_runtime_path=['/run']])
 489
 490 # LXC container path, where the containers are actually stored
 491 # This is overridden by an entry in the file called LXCCONF
 492 # (i.e. /etc/lxc/lxc.conf)
 493 AC_ARG_WITH([config-path],
 494         [AS_HELP_STRING([--with-config-path=dir], [lxc configuration repository path])],
 495         [with_config_path=$withval], [with_config_path=['${localstatedir}/lib/lxc']])
 496
 497 # The path of the global lxc configuration file.
 498 AC_ARG_WITH([global-conf],
 499         [AS_HELP_STRING([--with-global-conf=dir], [global lxc configuration file])],
 500         [with_global_conf=$withval], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 501
 502 # The path of the userns network configuration file
 503 AC_ARG_WITH([usernic-conf],
 504         [AS_HELP_STRING([--with-usernic-conf], [user network interface configuration file])],
 505         [with_usernic_conf=$withval], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 506
 507 # The path of the runtime usernic database
 508 AC_ARG_WITH([usernic-db],
 509         [AS_HELP_STRING([--with-usernic-db], [lxc user nic database])],
 510         [with_usernic_db=$withval], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 511
 512 # Rootfs path, where the container mount structure is assembled
 513 AC_ARG_WITH([rootfs-path],
 514         [AS_HELP_STRING([--with-rootfs-path=dir], [lxc rootfs mount point])],
 515         [with_rootfs_path=$withval], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 516
 517 # cgroup pattern specification
 518 AC_ARG_WITH([cgroup-pattern],
 519         [AS_HELP_STRING([--with-cgroup-pattern=pattern], [pattern for container cgroups])],
 520         [with_cgroup_pattern=$withval], [with_cgroup_pattern=['']])
 521
 522 # The path for the apparmor_parser's cache for generated apparmor profiles
 523 AC_ARG_WITH([apparmor-cache-dir],
 524         [AS_HELP_STRING([--with-apparmor-cache-dir=dir],[path for apparmor_parser cache])],
 525         [with_apparmor_cache_dir=$withval], [with_apparmor_cache_dir=['${localstatedir}/cache/lxc/apparmor']])
 526
 527 # Container log path.  By default, use $lxcpath.
 528 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 529 AC_ARG_ENABLE([configpath-log],
 530         [AS_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 531         [enable_configpath_log=$enableval], [enable_configpath_log=no])
 532 AC_MSG_RESULT([$enable_configpath_log])
 533 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 534
 535 if test "$enable_configpath_log" = "yes"; then
 536         default_log_path="${with_config_path}"
 537 else
 538         default_log_path="${localstatedir}/log/lxc"
 539 fi
 540
 541 AC_ARG_WITH([log-path],
 542         [AS_HELP_STRING([--with-log-path=dir],[per container log path])],
 543         [with_log_path=$withval], [with_log_path=['${default_log_path}']])
 544
 545 # Expand some useful variables
 546 AS_AC_EXPAND(PREFIX, "$prefix")
 547 AS_AC_EXPAND(LIBDIR, "$libdir")
 548 AS_AC_EXPAND(BINDIR, "$bindir")
 549 AS_AC_EXPAND(SBINDIR, "$sbindir")
 550 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 551 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 552 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 553 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 554 AS_AC_EXPAND(DATADIR, "$datadir")
 555 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 556 AS_AC_EXPAND(DOCDIR, "$docdir")
 557 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date --utc --date=@${SOURCE_DATE_EPOCH:-$(date +%s)} '+%Y-%m-%d')")
 558 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 559 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 560 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 561 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 562 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 563 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 564 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 565 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 566 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 567 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 568 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 569 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 570 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 571 AS_AC_EXPAND(APPARMOR_CACHE_DIR, "$with_apparmor_cache_dir")
 572 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 573
 574 # We need the install path so criu knows where to reference the hook scripts.
 575 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 576
 577 # Check for some standard kernel headers
 578 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 579                                 [],
 580                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 581                                 [#include <sys/socket.h>])
 582
 583 # Check for alternate C libraries
 584 AC_MSG_CHECKING(for bionic libc)
 585 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 586         [[#ifndef __ANDROID__
 587 error: Not bionic!
 588 #endif]])],
 589         [is_bionic=yes],
 590         [is_bionic=no])
 591 if test "x$is_bionic" = "xyes"; then
 592         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 593         AC_MSG_RESULT([yes])
 594 else
 595         AC_MSG_RESULT([no])
 596 fi
 597 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 598
 599 # Configuration examples
 600 AC_ARG_ENABLE([pam],
 601         [AS_HELP_STRING([--enable-pam], [enable pam module [default=no]])],
 602         [enable_pam=$enableval], [enable_pam=no])
 603 AM_CONDITIONAL([ENABLE_PAM], [test "x$enable_pam" = "xyes"])
 604
 605 AM_COND_IF([ENABLE_PAM],
 606         [AC_ARG_WITH(
 607                 [pamdir],
 608                 [AS_HELP_STRING([--with-pamdir=PATH],[Specify the directory where PAM modules are stored,
 609                                                         or "none" if PAM modules are not to be built])],
 610                 [pamdir=$withval],
 611                 [
 612                         if test "${prefix}" = "/usr"; then
 613                                 pamdir="/lib${libdir##*/lib}/security"
 614                         else
 615                                 pamdir="\$(libdir)/security"
 616                         fi
 617                 ]
 618         )])
 619
 620 AM_CONDITIONAL([HAVE_PAM], [test x"$pamdir" != "xnone"])
 621 AM_COND_IF([ENABLE_PAM],
 622         [if test "z$pamdir" != "znone"; then
 623                 AC_ARG_VAR([PAM_CFLAGS], [C compiler flags for pam])
 624                 AC_ARG_VAR([PAM_LIBS], [linker flags for pam])
 625                 AC_CHECK_LIB(
 626                         [pam],
 627                         [pam_authenticate],
 628                         [PAM_LIBS="-lpam"],
 629                         [AC_MSG_ERROR([*** libpam not found.])
 630                         ])
 631
 632                 AC_SUBST(PAM_LIBS)
 633                 AC_SUBST([pamdir])
 634         fi])
 635
 636 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 637 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 638
 639 # Some systems lack PR_{G,S}ET_NO_NEW_PRIVS definition => HAVE_DECL_PR_{G,S}ET_NO_NEW_PRIVS
 640 AC_CHECK_DECLS([PR_SET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 641 AC_CHECK_DECLS([PR_GET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 642
 643 # Check for some headers
 644 AC_CHECK_HEADERS([pty.h sys/memfd.h sys/personality.h sys/resource.h sys/signalfd.h sys/timerfd.h utmpx.h])
 645
 646 AC_CHECK_HEADER([ifaddrs.h],
 647         AM_CONDITIONAL(HAVE_IFADDRS_H, true)
 648         AC_DEFINE(HAVE_IFADDRS_H, 1, [Have ifaddrs.h]),
 649         AM_CONDITIONAL(HAVE_IFADDRS_H, false))
 650
 651 # lookup major()/minor()/makedev()
 652 AC_HEADER_MAJOR
 653
 654 # Check for some syscalls functions
 655 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat gettid memfd_create move_mount open_tree execveat clone3 fsopen fspick fsconfig fsmount, openat2, close_range, statvfs])
 656 AC_CHECK_TYPES([__aligned_u64], [], [], [[#include <linux/types.h>]])
 657 AC_CHECK_TYPES([struct open_how], [], [], [[#include <linux/openat2.h>]])
 658 AC_CHECK_TYPES([struct clone_args], [], [], [[#include <linux/sched.h>]])
 659 AC_CHECK_MEMBERS([struct clone_args.set_tid],[],[],[[#include <linux/sched.h>]])
 660 AC_CHECK_MEMBERS([struct clone_args.cgroup],[],[],[[#include <linux/sched.h>]])
 661
 662 # Check for strerror_r() support. Defines:
 663 # - HAVE_STRERROR_R if available
 664 # - HAVE_DECL_STRERROR_R if defined
 665 # - STRERROR_R_CHAR_P if it returns char *
 666 AC_FUNC_STRERROR_R
 667
 668 # Check if "%m" is supported by printf and Co
 669 AC_MSG_CHECKING([%m format])
 670 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 671 #include <stdio.h>
 672 int main(void)
 673 {
 674   char msg[256];
 675   int rc;
 676
 677   rc = snprintf(msg, sizeof(msg), "%m\n");
 678   if ((rc > 1) && (msg[0] != '%'))
 679   {
 680     return 0;
 681   }
 682   else
 683   {
 684     return 1;
 685   }
 686 }]])],[fmt_m=yes],[fmt_m=no],[fmt_m=no])
 687 if test "x$fmt_m" = "xyes"; then
 688         AC_DEFINE([HAVE_M_FORMAT], 1, [Have %m format])
 689         AC_MSG_RESULT([yes])
 690 else
 691         AC_MSG_RESULT([no])
 692 fi
 693
 694 # Check for some functions
 695 AC_CHECK_LIB(pthread, main)
 696 AC_CHECK_LIB(util, openpty)
 697 AC_CHECK_FUNCS([hasmntopt setmntent endmntent utmpxname])
 698 AC_CHECK_FUNCS([getgrgid_r],
 699         AM_CONDITIONAL(HAVE_GETGRGID_R, true)
 700         AC_DEFINE(HAVE_GETGRGID_R,1,[Have getgrgid_r]),
 701         AM_CONDITIONAL(HAVE_GETGRGID_R, false))
 702 AC_CHECK_FUNCS([getline],
 703         AM_CONDITIONAL(HAVE_GETLINE, true)
 704         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 705         AM_CONDITIONAL(HAVE_GETLINE, false))
 706 AC_CHECK_FUNCS([getsubopt],
 707         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 708         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 709         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 710 AC_CHECK_FUNCS([fgetln],
 711         AM_CONDITIONAL(HAVE_FGETLN, true)
 712         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 713         AM_CONDITIONAL(HAVE_FGETLN, false))
 714 AC_CHECK_FUNCS([keyctl],
 715         AM_CONDITIONAL(HAVE_KEYCTL, true)
 716         AC_DEFINE(HAVE_KEYCTL,1,[Have keyctl]),
 717         AM_CONDITIONAL(HAVE_KEYCTL, false))
 718 AC_CHECK_FUNCS([openpty],
 719         AM_CONDITIONAL(HAVE_OPENPTY, true)
 720         AC_DEFINE(HAVE_OPENPTY,1,[Have openpty]),
 721         AM_CONDITIONAL(HAVE_OPENPTY, false))
 722 AC_CHECK_FUNCS([prlimit],
 723         AM_CONDITIONAL(HAVE_PRLIMIT, true)
 724         AC_DEFINE(HAVE_PRLIMIT,1,[Have prlimit]),
 725         AM_CONDITIONAL(HAVE_PRLIMIT, false))
 726 AC_CHECK_FUNCS([prlimit64],
 727         AM_CONDITIONAL(HAVE_PRLIMIT64, true)
 728         AC_DEFINE(HAVE_PRLIMIT64,1,[Have prlimit64]),
 729         AM_CONDITIONAL(HAVE_PRLIMIT64, false))
 730 AC_CHECK_FUNCS([pthread_setcancelstate],
 731         AM_CONDITIONAL(HAVE_PTHREAD_SETCANCELSTATE, true)
 732         AC_DEFINE(HAVE_PTHREAD_SETCANCELSTATE,1,[Have pthread_setcancelstate]),
 733         AM_CONDITIONAL(HAVE_PTHREAD_SETCANCELSTATE, false))
 734 AC_CHECK_FUNCS([strlcpy],
 735         AM_CONDITIONAL(HAVE_STRLCPY, true)
 736         AC_DEFINE(HAVE_STRLCPY,1,[Have strlcpy]),
 737         AM_CONDITIONAL(HAVE_STRLCPY, false))
 738 AC_CHECK_FUNCS([strlcat],
 739         AM_CONDITIONAL(HAVE_STRLCAT, true)
 740         AC_DEFINE(HAVE_STRLCAT,1,[Have strlcat]),
 741         AM_CONDITIONAL(HAVE_STRLCAT, false))
 742 AC_CHECK_FUNCS([strchrnul],
 743         AM_CONDITIONAL(HAVE_STRCHRNUL, true)
 744         AC_DEFINE(HAVE_STRCHRNUL,1,[Have strchnul]),
 745         AM_CONDITIONAL(HAVE_STRCHRNUL, false))
 746 AC_CHECK_FUNCS([fmemopen],
 747         AM_CONDITIONAL(HAVE_FMEMOPEN, true)
 748         AC_DEFINE(HAVE_FMEMOPEN,1,[Have fmemopen]),
 749         AM_CONDITIONAL(HAVE_FMEMOPEN, false))
 750
 751 # HAVE_STRUCT_RTNL_LINK_STATS64={0,1}
 752 AC_CHECK_TYPES([struct rtnl_link_stats64], [], [], [[#include <linux/if_link.h>]])
 753
 754 # Check for some libraries
 755 AX_PTHREAD
 756 AC_SEARCH_LIBS(clock_gettime, [rt])
 757
 758 # See if we support thread-local storage.
 759 LXC_CHECK_TLS
 760
 761 # Hardening flags
 762 CC_CHECK_FLAGS_APPEND([AM_CFLAGS],[CFLAGS],[ \
 763         -fPIE \
 764         -Wvla \
 765         -std=gnu11 \
 766         -fms-extensions \
 767         -fdiagnostics-color \
 768         -Wimplicit-fallthrough=5 \
 769         -Wcast-align \
 770         -Wstrict-prototypes \
 771         -fno-strict-aliasing \
 772         -fstack-clash-protection \
 773         -fstack-protector-strong \
 774         --param=ssp-buffer-size=4 \
 775         -g \
 776         --mcet -fcf-protection \
 777         -Werror=implicit-function-declaration \
 778         -Wlogical-op \
 779         -Wmissing-include-dirs \
 780         -Wold-style-definition \
 781         -Winit-self \
 782         -Wunused-but-set-variable \
 783         -Wfloat-equal \
 784         -Wsuggest-attribute=noreturn \
 785         -Werror=return-type \
 786         -Werror=incompatible-pointer-types \
 787         -Wformat=2 \
 788         -Wshadow \
 789         -Wendif-labels \
 790         -Werror=overflow \
 791         -fdiagnostics-show-option \
 792         -Werror=shift-count-overflow \
 793         -Werror=shift-overflow=2 \
 794         -Wdate-time \
 795         -Wnested-externs \
 796         -fasynchronous-unwind-tables \
 797         -pipe \
 798         -fexceptions \
 799         -Warray-bounds \
 800         -Wrestrict \
 801         -Wreturn-local-addr \
 802         -flto=thin \
 803         -fsanitize=cfi \
 804         -Wstringop-overflow])
 805 AC_SUBST(AM_CFLAGS)
 806
 807 CC_CHECK_FLAGS_APPEND([AM_LDFLAGS],[LDFLAGS],[ \
 808         -Wl,--as-needed \
 809         -Wl,--gc-sections \
 810         -Wl,-z,relro \
 811         -Wl,-z,now \
 812         -pie \
 813         -Wl,-fuse-ld=gold])
 814
 815 AM_COND_IF([ENABLE_NO_UNDEFINED],
 816         [CC_CHECK_FLAGS_APPEND([AM_LDFLAGS],[LDFLAGS],[-Wl,--no-undefined])])
 817
 818 AC_SUBST(AM_LDFLAGS)
 819
 820 CFLAGS="$CFLAGS -Wvla -std=gnu11 -fms-extensions"
 821 if test "x$enable_werror" = "xyes"; then
 822         CFLAGS="$CFLAGS -Werror"
 823 fi
 824
 825 AC_ARG_ENABLE([thread-safety],
 826         [AS_HELP_STRING([--enable-thread-safety], [enforce thread-safety otherwise fail the build [default=yes]])],
 827         [enable_thread_safety=$enableval], [enable_thread_safety=yes])
 828 AM_CONDITIONAL([ENFORCE_THREAD_SAFETY], [test "x$enable_thread_safety" = "xyes"])
 829 if test "x$enable_thread_safety" = "xyes"; then
 830         AC_DEFINE([ENFORCE_THREAD_SAFETY], 1, [enforce thread-safety otherwise fail the build])
 831         AC_MSG_RESULT([yes])
 832 else
 833         AC_MSG_RESULT([no])
 834 fi
 835
 836 AC_ARG_ENABLE([coverity-build],
 837         [AS_HELP_STRING([--enable-coverity-build], [build for use with Coverity [default=no]])],
 838         [enable_coverity_build=$enableval], [enable_coverity_build=no])
 839 AM_CONDITIONAL([ENABLE_COVERITY_BUILD], [test "x$enable_coverity_build" = "xyes"])
 840 if test "x$enable_coverity_build" = "xyes"; then
 841         AC_DEFINE([ENABLE_COVERITY_BUILD], 1, [build for use with Coverity])
 842         AC_MSG_RESULT([yes])
 843 else
 844         AC_MSG_RESULT([no])
 845 fi
 846
 847 AC_ARG_ENABLE([dlog],
 848         [AS_HELP_STRING([--enable-dlog], [enable dlog support [default=no]])],
 849         [enable_dlog=$enableval], [enable_dlog=no])
 850 AM_CONDITIONAL([ENABLE_DLOG], [test "x$enable_dlog" = "xyes"])
 851
 852 AM_COND_IF([ENABLE_DLOG],
 853         [PKG_CHECK_MODULES([DLOG],[dlog],[],[
 854                 AC_CHECK_HEADER([dlog.h],[],[AC_MSG_ERROR([You must install the dlog development package in order to compile lxc])])
 855                 AC_CHECK_LIB([dlog], [dlog_print],[],[AC_MSG_ERROR([You must install the dlog development package in order to compile lxc])])
 856                 AC_SUBST([DLOG_LIBS], [-ldlog])
 857                 ])
 858         ])
 859
 860 AC_ARG_ENABLE([memfd-rexec],
 861         [AS_HELP_STRING([--enable-memfd-rexec], [enforce liblxc as a memfd to protect against certain symlink attacks [default=yes]])],
 862         [enable_memfd_rexec=$enableval], [enable_memfd_rexec=yes])
 863 AM_CONDITIONAL([ENFORCE_MEMFD_REXEC], [test "x$enable_memfd_rexec" = "xyes"])
 864 if test "x$enable_memfd_rexec" = "xyes"; then
 865         AC_DEFINE([ENFORCE_MEMFD_REXEC], 1, [Rexec liblxc as memfd])
 866         AC_MSG_RESULT([yes])
 867 else
 868         AC_MSG_RESULT([no])
 869 fi
 870
 871 # Files requiring some variable expansion
 872 AC_CONFIG_FILES([
 873         Makefile
 874         lxc.pc
 875         lxc.spec
 876
 877         coccinelle/Makefile
 878
 879         config/Makefile
 880         config/apparmor/Makefile
 881         config/apparmor/abstractions/start-container
 882         config/selinux/Makefile
 883         config/bash/Makefile
 884         config/bash/lxc
 885         config/init/Makefile
 886         config/init/common/Makefile
 887         config/init/common/lxc-containers
 888         config/init/common/lxc-net
 889         config/init/systemd/Makefile
 890         config/init/systemd/lxc.service
 891         config/init/systemd/lxc@.service
 892         config/init/systemd/lxc-net.service
 893         config/init/systemd/lxc-monitord.service
 894         config/init/sysvinit/Makefile
 895         config/init/sysvinit/lxc-containers
 896         config/init/sysvinit/lxc-net
 897         config/init/upstart/lxc.conf
 898         config/init/upstart/lxc-net.conf
 899         config/init/upstart/Makefile
 900         config/etc/Makefile
 901         config/templates/Makefile
 902         config/templates/common.conf
 903         config/templates/common.conf.d/Makefile
 904         config/templates/nesting.conf
 905         config/templates/oci.common.conf
 906         config/templates/userns.conf
 907         config/yum/Makefile
 908         config/sysconfig/Makefile
 909         config/sysconfig/lxc
 910
 911         doc/Makefile
 912         doc/api/Makefile
 913         doc/lxc-attach.sgml
 914         doc/lxc-autostart.sgml
 915         doc/lxc-cgroup.sgml
 916         doc/lxc-checkconfig.sgml
 917         doc/lxc-checkpoint.sgml
 918         doc/lxc-config.sgml
 919         doc/lxc-console.sgml
 920         doc/lxc-copy.sgml
 921         doc/lxc-create.sgml
 922         doc/lxc-destroy.sgml
 923         doc/lxc-device.sgml
 924         doc/lxc-execute.sgml
 925         doc/lxc-freeze.sgml
 926         doc/lxc-info.sgml
 927         doc/lxc-ls.sgml
 928         doc/lxc-monitor.sgml
 929         doc/lxc-snapshot.sgml
 930         doc/lxc-start.sgml
 931         doc/lxc-stop.sgml
 932         doc/lxc-top.sgml
 933         doc/lxc-unfreeze.sgml
 934         doc/lxc-unshare.sgml
 935         doc/lxc-update-config.sgml
 936         doc/lxc-user-nic.sgml
 937         doc/lxc-usernsexec.sgml
 938         doc/lxc-wait.sgml
 939
 940         doc/pam_cgfs.sgml
 941
 942         doc/lxc.conf.sgml
 943         doc/lxc.container.conf.sgml
 944         doc/lxc.system.conf.sgml
 945         doc/lxc-usernet.sgml
 946         doc/lxc.sgml
 947         doc/common_options.sgml
 948         doc/see_also.sgml
 949
 950         doc/rootfs/Makefile
 951
 952         doc/examples/Makefile
 953         doc/examples/lxc-macvlan.conf
 954         doc/examples/lxc-vlan.conf
 955         doc/examples/lxc-no-netns.conf
 956         doc/examples/lxc-empty-netns.conf
 957         doc/examples/lxc-phys.conf
 958         doc/examples/lxc-veth.conf
 959         doc/examples/lxc-complex.conf
 960
 961         doc/ja/Makefile
 962         doc/ja/lxc-attach.sgml
 963         doc/ja/lxc-autostart.sgml
 964         doc/ja/lxc-cgroup.sgml
 965         doc/ja/lxc-checkconfig.sgml
 966         doc/ja/lxc-checkpoint.sgml
 967         doc/ja/lxc-config.sgml
 968         doc/ja/lxc-console.sgml
 969         doc/ja/lxc-copy.sgml
 970         doc/ja/lxc-create.sgml
 971         doc/ja/lxc-destroy.sgml
 972         doc/ja/lxc-device.sgml
 973         doc/ja/lxc-execute.sgml
 974         doc/ja/lxc-freeze.sgml
 975         doc/ja/lxc-info.sgml
 976         doc/ja/lxc-ls.sgml
 977         doc/ja/lxc-monitor.sgml
 978         doc/ja/lxc-snapshot.sgml
 979         doc/ja/lxc-start.sgml
 980         doc/ja/lxc-stop.sgml
 981         doc/ja/lxc-top.sgml
 982         doc/ja/lxc-unfreeze.sgml
 983         doc/ja/lxc-unshare.sgml
 984         doc/ja/lxc-update-config.sgml
 985         doc/ja/lxc-user-nic.sgml
 986         doc/ja/lxc-usernsexec.sgml
 987         doc/ja/lxc-wait.sgml
 988
 989         doc/ja/pam_cgfs.sgml
 990
 991         doc/ja/lxc.conf.sgml
 992         doc/ja/lxc.container.conf.sgml
 993         doc/ja/lxc.system.conf.sgml
 994         doc/ja/lxc-usernet.sgml
 995         doc/ja/lxc.sgml
 996         doc/ja/common_options.sgml
 997         doc/ja/see_also.sgml
 998
 999         doc/ko/Makefile
1000         doc/ko/lxc-attach.sgml
1001         doc/ko/lxc-autostart.sgml
1002         doc/ko/lxc-cgroup.sgml
1003         doc/ko/lxc-checkconfig.sgml
1004         doc/ko/lxc-checkpoint.sgml
1005         doc/ko/lxc-config.sgml
1006         doc/ko/lxc-console.sgml
1007         doc/ko/lxc-copy.sgml
1008         doc/ko/lxc-create.sgml
1009         doc/ko/lxc-destroy.sgml
1010         doc/ko/lxc-device.sgml
1011         doc/ko/lxc-execute.sgml
1012         doc/ko/lxc-freeze.sgml
1013         doc/ko/lxc-info.sgml
1014         doc/ko/lxc-ls.sgml
1015         doc/ko/lxc-monitor.sgml
1016         doc/ko/lxc-snapshot.sgml
1017         doc/ko/lxc-start.sgml
1018         doc/ko/lxc-stop.sgml
1019         doc/ko/lxc-top.sgml
1020         doc/ko/lxc-unfreeze.sgml
1021         doc/ko/lxc-unshare.sgml
1022         doc/ko/lxc-user-nic.sgml
1023         doc/ko/lxc-usernsexec.sgml
1024         doc/ko/lxc-wait.sgml
1025
1026         doc/ko/lxc.conf.sgml
1027         doc/ko/lxc.container.conf.sgml
1028         doc/ko/lxc.system.conf.sgml
1029         doc/ko/lxc-usernet.sgml
1030         doc/ko/lxc.sgml
1031         doc/ko/common_options.sgml
1032         doc/ko/see_also.sgml
1033
1034         hooks/Makefile
1035         hooks/dhclient
1036
1037         templates/Makefile
1038         templates/lxc-busybox
1039         templates/lxc-download
1040         templates/lxc-local
1041         templates/lxc-oci
1042
1043         src/Makefile
1044         src/lxc/Makefile
1045         src/lxc/lxc.functions
1046         src/lxc/cmd/lxc-checkconfig
1047         src/lxc/cmd/lxc-update-config
1048         src/lxc/version.h
1049
1050         src/tests/Makefile
1051         src/tests/lxc-test-usernic
1052 ])
1053 AC_CONFIG_COMMANDS([default],[[]],[[]])
1054 AC_OUTPUT
1055
1056 # Configuration overview
1057 cat << EOF
1058
1059 ----------------------------
1060 Binaries
1061  - Command Line Tools:
1062    - lxc-attach:     $enable_tools
1063    - lxc-autostart:  $enable_tools
1064    - lxc-cgroup:     $enable_tools
1065    - lxc-checkpoint: $enable_tools
1066    - lxc-config:     $enable_tools
1067    - lxc-console:    $enable_tools
1068    - lxc-copy:       $enable_tools
1069    - lxc-create:     $enable_tools
1070    - lxc-destroy:    $enable_tools
1071    - lxc-device:     $enable_tools
1072    - lxc-execute:    $enable_tools
1073    - lxc-freeze:     $enable_tools
1074    - lxc-info:       $enable_tools
1075    - lxc-ls:         $enable_tools
1076    - lxc-monitor:    $enable_tools
1077    - lxc-snapshot:   $enable_tools
1078    - lxc-start:      $enable_tools
1079    - lxc-stop:       $enable_tools
1080    - lxc-top:        $enable_tools
1081    - lxc-unfreeze:   $enable_tools
1082    - lxc-unshare:    $enable_tools
1083    - lxc-wait:       $enable_tools
1084
1085  - liblxc Commands:
1086    - lxc-checkconfig:   $enable_commands
1087    - lxc-update-config: $enable_commands
1088    - lxc-init:          $enable_commands
1089    - lxc-monitord:      $enable_commands
1090    - lxc-user-nic:      $enable_commands
1091    - lxc-usernsexec:    $enable_commands
1092
1093  - static binaries: $enable_static_binaries
1094
1095 Environment:
1096  - compiler: $CC
1097  - cflags: ${AM_CFLAGS} ${PTHREAD_CFLAGS}
1098  - ldflags: ${AM_LDFLAGS} ${PTHREAD_LIBS}
1099  - distribution: $with_distro
1100  - init script type(s): $init_script
1101  - rpath: $enable_rpath
1102  - OpenSSL: $enable_openssl
1103  - Bash integration: $enable_bash
1104
1105 Security features:
1106  - Apparmor: $enable_apparmor
1107  - Linux capabilities: $enable_capabilities
1108  - seccomp: $enable_seccomp
1109  - SELinux: $enable_selinux
1110  - memfd rexec: $enable_memfd_rexec
1111
1112 PAM:
1113  - PAM module: $enable_pam
1114  - cgroup PAM module: $pamdir
1115
1116 Documentation:
1117  - examples: $enable_examples
1118  - API documentation: $enable_api_docs
1119  - user documentation: $enable_doc
1120
1121 Debugging:
1122  - Sanitizers: $enable_sanitizers
1123  - Coverity: $enable_coverity_build
1124  - mutex debugging: $enable_mutex_debugging
1125  - tests: $enable_tests
1126
1127 Paths:
1128  - Logs in configpath: $enable_configpath_log
1129
1130 Thread-safety:
1131  - enforce: $enable_thread_safety
1132
1133 Dlog:
1134  - enable: $enable_dlog
1135 EOF