acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2019 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl Set OVS DPCLS Autovalidator as default subtable search at compile time?
  18 dnl This enables automatically running all unit tests with all DPCLS
  19 dnl implementations.
  20 AC_DEFUN([OVS_CHECK_DPCLS_AUTOVALIDATOR], [
  21   AC_ARG_ENABLE([autovalidator],
  22                 [AC_HELP_STRING([--enable-autovalidator], [Enable DPCLS autovalidator as default subtable search implementation.])],
  23                 [autovalidator=yes],[autovalidator=no])
  24   AC_MSG_CHECKING([whether DPCLS Autovalidator is default implementation])
  25   if test "$autovalidator" != yes; then
  26     AC_MSG_RESULT([no])
  27   else
  28     OVS_CFLAGS="$OVS_CFLAGS -DDPCLS_AUTOVALIDATOR_DEFAULT"
  29     AC_MSG_RESULT([yes])
  30   fi
  31 ])
  32
  33 dnl OVS_ENABLE_WERROR
  34 AC_DEFUN([OVS_ENABLE_WERROR],
  35   [AC_ARG_ENABLE(
  36      [Werror],
  37      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  38      [], [enable_Werror=no])
  39    AC_CONFIG_COMMANDS_PRE(
  40      [if test "X$enable_Werror" = Xyes; then
  41         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  42       fi])
  43
  44    # Unless --enable-Werror is specified, report but do not fail the build
  45    # for errors reported by flake8.
  46    if test "X$enable_Werror" = Xyes; then
  47      FLAKE8_WERROR=
  48    else
  49      FLAKE8_WERROR=-
  50    fi
  51    AC_SUBST([FLAKE8_WERROR])
  52
  53    # If --enable-Werror is specified, fail the build on sparse warnings.
  54    if test "X$enable_Werror" = Xyes; then
  55      SPARSE_WERROR=-Wsparse-error
  56    else
  57      SPARSE_WERROR=
  58    fi
  59    AC_SUBST([SPARSE_WERROR])])
  60
  61 dnl OVS_CHECK_LINUX
  62 dnl
  63 dnl Configure linux kernel source tree
  64 AC_DEFUN([OVS_CHECK_LINUX], [
  65   AC_ARG_WITH([linux],
  66               [AC_HELP_STRING([--with-linux=/path/to/linux],
  67                               [Specify the Linux kernel build directory])])
  68   AC_ARG_WITH([linux-source],
  69               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  70                               [Specify the Linux kernel source directory
  71                                (usually figured out automatically from build
  72                                directory)])])
  73
  74   # Deprecated equivalents to --with-linux, --with-linux-source.
  75   AC_ARG_WITH([l26])
  76   AC_ARG_WITH([l26-source])
  77
  78   if test X"$with_linux" != X; then
  79     KBUILD=$with_linux
  80   elif test X"$with_l26" != X; then
  81     KBUILD=$with_l26
  82     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  83   else
  84     KBUILD=
  85   fi
  86
  87   if test X"$KBUILD" != X; then
  88     if test X"$with_linux_source" != X; then
  89       KSRC=$with_linux_source
  90     elif test X"$with_l26_source" != X; then
  91       KSRC=$with_l26_source
  92       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  93     else
  94       KSRC=
  95     fi
  96   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  97     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  98   fi
  99
 100   if test -n "$KBUILD"; then
 101     KBUILD=`eval echo "$KBUILD"`
 102     case $KBUILD in
 103         /*) ;;
 104         *) KBUILD=`pwd`/$KBUILD ;;
 105     esac
 106
 107     # The build directory is what the user provided.
 108     # Make sure that it exists.
 109     AC_MSG_CHECKING([for Linux build directory])
 110     if test -d "$KBUILD"; then
 111         AC_MSG_RESULT([$KBUILD])
 112         AC_SUBST(KBUILD)
 113     else
 114         AC_MSG_RESULT([no])
 115         AC_ERROR([source dir $KBUILD doesn't exist])
 116     fi
 117
 118     # Debian breaks kernel headers into "source" header and "build" headers.
 119     # We want the source headers, but $KBUILD gives us the "build" headers.
 120     # Use heuristics to find the source headers.
 121     AC_MSG_CHECKING([for Linux source directory])
 122     if test -n "$KSRC"; then
 123       KSRC=`eval echo "$KSRC"`
 124       case $KSRC in
 125           /*) ;;
 126           *) KSRC=`pwd`/$KSRC ;;
 127       esac
 128       if test ! -e $KSRC/include/linux/kernel.h; then
 129         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 130       fi
 131     else
 132       KSRC=$KBUILD
 133       if test ! -e $KSRC/include/linux/kernel.h; then
 134         # Debian kernel build Makefiles tend to include a line of the form:
 135         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 136         # First try to extract the source directory from this line.
 137         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 138         if test ! -e "$KSRC"/include/linux/kernel.h; then
 139           # Didn't work.  Fall back to name-based heuristics that used to work.
 140           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 141             */build)
 142               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 143               ;; # (
 144             *)
 145               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 146               ;;
 147           esac
 148         fi
 149       fi
 150       if test ! -e "$KSRC"/include/linux/kernel.h; then
 151         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 152       fi
 153     fi
 154     AC_MSG_RESULT([$KSRC])
 155
 156     AC_MSG_CHECKING([for kernel version])
 157     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 158     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 159     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 160     if test X"$version" = X || test X"$patchlevel" = X; then
 161        AC_ERROR([cannot determine kernel version])
 162     elif test X"$sublevel" = X; then
 163        kversion=$version.$patchlevel
 164     else
 165        kversion=$version.$patchlevel.$sublevel
 166     fi
 167     AC_MSG_RESULT([$kversion])
 168
 169     if test "$version" -ge 5; then
 170        if test "$version" = 5 && test "$patchlevel" -le 8; then
 171           : # Linux 5.x
 172        else
 173           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 5.8.x is not supported (please refer to the FAQ for advice)])
 174        fi
 175     elif test "$version" = 4; then
 176        : # Linux 4.x
 177     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 178        : # Linux 3.x
 179     else
 180        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 181     fi
 182     if (test ! -e "$KBUILD"/include/linux/version.h && \
 183         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 184        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 185         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 186         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 187     fi
 188     OVS_CHECK_LINUX_COMPAT
 189   fi
 190   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 191 ])
 192
 193 dnl OVS_CHECK_LINUX_NETLINK
 194 dnl
 195 dnl Configure Linux netlink compat.
 196 AC_DEFUN([OVS_CHECK_LINUX_NETLINK], [
 197   AC_COMPILE_IFELSE([
 198     AC_LANG_PROGRAM([#include <linux/netlink.h>], [
 199         struct nla_bitfield32 x =  { 0 };
 200     ])],
 201     [AC_DEFINE([HAVE_NLA_BITFIELD32], [1],
 202     [Define to 1 if struct nla_bitfield32 is available.])])
 203 ])
 204
 205 dnl OVS_CHECK_LINUX_TC
 206 dnl
 207 dnl Configure Linux tc compat.
 208 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 209   AC_COMPILE_IFELSE([
 210     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 211         int x = TCA_ACT_FLAGS;
 212     ])],
 213     [AC_DEFINE([HAVE_TCA_ACT_FLAGS], [1],
 214                [Define to 1 if TCA_ACT_FLAGS is available.])])
 215
 216   AC_CHECK_MEMBERS([struct tcf_t.firstuse], [], [], [#include <linux/pkt_cls.h>])
 217
 218   AC_COMPILE_IFELSE([
 219     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 220         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 221     ])],
 222     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 223                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 224
 225   AC_COMPILE_IFELSE([
 226     AC_LANG_PROGRAM([#include <linux/tc_act/tc_mpls.h>], [
 227         int x = TCA_MPLS_TTL;
 228     ])],
 229     [AC_DEFINE([HAVE_TCA_MPLS_TTL], [1],
 230                [Define to 1 if HAVE_TCA_MPLS_TTL is available.])])
 231
 232   AC_COMPILE_IFELSE([
 233     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 234         int x = TCA_TUNNEL_KEY_ENC_TTL;
 235     ])],
 236     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 237                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 238
 239   AC_COMPILE_IFELSE([
 240     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 241         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 242     ])],
 243     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 244                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 245
 246   AC_COMPILE_IFELSE([
 247     AC_LANG_PROGRAM([#include <linux/tc_act/tc_skbedit.h>], [
 248         int x = TCA_SKBEDIT_FLAGS;
 249     ])],
 250     [AC_DEFINE([HAVE_TCA_SKBEDIT_FLAGS], [1],
 251                [Define to 1 if TCA_SKBEDIT_FLAGS is available.])])
 252 ])
 253
 254 dnl OVS_CHECK_LINUX_SCTP_CT
 255 dnl
 256 dnl Checks for kernels which need additional SCTP state
 257 AC_DEFUN([OVS_CHECK_LINUX_SCTP_CT], [
 258   AC_COMPILE_IFELSE([
 259     AC_LANG_PROGRAM([#include <linux/netfilter/nfnetlink.h>
 260 #include <linux/netfilter/nfnetlink_conntrack.h>
 261 #include <linux/netfilter/nf_conntrack_common.h>
 262 #include <linux/netfilter/nf_conntrack_sctp.h>], [
 263         int x = SCTP_CONNTRACK_HEARTBEAT_SENT;
 264     ])],
 265     [AC_DEFINE([HAVE_SCTP_CONNTRACK_HEARTBEATS], [1],
 266                [Define to 1 if SCTP_CONNTRACK_HEARTBEAT_SENT is available.])])
 267 ])
 268
 269 dnl OVS_CHECK_LINUX_VIRTIO_TYPES
 270 dnl
 271 dnl Checks for kernels that need virtio_types definition.
 272 AC_DEFUN([OVS_CHECK_LINUX_VIRTIO_TYPES], [
 273   AC_COMPILE_IFELSE([
 274     AC_LANG_PROGRAM([#include <linux/virtio_types.h>], [
 275         __virtio16 x =  0;
 276     ])],
 277     [AC_DEFINE([HAVE_VIRTIO_TYPES], [1],
 278     [Define to 1 if __virtio16 is available.])])
 279 ])
 280
 281 dnl OVS_FIND_DEPENDENCY(FUNCTION, SEARCH_LIBS, NAME_TO_PRINT)
 282 dnl
 283 dnl Check for a function in a library list.
 284 AC_DEFUN([OVS_FIND_DEPENDENCY], [
 285   AC_SEARCH_LIBS([$1], [$2], [], [
 286     AC_MSG_ERROR([unable to find $3, install the dependency package])
 287   ])
 288 ])
 289
 290 dnl OVS_CHECK_LINUX_AF_XDP
 291 dnl
 292 dnl Check both Linux kernel AF_XDP and libbpf support
 293 AC_DEFUN([OVS_CHECK_LINUX_AF_XDP], [
 294   AC_ARG_ENABLE([afxdp],
 295                 [AC_HELP_STRING([--enable-afxdp], [Enable AF-XDP support])],
 296                 [], [enable_afxdp=no])
 297   AC_MSG_CHECKING([whether AF_XDP is enabled])
 298   if test "$enable_afxdp" != yes; then
 299     AC_MSG_RESULT([no])
 300     AF_XDP_ENABLE=false
 301   else
 302     AC_MSG_RESULT([yes])
 303     AF_XDP_ENABLE=true
 304
 305     AC_CHECK_HEADER([bpf/libbpf.h], [],
 306       [AC_MSG_ERROR([unable to find bpf/libbpf.h for AF_XDP support])])
 307
 308     AC_CHECK_HEADER([linux/if_xdp.h], [],
 309       [AC_MSG_ERROR([unable to find linux/if_xdp.h for AF_XDP support])])
 310
 311     AC_CHECK_HEADER([bpf/xsk.h], [],
 312       [AC_MSG_ERROR([unable to find bpf/xsk.h for AF_XDP support])])
 313
 314     AC_CHECK_FUNCS([pthread_spin_lock], [],
 315       [AC_MSG_ERROR([unable to find pthread_spin_lock for AF_XDP support])])
 316
 317     OVS_FIND_DEPENDENCY([numa_alloc_onnode], [numa], [libnuma])
 318
 319     AC_DEFINE([HAVE_AF_XDP], [1],
 320               [Define to 1 if AF_XDP support is available and enabled.])
 321     LIBBPF_LDADD=" -lbpf -lelf"
 322     AC_SUBST([LIBBPF_LDADD])
 323
 324     AC_CHECK_DECL([xsk_ring_prod__needs_wakeup], [
 325       AC_DEFINE([HAVE_XDP_NEED_WAKEUP], [1],
 326         [XDP need wakeup support detected in xsk.h.])
 327     ], [], [[#include <bpf/xsk.h>]])
 328   fi
 329   AM_CONDITIONAL([HAVE_AF_XDP], test "$AF_XDP_ENABLE" = true)
 330 ])
 331
 332 dnl OVS_CHECK_DPDK
 333 dnl
 334 dnl Configure DPDK source tree
 335 AC_DEFUN([OVS_CHECK_DPDK], [
 336   AC_ARG_WITH([dpdk],
 337               [AC_HELP_STRING([--with-dpdk=static|shared|yes],
 338                               [Specify "static" or "shared" depending on the
 339                               DPDK libraries to use])],
 340               [have_dpdk=true])
 341
 342   AC_MSG_CHECKING([whether dpdk is enabled])
 343   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 344     AC_MSG_RESULT([no])
 345     DPDKLIB_FOUND=false
 346   else
 347     AC_MSG_RESULT([yes])
 348     case "$with_dpdk" in
 349       "shared")
 350           PKG_CHECK_MODULES([DPDK], [libdpdk], [
 351               DPDK_INCLUDE="$DPDK_CFLAGS"
 352               DPDK_LIB="$DPDK_LIBS"], [
 353               DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 354               DPDK_LIB="-ldpdk"])
 355               ;;
 356       "static" | "yes")
 357           PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 358               DPDK_INCLUDE="$DPDK_CFLAGS"
 359               DPDK_LIB="$DPDK_LIBS"], [
 360               DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 361               DPDK_LIB="-ldpdk"])
 362
 363           dnl Statically linked private DPDK objects of form
 364           dnl -l:file.a must be positioned between
 365           dnl --whole-archive ... --no-whole-archive linker parameters.
 366           dnl Old pkg-config versions misplace --no-whole-archive parameter
 367           dnl and put it next to --whole-archive.
 368           AC_MSG_CHECKING([for faulty pkg-config version])
 369           echo "$DPDK_LIB" | grep -q 'whole-archive.*l:lib.*no-whole-archive'
 370           status=$?
 371           case $status in
 372             0)
 373               AC_MSG_RESULT([no])
 374               ;;
 375             1)
 376               AC_MSG_RESULT([yes])
 377               AC_MSG_ERROR([Please upgrade pkg-config])
 378               ;;
 379             *)
 380               AC_MSG_ERROR([grep exited with status $status])
 381               ;;
 382           esac
 383     esac
 384
 385     ovs_save_CFLAGS="$CFLAGS"
 386     ovs_save_LDFLAGS="$LDFLAGS"
 387     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 388
 389     AC_CHECK_HEADERS([rte_config.h], [], [
 390       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 391     ], [AC_INCLUDES_DEFAULT])
 392
 393     AC_CHECK_DECLS([RTE_LIBRTE_VHOST_NUMA, RTE_EAL_NUMA_AWARE_HUGEPAGES], [
 394       OVS_FIND_DEPENDENCY([get_mempolicy], [numa], [libnuma])
 395     ], [], [[#include <rte_config.h>]])
 396
 397     AC_CHECK_DECL([RTE_LIBRTE_PMD_PCAP], [
 398       OVS_FIND_DEPENDENCY([pcap_dump_close], [pcap], [libpcap])
 399     ], [], [[#include <rte_config.h>]])
 400
 401     AC_CHECK_DECL([RTE_LIBRTE_PMD_AF_XDP], [
 402       LIBBPF_LDADD="-lbpf"
 403     ], [], [[#include <rte_config.h>]])
 404
 405     AC_CHECK_DECL([RTE_LIBRTE_VHOST_NUMA], [
 406       AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])
 407     ], [], [[#include <rte_config.h>]])
 408
 409     AC_CHECK_DECL([RTE_LIBRTE_MLX5_PMD], [dnl found
 410       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 411         OVS_FIND_DEPENDENCY([mlx5dv_create_wq], [mlx5], [libmlx5])
 412         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 413       ], [[#include <rte_config.h>]])
 414     ], [], [[#include <rte_config.h>]])
 415
 416     AC_CHECK_DECL([RTE_LIBRTE_MLX4_PMD], [dnl found
 417       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 418         OVS_FIND_DEPENDENCY([mlx4dv_init_obj], [mlx4], [libmlx4])
 419         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 420       ], [[#include <rte_config.h>]])
 421     ], [], [[#include <rte_config.h>]])
 422
 423     # DPDK uses dlopen to load plugins.
 424     OVS_FIND_DEPENDENCY([dlopen], [dl], [libdl])
 425
 426     AC_MSG_CHECKING([whether linking with dpdk works])
 427     LIBS="$DPDK_LIB $LIBS"
 428     AC_LINK_IFELSE(
 429       [AC_LANG_PROGRAM([#include <rte_config.h>
 430                         #include <rte_eal.h>],
 431                        [int rte_argc; char ** rte_argv;
 432                         rte_eal_init(rte_argc, rte_argv);])],
 433       [AC_MSG_RESULT([yes])
 434        DPDKLIB_FOUND=true],
 435       [AC_MSG_RESULT([no])
 436        AC_MSG_ERROR(m4_normalize([
 437           Could not find DPDK library in default search path, update
 438           PKG_CONFIG_PATH for pkg-config to find the .pc file in
 439           non-standard location]))
 440       ])
 441
 442     CFLAGS="$ovs_save_CFLAGS"
 443     LDFLAGS="$ovs_save_LDFLAGS"
 444     # Stripping out possible instruction set specific configuration that DPDK
 445     # forces in pkg-config since this could override user-specified options.
 446     # It's enough to have -mssse3 to build with DPDK headers.
 447     DPDK_INCLUDE=$(echo "$DPDK_INCLUDE" | sed 's/-march=[[^ ]]*//g')
 448     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 449     OVS_ENABLE_OPTION([-mssse3])
 450
 451     # DPDK pmd drivers are not linked unless --whole-archive is used.
 452     #
 453     # This happens because the rest of the DPDK code doesn't use any symbol in
 454     # the pmd driver objects, and the drivers register themselves using an
 455     # __attribute__((constructor)) function.
 456     # Wrap the DPDK libraries inside a single -Wl directive
 457     # after comma separation to prevent autotools from reordering them.
 458     DPDK_vswitchd_LDFLAGS=$(echo "$DPDK_LIB"| tr -s ' ' ',' | sed 's/-Wl,//g')
 459     # Replace -pthread with -lpthread for LD and remove the last extra comma.
 460     DPDK_vswitchd_LDFLAGS=$(echo "$DPDK_vswitchd_LDFLAGS"| sed 's/,$//' | \
 461                             sed 's/-pthread/-lpthread/g')
 462     # Prepend "-Wl,".
 463     DPDK_vswitchd_LDFLAGS="-Wl,$DPDK_vswitchd_LDFLAGS"
 464
 465     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 466     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 467   fi
 468
 469   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 470 ])
 471
 472 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 473 dnl
 474 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 475 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 476 dnl <REGEX> translated to uppercase.
 477 AC_DEFUN([OVS_GREP_IFELSE], [
 478   AC_MSG_CHECKING([whether $2 matches in $1])
 479   if test -f $1; then
 480     grep '$2' $1 >/dev/null 2>&1
 481     status=$?
 482     case $status in
 483       0)
 484         AC_MSG_RESULT([yes])
 485         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 486         ;;
 487       1)
 488         AC_MSG_RESULT([no])
 489         $4
 490         ;;
 491       *)
 492         AC_MSG_ERROR([grep exited with status $status])
 493         ;;
 494     esac
 495   else
 496     AC_MSG_RESULT([file not found])
 497     $4
 498   fi
 499 ])
 500
 501 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 502 dnl
 503 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 504 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 505 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 506 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 507 dnl translated to uppercase.
 508 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 509   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 510   if test -f $1; then
 511     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 512     status=$?
 513     case $status in
 514       0)
 515         AC_MSG_RESULT([yes])
 516         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 517         ;;
 518       1)
 519         AC_MSG_RESULT([no])
 520         $5
 521         ;;
 522       *)
 523         AC_MSG_ERROR([grep exited with status $status])
 524         ;;
 525     esac
 526   else
 527     AC_MSG_RESULT([file not found])
 528     $5
 529   fi
 530 ])
 531
 532 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 533 dnl
 534 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 535 dnl the function signature starting from the line matching FUNCTION
 536 dnl and ending with the line containing the closing parenthesis.  If
 537 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 538 dnl IF-MATCH is empty then it defines to
 539 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 540 dnl <REGEX> translated to uppercase.
 541 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 542   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 543   if test -f $1; then
 544     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 545     status=$?
 546     case $status in
 547       0)
 548         AC_MSG_RESULT([yes])
 549         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 550         ;;
 551       1)
 552         AC_MSG_RESULT([no])
 553         $5
 554         ;;
 555       *)
 556         AC_MSG_ERROR([grep exited with status $status])
 557         ;;
 558     esac
 559   else
 560     AC_MSG_RESULT([file not found])
 561     $5
 562   fi
 563 ])
 564
 565 dnl OVS_FIND_OP_PARAM_IFELSE(FILE, OP, REGEX, [IF-MATCH], [IF-NO-MATCH])
 566 dnl
 567 dnl Looks for OP in FILE. If it is found, greps for REGEX within the
 568 dnl OP definition. If this is successful, runs IF-MATCH, otherwise
 569 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 570 dnl OVS_DEFINE(HAVE_<OP>_WITH_<REGEX>), with <OP> and <REGEX>
 571 dnl translated to uppercase.
 572 AC_DEFUN([OVS_FIND_OP_PARAM_IFELSE], [
 573   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 574   if test -f $1; then
 575     awk '/$2[[ \t\n]]*\)\(/,/;/' $1 2>/dev/null | grep '$3' >/dev/null
 576     status=$?
 577     case $status in
 578       0)
 579         AC_MSG_RESULT([yes])
 580         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 581         ;;
 582       1)
 583         AC_MSG_RESULT([no])
 584         $5
 585         ;;
 586       *)
 587         AC_MSG_ERROR([grep exited with status $status])
 588         ;;
 589     esac
 590   else
 591     AC_MSG_RESULT([file not found])
 592     $5
 593   fi
 594 ])
 595
 596 dnl OVS_DEFINE(NAME)
 597 dnl
 598 dnl Defines NAME to 1 in kcompat.h.
 599 AC_DEFUN([OVS_DEFINE], [
 600   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 601 ])
 602
 603 dnl OVS_CHECK_LINUX_COMPAT
 604 dnl
 605 dnl Runs various Autoconf checks on the Linux kernel source in
 606 dnl the directory in $KBUILD.
 607 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 608   rm -f datapath/linux/kcompat.h.new
 609   mkdir -p datapath/linux
 610   : > datapath/linux/kcompat.h.new
 611
 612   echo '#include <linux/version.h>
 613 #ifndef RHEL_RELEASE_CODE
 614 #define RHEL_RELEASE_CODE 0
 615 #define RHEL_RELEASE_VERSION(a, b) 0
 616 #endif' >> datapath/linux/kcompat.h.new
 617
 618   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 619                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 620
 621   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 622                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 623
 624   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub],
 625                         [dst_entry])
 626   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 627                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 628   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup_flow.*net],
 629                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_FLOW_NET])])
 630   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 631   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup_flow])
 632
 633   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 634   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 635   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 636
 637   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 638                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 639   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 640                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 641   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h],
 642                   [DECLARE_STATIC_KEY_FALSE],
 643                   [OVS_DEFINE([HAVE_DECLARE_STATIC_KEY])])
 644
 645   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 646   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 647
 648   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 649   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 650   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 651   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 652   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 653   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_hwaccel_clear_tag])
 654
 655   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 656   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 657   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 658                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 659   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 660                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 661
 662   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 663                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 664   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 665                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 666   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 667                         [ip_do_fragment], [net],
 668                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 669   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 670                         [ip_local_out], [net],
 671                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 672
 673   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 674
 675   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 676                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 677   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 678   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 679                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 680   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 681                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 682   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 683   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 684   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 685                         [frags_work])
 686   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 687                         [rwlock])
 688   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 689                         [list_evictor])
 690   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 691   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 692                         [sub_frag_mem_limit], [struct.netns_frags],
 693                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 694   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 695                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 696   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 697                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 698
 699   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 700   dnl OVS does not really need ipv6 label field, but its presence signifies that
 701   dnl the stack has all required ipv6 support.
 702   dnl OVS also does not need dst_cache But this dependency allows us to write
 703   dnl much cleaner code.
 704
 705   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 706                         [label],
 707                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 708                                          [iptunnel_pull_offloads],
 709                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 710                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 711                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 712
 713   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 714                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 715   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 716                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 717   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 718                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 719   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 720   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 721   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 722   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 723   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 724   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 725   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 726   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 727   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 728   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 729                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 730   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 731   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 732   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 733   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 734   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 735   dnl So check type of tstats.
 736   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 737                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 738   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 739                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 740   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 741   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 742   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 743                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 744   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 745   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 746   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 747                         [extended])
 748   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 749                         [netdev_master_upper_dev_link], [upper_priv],
 750                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 751   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 752                   [netdev_master_upper_dev_link_rh],
 753                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 754
 755   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 756                         [max_mtu])
 757   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 758                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 759   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 760                         [dev_change_flags], [extack],
 761                         [OVS_DEFINE([HAVE_DEV_CHANGE_FLAGS_TAKES_EXTACK])])
 762
 763   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 764   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state],
 765                         [struct net ], [OVS_DEFINE([HAVE_NF_HOOK_STATE_NET])])
 766   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 767   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 768                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 769   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 770                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 771   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 772                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 773   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 774   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [CONFIG_NF_NAT_NEEDED])
 775
 776
 777   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 778                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 779
 780   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 781                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 782                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 783   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 784                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 785
 786   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 787                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 788                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 789   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 790                   [nf_ct_get_tuplepr], [struct.net],
 791                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 792   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 793                   [nf_ct_set])
 794   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 795                   [nf_ct_is_untracked])
 796   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 797                   [nf_ct_invert_tuplepr])
 798   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 799                   [nf_ct_zone_init])
 800   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 801                   [net_ns_get])
 802   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 803                   [nf_connlabels_get])
 804   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 805                   [nf_connlabels_get], [int bit],
 806                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 807   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 808                         [nf_conn_labels], [words])
 809   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 810   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 811   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 812   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_packet],
 813                   [OVS_DEFINE([HAVE_UPSTREAM_NF_NAT])])
 814   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 815   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 816                   [OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h],
 817                                    [int nf_conncount_add],
 818                                    [], [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])])
 819   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [nf_ct_set_timeout])
 820   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [struct nf_ct_timeout],
 821                   [OVS_DEFINE([HAVE_NF_CT_TIMEOUT])])
 822   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h],
 823                         [\(*nf_ct_timeout_find_get_hook\)], [net],
 824                         [OVS_DEFINE([HAVE_NF_CT_TIMEOUT_FIND_GET_HOOK_NET])])
 825
 826   OVS_GREP_IFELSE([$KSRC/include/linux/random.h],
 827                   [prandom_u32[[\(]]],
 828                   [OVS_DEFINE([HAVE_PRANDOM_U32])])
 829   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 830   OVS_GREP_IFELSE([$KSRC/include/linux/prandom.h],
 831                   [prandom_u32[[\(]]],
 832                   [OVS_DEFINE([HAVE_PRANDOM_U32])])
 833   OVS_GREP_IFELSE([$KSRC/include/linux/prandom.h], [prandom_u32_max])
 834
 835   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 836   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 837   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 838                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 839   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 840
 841   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 842                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 843                                    [rcu_read_lock_held])])
 844   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 845   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 846   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
 847                         [rtnl_create_link], [extack],
 848                         [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_TAKES_EXTACK])])
 849   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [nf_reset_ct])
 850
 851   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 852   # is necessary because some versions of this header remove the
 853   # member but retain the kerneldoc comment that describes it (which
 854   # starts with @).  The brackets must be doubled because of m4
 855   # quoting rules.
 856   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 857                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 858   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 859   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 860   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 861   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 862   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 863   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 864   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 865                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 866   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 867                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 868   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 869                   [skb_copy_from_linear_data_offset])
 870   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 871                   [skb_reset_tail_pointer])
 872   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 873   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 874                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 875   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 876   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 877   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 878   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 879   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 880   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 881   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 882   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 883                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 884   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 885   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 886                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 887   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 888   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 889   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 890   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 891   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 892   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 893   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 894   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 895   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 896
 897   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 898                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 899   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 900                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 901
 902   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 903   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 904
 905   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 906   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 907
 908   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 909   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 910   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 911   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 912                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 913   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 914   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 915                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 916   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_validate_flags])
 917   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 918                         [genl_notify], [net],
 919                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 920
 921
 922   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 923                         [genl_multicast_group], [id])
 924   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 925
 926   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 927   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 928   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 929   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 930   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 931   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 932                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 933   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 934                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 935
 936   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 937   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 938   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 939   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 940   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 941   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 942   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 943   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 944   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_nest_start_noflag])
 945   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 946                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 947   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 948                         [nla_parse], [netlink_ext_ack],
 949                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 950
 951   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 952
 953   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 954   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 955   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 956   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 957   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 958
 959   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 960                         [metadata_dst_alloc], [metadata_type])
 961
 962   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 963
 964   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 965                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 966   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 967                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 968                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 969   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 970   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 971   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 972                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 973   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 974                         [gro_receive])
 975
 976   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 977                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 978   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 979                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 980
 981   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 982   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 983   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 984                         [udp_add_offload], [net],
 985                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 986   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 987                         [nf_defrag_ipv6_enable], [net],
 988                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 989   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 990                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 991   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 992                         [needs_free_netdev],
 993                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 994   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 995                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 996   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 997                   [nf_conntrack_helper_put],
 998                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 999   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
1000                   [nf_nat_helper_try_module_get])
1001   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
1002                   [nf_nat_helper_put])
1003   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
1004                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
1005   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
1006                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
1007   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
1008                         [extack],
1009                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
1010   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
1011                         [list],
1012                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
1013   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
1014                   [IP_CT_UNTRACKED])
1015   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
1016                         [netdev_master_upper_dev_link], [extack],
1017                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
1018   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
1019                   [__LINUX_COMPILER_TYPES_H],
1020                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
1021   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
1022                   [ktime_get_ts64],
1023                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
1024   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
1025                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
1026                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
1027   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
1028                   [ktime_get_ns],
1029                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
1030   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
1031                   frag_percpu_counter_batch[],
1032                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
1033   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1034                   [null_compute_pseudo],
1035                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
1036   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1037                   [__skb_checksum_convert],
1038                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
1039   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
1040                         [max_mtu],
1041                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
1042   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
1043                         [erspan_ver],
1044                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
1045   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1046                   [SKB_GSO_IPXIP6],
1047                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
1048   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
1049                         [ip6_make_flowlabel], [fl6],
1050                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
1051   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
1052                         [auto_flowlabels],
1053                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
1054   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
1055                   [netif_keep_dst],
1056                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
1057   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
1058                         [ndo_get_iflink],
1059                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
1060   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1061                   [skb_set_inner_ipproto],
1062                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
1063   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1064                   [tunnel_encap_types],
1065                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
1066   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1067                   [IFLA_IPTUN_ENCAP_TYPE],
1068                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
1069   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1070                   [IFLA_IPTUN_COLLECT_METADATA],
1071                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
1072   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1073                   [IFLA_GRE_ENCAP_DPORT])
1074   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1075                   [IFLA_GRE_COLLECT_METADATA])
1076   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1077                   [IFLA_GRE_IGNORE_DF])
1078   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1079                   [IFLA_GRE_FWMARK])
1080   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1081                   [IFLA_GRE_ERSPAN_INDEX])
1082   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1083                   [IFLA_GRE_ERSPAN_HWID])
1084   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1085                   [IFLA_IPTUN_FWMARK])
1086   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1087                         [csum_valid],
1088                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
1089   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1090                         [vlan_present],
1091                         [OVS_DEFINE([HAVE_SKBUFF_VLAN_PRESENT])])
1092   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1093                   [skb_checksum_simple_validate])
1094   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
1095                   [void.*ndo_get_stats64],
1096                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
1097   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
1098                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
1099   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
1100                         [ip_tunnel_info_opts_set], [flags],
1101                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
1102   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
1103                         [rnd],
1104                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
1105   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [__LINUX_OVERFLOW_H],
1106                   [OVS_DEFINE([HAVE_OVERFLOW_H])])
1107   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [struct_size],
1108                   [OVS_DEFINE([HAVE_STRUCT_SIZE])])
1109   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_array],
1110                   [OVS_DEFINE([HAVE_KVMALLOC_ARRAY])])
1111   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_node],
1112                   [OVS_DEFINE([HAVE_KVMALLOC_NODE])])
1113   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
1114                   [nf_conntrack_l3proto],
1115                   [OVS_DEFINE([HAVE_NF_CONNTRACK_L3PROATO_H])])
1116   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_core.h],
1117                         [nf_conntrack_in], [nf_hook_state],
1118                         [OVS_DEFINE([HAVE_NF_CONNTRACK_IN_TAKES_NF_HOOK_STATE])])
1119   OVS_GREP_IFELSE([$KSRC/include/net/ipv6_frag.h], [IP6_DEFRAG_CONNTRACK_IN],
1120                   [OVS_DEFINE([HAVE_IPV6_FRAG_H])])
1121   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
1122                         [nf_ct_helper_ext_add], [nf_conntrack_helper],
1123                         [OVS_DEFINE([HAVE_NF_CT_HELPER_EXT_ADD_TAKES_HELPER])])
1124   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_calc_hlen],
1125                   [OVS_DEFINE([HAVE_GRE_CALC_HLEN])])
1126   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [ip_gre_calc_hlen],
1127                   [OVS_DEFINE([HAVE_IP_GRE_CALC_HLEN])])
1128   OVS_GREP_IFELSE([$KSRC/include/linux/rbtree.h], [rb_link_node_rcu],
1129                   [OVS_DEFINE([HAVE_RBTREE_RB_LINK_NODE_RCU])])
1130   OVS_GREP_IFELSE([$KSRC/include/net/dst_ops.h], [bool confirm_neigh],
1131                   [OVS_DEFINE([HAVE_DST_OPS_CONFIRM_NEIGH])])
1132   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [fqdir],
1133                   [OVS_DEFINE([HAVE_INET_FRAG_FQDIR])])
1134   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h], [genl_ops],
1135                         [policy],
1136                         [OVS_DEFINE([HAVE_GENL_OPS_POLICY])])
1137   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h],
1138                   [nla_parse_deprecated_strict],
1139                   [OVS_DEFINE([HAVE_NLA_PARSE_DEPRECATED_STRICT])])
1140   OVS_FIND_OP_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
1141                            [validate], [extack],
1142                            [OVS_DEFINE([HAVE_RTNLOP_VALIDATE_WITH_EXTACK])])
1143   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1144                   [__skb_set_hash])
1145   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [sw_hash])
1146   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash_raw])
1147
1148   if cmp -s datapath/linux/kcompat.h.new \
1149             datapath/linux/kcompat.h >/dev/null 2>&1; then
1150     rm datapath/linux/kcompat.h.new
1151   else
1152     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
1153   fi
1154 ])
1155
1156 dnl Checks for net/if_dl.h.
1157 dnl
1158 dnl (We use this as a proxy for checking whether we're building on FreeBSD
1159 dnl or NetBSD.)
1160 AC_DEFUN([OVS_CHECK_IF_DL],
1161   [AC_CHECK_HEADER([net/if_dl.h],
1162                    [HAVE_IF_DL=yes],
1163                    [HAVE_IF_DL=no])
1164    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
1165    if test "$HAVE_IF_DL" = yes; then
1166       AC_DEFINE([HAVE_IF_DL], [1],
1167                 [Define to 1 if net/if_dl.h is available.])
1168
1169       # On these platforms we use libpcap to access network devices.
1170       AC_SEARCH_LIBS([pcap_open_live], [pcap])
1171    fi])
1172
1173 dnl Checks for buggy strtok_r.
1174 dnl
1175 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
1176 dnl with optimization that can cause segfaults:
1177 dnl
1178 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
1179 AC_DEFUN([OVS_CHECK_STRTOK_R],
1180   [AC_CACHE_CHECK(
1181      [whether strtok_r macro segfaults on some inputs],
1182      [ovs_cv_strtok_r_bug],
1183      [AC_RUN_IFELSE(
1184         [AC_LANG_PROGRAM([#include <stdio.h>
1185                           #include <string.h>
1186                          ],
1187                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
1188                            /* Assume bug is present, because relatively minor
1189                               changes in compiler settings (e.g. optimization
1190                               level) can make it crop up. */
1191                            return 1;
1192                            #else
1193                            char string[] = ":::";
1194                            char *save_ptr = (char *) 0xc0ffee;
1195                            char *token1, *token2;
1196                            token1 = strtok_r(string, ":", &save_ptr);
1197                            token2 = strtok_r(NULL, ":", &save_ptr);
1198                            freopen ("/dev/null", "w", stdout);
1199                            printf ("%s %s\n", token1, token2);
1200                            return 0;
1201                            #endif
1202                           ]])],
1203         [ovs_cv_strtok_r_bug=no],
1204         [ovs_cv_strtok_r_bug=yes],
1205         [ovs_cv_strtok_r_bug=yes])])
1206    if test $ovs_cv_strtok_r_bug = yes; then
1207      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1208                [Define if strtok_r macro segfaults on some inputs])
1209    fi
1210 ])
1211
1212 dnl ----------------------------------------------------------------------
1213 dnl These macros are from GNU PSPP, with the following original license:
1214 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1215 dnl This file is free software; the Free Software Foundation
1216 dnl gives unlimited permission to copy and/or distribute it,
1217 dnl with or without modifications, as long as this notice is preserved.
1218
1219 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1220   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1221   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1222     [ovs_save_CFLAGS="$CFLAGS"
1223      dnl Include -Werror in the compiler options, because without -Werror
1224      dnl clang's GCC-compatible compiler driver does not return a failure
1225      dnl exit status even though it complains about options it does not
1226      dnl understand.
1227      dnl
1228      dnl Also, check stderr as gcc exits with status 0 for options
1229      dnl rejected at getopt level.
1230      dnl    % touch /tmp/a.c
1231      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1232      dnl    gcc: unrecognized option '-Qunused-arguments'
1233      dnl    0
1234      dnl    %
1235      dnl
1236      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1237      dnl it does not understand, unless it has another error to report, so
1238      dnl instead of testing for -Wno-<foo>, test for the positive version.
1239      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1240      AC_COMPILE_IFELSE(
1241        [AC_LANG_SOURCE([int x;])],
1242        [if test -s conftest.err && grep "unrecognized option" conftest.err
1243         then
1244           ovs_cv_name[]=no
1245         else
1246           ovs_cv_name[]=yes
1247         fi],
1248        [ovs_cv_name[]=no])
1249      CFLAGS="$ovs_save_CFLAGS"])
1250   if test $ovs_cv_name = yes; then
1251     m4_if([$2], [], [:], [$2])
1252   else
1253     m4_if([$3], [], [:], [$3])
1254   fi
1255 ])
1256
1257 dnl OVS_CHECK_WERROR
1258 dnl
1259 dnl Check whether the C compiler accepts -Werror.
1260 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1261 AC_DEFUN([OVS_CHECK_WERROR],
1262   [WERROR=
1263    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1264
1265 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1266 dnl Check whether the given C compiler OPTION is accepted.
1267 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1268 AC_DEFUN([OVS_CHECK_CC_OPTION],
1269   [AC_REQUIRE([OVS_CHECK_WERROR])
1270    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1271
1272 dnl OVS_ENABLE_OPTION([OPTION])
1273 dnl Check whether the given C compiler OPTION is accepted.
1274 dnl If so, add it to WARNING_FLAGS.
1275 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1276 AC_DEFUN([OVS_ENABLE_OPTION],
1277   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1278    AC_SUBST([WARNING_FLAGS])])
1279
1280 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1281 dnl Check whether the given C compiler OPTION is accepted.
1282 dnl If so, enable the given Automake CONDITIONAL.
1283
1284 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1285 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1286   [OVS_CHECK_CC_OPTION(
1287     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1288    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1289 dnl ----------------------------------------------------------------------
1290
1291 dnl Check for too-old XenServer.
1292 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1293   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1294     [if test -e /etc/redhat-release; then
1295        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1296      fi
1297      if test -z "$ovs_cv_xsversion"; then
1298        ovs_cv_xsversion=none
1299      fi])
1300   case $ovs_cv_xsversion in
1301     none)
1302       ;;
1303
1304     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1305     [[6-9]]* |                           dnl XenServer 6 or later
1306     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1307     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1308     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1309     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1310       ;;
1311
1312     *)
1313       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1314       ;;
1315   esac])
1316
1317 dnl OVS_CHECK_SPARSE_TARGET
1318 dnl
1319 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1320 dnl target for which the code is being built.  This helps it out.
1321 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1322   [AC_CACHE_CHECK(
1323     [target hint for cgcc],
1324     [ac_cv_sparse_target],
1325     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1326        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1327        [x86_64-*], [ac_cv_sparse_target=x86_64],
1328        [ac_cv_sparse_target=other])])
1329    AS_CASE([$ac_cv_sparse_target],
1330      [x86], [SPARSEFLAGS= CGCCFLAGS="-target=i86 -target=host_os_specs"],
1331      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS="-target=x86_64 -target=host_os_specs"],
1332      [SPARSEFLAGS= CGCCFLAGS=])
1333
1334    dnl Get the default defines for vector instructions from compiler to
1335    dnl allow "sparse" correctly check the same code that will be built.
1336    dnl Required for checking DPDK headers.
1337    AC_MSG_CHECKING([vector options for cgcc])
1338    VECTOR=$($CC -dM -E - < /dev/null | grep -E "MMX|SSE|AVX" | \
1339             cut -c 9- | sed 's/ /=/' | sed 's/^/-D/' | tr '\n' ' ')
1340    AC_MSG_RESULT([$VECTOR])
1341    CGCCFLAGS="$CGCCFLAGS $VECTOR"
1342
1343    AC_SUBST([SPARSEFLAGS])
1344    AC_SUBST([CGCCFLAGS])])
1345
1346 dnl OVS_SPARSE_EXTRA_INCLUDES
1347 dnl
1348 dnl The cgcc script from "sparse" does not search gcc's default
1349 dnl search path. Get the default search path from GCC and pass
1350 dnl them to sparse.
1351 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1352     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1353            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1354
1355 dnl OVS_ENABLE_SPARSE
1356 AC_DEFUN([OVS_ENABLE_SPARSE],
1357   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1358    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1359    : ${SPARSE=sparse}
1360    AC_SUBST([SPARSE])
1361    AC_CONFIG_COMMANDS_PRE(
1362      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1363
1364    AC_ARG_ENABLE(
1365      [sparse],
1366      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1367      [], [enable_sparse=no])
1368    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1369
1370 dnl OVS_CTAGS_IDENTIFIERS
1371 dnl
1372 dnl ctags ignores symbols with extras identifiers. This is a list of
1373 dnl specially handled identifiers to be ignored. [ctags(1) -I <list>].
1374 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1375     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1376            ["OVS_LOCKABLE OVS_NO_THREAD_SAFETY_ANALYSIS OVS_REQ_RDLOCK+ OVS_ACQ_RDLOCK+ OVS_REQ_WRLOCK+ OVS_ACQ_WRLOCK+ OVS_REQUIRES+ OVS_ACQUIRES+ OVS_TRY_WRLOCK+ OVS_TRY_RDLOCK+ OVS_TRY_LOCK+ OVS_GUARDED_BY+ OVS_EXCLUDED+ OVS_RELEASES+ OVS_ACQ_BEFORE+ OVS_ACQ_AFTER+"]))
1377
1378 dnl OVS_PTHREAD_SET_NAME
1379 dnl
1380 dnl This checks for three known variants of pthreads functions for setting
1381 dnl the name of the current thread:
1382 dnl
1383 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1384 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1385 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1386 dnl
1387 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1388 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1389 dnl provide to it.
1390 dnl
1391 dnl This macro defines:
1392 dnl
1393 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1394 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1395 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1396 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1397   [AC_CHECK_FUNCS([pthread_set_name_np])
1398    if test $ac_cv_func_pthread_set_name_np != yes; then
1399      AC_CACHE_CHECK(
1400        [for pthread_setname_np() variant],
1401        [ovs_cv_pthread_setname_np],
1402        [AC_LINK_IFELSE(
1403          [AC_LANG_PROGRAM([#include <pthread.h>
1404   ], [pthread_setname_np(pthread_self(), "name");])],
1405          [ovs_cv_pthread_setname_np=glibc],
1406          [AC_LINK_IFELSE(
1407            [AC_LANG_PROGRAM([#include <pthread.h>
1408 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1409            [ovs_cv_pthread_setname_np=netbsd],
1410            [ovs_cv_pthread_setname_np=none])])])
1411      case $ovs_cv_pthread_setname_np in # (
1412        glibc)
1413           AC_DEFINE(
1414             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1415             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1416           ;; # (
1417        netbsd)
1418           AC_DEFINE(
1419             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1420             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1421           ;;
1422      esac
1423    fi])
1424
1425 dnl OVS_CHECK_LINUX_HOST.
1426 dnl
1427 dnl Checks whether we're building for a Linux host, based on the presence of
1428 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1429 dnl LINUX based on the result.
1430 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1431   [AC_CACHE_CHECK(
1432      [whether __linux__ is defined],
1433      [ovs_cv_linux],
1434      [AC_COMPILE_IFELSE(
1435         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1436         [ovs_cv_linux=true],
1437         [ovs_cv_linux=false])])
1438    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])