acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2019 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 5; then
 154        if test "$version" = 5 && test "$patchlevel" -le 0; then
 155           : # Linux 5.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 5.0.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 4; then
 160        : # Linux 4.x
 161     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 162        : # Linux 3.x
 163     else
 164        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 165     fi
 166     if (test ! -e "$KBUILD"/include/linux/version.h && \
 167         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 168        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 169         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 170         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 171     fi
 172     OVS_CHECK_LINUX_COMPAT
 173   fi
 174   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 175 ])
 176
 177 dnl OVS_CHECK_LINUX_TC
 178 dnl
 179 dnl Configure Linux tc compat.
 180 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 181   AC_COMPILE_IFELSE([
 182     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 183         int x = TCA_FLOWER_KEY_ENC_IP_TTL_MASK;
 184     ])],
 185     [AC_DEFINE([HAVE_TCA_FLOWER_KEY_ENC_IP_TTL_MASK], [1],
 186                [Define to 1 if TCA_FLOWER_KEY_ENC_IP_TTL_MASK is available.])])
 187
 188   AC_COMPILE_IFELSE([
 189     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 190         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 191     ])],
 192     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 193                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 194
 195   AC_COMPILE_IFELSE([
 196     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 197         int x = TCA_TUNNEL_KEY_ENC_TTL;
 198     ])],
 199     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 200                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 201
 202   AC_COMPILE_IFELSE([
 203     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 204         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 205     ])],
 206     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 207                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 208
 209   AC_COMPILE_IFELSE([
 210     AC_LANG_PROGRAM([#include <linux/tc_act/tc_skbedit.h>], [
 211         int x = TCA_SKBEDIT_FLAGS;
 212     ])],
 213     [AC_DEFINE([HAVE_TCA_SKBEDIT_FLAGS], [1],
 214                [Define to 1 if TCA_SKBEDIT_FLAGS is available.])])
 215 ])
 216
 217 dnl OVS_CHECK_LINUX_SCTP_CT
 218 dnl
 219 dnl Checks for kernels which need additional SCTP state
 220 AC_DEFUN([OVS_CHECK_LINUX_SCTP_CT], [
 221   AC_COMPILE_IFELSE([
 222     AC_LANG_PROGRAM([#include <linux/netfilter/nfnetlink.h>
 223 #include <linux/netfilter/nfnetlink_conntrack.h>
 224 #include <linux/netfilter/nf_conntrack_common.h>
 225 #include <linux/netfilter/nf_conntrack_sctp.h>], [
 226         int x = SCTP_CONNTRACK_HEARTBEAT_SENT;
 227     ])],
 228     [AC_DEFINE([HAVE_SCTP_CONNTRACK_HEARTBEATS], [1],
 229                [Define to 1 if SCTP_CONNTRACK_HEARTBEAT_SENT is available.])])
 230 ])
 231
 232 dnl OVS_FIND_DEPENDENCY(FUNCTION, SEARCH_LIBS, NAME_TO_PRINT)
 233 dnl
 234 dnl Check for a function in a library list.
 235 AC_DEFUN([OVS_FIND_DEPENDENCY], [
 236   AC_SEARCH_LIBS([$1], [$2], [], [
 237     AC_MSG_ERROR([unable to find $3, install the dependency package])
 238   ])
 239 ])
 240
 241 dnl OVS_CHECK_DPDK
 242 dnl
 243 dnl Configure DPDK source tree
 244 AC_DEFUN([OVS_CHECK_DPDK], [
 245   AC_ARG_WITH([dpdk],
 246               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 247                               [Specify the DPDK build directory])],
 248               [have_dpdk=true])
 249
 250   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 251   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 252     AC_MSG_RESULT([no])
 253     DPDKLIB_FOUND=false
 254   else
 255     AC_MSG_RESULT([yes])
 256     case "$with_dpdk" in
 257       yes)
 258         DPDK_AUTO_DISCOVER="true"
 259         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 260             DPDK_INCLUDE="$DPDK_CFLAGS"
 261             DPDK_LIB="$DPDK_LIBS"], [
 262             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 263             DPDK_LIB="-ldpdk"])
 264         ;;
 265       *)
 266         DPDK_AUTO_DISCOVER="false"
 267         DPDK_INCLUDE_PATH="$with_dpdk/include"
 268         # If 'with_dpdk' is passed install directory, point to headers
 269         # installed in $DESTDIR/$prefix/include/dpdk
 270         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 271            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 272         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 273            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 274         fi
 275         DPDK_LIB_DIR="$with_dpdk/lib"
 276         DPDK_LIB="-ldpdk"
 277         ;;
 278     esac
 279
 280     ovs_save_CFLAGS="$CFLAGS"
 281     ovs_save_LDFLAGS="$LDFLAGS"
 282     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 283     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 284       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 285     fi
 286
 287     AC_CHECK_HEADERS([rte_config.h], [], [
 288       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 289     ], [AC_INCLUDES_DEFAULT])
 290
 291     AC_CHECK_DECLS([RTE_LIBRTE_VHOST_NUMA, RTE_EAL_NUMA_AWARE_HUGEPAGES], [
 292       OVS_FIND_DEPENDENCY([get_mempolicy], [numa], [libnuma])
 293     ], [], [[#include <rte_config.h>]])
 294
 295     AC_CHECK_DECL([RTE_LIBRTE_VHOST_NUMA], [
 296       AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])
 297     ], [], [[#include <rte_config.h>]])
 298
 299     AC_CHECK_DECL([RTE_LIBRTE_PMD_PCAP], [
 300       OVS_FIND_DEPENDENCY([pcap_dump], [pcap], [libpcap])
 301       AC_CHECK_DECL([RTE_LIBRTE_PDUMP], [
 302         AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])
 303       ], [], [[#include <rte_config.h>]])
 304     ], [], [[#include <rte_config.h>]])
 305
 306     AC_CHECK_DECL([RTE_LIBRTE_MLX5_PMD], [dnl found
 307       OVS_FIND_DEPENDENCY([mnl_attr_put], [mnl], [libmnl])
 308       AC_CHECK_DECL([RTE_LIBRTE_MLX5_DLOPEN_DEPS], [], [dnl not found
 309         OVS_FIND_DEPENDENCY([mlx5dv_create_wq], [mlx5], [libmlx5])
 310         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 311       ], [[#include <rte_config.h>]])
 312     ], [], [[#include <rte_config.h>]])
 313
 314     AC_CHECK_DECL([RTE_LIBRTE_MLX4_PMD], [dnl found
 315       AC_CHECK_DECL([RTE_LIBRTE_MLX4_DLOPEN_DEPS], [], [dnl not found
 316         OVS_FIND_DEPENDENCY([mlx4dv_init_obj], [mlx4], [libmlx4])
 317         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 318       ], [[#include <rte_config.h>]])
 319     ], [], [[#include <rte_config.h>]])
 320
 321     # DPDK uses dlopen to load plugins.
 322     OVS_FIND_DEPENDENCY([dlopen], [dl], [libdl])
 323
 324     AC_MSG_CHECKING([whether linking with dpdk works])
 325     LIBS="$DPDK_LIB $LIBS"
 326     AC_LINK_IFELSE(
 327       [AC_LANG_PROGRAM([#include <rte_config.h>
 328                         #include <rte_eal.h>],
 329                        [int rte_argc; char ** rte_argv;
 330                         rte_eal_init(rte_argc, rte_argv);])],
 331       [AC_MSG_RESULT([yes])
 332        DPDKLIB_FOUND=true],
 333       [AC_MSG_RESULT([no])
 334        if test "$DPDK_AUTO_DISCOVER" = "true"; then
 335          AC_MSG_ERROR(m4_normalize([
 336             Could not find DPDK library in default search path, Use --with-dpdk
 337             to specify the DPDK library installed in non-standard location]))
 338        else
 339          AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 340        fi
 341       ])
 342
 343     CFLAGS="$ovs_save_CFLAGS"
 344     LDFLAGS="$ovs_save_LDFLAGS"
 345     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 346       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 347     fi
 348     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 349     OVS_ENABLE_OPTION([-mssse3])
 350
 351     # DPDK pmd drivers are not linked unless --whole-archive is used.
 352     #
 353     # This happens because the rest of the DPDK code doesn't use any symbol in
 354     # the pmd driver objects, and the drivers register themselves using an
 355     # __attribute__((constructor)) function.
 356     #
 357     # These options are specified inside a single -Wl directive to prevent
 358     # autotools from reordering them.
 359     #
 360     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 361     # will already have flagged just the right set of libs with
 362     # --whole-archive - in those cases do not wrap it once more.
 363     case "$DPDK_LIB" in
 364       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 365       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 366     esac
 367     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 368     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 369   fi
 370
 371   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 372 ])
 373
 374 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 375 dnl
 376 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 377 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 378 dnl <REGEX> translated to uppercase.
 379 AC_DEFUN([OVS_GREP_IFELSE], [
 380   AC_MSG_CHECKING([whether $2 matches in $1])
 381   if test -f $1; then
 382     grep '$2' $1 >/dev/null 2>&1
 383     status=$?
 384     case $status in
 385       0)
 386         AC_MSG_RESULT([yes])
 387         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 388         ;;
 389       1)
 390         AC_MSG_RESULT([no])
 391         $4
 392         ;;
 393       *)
 394         AC_MSG_ERROR([grep exited with status $status])
 395         ;;
 396     esac
 397   else
 398     AC_MSG_RESULT([file not found])
 399     $4
 400   fi
 401 ])
 402
 403 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 404 dnl
 405 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 406 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 407 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 408 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 409 dnl translated to uppercase.
 410 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 411   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 412   if test -f $1; then
 413     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 414     status=$?
 415     case $status in
 416       0)
 417         AC_MSG_RESULT([yes])
 418         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 419         ;;
 420       1)
 421         AC_MSG_RESULT([no])
 422         $5
 423         ;;
 424       *)
 425         AC_MSG_ERROR([grep exited with status $status])
 426         ;;
 427     esac
 428   else
 429     AC_MSG_RESULT([file not found])
 430     $5
 431   fi
 432 ])
 433
 434 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 435 dnl
 436 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 437 dnl the function signature starting from the line matching FUNCTION
 438 dnl and ending with the line containing the closing parenthesis.  If
 439 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 440 dnl IF-MATCH is empty then it defines to
 441 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 442 dnl <REGEX> translated to uppercase.
 443 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 444   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 445   if test -f $1; then
 446     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 447     status=$?
 448     case $status in
 449       0)
 450         AC_MSG_RESULT([yes])
 451         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 452         ;;
 453       1)
 454         AC_MSG_RESULT([no])
 455         $5
 456         ;;
 457       *)
 458         AC_MSG_ERROR([grep exited with status $status])
 459         ;;
 460     esac
 461   else
 462     AC_MSG_RESULT([file not found])
 463     $5
 464   fi
 465 ])
 466
 467 dnl OVS_DEFINE(NAME)
 468 dnl
 469 dnl Defines NAME to 1 in kcompat.h.
 470 AC_DEFUN([OVS_DEFINE], [
 471   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 472 ])
 473
 474 dnl OVS_CHECK_LINUX_COMPAT
 475 dnl
 476 dnl Runs various Autoconf checks on the Linux kernel source in
 477 dnl the directory in $KBUILD.
 478 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 479   rm -f datapath/linux/kcompat.h.new
 480   mkdir -p datapath/linux
 481   : > datapath/linux/kcompat.h.new
 482
 483   echo '#include <linux/version.h>
 484 #ifndef RHEL_RELEASE_CODE
 485 #define RHEL_RELEASE_CODE 0
 486 #define RHEL_RELEASE_VERSION(a, b) 0
 487 #endif' >> datapath/linux/kcompat.h.new
 488
 489   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 490                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 491
 492   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 493                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 494
 495   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 496                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 497   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 498
 499   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 500   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 501   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 502
 503   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 504                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 505   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 506                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 507
 508   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 509   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 510
 511   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 512   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 513   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 514   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 515   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 516   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_hwaccel_clear_tag])
 517
 518   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 519   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 520   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 521                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 522   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 523                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 524
 525   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 526                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 527   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 528                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 529   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 530                         [ip_do_fragment], [net],
 531                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 532   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 533                         [ip_local_out], [net],
 534                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 535
 536   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 537
 538   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 539                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 540   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 541   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 542                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 543   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 544                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 545   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 546   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 547   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 548                         [frags_work])
 549   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 550                         [rwlock])
 551   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 552                         [list_evictor])
 553   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 554   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 555                         [sub_frag_mem_limit], [struct.netns_frags],
 556                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 557   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 558                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 559   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 560                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 561
 562   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 563   dnl OVS does not really need ipv6 label field, but its presence signifies that
 564   dnl the stack has all required ipv6 support.
 565   dnl OVS also does not need dst_cache But this dependency allows us to write
 566   dnl much cleaner code.
 567
 568   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 569                         [label],
 570                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 571                                          [iptunnel_pull_offloads],
 572                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 573                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 574                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 575
 576   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 577                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 578   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 579                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 580   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 581                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 582   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 583   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 584   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 585   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 586   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 587   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 588   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 589   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 590   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 591   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 592                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 593   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 594   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 595   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 596   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 597   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 598   dnl So check type of tstats.
 599   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 600                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 601   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 602                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 603   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 604   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 605   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 606                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 607   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 608   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 609   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 610                         [extended])
 611   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 612                         [netdev_master_upper_dev_link], [upper_priv],
 613                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 614   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 615                   [netdev_master_upper_dev_link_rh],
 616                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 617
 618   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 619                         [max_mtu])
 620   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 621                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 622   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 623                         [dev_change_flags], [extack],
 624                         [OVS_DEFINE([HAVE_DEV_CHANGE_FLAGS_TAKES_EXTACK])])
 625
 626   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 627   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state],
 628                         [struct net ], [OVS_DEFINE([HAVE_NF_HOOK_STATE_NET])])
 629   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 630   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 631                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 632   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 633                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 634   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 635                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 636   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 637
 638
 639   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 640                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 641
 642   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 643                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 644                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 645   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 646                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 647
 648   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 649                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 650                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 651   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 652                   [nf_ct_get_tuplepr], [struct.net],
 653                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 654   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 655                   [nf_ct_set])
 656   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 657                   [nf_ct_is_untracked])
 658   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 659                   [nf_ct_zone_init])
 660   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 661                   [net_ns_get])
 662   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 663                   [nf_connlabels_get])
 664   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 665                   [nf_connlabels_get], [int bit],
 666                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 667   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 668                         [nf_conn_labels], [words])
 669   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 670   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 671   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 672   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 673   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 674                   [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])
 675
 676   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 677   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 678
 679   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 680   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 681   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 682                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 683   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 684
 685   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 686                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 687                                    [rcu_read_lock_held])])
 688   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 689   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 690   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
 691                         [rtnl_create_link], [extack],
 692                         [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_TAKES_EXTACK])])
 693
 694   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 695   # is necessary because some versions of this header remove the
 696   # member but retain the kerneldoc comment that describes it (which
 697   # starts with @).  The brackets must be doubled because of m4
 698   # quoting rules.
 699   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 700                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 701   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 702   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 703   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 704   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 705   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 706   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 707   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 708                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 709   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 710                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 711   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 712                   [skb_copy_from_linear_data_offset])
 713   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 714                   [skb_reset_tail_pointer])
 715   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 716   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 717                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 718   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 719   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 720   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 721   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 722   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 723   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 724   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 725   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 726                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 727   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 728   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 729                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 730   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 731                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 732   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 733   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 734   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 735   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 736   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 737   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 738   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 739   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 740   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 741
 742   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 743                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 744   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 745                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 746   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 747                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 748
 749   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 750   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 751
 752   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 753   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 754
 755   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 756   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 757   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 758   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 759                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 760   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 761   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 762                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 763   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 764                         [genl_notify], [net],
 765                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 766
 767
 768   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 769                         [genl_multicast_group], [id])
 770   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 771
 772   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 773   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 774   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 775   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 776   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 777   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 778                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 779   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 780                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 781
 782   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 783   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 784   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 785   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 786   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 787   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 788   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 789   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 790   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 791                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 792   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 793                         [nla_parse], [netlink_ext_ack],
 794                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 795
 796   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 797
 798   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 799                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 800   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 801   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 802   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 803   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 804   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 805
 806   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 807                         [metadata_dst_alloc], [metadata_type])
 808
 809   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 810
 811   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 812                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 813   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 814                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 815                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 816   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 817   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 818   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 819                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 820   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 821                         [gro_receive])
 822
 823   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 824                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 825   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 826                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 827
 828   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 829   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 830   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 831                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 832   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 833                         [udp_add_offload], [net],
 834                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 835   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 836                         [nf_defrag_ipv6_enable], [net],
 837                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 838   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 839                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 840   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 841                         [needs_free_netdev],
 842                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 843   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 844                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 845   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 846                   [nf_conntrack_helper_put],
 847                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 848   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 849                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 850   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 851                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 852   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 853                         [extack],
 854                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 855   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 856                         [list],
 857                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 858   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 859                   [IP_CT_UNTRACKED])
 860   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 861                         [netdev_master_upper_dev_link], [extack],
 862                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 863   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 864                   [__LINUX_COMPILER_TYPES_H],
 865                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 866   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 867                   [ktime_get_ts64],
 868                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 869   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 870                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 871                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 872   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 873                   [ktime_get_ns],
 874                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 875   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 876                   frag_percpu_counter_batch[],
 877                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 878   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 879                   [null_compute_pseudo],
 880                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 881   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 882                   [__skb_checksum_convert],
 883                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
 884   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 885                         [max_mtu],
 886                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
 887   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
 888                         [erspan_ver],
 889                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
 890   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 891                   [SKB_GSO_IPXIP6],
 892                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
 893   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
 894                         [ip6_make_flowlabel], [fl6],
 895                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
 896   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
 897                         [auto_flowlabels],
 898                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
 899   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 900                   [netif_keep_dst],
 901                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
 902   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 903                         [ndo_get_iflink],
 904                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
 905   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 906                   [skb_set_inner_ipproto],
 907                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
 908   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 909                   [tunnel_encap_types],
 910                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
 911   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 912                   [IFLA_IPTUN_ENCAP_TYPE],
 913                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
 914   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 915                   [IFLA_IPTUN_COLLECT_METADATA],
 916                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
 917   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 918                   [IFLA_GRE_ENCAP_DPORT])
 919   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 920                   [IFLA_GRE_COLLECT_METADATA])
 921   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 922                   [IFLA_GRE_IGNORE_DF])
 923   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 924                   [IFLA_GRE_FWMARK])
 925   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 926                   [IFLA_GRE_ERSPAN_INDEX])
 927   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 928                   [IFLA_GRE_ERSPAN_HWID])
 929   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 930                   [IFLA_IPTUN_FWMARK])
 931   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
 932                         [csum_valid],
 933                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
 934   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
 935                         [vlan_present],
 936                         [OVS_DEFINE([HAVE_SKBUFF_VLAN_PRESENT])])
 937   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 938                   [skb_checksum_simple_validate])
 939   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 940                   [void.*ndo_get_stats64],
 941                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
 942   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
 943                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
 944   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
 945                         [ip_tunnel_info_opts_set], [flags],
 946                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
 947   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 948                         [rnd],
 949                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
 950   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [__LINUX_OVERFLOW_H],
 951                   [OVS_DEFINE([HAVE_OVERFLOW_H])])
 952   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [struct_size],
 953                   [OVS_DEFINE([HAVE_STRUCT_SIZE])])
 954   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_array],
 955                   [OVS_DEFINE([HAVE_KVMALLOC_ARRAY])])
 956   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_node],
 957                   [OVS_DEFINE([HAVE_KVMALLOC_NODE])])
 958   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 959                   [nf_conntrack_l3proto],
 960                   [OVS_DEFINE([HAVE_NF_CONNTRACK_L3PROATO_H])])
 961   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_core.h],
 962                         [nf_conntrack_in], [nf_hook_state],
 963                         [OVS_DEFINE([HAVE_NF_CONNTRACK_IN_TAKES_NF_HOOK_STATE])])
 964   OVS_GREP_IFELSE([$KSRC/include/net/ipv6_frag.h], [IP6_DEFRAG_CONNTRACK_IN],
 965                   [OVS_DEFINE([HAVE_IPV6_FRAG_H])])
 966   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 967                         [nf_ct_helper_ext_add], [nf_conntrack_helper],
 968                         [OVS_DEFINE([HAVE_NF_CT_HELPER_EXT_ADD_TAKES_HELPER])])
 969
 970   if cmp -s datapath/linux/kcompat.h.new \
 971             datapath/linux/kcompat.h >/dev/null 2>&1; then
 972     rm datapath/linux/kcompat.h.new
 973   else
 974     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 975   fi
 976 ])
 977
 978 dnl Checks for net/if_dl.h.
 979 dnl
 980 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 981 dnl or NetBSD.)
 982 AC_DEFUN([OVS_CHECK_IF_DL],
 983   [AC_CHECK_HEADER([net/if_dl.h],
 984                    [HAVE_IF_DL=yes],
 985                    [HAVE_IF_DL=no])
 986    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 987    if test "$HAVE_IF_DL" = yes; then
 988       AC_DEFINE([HAVE_IF_DL], [1],
 989                 [Define to 1 if net/if_dl.h is available.])
 990
 991       # On these platforms we use libpcap to access network devices.
 992       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 993    fi])
 994
 995 dnl Checks for buggy strtok_r.
 996 dnl
 997 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 998 dnl with optimization that can cause segfaults:
 999 dnl
1000 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
1001 AC_DEFUN([OVS_CHECK_STRTOK_R],
1002   [AC_CACHE_CHECK(
1003      [whether strtok_r macro segfaults on some inputs],
1004      [ovs_cv_strtok_r_bug],
1005      [AC_RUN_IFELSE(
1006         [AC_LANG_PROGRAM([#include <stdio.h>
1007                           #include <string.h>
1008                          ],
1009                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
1010                            /* Assume bug is present, because relatively minor
1011                               changes in compiler settings (e.g. optimization
1012                               level) can make it crop up. */
1013                            return 1;
1014                            #else
1015                            char string[] = ":::";
1016                            char *save_ptr = (char *) 0xc0ffee;
1017                            char *token1, *token2;
1018                            token1 = strtok_r(string, ":", &save_ptr);
1019                            token2 = strtok_r(NULL, ":", &save_ptr);
1020                            freopen ("/dev/null", "w", stdout);
1021                            printf ("%s %s\n", token1, token2);
1022                            return 0;
1023                            #endif
1024                           ]])],
1025         [ovs_cv_strtok_r_bug=no],
1026         [ovs_cv_strtok_r_bug=yes],
1027         [ovs_cv_strtok_r_bug=yes])])
1028    if test $ovs_cv_strtok_r_bug = yes; then
1029      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1030                [Define if strtok_r macro segfaults on some inputs])
1031    fi
1032 ])
1033
1034 dnl ----------------------------------------------------------------------
1035 dnl These macros are from GNU PSPP, with the following original license:
1036 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1037 dnl This file is free software; the Free Software Foundation
1038 dnl gives unlimited permission to copy and/or distribute it,
1039 dnl with or without modifications, as long as this notice is preserved.
1040
1041 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1042   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1043   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1044     [ovs_save_CFLAGS="$CFLAGS"
1045      dnl Include -Werror in the compiler options, because without -Werror
1046      dnl clang's GCC-compatible compiler driver does not return a failure
1047      dnl exit status even though it complains about options it does not
1048      dnl understand.
1049      dnl
1050      dnl Also, check stderr as gcc exits with status 0 for options
1051      dnl rejected at getopt level.
1052      dnl    % touch /tmp/a.c
1053      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1054      dnl    gcc: unrecognized option '-Qunused-arguments'
1055      dnl    0
1056      dnl    %
1057      dnl
1058      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1059      dnl it does not understand, unless it has another error to report, so
1060      dnl instead of testing for -Wno-<foo>, test for the positive version.
1061      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1062      AC_COMPILE_IFELSE(
1063        [AC_LANG_SOURCE([int x;])],
1064        [if test -s conftest.err && grep "unrecognized option" conftest.err
1065         then
1066           ovs_cv_name[]=no
1067         else
1068           ovs_cv_name[]=yes
1069         fi],
1070        [ovs_cv_name[]=no])
1071      CFLAGS="$ovs_save_CFLAGS"])
1072   if test $ovs_cv_name = yes; then
1073     m4_if([$2], [], [:], [$2])
1074   else
1075     m4_if([$3], [], [:], [$3])
1076   fi
1077 ])
1078
1079 dnl OVS_CHECK_WERROR
1080 dnl
1081 dnl Check whether the C compiler accepts -Werror.
1082 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1083 AC_DEFUN([OVS_CHECK_WERROR],
1084   [WERROR=
1085    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1086
1087 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1088 dnl Check whether the given C compiler OPTION is accepted.
1089 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1090 AC_DEFUN([OVS_CHECK_CC_OPTION],
1091   [AC_REQUIRE([OVS_CHECK_WERROR])
1092    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1093
1094 dnl OVS_ENABLE_OPTION([OPTION])
1095 dnl Check whether the given C compiler OPTION is accepted.
1096 dnl If so, add it to WARNING_FLAGS.
1097 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1098 AC_DEFUN([OVS_ENABLE_OPTION],
1099   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1100    AC_SUBST([WARNING_FLAGS])])
1101
1102 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1103 dnl Check whether the given C compiler OPTION is accepted.
1104 dnl If so, enable the given Automake CONDITIONAL.
1105
1106 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1107 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1108   [OVS_CHECK_CC_OPTION(
1109     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1110    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1111 dnl ----------------------------------------------------------------------
1112
1113 dnl Check for too-old XenServer.
1114 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1115   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1116     [if test -e /etc/redhat-release; then
1117        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1118      fi
1119      if test -z "$ovs_cv_xsversion"; then
1120        ovs_cv_xsversion=none
1121      fi])
1122   case $ovs_cv_xsversion in
1123     none)
1124       ;;
1125
1126     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1127     [[6-9]]* |                           dnl XenServer 6 or later
1128     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1129     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1130     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1131     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1132       ;;
1133
1134     *)
1135       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1136       ;;
1137   esac])
1138
1139 dnl OVS_CHECK_SPARSE_TARGET
1140 dnl
1141 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1142 dnl target for which the code is being built.  This helps it out.
1143 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1144   [AC_CACHE_CHECK(
1145     [target hint for cgcc],
1146     [ac_cv_sparse_target],
1147     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1148        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1149        [x86_64-*], [ac_cv_sparse_target=x86_64],
1150        [ac_cv_sparse_target=other])])
1151    AS_CASE([$ac_cv_sparse_target],
1152      [x86], [SPARSEFLAGS= CGCCFLAGS="-target=i86 -target=host_os_specs"],
1153      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS="-target=x86_64 -target=host_os_specs"],
1154      [SPARSEFLAGS= CGCCFLAGS=])
1155
1156    dnl Get the the default defines for vector instructions from compiler to
1157    dnl allow "sparse" correctly check the same code that will be built.
1158    dnl Required for checking DPDK headers.
1159    AC_MSG_CHECKING([vector options for cgcc])
1160    VECTOR=$($CC -dM -E - < /dev/null | grep -E "MMX|SSE|AVX" | \
1161             cut -c 9- | sed 's/ /=/' | sed 's/^/-D/' | tr '\n' ' ')
1162    AC_MSG_RESULT([$VECTOR])
1163    CGCCFLAGS="$CGCCFLAGS $VECTOR"
1164
1165    AC_SUBST([SPARSEFLAGS])
1166    AC_SUBST([CGCCFLAGS])])
1167
1168 dnl OVS_SPARSE_EXTRA_INCLUDES
1169 dnl
1170 dnl The cgcc script from "sparse" does not search gcc's default
1171 dnl search path. Get the default search path from GCC and pass
1172 dnl them to sparse.
1173 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1174     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1175            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1176
1177 dnl OVS_ENABLE_SPARSE
1178 AC_DEFUN([OVS_ENABLE_SPARSE],
1179   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1180    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1181    : ${SPARSE=sparse}
1182    AC_SUBST([SPARSE])
1183    AC_CONFIG_COMMANDS_PRE(
1184      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1185
1186    AC_ARG_ENABLE(
1187      [sparse],
1188      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1189      [], [enable_sparse=no])
1190    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1191
1192 dnl OVS_CTAGS_IDENTIFIERS
1193 dnl
1194 dnl ctags ignores symbols with extras identifiers. This builds a list of
1195 dnl specially handled identifiers to be ignored.
1196 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1197     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1198            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1199
1200 dnl OVS_PTHREAD_SET_NAME
1201 dnl
1202 dnl This checks for three known variants of pthreads functions for setting
1203 dnl the name of the current thread:
1204 dnl
1205 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1206 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1207 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1208 dnl
1209 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1210 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1211 dnl provide to it.
1212 dnl
1213 dnl This macro defines:
1214 dnl
1215 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1216 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1217 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1218 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1219   [AC_CHECK_FUNCS([pthread_set_name_np])
1220    if test $ac_cv_func_pthread_set_name_np != yes; then
1221      AC_CACHE_CHECK(
1222        [for pthread_setname_np() variant],
1223        [ovs_cv_pthread_setname_np],
1224        [AC_LINK_IFELSE(
1225          [AC_LANG_PROGRAM([#include <pthread.h>
1226   ], [pthread_setname_np(pthread_self(), "name");])],
1227          [ovs_cv_pthread_setname_np=glibc],
1228          [AC_LINK_IFELSE(
1229            [AC_LANG_PROGRAM([#include <pthread.h>
1230 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1231            [ovs_cv_pthread_setname_np=netbsd],
1232            [ovs_cv_pthread_setname_np=none])])])
1233      case $ovs_cv_pthread_setname_np in # (
1234        glibc)
1235           AC_DEFINE(
1236             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1237             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1238           ;; # (
1239        netbsd)
1240           AC_DEFINE(
1241             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1242             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1243           ;;
1244      esac
1245    fi])
1246
1247 dnl OVS_CHECK_LINUX_HOST.
1248 dnl
1249 dnl Checks whether we're building for a Linux host, based on the presence of
1250 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1251 dnl LINUX based on the result.
1252 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1253   [AC_CACHE_CHECK(
1254      [whether __linux__ is defined],
1255      [ovs_cv_linux],
1256      [AC_COMPILE_IFELSE(
1257         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1258         [ovs_cv_linux=true],
1259         [ovs_cv_linux=false])])
1260    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])