meson.build

   1 # SPDX-License-Identifier: LGPL-2.1-or-later
   2
   3 # Project.
   4 project(
   5     'lxc',
   6     'c',
   7     version: '5.0.0',
   8     license: 'LGPLv2+',
   9     default_options: [
  10         'b_lto=true',
  11         'b_lto_mode=thin',
  12         'b_colorout=always',
  13         'b_asneeded=true',
  14         'b_pie=true',
  15         'b_staticpic=true',
  16         'c_std=gnu11',
  17         'warning_level=2',
  18     ],
  19     meson_version: '>= 0.61')
  20
  21 cc = meson.get_compiler('c')
  22 pkgconfig = import('pkgconfig')
  23 pkgconfig_libs = []
  24
  25 # Version.
  26 liblxc_version = '1.7.0'
  27 version_data = configuration_data()
  28 version_data.set('LXC_VERSION_MAJOR', '5')
  29 version_data.set('LXC_VERSION_MINOR', '0')
  30 version_data.set('LXC_VERSION_MICRO', '0')
  31 version_data.set('LXC_VERSION_BETA', '')
  32 version_data.set('LXC_ABI', liblxc_version)
  33 version_data.set('LXC_DEVEL', '1')
  34 version_data.set('LXC_VERSION', meson.project_version())
  35
  36 # Path handling.
  37 project_source_root = meson.current_source_dir()
  38 project_build_root = meson.current_build_dir()
  39 prefixdir = get_option('prefix')
  40
  41 apparmorcachedir = get_option('apparmor-cache-path')
  42 globalconfig = get_option('global-config-path')
  43 localstatedir = join_paths('/', get_option('localstatedir'))
  44 logpath = get_option('log-path')
  45 lxcpathprefix = get_option('data-path')
  46 rootfsmount = get_option('rootfs-mount-path')
  47 user_network_db_opt = get_option('usernet-db-path')
  48 user_network_conf_opt = get_option('usernet-config-path')
  49
  50 bashcompletiondir = join_paths('/', 'usr', 'share', 'bash-completion', 'completions')
  51 bindir = join_paths(prefixdir, get_option('bindir'))
  52 datadir = join_paths(prefixdir, get_option('datadir'))
  53 mandir = join_paths(prefixdir, get_option('mandir'))
  54 docdir = join_paths(datadir, get_option('doc-path'))
  55 includedir = join_paths(prefixdir, get_option('includedir'))
  56 libdir = join_paths(prefixdir, get_option('libdir'))
  57 libexecdir = join_paths(prefixdir, get_option('libexecdir'))
  58 runtimepath = join_paths(prefixdir, get_option('runtime-path'))
  59 sbindir = join_paths(prefixdir, get_option('sbindir'))
  60 sysconfdir = join_paths(prefixdir, get_option('sysconfdir'))
  61
  62 lxcapparmorcachedir = join_paths(localstatedir, apparmorcachedir)
  63 lxcconfdir = join_paths(sysconfdir, globalconfig)
  64 lxcdefaultconfig = join_paths(lxcconfdir, 'default.conf')
  65 lxcglobalconfig = join_paths(lxcconfdir, 'lxc.conf')
  66 lxcexamplesdir = join_paths(docdir, 'examples')
  67 lxchookbindir = join_paths(libexecdir, 'lxc/hooks')
  68 lxcinclude = join_paths(includedir, 'lxc')
  69 lxclibexec = join_paths(libexecdir, 'lxc')
  70 lxclogpath = join_paths(localstatedir, logpath)
  71 lxcpath = join_paths(localstatedir, lxcpathprefix)
  72 lxcrootfsmount = join_paths(libdir, rootfsmount)
  73 lxcdatadir = join_paths(datadir, 'lxc')
  74 lxchookdir = join_paths(lxcdatadir, 'hooks')
  75 lxcselinuxdir = join_paths(lxcdatadir, 'selinux')
  76 lxctemplateconfdir = join_paths(lxcdatadir, 'config')
  77 lxctemplateconfcommondir = join_paths(lxctemplateconfdir, 'common.conf.d')
  78 lxctemplatedir = join_paths(lxcdatadir, 'templates')
  79 lxc_user_network_conf = join_paths(sysconfdir, user_network_conf_opt)
  80 lxc_user_network_db = join_paths(runtimepath, user_network_db_opt)
  81 pam_security = join_paths(libdir, 'security')
  82
  83 # Configuration options.
  84 srcconf = configuration_data()
  85 srcconf.set('_GNU_SOURCE', true)
  86 srcconf.set('_FILE_OFFSET_BITS', 64)
  87 srcconf.set('__STDC_FORMAT_MACROS', true)
  88 srcconf.set_quoted('APPARMOR_CACHE_DIR', lxcapparmorcachedir)
  89 srcconf.set_quoted('LIBEXECDIR', libexecdir)
  90 srcconf.set_quoted('LOGPATH', lxclogpath)
  91 srcconf.set_quoted('LXC_DEFAULT_CONFIG', lxcdefaultconfig)
  92 srcconf.set_quoted('LXC_GLOBAL_CONF', lxcglobalconfig)
  93 srcconf.set_quoted('LXCINITDIR', libexecdir)
  94 srcconf.set_quoted('LXCPATH', lxcpath)
  95 srcconf.set_quoted('LXCROOTFSMOUNT', lxcrootfsmount)
  96 srcconf.set_quoted('LXCTEMPLATECONFIG', lxctemplateconfdir)
  97 srcconf.set_quoted('LXCTEMPLATECONFIG', lxctemplateconfdir)
  98 srcconf.set_quoted('LXCTEMPLATEDIR', lxctemplatedir)
  99 srcconf.set_quoted('LXC_USERNIC_CONF', lxc_user_network_conf)
 100 srcconf.set_quoted('LXC_USERNIC_DB', lxc_user_network_db)
 101 srcconf.set_quoted('RUNTIME_PATH', runtimepath)
 102 srcconf.set_quoted('SBINDIR', sbindir)
 103
 104 conf = configuration_data()
 105 conf.set('BINDIR', bindir)
 106 conf.set('LIBEXECDIR', libexecdir)
 107 conf.set('LOCALSTATEDIR', localstatedir)
 108 conf.set('LXC_GLOBAL_CONF', lxcglobalconfig)
 109 conf.set('LXCHOOKDIR', lxchookdir)
 110 conf.set('LXCINITDIR', libexecdir)
 111 conf.set('LXCROOTFSMOUNT', lxcrootfsmount)
 112 conf.set('LXCTEMPLATECONFIG', lxctemplateconfdir)
 113 conf.set('LXCTEMPLATEDIR', lxctemplatedir)
 114 conf.set('PACKAGE_VERSION', meson.project_version())
 115 conf.set('RUNTIME_PATH', runtimepath)
 116 conf.set('SYSCONFDIR', sysconfdir)
 117
 118 # Set sysconfdir
 119 fs = import('fs')
 120 if fs.is_dir('/etc/sysconfig')
 121     distrosysconfdir = join_paths(sysconfdir, 'sysconfig')
 122     conf.set('LXC_DISTRO_SYSCONF', distrosysconfdir)
 123 elif fs.is_dir('/etc/default')
 124     distrosysconfdir = join_paths(sysconfdir, 'default')
 125     conf.set('LXC_DISTRO_SYSCONF', distrosysconfdir)
 126 else
 127     distrosysconfdir = ''
 128 endif
 129
 130 # Cross-compile on Android.
 131 srcconf.set10('IS_BIONIC', host_machine.system() == 'android')
 132
 133 # Custom configuration.
 134 cgrouppattern = get_option('cgroup-pattern')
 135 coverity = get_option('coverity-build')
 136 init_script = get_option('init-script')
 137 sanitize = get_option('b_sanitize')
 138 want_examples = get_option('examples')
 139 want_io_uring = get_option('io-uring-event-loop')
 140 want_pam_cgroup = get_option('pam-cgroup')
 141 want_mans = get_option('man')
 142 want_tests = get_option('tests')
 143 want_tools = get_option('tools')
 144 want_tools_multicall = get_option('tools-multicall')
 145 want_commands = get_option('commands')
 146 want_capabilities = get_option('capabilities')
 147 want_apparmor = get_option('apparmor')
 148 want_openssl = get_option('openssl')
 149 want_selinux = get_option('selinux')
 150 want_oss_fuzz = get_option('oss-fuzz')
 151 want_seccomp = get_option('seccomp')
 152 want_thread_safety = get_option('thread-safety')
 153 want_memfd_rexec = get_option('memfd-rexec')
 154 want_sd_bus = get_option('sd-bus')
 155
 156 srcconf.set_quoted('DEFAULT_CGROUP_PATTERN', cgrouppattern)
 157 if coverity
 158     srcconf.set('ENABLE_COVERITY_BUILD', 1)
 159 endif
 160
 161 dummy_config_data = configuration_data()
 162 dummy_config_data.set_quoted('DUMMY_VARIABLE', '1')
 163
 164 # Those generate many false positives, and we do not want to change the code to
 165 # avoid them.
 166 basic_disabled_warnings = [
 167         '-Wno-format-signedness',
 168         '-Wno-missing-field-initializers',
 169         '-Wno-unused-parameter',
 170 ]
 171
 172 # Build flags.
 173 possible_cc_flags = [
 174     '-Wvla',
 175     '-Wimplicit-fallthrough=5',
 176     '-Wcast-align',
 177     '-Wstrict-prototypes',
 178     '-fno-strict-aliasing',
 179     '-fstack-clash-protection',
 180     '--param=ssp-buffer-size=4',
 181     '--mcet -fcf-protection',
 182     '-Werror=implicit-function-declaration',
 183     '-Wlogical-op',
 184     '-Wmissing-include-dirs',
 185     '-Wold-style-definition',
 186     '-Winit-self',
 187     '-Wunused-but-set-variable',
 188     '-Wno-unused-parameter',
 189     '-Wfloat-equal',
 190     '-Wsuggest-attribute=noreturn',
 191     '-Werror=return-type',
 192     '-Werror=incompatible-pointer-types',
 193     '-Wformat=2',
 194     '-Wshadow',
 195     '-Wendif-labels',
 196     '-Werror=overflow',
 197     '-fdiagnostics-show-option',
 198     '-Werror=shift-count-overflow',
 199     '-Werror=shift-overflow=2',
 200     '-Wdate-time',
 201     '-Wnested-externs',
 202     '-fasynchronous-unwind-tables',
 203     '-fexceptions',
 204     '-Warray-bounds',
 205     '-Wrestrict',
 206     '-Wreturn-local-addr',
 207     '-fsanitize=cfi',
 208     '-Wstringop-overflow',
 209 ]
 210
 211 possible_link_flags = [
 212     '-Wl,--gc-sections',
 213     '-Wl,-z,relro',
 214     '-Wl,-z,now',
 215     '-Wl,-fuse-ld=gold',
 216     '-fstack-protector',
 217     '-fstack-protector-strong',
 218 ]
 219
 220 if sanitize == 'none'
 221     possible_link_flags += '-Wl,--warn-common'
 222 endif
 223
 224 if cc.get_id() == 'clang'
 225     possible_cc_flags += [
 226             '-Wno-typedef-redefinition',
 227             '-Wno-gnu-variable-sized-type-not-at-end',
 228     ]
 229 endif
 230
 231 if meson.version().version_compare('>=0.46')
 232     add_project_link_arguments(cc.get_supported_link_arguments(possible_link_flags), language: 'c')
 233 else
 234     add_project_link_arguments(possible_link_flags, language: 'c')
 235 endif
 236
 237 add_project_arguments(cc.get_supported_arguments(basic_disabled_warnings), language : 'c')
 238 add_project_arguments(cc.get_supported_arguments(possible_cc_flags), language: 'c')
 239
 240 if add_languages('cpp', required : want_oss_fuzz)
 241     #  Used only for tests
 242     cxx = meson.get_compiler('cpp')
 243     cxx_cmd = ' '.join(cxx.cmd_array())
 244     add_project_arguments(cxx.get_supported_arguments(basic_disabled_warnings), language : 'cpp')
 245 endif
 246
 247 # Feature detection
 248 ## I/O uring.
 249 if want_io_uring
 250     liburing = dependency('liburing')
 251     if cc.has_function('io_uring_prep_poll_add', prefix: '#include <liburing.h>', dependencies: liburing) == false
 252         error('liburing version does not support IORING_POLL_ADD_MULTI')
 253     endif
 254
 255     srcconf.set10('HAVE_LIBURING', true)
 256 else
 257     srcconf.set10('HAVE_LIBURING', false)
 258 endif
 259
 260 if not want_sd_bus.disabled()
 261     has_sd_bus = true
 262     sd_bus_optional = want_sd_bus.auto()
 263
 264     libsystemd = dependency('libsystemd', required: not sd_bus_optional)
 265     if not libsystemd.found()
 266         if not sd_bus_optional
 267             error('missing required libsystemd dependency')
 268         endif
 269
 270         has_sd_bus = false
 271     endif
 272
 273     if not cc.has_header('systemd/sd-bus.h')
 274         if not sd_bus_optional
 275             error('libsystemd misses required systemd/sd-bus.h header')
 276         endif
 277
 278         has_sd_bus = false
 279     endif
 280
 281     if not cc.has_header('systemd/sd-event.h')
 282         if not sd_bus_optional
 283             error('libsystemd misses required systemd/sd-event.h header')
 284         endif
 285
 286         has_sd_bus = false
 287     endif
 288
 289     if not cc.has_function('sd_bus_call_method_asyncv', prefix: '#include <systemd/sd-bus.h>', dependencies: libsystemd)
 290         if not sd_bus_optional
 291             error('libsystemd misses required sd_bus_call_method_asyncv function')
 292         endif
 293
 294         has_sd_bus = false
 295     endif
 296
 297     srcconf.set10('HAVE_LIBSYSTEMD', has_sd_bus)
 298 else
 299     has_sd_bus = false
 300     srcconf.set10('HAVE_LIBSYSTEMD', false)
 301 endif
 302
 303 ## Time EPOCH.
 304 sh = find_program('sh')
 305 date = find_program('date')
 306 git = find_program('git', required: false)
 307 time_epoch = run_command(sh, '-c', 'echo "$SOURCE_DATE_EPOCH"', check: true).stdout().strip()
 308 if time_epoch == '' and git.found() and run_command('test', '-e', '.git', check: false).returncode() == 0
 309     # If we're in a git repository, use the creation time of the latest git tag.
 310     latest_tag = run_command(git, 'describe', '--abbrev=0', '--tags', check: false).stdout().strip()
 311     if latest_tag != ''
 312       time_epoch = run_command(git, 'log', '--no-show-signature', '-1', '--format=%at', latest_tag, check: true).stdout()
 313     endif
 314 endif
 315
 316 # Fallback to current epoch.
 317 if time_epoch == ''
 318     time_epoch = run_command(date, '+%s', check: true).stdout()
 319 endif
 320 generate_date = run_command(date, '--utc', '--date=@' + time_epoch, '+%Y-%m-%d', check: true).stdout().strip()
 321
 322 ## Manpages.
 323 sgml2man = find_program('docbook2X2man', 'docbook2x-man', 'db2x_docbook2man', 'docbook2man', 'docbook-to-man', required: want_mans)
 324 docbook2man = find_program('docbook2man', required: false)
 325
 326 docconf = configuration_data()
 327 docconf.set('builddir', '.')
 328 docconf.set('BINDIR', bindir)
 329 docconf.set('DATADIR', datadir)
 330 docconf.set('DOCDIR', docdir)
 331 docconf.set('LOGPATH', lxclogpath)
 332 docconf.set('LXC_DEFAULT_CONFIG', lxcdefaultconfig)
 333 docconf.set('LXC_GENERATE_DATE', generate_date)
 334 docconf.set('LXC_GLOBAL_CONF', lxcglobalconfig)
 335 docconf.set('LXCPATH', lxcpath)
 336 docconf.set('LXCTEMPLATEDIR', lxctemplatedir)
 337 docconf.set('LXC_USERNIC_CONF', lxc_user_network_conf)
 338 docconf.set('LXC_USERNIC_DB', lxc_user_network_db)
 339 docconf.set('PACKAGE_VERSION', version_data.get('LXC_VERSION'))
 340 if sgml2man.found() and docbook2man.found() and sgml2man.full_path() == docbook2man.full_path()
 341     docconf.set('docdtd', '"-//Davenport//DTD DocBook V3.0//EN"')
 342 else
 343     docconf.set('docdtd', '"-//OASIS//DTD DocBook XML" "http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd"')
 344 endif
 345
 346 ## Threads.
 347 threads = dependency('threads')
 348
 349 ## Seccomp.
 350 if want_seccomp
 351     libseccomp = dependency('libseccomp', required: false)
 352     srcconf.set10('HAVE_SECCOMP', libseccomp.found())
 353     pkgconfig_libs += libseccomp
 354     if libseccomp.found()
 355         if libseccomp.version().version_compare('>=2.5.0')
 356             # https://github.com/seccomp/libseccomp/commit/dead12bc788b259b148cc4d93b970ef0bd602b1a
 357             srcconf.set10('HAVE_DECL_SECCOMP_NOTIFY_FD', true)
 358         else
 359             srcconf.set10('HAVE_DECL_SECCOMP_NOTIFY_FD', false)
 360         endif
 361
 362         if libseccomp.version().version_compare('>=2.0.0')
 363             # https://github.com/seccomp/libseccomp/commit/6220c8c0fc479d97b6d3e3166a4e46fbfe25a3c0
 364             srcconf.set10('HAVE_DECL_SECCOMP_SYSCALL_RESOLVE_NAME_ARCH', true)
 365         else
 366             srcconf.set10('HAVE_DECL_SECCOMP_SYSCALL_RESOLVE_NAME_ARCH', false)
 367         endif
 368
 369         seccomp_headers = '''
 370         #include <seccomp.h>
 371         '''
 372
 373         foreach decl: [
 374             'scmp_filter_ctx',
 375             'struct seccomp_notif_sizes',
 376             'struct clone_args',
 377         ]
 378
 379             # We get -1 if the size cannot be determined
 380             if cc.sizeof(decl, prefix: seccomp_headers, args: '-D_GNU_SOURCE') > 0
 381                 srcconf.set10('HAVE_' + decl.underscorify().to_upper(), true)
 382             else
 383                 srcconf.set10('HAVE_' + decl.underscorify().to_upper(), false)
 384             endif
 385         endforeach
 386     endif
 387 else
 388     srcconf.set10('HAVE_SECCOMP', false)
 389 endif
 390
 391 ## SELinux.
 392 if want_selinux
 393     libselinux = dependency('libselinux', required: false)
 394     srcconf.set10('HAVE_SELINUX', libselinux.found())
 395     pkgconfig_libs += libselinux
 396 else
 397     srcconf.set10('HAVE_SELINUX', false)
 398 endif
 399
 400 ## AppArmor.
 401 if want_apparmor
 402     libapparmor = dependency('libapparmor', required: false)
 403     srcconf.set10('HAVE_APPARMOR', libapparmor.found())
 404 else
 405     srcconf.set10('HAVE_APPARMOR', false)
 406 endif
 407
 408 ## OpenSSL.
 409 if want_openssl
 410     libopenssl = dependency('openssl', required: false)
 411     srcconf.set10('HAVE_OPENSSL', libopenssl.found())
 412     pkgconfig_libs += libopenssl
 413 else
 414     srcconf.set10('HAVE_OPENSSL', false)
 415 endif
 416
 417 ## Libcap..
 418 if want_capabilities
 419     libcap = dependency('libcap', required: false)
 420     if not libcap.found()
 421         # Compat with Ubuntu 14.04 which ships libcap w/o .pc file
 422         libcap = cc.find_library('cap', required: false)
 423     else
 424         have = cc.has_function('cap_get_file', dependencies: libcap, prefix: '#include <sys/capability.h>')
 425         srcconf.set10('LIBCAP_SUPPORTS_FILE_CAPABILITIES', have)
 426     endif
 427     srcconf.set10('HAVE_LIBCAP', libcap.found())
 428     pkgconfig_libs += libcap
 429
 430     libcap_static = dependency('libcap', required: false, static: true)
 431     if not libcap_static.found()
 432         # Compat with Ubuntu 14.04 which ships libcap w/o .pc file
 433         libcap_static = cc.find_library('cap', required: false, static: true)
 434     endif
 435
 436     code = '''
 437 int main(int argc, char *argv[]) { return 0; };
 438 '''
 439     if libcap_static.found()
 440         libcap_static_linkable = cc.links(code, args: '-static', dependencies: libcap_static)
 441         srcconf.set10('HAVE_STATIC_LIBCAP', libcap_static_linkable)
 442     else
 443         srcconf.set10('HAVE_STATIC_LIBCAP', false)
 444     endif
 445 else
 446     libcap_static = []
 447     srcconf.set10('HAVE_LIBCAP', false)
 448     srcconf.set10('HAVE_STATIC_LIBCAP', false)
 449 endif
 450
 451 libutil = cc.find_library('util', required: false)
 452
 453 oss_fuzz_dependencies = []
 454 if want_oss_fuzz
 455     srcconf.set10('FUZZING_BUILD_MODE_UNSAFE_FOR_PRODUCTION', true)
 456     srcconf.set10('RUN_ON_OSS_FUZZ', true)
 457     fuzzing_engine = meson.get_compiler('cpp').find_library('FuzzingEngine')
 458 endif
 459
 460 srcconf.set10('ENFORCE_THREAD_SAFETY', want_thread_safety)
 461 srcconf.set10('ENFORCE_MEMFD_REXEC', want_memfd_rexec)
 462
 463 ## PAM.
 464 pam = cc.find_library('pam', has_headers: 'security/pam_modules.h', required: want_pam_cgroup)
 465 srcconf.set10('HAVE_PAM', pam.found())
 466 pkgconfig_libs += pam
 467
 468 ## Others.
 469 have = cc.has_function('fmemopen', prefix: '#include <stdio.h>', args: '-D_GNU_SOURCE')
 470 srcconf.set10('HAVE_FMEMOPEN', have)
 471
 472 have_openpty = cc.has_function('openpty', dependencies: libutil, prefix: '#include <pty.h>')
 473 srcconf.set10('HAVE_OPENPTY', have_openpty)
 474
 475 have = cc.has_function('pthread_setcancelstate', prefix: '#include <pthread.h>')
 476 srcconf.set10('HAVE_PTHREAD_SETCANCELSTATE', have)
 477
 478 have = cc.has_function('rand_r')
 479 srcconf.set10('HAVE_RAND_R', have)
 480
 481 have = cc.has_function('strchrnul', prefix: '#include <string.h>', args: '-D_GNU_SOURCE')
 482 srcconf.set10('HAVE_STRCHRNUL', have)
 483
 484 have_func_strerror_r = cc.has_function('strerror_r', prefix: '#include <string.h>', args: '-D_GNU_SOURCE')
 485 srcconf.set10('HAVE_STRERROR_R', have_func_strerror_r)
 486
 487 have_func_strerror_r_char_p = false
 488
 489 if have_func_strerror_r
 490     code = '''
 491 #define _GNU_SOURCE
 492 #include <string.h>
 493 int func (void) {
 494     char error_string[256];
 495     char *ptr = strerror_r (-2, error_string, 256);
 496     char c = *strerror_r (-2, error_string, 256);
 497     return c != 0 && ptr != (void*) 0L;
 498 }
 499 '''
 500
 501 have_func_strerror_r_char_p = cc.compiles(code, name : 'strerror_r() returns char *')
 502 endif
 503
 504 srcconf.set10('STRERROR_R_CHAR_P', have_func_strerror_r_char_p)
 505
 506 ## Compiler attributes.
 507 foreach ccattr: [
 508     'fallthrough',
 509     'nonnull',
 510     'returns_nonnull',
 511 ]
 512
 513     srcconf.set10('HAVE_COMPILER_ATTR_' + ccattr.underscorify().to_upper(), cc.has_function_attribute(ccattr))
 514 endforeach
 515
 516 ## Syscalls.
 517 found_syscalls = []
 518 missing_syscalls = []
 519 foreach tuple: [
 520     ['bpf'],
 521     ['close_range'],
 522     ['endmntent'],
 523     ['execveat'],
 524     ['faccessat'],
 525     ['strchrnul'],
 526     ['strerror_r'],
 527     ['fgetln'],
 528     ['fsconfig'],
 529     ['fsmount'],
 530     ['fsopen'],
 531     ['fspick'],
 532     ['getgrgid_r'],
 533     ['getline'],
 534     ['getsubopt'],
 535     ['gettid'],
 536     ['hasmntopt'],
 537     ['kcmp'],
 538     ['keyctl'],
 539     ['memfd_create'],
 540     ['mount_setattr'],
 541     ['move_mount'],
 542     ['openat2'],
 543     ['open_tree'],
 544     ['personality'],
 545     ['pidfd_open'],
 546     ['pidfd_send_signal'],
 547     ['pivot_root'],
 548     ['prlimit'],
 549     ['prlimit64'],
 550     ['renameat2'],
 551     ['sethostname'],
 552     ['setmntent'],
 553     ['setns'],
 554     ['sigdescr_np'],
 555     ['signalfd'],
 556     ['statx'],
 557     ['statvfs'],
 558     ['strlcat'],
 559     ['strlcpy'],
 560     ['unshare'],
 561 ]
 562
 563     if tuple.length() >= 2
 564         cond = tuple[1]
 565     else
 566         ident1 = 'HAVE_' + tuple[0].underscorify().to_upper()
 567         ident2 = 'ENABLE_' + tuple[0].underscorify().to_upper()
 568         cond = srcconf.get(ident1, 0) == 1 or srcconf.get(ident2, 0) == 1
 569     endif
 570
 571     if cond
 572         found_syscalls += tuple[0]
 573     else
 574         missing_syscalls += tuple[0]
 575     endif
 576 endforeach
 577
 578 ## Types.
 579 decl_headers = '''
 580 #include <uchar.h>
 581 #include <sys/mount.h>
 582 #include <sys/stat.h>
 583 #include <linux/fs.h>
 584 #include <linux/if_link.h>
 585 #include <linux/openat2.h>
 586 #include <linux/sched.h>
 587 #include <linux/types.h>
 588 '''
 589
 590 foreach decl: [
 591     '__aligned_u64',
 592     'struct clone_args',
 593     'struct mount_attr',
 594     'struct open_how',
 595     'struct rtnl_link_stats64',
 596 ]
 597
 598     # We get -1 if the size cannot be determined
 599     if cc.sizeof(decl, prefix: decl_headers, args: '-D_GNU_SOURCE') > 0
 600         srcconf.set10('HAVE_' + decl.underscorify().to_upper(), true)
 601     else
 602         srcconf.set10('HAVE_' + decl.underscorify().to_upper(), false)
 603     endif
 604 endforeach
 605
 606 found_types = []
 607 missing_types = []
 608 foreach tuple: [
 609     ['scmp_filter_ctx'],
 610     ['struct seccomp_notif_sizes'],
 611     ['struct clone_args'],
 612     ['__aligned_u64'],
 613     ['struct mount_attr'],
 614     ['struct open_how'],
 615     ['struct rtnl_link_stats64'],
 616 ]
 617
 618     if tuple.length() >= 2
 619         cond = tuple[1]
 620     else
 621         ident1 = 'HAVE_' + tuple[0].underscorify().to_upper()
 622         ident2 = 'ENABLE_' + tuple[0].underscorify().to_upper()
 623         cond = srcconf.get(ident1, 0) == 1 or srcconf.get(ident2, 0) == 1
 624     endif
 625
 626     if cond
 627         found_types += tuple[0]
 628     else
 629         missing_types += tuple[0]
 630     endif
 631 endforeach
 632
 633 ## Headers.
 634 foreach ident: [
 635     ['bpf',               '''#include <sys/syscall.h>
 636                              #include <unistd.h>'''],
 637     ['close_range',       '''#include <unistd.h>'''],
 638     ['execveat',          '''#include <unistd.h>'''],
 639     ['endmntent',         '''#include <stdio.h>
 640                              #include <mntent.h>'''],
 641     ['faccessat',         '''#include <fcntl.h>
 642                              #include <unistd.h>'''],
 643     ['fexecve',           '''#include <unistd.h>'''],
 644     ['fgetln',            '''#include <stdio.h>'''],
 645     ['fsconfig',          '''#include <sys/mount.h>'''],
 646     ['fsmount',           '''#include <sys/mount.h>'''],
 647     ['fsopen',            '''#include <sys/mount.h>'''],
 648     ['fspick',            '''#include <sys/mount.h>'''],
 649     ['getgrgid_r',        '''#include <sys/types.h>
 650                              #include <grp.h>'''],
 651     ['getline',           '''#include <stdio.h>'''],
 652     ['getsubopt',         '''#include <stdlib.h>'''],
 653     ['gettid',            '''#include <sys/types.h>
 654                              #include <unistd.h>'''],
 655     ['hasmntopt',         '''#include <stdio.h>
 656                              #include <mntent.h>'''],
 657     ['kcmp',              '''#include <linux/kcmp.h>'''],
 658     ['keyctl',            '''#include <sys/types.h>
 659                              #include <keyutils.h>'''],
 660     ['memfd_create',      '''#include <sys/mman.h>'''],
 661     ['mount_setattr',     '''#include <sys/mount.h>'''],
 662     ['move_mount',        '''#include <sys/mount.h>'''],
 663     ['openat2',           '''#include <sys/types.h>
 664                              #include <sys/stat.h>
 665                              #include <fctnl.h>'''],
 666     ['open_tree',         '''#include <sys/mount.h>'''],
 667     ['personality',       '''#include <sys/personality.h>'''],
 668     ['pidfd_open',        '''#include <stdlib.h>
 669                              #include <unistd.h>
 670                              #include <signal.h>
 671                              #include <sys/wait.h>'''],
 672     ['pidfd_send_signal', '''#include <stdlib.h>
 673                              #include <unistd.h>
 674                              #include <signal.h>
 675                              #include <sys/wait.h>'''],
 676     ['pivot_root',        '''#include <stdlib.h>
 677                              #include <unistd.h>'''],     # no known header declares pivot_root
 678     ['prlimit',           '''#include <sys/time.h>
 679                              #include <sys/resource.h>'''],
 680     ['prlimit64',         '''#include <sys/time.h>
 681                              #include <sys/resource.h>'''],
 682     ['renameat2',         '''#include <stdio.h>
 683                              #include <fcntl.h>'''],
 684     ['sethostname',       '''#include <unistd.h>'''],
 685     ['setmntent',         '''#include <stdio.h>
 686                              #include <mntent.h>'''],
 687     ['setns',             '''#include <sched.h>'''],
 688     ['sigdescr_np',       '''#include <string.h>'''],
 689     ['signalfd',          '''#include <sys/signalfd.h>'''],
 690     ['statvfs',           '''#include <sys/statvfs.h>'''],
 691     ['statx',             '''#include <sys/types.h>
 692                              #include <sys/stat.h>
 693                              #include <unistd.h>'''],
 694     ['strchrnul',         '''#include <string.h>'''],
 695     ['strlcat',           '''#include <string.h>'''],
 696     ['strlcpy',           '''#include <string.h>'''],
 697     ['unshare',           '''#include <sched.h>'''],
 698 ]
 699
 700     have = cc.has_function(ident[0], prefix: ident[1], args: '-D_GNU_SOURCE')
 701     srcconf.set10('HAVE_' + ident[0].to_upper(), have)
 702 endforeach
 703
 704 found_headers = []
 705 missing_headers = []
 706 foreach tuple: [
 707     ['systemd/sd-bus.h'],
 708     ['systemd/sd-event.h'],
 709     ['sys/resource.h'],
 710     ['sys/memfd.h'],
 711     ['sys/personality.h'],
 712     ['sys/signalfd.h'],
 713     ['sys/timerfd.h'],
 714     ['pty.h'],
 715     ['utmpx.h'],
 716 ]
 717     srcconf.set10('HAVE_' + tuple[0].underscorify().to_upper(), cc.has_header(tuple[0]))
 718
 719     if tuple.length() >= 2
 720         cond = tuple[1]
 721     else
 722         ident1 = 'HAVE_' + tuple[0].underscorify().to_upper()
 723         ident2 = 'ENABLE_' + tuple[0].underscorify().to_upper()
 724         cond = srcconf.get(ident1, 0) == 1 or srcconf.get(ident2, 0) == 1
 725     endif
 726
 727     if cond
 728         found_headers += tuple[0]
 729     else
 730         missing_headers += tuple[0]
 731     endif
 732 endforeach
 733
 734 ## Deps.
 735 found_deps = []
 736 missing_deps = []
 737 foreach tuple: [
 738     ['AppArmor'],
 739     ['SECCOMP'],
 740     ['SELinux'],
 741     ['libcap'],
 742     ['static libcap'],
 743     ['pam'],
 744     ['openssl'],
 745     ['liburing'],
 746     ['libsystemd'],
 747 ]
 748
 749     if tuple.length() >= 2
 750         cond = tuple[1]
 751     else
 752         ident1 = 'HAVE_' + tuple[0].underscorify().to_upper()
 753         ident2 = 'ENABLE_' + tuple[0].underscorify().to_upper()
 754         cond = srcconf.get(ident1, 0) == 1 or srcconf.get(ident2, 0) == 1
 755     endif
 756
 757     if cond
 758         found_deps += tuple[0]
 759     else
 760         missing_deps += tuple[0]
 761     endif
 762 endforeach
 763
 764 # Generate config.h
 765 config_h = configure_file(
 766         output: 'config.h',
 767         configuration: srcconf)
 768
 769 add_project_arguments('-include', 'config.h', language: 'c')
 770
 771 # Binaries.
 772 cmd_programs = []
 773 hook_programs = []
 774 public_programs = []
 775 template_scripts = []
 776 test_programs = []
 777
 778 # Includes.
 779 liblxc_includes = include_directories(
 780     '.',
 781     'src',
 782     'src/include',
 783     'src/lxc',
 784     'src/lxc/cgroups',
 785     'src/lxc/storage')
 786
 787 # Early sub-directories.
 788 subdir('src/include')
 789 subdir('src/lxc')
 790 subdir('src/lxc/pam')
 791
 792 # Library.
 793 liblxc_dependencies = [
 794     threads,
 795 ]
 796
 797 if want_seccomp
 798     liblxc_dependencies += libseccomp
 799 endif
 800
 801 if want_capabilities
 802     liblxc_dependencies += [libcap]
 803 endif
 804
 805 if want_openssl
 806     liblxc_dependencies += [libopenssl]
 807 endif
 808
 809 if want_selinux
 810     liblxc_dependencies += [libselinux]
 811 endif
 812
 813 if want_apparmor
 814     liblxc_dependencies += [libapparmor]
 815 endif
 816
 817 if want_io_uring
 818     liblxc_dependencies += [liburing]
 819 endif
 820
 821 if has_sd_bus
 822     liblxc_dependencies += [libsystemd]
 823 endif
 824
 825 if have_openpty
 826     liblxc_dependencies += [libutil]
 827     if want_oss_fuzz
 828         oss_fuzz_dependencies += [libutil]
 829     endif
 830 endif
 831
 832 liblxc_link_whole = [liblxc_static]
 833
 834 liblxc = shared_library(
 835     'lxc',
 836     version: liblxc_version,
 837     include_directories: liblxc_includes,
 838     link_args: ['-DPIC'],
 839     c_args: ['-DPIC'],
 840     link_whole: liblxc_link_whole,
 841     dependencies: liblxc_dependencies,
 842     install: true)
 843
 844 liblxc_dep = declare_dependency(
 845     link_with: liblxc,
 846     dependencies: liblxc_dependencies)
 847
 848 # Rest of sub-directories.
 849 if want_apparmor
 850     subdir('config/apparmor')
 851     subdir('config/apparmor/abstractions')
 852     subdir('config/apparmor/profiles')
 853 endif
 854 subdir('config/bash')
 855 subdir('config/etc')
 856 subdir('config/init/common')
 857 subdir('config/init/systemd')
 858 subdir('config/init/sysvinit')
 859 subdir('config/init/upstart')
 860 if want_selinux
 861     subdir('config/selinux')
 862 endif
 863 subdir('config/sysconfig')
 864 subdir('config/templates')
 865 subdir('config/templates/common.conf.d')
 866 subdir('config/yum')
 867 subdir('doc')
 868 subdir('doc/ja')
 869 subdir('doc/ko')
 870 subdir('doc/examples')
 871 subdir('doc/rootfs')
 872 subdir('hooks')
 873 if want_commands
 874     subdir('src/lxc/cmd')
 875 endif
 876 if want_tools or want_tools_multicall
 877     subdir('src/lxc/tools')
 878 endif
 879 subdir('src/lxc/tools/include')
 880 subdir('src/tests')
 881 subdir('templates')
 882
 883 # Pkg-config.
 884 pkg_config_file = pkgconfig.generate(liblxc,
 885     description: 'linux container tools',
 886     version: version_data.get('LXC_VERSION'),
 887     url: 'http://linuxcontainers.org',
 888     libraries: '-lutil -lpthread -ldl',
 889     libraries_private: pkgconfig_libs,
 890 )
 891
 892 # Empty dirs.
 893 install_emptydir(join_paths(localstatedir, 'cache', 'lxc'))
 894 install_emptydir(join_paths(localstatedir, 'lib', 'lxc'))
 895
 896 # RPM spec file.
 897 specconf = configuration_data()
 898 specconf.set('LXC_VERSION_BASE', meson.project_version())
 899 specconf.set('LXC_VERSION_BETA', version_data.get('LXC_VERSION_BETA'))
 900 specconf.set('PACKAGE', meson.project_name())
 901 specconf.set('LXC_DISTRO_SYSCONF', conf.get('LXC_DISTRO_SYSCONF'))
 902
 903 configure_file(
 904     configuration: specconf,
 905     input: 'lxc.spec.in',
 906     output: 'lxc.spec',
 907     install: false)
 908
 909 # Build overview.
 910 status = [
 911     '@0@ @1@'.format(meson.project_name(), meson.project_version()),
 912
 913     'Meson version:                     @0@'.format(meson.version()),
 914
 915     'prefix directory:          @0@'.format(prefixdir),
 916     'bin directory:                     @0@'.format(bindir),
 917     'data directory:            @0@'.format(datadir),
 918     'doc directory:                     @0@'.format(docdir),
 919     'include directory:         @0@'.format(includedir),
 920     'lib directory:                     @0@'.format(libdir),
 921     'libexec directory:         @0@'.format(libexecdir),
 922     'local state directory:             @0@'.format(localstatedir),
 923     'sbin directory:            @0@'.format(sbindir),
 924     'sysconf directory:         @0@'.format(sysconfdir),
 925
 926     'lxc cgroup pattern:                @0@'.format(cgrouppattern),
 927     'lxc init directory:                @0@'.format(libexecdir),
 928     'runtime path:                      @0@'.format(runtimepath),
 929
 930     'lxc default config:                @0@'.format(lxcdefaultconfig),
 931     'lxc global config:         @0@'.format(lxcglobalconfig),
 932     'lxc hook directory:                @0@'.format(lxchookdir),
 933     'lxc hook bin directory:    @0@'.format(lxchookbindir),
 934     'lxc rootfs mount directory:        @0@'.format(lxcrootfsmount),
 935     'log path:                  @0@'.format(lxclogpath),
 936     'lxc path:                  @0@'.format(lxcpath),
 937     'lxc template config:               @0@'.format(lxctemplateconfdir),
 938     'lxc template directory:    @0@'.format(lxctemplatedir),
 939     'lxc user network config:   @0@'.format(lxc_user_network_conf),
 940     'lxc user network database: @0@'.format(lxc_user_network_db)]
 941
 942 alt_time_epoch = run_command('date', '-Is', '-u', '-d',
 943                              '@@0@'.format(time_epoch), check: true).stdout().strip()
 944 status += [
 945     'time epoch:                        @0@ (@1@)'.format(time_epoch, alt_time_epoch)]
 946
 947 status += [
 948     '',
 949     'supported dependencies:    @0@'.format(', '.join(found_deps)),
 950     '',
 951     'unsupported dependencies:  @0@'.format(', '.join(missing_deps)),
 952     '']
 953
 954 status += [
 955     '',
 956     'supported headers: @0@'.format(', '.join(found_headers)),
 957     '',
 958     'unsupported headers:       @0@'.format(', '.join(missing_headers)),
 959     '']
 960
 961 status += [
 962     '',
 963     'supported calls:   @0@'.format(', '.join(found_syscalls)),
 964     '',
 965     'unsupported calls: @0@'.format(', '.join(missing_syscalls)),
 966     '']
 967
 968 status += [
 969     '',
 970     'supported types:   @0@'.format(', '.join(found_types)),
 971     '',
 972     'unsupported types: @0@'.format(', '.join(missing_types)),
 973     '']
 974
 975 message('\n     '.join(status))