configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_devel], 1)
   5 m4_define([lxc_version_major], 2)
   6 m4_define([lxc_version_minor], 1)
   7 m4_define([lxc_version_micro], 0)
   8 m4_define([lxc_version_beta], [])
   9
  10 m4_define([lxc_abi_major], 1)
  11 m4_define([lxc_abi_minor], 3)
  12 m4_define([lxc_abi_micro], 0)
  13 m4_define([lxc_abi], [lxc_abi_major.lxc_abi_minor.lxc_abi_micro])
  14
  15 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  16 m4_define([lxc_version],
  17           [ifelse(lxc_devel, 1,
  18         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])-devel,
  19         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta]))])
  20
  21 AC_INIT([lxc], [lxc_version])
  22
  23 # We need pkg-config
  24 PKG_PROG_PKG_CONFIG
  25
  26 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  27 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  28
  29 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  30 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  31 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  32 AC_SUBST([LXC_VERSION], [lxc_version])
  33 AC_SUBST([LXC_DEVEL], [lxc_devel])
  34
  35 AC_SUBST([LXC_ABI_MAJOR], [lxc_abi_major])
  36 AC_SUBST([LXC_ABI_MINOR], [lxc_abi_minor])
  37 AC_SUBST([LXC_ABI_MICRO], [lxc_abi_micro])
  38 AC_SUBST([LXC_ABI], [lxc_abi])
  39
  40 AC_CONFIG_SRCDIR([configure.ac])
  41 AC_CONFIG_AUX_DIR([config])
  42 AC_CONFIG_HEADERS([src/config.h])
  43 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  44 AC_CANONICAL_HOST
  45 AM_PROG_CC_C_O
  46 AC_GNU_SOURCE
  47
  48 # libtool
  49 LT_INIT
  50 AC_SUBST([LIBTOOL_DEPS])
  51
  52 # Detect the distribution. This is used for the default configuration and
  53 # for some distro-specific build options.
  54 AC_MSG_CHECKING([host distribution])
  55 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva, pardus, sparclinux, altlinux.]))
  56 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  57         with_distro=`lsb_release -is`
  58 fi
  59 if test "z$with_distro" = "z"; then
  60         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  61         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  62         AC_CHECK_FILE(/etc/sparclinux-release,with_distro="sparclinux")
  63         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  64         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  65         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  66         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  67         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  68         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  69         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  70         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
  71         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  72         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  73         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  74         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  75         AC_CHECK_FILE(/etc/altlinux-release,with_distro="altlinux")
  76         AC_CHECK_FILE(/etc/pld-release,with_distro="pld")
  77 fi
  78 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  79
  80 if test "z$with_distro" = "zforsparc"; then
  81         with_distro="sparclinux"
  82 fi
  83
  84 if test "z$with_distro" = "z"; then
  85         with_distro="unknown"
  86 fi
  87 case $with_distro in
  88         ubuntu|raspbian)
  89                 distroconf=default.conf.lxcbr
  90                 distrosysconf="$sysconfdir/default"
  91                 ;;
  92         redhat|centos|fedora|oracle|oracleserver|sparclinux|altlinux|suse|opensuse*|plamo|pld)
  93                 distroconf=default.conf.lxcbr
  94                 distrosysconf="$sysconfdir/sysconfig"
  95                 ;;
  96         *)
  97                 distroconf=default.conf.unknown
  98                 distrosysconf="$sysconfdir/default"
  99                 ;;
 100 esac
 101 AC_MSG_RESULT([$with_distro])
 102 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
 103 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
 104
 105 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
 106
 107 # Check for init system type
 108 AC_MSG_CHECKING([for init system type])
 109 AC_ARG_WITH([init-script],
 110             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
 111                             [Type(s) of init script to install: sysvinit, systemd, upstart,
 112                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
 113 case "$with_init_script" in
 114         distro)
 115                 case $with_distro in
 116                         fedora|altlinux|opensuse*)
 117                                 init_script=systemd
 118                                 ;;
 119                         redhat|oracle|oracleserver|sparclinux|plamo)
 120                                 init_script=sysvinit
 121                                 ;;
 122                         centos)
 123                                 init_script=sysvinit,systemd
 124                                 ;;
 125                         debian|raspbian|ubuntu)
 126                                 init_script=upstart,systemd
 127                                 ;;
 128                         pld)
 129                                 init_script=sysvinit,upstart,systemd
 130                                 ;;
 131                         *)
 132                                 echo -n "Linux distribution init system unknown."
 133                                 init_script=
 134                                 ;;
 135                 esac
 136                 ;;
 137         *)
 138                 init_script=$with_init_script
 139                 ;;
 140 esac
 141
 142 # Check valid init systems were given, run in subshell so we don't mess up IFS
 143 (IFS="," ; for init_sys in $init_script;
 144 do
 145         case "$init_sys" in
 146                 none|sysvinit|systemd|upstart)
 147                         ;;
 148                 *)
 149                         exit 1
 150                         ;;
 151         esac
 152 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 153
 154 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 155 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 156 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 157 AC_MSG_RESULT($init_script)
 158
 159 # systemd unit dir
 160 AC_ARG_WITH([systemdsystemunitdir],
 161             AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 162             [],
 163             [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 164 if test -z "$with_systemdsystemunitdir"; then
 165   with_systemdsystemunitdir=/lib/systemd/system
 166 fi
 167 if test "x$with_systemdsystemunitdir" != "xno"; then
 168   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 169 fi
 170
 171 AC_ARG_ENABLE([werror],
 172         [AC_HELP_STRING([--disable-werror],
 173         [do not treat warnings as errors])],
 174         [], [enable_werror=yes])
 175
 176 # Allow enabling deprecated executables
 177 AC_ARG_ENABLE([deprecated],
 178         [AC_HELP_STRING([--enable-deprecated],
 179         [enable deprecated executables [default=no]])],
 180         [], [enable_deprecated=false])
 181 AM_CONDITIONAL([ENABLE_DEPRECATED], [test "x$enable_deprecated" = "xyes"])
 182
 183 # Allow disabling rpath
 184 AC_ARG_ENABLE([rpath],
 185         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 186         [], [enable_rpath=no])
 187 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 188
 189 # Documentation (manpages)
 190 AC_ARG_ENABLE([doc],
 191         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 192         [], [enable_doc=auto])
 193
 194 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 195         db2xman=""
 196         dbparsers="docbook2X2man docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 197
 198         AC_MSG_CHECKING(for docbook2x-man)
 199         for name in ${dbparsers}; do
 200                 if "$name" --help >/dev/null 2>&1; then
 201                         db2xman="$name"
 202                         break;
 203                 fi
 204         done
 205
 206         if test -n "${db2xman}"; then
 207                 AC_MSG_RESULT([${db2xman}])
 208                 enable_doc="yes"
 209         else
 210                 AC_MSG_RESULT([no])
 211                 if test "x$enable_doc" = "xyes"; then
 212                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 213                 fi
 214                 enable_doc="no"
 215         fi
 216
 217         AC_SUBST(db2xman)
 218 fi
 219 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 220 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 221
 222 if test "x$db2xman" = "xdocbook2man"; then
 223         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 224 else
 225         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 226 fi
 227 AC_SUBST(docdtd)
 228
 229 # Documentation (API)
 230 AC_ARG_ENABLE([api-docs],
 231         [AC_HELP_STRING([--enable-api-docs],
 232         [make API documentation [default=auto]])],
 233         [], [enable_api_docs=auto])
 234
 235 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 236         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 237         AC_SUBST([HAVE_DOXYGEN])
 238
 239         if test "x$HAVE_DOXYGEN" != "x"; then
 240                 enable_api_docs="yes"
 241         else
 242                 if test "x$enable_api_docs" = "xyes"; then
 243                         AC_MSG_ERROR([doxygen is required, but could not be found])
 244                 fi
 245                 enable_api_docs="no"
 246         fi
 247 fi
 248
 249 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 250
 251 # Apparmor
 252 AC_ARG_ENABLE([apparmor],
 253         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 254         [], [enable_apparmor=auto])
 255
 256 if test "$enable_apparmor" = "auto" ; then
 257         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 258 fi
 259 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 260
 261 # GnuTLS
 262 AC_ARG_ENABLE([gnutls],
 263         [AC_HELP_STRING([--enable-gnutls], [enable GnuTLS support [default=auto]])],
 264         [], [enable_gnutls=auto])
 265
 266 if test "$enable_gnutls" = "auto" ; then
 267         AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 268 fi
 269 AM_CONDITIONAL([ENABLE_GNUTLS], [test "x$enable_gnutls" = "xyes"])
 270
 271 AM_COND_IF([ENABLE_GNUTLS],
 272         [AC_CHECK_HEADER([gnutls/gnutls.h],[],[AC_MSG_ERROR([You must install the GnuTLS development package in order to compile lxc])])
 273         AC_CHECK_LIB([gnutls], [gnutls_hash_fast],[],[AC_MSG_ERROR([You must install the GnuTLS development package in order to compile lxc])])
 274         AC_SUBST([GNUTLS_LIBS], [-lgnutls])])
 275
 276 # SELinux
 277 AC_ARG_ENABLE([selinux],
 278         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 279         [], [enable_selinux=auto])
 280
 281 if test "x$enable_selinux" = xauto; then
 282         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 283 fi
 284 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 285 AM_COND_IF([ENABLE_SELINUX],
 286         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 287         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 288         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 289
 290 # Seccomp syscall filter
 291 AC_ARG_ENABLE([seccomp],
 292         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 293         [], [enable_seccomp=auto])
 294
 295 if test "x$enable_seccomp" = "xauto" ; then
 296         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 297 fi
 298 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 299
 300 AM_COND_IF([ENABLE_SECCOMP],
 301         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 302                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 303                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 304                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 305                 ])
 306         ])
 307
 308 AC_MSG_CHECKING(for static libcap)
 309 # Check for static libcap, make sure the function checked for differs from the
 310 # the one checked below so the cache doesn't give a wrong answer
 311 OLD_CFLAGS="$CFLAGS"
 312 OLD_CPPFLAGS="$CPPFLAGS"
 313 OLD_LDFLAGS="$LDFLAGS"
 314 OLD_LIBS="$LIBS"
 315 CFLAGS=""
 316 CPPFLAGS=""
 317 LDFLAGS="-static"
 318 LIBS="-lcap"
 319 AC_LINK_IFELSE([
 320   AC_LANG_SOURCE(
 321     [[int main() { return 0; }]]
 322   )],[have_static_libcap=yes],[have_static_libcap=no])
 323 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 324 if test "x$have_static_libcap" = "xyes"; then
 325         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 326         AC_MSG_RESULT([yes])
 327 else
 328         AC_MSG_RESULT([no])
 329 fi
 330 CPPFLAGS="$OLD_CPPFLAGS"
 331 CFLAGS="$OLD_CFLAGS"
 332 LDFLAGS="$OLD_LDFLAGS"
 333 LIBS="$OLD_LIBS"
 334
 335
 336 # Linux capabilities
 337 AC_ARG_ENABLE([capabilities],
 338         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 339         [], [enable_capabilities=auto])
 340
 341 if test "x$enable_capabilities" = "xauto"; then
 342         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 343 fi
 344 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 345
 346 AM_COND_IF([ENABLE_CAP],
 347         [AC_CHECK_HEADER([sys/capability.h],[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 348         AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 349         # Test whether we support getting file capabilities via cap_get_file().
 350         AC_CHECK_LIB(cap,cap_get_file, AC_DEFINE(LIBCAP_SUPPORTS_FILE_CAPABILITIES,1,[Have cap_get_file]),[],[])
 351         AC_SUBST([CAP_LIBS], [-lcap])])
 352
 353 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 354 OLD_CFLAGS="$CFLAGS"
 355 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 356 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 357 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 358 CFLAGS="$OLD_CFLAGS"
 359
 360 # Configuration examples
 361 AC_ARG_ENABLE([examples],
 362         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 363         [], [enable_examples=yes])
 364 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 365
 366 # Python3 module and scripts
 367 AC_ARG_ENABLE([python],
 368         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 369         [], [enable_python=auto])
 370
 371 if test "x$enable_python" = "xauto"; then
 372         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 373         if test "$CC" = "clang"; then
 374                 enable_python=no
 375         fi
 376 fi
 377
 378 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 379         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 380 fi
 381
 382 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 383
 384 AM_COND_IF([ENABLE_PYTHON],
 385         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 386         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 387         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 388
 389 # Enable dumping stack traces
 390 AC_ARG_ENABLE([mutex-debugging],
 391         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 392         [], [enable_mutex_debugging=no])
 393 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 394
 395 AM_COND_IF([MUTEX_DEBUGGING],
 396         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 397
 398 # Not in older autoconf versions
 399 # AS_VAR_COPY(DEST, SOURCE)
 400 # -------------------------
 401 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 402 # shell variable SOURCE.
 403 m4_ifdef([AS_VAR_COPY], [],
 404 [AC_DEFUN([AS_VAR_COPY],
 405     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 406 ])
 407
 408 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 409 m4_ifdef([PKG_CHECK_VAR], [],
 410 [AC_DEFUN([PKG_CHECK_VAR],
 411     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 412      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 413      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 414      AS_VAR_COPY([$1], [pkg_cv_][$1])
 415      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 416     ])# PKG_CHECK_VAR
 417 ])
 418
 419 # Lua module and scripts
 420 AC_ARG_ENABLE([lua],
 421         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 422         [], [enable_lua=auto])
 423
 424 AC_ARG_WITH([lua-pc],
 425         [AS_HELP_STRING(
 426                 [--with-lua-pc=PKG],
 427                 [Specify pkg-config package name for lua]
 428         )], [], [with_lua_pc=no])
 429
 430 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 431         # exit with error if not found
 432         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 433 fi
 434
 435 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 436         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 437                 [LUAPKGCONFIG=$with_lua_pc
 438                 enable_lua=yes],
 439                 [enable_lua=no])
 440 fi
 441
 442 if test "x$enable_lua" != "xno"; then
 443         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 444                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 445                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 446                                 [AS_IF([test "x$enable_lua" = "xyes"],
 447                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 448                                         [enable_lua=no])]
 449                         )]
 450                 )])
 451         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 452 fi
 453
 454 AM_CONDITIONAL([ENABLE_LUA],
 455         [test "x$enable_lua" = "xyes"])
 456
 457 AM_COND_IF([ENABLE_LUA],
 458         [AC_MSG_CHECKING([Lua version])
 459         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 460                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 461         AC_MSG_RESULT([$LUA_VERSION])
 462         AC_SUBST([LUA_LIBDIR], [$libdir/lua/$LUA_VERSION])
 463         AC_SUBST([LUA_SHAREDIR], [$datadir/lua/$LUA_VERSION])
 464         ])
 465
 466 # Optional bash integration
 467 AC_ARG_ENABLE([bash],
 468         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 469         [], [enable_bash=yes])
 470 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 471
 472 AM_COND_IF([ENABLE_BASH],
 473         [AC_MSG_CHECKING([bash completion directory])
 474         PKG_CHECK_VAR(bashcompdir, [bash-completion], [completionsdir], ,
 475                 bashcompdir="${sysconfdir}/bash_completion.d")
 476         AC_MSG_RESULT([$bashcompdir])
 477         AC_SUBST(bashcompdir)
 478         ])
 479
 480 # Optional test binaries
 481 AC_ARG_ENABLE([tests],
 482         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 483         [], [enable_tests=no])
 484 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 485
 486 # Allow overriding the default runtime dir (/run)
 487 AC_ARG_WITH([runtime-path],
 488         [AC_HELP_STRING(
 489                 [--with-runtime-path=dir],
 490                 [runtime directory (default: /run)]
 491         )], [], [with_runtime_path=['/run']])
 492
 493 # LXC container path, where the containers are actually stored
 494 # This is overridden by an entry in the file called LXCCONF
 495 # (i.e. /etc/lxc/lxc.conf)
 496 AC_ARG_WITH([config-path],
 497         [AC_HELP_STRING(
 498                 [--with-config-path=dir],
 499                 [lxc configuration repository path]
 500         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 501
 502 # The path of the global lxc configuration file.
 503 AC_ARG_WITH([global-conf],
 504         [AC_HELP_STRING(
 505                 [--with-global-conf=dir],
 506                 [global lxc configuration file]
 507         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 508
 509 # The path of the userns network configuration file
 510 AC_ARG_WITH([usernic-conf],
 511         [AC_HELP_STRING(
 512                 [--with-usernic-conf],
 513                 [user network interface configuration file]
 514         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 515
 516 # The path of the runtime usernic database
 517 AC_ARG_WITH([usernic-db],
 518         [AC_HELP_STRING(
 519                 [--with-usernic-db],
 520                 [lxc user nic database]
 521         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 522
 523 # Rootfs path, where the container mount structure is assembled
 524 AC_ARG_WITH([rootfs-path],
 525         [AC_HELP_STRING(
 526                 [--with-rootfs-path=dir],
 527                 [lxc rootfs mount point]
 528         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 529
 530 # cgroup pattern specification
 531 AC_ARG_WITH([cgroup-pattern],
 532         [AC_HELP_STRING(
 533                 [--with-cgroup-pattern=pattern],
 534                 [pattern for container cgroups]
 535         )], [], [with_cgroup_pattern=['lxc/%n']])
 536
 537 # Container log path.  By default, use $lxcpath.
 538 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 539 AC_ARG_ENABLE([configpath-log],
 540         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 541         [], [enable_configpath_log=no])
 542 AC_MSG_RESULT([$enable_configpath_log])
 543 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 544
 545 if test "$enable_configpath_log" = "yes"; then
 546         default_log_path="${with_config_path}"
 547 else
 548         default_log_path="${localstatedir}/log/lxc"
 549 fi
 550
 551 AC_ARG_WITH([log-path],
 552         [AC_HELP_STRING(
 553                 [--with-log-path=dir],
 554                 [per container log path]
 555         )], [], [with_log_path=['${default_log_path}']])
 556
 557 # Expand some useful variables
 558 AS_AC_EXPAND(PREFIX, "$prefix")
 559 AS_AC_EXPAND(LIBDIR, "$libdir")
 560 AS_AC_EXPAND(BINDIR, "$bindir")
 561 AS_AC_EXPAND(SBINDIR, "$sbindir")
 562 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 563 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 564 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 565 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 566 AS_AC_EXPAND(DATADIR, "$datadir")
 567 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 568 AS_AC_EXPAND(DOCDIR, "$docdir")
 569 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date --utc --date=@${SOURCE_DATE_EPOCH:-$(date +%s)} '+%Y-%m-%d')")
 570 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 571 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 572 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 573 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 574 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 575 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 576 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 577 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 578 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 579 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 580 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 581 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 582 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 583 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 584
 585 # We need the install path so criu knows where to reference the hook scripts.
 586 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 587
 588 # Check for some standard kernel headers
 589 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 590                                 [],
 591                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 592                                 [#include <sys/socket.h>])
 593
 594 # Check for alternate C libraries
 595 AC_MSG_CHECKING(for bionic libc)
 596 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 597         [[#ifndef __ANDROID__
 598 error: Not bionic!
 599 #endif]])],
 600         [is_bionic=yes],
 601         [is_bionic=no])
 602 if test "x$is_bionic" = "xyes"; then
 603         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 604         AC_MSG_RESULT([yes])
 605 else
 606         AC_MSG_RESULT([no])
 607 fi
 608 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 609
 610 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 611 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 612
 613 # Some systems lack PR_{G,S}ET_NO_NEW_PRIVS definition => HAVE_DECL_PR_{G,S}ET_NO_NEW_PRIVS
 614 AC_CHECK_DECLS([PR_SET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 615 AC_CHECK_DECLS([PR_GET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 616
 617 # Check for some headers
 618 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/memfd.h sys/personality.h utmpx.h sys/timerfd.h sys/resource.h])
 619
 620 # lookup major()/minor()/makedev()
 621 AC_HEADER_MAJOR
 622
 623 # Check for some syscalls functions
 624 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat gettid memfd_create])
 625
 626 # Check for some functions
 627 AC_CHECK_LIB(pthread, main)
 628 AC_CHECK_FUNCS(statvfs)
 629 AC_CHECK_LIB(util, openpty)
 630 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 631 AC_CHECK_FUNCS([getline],
 632         AM_CONDITIONAL(HAVE_GETLINE, true)
 633         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 634         AM_CONDITIONAL(HAVE_GETLINE, false))
 635 AC_CHECK_FUNCS([getsubopt],
 636         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 637         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 638         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 639 AC_CHECK_FUNCS([fgetln],
 640         AM_CONDITIONAL(HAVE_FGETLN, true)
 641         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 642         AM_CONDITIONAL(HAVE_FGETLN, false))
 643 AC_CHECK_FUNCS([prlimit],
 644         AM_CONDITIONAL(HAVE_PRLIMIT, true)
 645         AC_DEFINE(HAVE_PRLIMIT,1,[Have prlimit]),
 646         AM_CONDITIONAL(HAVE_PRLIMIT, false))
 647 AC_CHECK_FUNCS([prlimit64],
 648         AM_CONDITIONAL(HAVE_PRLIMIT64, true)
 649         AC_DEFINE(HAVE_PRLIMIT64,1,[Have prlimit64]),
 650         AM_CONDITIONAL(HAVE_PRLIMIT64, false))
 651
 652 # Check for some libraries
 653 AX_PTHREAD
 654 AC_SEARCH_LIBS(clock_gettime, [rt])
 655
 656 # Check for some standard binaries
 657 AC_PROG_GCC_TRADITIONAL
 658 AC_PROG_SED
 659
 660 # See if we support thread-local storage.
 661 LXC_CHECK_TLS
 662
 663 if test "x$GCC" = "xyes"; then
 664         CFLAGS="$CFLAGS -Wall"
 665         if test "x$enable_werror" = "xyes"; then
 666                 CFLAGS="$CFLAGS -Werror"
 667         fi
 668 fi
 669
 670 # Files requiring some variable expansion
 671 AC_CONFIG_FILES([
 672         Makefile
 673         lxc.pc
 674         lxc.spec
 675
 676         config/Makefile
 677         config/apparmor/Makefile
 678         config/selinux/Makefile
 679         config/bash/Makefile
 680         config/bash/lxc
 681         config/init/Makefile
 682         config/init/common/Makefile
 683         config/init/common/lxc-containers
 684         config/init/common/lxc-net
 685         config/init/systemd/Makefile
 686         config/init/systemd/lxc.service
 687         config/init/systemd/lxc@.service
 688         config/init/systemd/lxc-net.service
 689         config/init/sysvinit/Makefile
 690         config/init/sysvinit/lxc-containers
 691         config/init/sysvinit/lxc-net
 692         config/init/upstart/lxc.conf
 693         config/init/upstart/lxc-net.conf
 694         config/init/upstart/Makefile
 695         config/etc/Makefile
 696         config/templates/Makefile
 697         config/templates/alpine.common.conf
 698         config/templates/alpine.userns.conf
 699         config/templates/archlinux.common.conf
 700         config/templates/archlinux.userns.conf
 701         config/templates/centos.common.conf
 702         config/templates/centos.userns.conf
 703         config/templates/common.conf
 704         config/templates/common.conf.d/Makefile
 705         config/templates/debian.common.conf
 706         config/templates/debian.userns.conf
 707         config/templates/fedora.common.conf
 708         config/templates/fedora.userns.conf
 709         config/templates/gentoo.common.conf
 710         config/templates/gentoo.moresecure.conf
 711         config/templates/gentoo.userns.conf
 712         config/templates/nesting.conf
 713         config/templates/oci.common.conf
 714         config/templates/opensuse.common.conf
 715         config/templates/opensuse.userns.conf
 716         config/templates/oracle.common.conf
 717         config/templates/oracle.userns.conf
 718         config/templates/plamo.common.conf
 719         config/templates/plamo.userns.conf
 720         config/templates/slackware.common.conf
 721         config/templates/slackware.userns.conf
 722         config/templates/ubuntu-cloud.common.conf
 723         config/templates/ubuntu-cloud.lucid.conf
 724         config/templates/ubuntu-cloud.userns.conf
 725         config/templates/ubuntu.common.conf
 726         config/templates/ubuntu.lucid.conf
 727         config/templates/ubuntu.userns.conf
 728         config/templates/openwrt.common.conf
 729         config/templates/sparclinux.common.conf
 730         config/templates/sparclinux.userns.conf
 731         config/templates/voidlinux.common.conf
 732         config/templates/voidlinux.userns.conf
 733         config/templates/sabayon.common.conf
 734         config/templates/sabayon.userns.conf
 735         config/templates/userns.conf
 736         config/yum/Makefile
 737         config/sysconfig/Makefile
 738         config/sysconfig/lxc
 739
 740         doc/Makefile
 741         doc/api/Makefile
 742         doc/lxc-attach.sgml
 743         doc/lxc-autostart.sgml
 744         doc/lxc-cgroup.sgml
 745         doc/lxc-checkconfig.sgml
 746         doc/lxc-checkpoint.sgml
 747         doc/lxc-clone.sgml
 748         doc/lxc-config.sgml
 749         doc/lxc-console.sgml
 750         doc/lxc-copy.sgml
 751         doc/lxc-create.sgml
 752         doc/lxc-destroy.sgml
 753         doc/lxc-device.sgml
 754         doc/lxc-execute.sgml
 755         doc/lxc-freeze.sgml
 756         doc/lxc-info.sgml
 757         doc/lxc-ls.sgml
 758         doc/lxc-monitor.sgml
 759         doc/lxc-snapshot.sgml
 760         doc/lxc-start-ephemeral.sgml
 761         doc/lxc-start.sgml
 762         doc/lxc-stop.sgml
 763         doc/lxc-top.sgml
 764         doc/lxc-unfreeze.sgml
 765         doc/lxc-unshare.sgml
 766         doc/lxc-update-config.sgml
 767         doc/lxc-user-nic.sgml
 768         doc/lxc-usernsexec.sgml
 769         doc/lxc-wait.sgml
 770
 771         doc/lxc.conf.sgml
 772         doc/lxc.container.conf.sgml
 773         doc/lxc.system.conf.sgml
 774         doc/lxc-usernet.sgml
 775         doc/lxc.sgml
 776         doc/common_options.sgml
 777         doc/see_also.sgml
 778
 779         doc/rootfs/Makefile
 780
 781         doc/examples/Makefile
 782         doc/examples/lxc-macvlan.conf
 783         doc/examples/lxc-vlan.conf
 784         doc/examples/lxc-no-netns.conf
 785         doc/examples/lxc-empty-netns.conf
 786         doc/examples/lxc-phys.conf
 787         doc/examples/lxc-veth.conf
 788         doc/examples/lxc-complex.conf
 789
 790         doc/ja/Makefile
 791         doc/ja/lxc-attach.sgml
 792         doc/ja/lxc-autostart.sgml
 793         doc/ja/lxc-cgroup.sgml
 794         doc/ja/lxc-checkconfig.sgml
 795         doc/ja/lxc-checkpoint.sgml
 796         doc/ja/lxc-clone.sgml
 797         doc/ja/lxc-config.sgml
 798         doc/ja/lxc-console.sgml
 799         doc/ja/lxc-copy.sgml
 800         doc/ja/lxc-create.sgml
 801         doc/ja/lxc-destroy.sgml
 802         doc/ja/lxc-device.sgml
 803         doc/ja/lxc-execute.sgml
 804         doc/ja/lxc-freeze.sgml
 805         doc/ja/lxc-info.sgml
 806         doc/ja/lxc-ls.sgml
 807         doc/ja/lxc-monitor.sgml
 808         doc/ja/lxc-snapshot.sgml
 809         doc/ja/lxc-start-ephemeral.sgml
 810         doc/ja/lxc-start.sgml
 811         doc/ja/lxc-stop.sgml
 812         doc/ja/lxc-top.sgml
 813         doc/ja/lxc-unfreeze.sgml
 814         doc/ja/lxc-unshare.sgml
 815         doc/ja/lxc-update-config.sgml
 816         doc/ja/lxc-user-nic.sgml
 817         doc/ja/lxc-usernsexec.sgml
 818         doc/ja/lxc-wait.sgml
 819
 820         doc/ja/lxc.conf.sgml
 821         doc/ja/lxc.container.conf.sgml
 822         doc/ja/lxc.system.conf.sgml
 823         doc/ja/lxc-usernet.sgml
 824         doc/ja/lxc.sgml
 825         doc/ja/common_options.sgml
 826         doc/ja/see_also.sgml
 827
 828         doc/ko/Makefile
 829         doc/ko/lxc-attach.sgml
 830         doc/ko/lxc-autostart.sgml
 831         doc/ko/lxc-cgroup.sgml
 832         doc/ko/lxc-checkconfig.sgml
 833         doc/ko/lxc-checkpoint.sgml
 834         doc/ko/lxc-clone.sgml
 835         doc/ko/lxc-config.sgml
 836         doc/ko/lxc-console.sgml
 837         doc/ko/lxc-copy.sgml
 838         doc/ko/lxc-create.sgml
 839         doc/ko/lxc-destroy.sgml
 840         doc/ko/lxc-device.sgml
 841         doc/ko/lxc-execute.sgml
 842         doc/ko/lxc-freeze.sgml
 843         doc/ko/lxc-info.sgml
 844         doc/ko/lxc-ls.sgml
 845         doc/ko/lxc-monitor.sgml
 846         doc/ko/lxc-snapshot.sgml
 847         doc/ko/lxc-start-ephemeral.sgml
 848         doc/ko/lxc-start.sgml
 849         doc/ko/lxc-stop.sgml
 850         doc/ko/lxc-top.sgml
 851         doc/ko/lxc-unfreeze.sgml
 852         doc/ko/lxc-unshare.sgml
 853         doc/ko/lxc-user-nic.sgml
 854         doc/ko/lxc-usernsexec.sgml
 855         doc/ko/lxc-wait.sgml
 856
 857         doc/ko/lxc.conf.sgml
 858         doc/ko/lxc.container.conf.sgml
 859         doc/ko/lxc.system.conf.sgml
 860         doc/ko/lxc-usernet.sgml
 861         doc/ko/lxc.sgml
 862         doc/ko/common_options.sgml
 863         doc/ko/see_also.sgml
 864
 865         hooks/Makefile
 866         hooks/dhclient
 867
 868         templates/Makefile
 869         templates/lxc-alpine
 870         templates/lxc-altlinux
 871         templates/lxc-archlinux
 872         templates/lxc-busybox
 873         templates/lxc-centos
 874         templates/lxc-cirros
 875         templates/lxc-debian
 876         templates/lxc-download
 877         templates/lxc-fedora
 878         templates/lxc-fedora-legacy
 879         templates/lxc-gentoo
 880         templates/lxc-local
 881         templates/lxc-oci
 882         templates/lxc-openmandriva
 883         templates/lxc-opensuse
 884         templates/lxc-oracle
 885         templates/lxc-plamo
 886         templates/lxc-pld
 887         templates/lxc-slackware
 888         templates/lxc-sshd
 889         templates/lxc-ubuntu
 890         templates/lxc-ubuntu-cloud
 891         templates/lxc-sparclinux
 892         templates/lxc-voidlinux
 893         templates/lxc-sabayon
 894
 895         src/Makefile
 896         src/lxc/Makefile
 897         src/lxc/lxc.functions
 898         src/lxc/cmd/lxc-checkconfig
 899         src/lxc/cmd/lxc-update-config
 900         src/lxc/tools/lxc-start-ephemeral
 901         src/lxc/version.h
 902         src/python-lxc/Makefile
 903
 904         src/lua-lxc/Makefile
 905
 906         src/tests/Makefile
 907         src/tests/lxc-test-usernic
 908 ])
 909 AC_CONFIG_COMMANDS([default],[[]],[[]])
 910 AC_OUTPUT
 911
 912 # Configuration overview
 913 cat << EOF
 914
 915 ----------------------------
 916 Environment:
 917  - compiler: $CC
 918  - distribution: $with_distro
 919  - init script type(s): $init_script
 920  - rpath: $enable_rpath
 921  - GnuTLS: $enable_gnutls
 922  - Bash integration: $enable_bash
 923
 924 Security features:
 925  - Apparmor: $enable_apparmor
 926  - Linux capabilities: $enable_capabilities
 927  - seccomp: $enable_seccomp
 928  - SELinux: $enable_selinux
 929
 930 Bindings:
 931  - lua: $enable_lua
 932  - python3: $enable_python
 933
 934 Documentation:
 935  - examples: $enable_examples
 936  - API documentation: $enable_api_docs
 937  - user documentation: $enable_doc
 938
 939 Debugging:
 940  - tests: $enable_tests
 941  - mutex debugging: $enable_mutex_debugging
 942
 943 Paths:
 944  - Logs in configpath: $enable_configpath_log
 945 EOF