configure.ac

   1 AC_PREREQ([2.69])
   2
   3 m4_define([lxc_devel], 1)
   4 m4_define([lxc_version_major], 3)
   5 m4_define([lxc_version_minor], 2)
   6 m4_define([lxc_version_micro], 1)
   7 m4_define([lxc_version_beta], [])
   8
   9 m4_define([lxc_abi_major], 1)
  10 m4_define([lxc_abi_minor], 6)
  11 m4_define([lxc_abi_micro], 0)
  12 m4_define([lxc_abi], [lxc_abi_major.lxc_abi_minor.lxc_abi_micro])
  13
  14 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  15 m4_define([lxc_version],
  16        [ifelse(lxc_devel, 1,
  17         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])-devel,
  18         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta]))])
  19
  20 AC_INIT([lxc],[lxc_version])
  21
  22 # We need pkg-config
  23 PKG_PROG_PKG_CONFIG
  24
  25 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  26 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  27
  28 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  29 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  30 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  31 AC_SUBST([LXC_VERSION], [lxc_version])
  32 AC_SUBST([LXC_DEVEL], [lxc_devel])
  33
  34 AC_SUBST([LXC_ABI_MAJOR], [lxc_abi_major])
  35 AC_SUBST([LXC_ABI_MINOR], [lxc_abi_minor])
  36 AC_SUBST([LXC_ABI_MICRO], [lxc_abi_micro])
  37 AC_SUBST([LXC_ABI], [lxc_abi])
  38
  39 AC_CONFIG_SRCDIR([configure.ac])
  40 AC_CONFIG_AUX_DIR([config])
  41 AC_CONFIG_HEADERS([src/config.h])
  42 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  43 AC_CANONICAL_HOST
  44 AM_PROG_CC_C_O
  45 AC_USE_SYSTEM_EXTENSIONS
  46
  47 # Test if we have a new enough compiler.
  48 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  49 #define GCC_VERSION \
  50         (__GNUC__ * 10000 + __GNUC_MINOR__ * 100 + __GNUC_PATCHLEVEL__)
  51
  52 #define CLANG_VERSION \
  53         (__clang_major__ * 10000 + __clang_minor__ * 100 + __clang_patchlevel__)
  54
  55 #if GCC_VERSION < 40700 && CLANG_VERSION < 10000
  56 #error Sorry, your compiler is too old - please upgrade it
  57 #endif
  58         ]])], [valid_compiler=yes], [valid_compiler=no])
  59 if test "x$valid_compiler" = "xno"; then
  60         AC_MSG_ERROR([Sorry, your compiler is too old - please upgrade it])
  61 fi
  62
  63 # libtool
  64 LT_INIT
  65 AC_SUBST([LIBTOOL_DEPS])
  66
  67 # Detect the distribution. This is used for the default configuration and
  68 # for some distro-specific build options.
  69 AC_MSG_CHECKING([host distribution])
  70 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, redhatenterpriseserver, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva, pardus, sparclinux, altlinux.]))
  71 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  72         with_distro=`lsb_release -is`
  73 fi
  74 if test "z$with_distro" = "z"; then
  75         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  76         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  77         AC_CHECK_FILE(/etc/sparclinux-release,with_distro="sparclinux")
  78         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  79         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  80         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  81         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  82         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  83         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  84         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  85         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
  86         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  87         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  88         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  89         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  90         AC_CHECK_FILE(/etc/altlinux-release,with_distro="altlinux")
  91         AC_CHECK_FILE(/etc/pld-release,with_distro="pld")
  92 fi
  93 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  94
  95 if test "z$with_distro" = "zforsparc"; then
  96         with_distro="sparclinux"
  97 fi
  98
  99 if test "z$with_distro" = "z"; then
 100         with_distro="unknown"
 101 fi
 102 case $with_distro in
 103         ubuntu|raspbian)
 104                 distroconf=default.conf.lxcbr
 105                 distrosysconf="$sysconfdir/default"
 106                 ;;
 107         redhat|redhatenterpriseserver|centos|fedora|oracle|oracleserver|sparclinux|altlinux|suse|opensuse*|plamo|pld)
 108                 distroconf=default.conf.lxcbr
 109                 distrosysconf="$sysconfdir/sysconfig"
 110                 ;;
 111         *)
 112                 distroconf=default.conf.unknown
 113                 distrosysconf="$sysconfdir/default"
 114                 ;;
 115 esac
 116 AC_MSG_RESULT([$with_distro])
 117 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
 118 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
 119
 120 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
 121
 122 # Check for init system type
 123 AC_MSG_CHECKING([for init system type])
 124 AC_ARG_WITH([init-script],
 125             [AS_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
 126                             [Type(s) of init script to install: sysvinit, systemd, upstart,
 127                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
 128 case "$with_init_script" in
 129         distro)
 130                 case $with_distro in
 131                         fedora|altlinux|opensuse*)
 132                                 init_script=systemd
 133                                 ;;
 134                         redhat|redhatenterpriseserver|oracle|oracleserver|sparclinux|plamo)
 135                                 init_script=sysvinit
 136                                 ;;
 137                         centos)
 138                                 init_script=sysvinit,systemd
 139                                 ;;
 140                         debian|raspbian|ubuntu)
 141                                 init_script=upstart,systemd
 142                                 ;;
 143                         pld)
 144                                 init_script=sysvinit,upstart,systemd
 145                                 ;;
 146                         *)
 147                                 echo -n "Linux distribution init system unknown."
 148                                 init_script=
 149                                 ;;
 150                 esac
 151                 ;;
 152         *)
 153                 init_script=$with_init_script
 154                 ;;
 155 esac
 156
 157 # Check valid init systems were given, run in subshell so we don't mess up IFS
 158 (IFS="," ; for init_sys in $init_script;
 159 do
 160         case "$init_sys" in
 161                 none|sysvinit|systemd|upstart)
 162                         ;;
 163                 *)
 164                         exit 1
 165                         ;;
 166         esac
 167 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 168
 169 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 170 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 171 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 172 AC_MSG_RESULT($init_script)
 173
 174 # systemd unit dir
 175 AC_ARG_WITH([systemdsystemunitdir],
 176         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 177         [with_systemdsystemunitdir=$withval],
 178         [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 179 if test -z "$with_systemdsystemunitdir"; then
 180   with_systemdsystemunitdir=/lib/systemd/system
 181 fi
 182 if test "x$with_systemdsystemunitdir" != "xno"; then
 183   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 184 fi
 185
 186 AC_ARG_ENABLE([werror],
 187         [AS_HELP_STRING([--disable-werror], [do not treat warnings as errors])],
 188         [enable_werror=$enableval], [enable_werror=yes])
 189
 190 # Allow disabling rpath
 191 AC_ARG_ENABLE([rpath],
 192         [AS_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 193         [enable_rpath=$enableval], [enable_rpath=no])
 194 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 195
 196 # Documentation (manpages)
 197 AC_ARG_ENABLE([doc],
 198         [AS_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 199         [enable_doc=$enableval], [enable_doc=auto])
 200
 201 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 202         db2xman=""
 203         dbparsers="docbook2X2man docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 204
 205         AC_MSG_CHECKING(for docbook2x-man)
 206         for name in ${dbparsers}; do
 207                 if "$name" --help >/dev/null 2>&1; then
 208                         db2xman="$name"
 209                         break;
 210                 fi
 211         done
 212
 213         if test -n "${db2xman}"; then
 214                 AC_MSG_RESULT([${db2xman}])
 215                 enable_doc="yes"
 216         else
 217                 AC_MSG_RESULT([no])
 218                 if test "x$enable_doc" = "xyes"; then
 219                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 220                 fi
 221                 enable_doc="no"
 222         fi
 223
 224         AC_SUBST(db2xman)
 225 fi
 226 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 227 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 228
 229 if test "x$db2xman" = "xdocbook2man"; then
 230         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 231 else
 232         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 233 fi
 234 AC_SUBST(docdtd)
 235
 236 # Documentation (API)
 237 AC_ARG_ENABLE([api-docs],
 238         [AS_HELP_STRING([--enable-api-docs], [make API documentation [default=auto]])],
 239         [enable_api_docs=$enableval], [enable_api_docs=auto])
 240
 241 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 242         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 243         AC_SUBST([HAVE_DOXYGEN])
 244
 245         if test "x$HAVE_DOXYGEN" != "x"; then
 246                 enable_api_docs="yes"
 247         else
 248                 if test "x$enable_api_docs" = "xyes"; then
 249                         AC_MSG_ERROR([doxygen is required, but could not be found])
 250                 fi
 251                 enable_api_docs="no"
 252         fi
 253 fi
 254
 255 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 256
 257 AC_CONFIG_MACRO_DIRS([config])
 258
 259 # Apparmor
 260 AC_ARG_ENABLE([apparmor],
 261         [AS_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 262         [enable_apparmor=$enableval], [enable_apparmor=auto])
 263
 264 if test "$enable_apparmor" = "auto" ; then
 265         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 266 fi
 267 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 268
 269 # OpenSSL
 270 # libssl-dev
 271 AC_ARG_ENABLE([openssl],
 272         [AS_HELP_STRING([--enable-openssl], [enable OpenSSL support [default=auto]])],
 273         [enable_openssl=$enableval], [enable_openssl=auto])
 274
 275 if test "$enable_openssl" = "auto" ; then
 276         AC_CHECK_LIB([ssl], [OPENSSL_init_ssl], [enable_openssl=yes], [enable_openssl=no])
 277
 278 fi
 279 AM_CONDITIONAL([ENABLE_OPENSSL], [test "x$enable_openssl" = "xyes"])
 280
 281 AM_COND_IF([ENABLE_OPENSSL],
 282         [AC_CHECK_HEADER([openssl/engine.h],[],[AC_MSG_ERROR([You must install the OpenSSL development package in order to compile lxc])])
 283         AC_SUBST([OPENSSL_LIBS], '-lssl -lcrypto')])
 284
 285 # SELinux
 286 AC_ARG_ENABLE([selinux],
 287         [AS_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 288         [enable_selinux=$enableval], [enable_selinux=auto])
 289
 290 if test "x$enable_selinux" = xauto; then
 291         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 292 fi
 293 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 294 AM_COND_IF([ENABLE_SELINUX],
 295         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 296         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 297         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 298
 299 # Seccomp syscall filter
 300 AC_ARG_ENABLE([seccomp],
 301         [AS_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 302         [enable_seccomp=$enableval], [enable_seccomp=auto])
 303
 304 if test "x$enable_seccomp" = "xauto" ; then
 305         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 306 fi
 307 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 308
 309 AM_COND_IF([ENABLE_SECCOMP],
 310         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 311                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 312                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 313                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 314                 ])
 315         ])
 316
 317 AC_MSG_CHECKING(for static libcap)
 318 # Check for static libcap, make sure the function checked for differs from the
 319 # the one checked below so the cache doesn't give a wrong answer
 320 OLD_CFLAGS="$CFLAGS"
 321 OLD_CPPFLAGS="$CPPFLAGS"
 322 OLD_LDFLAGS="$LDFLAGS"
 323 OLD_LIBS="$LIBS"
 324 CFLAGS=""
 325 CPPFLAGS=""
 326 LDFLAGS="-static"
 327 LIBS="-lcap"
 328 AC_LINK_IFELSE([
 329   AC_LANG_SOURCE(
 330     [[int main() { return 0; }]]
 331   )],[have_static_libcap=yes],[have_static_libcap=no])
 332 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 333 if test "x$have_static_libcap" = "xyes"; then
 334         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 335         AC_MSG_RESULT([yes])
 336 else
 337         AC_MSG_RESULT([no])
 338 fi
 339 CPPFLAGS="$OLD_CPPFLAGS"
 340 CFLAGS="$OLD_CFLAGS"
 341 LDFLAGS="$OLD_LDFLAGS"
 342 LIBS="$OLD_LIBS"
 343
 344
 345 # Linux capabilities
 346 AC_ARG_ENABLE([capabilities],
 347         [AS_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 348         [enable_capabilities=$enableval], [enable_capabilities=auto])
 349
 350 if test "x$enable_capabilities" = "xauto"; then
 351         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 352 fi
 353 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 354
 355 AM_COND_IF([ENABLE_CAP],
 356         [AC_CHECK_HEADER([sys/capability.h],[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 357         AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 358         # Test whether we support getting file capabilities via cap_get_file().
 359         AC_CHECK_LIB(cap,cap_get_file, AC_DEFINE(LIBCAP_SUPPORTS_FILE_CAPABILITIES,1,[Have cap_get_file]),[],[])
 360         AC_SUBST([CAP_LIBS], [-lcap])])
 361
 362 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 363 OLD_CFLAGS="$CFLAGS"
 364 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 365 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 366 AC_CHECK_DECLS([seccomp_notify_fd], [], [], [[#include <seccomp.h>]])
 367 AC_CHECK_TYPES([struct seccomp_notif_sizes], [], [], [[#include <seccomp.h>]])
 368 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 369 CFLAGS="$OLD_CFLAGS"
 370
 371 AC_CHECK_HEADERS([linux/bpf.h], [
 372         AC_CHECK_TYPES([struct bpf_cgroup_dev_ctx], [], [], [[#include <linux/bpf.h>]])
 373 ], [], [])
 374
 375 # Configuration examples
 376 AC_ARG_ENABLE([examples],
 377         [AS_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 378         [enable_examples=$enableval], [enable_examples=yes])
 379 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 380
 381 # Enable dumping stack traces
 382 AC_ARG_ENABLE([mutex-debugging],
 383         [AS_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 384         [enable_mutex_debugging=$enableval], [enable_mutex_debugging=no])
 385 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 386
 387 AM_COND_IF([MUTEX_DEBUGGING],
 388         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 389
 390 # Not in older autoconf versions
 391 # AS_VAR_COPY(DEST, SOURCE)
 392 # -------------------------
 393 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 394 # shell variable SOURCE.
 395 m4_ifdef([AS_VAR_COPY], [],
 396 [AC_DEFUN([AS_VAR_COPY],
 397     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 398 ])
 399
 400 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 401 m4_ifdef([PKG_CHECK_VAR], [],
 402 [AC_DEFUN([PKG_CHECK_VAR],
 403     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 404      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 405      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 406      AS_VAR_COPY([$1], [pkg_cv_][$1])
 407      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 408     ])# PKG_CHECK_VAR
 409 ])
 410
 411 # Optional bash integration
 412 AC_ARG_ENABLE([bash],
 413         [AS_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 414         [enable_bash=$enableval], [enable_bash=yes])
 415 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 416
 417 AM_COND_IF([ENABLE_BASH],
 418         [AC_MSG_CHECKING([bash completion directory])
 419         PKG_CHECK_VAR(bashcompdir, [bash-completion], [completionsdir], ,
 420                 bashcompdir="${sysconfdir}/bash_completion.d")
 421         AC_MSG_RESULT([$bashcompdir])
 422         AC_SUBST(bashcompdir)
 423         ])
 424
 425 # Build the command line tools
 426 AC_ARG_ENABLE([tools],
 427         [AS_HELP_STRING([--enable-tools], [build the command line tools [default=yes]])],
 428         [enable_tools=$enableval], [enable_tools=yes])
 429 AM_CONDITIONAL([ENABLE_TOOLS], [test "x$enable_tools" = "xyes"])
 430
 431 # Build the liblxc commands
 432 AC_ARG_ENABLE([commands],
 433         [AS_HELP_STRING([--enable-commands], [build the liblxc commands [default=yes]])],
 434         [enable_commands=$enableval], [enable_commands=yes])
 435 AM_CONDITIONAL([ENABLE_COMMANDS], [test "x$enable_commands" = "xyes"])
 436
 437 # Build with ASAN commands
 438 AC_ARG_ENABLE([asan],
 439         [AS_HELP_STRING([--enable-asan], [build with address sanitizer enabled [default=no]])],
 440         [enable_asan=$enableval], [enable_asan=no])
 441 AM_CONDITIONAL([ENABLE_ASAN], [test "x$enable_asan" = "xyes"])
 442
 443 # Build with UBSAN commands
 444 AC_ARG_ENABLE([ubsan],
 445         [AS_HELP_STRING([--enable-ubsan], [build with ubsan sanitizer enabled [default=no]])],
 446         [enable_asan=$enableval], [enable_ubsan=no])
 447 AM_CONDITIONAL([ENABLE_UBSAN], [test "x$enable_ubsan" = "xyes"])
 448
 449 # Optional test binaries
 450 AC_ARG_ENABLE([tests],
 451         [AS_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 452         [enable_tests=$enableval], [enable_tests=no])
 453 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 454
 455 # Allow overriding the default runtime dir (/run)
 456 AC_ARG_WITH([runtime-path],
 457         [AS_HELP_STRING([--with-runtime-path=dir], [runtime directory (default: /run)])],
 458         [with_runtime_path=$withval], [with_runtime_path=['/run']])
 459
 460 # LXC container path, where the containers are actually stored
 461 # This is overridden by an entry in the file called LXCCONF
 462 # (i.e. /etc/lxc/lxc.conf)
 463 AC_ARG_WITH([config-path],
 464         [AS_HELP_STRING([--with-config-path=dir], [lxc configuration repository path])],
 465         [with_config_path=$withval], [with_config_path=['${localstatedir}/lib/lxc']])
 466
 467 # The path of the global lxc configuration file.
 468 AC_ARG_WITH([global-conf],
 469         [AS_HELP_STRING([--with-global-conf=dir], [global lxc configuration file])],
 470         [with_global_conf=$withval], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 471
 472 # The path of the userns network configuration file
 473 AC_ARG_WITH([usernic-conf],
 474         [AS_HELP_STRING([--with-usernic-conf], [user network interface configuration file])],
 475         [with_usernic_conf=$withval], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 476
 477 # The path of the runtime usernic database
 478 AC_ARG_WITH([usernic-db],
 479         [AS_HELP_STRING([--with-usernic-db], [lxc user nic database])],
 480         [with_usernic_db=$withval], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 481
 482 # Rootfs path, where the container mount structure is assembled
 483 AC_ARG_WITH([rootfs-path],
 484         [AS_HELP_STRING([--with-rootfs-path=dir], [lxc rootfs mount point])],
 485         [with_rootfs_path=$withval], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 486
 487 # cgroup pattern specification
 488 AC_ARG_WITH([cgroup-pattern],
 489         [AS_HELP_STRING([--with-cgroup-pattern=pattern], [pattern for container cgroups])],
 490         [with_cgroup_pattern=$withval], [with_cgroup_pattern=['lxc.payload/%n']])
 491
 492 # The path for the apparmor_parser's cache for generated apparmor profiles
 493 AC_ARG_WITH([apparmor-cache-dir],
 494         [AS_HELP_STRING([--with-apparmor-cache-dir=dir],[path for apparmor_parser cache])],
 495         [with_apparmor_cache_dir=$withval], [with_apparmor_cache_dir=['${localstatedir}/cache/lxc/apparmor']])
 496
 497 # Container log path.  By default, use $lxcpath.
 498 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 499 AC_ARG_ENABLE([configpath-log],
 500         [AS_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 501         [enable_configpath_log=$enableval], [enable_configpath_log=no])
 502 AC_MSG_RESULT([$enable_configpath_log])
 503 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 504
 505 if test "$enable_configpath_log" = "yes"; then
 506         default_log_path="${with_config_path}"
 507 else
 508         default_log_path="${localstatedir}/log/lxc"
 509 fi
 510
 511 AC_ARG_WITH([log-path],
 512         [AS_HELP_STRING([--with-log-path=dir],[per container log path])],
 513         [with_log_path=$withval], [with_log_path=['${default_log_path}']])
 514
 515 # Expand some useful variables
 516 AS_AC_EXPAND(PREFIX, "$prefix")
 517 AS_AC_EXPAND(LIBDIR, "$libdir")
 518 AS_AC_EXPAND(BINDIR, "$bindir")
 519 AS_AC_EXPAND(SBINDIR, "$sbindir")
 520 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 521 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 522 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 523 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 524 AS_AC_EXPAND(DATADIR, "$datadir")
 525 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 526 AS_AC_EXPAND(DOCDIR, "$docdir")
 527 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date --utc --date=@${SOURCE_DATE_EPOCH:-$(date +%s)} '+%Y-%m-%d')")
 528 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 529 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 530 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 531 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 532 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 533 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 534 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 535 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 536 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 537 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 538 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 539 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 540 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 541 AS_AC_EXPAND(APPARMOR_CACHE_DIR, "$with_apparmor_cache_dir")
 542 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 543
 544 # We need the install path so criu knows where to reference the hook scripts.
 545 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 546
 547 # Check for some standard kernel headers
 548 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 549                                 [],
 550                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 551                                 [#include <sys/socket.h>])
 552
 553 # Check for alternate C libraries
 554 AC_MSG_CHECKING(for bionic libc)
 555 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 556         [[#ifndef __ANDROID__
 557 error: Not bionic!
 558 #endif]])],
 559         [is_bionic=yes],
 560         [is_bionic=no])
 561 if test "x$is_bionic" = "xyes"; then
 562         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 563         AC_MSG_RESULT([yes])
 564 else
 565         AC_MSG_RESULT([no])
 566 fi
 567 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 568
 569 # Configuration examples
 570 AC_ARG_ENABLE([pam],
 571         [AS_HELP_STRING([--enable-pam], [enable pam module [default=no]])],
 572         [enable_pam=$enableval], [enable_pam=no])
 573 AM_CONDITIONAL([ENABLE_PAM], [test "x$enable_pam" = "xyes"])
 574
 575 AM_COND_IF([ENABLE_PAM],
 576         [AC_ARG_WITH(
 577                 [pamdir],
 578                 [AS_HELP_STRING([--with-pamdir=PATH],[Specify the directory where PAM modules are stored,
 579                                                         or "none" if PAM modules are not to be built])],
 580                 [pamdir=$withval],
 581                 [
 582                         if test "${prefix}" = "/usr"; then
 583                                 pamdir="/lib${libdir##*/lib}/security"
 584                         else
 585                                 pamdir="\$(libdir)/security"
 586                         fi
 587                 ]
 588         )])
 589
 590 AM_CONDITIONAL([HAVE_PAM], [test x"$pamdir" != "xnone"])
 591 AM_COND_IF([ENABLE_PAM],
 592         [if test "z$pamdir" != "znone"; then
 593                 AC_ARG_VAR([PAM_CFLAGS], [C compiler flags for pam])
 594                 AC_ARG_VAR([PAM_LIBS], [linker flags for pam])
 595                 AC_CHECK_LIB(
 596                         [pam],
 597                         [pam_authenticate],
 598                         [PAM_LIBS="-lpam"],
 599                         [AC_MSG_ERROR([*** libpam not found.])
 600                         ])
 601
 602                 AC_SUBST(PAM_LIBS)
 603                 AC_SUBST([pamdir])
 604         fi])
 605
 606 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 607 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 608
 609 # Some systems lack PR_{G,S}ET_NO_NEW_PRIVS definition => HAVE_DECL_PR_{G,S}ET_NO_NEW_PRIVS
 610 AC_CHECK_DECLS([PR_SET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 611 AC_CHECK_DECLS([PR_GET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 612
 613 # Check for some headers
 614 AC_CHECK_HEADERS([pty.h sys/memfd.h sys/personality.h sys/resource.h sys/signalfd.h sys/timerfd.h utmpx.h])
 615
 616 AC_CHECK_HEADER([ifaddrs.h],
 617         AM_CONDITIONAL(HAVE_IFADDRS_H, true)
 618         AC_DEFINE(HAVE_IFADDRS_H, 1, [Have ifaddrs.h]),
 619         AM_CONDITIONAL(HAVE_IFADDRS_H, false))
 620
 621 # lookup major()/minor()/makedev()
 622 AC_HEADER_MAJOR
 623
 624 # Check for some syscalls functions
 625 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat gettid memfd_create])
 626
 627 # Check for strerror_r() support. Defines:
 628 # - HAVE_STRERROR_R if available
 629 # - HAVE_DECL_STRERROR_R if defined
 630 # - STRERROR_R_CHAR_P if it returns char *
 631 AC_FUNC_STRERROR_R
 632
 633 # Check if "%m" is supported by printf and Co
 634 AC_MSG_CHECKING([%m format])
 635 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 636 #include <stdio.h>
 637 int main(void)
 638 {
 639   char msg[256];
 640   int rc;
 641
 642   rc = snprintf(msg, sizeof(msg), "%m\n");
 643   if ((rc > 1) && (msg[0] != '%'))
 644   {
 645     return 0;
 646   }
 647   else
 648   {
 649     return 1;
 650   }
 651 }]])],[fmt_m=yes],[fmt_m=no],[fmt_m=no])
 652 if test "x$fmt_m" = "xyes"; then
 653         AC_DEFINE([HAVE_M_FORMAT], 1, [Have %m format])
 654         AC_MSG_RESULT([yes])
 655 else
 656         AC_MSG_RESULT([no])
 657 fi
 658
 659 # Check for some functions
 660 AC_CHECK_LIB(pthread, main)
 661 AC_CHECK_FUNCS(statvfs)
 662 AC_CHECK_LIB(util, openpty)
 663 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 664 AC_CHECK_FUNCS([getgrgid_r],
 665         AM_CONDITIONAL(HAVE_GETGRGID_R, true)
 666         AC_DEFINE(HAVE_GETGRGID_R,1,[Have getgrgid_r]),
 667         AM_CONDITIONAL(HAVE_GETGRGID_R, false))
 668 AC_CHECK_FUNCS([getline],
 669         AM_CONDITIONAL(HAVE_GETLINE, true)
 670         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 671         AM_CONDITIONAL(HAVE_GETLINE, false))
 672 AC_CHECK_FUNCS([getsubopt],
 673         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 674         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 675         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 676 AC_CHECK_FUNCS([fgetln],
 677         AM_CONDITIONAL(HAVE_FGETLN, true)
 678         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 679         AM_CONDITIONAL(HAVE_FGETLN, false))
 680 AC_CHECK_FUNCS([keyctl],
 681         AM_CONDITIONAL(HAVE_KEYCTL, true)
 682         AC_DEFINE(HAVE_KEYCTL,1,[Have keyctl]),
 683         AM_CONDITIONAL(HAVE_KEYCTL, false))
 684 AC_CHECK_FUNCS([prlimit],
 685         AM_CONDITIONAL(HAVE_PRLIMIT, true)
 686         AC_DEFINE(HAVE_PRLIMIT,1,[Have prlimit]),
 687         AM_CONDITIONAL(HAVE_PRLIMIT, false))
 688 AC_CHECK_FUNCS([prlimit64],
 689         AM_CONDITIONAL(HAVE_PRLIMIT64, true)
 690         AC_DEFINE(HAVE_PRLIMIT64,1,[Have prlimit64]),
 691         AM_CONDITIONAL(HAVE_PRLIMIT64, false))
 692 AC_CHECK_FUNCS([pthread_setcancelstate],
 693         AM_CONDITIONAL(HAVE_PTHREAD_SETCANCELSTATE, true)
 694         AC_DEFINE(HAVE_PTHREAD_SETCANCELSTATE,1,[Have pthread_setcancelstate]),
 695         AM_CONDITIONAL(HAVE_PTHREAD_SETCANCELSTATE, false))
 696 AC_CHECK_FUNCS([strlcpy],
 697         AM_CONDITIONAL(HAVE_STRLCPY, true)
 698         AC_DEFINE(HAVE_STRLCPY,1,[Have strlcpy]),
 699         AM_CONDITIONAL(HAVE_STRLCPY, false))
 700 AC_CHECK_FUNCS([strlcat],
 701         AM_CONDITIONAL(HAVE_STRLCAT, true)
 702         AC_DEFINE(HAVE_STRLCAT,1,[Have strlcat]),
 703         AM_CONDITIONAL(HAVE_STRLCAT, false))
 704
 705 # HAVE_STRUCT_RTNL_LINK_STATS64={0,1}
 706 AC_CHECK_TYPES([struct rtnl_link_stats64], [], [], [[#include <linux/if_link.h>]])
 707
 708 # Check for some libraries
 709 AX_PTHREAD
 710 AC_SEARCH_LIBS(clock_gettime, [rt])
 711
 712 # Check for some standard binaries
 713 AC_PROG_GCC_TRADITIONAL
 714 AC_PROG_SED
 715
 716 # See if we support thread-local storage.
 717 LXC_CHECK_TLS
 718
 719 # Hardening flags
 720 AX_CHECK_COMPILE_FLAG([-fdiagnostics-color], [CFLAGS="$CFLAGS -fdiagnostics-color"],,[-Werror])
 721 AX_CHECK_COMPILE_FLAG([-Wimplicit-fallthrough=5], [CFLAGS="$CFLAGS -Wimplicit-fallthrough=5"],,[-Werror])
 722 AX_CHECK_COMPILE_FLAG([-Wcast-align], [CFLAGS="$CFLAGS -Wcast-align"],,[-Werror])
 723 AX_CHECK_COMPILE_FLAG([-Wstrict-prototypes], [CFLAGS="$CFLAGS -Wstrict-prototypes"],,[-Werror])
 724 AX_CHECK_COMPILE_FLAG([-fno-strict-aliasing], [CFLAGS="$CFLAGS -fno-strict-aliasing"],,[-Werror])
 725 AX_CHECK_COMPILE_FLAG([-fstack-clash-protection], [CFLAGS="$CFLAGS -fstack-clash-protection"],,[-Werror])
 726 AX_CHECK_LINK_FLAG([-fstack-protector-strong], [CFLAGS="$CFLAGS -fstack-protector-strong"],,[-Werror])
 727 AX_CHECK_LINK_FLAG([--param=ssp-buffer-size=4], [CFLAGS="$CFLAGS --param=ssp-buffer-size=4"],,[-Werror])
 728 AX_CHECK_COMPILE_FLAG([-g], [CFLAGS="$CFLAGS -g"],,[-Werror])
 729 AX_CHECK_COMPILE_FLAG([--mcet -fcf-protection], [CFLAGS="$CFLAGS --mcet -fcf-protection"],,[-Werror])
 730 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"],,[-Werror])
 731 AX_CHECK_COMPILE_FLAG([-Wlogical-op], [CFLAGS="$CFLAGS -Wlogical-op"],,[-Werror])
 732 AX_CHECK_COMPILE_FLAG([-Wmissing-include-dirs], [CFLAGS="$CFLAGS -Wmissing-include-dirs"],,[-Werror])
 733 AX_CHECK_COMPILE_FLAG([-Wold-style-definition], [CFLAGS="$CFLAGS -Wold-style-definition"],,[-Werror])
 734 AX_CHECK_COMPILE_FLAG([-Winit-self], [CFLAGS="$CFLAGS -Winit-self"],,[-Werror])
 735 AX_CHECK_COMPILE_FLAG([-Wunused-but-set-variable], [CFLAGS="$CFLAGS -Wunused-but-set-variable"],,[-Werror])
 736 AX_CHECK_COMPILE_FLAG([-Wfloat-equal], [CFLAGS="$CFLAGS -Wfloat-equal"],,[-Werror])
 737 AX_CHECK_COMPILE_FLAG([-Wsuggest-attribute=noreturn], [CFLAGS="$CFLAGS -Wsuggest-attribute=noreturn"],,[-Werror])
 738 AX_CHECK_COMPILE_FLAG([-Werror=return-type], [CFLAGS="$CFLAGS -Werror=return-type"],,[-Werror])
 739 AX_CHECK_COMPILE_FLAG([-Werror=incompatible-pointer-types], [CFLAGS="$CFLAGS -Werror=incompatible-pointer-types"],,[-Werror])
 740 AX_CHECK_COMPILE_FLAG([-Wformat=2], [CFLAGS="$CFLAGS -Wformat=2"],,[-Werror])
 741 AX_CHECK_COMPILE_FLAG([-Wshadow], [CFLAGS="$CFLAGS -Wshadow"],,[-Werror])
 742 AX_CHECK_COMPILE_FLAG([-Wendif-labels], [CFLAGS="$CFLAGS -Wendif-labels"],,[-Werror])
 743 AX_CHECK_COMPILE_FLAG([-Werror=overflow], [CFLAGS="$CFLAGS -Werror=overflow"],,[-Werror])
 744 AX_CHECK_COMPILE_FLAG([-fdiagnostics-show-option], [CFLAGS="$CFLAGS -fdiagnostics-show-option"],,[-Werror])
 745 AX_CHECK_COMPILE_FLAG([-Werror=shift-count-overflow], [CFLAGS="$CFLAGS -Werror=shift-count-overflow"],,[-Werror])
 746 AX_CHECK_COMPILE_FLAG([-Werror=shift-overflow=2], [CFLAGS="$CFLAGS -Werror=shift-overflow=2"],,[-Werror])
 747 AX_CHECK_COMPILE_FLAG([-Wdate-time], [CFLAGS="$CFLAGS -Wdate-time"],,[-Werror])
 748 AX_CHECK_COMPILE_FLAG([-Wnested-externs], [CFLAGS="$CFLAGS -Wnested-externs"],,[-Werror])
 749 AX_CHECK_COMPILE_FLAG([-fasynchronous-unwind-tables], [CFLAGS="$CFLAGS -fasynchronous-unwind-tables"],,[-Werror])
 750 AX_CHECK_COMPILE_FLAG([-pipe], [CFLAGS="$CFLAGS -pipe"],,[-Werror])
 751 AX_CHECK_COMPILE_FLAG([-fexceptions], [CFLAGS="$CFLAGS -fexceptions"],,[-Werror])
 752
 753 AX_CHECK_LINK_FLAG([-z relro], [LDFLAGS="$LDFLAGS -z relro"],,[])
 754 AX_CHECK_LINK_FLAG([-z now], [LDFLAGS="$LDFLAGS -z now"],,[])
 755
 756 CFLAGS="$CFLAGS -Wvla -std=gnu11"
 757 if test "x$enable_werror" = "xyes"; then
 758         CFLAGS="$CFLAGS -Werror"
 759 fi
 760
 761 AC_ARG_ENABLE([thread-safety],
 762         [AS_HELP_STRING([--enable-thread-safety], [enforce thread-safety otherwise fail the build [default=yes]])],
 763         [enable_thread_safety=$enableval], [enable_thread_safety=yes])
 764 AM_CONDITIONAL([ENFORCE_THREAD_SAFETY], [test "x$enable_thread_safety" = "xyes"])
 765
 766 AC_ARG_ENABLE([dlog],
 767         [AS_HELP_STRING([--enable-dlog], [enable dlog support [default=no]])],
 768         [enable_dlog=$enableval], [enable_dlog=no])
 769 AM_CONDITIONAL([ENABLE_DLOG], [test "x$enable_dlog" = "xyes"])
 770
 771 AM_COND_IF([ENABLE_DLOG],
 772         [PKG_CHECK_MODULES([DLOG],[dlog],[],[
 773                 AC_CHECK_HEADER([dlog.h],[],[AC_MSG_ERROR([You must install the dlog development package in order to compile lxc])])
 774                 AC_CHECK_LIB([dlog], [dlog_print],[],[AC_MSG_ERROR([You must install the dlog development package in order to compile lxc])])
 775                 AC_SUBST([DLOG_LIBS], [-ldlog])
 776                 ])
 777         ])
 778
 779 AC_ARG_ENABLE([memfd-rexec],
 780         [AS_HELP_STRING([--enable-memfd-rexec], [enforce liblxc as a memfd to protect against certain symlink attacks [default=yes]])],
 781         [enable_memfd_rexec=$enableval], [enable_memfd_rexec=yes])
 782 AM_CONDITIONAL([ENFORCE_MEMFD_REXEC], [test "x$enable_memfd_rexec" = "xyes"])
 783 if test "x$enable_memfd_rexec" = "xyes"; then
 784         AC_DEFINE([ENFORCE_MEMFD_REXEC], 1, [Rexec liblxc as memfd])
 785         AC_MSG_RESULT([yes])
 786 else
 787         AC_MSG_RESULT([no])
 788 fi
 789
 790 # Files requiring some variable expansion
 791 AC_CONFIG_FILES([
 792         Makefile
 793         lxc.pc
 794         lxc.spec
 795
 796         config/Makefile
 797         config/apparmor/Makefile
 798         config/apparmor/abstractions/start-container
 799         config/selinux/Makefile
 800         config/bash/Makefile
 801         config/bash/lxc
 802         config/init/Makefile
 803         config/init/common/Makefile
 804         config/init/common/lxc-containers
 805         config/init/common/lxc-net
 806         config/init/systemd/Makefile
 807         config/init/systemd/lxc.service
 808         config/init/systemd/lxc@.service
 809         config/init/systemd/lxc-net.service
 810         config/init/sysvinit/Makefile
 811         config/init/sysvinit/lxc-containers
 812         config/init/sysvinit/lxc-net
 813         config/init/upstart/lxc.conf
 814         config/init/upstart/lxc-net.conf
 815         config/init/upstart/Makefile
 816         config/etc/Makefile
 817         config/templates/Makefile
 818         config/templates/common.conf
 819         config/templates/common.conf.d/Makefile
 820         config/templates/nesting.conf
 821         config/templates/oci.common.conf
 822         config/templates/userns.conf
 823         config/yum/Makefile
 824         config/sysconfig/Makefile
 825         config/sysconfig/lxc
 826
 827         doc/Makefile
 828         doc/api/Makefile
 829         doc/lxc-attach.sgml
 830         doc/lxc-autostart.sgml
 831         doc/lxc-cgroup.sgml
 832         doc/lxc-checkconfig.sgml
 833         doc/lxc-checkpoint.sgml
 834         doc/lxc-config.sgml
 835         doc/lxc-console.sgml
 836         doc/lxc-copy.sgml
 837         doc/lxc-create.sgml
 838         doc/lxc-destroy.sgml
 839         doc/lxc-device.sgml
 840         doc/lxc-execute.sgml
 841         doc/lxc-freeze.sgml
 842         doc/lxc-info.sgml
 843         doc/lxc-ls.sgml
 844         doc/lxc-monitor.sgml
 845         doc/lxc-snapshot.sgml
 846         doc/lxc-start.sgml
 847         doc/lxc-stop.sgml
 848         doc/lxc-top.sgml
 849         doc/lxc-unfreeze.sgml
 850         doc/lxc-unshare.sgml
 851         doc/lxc-update-config.sgml
 852         doc/lxc-user-nic.sgml
 853         doc/lxc-usernsexec.sgml
 854         doc/lxc-wait.sgml
 855
 856         doc/pam_cgfs.sgml
 857
 858         doc/lxc.conf.sgml
 859         doc/lxc.container.conf.sgml
 860         doc/lxc.system.conf.sgml
 861         doc/lxc-usernet.sgml
 862         doc/lxc.sgml
 863         doc/common_options.sgml
 864         doc/see_also.sgml
 865
 866         doc/rootfs/Makefile
 867
 868         doc/examples/Makefile
 869         doc/examples/lxc-macvlan.conf
 870         doc/examples/lxc-vlan.conf
 871         doc/examples/lxc-no-netns.conf
 872         doc/examples/lxc-empty-netns.conf
 873         doc/examples/lxc-phys.conf
 874         doc/examples/lxc-veth.conf
 875         doc/examples/lxc-complex.conf
 876
 877         doc/ja/Makefile
 878         doc/ja/lxc-attach.sgml
 879         doc/ja/lxc-autostart.sgml
 880         doc/ja/lxc-cgroup.sgml
 881         doc/ja/lxc-checkconfig.sgml
 882         doc/ja/lxc-checkpoint.sgml
 883         doc/ja/lxc-config.sgml
 884         doc/ja/lxc-console.sgml
 885         doc/ja/lxc-copy.sgml
 886         doc/ja/lxc-create.sgml
 887         doc/ja/lxc-destroy.sgml
 888         doc/ja/lxc-device.sgml
 889         doc/ja/lxc-execute.sgml
 890         doc/ja/lxc-freeze.sgml
 891         doc/ja/lxc-info.sgml
 892         doc/ja/lxc-ls.sgml
 893         doc/ja/lxc-monitor.sgml
 894         doc/ja/lxc-snapshot.sgml
 895         doc/ja/lxc-start.sgml
 896         doc/ja/lxc-stop.sgml
 897         doc/ja/lxc-top.sgml
 898         doc/ja/lxc-unfreeze.sgml
 899         doc/ja/lxc-unshare.sgml
 900         doc/ja/lxc-update-config.sgml
 901         doc/ja/lxc-user-nic.sgml
 902         doc/ja/lxc-usernsexec.sgml
 903         doc/ja/lxc-wait.sgml
 904
 905         doc/ja/pam_cgfs.sgml
 906
 907         doc/ja/lxc.conf.sgml
 908         doc/ja/lxc.container.conf.sgml
 909         doc/ja/lxc.system.conf.sgml
 910         doc/ja/lxc-usernet.sgml
 911         doc/ja/lxc.sgml
 912         doc/ja/common_options.sgml
 913         doc/ja/see_also.sgml
 914
 915         doc/ko/Makefile
 916         doc/ko/lxc-attach.sgml
 917         doc/ko/lxc-autostart.sgml
 918         doc/ko/lxc-cgroup.sgml
 919         doc/ko/lxc-checkconfig.sgml
 920         doc/ko/lxc-checkpoint.sgml
 921         doc/ko/lxc-config.sgml
 922         doc/ko/lxc-console.sgml
 923         doc/ko/lxc-copy.sgml
 924         doc/ko/lxc-create.sgml
 925         doc/ko/lxc-destroy.sgml
 926         doc/ko/lxc-device.sgml
 927         doc/ko/lxc-execute.sgml
 928         doc/ko/lxc-freeze.sgml
 929         doc/ko/lxc-info.sgml
 930         doc/ko/lxc-ls.sgml
 931         doc/ko/lxc-monitor.sgml
 932         doc/ko/lxc-snapshot.sgml
 933         doc/ko/lxc-start.sgml
 934         doc/ko/lxc-stop.sgml
 935         doc/ko/lxc-top.sgml
 936         doc/ko/lxc-unfreeze.sgml
 937         doc/ko/lxc-unshare.sgml
 938         doc/ko/lxc-user-nic.sgml
 939         doc/ko/lxc-usernsexec.sgml
 940         doc/ko/lxc-wait.sgml
 941
 942         doc/ko/lxc.conf.sgml
 943         doc/ko/lxc.container.conf.sgml
 944         doc/ko/lxc.system.conf.sgml
 945         doc/ko/lxc-usernet.sgml
 946         doc/ko/lxc.sgml
 947         doc/ko/common_options.sgml
 948         doc/ko/see_also.sgml
 949
 950         hooks/Makefile
 951         hooks/dhclient
 952
 953         templates/Makefile
 954         templates/lxc-busybox
 955         templates/lxc-download
 956         templates/lxc-local
 957         templates/lxc-oci
 958
 959         src/Makefile
 960         src/lxc/Makefile
 961         src/lxc/lxc.functions
 962         src/lxc/cmd/lxc-checkconfig
 963         src/lxc/cmd/lxc-update-config
 964         src/lxc/version.h
 965
 966         src/tests/Makefile
 967         src/tests/lxc-test-usernic
 968 ])
 969 AC_CONFIG_COMMANDS([default],[[]],[[]])
 970 AC_OUTPUT
 971
 972 # Configuration overview
 973 cat << EOF
 974
 975 ----------------------------
 976 Binaries
 977  - Command Line Tools:
 978    - lxc-attach:     $enable_tools
 979    - lxc-autostart:  $enable_tools
 980    - lxc-cgroup:     $enable_tools
 981    - lxc-checkpoint: $enable_tools
 982    - lxc-config:     $enable_tools
 983    - lxc-console:    $enable_tools
 984    - lxc-copy:       $enable_tools
 985    - lxc-create:     $enable_tools
 986    - lxc-destroy:    $enable_tools
 987    - lxc-device:     $enable_tools
 988    - lxc-execute:    $enable_tools
 989    - lxc-freeze:     $enable_tools
 990    - lxc-info:       $enable_tools
 991    - lxc-ls:         $enable_tools
 992    - lxc-monitor:    $enable_tools
 993    - lxc-snapshot:   $enable_tools
 994    - lxc-start:      $enable_tools
 995    - lxc-stop:       $enable_tools
 996    - lxc-top:        $enable_tools
 997    - lxc-unfreeze:   $enable_tools
 998    - lxc-unshare:    $enable_tools
 999    - lxc-wait:       $enable_tools
1000
1001  - liblxc Commands:
1002    - lxc-checkconfig:   $enable_commands
1003    - lxc-update-config: $enable_commands
1004    - lxc-init:          $enable_commands
1005    - lxc-monitord:      $enable_commands
1006    - lxc-user-nic:      $enable_commands
1007    - lxc-usernsexec:    $enable_commands
1008
1009 Environment:
1010  - compiler: $CC
1011  - distribution: $with_distro
1012  - init script type(s): $init_script
1013  - rpath: $enable_rpath
1014  - OpenSSL: $enable_openssl
1015  - Bash integration: $enable_bash
1016
1017 Security features:
1018  - Apparmor: $enable_apparmor
1019  - Linux capabilities: $enable_capabilities
1020  - seccomp: $enable_seccomp
1021  - SELinux: $enable_selinux
1022  - memfd rexec: $enable_memfd_rexec
1023
1024 PAM:
1025  - PAM module: $enable_pam
1026  - cgroup PAM module: $pamdir
1027
1028 Documentation:
1029  - examples: $enable_examples
1030  - API documentation: $enable_api_docs
1031  - user documentation: $enable_doc
1032
1033 Debugging:
1034  - tests: $enable_tests
1035  - ASAN: $enable_asan
1036  - mutex debugging: $enable_mutex_debugging
1037
1038 Paths:
1039  - Logs in configpath: $enable_configpath_log
1040
1041 Thread-safety:
1042  - enforce: $enable_thread_safety
1043
1044 Dlog:
1045  - enable: $enable_dlog
1046 EOF