configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_devel], 1)
   5 m4_define([lxc_version_major], 2)
   6 m4_define([lxc_version_minor], 0)
   7 m4_define([lxc_version_micro], 0)
   8 m4_define([lxc_version_beta], [])
   9
  10 m4_define([lxc_abi_major], 1)
  11 m4_define([lxc_abi_minor], 2)
  12 m4_define([lxc_abi_micro], 0)
  13 m4_define([lxc_abi], [lxc_abi_major.lxc_abi_minor.lxc_abi_micro])
  14
  15 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  16 m4_define([lxc_version],
  17           [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])])
  18
  19 AC_INIT([lxc], [lxc_version])
  20
  21 # We need pkg-config
  22 PKG_PROG_PKG_CONFIG
  23
  24 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  25 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  26
  27 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  28 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  29 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  30 AC_SUBST([LXC_VERSION], [lxc_version])
  31 AC_SUBST([LXC_DEVEL], [lxc_devel])
  32
  33 AC_SUBST([LXC_ABI_MAJOR], [lxc_abi_major])
  34 AC_SUBST([LXC_ABI_MINOR], [lxc_abi_minor])
  35 AC_SUBST([LXC_ABI_MICRO], [lxc_abi_micro])
  36 AC_SUBST([LXC_ABI], [lxc_abi])
  37
  38 AC_CONFIG_SRCDIR([configure.ac])
  39 AC_CONFIG_AUX_DIR([config])
  40 AC_CONFIG_HEADERS([src/config.h])
  41 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  42 AC_CANONICAL_HOST
  43 AM_PROG_CC_C_O
  44 AC_GNU_SOURCE
  45
  46 # libtool
  47 LT_INIT
  48 AC_SUBST([LIBTOOL_DEPS])
  49
  50 # Detect the distribution. This is used for the default configuration and
  51 # for some distro-specific build options.
  52 AC_MSG_CHECKING([host distribution])
  53 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva, pardus, sparclinux, altlinux.]))
  54 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  55         with_distro=`lsb_release -is`
  56 fi
  57 if test "z$with_distro" = "z"; then
  58         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  59         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  60         AC_CHECK_FILE(/etc/sparclinux-release,with_distro="sparclinux")
  61         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  62         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  63         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  64         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  65         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  66         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  67         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  68         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
  69         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  70         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  71         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  72         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  73         AC_CHECK_FILE(/etc/altlinux-release,with_distro="altlinux")
  74         AC_CHECK_FILE(/etc/pld-release,with_distro="pld")
  75 fi
  76 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  77
  78 if test "z$with_distro" = "zforsparc"; then
  79         with_distro="sparclinux"
  80 fi
  81
  82 if test "z$with_distro" = "z"; then
  83         with_distro="unknown"
  84 fi
  85 case $with_distro in
  86         ubuntu|raspbian)
  87                 distroconf=default.conf.lxcbr
  88                 distrosysconf="$sysconfdir/default"
  89                 ;;
  90         redhat|centos|fedora|oracle|oracleserver|sparclinux|altlinux|suse|opensuse*|plamo|pld)
  91                 distroconf=default.conf.lxcbr
  92                 distrosysconf="$sysconfdir/sysconfig"
  93                 ;;
  94         *)
  95                 distroconf=default.conf.unknown
  96                 distrosysconf="$sysconfdir/default"
  97                 ;;
  98 esac
  99 AC_MSG_RESULT([$with_distro])
 100 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
 101 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
 102
 103 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
 104
 105 # Check for init system type
 106 AC_MSG_CHECKING([for init system type])
 107 AC_ARG_WITH([init-script],
 108             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
 109                             [Type(s) of init script to install: sysvinit, systemd, upstart,
 110                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
 111 case "$with_init_script" in
 112         distro)
 113                 case $with_distro in
 114                         fedora|altlinux|opensuse*)
 115                                 init_script=systemd
 116                                 ;;
 117                         redhat|centos|oracle|oracleserver|sparclinux|plamo)
 118                                 init_script=sysvinit
 119                                 ;;
 120                         debian|raspbian)
 121                                 init_script=upstart,systemd
 122                                 ;;
 123                         ubuntu)
 124                                 init_script=upstart,systemd
 125                                 ;;
 126                         pld)
 127                                 init_script=sysvinit,upstart,systemd
 128                                 ;;
 129                         *)
 130                                 echo -n "Linux distribution init system unknown."
 131                                 init_script=
 132                                 ;;
 133                 esac
 134                 ;;
 135         *)
 136                 init_script=$with_init_script
 137                 ;;
 138 esac
 139
 140 # Check valid init systems were given, run in subshell so we don't mess up IFS
 141 (IFS="," ; for init_sys in $init_script;
 142 do
 143         case "$init_sys" in
 144                 none|sysvinit|systemd|upstart)
 145                         ;;
 146                 *)
 147                         exit 1
 148                         ;;
 149         esac
 150 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 151
 152 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 153 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 154 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 155 AC_MSG_RESULT($init_script)
 156
 157 # systemd unit dir
 158 AC_ARG_WITH([systemdsystemunitdir],
 159             AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 160             [],
 161             [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 162 if test -z "$with_systemdsystemunitdir"; then
 163   with_systemdsystemunitdir=/lib/systemd/system
 164 fi
 165 if test "x$with_systemdsystemunitdir" != "xno"; then
 166   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 167 fi
 168
 169 AC_ARG_ENABLE([werror],
 170         [AC_HELP_STRING([--disable-werror],
 171         [do not treat warnings as errors])],
 172         [], [enable_werror=yes])
 173
 174 # Allow enabling deprecated executables
 175 AC_ARG_ENABLE([deprecated],
 176         [AC_HELP_STRING([--enable-deprecated],
 177         [enable deprecated executables [default=no]])],
 178         [], [enable_deprecated=false])
 179 AM_CONDITIONAL([ENABLE_DEPRECATED], [test "x$enable_deprecated" = "xyes"])
 180
 181 # Allow disabling rpath
 182 AC_ARG_ENABLE([rpath],
 183         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 184         [], [enable_rpath=no])
 185 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 186
 187 # Documentation (manpages)
 188 AC_ARG_ENABLE([doc],
 189         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 190         [], [enable_doc=auto])
 191
 192 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 193         db2xman=""
 194         dbparsers="docbook2X2man docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 195
 196         AC_MSG_CHECKING(for docbook2x-man)
 197         for name in ${dbparsers}; do
 198                 if "$name" --help >/dev/null 2>&1; then
 199                         db2xman="$name"
 200                         break;
 201                 fi
 202         done
 203
 204         if test -n "${db2xman}"; then
 205                 AC_MSG_RESULT([${db2xman}])
 206                 enable_doc="yes"
 207         else
 208                 AC_MSG_RESULT([no])
 209                 if test "x$enable_doc" = "xyes"; then
 210                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 211                 fi
 212                 enable_doc="no"
 213         fi
 214
 215         AC_SUBST(db2xman)
 216 fi
 217 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 218 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 219
 220 if test "x$db2xman" = "xdocbook2man"; then
 221         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 222 else
 223         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 224 fi
 225 AC_SUBST(docdtd)
 226
 227 # Documentation (API)
 228 AC_ARG_ENABLE([api-docs],
 229         [AC_HELP_STRING([--enable-api-docs],
 230         [make API documentation [default=auto]])],
 231         [], [enable_api_docs=auto])
 232
 233 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 234         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 235         AC_SUBST([HAVE_DOXYGEN])
 236
 237         if test "x$HAVE_DOXYGEN" != "x"; then
 238                 enable_api_docs="yes"
 239         else
 240                 if test "x$enable_api_docs" = "xyes"; then
 241                         AC_MSG_ERROR([doxygen is required, but could not be found])
 242                 fi
 243                 enable_api_docs="no"
 244         fi
 245 fi
 246
 247 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 248
 249 # Apparmor
 250 AC_ARG_ENABLE([apparmor],
 251         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 252         [], [enable_apparmor=auto])
 253
 254 if test "$enable_apparmor" = "auto" ; then
 255         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 256 fi
 257 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 258
 259 AM_COND_IF([ENABLE_APPARMOR],
 260         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 261         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 262         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 263
 264 # GnuTLS
 265 AC_ARG_ENABLE([gnutls],
 266         [AC_HELP_STRING([--enable-gnutls], [enable GnuTLS support [default=auto]])],
 267         [], [enable_gnutls=auto])
 268
 269 if test "$enable_gnutls" = "auto" ; then
 270         AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 271 fi
 272 AM_CONDITIONAL([ENABLE_GNUTLS], [test "x$enable_gnutls" = "xyes"])
 273
 274 AM_COND_IF([ENABLE_GNUTLS],
 275         [AC_CHECK_HEADER([gnutls/gnutls.h],[],[AC_MSG_ERROR([You must install the GnuTLS development package in order to compile lxc])])
 276         AC_CHECK_LIB([gnutls], [gnutls_hash_fast],[],[AC_MSG_ERROR([You must install the GnuTLS development package in order to compile lxc])])
 277         AC_SUBST([GNUTLS_LIBS], [-lgnutls])])
 278
 279 # SELinux
 280 AC_ARG_ENABLE([selinux],
 281         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 282         [], [enable_selinux=auto])
 283
 284 if test "x$enable_selinux" = xauto; then
 285         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 286 fi
 287 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 288 AM_COND_IF([ENABLE_SELINUX],
 289         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 290         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 291         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 292
 293 # Seccomp syscall filter
 294 AC_ARG_ENABLE([seccomp],
 295         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 296         [], [enable_seccomp=auto])
 297
 298 if test "x$enable_seccomp" = "xauto" ; then
 299         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 300 fi
 301 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 302
 303 AM_COND_IF([ENABLE_SECCOMP],
 304         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 305                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 306                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 307                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 308                 ])
 309         ])
 310
 311 # cgmanager
 312 AC_ARG_ENABLE([cgmanager],
 313         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 314         [], [enable_cgmanager=auto])
 315
 316 if test "x$enable_cgmanager" = "xauto" ; then
 317         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus -ldbus-1])
 318 fi
 319 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 320
 321 AM_COND_IF([ENABLE_CGMANAGER],
 322         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 323         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 324         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 325         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 326         ])
 327
 328 AC_MSG_CHECKING(for get_pid_cgroup_abs_sync)
 329 save_LIBS=$LIBS
 330 AC_SEARCH_LIBS([cgmanager_get_pid_cgroup_abs_sync], [cgmanager], [have_abs_cgroups=yes], [have_abs_cgroups=no], [-lnih -lnih-dbus -ldbus-1])
 331 LIBS=$save_LIBS
 332 if test "x$have_abs_cgroups" = "xyes"; then
 333         AC_DEFINE([HAVE_CGMANAGER_GET_PID_CGROUP_ABS_SYNC], 1, [Have cgmanager_get_pid_cgroup_abs_sync])
 334         AC_MSG_RESULT([yes])
 335 else
 336         AC_MSG_RESULT([no])
 337 fi
 338
 339 AC_MSG_CHECKING(for cgmanager_list_controllers)
 340 save_LIBS=$LIBS
 341 AC_SEARCH_LIBS([cgmanager_list_controllers_sync], [cgmanager], [have_list_controllers=yes], [have_list_controllers=no], [-lnih -lnih-dbus -ldbus-1])
 342 LIBS=$save_LIBS
 343 if test "x$have_list_controllers" = "xyes"; then
 344         AC_DEFINE([HAVE_CGMANAGER_LIST_CONTROLLERS], 1, [Have cgmanager_list_controllers])
 345         AC_MSG_RESULT([yes])
 346 else
 347         AC_MSG_RESULT([no])
 348 fi
 349
 350 # Check for static libcap, make sure the function checked for differs from the
 351 # the one checked below so the cache doesn't give a wrong answer
 352 OLD_CFLAGS="$CFLAGS"
 353 CFLAGS="$CFLAGS -static"
 354 AC_CHECK_LIB([cap],[cap_init],[have_static_libcap=yes],[have_static_libcap=no])
 355 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 356 if test "x$have_static_libcap" = "xyes"; then
 357         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 358 fi
 359 CFLAGS="$OLD_CFLAGS"
 360
 361
 362 # Linux capabilities
 363 AC_ARG_ENABLE([capabilities],
 364         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 365         [], [enable_capabilities=auto])
 366
 367 if test "x$enable_capabilities" = "xauto"; then
 368         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 369 fi
 370 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 371
 372 AM_COND_IF([ENABLE_CAP],
 373         [AC_CHECK_LIB(cap,cap_set_proc,[true],[AC_MSG_ERROR([You are missing libcap support.])])
 374         AC_SUBST([CAP_LIBS], [-lcap])])
 375
 376 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 377 OLD_CFLAGS="$CFLAGS"
 378 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 379 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 380 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 381 CFLAGS="$OLD_CFLAGS"
 382
 383 # Configuration examples
 384 AC_ARG_ENABLE([examples],
 385         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 386         [], [enable_examples=yes])
 387 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 388
 389 # Python3 module and scripts
 390 AC_ARG_ENABLE([python],
 391         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 392         [], [enable_python=auto])
 393
 394 if test "x$enable_python" = "xauto"; then
 395         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 396         if test "$CC" = "clang"; then
 397                 enable_python=no
 398         fi
 399 fi
 400
 401 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 402         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 403 fi
 404
 405 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 406
 407 AM_COND_IF([ENABLE_PYTHON],
 408         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 409         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 410         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 411
 412 # Enable dumping stack traces
 413 AC_ARG_ENABLE([mutex-debugging],
 414         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 415         [], [enable_mutex_debugging=no])
 416 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 417
 418 AM_COND_IF([MUTEX_DEBUGGING],
 419         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 420
 421 # Not in older autoconf versions
 422 # AS_VAR_COPY(DEST, SOURCE)
 423 # -------------------------
 424 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 425 # shell variable SOURCE.
 426 m4_ifdef([AS_VAR_COPY], [],
 427 [AC_DEFUN([AS_VAR_COPY],
 428     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 429 ])
 430
 431 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 432 m4_ifdef([PKG_CHECK_VAR], [],
 433 [AC_DEFUN([PKG_CHECK_VAR],
 434     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 435      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 436      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 437      AS_VAR_COPY([$1], [pkg_cv_][$1])
 438      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 439     ])# PKG_CHECK_VAR
 440 ])
 441
 442 # Lua module and scripts
 443 AC_ARG_ENABLE([lua],
 444         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 445         [], [enable_lua=auto])
 446
 447 AC_ARG_WITH([lua-pc],
 448         [AS_HELP_STRING(
 449                 [--with-lua-pc=PKG],
 450                 [Specify pkg-config package name for lua]
 451         )], [], [with_lua_pc=no])
 452
 453 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 454         # exit with error if not found
 455         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 456 fi
 457
 458 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 459         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 460                 [LUAPKGCONFIG=$with_lua_pc
 461                 enable_lua=yes],
 462                 [enable_lua=no])
 463 fi
 464
 465 if test "x$enable_lua" != "xno"; then
 466         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 467                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 468                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 469                                 [AS_IF([test "x$enable_lua" = "xyes"],
 470                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 471                                         [enable_lua=no])]
 472                         )]
 473                 )])
 474         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 475 fi
 476
 477 AM_CONDITIONAL([ENABLE_LUA],
 478         [test "x$enable_lua" = "xyes"])
 479
 480 AM_COND_IF([ENABLE_LUA],
 481         [AC_MSG_CHECKING([Lua version])
 482         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 483                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 484         AC_MSG_RESULT([$LUA_VERSION])
 485         AC_SUBST([LUA_LIBDIR], [$libdir/lua/$LUA_VERSION])
 486         AC_SUBST([LUA_SHAREDIR], [$datadir/lua/$LUA_VERSION])
 487         ])
 488
 489 # Optional bash integration
 490 AC_ARG_ENABLE([bash],
 491         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 492         [], [enable_bash=yes])
 493 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 494
 495 AM_COND_IF([ENABLE_BASH],
 496         [AC_MSG_CHECKING([bash completion directory])
 497         PKG_CHECK_VAR(bashcompdir, [bash-completion], [completionsdir], ,
 498                 bashcompdir="${sysconfdir}/bash_completion.d")
 499         AC_MSG_RESULT([$bashcompdir])
 500         AC_SUBST(bashcompdir)
 501         ])
 502
 503 # Optional test binaries
 504 AC_ARG_ENABLE([tests],
 505         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 506         [], [enable_tests=no])
 507 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 508
 509 # Allow overriding the default runtime dir (/run)
 510 AC_ARG_WITH([runtime-path],
 511         [AC_HELP_STRING(
 512                 [--with-runtime-path=dir],
 513                 [runtime directory (default: /run)]
 514         )], [], [with_runtime_path=['/run']])
 515
 516 # LXC container path, where the containers are actually stored
 517 # This is overridden by an entry in the file called LXCCONF
 518 # (i.e. /etc/lxc/lxc.conf)
 519 AC_ARG_WITH([config-path],
 520         [AC_HELP_STRING(
 521                 [--with-config-path=dir],
 522                 [lxc configuration repository path]
 523         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 524
 525 # The path of the global lxc configuration file.
 526 AC_ARG_WITH([global-conf],
 527         [AC_HELP_STRING(
 528                 [--with-global-conf=dir],
 529                 [global lxc configuration file]
 530         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 531
 532 # The path of the userns network configuration file
 533 AC_ARG_WITH([usernic-conf],
 534         [AC_HELP_STRING(
 535                 [--with-usernic-conf],
 536                 [user network interface configuration file]
 537         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 538
 539 # The path of the runtime usernic database
 540 AC_ARG_WITH([usernic-db],
 541         [AC_HELP_STRING(
 542                 [--with-usernic-db],
 543                 [lxc user nic database]
 544         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 545
 546 # Rootfs path, where the container mount structure is assembled
 547 AC_ARG_WITH([rootfs-path],
 548         [AC_HELP_STRING(
 549                 [--with-rootfs-path=dir],
 550                 [lxc rootfs mount point]
 551         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 552
 553 # cgroup pattern specification
 554 AC_ARG_WITH([cgroup-pattern],
 555         [AC_HELP_STRING(
 556                 [--with-cgroup-pattern=pattern],
 557                 [pattern for container cgroups]
 558         )], [], [with_cgroup_pattern=['/lxc/%n']])
 559
 560 # Container log path.  By default, use $lxcpath.
 561 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 562 AC_ARG_ENABLE([configpath-log],
 563         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 564         [], [enable_configpath_log=no])
 565 AC_MSG_RESULT([$enable_configpath_log])
 566 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 567
 568 if test "$enable_configpath_log" = "yes"; then
 569         default_log_path="${with_config_path}"
 570 else
 571         default_log_path="${localstatedir}/log/lxc"
 572 fi
 573
 574 AC_ARG_WITH([log-path],
 575         [AC_HELP_STRING(
 576                 [--with-log-path=dir],
 577                 [per container log path]
 578         )], [], [with_log_path=['${default_log_path}']])
 579
 580 # Expand some useful variables
 581 AS_AC_EXPAND(PREFIX, "$prefix")
 582 AS_AC_EXPAND(LIBDIR, "$libdir")
 583 AS_AC_EXPAND(BINDIR, "$bindir")
 584 AS_AC_EXPAND(SBINDIR, "$sbindir")
 585 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 586 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 587 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 588 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 589 AS_AC_EXPAND(DATADIR, "$datadir")
 590 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 591 AS_AC_EXPAND(DOCDIR, "$docdir")
 592 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date --utc --date=@${SOURCE_DATE_EPOCH:-$(date +%s)} '+%Y-%m-%d')")
 593 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 594 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 595 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 596 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 597 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 598 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 599 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 600 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 601 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 602 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 603 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 604 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 605 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 606 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 607
 608 # We need the install path so criu knows where to reference the hook scripts.
 609 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 610
 611 # Check for some standard kernel headers
 612 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 613                                 [],
 614                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 615                                 [#include <sys/socket.h>])
 616
 617 # Check for alternate C libraries
 618 AC_MSG_CHECKING(for bionic libc)
 619 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 620         [[#ifndef __ANDROID__
 621 error: Not bionic!
 622 #endif]])],
 623         [is_bionic=yes],
 624         [is_bionic=no])
 625 if test "x$is_bionic" = "xyes"; then
 626         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 627         AC_MSG_RESULT([yes])
 628 else
 629         AC_MSG_RESULT([no])
 630 fi
 631 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 632
 633 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 634 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 635
 636 # Some systems lack PR_{G,S}ET_NO_NEW_PRIVS definition => HAVE_DECL_PR_{G,S}ET_NO_NEW_PRIVS
 637 AC_CHECK_DECLS([PR_SET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 638 AC_CHECK_DECLS([PR_GET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 639
 640 # Check for some headers
 641 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/memfd.h sys/personality.h utmpx.h sys/timerfd.h])
 642
 643 # lookup major()/minor()/makedev()
 644 AC_HEADER_MAJOR
 645
 646 # Check for some syscalls functions
 647 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat gettid memfd_create])
 648
 649 # Check for some functions
 650 AC_CHECK_LIB(pthread, main)
 651 AC_CHECK_FUNCS(pthread_atfork)
 652 AC_CHECK_FUNCS(statvfs)
 653 AC_CHECK_LIB(util, openpty)
 654 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 655 AC_CHECK_FUNCS([getline],
 656         AM_CONDITIONAL(HAVE_GETLINE, true)
 657         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 658         AM_CONDITIONAL(HAVE_GETLINE, false))
 659 AC_CHECK_FUNCS([getsubopt],
 660         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 661         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 662         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 663 AC_CHECK_FUNCS([fgetln],
 664         AM_CONDITIONAL(HAVE_FGETLN, true)
 665         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 666         AM_CONDITIONAL(HAVE_FGETLN, false))
 667
 668 # Check for some libraries
 669 AC_SEARCH_LIBS(sem_open, [rt pthread])
 670 AC_SEARCH_LIBS(clock_gettime, [rt])
 671
 672 # Check for some standard binaries
 673 AC_PROG_GCC_TRADITIONAL
 674 AC_PROG_SED
 675
 676 # See if we support thread-local storage.
 677 LXC_CHECK_TLS
 678
 679 if test "x$GCC" = "xyes"; then
 680         CFLAGS="$CFLAGS -Wall"
 681         if test "x$enable_werror" = "xyes"; then
 682                 CFLAGS="$CFLAGS -Werror"
 683         fi
 684 fi
 685
 686 # Files requiring some variable expansion
 687 AC_CONFIG_FILES([
 688         Makefile
 689         lxc.pc
 690         lxc.spec
 691
 692         config/Makefile
 693         config/apparmor/Makefile
 694         config/selinux/Makefile
 695         config/bash/Makefile
 696         config/bash/lxc
 697         config/init/Makefile
 698         config/init/common/Makefile
 699         config/init/common/lxc-containers
 700         config/init/common/lxc-net
 701         config/init/systemd/Makefile
 702         config/init/systemd/lxc.service
 703         config/init/systemd/lxc@.service
 704         config/init/systemd/lxc-net.service
 705         config/init/sysvinit/Makefile
 706         config/init/sysvinit/lxc-containers
 707         config/init/sysvinit/lxc-net
 708         config/init/upstart/lxc.conf
 709         config/init/upstart/lxc-net.conf
 710         config/init/upstart/Makefile
 711         config/etc/Makefile
 712         config/templates/Makefile
 713         config/templates/alpine.common.conf
 714         config/templates/alpine.userns.conf
 715         config/templates/archlinux.common.conf
 716         config/templates/archlinux.userns.conf
 717         config/templates/centos.common.conf
 718         config/templates/centos.userns.conf
 719         config/templates/common.conf
 720         config/templates/common.conf.d/Makefile
 721         config/templates/debian.common.conf
 722         config/templates/debian.userns.conf
 723         config/templates/fedora.common.conf
 724         config/templates/fedora.userns.conf
 725         config/templates/gentoo.common.conf
 726         config/templates/gentoo.moresecure.conf
 727         config/templates/gentoo.userns.conf
 728         config/templates/nesting.conf
 729         config/templates/opensuse.common.conf
 730         config/templates/opensuse.userns.conf
 731         config/templates/oracle.common.conf
 732         config/templates/oracle.userns.conf
 733         config/templates/plamo.common.conf
 734         config/templates/plamo.userns.conf
 735         config/templates/slackware.common.conf
 736         config/templates/slackware.userns.conf
 737         config/templates/ubuntu-cloud.common.conf
 738         config/templates/ubuntu-cloud.lucid.conf
 739         config/templates/ubuntu-cloud.userns.conf
 740         config/templates/ubuntu.common.conf
 741         config/templates/ubuntu.lucid.conf
 742         config/templates/ubuntu.userns.conf
 743         config/templates/openwrt.common.conf
 744         config/templates/sparclinux.common.conf
 745         config/templates/sparclinux.userns.conf
 746         config/templates/voidlinux.common.conf
 747         config/templates/voidlinux.userns.conf
 748         config/templates/sabayon.common.conf
 749         config/templates/sabayon.userns.conf
 750         config/templates/userns.conf
 751         config/yum/Makefile
 752         config/sysconfig/Makefile
 753         config/sysconfig/lxc
 754
 755         doc/Makefile
 756         doc/api/Makefile
 757         doc/lxc-attach.sgml
 758         doc/lxc-autostart.sgml
 759         doc/lxc-cgroup.sgml
 760         doc/lxc-checkconfig.sgml
 761         doc/lxc-checkpoint.sgml
 762         doc/lxc-clone.sgml
 763         doc/lxc-config.sgml
 764         doc/lxc-console.sgml
 765         doc/lxc-copy.sgml
 766         doc/lxc-create.sgml
 767         doc/lxc-destroy.sgml
 768         doc/lxc-device.sgml
 769         doc/lxc-execute.sgml
 770         doc/lxc-freeze.sgml
 771         doc/lxc-info.sgml
 772         doc/lxc-ls.sgml
 773         doc/lxc-monitor.sgml
 774         doc/lxc-snapshot.sgml
 775         doc/lxc-start-ephemeral.sgml
 776         doc/lxc-start.sgml
 777         doc/lxc-stop.sgml
 778         doc/lxc-top.sgml
 779         doc/lxc-unfreeze.sgml
 780         doc/lxc-unshare.sgml
 781         doc/lxc-user-nic.sgml
 782         doc/lxc-usernsexec.sgml
 783         doc/lxc-wait.sgml
 784
 785         doc/lxc.conf.sgml
 786         doc/lxc.container.conf.sgml
 787         doc/lxc.system.conf.sgml
 788         doc/lxc-usernet.sgml
 789         doc/lxc.sgml
 790         doc/common_options.sgml
 791         doc/see_also.sgml
 792
 793         doc/rootfs/Makefile
 794
 795         doc/examples/Makefile
 796         doc/examples/lxc-macvlan.conf
 797         doc/examples/lxc-vlan.conf
 798         doc/examples/lxc-no-netns.conf
 799         doc/examples/lxc-empty-netns.conf
 800         doc/examples/lxc-phys.conf
 801         doc/examples/lxc-veth.conf
 802         doc/examples/lxc-complex.conf
 803
 804         doc/ja/Makefile
 805         doc/ja/lxc-attach.sgml
 806         doc/ja/lxc-autostart.sgml
 807         doc/ja/lxc-cgroup.sgml
 808         doc/ja/lxc-checkconfig.sgml
 809         doc/ja/lxc-checkpoint.sgml
 810         doc/ja/lxc-clone.sgml
 811         doc/ja/lxc-config.sgml
 812         doc/ja/lxc-console.sgml
 813         doc/ja/lxc-copy.sgml
 814         doc/ja/lxc-create.sgml
 815         doc/ja/lxc-destroy.sgml
 816         doc/ja/lxc-device.sgml
 817         doc/ja/lxc-execute.sgml
 818         doc/ja/lxc-freeze.sgml
 819         doc/ja/lxc-info.sgml
 820         doc/ja/lxc-ls.sgml
 821         doc/ja/lxc-monitor.sgml
 822         doc/ja/lxc-snapshot.sgml
 823         doc/ja/lxc-start-ephemeral.sgml
 824         doc/ja/lxc-start.sgml
 825         doc/ja/lxc-stop.sgml
 826         doc/ja/lxc-top.sgml
 827         doc/ja/lxc-unfreeze.sgml
 828         doc/ja/lxc-unshare.sgml
 829         doc/ja/lxc-user-nic.sgml
 830         doc/ja/lxc-usernsexec.sgml
 831         doc/ja/lxc-wait.sgml
 832
 833         doc/ja/lxc.conf.sgml
 834         doc/ja/lxc.container.conf.sgml
 835         doc/ja/lxc.system.conf.sgml
 836         doc/ja/lxc-usernet.sgml
 837         doc/ja/lxc.sgml
 838         doc/ja/common_options.sgml
 839         doc/ja/see_also.sgml
 840
 841         doc/ko/Makefile
 842         doc/ko/lxc-attach.sgml
 843         doc/ko/lxc-autostart.sgml
 844         doc/ko/lxc-cgroup.sgml
 845         doc/ko/lxc-checkconfig.sgml
 846         doc/ko/lxc-checkpoint.sgml
 847         doc/ko/lxc-clone.sgml
 848         doc/ko/lxc-config.sgml
 849         doc/ko/lxc-console.sgml
 850         doc/ko/lxc-copy.sgml
 851         doc/ko/lxc-create.sgml
 852         doc/ko/lxc-destroy.sgml
 853         doc/ko/lxc-device.sgml
 854         doc/ko/lxc-execute.sgml
 855         doc/ko/lxc-freeze.sgml
 856         doc/ko/lxc-info.sgml
 857         doc/ko/lxc-ls.sgml
 858         doc/ko/lxc-monitor.sgml
 859         doc/ko/lxc-snapshot.sgml
 860         doc/ko/lxc-start-ephemeral.sgml
 861         doc/ko/lxc-start.sgml
 862         doc/ko/lxc-stop.sgml
 863         doc/ko/lxc-top.sgml
 864         doc/ko/lxc-unfreeze.sgml
 865         doc/ko/lxc-unshare.sgml
 866         doc/ko/lxc-user-nic.sgml
 867         doc/ko/lxc-usernsexec.sgml
 868         doc/ko/lxc-wait.sgml
 869
 870         doc/ko/lxc.conf.sgml
 871         doc/ko/lxc.container.conf.sgml
 872         doc/ko/lxc.system.conf.sgml
 873         doc/ko/lxc-usernet.sgml
 874         doc/ko/lxc.sgml
 875         doc/ko/common_options.sgml
 876         doc/ko/see_also.sgml
 877
 878         hooks/Makefile
 879
 880         templates/Makefile
 881         templates/lxc-alpine
 882         templates/lxc-altlinux
 883         templates/lxc-archlinux
 884         templates/lxc-busybox
 885         templates/lxc-centos
 886         templates/lxc-cirros
 887         templates/lxc-debian
 888         templates/lxc-download
 889         templates/lxc-fedora
 890         templates/lxc-gentoo
 891         templates/lxc-openmandriva
 892         templates/lxc-opensuse
 893         templates/lxc-oracle
 894         templates/lxc-plamo
 895         templates/lxc-pld
 896         templates/lxc-slackware
 897         templates/lxc-sshd
 898         templates/lxc-ubuntu
 899         templates/lxc-ubuntu-cloud
 900         templates/lxc-sparclinux
 901         templates/lxc-voidlinux
 902         templates/lxc-sabayon
 903
 904         src/Makefile
 905         src/lxc/Makefile
 906         src/lxc/lxc.functions
 907         src/lxc/tools/lxc-checkconfig
 908         src/lxc/tools/lxc-start-ephemeral
 909         src/lxc/version.h
 910         src/python-lxc/Makefile
 911
 912         src/lua-lxc/Makefile
 913
 914         src/tests/Makefile
 915         src/tests/lxc-test-usernic
 916 ])
 917 AC_CONFIG_COMMANDS([default],[[]],[[]])
 918 AC_OUTPUT
 919
 920 # Configuration overview
 921 cat << EOF
 922
 923 ----------------------------
 924 Environment:
 925  - compiler: $CC
 926  - distribution: $with_distro
 927  - init script type(s): $init_script
 928  - rpath: $enable_rpath
 929  - GnuTLS: $enable_gnutls
 930  - Bash integration: $enable_bash
 931
 932 Security features:
 933  - Apparmor: $enable_apparmor
 934  - Linux capabilities: $enable_capabilities
 935  - seccomp: $enable_seccomp
 936  - SELinux: $enable_selinux
 937  - cgmanager: $enable_cgmanager
 938
 939 Bindings:
 940  - lua: $enable_lua
 941  - python3: $enable_python
 942
 943 Documentation:
 944  - examples: $enable_examples
 945  - API documentation: $enable_api_docs
 946  - user documentation: $enable_doc
 947
 948 Debugging:
 949  - tests: $enable_tests
 950  - mutex debugging: $enable_mutex_debugging
 951
 952 Paths:
 953  - Logs in configpath: $enable_configpath_log
 954 EOF
 955
 956 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 957 cat << EOF
 958
 959 WARNING: Threading not supported on your platform
 960
 961         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 962         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 963 EOF
 964 fi