configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_devel], 1)
   5 m4_define([lxc_version_major], 2)
   6 m4_define([lxc_version_minor], 1)
   7 m4_define([lxc_version_micro], 0)
   8 m4_define([lxc_version_beta], [])
   9
  10 m4_define([lxc_abi_major], 1)
  11 m4_define([lxc_abi_minor], 3)
  12 m4_define([lxc_abi_micro], 0)
  13 m4_define([lxc_abi], [lxc_abi_major.lxc_abi_minor.lxc_abi_micro])
  14
  15 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  16 m4_define([lxc_version],
  17           [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])])
  18
  19 AC_INIT([lxc], [lxc_version])
  20
  21 # We need pkg-config
  22 PKG_PROG_PKG_CONFIG
  23
  24 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  25 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  26
  27 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  28 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  29 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  30 AC_SUBST([LXC_VERSION], [lxc_version])
  31 AC_SUBST([LXC_DEVEL], [lxc_devel])
  32
  33 AC_SUBST([LXC_ABI_MAJOR], [lxc_abi_major])
  34 AC_SUBST([LXC_ABI_MINOR], [lxc_abi_minor])
  35 AC_SUBST([LXC_ABI_MICRO], [lxc_abi_micro])
  36 AC_SUBST([LXC_ABI], [lxc_abi])
  37
  38 AC_CONFIG_SRCDIR([configure.ac])
  39 AC_CONFIG_AUX_DIR([config])
  40 AC_CONFIG_HEADERS([src/config.h])
  41 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  42 AC_CANONICAL_HOST
  43 AM_PROG_CC_C_O
  44 AC_GNU_SOURCE
  45
  46 # libtool
  47 LT_INIT
  48 AC_SUBST([LIBTOOL_DEPS])
  49
  50 # Detect the distribution. This is used for the default configuration and
  51 # for some distro-specific build options.
  52 AC_MSG_CHECKING([host distribution])
  53 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva, pardus, sparclinux, altlinux.]))
  54 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  55         with_distro=`lsb_release -is`
  56 fi
  57 if test "z$with_distro" = "z"; then
  58         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  59         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  60         AC_CHECK_FILE(/etc/sparclinux-release,with_distro="sparclinux")
  61         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  62         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  63         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  64         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  65         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  66         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  67         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  68         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
  69         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  70         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  71         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  72         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  73         AC_CHECK_FILE(/etc/altlinux-release,with_distro="altlinux")
  74         AC_CHECK_FILE(/etc/pld-release,with_distro="pld")
  75 fi
  76 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  77
  78 if test "z$with_distro" = "zforsparc"; then
  79         with_distro="sparclinux"
  80 fi
  81
  82 if test "z$with_distro" = "z"; then
  83         with_distro="unknown"
  84 fi
  85 case $with_distro in
  86         ubuntu|raspbian)
  87                 distroconf=default.conf.lxcbr
  88                 distrosysconf="$sysconfdir/default"
  89                 ;;
  90         redhat|centos|fedora|oracle|oracleserver|sparclinux|altlinux|suse|opensuse*|plamo|pld)
  91                 distroconf=default.conf.lxcbr
  92                 distrosysconf="$sysconfdir/sysconfig"
  93                 ;;
  94         *)
  95                 distroconf=default.conf.unknown
  96                 distrosysconf="$sysconfdir/default"
  97                 ;;
  98 esac
  99 AC_MSG_RESULT([$with_distro])
 100 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
 101 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
 102
 103 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
 104
 105 # Check for init system type
 106 AC_MSG_CHECKING([for init system type])
 107 AC_ARG_WITH([init-script],
 108             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
 109                             [Type(s) of init script to install: sysvinit, systemd, upstart,
 110                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
 111 case "$with_init_script" in
 112         distro)
 113                 case $with_distro in
 114                         fedora|altlinux|opensuse*)
 115                                 init_script=systemd
 116                                 ;;
 117                         redhat|oracle|oracleserver|sparclinux|plamo)
 118                                 init_script=sysvinit
 119                                 ;;
 120                         centos)
 121                                 init_script=sysvinit,systemd
 122                                 ;;
 123                         debian|raspbian|ubuntu)
 124                                 init_script=upstart,systemd
 125                                 ;;
 126                         pld)
 127                                 init_script=sysvinit,upstart,systemd
 128                                 ;;
 129                         *)
 130                                 echo -n "Linux distribution init system unknown."
 131                                 init_script=
 132                                 ;;
 133                 esac
 134                 ;;
 135         *)
 136                 init_script=$with_init_script
 137                 ;;
 138 esac
 139
 140 # Check valid init systems were given, run in subshell so we don't mess up IFS
 141 (IFS="," ; for init_sys in $init_script;
 142 do
 143         case "$init_sys" in
 144                 none|sysvinit|systemd|upstart)
 145                         ;;
 146                 *)
 147                         exit 1
 148                         ;;
 149         esac
 150 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 151
 152 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 153 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 154 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 155 AC_MSG_RESULT($init_script)
 156
 157 # systemd unit dir
 158 AC_ARG_WITH([systemdsystemunitdir],
 159             AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 160             [],
 161             [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 162 if test -z "$with_systemdsystemunitdir"; then
 163   with_systemdsystemunitdir=/lib/systemd/system
 164 fi
 165 if test "x$with_systemdsystemunitdir" != "xno"; then
 166   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 167 fi
 168
 169 AC_ARG_ENABLE([werror],
 170         [AC_HELP_STRING([--disable-werror],
 171         [do not treat warnings as errors])],
 172         [], [enable_werror=yes])
 173
 174 # Allow enabling deprecated executables
 175 AC_ARG_ENABLE([deprecated],
 176         [AC_HELP_STRING([--enable-deprecated],
 177         [enable deprecated executables [default=no]])],
 178         [], [enable_deprecated=false])
 179 AM_CONDITIONAL([ENABLE_DEPRECATED], [test "x$enable_deprecated" = "xyes"])
 180
 181 # Allow disabling rpath
 182 AC_ARG_ENABLE([rpath],
 183         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 184         [], [enable_rpath=no])
 185 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 186
 187 # Documentation (manpages)
 188 AC_ARG_ENABLE([doc],
 189         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 190         [], [enable_doc=auto])
 191
 192 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 193         db2xman=""
 194         dbparsers="docbook2X2man docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 195
 196         AC_MSG_CHECKING(for docbook2x-man)
 197         for name in ${dbparsers}; do
 198                 if "$name" --help >/dev/null 2>&1; then
 199                         db2xman="$name"
 200                         break;
 201                 fi
 202         done
 203
 204         if test -n "${db2xman}"; then
 205                 AC_MSG_RESULT([${db2xman}])
 206                 enable_doc="yes"
 207         else
 208                 AC_MSG_RESULT([no])
 209                 if test "x$enable_doc" = "xyes"; then
 210                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 211                 fi
 212                 enable_doc="no"
 213         fi
 214
 215         AC_SUBST(db2xman)
 216 fi
 217 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 218 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 219
 220 if test "x$db2xman" = "xdocbook2man"; then
 221         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 222 else
 223         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 224 fi
 225 AC_SUBST(docdtd)
 226
 227 # Documentation (API)
 228 AC_ARG_ENABLE([api-docs],
 229         [AC_HELP_STRING([--enable-api-docs],
 230         [make API documentation [default=auto]])],
 231         [], [enable_api_docs=auto])
 232
 233 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 234         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 235         AC_SUBST([HAVE_DOXYGEN])
 236
 237         if test "x$HAVE_DOXYGEN" != "x"; then
 238                 enable_api_docs="yes"
 239         else
 240                 if test "x$enable_api_docs" = "xyes"; then
 241                         AC_MSG_ERROR([doxygen is required, but could not be found])
 242                 fi
 243                 enable_api_docs="no"
 244         fi
 245 fi
 246
 247 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 248
 249 # Apparmor
 250 AC_ARG_ENABLE([apparmor],
 251         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 252         [], [enable_apparmor=auto])
 253
 254 if test "$enable_apparmor" = "auto" ; then
 255         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 256 fi
 257 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 258
 259 AM_COND_IF([ENABLE_APPARMOR],
 260         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 261         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 262         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 263
 264 # GnuTLS
 265 AC_ARG_ENABLE([gnutls],
 266         [AC_HELP_STRING([--enable-gnutls], [enable GnuTLS support [default=auto]])],
 267         [], [enable_gnutls=auto])
 268
 269 if test "$enable_gnutls" = "auto" ; then
 270         AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 271 fi
 272 AM_CONDITIONAL([ENABLE_GNUTLS], [test "x$enable_gnutls" = "xyes"])
 273
 274 AM_COND_IF([ENABLE_GNUTLS],
 275         [AC_CHECK_HEADER([gnutls/gnutls.h],[],[AC_MSG_ERROR([You must install the GnuTLS development package in order to compile lxc])])
 276         AC_CHECK_LIB([gnutls], [gnutls_hash_fast],[],[AC_MSG_ERROR([You must install the GnuTLS development package in order to compile lxc])])
 277         AC_SUBST([GNUTLS_LIBS], [-lgnutls])])
 278
 279 # SELinux
 280 AC_ARG_ENABLE([selinux],
 281         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 282         [], [enable_selinux=auto])
 283
 284 if test "x$enable_selinux" = xauto; then
 285         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 286 fi
 287 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 288 AM_COND_IF([ENABLE_SELINUX],
 289         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 290         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 291         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 292
 293 # Seccomp syscall filter
 294 AC_ARG_ENABLE([seccomp],
 295         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 296         [], [enable_seccomp=auto])
 297
 298 if test "x$enable_seccomp" = "xauto" ; then
 299         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 300 fi
 301 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 302
 303 AM_COND_IF([ENABLE_SECCOMP],
 304         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 305                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 306                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 307                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 308                 ])
 309         ])
 310
 311 # cgmanager
 312 AC_ARG_ENABLE([cgmanager],
 313         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 314         [], [enable_cgmanager=auto])
 315
 316 if test "x$enable_cgmanager" = "xauto" ; then
 317         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus -ldbus-1])
 318 fi
 319 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 320
 321 AM_COND_IF([ENABLE_CGMANAGER],
 322         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 323         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 324         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 325         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 326         ])
 327
 328 AC_MSG_CHECKING(for get_pid_cgroup_abs_sync)
 329 save_LIBS=$LIBS
 330 AC_SEARCH_LIBS([cgmanager_get_pid_cgroup_abs_sync], [cgmanager], [have_abs_cgroups=yes], [have_abs_cgroups=no], [-lnih -lnih-dbus -ldbus-1])
 331 LIBS=$save_LIBS
 332 if test "x$have_abs_cgroups" = "xyes"; then
 333         AC_DEFINE([HAVE_CGMANAGER_GET_PID_CGROUP_ABS_SYNC], 1, [Have cgmanager_get_pid_cgroup_abs_sync])
 334         AC_MSG_RESULT([yes])
 335 else
 336         AC_MSG_RESULT([no])
 337 fi
 338
 339 AC_MSG_CHECKING(for cgmanager_list_controllers)
 340 save_LIBS=$LIBS
 341 AC_SEARCH_LIBS([cgmanager_list_controllers_sync], [cgmanager], [have_list_controllers=yes], [have_list_controllers=no], [-lnih -lnih-dbus -ldbus-1])
 342 LIBS=$save_LIBS
 343 if test "x$have_list_controllers" = "xyes"; then
 344         AC_DEFINE([HAVE_CGMANAGER_LIST_CONTROLLERS], 1, [Have cgmanager_list_controllers])
 345         AC_MSG_RESULT([yes])
 346 else
 347         AC_MSG_RESULT([no])
 348 fi
 349
 350 AC_MSG_CHECKING(for static libcap)
 351 # Check for static libcap, make sure the function checked for differs from the
 352 # the one checked below so the cache doesn't give a wrong answer
 353 OLD_CFLAGS="$CFLAGS"
 354 OLD_CPPFLAGS="$CPPFLAGS"
 355 OLD_LDFLAGS="$LDFLAGS"
 356 OLD_LIBS="$LIBS"
 357 CFLAGS=""
 358 CPPFLAGS=""
 359 LDFLAGS="-static"
 360 LIBS="-lcap"
 361 AC_LINK_IFELSE([
 362   AC_LANG_SOURCE(
 363     [[int main() { return 0; }]]
 364   )],[have_static_libcap=yes],[have_static_libcap=no])
 365 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 366 if test "x$have_static_libcap" = "xyes"; then
 367         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 368         AC_MSG_RESULT([yes])
 369 else
 370         AC_MSG_RESULT([no])
 371 fi
 372 CPPFLAGS="$OLD_CPPFLAGS"
 373 CFLAGS="$OLD_CFLAGS"
 374 LDFLAGS="$OLD_LDFLAGS"
 375 LIBS="$OLD_LIBS"
 376
 377
 378 # Linux capabilities
 379 AC_ARG_ENABLE([capabilities],
 380         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 381         [], [enable_capabilities=auto])
 382
 383 if test "x$enable_capabilities" = "xauto"; then
 384         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 385 fi
 386 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 387
 388 AM_COND_IF([ENABLE_CAP],
 389         [AC_CHECK_HEADER([sys/capability.h],[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 390         AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 391         # Test whether we support getting file capabilities via cap_get_file().
 392         AC_CHECK_LIB(cap,cap_get_file, AC_DEFINE(LIBCAP_SUPPORTS_FILE_CAPABILITIES,1,[Have cap_get_file]),[],[])
 393         AC_SUBST([CAP_LIBS], [-lcap])])
 394
 395 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 396 OLD_CFLAGS="$CFLAGS"
 397 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 398 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 399 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 400 CFLAGS="$OLD_CFLAGS"
 401
 402 # Configuration examples
 403 AC_ARG_ENABLE([examples],
 404         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 405         [], [enable_examples=yes])
 406 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 407
 408 # Python3 module and scripts
 409 AC_ARG_ENABLE([python],
 410         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 411         [], [enable_python=auto])
 412
 413 if test "x$enable_python" = "xauto"; then
 414         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 415         if test "$CC" = "clang"; then
 416                 enable_python=no
 417         fi
 418 fi
 419
 420 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 421         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 422 fi
 423
 424 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 425
 426 AM_COND_IF([ENABLE_PYTHON],
 427         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 428         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 429         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 430
 431 # Enable dumping stack traces
 432 AC_ARG_ENABLE([mutex-debugging],
 433         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 434         [], [enable_mutex_debugging=no])
 435 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 436
 437 AM_COND_IF([MUTEX_DEBUGGING],
 438         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 439
 440 # Not in older autoconf versions
 441 # AS_VAR_COPY(DEST, SOURCE)
 442 # -------------------------
 443 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 444 # shell variable SOURCE.
 445 m4_ifdef([AS_VAR_COPY], [],
 446 [AC_DEFUN([AS_VAR_COPY],
 447     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 448 ])
 449
 450 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 451 m4_ifdef([PKG_CHECK_VAR], [],
 452 [AC_DEFUN([PKG_CHECK_VAR],
 453     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 454      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 455      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 456      AS_VAR_COPY([$1], [pkg_cv_][$1])
 457      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 458     ])# PKG_CHECK_VAR
 459 ])
 460
 461 # Lua module and scripts
 462 AC_ARG_ENABLE([lua],
 463         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 464         [], [enable_lua=auto])
 465
 466 AC_ARG_WITH([lua-pc],
 467         [AS_HELP_STRING(
 468                 [--with-lua-pc=PKG],
 469                 [Specify pkg-config package name for lua]
 470         )], [], [with_lua_pc=no])
 471
 472 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 473         # exit with error if not found
 474         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 475 fi
 476
 477 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 478         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 479                 [LUAPKGCONFIG=$with_lua_pc
 480                 enable_lua=yes],
 481                 [enable_lua=no])
 482 fi
 483
 484 if test "x$enable_lua" != "xno"; then
 485         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 486                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 487                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 488                                 [AS_IF([test "x$enable_lua" = "xyes"],
 489                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 490                                         [enable_lua=no])]
 491                         )]
 492                 )])
 493         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 494 fi
 495
 496 AM_CONDITIONAL([ENABLE_LUA],
 497         [test "x$enable_lua" = "xyes"])
 498
 499 AM_COND_IF([ENABLE_LUA],
 500         [AC_MSG_CHECKING([Lua version])
 501         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 502                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 503         AC_MSG_RESULT([$LUA_VERSION])
 504         AC_SUBST([LUA_LIBDIR], [$libdir/lua/$LUA_VERSION])
 505         AC_SUBST([LUA_SHAREDIR], [$datadir/lua/$LUA_VERSION])
 506         ])
 507
 508 # Optional bash integration
 509 AC_ARG_ENABLE([bash],
 510         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 511         [], [enable_bash=yes])
 512 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 513
 514 AM_COND_IF([ENABLE_BASH],
 515         [AC_MSG_CHECKING([bash completion directory])
 516         PKG_CHECK_VAR(bashcompdir, [bash-completion], [completionsdir], ,
 517                 bashcompdir="${sysconfdir}/bash_completion.d")
 518         AC_MSG_RESULT([$bashcompdir])
 519         AC_SUBST(bashcompdir)
 520         ])
 521
 522 # Optional test binaries
 523 AC_ARG_ENABLE([tests],
 524         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 525         [], [enable_tests=no])
 526 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 527
 528 # Allow overriding the default runtime dir (/run)
 529 AC_ARG_WITH([runtime-path],
 530         [AC_HELP_STRING(
 531                 [--with-runtime-path=dir],
 532                 [runtime directory (default: /run)]
 533         )], [], [with_runtime_path=['/run']])
 534
 535 # LXC container path, where the containers are actually stored
 536 # This is overridden by an entry in the file called LXCCONF
 537 # (i.e. /etc/lxc/lxc.conf)
 538 AC_ARG_WITH([config-path],
 539         [AC_HELP_STRING(
 540                 [--with-config-path=dir],
 541                 [lxc configuration repository path]
 542         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 543
 544 # The path of the global lxc configuration file.
 545 AC_ARG_WITH([global-conf],
 546         [AC_HELP_STRING(
 547                 [--with-global-conf=dir],
 548                 [global lxc configuration file]
 549         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 550
 551 # The path of the userns network configuration file
 552 AC_ARG_WITH([usernic-conf],
 553         [AC_HELP_STRING(
 554                 [--with-usernic-conf],
 555                 [user network interface configuration file]
 556         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 557
 558 # The path of the runtime usernic database
 559 AC_ARG_WITH([usernic-db],
 560         [AC_HELP_STRING(
 561                 [--with-usernic-db],
 562                 [lxc user nic database]
 563         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 564
 565 # Rootfs path, where the container mount structure is assembled
 566 AC_ARG_WITH([rootfs-path],
 567         [AC_HELP_STRING(
 568                 [--with-rootfs-path=dir],
 569                 [lxc rootfs mount point]
 570         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 571
 572 # cgroup pattern specification
 573 AC_ARG_WITH([cgroup-pattern],
 574         [AC_HELP_STRING(
 575                 [--with-cgroup-pattern=pattern],
 576                 [pattern for container cgroups]
 577         )], [], [with_cgroup_pattern=['lxc/%n']])
 578
 579 # Container log path.  By default, use $lxcpath.
 580 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 581 AC_ARG_ENABLE([configpath-log],
 582         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 583         [], [enable_configpath_log=no])
 584 AC_MSG_RESULT([$enable_configpath_log])
 585 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 586
 587 if test "$enable_configpath_log" = "yes"; then
 588         default_log_path="${with_config_path}"
 589 else
 590         default_log_path="${localstatedir}/log/lxc"
 591 fi
 592
 593 AC_ARG_WITH([log-path],
 594         [AC_HELP_STRING(
 595                 [--with-log-path=dir],
 596                 [per container log path]
 597         )], [], [with_log_path=['${default_log_path}']])
 598
 599 # Expand some useful variables
 600 AS_AC_EXPAND(PREFIX, "$prefix")
 601 AS_AC_EXPAND(LIBDIR, "$libdir")
 602 AS_AC_EXPAND(BINDIR, "$bindir")
 603 AS_AC_EXPAND(SBINDIR, "$sbindir")
 604 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 605 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 606 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 607 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 608 AS_AC_EXPAND(DATADIR, "$datadir")
 609 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 610 AS_AC_EXPAND(DOCDIR, "$docdir")
 611 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date --utc --date=@${SOURCE_DATE_EPOCH:-$(date +%s)} '+%Y-%m-%d')")
 612 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 613 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 614 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 615 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 616 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 617 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 618 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 619 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 620 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 621 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 622 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 623 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 624 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 625 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 626
 627 # We need the install path so criu knows where to reference the hook scripts.
 628 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 629
 630 # Check for some standard kernel headers
 631 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 632                                 [],
 633                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 634                                 [#include <sys/socket.h>])
 635
 636 # Check for alternate C libraries
 637 AC_MSG_CHECKING(for bionic libc)
 638 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 639         [[#ifndef __ANDROID__
 640 error: Not bionic!
 641 #endif]])],
 642         [is_bionic=yes],
 643         [is_bionic=no])
 644 if test "x$is_bionic" = "xyes"; then
 645         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 646         AC_MSG_RESULT([yes])
 647 else
 648         AC_MSG_RESULT([no])
 649 fi
 650 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 651
 652 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 653 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 654
 655 # Some systems lack PR_{G,S}ET_NO_NEW_PRIVS definition => HAVE_DECL_PR_{G,S}ET_NO_NEW_PRIVS
 656 AC_CHECK_DECLS([PR_SET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 657 AC_CHECK_DECLS([PR_GET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 658
 659 # Check for some headers
 660 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/memfd.h sys/personality.h utmpx.h sys/timerfd.h sys/resource.h])
 661
 662 # lookup major()/minor()/makedev()
 663 AC_HEADER_MAJOR
 664
 665 # Check for some syscalls functions
 666 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat gettid memfd_create])
 667
 668 # Check for some functions
 669 AC_CHECK_LIB(pthread, main)
 670 AC_CHECK_FUNCS(pthread_atfork)
 671 AC_CHECK_FUNCS(statvfs)
 672 AC_CHECK_LIB(util, openpty)
 673 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 674 AC_CHECK_FUNCS([getline],
 675         AM_CONDITIONAL(HAVE_GETLINE, true)
 676         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 677         AM_CONDITIONAL(HAVE_GETLINE, false))
 678 AC_CHECK_FUNCS([getsubopt],
 679         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 680         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 681         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 682 AC_CHECK_FUNCS([fgetln],
 683         AM_CONDITIONAL(HAVE_FGETLN, true)
 684         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 685         AM_CONDITIONAL(HAVE_FGETLN, false))
 686 AC_CHECK_FUNCS([prlimit],
 687         AM_CONDITIONAL(HAVE_PRLIMIT, true)
 688         AC_DEFINE(HAVE_PRLIMIT,1,[Have prlimit]),
 689         AM_CONDITIONAL(HAVE_PRLIMIT, false))
 690 AC_CHECK_FUNCS([prlimit64],
 691         AM_CONDITIONAL(HAVE_PRLIMIT64, true)
 692         AC_DEFINE(HAVE_PRLIMIT64,1,[Have prlimit64]),
 693         AM_CONDITIONAL(HAVE_PRLIMIT64, false))
 694
 695 # Check for some libraries
 696 AX_PTHREAD
 697 AC_SEARCH_LIBS(clock_gettime, [rt])
 698
 699 # Check for some standard binaries
 700 AC_PROG_GCC_TRADITIONAL
 701 AC_PROG_SED
 702
 703 # See if we support thread-local storage.
 704 LXC_CHECK_TLS
 705
 706 if test "x$GCC" = "xyes"; then
 707         CFLAGS="$CFLAGS -Wall"
 708         if test "x$enable_werror" = "xyes"; then
 709                 CFLAGS="$CFLAGS -Werror"
 710         fi
 711 fi
 712
 713 # Files requiring some variable expansion
 714 AC_CONFIG_FILES([
 715         Makefile
 716         lxc.pc
 717         lxc.spec
 718
 719         config/Makefile
 720         config/apparmor/Makefile
 721         config/selinux/Makefile
 722         config/bash/Makefile
 723         config/bash/lxc
 724         config/init/Makefile
 725         config/init/common/Makefile
 726         config/init/common/lxc-containers
 727         config/init/common/lxc-net
 728         config/init/systemd/Makefile
 729         config/init/systemd/lxc.service
 730         config/init/systemd/lxc@.service
 731         config/init/systemd/lxc-net.service
 732         config/init/sysvinit/Makefile
 733         config/init/sysvinit/lxc-containers
 734         config/init/sysvinit/lxc-net
 735         config/init/upstart/lxc.conf
 736         config/init/upstart/lxc-net.conf
 737         config/init/upstart/Makefile
 738         config/etc/Makefile
 739         config/templates/Makefile
 740         config/templates/alpine.common.conf
 741         config/templates/alpine.userns.conf
 742         config/templates/archlinux.common.conf
 743         config/templates/archlinux.userns.conf
 744         config/templates/centos.common.conf
 745         config/templates/centos.userns.conf
 746         config/templates/common.conf
 747         config/templates/common.conf.d/Makefile
 748         config/templates/debian.common.conf
 749         config/templates/debian.userns.conf
 750         config/templates/fedora.common.conf
 751         config/templates/fedora.userns.conf
 752         config/templates/gentoo.common.conf
 753         config/templates/gentoo.moresecure.conf
 754         config/templates/gentoo.userns.conf
 755         config/templates/nesting.conf
 756         config/templates/oci.common.conf
 757         config/templates/opensuse.common.conf
 758         config/templates/opensuse.userns.conf
 759         config/templates/oracle.common.conf
 760         config/templates/oracle.userns.conf
 761         config/templates/plamo.common.conf
 762         config/templates/plamo.userns.conf
 763         config/templates/slackware.common.conf
 764         config/templates/slackware.userns.conf
 765         config/templates/ubuntu-cloud.common.conf
 766         config/templates/ubuntu-cloud.lucid.conf
 767         config/templates/ubuntu-cloud.userns.conf
 768         config/templates/ubuntu.common.conf
 769         config/templates/ubuntu.lucid.conf
 770         config/templates/ubuntu.userns.conf
 771         config/templates/openwrt.common.conf
 772         config/templates/sparclinux.common.conf
 773         config/templates/sparclinux.userns.conf
 774         config/templates/voidlinux.common.conf
 775         config/templates/voidlinux.userns.conf
 776         config/templates/sabayon.common.conf
 777         config/templates/sabayon.userns.conf
 778         config/templates/userns.conf
 779         config/yum/Makefile
 780         config/sysconfig/Makefile
 781         config/sysconfig/lxc
 782
 783         doc/Makefile
 784         doc/api/Makefile
 785         doc/lxc-attach.sgml
 786         doc/lxc-autostart.sgml
 787         doc/lxc-cgroup.sgml
 788         doc/lxc-checkconfig.sgml
 789         doc/lxc-checkpoint.sgml
 790         doc/lxc-clone.sgml
 791         doc/lxc-config.sgml
 792         doc/lxc-console.sgml
 793         doc/lxc-copy.sgml
 794         doc/lxc-create.sgml
 795         doc/lxc-destroy.sgml
 796         doc/lxc-device.sgml
 797         doc/lxc-execute.sgml
 798         doc/lxc-freeze.sgml
 799         doc/lxc-info.sgml
 800         doc/lxc-ls.sgml
 801         doc/lxc-monitor.sgml
 802         doc/lxc-snapshot.sgml
 803         doc/lxc-start-ephemeral.sgml
 804         doc/lxc-start.sgml
 805         doc/lxc-stop.sgml
 806         doc/lxc-top.sgml
 807         doc/lxc-unfreeze.sgml
 808         doc/lxc-unshare.sgml
 809         doc/lxc-update-config.sgml
 810         doc/lxc-user-nic.sgml
 811         doc/lxc-usernsexec.sgml
 812         doc/lxc-wait.sgml
 813
 814         doc/lxc.conf.sgml
 815         doc/lxc.container.conf.sgml
 816         doc/lxc.system.conf.sgml
 817         doc/lxc-usernet.sgml
 818         doc/lxc.sgml
 819         doc/common_options.sgml
 820         doc/see_also.sgml
 821
 822         doc/rootfs/Makefile
 823
 824         doc/examples/Makefile
 825         doc/examples/lxc-macvlan.conf
 826         doc/examples/lxc-vlan.conf
 827         doc/examples/lxc-no-netns.conf
 828         doc/examples/lxc-empty-netns.conf
 829         doc/examples/lxc-phys.conf
 830         doc/examples/lxc-veth.conf
 831         doc/examples/lxc-complex.conf
 832
 833         doc/ja/Makefile
 834         doc/ja/lxc-attach.sgml
 835         doc/ja/lxc-autostart.sgml
 836         doc/ja/lxc-cgroup.sgml
 837         doc/ja/lxc-checkconfig.sgml
 838         doc/ja/lxc-checkpoint.sgml
 839         doc/ja/lxc-clone.sgml
 840         doc/ja/lxc-config.sgml
 841         doc/ja/lxc-console.sgml
 842         doc/ja/lxc-copy.sgml
 843         doc/ja/lxc-create.sgml
 844         doc/ja/lxc-destroy.sgml
 845         doc/ja/lxc-device.sgml
 846         doc/ja/lxc-execute.sgml
 847         doc/ja/lxc-freeze.sgml
 848         doc/ja/lxc-info.sgml
 849         doc/ja/lxc-ls.sgml
 850         doc/ja/lxc-monitor.sgml
 851         doc/ja/lxc-snapshot.sgml
 852         doc/ja/lxc-start-ephemeral.sgml
 853         doc/ja/lxc-start.sgml
 854         doc/ja/lxc-stop.sgml
 855         doc/ja/lxc-top.sgml
 856         doc/ja/lxc-unfreeze.sgml
 857         doc/ja/lxc-unshare.sgml
 858         doc/ja/lxc-update-config.sgml
 859         doc/ja/lxc-user-nic.sgml
 860         doc/ja/lxc-usernsexec.sgml
 861         doc/ja/lxc-wait.sgml
 862
 863         doc/ja/lxc.conf.sgml
 864         doc/ja/lxc.container.conf.sgml
 865         doc/ja/lxc.system.conf.sgml
 866         doc/ja/lxc-usernet.sgml
 867         doc/ja/lxc.sgml
 868         doc/ja/common_options.sgml
 869         doc/ja/see_also.sgml
 870
 871         doc/ko/Makefile
 872         doc/ko/lxc-attach.sgml
 873         doc/ko/lxc-autostart.sgml
 874         doc/ko/lxc-cgroup.sgml
 875         doc/ko/lxc-checkconfig.sgml
 876         doc/ko/lxc-checkpoint.sgml
 877         doc/ko/lxc-clone.sgml
 878         doc/ko/lxc-config.sgml
 879         doc/ko/lxc-console.sgml
 880         doc/ko/lxc-copy.sgml
 881         doc/ko/lxc-create.sgml
 882         doc/ko/lxc-destroy.sgml
 883         doc/ko/lxc-device.sgml
 884         doc/ko/lxc-execute.sgml
 885         doc/ko/lxc-freeze.sgml
 886         doc/ko/lxc-info.sgml
 887         doc/ko/lxc-ls.sgml
 888         doc/ko/lxc-monitor.sgml
 889         doc/ko/lxc-snapshot.sgml
 890         doc/ko/lxc-start-ephemeral.sgml
 891         doc/ko/lxc-start.sgml
 892         doc/ko/lxc-stop.sgml
 893         doc/ko/lxc-top.sgml
 894         doc/ko/lxc-unfreeze.sgml
 895         doc/ko/lxc-unshare.sgml
 896         doc/ko/lxc-user-nic.sgml
 897         doc/ko/lxc-usernsexec.sgml
 898         doc/ko/lxc-wait.sgml
 899
 900         doc/ko/lxc.conf.sgml
 901         doc/ko/lxc.container.conf.sgml
 902         doc/ko/lxc.system.conf.sgml
 903         doc/ko/lxc-usernet.sgml
 904         doc/ko/lxc.sgml
 905         doc/ko/common_options.sgml
 906         doc/ko/see_also.sgml
 907
 908         hooks/Makefile
 909         hooks/dhclient
 910
 911         templates/Makefile
 912         templates/lxc-alpine
 913         templates/lxc-altlinux
 914         templates/lxc-archlinux
 915         templates/lxc-busybox
 916         templates/lxc-centos
 917         templates/lxc-cirros
 918         templates/lxc-debian
 919         templates/lxc-download
 920         templates/lxc-fedora
 921         templates/lxc-fedora-legacy
 922         templates/lxc-gentoo
 923         templates/lxc-oci
 924         templates/lxc-openmandriva
 925         templates/lxc-opensuse
 926         templates/lxc-oracle
 927         templates/lxc-plamo
 928         templates/lxc-pld
 929         templates/lxc-slackware
 930         templates/lxc-sshd
 931         templates/lxc-ubuntu
 932         templates/lxc-ubuntu-cloud
 933         templates/lxc-sparclinux
 934         templates/lxc-voidlinux
 935         templates/lxc-sabayon
 936
 937         src/Makefile
 938         src/lxc/Makefile
 939         src/lxc/lxc.functions
 940         src/lxc/tools/lxc-checkconfig
 941         src/lxc/tools/lxc-start-ephemeral
 942         src/lxc/tools/lxc-update-config
 943         src/lxc/version.h
 944         src/python-lxc/Makefile
 945
 946         src/lua-lxc/Makefile
 947
 948         src/tests/Makefile
 949         src/tests/lxc-test-usernic
 950 ])
 951 AC_CONFIG_COMMANDS([default],[[]],[[]])
 952 AC_OUTPUT
 953
 954 # Configuration overview
 955 cat << EOF
 956
 957 ----------------------------
 958 Environment:
 959  - compiler: $CC
 960  - distribution: $with_distro
 961  - init script type(s): $init_script
 962  - rpath: $enable_rpath
 963  - GnuTLS: $enable_gnutls
 964  - Bash integration: $enable_bash
 965
 966 Security features:
 967  - Apparmor: $enable_apparmor
 968  - Linux capabilities: $enable_capabilities
 969  - seccomp: $enable_seccomp
 970  - SELinux: $enable_selinux
 971  - cgmanager: $enable_cgmanager
 972
 973 Bindings:
 974  - lua: $enable_lua
 975  - python3: $enable_python
 976
 977 Documentation:
 978  - examples: $enable_examples
 979  - API documentation: $enable_api_docs
 980  - user documentation: $enable_doc
 981
 982 Debugging:
 983  - tests: $enable_tests
 984  - mutex debugging: $enable_mutex_debugging
 985
 986 Paths:
 987  - Logs in configpath: $enable_configpath_log
 988 EOF
 989
 990 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 991 cat << EOF
 992
 993 WARNING: Threading not supported on your platform
 994
 995         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 996         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 997 EOF
 998 fi