configure.ac

   1 AC_PREREQ([2.69])
   2
   3 m4_define([lxc_devel], 1)
   4 m4_define([lxc_version_major], 4)
   5 m4_define([lxc_version_minor], 0)
   6 m4_define([lxc_version_micro], 0)
   7 m4_define([lxc_version_beta], [])
   8
   9 m4_define([lxc_abi_major], 1)
  10 m4_define([lxc_abi_minor], 7)
  11 m4_define([lxc_abi_micro], 0)
  12 m4_define([lxc_abi], [lxc_abi_major.lxc_abi_minor.lxc_abi_micro])
  13
  14 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  15 m4_define([lxc_version],
  16        [ifelse(lxc_devel, 1,
  17         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])-devel,
  18         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta]))])
  19
  20 AC_INIT([lxc],[lxc_version])
  21
  22 # We need pkg-config
  23 PKG_PROG_PKG_CONFIG
  24
  25 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  26 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  27
  28 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  29 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  30 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  31 AC_SUBST([LXC_VERSION], [lxc_version])
  32 AC_SUBST([LXC_DEVEL], [lxc_devel])
  33
  34 AC_SUBST([LXC_ABI_MAJOR], [lxc_abi_major])
  35 AC_SUBST([LXC_ABI_MINOR], [lxc_abi_minor])
  36 AC_SUBST([LXC_ABI_MICRO], [lxc_abi_micro])
  37 AC_SUBST([LXC_ABI], [lxc_abi])
  38
  39 AC_CONFIG_SRCDIR([configure.ac])
  40 AC_CONFIG_AUX_DIR([config])
  41 AC_CONFIG_HEADERS([src/config.h])
  42 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  43 AC_CANONICAL_HOST
  44 AM_PROG_CC_C_O
  45 AC_USE_SYSTEM_EXTENSIONS
  46 AC_SYS_LARGEFILE
  47 AC_GNU_SOURCE
  48
  49 # Test if we have a new enough compiler.
  50 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  51 #define GCC_VERSION \
  52         (__GNUC__ * 10000 + __GNUC_MINOR__ * 100 + __GNUC_PATCHLEVEL__)
  53
  54 #define CLANG_VERSION \
  55         (__clang_major__ * 10000 + __clang_minor__ * 100 + __clang_patchlevel__)
  56
  57 #if GCC_VERSION < 40700 && CLANG_VERSION < 10000
  58 #error Sorry, your compiler is too old - please upgrade it
  59 #endif
  60         ]])], [valid_compiler=yes], [valid_compiler=no])
  61 if test "x$valid_compiler" = "xno"; then
  62         AC_MSG_ERROR([Sorry, your compiler is too old - please upgrade it])
  63 fi
  64
  65 AC_PROG_GCC_TRADITIONAL
  66 AC_PROG_CXX
  67 AC_ENABLE_SHARED
  68 AC_ENABLE_STATIC
  69 # Check binaries
  70 AC_PROG_SED
  71 case $CC in clang*)
  72         AC_CHECK_TOOL([AR], llvm-ar)
  73         AC_CHECK_TOOL([NM], llvm-nm)
  74         AC_CHECK_TOOL([OBJCOPY], llvm-objcopy)
  75         AC_CHECK_TOOL([RANLIB], llvm-ranlib)
  76 esac
  77
  78 # libtool
  79 LT_INIT
  80 AC_SUBST([LIBTOOL_DEPS])
  81
  82 # Detect the distribution. This is used for the default configuration and
  83 # for some distro-specific build options.
  84 AC_MSG_CHECKING([host distribution])
  85 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, redhatenterpriseserver, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva, pardus, sparclinux, altlinux.]))
  86 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  87         with_distro=$(lsb_release -is)
  88 fi
  89 if test "z$with_distro" = "z"; then
  90         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  91         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  92         AC_CHECK_FILE(/etc/sparclinux-release,with_distro="sparclinux")
  93         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  94         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  95         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  96         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  97         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  98         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  99         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 100         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
 101         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
 102         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
 103         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
 104         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
 105         AC_CHECK_FILE(/etc/altlinux-release,with_distro="altlinux")
 106         AC_CHECK_FILE(/etc/pld-release,with_distro="pld")
 107 fi
 108 with_distro=$(echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]')
 109
 110 if test "z$with_distro" = "zforsparc"; then
 111         with_distro="sparclinux"
 112 fi
 113
 114 if test "z$with_distro" = "z"; then
 115         with_distro="unknown"
 116 fi
 117 case $with_distro in
 118         ubuntu|raspbian)
 119                 distroconf=default.conf.lxcbr
 120                 distrosysconf="$sysconfdir/default"
 121                 ;;
 122         redhat|redhatenterpriseserver|centos|fedora|oracle|oracleserver|sparclinux|altlinux|suse|opensuse*|plamo|pld)
 123                 distroconf=default.conf.lxcbr
 124                 distrosysconf="$sysconfdir/sysconfig"
 125                 ;;
 126         *)
 127                 distroconf=default.conf.unknown
 128                 distrosysconf="$sysconfdir/default"
 129                 ;;
 130 esac
 131 AC_MSG_RESULT([$with_distro])
 132 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
 133 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
 134
 135 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
 136
 137 # Check for init system type
 138 AC_MSG_CHECKING([for init system type])
 139 AC_ARG_WITH([init-script],
 140             [AS_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
 141                             [Type(s) of init script to install: sysvinit, systemd, upstart,
 142                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
 143 case "$with_init_script" in
 144         distro)
 145                 case $with_distro in
 146                         fedora|altlinux|opensuse*)
 147                                 init_script=systemd
 148                                 ;;
 149                         redhat|redhatenterpriseserver|oracle|oracleserver|sparclinux|plamo)
 150                                 init_script=sysvinit
 151                                 ;;
 152                         centos)
 153                                 init_script=sysvinit,systemd
 154                                 ;;
 155                         debian|raspbian|ubuntu)
 156                                 init_script=upstart,systemd
 157                                 ;;
 158                         pld)
 159                                 init_script=sysvinit,upstart,systemd
 160                                 ;;
 161                         *)
 162                                 echo -n "Linux distribution init system unknown."
 163                                 init_script=
 164                                 ;;
 165                 esac
 166                 ;;
 167         *)
 168                 init_script=$with_init_script
 169                 ;;
 170 esac
 171
 172 # Check valid init systems were given, run in subshell so we don't mess up IFS
 173 (IFS="," ; for init_sys in $init_script;
 174 do
 175         case "$init_sys" in
 176                 none|sysvinit|systemd|upstart)
 177                         ;;
 178                 *)
 179                         exit 1
 180                         ;;
 181         esac
 182 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 183
 184 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 185 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 186 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 187 AC_MSG_RESULT($init_script)
 188
 189 # systemd unit dir
 190 AC_ARG_WITH([systemdsystemunitdir],
 191         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 192         [with_systemdsystemunitdir=$withval],
 193         [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 194 if test -z "$with_systemdsystemunitdir"; then
 195   with_systemdsystemunitdir=/lib/systemd/system
 196 fi
 197 if test "x$with_systemdsystemunitdir" != "xno"; then
 198   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 199 fi
 200
 201 AC_ARG_ENABLE([werror],
 202         [AS_HELP_STRING([--disable-werror], [do not treat warnings as errors])],
 203         [enable_werror=$enableval], [enable_werror=yes])
 204
 205 AC_ARG_ENABLE([no_undefined],
 206         [AS_HELP_STRING([--disable-no-undefined], [do not pass -Wl,--no-undefined])],
 207         [enable_no_undefined=$enableval], [enable_no_undefined=yes])
 208 AM_CONDITIONAL([ENABLE_NO_UNDEFINED], [test "x$enable_no_undefined" = "xyes"])
 209
 210 AC_ARG_ENABLE([fuzzers],
 211         [AS_HELP_STRING([--enable-fuzzers], [compile with fuzzers])],
 212         [enable_fuzzers=$enableval], [enable_fuzzers=no])
 213 AM_CONDITIONAL([ENABLE_FUZZERS], [test "x$enable_fuzzers" = "xyes"])
 214
 215 AM_CONDITIONAL([OSS_FUZZ], [test "x$LIB_FUZZING_ENGINE" != x])
 216
 217 # Allow disabling rpath
 218 AC_ARG_ENABLE([rpath],
 219         [AS_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 220         [enable_rpath=$enableval], [enable_rpath=no])
 221 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 222
 223 # Documentation (manpages)
 224 AC_ARG_ENABLE([doc],
 225         [AS_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 226         [enable_doc=$enableval], [enable_doc=auto])
 227
 228 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 229         db2xman=""
 230         dbparsers="docbook2X2man docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 231
 232         AC_MSG_CHECKING(for docbook2x-man)
 233         for name in ${dbparsers}; do
 234                 if "$name" --help >/dev/null 2>&1; then
 235                         db2xman="$name"
 236                         break;
 237                 fi
 238         done
 239
 240         if test -n "${db2xman}"; then
 241                 AC_MSG_RESULT([${db2xman}])
 242                 enable_doc="yes"
 243         else
 244                 AC_MSG_RESULT([no])
 245                 if test "x$enable_doc" = "xyes"; then
 246                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 247                 fi
 248                 enable_doc="no"
 249         fi
 250
 251         AC_SUBST(db2xman)
 252 fi
 253 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 254 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 255
 256 if test "x$db2xman" = "xdocbook2man"; then
 257         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 258 else
 259         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 260 fi
 261 AC_SUBST(docdtd)
 262
 263 # Documentation (API)
 264 AC_ARG_ENABLE([api-docs],
 265         [AS_HELP_STRING([--enable-api-docs], [make API documentation [default=auto]])],
 266         [enable_api_docs=$enableval], [enable_api_docs=auto])
 267
 268 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 269         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 270         AC_SUBST([HAVE_DOXYGEN])
 271
 272         if test "x$HAVE_DOXYGEN" != "x"; then
 273                 enable_api_docs="yes"
 274         else
 275                 if test "x$enable_api_docs" = "xyes"; then
 276                         AC_MSG_ERROR([doxygen is required, but could not be found])
 277                 fi
 278                 enable_api_docs="no"
 279         fi
 280 fi
 281
 282 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 283
 284 AC_CONFIG_MACRO_DIRS([config])
 285
 286 # Apparmor
 287 AC_ARG_ENABLE([apparmor],
 288         [AS_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 289         [enable_apparmor=$enableval], [enable_apparmor=auto])
 290
 291 if test "$enable_apparmor" = "auto" ; then
 292         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 293 fi
 294 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 295
 296 # OpenSSL
 297 # libssl-dev
 298 AC_ARG_ENABLE([openssl],
 299         [AS_HELP_STRING([--enable-openssl], [enable OpenSSL support [default=auto]])],
 300         [enable_openssl=$enableval], [enable_openssl=auto])
 301
 302 if test "$enable_openssl" = "auto" ; then
 303         AC_CHECK_LIB([ssl], [OPENSSL_init_ssl], [enable_openssl=yes], [enable_openssl=no])
 304
 305 fi
 306 AM_CONDITIONAL([ENABLE_OPENSSL], [test "x$enable_openssl" = "xyes"])
 307
 308 AC_ARG_ENABLE([static-binaries],
 309         [AS_HELP_STRING([--enable-static-binaries], [build all binaries statically [default=no]])],
 310         [enable_static_binaries=$enableval], [enable_static_binaries=no])
 311 AM_CONDITIONAL([ENABLE_STATIC_BINARIES], [test "x$enable_static_binaries" = "xyes"])
 312
 313 AM_COND_IF([ENABLE_OPENSSL],
 314         [AC_CHECK_HEADER([openssl/engine.h],[],[AC_MSG_ERROR([You must install the OpenSSL development package in order to compile lxc])])
 315         AM_COND_IF([ENABLE_STATIC_BINARIES], [AC_SUBST([OPENSSL_LIBS], '-lssl -lcrypto -ldl')], [AC_SUBST([OPENSSL_LIBS], '-lssl -lcrypto')])])
 316
 317 # SELinux
 318 AC_ARG_ENABLE([selinux],
 319         [AS_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 320         [enable_selinux=$enableval], [enable_selinux=auto])
 321
 322 if test "x$enable_selinux" = xauto; then
 323         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 324 fi
 325 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 326 AM_COND_IF([ENABLE_SELINUX],
 327         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 328         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 329         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 330
 331 # Seccomp syscall filter
 332 AC_ARG_ENABLE([seccomp],
 333         [AS_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 334         [enable_seccomp=$enableval], [enable_seccomp=auto])
 335
 336 if test "x$enable_seccomp" = "xauto" ; then
 337         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 338 fi
 339 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 340
 341 AM_COND_IF([ENABLE_SECCOMP],
 342         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 343                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 344                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 345                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 346                 ])
 347         # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 348         OLD_CFLAGS="$CFLAGS"
 349         CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 350         AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 351         AC_CHECK_DECLS([seccomp_notify_fd], [], [], [[#include <seccomp.h>]])
 352         AC_CHECK_TYPES([struct seccomp_notif_sizes], [], [], [[#include <seccomp.h>]])
 353         AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 354         CFLAGS="$OLD_CFLAGS"
 355         ])
 356
 357 AC_MSG_CHECKING(for static libcap)
 358 # Check for static libcap, make sure the function checked for differs from the
 359 # the one checked below so the cache doesn't give a wrong answer
 360 OLD_CFLAGS="$CFLAGS"
 361 OLD_CPPFLAGS="$CPPFLAGS"
 362 OLD_LDFLAGS="$LDFLAGS"
 363 OLD_LIBS="$LIBS"
 364 CFLAGS=""
 365 CPPFLAGS=""
 366 LDFLAGS="-static"
 367 LIBS="-lcap"
 368 AC_LINK_IFELSE([
 369   AC_LANG_SOURCE(
 370     [[int main() { return 0; }]]
 371   )],[have_static_libcap=yes],[have_static_libcap=no])
 372 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 373 if test "x$have_static_libcap" = "xyes"; then
 374         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 375         AC_MSG_RESULT([yes])
 376 else
 377         AC_MSG_RESULT([no])
 378 fi
 379 CPPFLAGS="$OLD_CPPFLAGS"
 380 CFLAGS="$OLD_CFLAGS"
 381 LDFLAGS="$OLD_LDFLAGS"
 382 LIBS="$OLD_LIBS"
 383
 384
 385 # Linux capabilities
 386 AC_ARG_ENABLE([capabilities],
 387         [AS_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 388         [enable_capabilities=$enableval], [enable_capabilities=auto])
 389
 390 if test "x$enable_capabilities" = "xauto"; then
 391         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 392 fi
 393 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 394
 395 AM_COND_IF([ENABLE_CAP],
 396         [AC_CHECK_HEADER([sys/capability.h],[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 397         AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 398         # Test whether we support getting file capabilities via cap_get_file().
 399         AC_CHECK_LIB(cap,cap_get_file, AC_DEFINE(LIBCAP_SUPPORTS_FILE_CAPABILITIES,1,[Have cap_get_file]),[],[])
 400         AC_SUBST([CAP_LIBS], [-lcap])])
 401
 402 # Configuration examples
 403 AC_ARG_ENABLE([examples],
 404         [AS_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 405         [enable_examples=$enableval], [enable_examples=yes])
 406 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 407
 408 # Enable dumping stack traces
 409 AC_ARG_ENABLE([mutex-debugging],
 410         [AS_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 411         [enable_mutex_debugging=$enableval], [enable_mutex_debugging=no])
 412 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 413
 414 AM_COND_IF([MUTEX_DEBUGGING],
 415         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 416
 417 # Not in older autoconf versions
 418 # AS_VAR_COPY(DEST, SOURCE)
 419 # -------------------------
 420 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 421 # shell variable SOURCE.
 422 m4_ifdef([AS_VAR_COPY], [],
 423 [AC_DEFUN([AS_VAR_COPY],
 424     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 425 ])
 426
 427 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 428 m4_ifdef([PKG_CHECK_VAR], [],
 429 [AC_DEFUN([PKG_CHECK_VAR],
 430     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 431      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 432      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 433      AS_VAR_COPY([$1], [pkg_cv_][$1])
 434      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 435     ])# PKG_CHECK_VAR
 436 ])
 437
 438 # Optional bash integration
 439 AC_ARG_ENABLE([bash],
 440         [AS_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 441         [enable_bash=$enableval], [enable_bash=yes])
 442 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 443
 444 AM_COND_IF([ENABLE_BASH],
 445         [AC_MSG_CHECKING([bash completion directory])
 446         PKG_CHECK_VAR(bashcompdir, [bash-completion], [completionsdir], ,
 447                 bashcompdir="${sysconfdir}/bash_completion.d")
 448         AC_MSG_RESULT([$bashcompdir])
 449         AC_SUBST(bashcompdir)
 450         ])
 451
 452 # Build the command line tools
 453 AC_ARG_ENABLE([tools],
 454         [AS_HELP_STRING([--enable-tools], [build the command line tools [default=yes]])],
 455         [enable_tools=$enableval], [enable_tools=yes])
 456 AM_CONDITIONAL([ENABLE_TOOLS], [test "x$enable_tools" = "xyes"])
 457
 458 # Build the liblxc commands
 459 AC_ARG_ENABLE([commands],
 460         [AS_HELP_STRING([--enable-commands], [build the liblxc commands [default=yes]])],
 461         [enable_commands=$enableval], [enable_commands=yes])
 462 AM_CONDITIONAL([ENABLE_COMMANDS], [test "x$enable_commands" = "xyes"])
 463
 464 AC_ARG_ENABLE([static-binaries],
 465         [AS_HELP_STRING([--enable-static-binaries], [build all binaries statically [default=no]])],
 466         [enable_static_binaries=$enableval], [enable_static_binaries=no])
 467 AM_CONDITIONAL([ENABLE_STATIC_BINARIES], [test "x$enable_static_binaries" = "xyes"])
 468
 469 AC_ARG_ENABLE([sanitizers],
 470         [AS_HELP_STRING([--enable-sanitizers], [build with sanitizers enabled [default=no]])],
 471         [enable_sanitizers=$enableval], [enable_sanitizers=no])
 472 AM_CONDITIONAL([ENABLE_SANITIZERS], [test "x$enable_sanitizers" = "xyes"])
 473 if test "x$enable_sanitizers" = "xyes"; then
 474         AC_DEFINE([ENABLE_SANITIZERS], 1, [build with sanitizers enabled])
 475
 476         CC_CHECK_FLAGS_APPEND([AM_CFLAGS],[CFLAGS],[ \
 477                 -fsanitize=address \
 478                 -fsanitize=undefined \
 479                 -fno-optimize-sibling-calls \
 480                 -fno-omit-frame-pointer])
 481         AC_SUBST(AM_CFLAGS)
 482
 483         CC_CHECK_FLAGS_APPEND([AM_LDFLAGS],[LDFLAGS],[ \
 484                 -fsanitize=address \
 485                 -fsanitize=undefined])
 486         AC_SUBST(AM_LDFLAGS)
 487
 488         AC_MSG_RESULT([yes])
 489 else
 490         AC_MSG_RESULT([no])
 491 fi
 492
 493 if test "x$enable_fuzzers" = "xyes"; then
 494         if test "x$LIB_FUZZING_ENGINE" = x; then
 495                 CC_CHECK_FLAGS_APPEND([AM_CFLAGS],[CFLAGS],[ \
 496                         -DFUZZING_BUILD_MODE_UNSAFE_FOR_PRODUCTION \
 497                         -DRUN_ON_OSS_FUZZ=0 \
 498                         -fsanitize=fuzzer-no-link])
 499         else
 500                 CC_CHECK_FLAGS_APPEND([AM_CFLAGS],[CFLAGS],[ \
 501                         -DRUN_ON_OSS_FUZZ=1])
 502         fi
 503 else
 504         CC_CHECK_FLAGS_APPEND([AM_CFLAGS],[CFLAGS],[-flto=thin])
 505 fi
 506 AC_SUBST(AM_CFLAGS)
 507
 508 # Optional test binaries
 509 AC_ARG_ENABLE([tests],
 510         [AS_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 511         [enable_tests=$enableval], [enable_tests=no])
 512 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 513
 514 # Allow overriding the default runtime dir (/run)
 515 AC_ARG_WITH([runtime-path],
 516         [AS_HELP_STRING([--with-runtime-path=dir], [runtime directory (default: /run)])],
 517         [with_runtime_path=$withval], [with_runtime_path=['/run']])
 518
 519 # LXC container path, where the containers are actually stored
 520 # This is overridden by an entry in the file called LXCCONF
 521 # (i.e. /etc/lxc/lxc.conf)
 522 AC_ARG_WITH([config-path],
 523         [AS_HELP_STRING([--with-config-path=dir], [lxc configuration repository path])],
 524         [with_config_path=$withval], [with_config_path=['${localstatedir}/lib/lxc']])
 525
 526 # The path of the global lxc configuration file.
 527 AC_ARG_WITH([global-conf],
 528         [AS_HELP_STRING([--with-global-conf=dir], [global lxc configuration file])],
 529         [with_global_conf=$withval], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 530
 531 # The path of the userns network configuration file
 532 AC_ARG_WITH([usernic-conf],
 533         [AS_HELP_STRING([--with-usernic-conf], [user network interface configuration file])],
 534         [with_usernic_conf=$withval], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 535
 536 # The path of the runtime usernic database
 537 AC_ARG_WITH([usernic-db],
 538         [AS_HELP_STRING([--with-usernic-db], [lxc user nic database])],
 539         [with_usernic_db=$withval], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 540
 541 # Rootfs path, where the container mount structure is assembled
 542 AC_ARG_WITH([rootfs-path],
 543         [AS_HELP_STRING([--with-rootfs-path=dir], [lxc rootfs mount point])],
 544         [with_rootfs_path=$withval], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 545
 546 # cgroup pattern specification
 547 AC_ARG_WITH([cgroup-pattern],
 548         [AS_HELP_STRING([--with-cgroup-pattern=pattern], [pattern for container cgroups])],
 549         [with_cgroup_pattern=$withval], [with_cgroup_pattern=['']])
 550
 551 # The path for the apparmor_parser's cache for generated apparmor profiles
 552 AC_ARG_WITH([apparmor-cache-dir],
 553         [AS_HELP_STRING([--with-apparmor-cache-dir=dir],[path for apparmor_parser cache])],
 554         [with_apparmor_cache_dir=$withval], [with_apparmor_cache_dir=['${localstatedir}/cache/lxc/apparmor']])
 555
 556 # Container log path.  By default, use $lxcpath.
 557 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 558 AC_ARG_ENABLE([configpath-log],
 559         [AS_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 560         [enable_configpath_log=$enableval], [enable_configpath_log=no])
 561 AC_MSG_RESULT([$enable_configpath_log])
 562 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 563
 564 if test "$enable_configpath_log" = "yes"; then
 565         default_log_path="${with_config_path}"
 566 else
 567         default_log_path="${localstatedir}/log/lxc"
 568 fi
 569
 570 AC_ARG_WITH([log-path],
 571         [AS_HELP_STRING([--with-log-path=dir],[per container log path])],
 572         [with_log_path=$withval], [with_log_path=['${default_log_path}']])
 573
 574 # Expand some useful variables
 575 AS_AC_EXPAND(PREFIX, "$prefix")
 576 AS_AC_EXPAND(LIBDIR, "$libdir")
 577 AS_AC_EXPAND(BINDIR, "$bindir")
 578 AS_AC_EXPAND(SBINDIR, "$sbindir")
 579 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 580 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 581 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 582 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 583 AS_AC_EXPAND(DATADIR, "$datadir")
 584 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 585 AS_AC_EXPAND(DOCDIR, "$docdir")
 586 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date --utc --date=@${SOURCE_DATE_EPOCH:-$(date +%s)} '+%Y-%m-%d')")
 587 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 588 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 589 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 590 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 591 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 592 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 593 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 594 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 595 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 596 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 597 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 598 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 599 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 600 AS_AC_EXPAND(APPARMOR_CACHE_DIR, "$with_apparmor_cache_dir")
 601 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 602
 603 # We need the install path so criu knows where to reference the hook scripts.
 604 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 605
 606 # Check for some standard kernel headers
 607 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 608                                 [],
 609                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 610                                 [#include <sys/socket.h>])
 611
 612 # Check for alternate C libraries
 613 AC_MSG_CHECKING(for bionic libc)
 614 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 615         [[#ifndef __ANDROID__
 616 error: Not bionic!
 617 #endif]])],
 618         [is_bionic=yes],
 619         [is_bionic=no])
 620 if test "x$is_bionic" = "xyes"; then
 621         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 622         AC_MSG_RESULT([yes])
 623 else
 624         AC_MSG_RESULT([no])
 625 fi
 626 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 627
 628 # Configuration examples
 629 AC_ARG_ENABLE([pam],
 630         [AS_HELP_STRING([--enable-pam], [enable pam module [default=no]])],
 631         [enable_pam=$enableval], [enable_pam=no])
 632 AM_CONDITIONAL([ENABLE_PAM], [test "x$enable_pam" = "xyes"])
 633
 634 AM_COND_IF([ENABLE_PAM],
 635         [AC_ARG_WITH(
 636                 [pamdir],
 637                 [AS_HELP_STRING([--with-pamdir=PATH],[Specify the directory where PAM modules are stored,
 638                                                         or "none" if PAM modules are not to be built])],
 639                 [pamdir=$withval],
 640                 [
 641                         if test "${prefix}" = "/usr"; then
 642                                 pamdir="/lib${libdir##*/lib}/security"
 643                         else
 644                                 pamdir="\$(libdir)/security"
 645                         fi
 646                 ]
 647         )])
 648
 649 AM_CONDITIONAL([HAVE_PAM], [test x"$pamdir" != "xnone"])
 650 AM_COND_IF([ENABLE_PAM],
 651         [if test "z$pamdir" != "znone"; then
 652                 AC_ARG_VAR([PAM_CFLAGS], [C compiler flags for pam])
 653                 AC_ARG_VAR([PAM_LIBS], [linker flags for pam])
 654                 AC_CHECK_LIB(
 655                         [pam],
 656                         [pam_authenticate],
 657                         [PAM_LIBS="-lpam"],
 658                         [AC_MSG_ERROR([*** libpam not found.])
 659                         ])
 660
 661                 AC_SUBST(PAM_LIBS)
 662                 AC_SUBST([pamdir])
 663         fi])
 664
 665 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 666 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 667
 668 # Some systems lack PR_{G,S}ET_NO_NEW_PRIVS definition => HAVE_DECL_PR_{G,S}ET_NO_NEW_PRIVS
 669 AC_CHECK_DECLS([PR_SET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 670 AC_CHECK_DECLS([PR_GET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 671
 672 # Check for some headers
 673 AC_CHECK_HEADERS([pty.h sys/memfd.h sys/personality.h sys/resource.h sys/signalfd.h sys/timerfd.h utmpx.h])
 674
 675 AC_CHECK_HEADER([ifaddrs.h],
 676         AM_CONDITIONAL(HAVE_IFADDRS_H, true)
 677         AC_DEFINE(HAVE_IFADDRS_H, 1, [Have ifaddrs.h]),
 678         AM_CONDITIONAL(HAVE_IFADDRS_H, false))
 679
 680 AC_ARG_ENABLE([liburing],
 681         [AS_HELP_STRING([--enable-liburing], [enable liburing support [default=auto]])],
 682         [enable_liburing=$enableval], [enable_liburing=auto])
 683
 684 if test "x$enable_liburing" = "auto"; then
 685         AC_CHECK_LIB([uring],[__io_uring_sqring_wait],[enable_liburing=yes],[enable_liburing=no])
 686 fi
 687
 688 AM_CONDITIONAL([ENABLE_LIBURING], [test "x$enable_liburing" = "xyes"])
 689
 690 AM_COND_IF([ENABLE_LIBURING],
 691         [AC_CHECK_HEADER([liburing.h],[],[AC_MSG_ERROR([You must install the liburing development package in order to compile lxc])])
 692         # We use __io_uring_sqring_wait as an indicator whether liburing is new enough to support poll.
 693         AC_CHECK_LIB([uring],[__io_uring_sqring_wait],[],[AC_MSG_ERROR([The liburing development package in order to compile lxc])])
 694         AC_SUBST([LIBURING_LIBS], [-luring])])
 695
 696 # lookup major()/minor()/makedev()
 697 AC_HEADER_MAJOR
 698
 699 # Check for some syscalls functions
 700 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat gettid memfd_create move_mount open_tree execveat clone3 fsopen fspick fsconfig fsmount openat2 close_range statvfs mount_setattr sigdescr_np])
 701 AC_CHECK_TYPES([__aligned_u64], [], [], [[#include <linux/types.h>]])
 702 AC_CHECK_TYPES([struct mount_attr], [], [], [[#include <linux/mount.h>]])
 703 AC_CHECK_TYPES([struct open_how], [], [], [[#include <linux/openat2.h>]])
 704 AC_CHECK_TYPES([struct clone_args], [], [], [[#include <linux/sched.h>]])
 705 AC_CHECK_MEMBERS([struct clone_args.set_tid],[],[],[[#include <linux/sched.h>]])
 706 AC_CHECK_MEMBERS([struct clone_args.cgroup],[],[],[[#include <linux/sched.h>]])
 707
 708 # Check for strerror_r() support. Defines:
 709 # - HAVE_STRERROR_R if available
 710 # - HAVE_DECL_STRERROR_R if defined
 711 # - STRERROR_R_CHAR_P if it returns char *
 712 AC_FUNC_STRERROR_R
 713
 714 # Check for some functions
 715 AC_CHECK_LIB(pthread, main)
 716 AC_CHECK_LIB(util, openpty)
 717 AC_CHECK_FUNCS([hasmntopt setmntent endmntent utmpxname])
 718 AC_CHECK_FUNCS([getgrgid_r],
 719         AM_CONDITIONAL(HAVE_GETGRGID_R, true)
 720         AC_DEFINE(HAVE_GETGRGID_R,1,[Have getgrgid_r]),
 721         AM_CONDITIONAL(HAVE_GETGRGID_R, false))
 722 AC_CHECK_FUNCS([getline],
 723         AM_CONDITIONAL(HAVE_GETLINE, true)
 724         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 725         AM_CONDITIONAL(HAVE_GETLINE, false))
 726 AC_CHECK_FUNCS([getsubopt],
 727         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 728         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 729         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 730 AC_CHECK_FUNCS([fgetln],
 731         AM_CONDITIONAL(HAVE_FGETLN, true)
 732         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 733         AM_CONDITIONAL(HAVE_FGETLN, false))
 734 AC_CHECK_FUNCS([keyctl],
 735         AM_CONDITIONAL(HAVE_KEYCTL, true)
 736         AC_DEFINE(HAVE_KEYCTL,1,[Have keyctl]),
 737         AM_CONDITIONAL(HAVE_KEYCTL, false))
 738 AC_CHECK_FUNCS([openpty],
 739         AM_CONDITIONAL(HAVE_OPENPTY, true)
 740         AC_DEFINE(HAVE_OPENPTY,1,[Have openpty]),
 741         AM_CONDITIONAL(HAVE_OPENPTY, false))
 742 AC_CHECK_FUNCS([prlimit],
 743         AM_CONDITIONAL(HAVE_PRLIMIT, true)
 744         AC_DEFINE(HAVE_PRLIMIT,1,[Have prlimit]),
 745         AM_CONDITIONAL(HAVE_PRLIMIT, false))
 746 AC_CHECK_FUNCS([prlimit64],
 747         AM_CONDITIONAL(HAVE_PRLIMIT64, true)
 748         AC_DEFINE(HAVE_PRLIMIT64,1,[Have prlimit64]),
 749         AM_CONDITIONAL(HAVE_PRLIMIT64, false))
 750 AC_CHECK_FUNCS([pthread_setcancelstate],
 751         AM_CONDITIONAL(HAVE_PTHREAD_SETCANCELSTATE, true)
 752         AC_DEFINE(HAVE_PTHREAD_SETCANCELSTATE,1,[Have pthread_setcancelstate]),
 753         AM_CONDITIONAL(HAVE_PTHREAD_SETCANCELSTATE, false))
 754 AC_CHECK_FUNCS([strlcpy],
 755         AM_CONDITIONAL(HAVE_STRLCPY, true)
 756         AC_DEFINE(HAVE_STRLCPY,1,[Have strlcpy]),
 757         AM_CONDITIONAL(HAVE_STRLCPY, false))
 758 AC_CHECK_FUNCS([strlcat],
 759         AM_CONDITIONAL(HAVE_STRLCAT, true)
 760         AC_DEFINE(HAVE_STRLCAT,1,[Have strlcat]),
 761         AM_CONDITIONAL(HAVE_STRLCAT, false))
 762 AC_CHECK_FUNCS([strchrnul],
 763         AM_CONDITIONAL(HAVE_STRCHRNUL, true)
 764         AC_DEFINE(HAVE_STRCHRNUL,1,[Have strchnul]),
 765         AM_CONDITIONAL(HAVE_STRCHRNUL, false))
 766 AC_CHECK_FUNCS([fmemopen],
 767         AM_CONDITIONAL(HAVE_FMEMOPEN, true)
 768         AC_DEFINE(HAVE_FMEMOPEN,1,[Have fmemopen]),
 769         AM_CONDITIONAL(HAVE_FMEMOPEN, false))
 770
 771 # HAVE_STRUCT_RTNL_LINK_STATS64={0,1}
 772 AC_CHECK_TYPES([struct rtnl_link_stats64], [], [], [[#include <linux/if_link.h>]])
 773
 774 # Check for some libraries
 775 AX_PTHREAD
 776 AC_SEARCH_LIBS(clock_gettime, [rt])
 777
 778 # See if we support thread-local storage.
 779 LXC_CHECK_TLS
 780
 781 # Hardening flags
 782 CC_CHECK_FLAGS_APPEND([AM_CFLAGS],[CFLAGS],[ \
 783         -fPIE \
 784         -Wvla \
 785         -std=gnu11 \
 786         -fms-extensions \
 787         -fdiagnostics-color \
 788         -Wimplicit-fallthrough=5 \
 789         -Wcast-align \
 790         -Wstrict-prototypes \
 791         -fno-strict-aliasing \
 792         -fstack-clash-protection \
 793         -fstack-protector-strong \
 794         --param=ssp-buffer-size=4 \
 795         -g \
 796         --mcet -fcf-protection \
 797         -Werror=implicit-function-declaration \
 798         -Wlogical-op \
 799         -Wmissing-include-dirs \
 800         -Wold-style-definition \
 801         -Winit-self \
 802         -Wunused-but-set-variable \
 803         -Wfloat-equal \
 804         -Wsuggest-attribute=noreturn \
 805         -Werror=return-type \
 806         -Werror=incompatible-pointer-types \
 807         -Wformat=2 \
 808         -Wshadow \
 809         -Wendif-labels \
 810         -Werror=overflow \
 811         -fdiagnostics-show-option \
 812         -Werror=shift-count-overflow \
 813         -Werror=shift-overflow=2 \
 814         -Wdate-time \
 815         -Wnested-externs \
 816         -fasynchronous-unwind-tables \
 817         -pipe \
 818         -fexceptions \
 819         -Warray-bounds \
 820         -Wrestrict \
 821         -Wreturn-local-addr \
 822         -fsanitize=cfi \
 823         -Wstringop-overflow])
 824 AC_SUBST(AM_CFLAGS)
 825
 826 CC_CHECK_FLAGS_APPEND([AM_LDFLAGS],[LDFLAGS],[ \
 827         -Wl,--as-needed \
 828         -Wl,--gc-sections \
 829         -Wl,-z,relro \
 830         -Wl,-z,now \
 831         -pie \
 832         -Wl,-fuse-ld=gold])
 833
 834 AM_COND_IF([ENABLE_NO_UNDEFINED],
 835         [CC_CHECK_FLAGS_APPEND([AM_LDFLAGS],[LDFLAGS],[-Wl,--no-undefined])])
 836
 837 AC_SUBST(AM_LDFLAGS)
 838
 839 CFLAGS="$CFLAGS -Wvla -std=gnu11 -fms-extensions"
 840 if test "x$enable_werror" = "xyes"; then
 841         CFLAGS="$CFLAGS -Werror"
 842 fi
 843
 844 AC_ARG_ENABLE([thread-safety],
 845         [AS_HELP_STRING([--enable-thread-safety], [enforce thread-safety otherwise fail the build [default=yes]])],
 846         [enable_thread_safety=$enableval], [enable_thread_safety=yes])
 847 AM_CONDITIONAL([ENFORCE_THREAD_SAFETY], [test "x$enable_thread_safety" = "xyes"])
 848 if test "x$enable_thread_safety" = "xyes"; then
 849         AC_DEFINE([ENFORCE_THREAD_SAFETY], 1, [enforce thread-safety otherwise fail the build])
 850         AC_MSG_RESULT([yes])
 851 else
 852         AC_MSG_RESULT([no])
 853 fi
 854
 855 AC_ARG_ENABLE([coverity-build],
 856         [AS_HELP_STRING([--enable-coverity-build], [build for use with Coverity [default=no]])],
 857         [enable_coverity_build=$enableval], [enable_coverity_build=no])
 858 AM_CONDITIONAL([ENABLE_COVERITY_BUILD], [test "x$enable_coverity_build" = "xyes"])
 859 if test "x$enable_coverity_build" = "xyes"; then
 860         AC_DEFINE([ENABLE_COVERITY_BUILD], 1, [build for use with Coverity])
 861         AC_MSG_RESULT([yes])
 862 else
 863         AC_MSG_RESULT([no])
 864 fi
 865
 866 AC_ARG_ENABLE([dlog],
 867         [AS_HELP_STRING([--enable-dlog], [enable dlog support [default=no]])],
 868         [enable_dlog=$enableval], [enable_dlog=no])
 869 AM_CONDITIONAL([ENABLE_DLOG], [test "x$enable_dlog" = "xyes"])
 870
 871 AM_COND_IF([ENABLE_DLOG],
 872         [PKG_CHECK_MODULES([DLOG],[dlog],[],[
 873                 AC_CHECK_HEADER([dlog.h],[],[AC_MSG_ERROR([You must install the dlog development package in order to compile lxc])])
 874                 AC_CHECK_LIB([dlog], [dlog_print],[],[AC_MSG_ERROR([You must install the dlog development package in order to compile lxc])])
 875                 AC_SUBST([DLOG_LIBS], [-ldlog])
 876                 ])
 877         ])
 878
 879 AC_ARG_ENABLE([memfd-rexec],
 880         [AS_HELP_STRING([--enable-memfd-rexec], [enforce liblxc as a memfd to protect against certain symlink attacks [default=yes]])],
 881         [enable_memfd_rexec=$enableval], [enable_memfd_rexec=yes])
 882 AM_CONDITIONAL([ENFORCE_MEMFD_REXEC], [test "x$enable_memfd_rexec" = "xyes"])
 883 if test "x$enable_memfd_rexec" = "xyes"; then
 884         AC_DEFINE([ENFORCE_MEMFD_REXEC], 1, [Rexec liblxc as memfd])
 885         AC_MSG_RESULT([yes])
 886 else
 887         AC_MSG_RESULT([no])
 888 fi
 889
 890 # Files requiring some variable expansion
 891 AC_CONFIG_FILES([
 892         Makefile
 893         lxc.pc
 894         lxc.spec
 895
 896         coccinelle/Makefile
 897
 898         config/Makefile
 899         config/apparmor/Makefile
 900         config/apparmor/abstractions/start-container
 901         config/selinux/Makefile
 902         config/bash/Makefile
 903         config/bash/lxc
 904         config/init/Makefile
 905         config/init/common/Makefile
 906         config/init/common/lxc-containers
 907         config/init/common/lxc-net
 908         config/init/systemd/Makefile
 909         config/init/systemd/lxc.service
 910         config/init/systemd/lxc@.service
 911         config/init/systemd/lxc-net.service
 912         config/init/systemd/lxc-monitord.service
 913         config/init/sysvinit/Makefile
 914         config/init/sysvinit/lxc-containers
 915         config/init/sysvinit/lxc-net
 916         config/init/upstart/lxc.conf
 917         config/init/upstart/lxc-net.conf
 918         config/init/upstart/Makefile
 919         config/etc/Makefile
 920         config/templates/Makefile
 921         config/templates/common.conf
 922         config/templates/common.conf.d/Makefile
 923         config/templates/nesting.conf
 924         config/templates/oci.common.conf
 925         config/templates/userns.conf
 926         config/yum/Makefile
 927         config/sysconfig/Makefile
 928         config/sysconfig/lxc
 929
 930         doc/Makefile
 931         doc/api/Makefile
 932         doc/lxc-attach.sgml
 933         doc/lxc-autostart.sgml
 934         doc/lxc-cgroup.sgml
 935         doc/lxc-checkconfig.sgml
 936         doc/lxc-checkpoint.sgml
 937         doc/lxc-config.sgml
 938         doc/lxc-console.sgml
 939         doc/lxc-copy.sgml
 940         doc/lxc-create.sgml
 941         doc/lxc-destroy.sgml
 942         doc/lxc-device.sgml
 943         doc/lxc-execute.sgml
 944         doc/lxc-freeze.sgml
 945         doc/lxc-info.sgml
 946         doc/lxc-ls.sgml
 947         doc/lxc-monitor.sgml
 948         doc/lxc-snapshot.sgml
 949         doc/lxc-start.sgml
 950         doc/lxc-stop.sgml
 951         doc/lxc-top.sgml
 952         doc/lxc-unfreeze.sgml
 953         doc/lxc-unshare.sgml
 954         doc/lxc-update-config.sgml
 955         doc/lxc-user-nic.sgml
 956         doc/lxc-usernsexec.sgml
 957         doc/lxc-wait.sgml
 958
 959         doc/pam_cgfs.sgml
 960
 961         doc/lxc.conf.sgml
 962         doc/lxc.container.conf.sgml
 963         doc/lxc.system.conf.sgml
 964         doc/lxc-usernet.sgml
 965         doc/lxc.sgml
 966         doc/common_options.sgml
 967         doc/see_also.sgml
 968
 969         doc/rootfs/Makefile
 970
 971         doc/examples/Makefile
 972         doc/examples/lxc-macvlan.conf
 973         doc/examples/lxc-vlan.conf
 974         doc/examples/lxc-no-netns.conf
 975         doc/examples/lxc-empty-netns.conf
 976         doc/examples/lxc-phys.conf
 977         doc/examples/lxc-veth.conf
 978         doc/examples/lxc-complex.conf
 979
 980         doc/ja/Makefile
 981         doc/ja/lxc-attach.sgml
 982         doc/ja/lxc-autostart.sgml
 983         doc/ja/lxc-cgroup.sgml
 984         doc/ja/lxc-checkconfig.sgml
 985         doc/ja/lxc-checkpoint.sgml
 986         doc/ja/lxc-config.sgml
 987         doc/ja/lxc-console.sgml
 988         doc/ja/lxc-copy.sgml
 989         doc/ja/lxc-create.sgml
 990         doc/ja/lxc-destroy.sgml
 991         doc/ja/lxc-device.sgml
 992         doc/ja/lxc-execute.sgml
 993         doc/ja/lxc-freeze.sgml
 994         doc/ja/lxc-info.sgml
 995         doc/ja/lxc-ls.sgml
 996         doc/ja/lxc-monitor.sgml
 997         doc/ja/lxc-snapshot.sgml
 998         doc/ja/lxc-start.sgml
 999         doc/ja/lxc-stop.sgml
1000         doc/ja/lxc-top.sgml
1001         doc/ja/lxc-unfreeze.sgml
1002         doc/ja/lxc-unshare.sgml
1003         doc/ja/lxc-update-config.sgml
1004         doc/ja/lxc-user-nic.sgml
1005         doc/ja/lxc-usernsexec.sgml
1006         doc/ja/lxc-wait.sgml
1007
1008         doc/ja/pam_cgfs.sgml
1009
1010         doc/ja/lxc.conf.sgml
1011         doc/ja/lxc.container.conf.sgml
1012         doc/ja/lxc.system.conf.sgml
1013         doc/ja/lxc-usernet.sgml
1014         doc/ja/lxc.sgml
1015         doc/ja/common_options.sgml
1016         doc/ja/see_also.sgml
1017
1018         doc/ko/Makefile
1019         doc/ko/lxc-attach.sgml
1020         doc/ko/lxc-autostart.sgml
1021         doc/ko/lxc-cgroup.sgml
1022         doc/ko/lxc-checkconfig.sgml
1023         doc/ko/lxc-checkpoint.sgml
1024         doc/ko/lxc-config.sgml
1025         doc/ko/lxc-console.sgml
1026         doc/ko/lxc-copy.sgml
1027         doc/ko/lxc-create.sgml
1028         doc/ko/lxc-destroy.sgml
1029         doc/ko/lxc-device.sgml
1030         doc/ko/lxc-execute.sgml
1031         doc/ko/lxc-freeze.sgml
1032         doc/ko/lxc-info.sgml
1033         doc/ko/lxc-ls.sgml
1034         doc/ko/lxc-monitor.sgml
1035         doc/ko/lxc-snapshot.sgml
1036         doc/ko/lxc-start.sgml
1037         doc/ko/lxc-stop.sgml
1038         doc/ko/lxc-top.sgml
1039         doc/ko/lxc-unfreeze.sgml
1040         doc/ko/lxc-unshare.sgml
1041         doc/ko/lxc-user-nic.sgml
1042         doc/ko/lxc-usernsexec.sgml
1043         doc/ko/lxc-wait.sgml
1044
1045         doc/ko/lxc.conf.sgml
1046         doc/ko/lxc.container.conf.sgml
1047         doc/ko/lxc.system.conf.sgml
1048         doc/ko/lxc-usernet.sgml
1049         doc/ko/lxc.sgml
1050         doc/ko/common_options.sgml
1051         doc/ko/see_also.sgml
1052
1053         hooks/Makefile
1054         hooks/dhclient
1055
1056         templates/Makefile
1057         templates/lxc-busybox
1058         templates/lxc-download
1059         templates/lxc-local
1060         templates/lxc-oci
1061
1062         src/Makefile
1063         src/lxc/Makefile
1064         src/lxc/lxc.functions
1065         src/lxc/cmd/lxc-checkconfig
1066         src/lxc/cmd/lxc-update-config
1067         src/lxc/version.h
1068
1069         src/tests/Makefile
1070         src/tests/lxc-test-usernic
1071 ])
1072 AC_CONFIG_COMMANDS([default],[[]],[[]])
1073 AC_OUTPUT
1074
1075 # Configuration overview
1076 cat << EOF
1077
1078 ----------------------------
1079 Binaries
1080  - Command Line Tools:
1081    - lxc-attach:     $enable_tools
1082    - lxc-autostart:  $enable_tools
1083    - lxc-cgroup:     $enable_tools
1084    - lxc-checkpoint: $enable_tools
1085    - lxc-config:     $enable_tools
1086    - lxc-console:    $enable_tools
1087    - lxc-copy:       $enable_tools
1088    - lxc-create:     $enable_tools
1089    - lxc-destroy:    $enable_tools
1090    - lxc-device:     $enable_tools
1091    - lxc-execute:    $enable_tools
1092    - lxc-freeze:     $enable_tools
1093    - lxc-info:       $enable_tools
1094    - lxc-ls:         $enable_tools
1095    - lxc-monitor:    $enable_tools
1096    - lxc-snapshot:   $enable_tools
1097    - lxc-start:      $enable_tools
1098    - lxc-stop:       $enable_tools
1099    - lxc-top:        $enable_tools
1100    - lxc-unfreeze:   $enable_tools
1101    - lxc-unshare:    $enable_tools
1102    - lxc-wait:       $enable_tools
1103
1104  - liblxc Commands:
1105    - lxc-checkconfig:   $enable_commands
1106    - lxc-update-config: $enable_commands
1107    - lxc-init:          $enable_commands
1108    - lxc-monitord:      $enable_commands
1109    - lxc-user-nic:      $enable_commands
1110    - lxc-usernsexec:    $enable_commands
1111
1112  - static binaries: $enable_static_binaries
1113
1114 Environment:
1115  - compiler: $CC
1116  - cflags: ${AM_CFLAGS} ${PTHREAD_CFLAGS}
1117  - ldflags: ${AM_LDFLAGS} ${PTHREAD_LIBS}
1118  - distribution: $with_distro
1119  - init script type(s): $init_script
1120  - rpath: $enable_rpath
1121  - OpenSSL: $enable_openssl
1122  - Bash integration: $enable_bash
1123
1124 Security features:
1125  - Apparmor: $enable_apparmor
1126  - Linux capabilities: $enable_capabilities
1127  - seccomp: $enable_seccomp
1128  - SELinux: $enable_selinux
1129  - memfd rexec: $enable_memfd_rexec
1130
1131 PAM:
1132  - PAM module: $enable_pam
1133  - cgroup PAM module: $pamdir
1134
1135 Documentation:
1136  - examples: $enable_examples
1137  - API documentation: $enable_api_docs
1138  - user documentation: $enable_doc
1139
1140 Debugging:
1141  - Sanitizers: $enable_sanitizers
1142  - Coverity: $enable_coverity_build
1143  - mutex debugging: $enable_mutex_debugging
1144  - tests: $enable_tests
1145  - fuzzers: $enable_fuzzers
1146
1147 Paths:
1148  - Logs in configpath: $enable_configpath_log
1149
1150 Thread-safety:
1151  - enforce: $enable_thread_safety
1152
1153 Dlog:
1154  - enable: $enable_dlog
1155 EOF