acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 4; then
 154        if test "$version" = 4 && test "$patchlevel" -le 18; then
 155           : # Linux 4.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.18.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 160        : # Linux 3.x
 161     else
 162        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 163     fi
 164     if (test ! -e "$KBUILD"/include/linux/version.h && \
 165         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 166        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 167         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 168         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 169     fi
 170     OVS_CHECK_LINUX_COMPAT
 171   fi
 172   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 173 ])
 174
 175 dnl OVS_CHECK_LINUX_TC
 176 dnl
 177 dnl Configure Linux tc compat.
 178 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 179   AC_COMPILE_IFELSE([
 180     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 181         int x = TCA_FLOWER_KEY_ENC_IP_TTL_MASK;
 182     ])],
 183     [AC_DEFINE([HAVE_TCA_FLOWER_KEY_ENC_IP_TTL_MASK], [1],
 184                [Define to 1 if TCA_FLOWER_KEY_ENC_IP_TTL_MASK is available.])])
 185
 186   AC_COMPILE_IFELSE([
 187     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 188         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 189     ])],
 190     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 191                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 192
 193   AC_COMPILE_IFELSE([
 194     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 195         int x = TCA_TUNNEL_KEY_ENC_TTL;
 196     ])],
 197     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 198                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 199
 200   AC_COMPILE_IFELSE([
 201     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 202         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 203     ])],
 204     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 205                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 206 ])
 207
 208 dnl OVS_CHECK_DPDK
 209 dnl
 210 dnl Configure DPDK source tree
 211 AC_DEFUN([OVS_CHECK_DPDK], [
 212   AC_ARG_WITH([dpdk],
 213               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 214                               [Specify the DPDK build directory])],
 215               [have_dpdk=true])
 216
 217   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 218   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 219     AC_MSG_RESULT([no])
 220     DPDKLIB_FOUND=false
 221   else
 222     AC_MSG_RESULT([yes])
 223     case "$with_dpdk" in
 224       yes)
 225         DPDK_AUTO_DISCOVER="true"
 226         PKG_CHECK_MODULES([DPDK], [libdpdk],
 227                           [DPDK_INCLUDE="$DPDK_CFLAGS"],
 228                           [DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"])
 229         ;;
 230       *)
 231         DPDK_AUTO_DISCOVER="false"
 232         DPDK_INCLUDE_PATH="$with_dpdk/include"
 233         # If 'with_dpdk' is passed install directory, point to headers
 234         # installed in $DESTDIR/$prefix/include/dpdk
 235         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 236            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 237         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 238            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 239         fi
 240         DPDK_LIB_DIR="$with_dpdk/lib"
 241         ;;
 242     esac
 243
 244     DPDK_LIB="-ldpdk"
 245
 246     ovs_save_CFLAGS="$CFLAGS"
 247     ovs_save_LDFLAGS="$LDFLAGS"
 248     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 249     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 250       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 251     fi
 252
 253     AC_COMPILE_IFELSE([
 254       AC_LANG_PROGRAM(
 255         [
 256           #include <rte_config.h>
 257 #if RTE_LIBRTE_VHOST_NUMA
 258 #error
 259 #endif
 260         ], [])
 261       ], [],
 262       [AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])])
 263        AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])])
 264
 265     AC_COMPILE_IFELSE([
 266       AC_LANG_PROGRAM(
 267         [
 268           #include <rte_config.h>
 269 #if RTE_LIBRTE_PMD_PCAP
 270 #error
 271 #endif
 272         ], [])
 273       ], [],
 274       [AC_SEARCH_LIBS([pcap_dump],[pcap],[],[AC_MSG_ERROR([unable to find libpcap, install the dependency package])])
 275        AC_COMPILE_IFELSE([
 276          AC_LANG_PROGRAM(
 277            [
 278              #include <rte_config.h>
 279 #if RTE_LIBRTE_PDUMP
 280 #error
 281 #endif
 282          ], [])
 283        ], [],
 284        [AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])])
 285      ])
 286
 287     AC_COMPILE_IFELSE([
 288       AC_LANG_PROGRAM(
 289         [
 290           #include <rte_config.h>
 291 #if RTE_LIBRTE_MLX5_PMD
 292 #error
 293 #endif
 294         ], [])
 295       ], [],
 296       [AC_SEARCH_LIBS([mnl_attr_put],[mnl],[],[AC_MSG_ERROR([unable to find libmnl, install the dependency package])])
 297        AC_DEFINE([DPDK_MNL], [1], [MLX5 PMD detected in DPDK.])])
 298
 299     # On some systems we have to add -ldl to link with dpdk
 300     #
 301     # This code, at first, tries to link without -ldl (""),
 302     # then adds it and tries again.
 303     # Before each attempt the search cache must be unset,
 304     # otherwise autoconf will stick with the old result
 305
 306     DPDKLIB_FOUND=false
 307     save_LIBS=$LIBS
 308     for extras in "" "-ldl"; do
 309         LIBS="$DPDK_LIB $extras $save_LIBS"
 310         AC_LINK_IFELSE(
 311            [AC_LANG_PROGRAM([#include <rte_config.h>
 312                              #include <rte_eal.h>],
 313                             [int rte_argc; char ** rte_argv;
 314                              rte_eal_init(rte_argc, rte_argv);])],
 315            [DPDKLIB_FOUND=true])
 316         if $DPDKLIB_FOUND; then
 317             break
 318         fi
 319     done
 320
 321     # If linking unsuccessful
 322     if test "$DPDKLIB_FOUND" = "false" ; then
 323       if $DPDK_AUTO_DISCOVER; then
 324         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 325       else
 326         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 327       fi
 328     fi
 329     CFLAGS="$ovs_save_CFLAGS"
 330     LDFLAGS="$ovs_save_LDFLAGS"
 331     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 332       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 333     fi
 334     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 335     OVS_ENABLE_OPTION([-mssse3])
 336
 337     # DPDK pmd drivers are not linked unless --whole-archive is used.
 338     #
 339     # This happens because the rest of the DPDK code doesn't use any symbol in
 340     # the pmd driver objects, and the drivers register themselves using an
 341     # __attribute__((constructor)) function.
 342     #
 343     # These options are specified inside a single -Wl directive to prevent
 344     # autotools from reordering them.
 345     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 346     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 347     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 348   fi
 349
 350   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 351 ])
 352
 353 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 354 dnl
 355 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 356 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 357 dnl <REGEX> translated to uppercase.
 358 AC_DEFUN([OVS_GREP_IFELSE], [
 359   AC_MSG_CHECKING([whether $2 matches in $1])
 360   if test -f $1; then
 361     grep '$2' $1 >/dev/null 2>&1
 362     status=$?
 363     case $status in
 364       0)
 365         AC_MSG_RESULT([yes])
 366         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 367         ;;
 368       1)
 369         AC_MSG_RESULT([no])
 370         $4
 371         ;;
 372       *)
 373         AC_MSG_ERROR([grep exited with status $status])
 374         ;;
 375     esac
 376   else
 377     AC_MSG_RESULT([file not found])
 378     $4
 379   fi
 380 ])
 381
 382 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 383 dnl
 384 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 385 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 386 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 387 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 388 dnl translated to uppercase.
 389 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 390   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 391   if test -f $1; then
 392     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 393     status=$?
 394     case $status in
 395       0)
 396         AC_MSG_RESULT([yes])
 397         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 398         ;;
 399       1)
 400         AC_MSG_RESULT([no])
 401         $5
 402         ;;
 403       *)
 404         AC_MSG_ERROR([grep exited with status $status])
 405         ;;
 406     esac
 407   else
 408     AC_MSG_RESULT([file not found])
 409     $5
 410   fi
 411 ])
 412
 413 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 414 dnl
 415 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 416 dnl the function signature starting from the line matching FUNCTION
 417 dnl and ending with the line containing the closing parenthesis.  If
 418 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 419 dnl IF-MATCH is empty then it defines to
 420 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 421 dnl <REGEX> translated to uppercase.
 422 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 423   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 424   if test -f $1; then
 425     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 426     status=$?
 427     case $status in
 428       0)
 429         AC_MSG_RESULT([yes])
 430         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 431         ;;
 432       1)
 433         AC_MSG_RESULT([no])
 434         $5
 435         ;;
 436       *)
 437         AC_MSG_ERROR([grep exited with status $status])
 438         ;;
 439     esac
 440   else
 441     AC_MSG_RESULT([file not found])
 442     $5
 443   fi
 444 ])
 445
 446 dnl OVS_DEFINE(NAME)
 447 dnl
 448 dnl Defines NAME to 1 in kcompat.h.
 449 AC_DEFUN([OVS_DEFINE], [
 450   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 451 ])
 452
 453 dnl OVS_CHECK_LINUX_COMPAT
 454 dnl
 455 dnl Runs various Autoconf checks on the Linux kernel source in
 456 dnl the directory in $KBUILD.
 457 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 458   rm -f datapath/linux/kcompat.h.new
 459   mkdir -p datapath/linux
 460   : > datapath/linux/kcompat.h.new
 461
 462   echo '#include <linux/version.h>
 463 #ifndef RHEL_RELEASE_CODE
 464 #define RHEL_RELEASE_CODE 0
 465 #define RHEL_RELEASE_VERSION(a, b) 0
 466 #endif' >> datapath/linux/kcompat.h.new
 467
 468   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 469                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 470
 471   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 472                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 473
 474   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 475                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 476   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 477
 478   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 479   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 480   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 481
 482   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 483                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 484   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 485                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 486
 487   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 488   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 489
 490   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 491   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 492   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 493   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 494   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 495
 496   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 497   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 498   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 499                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 500   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 501                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 502
 503   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 504                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 505   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 506                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 507   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 508                         [ip_do_fragment], [net],
 509                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 510   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 511                         [ip_local_out], [net],
 512                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 513
 514   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 515
 516   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 517                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 518   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 519   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 520                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 521   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 522                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 523   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 524   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 525   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 526                         [frags_work])
 527   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 528                         [rwlock])
 529   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 530                         [list_evictor])
 531   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 532   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 533                         [sub_frag_mem_limit], [struct.netns_frags],
 534                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 535   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 536                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 537   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 538                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 539
 540   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 541   dnl OVS does not really need ipv6 label field, but its presence signifies that
 542   dnl the stack has all required ipv6 support.
 543   dnl OVS also does not need dst_cache But this dependency allows us to write
 544   dnl much cleaner code.
 545
 546   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 547                         [label],
 548                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 549                                          [iptunnel_pull_offloads],
 550                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 551                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 552                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 553
 554   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 555                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 556   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 557                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 558   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 559                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 560   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 561   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 562   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 563   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 564   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 565   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 566   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 567   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 568   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 569   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 570                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 571   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 572   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 573   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 574   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 575   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 576   dnl So check type of tstats.
 577   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 578                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 579   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 580                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 581   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 582   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 583   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 584                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 585   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 586   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 587   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 588                         [extended])
 589   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 590                         [netdev_master_upper_dev_link], [upper_priv],
 591                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 592   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 593                   [netdev_master_upper_dev_link_rh],
 594                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 595
 596   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 597                         [max_mtu])
 598   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 599                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 600
 601   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 602   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 603   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 604                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 605   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 606                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 607   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 608                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 609   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 610
 611
 612   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 613                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 614
 615   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 616                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 617                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 618   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 619                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 620
 621   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 622                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 623                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 624   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 625                   [nf_ct_get_tuplepr], [struct.net],
 626                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 627   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 628                   [nf_ct_set])
 629   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 630                   [nf_ct_is_untracked])
 631   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 632                   [nf_ct_zone_init])
 633   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 634                   [net_ns_get])
 635   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 636                   [nf_connlabels_get])
 637   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 638                   [nf_connlabels_get], [int bit],
 639                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 640   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 641                         [nf_conn_labels], [words])
 642   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 643   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 644   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 645   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 646   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 647                   [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])
 648
 649   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 650   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 651
 652   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 653   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 654   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 655                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 656   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 657
 658   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 659                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 660                                    [rcu_read_lock_held])])
 661   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 662   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 663
 664   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 665   # is necessary because some versions of this header remove the
 666   # member but retain the kerneldoc comment that describes it (which
 667   # starts with @).  The brackets must be doubled because of m4
 668   # quoting rules.
 669   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 670                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 671   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 672   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 673   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 674   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 675   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 676   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 677   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 678                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 679   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 680                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 681   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 682                   [skb_copy_from_linear_data_offset])
 683   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 684                   [skb_reset_tail_pointer])
 685   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 686   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 687                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 688   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 689   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 690   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 691   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 692   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 693   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 694   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 695   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 696                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 697   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 698   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 699                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 700   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 701                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 702   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 703   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 704   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 705   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 706   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 707   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 708   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 709   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 710   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 711
 712   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 713                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 714   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 715                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 716   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 717                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 718
 719   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 720   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 721
 722   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 723   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 724
 725   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 726   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 727   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 728   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 729                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 730   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 731   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 732                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 733   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 734                         [genl_notify], [net],
 735                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 736
 737
 738   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 739                         [genl_multicast_group], [id])
 740   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 741
 742   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 743   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 744   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 745   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 746   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 747   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 748                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 749   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 750                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 751
 752   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 753   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 754   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 755   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 756   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 757   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 758   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 759   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 760   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 761                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 762   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 763                         [nla_parse], [netlink_ext_ack],
 764                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 765
 766   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 767
 768   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 769                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 770   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 771   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 772   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 773   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 774   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 775
 776   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 777                         [metadata_dst_alloc], [metadata_type])
 778
 779   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 780
 781   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 782                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 783   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 784                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 785                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 786   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 787   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 788   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 789                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 790   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 791                         [gro_receive])
 792
 793   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 794                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 795   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 796                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 797
 798   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 799   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 800   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 801                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 802   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 803                         [udp_add_offload], [net],
 804                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 805   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 806                         [nf_defrag_ipv6_enable], [net],
 807                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 808   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 809                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 810   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 811                         [needs_free_netdev],
 812                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 813   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 814                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 815   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 816                   [nf_conntrack_helper_put],
 817                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 818   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 819                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 820   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 821                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 822   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 823                         [extack],
 824                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 825   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 826                         [list],
 827                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 828   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 829                   [IP_CT_UNTRACKED])
 830   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 831                         [netdev_master_upper_dev_link], [extack],
 832                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 833   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 834                   [__LINUX_COMPILER_TYPES_H],
 835                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 836   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 837                   [ktime_get_ts64],
 838                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 839   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 840                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 841                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 842   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 843                   [ktime_get_ns],
 844                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 845   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 846                   frag_percpu_counter_batch[],
 847                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 848   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 849                   [null_compute_pseudo],
 850                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 851   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 852                   [__skb_checksum_convert],
 853                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
 854   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 855                         [max_mtu],
 856                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
 857   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
 858                         [erspan_ver],
 859                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
 860   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 861                   [SKB_GSO_IPXIP6],
 862                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
 863   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
 864                         [ip6_make_flowlabel], [fl6],
 865                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
 866   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
 867                         [auto_flowlabels],
 868                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
 869   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 870                   [netif_keep_dst],
 871                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
 872   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 873                         [ndo_get_iflink],
 874                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
 875   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 876                   [skb_set_inner_ipproto],
 877                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
 878   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 879                   [tunnel_encap_types],
 880                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
 881   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 882                   [IFLA_IPTUN_ENCAP_TYPE],
 883                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
 884   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 885                   [IFLA_IPTUN_COLLECT_METADATA],
 886                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
 887   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 888                   [IFLA_GRE_ENCAP_DPORT])
 889   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 890                   [IFLA_GRE_COLLECT_METADATA])
 891   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 892                   [IFLA_GRE_IGNORE_DF])
 893   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 894                   [IFLA_GRE_FWMARK])
 895   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 896                   [IFLA_GRE_ERSPAN_INDEX])
 897   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 898                   [IFLA_GRE_ERSPAN_HWID])
 899   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 900                   [IFLA_IPTUN_FWMARK])
 901   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
 902                         [csum_valid],
 903                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
 904   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 905                   [skb_checksum_simple_validate])
 906   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 907                   [void.*ndo_get_stats64],
 908                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
 909   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
 910                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
 911   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
 912                         [ip_tunnel_info_opts_set], [flags],
 913                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
 914   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 915                         [rnd],
 916                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
 917
 918   if cmp -s datapath/linux/kcompat.h.new \
 919             datapath/linux/kcompat.h >/dev/null 2>&1; then
 920     rm datapath/linux/kcompat.h.new
 921   else
 922     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 923   fi
 924 ])
 925
 926 dnl Checks for net/if_dl.h.
 927 dnl
 928 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 929 dnl or NetBSD.)
 930 AC_DEFUN([OVS_CHECK_IF_DL],
 931   [AC_CHECK_HEADER([net/if_dl.h],
 932                    [HAVE_IF_DL=yes],
 933                    [HAVE_IF_DL=no])
 934    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 935    if test "$HAVE_IF_DL" = yes; then
 936       AC_DEFINE([HAVE_IF_DL], [1],
 937                 [Define to 1 if net/if_dl.h is available.])
 938
 939       # On these platforms we use libpcap to access network devices.
 940       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 941    fi])
 942
 943 dnl Checks for buggy strtok_r.
 944 dnl
 945 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 946 dnl with optimization that can cause segfaults:
 947 dnl
 948 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 949 AC_DEFUN([OVS_CHECK_STRTOK_R],
 950   [AC_CACHE_CHECK(
 951      [whether strtok_r macro segfaults on some inputs],
 952      [ovs_cv_strtok_r_bug],
 953      [AC_RUN_IFELSE(
 954         [AC_LANG_PROGRAM([#include <stdio.h>
 955                           #include <string.h>
 956                          ],
 957                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 958                            /* Assume bug is present, because relatively minor
 959                               changes in compiler settings (e.g. optimization
 960                               level) can make it crop up. */
 961                            return 1;
 962                            #else
 963                            char string[] = ":::";
 964                            char *save_ptr = (char *) 0xc0ffee;
 965                            char *token1, *token2;
 966                            token1 = strtok_r(string, ":", &save_ptr);
 967                            token2 = strtok_r(NULL, ":", &save_ptr);
 968                            freopen ("/dev/null", "w", stdout);
 969                            printf ("%s %s\n", token1, token2);
 970                            return 0;
 971                            #endif
 972                           ]])],
 973         [ovs_cv_strtok_r_bug=no],
 974         [ovs_cv_strtok_r_bug=yes],
 975         [ovs_cv_strtok_r_bug=yes])])
 976    if test $ovs_cv_strtok_r_bug = yes; then
 977      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 978                [Define if strtok_r macro segfaults on some inputs])
 979    fi
 980 ])
 981
 982 dnl ----------------------------------------------------------------------
 983 dnl These macros are from GNU PSPP, with the following original license:
 984 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 985 dnl This file is free software; the Free Software Foundation
 986 dnl gives unlimited permission to copy and/or distribute it,
 987 dnl with or without modifications, as long as this notice is preserved.
 988
 989 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 990   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
 991   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 992     [ovs_save_CFLAGS="$CFLAGS"
 993      dnl Include -Werror in the compiler options, because without -Werror
 994      dnl clang's GCC-compatible compiler driver does not return a failure
 995      dnl exit status even though it complains about options it does not
 996      dnl understand.
 997      dnl
 998      dnl Also, check stderr as gcc exits with status 0 for options
 999      dnl rejected at getopt level.
1000      dnl    % touch /tmp/a.c
1001      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1002      dnl    gcc: unrecognized option '-Qunused-arguments'
1003      dnl    0
1004      dnl    %
1005      dnl
1006      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1007      dnl it does not understand, unless it has another error to report, so
1008      dnl instead of testing for -Wno-<foo>, test for the positive version.
1009      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1010      AC_COMPILE_IFELSE(
1011        [AC_LANG_SOURCE([int x;])],
1012        [if test -s conftest.err && grep "unrecognized option" conftest.err
1013         then
1014           ovs_cv_name[]=no
1015         else
1016           ovs_cv_name[]=yes
1017         fi],
1018        [ovs_cv_name[]=no])
1019      CFLAGS="$ovs_save_CFLAGS"])
1020   if test $ovs_cv_name = yes; then
1021     m4_if([$2], [], [:], [$2])
1022   else
1023     m4_if([$3], [], [:], [$3])
1024   fi
1025 ])
1026
1027 dnl OVS_CHECK_WERROR
1028 dnl
1029 dnl Check whether the C compiler accepts -Werror.
1030 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1031 AC_DEFUN([OVS_CHECK_WERROR],
1032   [WERROR=
1033    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1034
1035 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1036 dnl Check whether the given C compiler OPTION is accepted.
1037 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1038 AC_DEFUN([OVS_CHECK_CC_OPTION],
1039   [AC_REQUIRE([OVS_CHECK_WERROR])
1040    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1041
1042 dnl OVS_ENABLE_OPTION([OPTION])
1043 dnl Check whether the given C compiler OPTION is accepted.
1044 dnl If so, add it to WARNING_FLAGS.
1045 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1046 AC_DEFUN([OVS_ENABLE_OPTION],
1047   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1048    AC_SUBST([WARNING_FLAGS])])
1049
1050 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1051 dnl Check whether the given C compiler OPTION is accepted.
1052 dnl If so, enable the given Automake CONDITIONAL.
1053
1054 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1055 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1056   [OVS_CHECK_CC_OPTION(
1057     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1058    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1059 dnl ----------------------------------------------------------------------
1060
1061 dnl Check for too-old XenServer.
1062 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1063   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1064     [if test -e /etc/redhat-release; then
1065        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1066      fi
1067      if test -z "$ovs_cv_xsversion"; then
1068        ovs_cv_xsversion=none
1069      fi])
1070   case $ovs_cv_xsversion in
1071     none)
1072       ;;
1073
1074     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1075     [[6-9]]* |                           dnl XenServer 6 or later
1076     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1077     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1078     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1079     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1080       ;;
1081
1082     *)
1083       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1084       ;;
1085   esac])
1086
1087 dnl OVS_CHECK_SPARSE_TARGET
1088 dnl
1089 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1090 dnl target for which the code is being built.  This helps it out.
1091 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1092   [AC_CACHE_CHECK(
1093     [target hint for cgcc],
1094     [ac_cv_sparse_target],
1095     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1096        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1097        [x86_64-*], [ac_cv_sparse_target=x86_64],
1098        [ac_cv_sparse_target=other])])
1099    AS_CASE([$ac_cv_sparse_target],
1100      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
1101      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
1102      [SPARSEFLAGS= CGCCFLAGS=])
1103    AC_SUBST([SPARSEFLAGS])
1104    AC_SUBST([CGCCFLAGS])])
1105
1106 dnl OVS_SPARSE_EXTRA_INCLUDES
1107 dnl
1108 dnl The cgcc script from "sparse" does not search gcc's default
1109 dnl search path. Get the default search path from GCC and pass
1110 dnl them to sparse.
1111 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1112     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1113            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1114
1115 dnl OVS_ENABLE_SPARSE
1116 AC_DEFUN([OVS_ENABLE_SPARSE],
1117   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1118    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1119    : ${SPARSE=sparse}
1120    AC_SUBST([SPARSE])
1121    AC_CONFIG_COMMANDS_PRE(
1122      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1123
1124    AC_ARG_ENABLE(
1125      [sparse],
1126      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1127      [], [enable_sparse=no])
1128    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1129
1130 dnl OVS_CTAGS_IDENTIFIERS
1131 dnl
1132 dnl ctags ignores symbols with extras identifiers. This builds a list of
1133 dnl specially handled identifiers to be ignored.
1134 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1135     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1136            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1137
1138 dnl OVS_PTHREAD_SET_NAME
1139 dnl
1140 dnl This checks for three known variants of pthreads functions for setting
1141 dnl the name of the current thread:
1142 dnl
1143 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1144 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1145 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1146 dnl
1147 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1148 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1149 dnl provide to it.
1150 dnl
1151 dnl This macro defines:
1152 dnl
1153 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1154 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1155 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1156 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1157   [AC_CHECK_FUNCS([pthread_set_name_np])
1158    if test $ac_cv_func_pthread_set_name_np != yes; then
1159      AC_CACHE_CHECK(
1160        [for pthread_setname_np() variant],
1161        [ovs_cv_pthread_setname_np],
1162        [AC_LINK_IFELSE(
1163          [AC_LANG_PROGRAM([#include <pthread.h>
1164   ], [pthread_setname_np(pthread_self(), "name");])],
1165          [ovs_cv_pthread_setname_np=glibc],
1166          [AC_LINK_IFELSE(
1167            [AC_LANG_PROGRAM([#include <pthread.h>
1168 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1169            [ovs_cv_pthread_setname_np=netbsd],
1170            [ovs_cv_pthread_setname_np=none])])])
1171      case $ovs_cv_pthread_setname_np in # (
1172        glibc)
1173           AC_DEFINE(
1174             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1175             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1176           ;; # (
1177        netbsd)
1178           AC_DEFINE(
1179             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1180             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1181           ;;
1182      esac
1183    fi])
1184
1185 dnl OVS_CHECK_LINUX_HOST.
1186 dnl
1187 dnl Checks whether we're building for a Linux host, based on the presence of
1188 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1189 dnl LINUX based on the result.
1190 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1191   [AC_CACHE_CHECK(
1192      [whether __linux__ is defined],
1193      [ovs_cv_linux],
1194      [AC_COMPILE_IFELSE(
1195         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1196         [ovs_cv_linux=true],
1197         [ovs_cv_linux=false])])
1198    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])