configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([lxcfs], [3.0.0], [lxc-devel@lists.linuxcontainers.org])
   5 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4")
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AM_INIT_AUTOMAKE([subdir-objects -Wno-portability])
   9
  10 AC_GNU_SOURCE
  11 AC_CONFIG_HEADERS([config.h])
  12 AC_CONFIG_FILES([
  13         Makefile
  14         config/Makefile
  15         config/init/Makefile
  16         config/init/systemd/Makefile
  17         config/init/sysvinit/Makefile
  18         config/init/upstart/Makefile
  19         share/Makefile
  20         share/00-lxcfs.conf
  21         share/lxc.mount.hook
  22         share/lxc.reboot.hook
  23         tests/Makefile ])
  24
  25 LT_INIT
  26 AC_PROG_CC
  27
  28 AC_PROG_CC_C99
  29
  30 AC_CHECK_LIB(pthread, main)
  31
  32 PKG_CHECK_MODULES(FUSE, fuse)
  33
  34 AC_PATH_PROG(HELP2MAN, help2man, false // No help2man //)
  35 AM_CONDITIONAL([HAVE_HELP2MAN], [test "x$HELP2MAN" != "xfalse // No help2man //" ])
  36
  37 AC_ARG_WITH([runtime-path],
  38         [AC_HELP_STRING(
  39                 [--with-runtime-path=dir],
  40                 [runtime directory (default: /run)]
  41         )], [], [with_runtime_path=['/run']])
  42
  43 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
  44 AS_AC_EXPAND(LXCFSSHAREDIR, "$datarootdir/lxcfs")
  45 AS_AC_EXPAND(LXCCONFDIR, "$datarootdir/lxc/config/common.conf.d")
  46 AS_AC_EXPAND(LXCFSTARGETDIR, "$localstatedir/lib/lxcfs")
  47
  48 # Detect the distribution. This is used for the default configuration and
  49 # for some distro-specific build options.
  50 AC_MSG_CHECKING([host distribution])
  51 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, paldo, openmandriva or pardus.]))
  52 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  53         with_distro=`lsb_release -is`
  54 fi
  55 if test "z$with_distro" = "z"; then
  56         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  57         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  58         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  59         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  60         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  61         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  62         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  63         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  64         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  65         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  66         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  67         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  68         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  69         AC_CHECK_FILE(/etc/pld-release,with_distro="pld")
  70 fi
  71 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  72
  73 if test "z$with_distro" = "z"; then
  74         with_distro="unknown"
  75 fi
  76 case $with_distro in
  77         ubuntu)
  78                 distroconf=default.conf.ubuntu
  79                 ;;
  80         redhat|centos|fedora|oracle|oracleserver|pld)
  81                 distroconf=default.conf.libvirt
  82                 ;;
  83         *)
  84                 distroconf=default.conf.unknown
  85                 ;;
  86 esac
  87 AC_MSG_RESULT([$with_distro])
  88 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu"])
  89 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
  90
  91 # Check for init system type
  92 AC_MSG_CHECKING([for init system type])
  93 AC_ARG_WITH([init-script],
  94             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
  95                             [Type(s) of init script to install: bsd, openrc, sysvinit, systemd, upstart,
  96                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
  97 case "$with_init_script" in
  98         distro)
  99                 case $with_distro in
 100                         fedora)
 101                                 init_script=systemd
 102                                 ;;
 103                         redhat|centos|oracle|oracleserver)
 104                                 init_script=sysvinit
 105                                 ;;
 106                         debian)
 107                                 init_script=upstart,systemd,sysvinit
 108                                 ;;
 109                         ubuntu)
 110                                 init_script=upstart,systemd,sysvinit
 111                                 ;;
 112                         pld)
 113                                 init_script=systemd,sysvinit
 114                                 ;;
 115                         slackware)
 116                                 echo -n "Warning: bsd init job not yet implemented"
 117                                 init_script=
 118                                 ;;
 119                         gentoo)
 120                                 echo -n "Warning: openrc init job not yet implemented"
 121                                 init_script=
 122                                 ;;
 123                         *)
 124                                 echo -n "Linux distribution init system unknown."
 125                                 init_script=
 126                                 ;;
 127                 esac
 128                 ;;
 129         *)
 130                 init_script=$with_init_script
 131                 ;;
 132 esac
 133
 134 # Check valid init systems were given, run in subshell so we don't mess up IFS
 135 (IFS="," ; for init_sys in $init_script;
 136 do
 137         case "$init_sys" in
 138                 none|bsd|openrc|sysvinit|systemd|upstart)
 139                         ;;
 140                 *)
 141                         exit 1
 142                         ;;
 143         esac
 144 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 145
 146 AM_CONDITIONAL([INIT_SCRIPT_BSD], [echo "$init_script" |grep -q "bsd"])
 147 AM_CONDITIONAL([INIT_SCRIPT_OPENRC], [echo "$init_script" |grep -q "openrc"])
 148 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 149 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 150 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 151 AC_MSG_RESULT($init_script)
 152
 153 AC_SUBST([lxcfsdir], "${libdir}/lxcfs")
 154
 155 # Rootfs path, where the container mount structure is assembled
 156 AC_ARG_WITH([rootfs-path],
 157         [AC_HELP_STRING(
 158                 [--with-rootfs-path=dir],
 159                 [lxc rootfs mount point]
 160         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 161
 162 AS_AC_EXPAND(LIBDIR, "$libdir")
 163
 164 AC_OUTPUT