acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2019 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 5; then
 154        if test "$version" = 5 && test "$patchlevel" -le 0; then
 155           : # Linux 5.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 5.0.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 4; then
 160        : # Linux 4.x
 161     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 162        : # Linux 3.x
 163     else
 164        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 165     fi
 166     if (test ! -e "$KBUILD"/include/linux/version.h && \
 167         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 168        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 169         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 170         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 171     fi
 172     OVS_CHECK_LINUX_COMPAT
 173   fi
 174   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 175 ])
 176
 177 dnl OVS_CHECK_LINUX_NETLINK
 178 dnl
 179 dnl Configure Linux netlink compat.
 180 AC_DEFUN([OVS_CHECK_LINUX_NETLINK], [
 181   AC_COMPILE_IFELSE([
 182     AC_LANG_PROGRAM([#include <linux/netlink.h>], [
 183         struct nla_bitfield32 x =  { 0 };
 184     ])],
 185     [AC_DEFINE([HAVE_NLA_BITFIELD32], [1],
 186     [Define to 1 if struct nla_bitfield32 is available.])])
 187 ])
 188
 189 dnl OVS_CHECK_LINUX_TC
 190 dnl
 191 dnl Configure Linux tc compat.
 192 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 193   AC_COMPILE_IFELSE([
 194     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 195         int x = TCA_ACT_FLAGS;
 196     ])],
 197     [AC_DEFINE([HAVE_TCA_ACT_FLAGS], [1],
 198                [Define to 1 if TCA_ACT_FLAGS is available.])])
 199
 200   AC_CHECK_MEMBERS([struct tcf_t.firstuse], [], [], [#include <linux/pkt_cls.h>])
 201
 202   AC_COMPILE_IFELSE([
 203     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 204         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 205     ])],
 206     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 207                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 208
 209   AC_COMPILE_IFELSE([
 210     AC_LANG_PROGRAM([#include <linux/tc_act/tc_mpls.h>], [
 211         int x = TCA_MPLS_TTL;
 212     ])],
 213     [AC_DEFINE([HAVE_TCA_MPLS_TTL], [1],
 214                [Define to 1 if HAVE_TCA_MPLS_TTL is available.])])
 215
 216   AC_COMPILE_IFELSE([
 217     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 218         int x = TCA_TUNNEL_KEY_ENC_TTL;
 219     ])],
 220     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 221                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 222
 223   AC_COMPILE_IFELSE([
 224     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 225         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 226     ])],
 227     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 228                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 229
 230   AC_COMPILE_IFELSE([
 231     AC_LANG_PROGRAM([#include <linux/tc_act/tc_skbedit.h>], [
 232         int x = TCA_SKBEDIT_FLAGS;
 233     ])],
 234     [AC_DEFINE([HAVE_TCA_SKBEDIT_FLAGS], [1],
 235                [Define to 1 if TCA_SKBEDIT_FLAGS is available.])])
 236 ])
 237
 238 dnl OVS_CHECK_LINUX_SCTP_CT
 239 dnl
 240 dnl Checks for kernels which need additional SCTP state
 241 AC_DEFUN([OVS_CHECK_LINUX_SCTP_CT], [
 242   AC_COMPILE_IFELSE([
 243     AC_LANG_PROGRAM([#include <linux/netfilter/nfnetlink.h>
 244 #include <linux/netfilter/nfnetlink_conntrack.h>
 245 #include <linux/netfilter/nf_conntrack_common.h>
 246 #include <linux/netfilter/nf_conntrack_sctp.h>], [
 247         int x = SCTP_CONNTRACK_HEARTBEAT_SENT;
 248     ])],
 249     [AC_DEFINE([HAVE_SCTP_CONNTRACK_HEARTBEATS], [1],
 250                [Define to 1 if SCTP_CONNTRACK_HEARTBEAT_SENT is available.])])
 251 ])
 252
 253 dnl OVS_FIND_DEPENDENCY(FUNCTION, SEARCH_LIBS, NAME_TO_PRINT)
 254 dnl
 255 dnl Check for a function in a library list.
 256 AC_DEFUN([OVS_FIND_DEPENDENCY], [
 257   AC_SEARCH_LIBS([$1], [$2], [], [
 258     AC_MSG_ERROR([unable to find $3, install the dependency package])
 259   ])
 260 ])
 261
 262 dnl OVS_CHECK_LINUX_AF_XDP
 263 dnl
 264 dnl Check both Linux kernel AF_XDP and libbpf support
 265 AC_DEFUN([OVS_CHECK_LINUX_AF_XDP], [
 266   AC_ARG_ENABLE([afxdp],
 267                 [AC_HELP_STRING([--enable-afxdp], [Enable AF-XDP support])],
 268                 [], [enable_afxdp=no])
 269   AC_MSG_CHECKING([whether AF_XDP is enabled])
 270   if test "$enable_afxdp" != yes; then
 271     AC_MSG_RESULT([no])
 272     AF_XDP_ENABLE=false
 273   else
 274     AC_MSG_RESULT([yes])
 275     AF_XDP_ENABLE=true
 276
 277     AC_CHECK_HEADER([bpf/libbpf.h], [],
 278       [AC_MSG_ERROR([unable to find bpf/libbpf.h for AF_XDP support])])
 279
 280     AC_CHECK_HEADER([linux/if_xdp.h], [],
 281       [AC_MSG_ERROR([unable to find linux/if_xdp.h for AF_XDP support])])
 282
 283     AC_CHECK_HEADER([bpf/xsk.h], [],
 284       [AC_MSG_ERROR([unable to find bpf/xsk.h for AF_XDP support])])
 285
 286     AC_CHECK_FUNCS([pthread_spin_lock], [],
 287       [AC_MSG_ERROR([unable to find pthread_spin_lock for AF_XDP support])])
 288
 289     OVS_FIND_DEPENDENCY([numa_alloc_onnode], [numa], [libnuma])
 290
 291     AC_DEFINE([HAVE_AF_XDP], [1],
 292               [Define to 1 if AF_XDP support is available and enabled.])
 293     LIBBPF_LDADD=" -lbpf -lelf"
 294     AC_SUBST([LIBBPF_LDADD])
 295
 296     AC_CHECK_DECL([xsk_ring_prod__needs_wakeup], [
 297       AC_DEFINE([HAVE_XDP_NEED_WAKEUP], [1],
 298         [XDP need wakeup support detected in xsk.h.])
 299     ], [], [[#include <bpf/xsk.h>]])
 300   fi
 301   AM_CONDITIONAL([HAVE_AF_XDP], test "$AF_XDP_ENABLE" = true)
 302 ])
 303
 304 dnl OVS_CHECK_DPDK
 305 dnl
 306 dnl Configure DPDK source tree
 307 AC_DEFUN([OVS_CHECK_DPDK], [
 308   AC_ARG_WITH([dpdk],
 309               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 310                               [Specify the DPDK build directory])],
 311               [have_dpdk=true])
 312
 313   AC_MSG_CHECKING([whether dpdk is enabled])
 314   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 315     AC_MSG_RESULT([no])
 316     DPDKLIB_FOUND=false
 317   else
 318     AC_MSG_RESULT([yes])
 319     case "$with_dpdk" in
 320       yes)
 321         DPDK_AUTO_DISCOVER="true"
 322         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 323             DPDK_INCLUDE="$DPDK_CFLAGS"
 324             DPDK_LIB="$DPDK_LIBS"], [
 325             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 326             DPDK_LIB="-ldpdk"])
 327         ;;
 328       *)
 329         DPDK_AUTO_DISCOVER="false"
 330         DPDK_INCLUDE_PATH="$with_dpdk/include"
 331         # If 'with_dpdk' is passed install directory, point to headers
 332         # installed in $DESTDIR/$prefix/include/dpdk
 333         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 334            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 335         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 336            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 337         fi
 338         DPDK_LIB_DIR="$with_dpdk/lib"
 339         DPDK_LIB="-ldpdk"
 340         ;;
 341     esac
 342
 343     ovs_save_CFLAGS="$CFLAGS"
 344     ovs_save_LDFLAGS="$LDFLAGS"
 345     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 346     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 347       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 348     fi
 349
 350     AC_CHECK_HEADERS([rte_config.h], [], [
 351       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 352     ], [AC_INCLUDES_DEFAULT])
 353
 354     AC_CHECK_DECLS([RTE_LIBRTE_VHOST_NUMA, RTE_EAL_NUMA_AWARE_HUGEPAGES], [
 355       OVS_FIND_DEPENDENCY([get_mempolicy], [numa], [libnuma])
 356     ], [], [[#include <rte_config.h>]])
 357
 358     AC_CHECK_DECL([RTE_LIBRTE_VHOST_NUMA], [
 359       AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])
 360     ], [], [[#include <rte_config.h>]])
 361
 362     AC_CHECK_DECL([RTE_LIBRTE_MLX5_PMD], [dnl found
 363       OVS_FIND_DEPENDENCY([mnl_attr_put], [mnl], [libmnl])
 364       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 365         OVS_FIND_DEPENDENCY([mlx5dv_create_wq], [mlx5], [libmlx5])
 366         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 367       ], [[#include <rte_config.h>]])
 368     ], [], [[#include <rte_config.h>]])
 369
 370     AC_CHECK_DECL([RTE_LIBRTE_MLX4_PMD], [dnl found
 371       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 372         OVS_FIND_DEPENDENCY([mlx4dv_init_obj], [mlx4], [libmlx4])
 373         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 374       ], [[#include <rte_config.h>]])
 375     ], [], [[#include <rte_config.h>]])
 376
 377     # DPDK uses dlopen to load plugins.
 378     OVS_FIND_DEPENDENCY([dlopen], [dl], [libdl])
 379
 380     AC_MSG_CHECKING([whether linking with dpdk works])
 381     LIBS="$DPDK_LIB $LIBS"
 382     AC_LINK_IFELSE(
 383       [AC_LANG_PROGRAM([#include <rte_config.h>
 384                         #include <rte_eal.h>],
 385                        [int rte_argc; char ** rte_argv;
 386                         rte_eal_init(rte_argc, rte_argv);])],
 387       [AC_MSG_RESULT([yes])
 388        DPDKLIB_FOUND=true],
 389       [AC_MSG_RESULT([no])
 390        if test "$DPDK_AUTO_DISCOVER" = "true"; then
 391          AC_MSG_ERROR(m4_normalize([
 392             Could not find DPDK library in default search path, Use --with-dpdk
 393             to specify the DPDK library installed in non-standard location]))
 394        else
 395          AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 396        fi
 397       ])
 398
 399     CFLAGS="$ovs_save_CFLAGS"
 400     LDFLAGS="$ovs_save_LDFLAGS"
 401     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 402       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 403     fi
 404     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 405     OVS_ENABLE_OPTION([-mssse3])
 406
 407     # DPDK pmd drivers are not linked unless --whole-archive is used.
 408     #
 409     # This happens because the rest of the DPDK code doesn't use any symbol in
 410     # the pmd driver objects, and the drivers register themselves using an
 411     # __attribute__((constructor)) function.
 412     #
 413     # These options are specified inside a single -Wl directive to prevent
 414     # autotools from reordering them.
 415     #
 416     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 417     # will already have flagged just the right set of libs with
 418     # --whole-archive - in those cases do not wrap it once more.
 419     case "$DPDK_LIB" in
 420       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 421       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 422     esac
 423     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 424     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 425   fi
 426
 427   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 428 ])
 429
 430 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 431 dnl
 432 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 433 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 434 dnl <REGEX> translated to uppercase.
 435 AC_DEFUN([OVS_GREP_IFELSE], [
 436   AC_MSG_CHECKING([whether $2 matches in $1])
 437   if test -f $1; then
 438     grep '$2' $1 >/dev/null 2>&1
 439     status=$?
 440     case $status in
 441       0)
 442         AC_MSG_RESULT([yes])
 443         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 444         ;;
 445       1)
 446         AC_MSG_RESULT([no])
 447         $4
 448         ;;
 449       *)
 450         AC_MSG_ERROR([grep exited with status $status])
 451         ;;
 452     esac
 453   else
 454     AC_MSG_RESULT([file not found])
 455     $4
 456   fi
 457 ])
 458
 459 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 460 dnl
 461 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 462 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 463 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 464 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 465 dnl translated to uppercase.
 466 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 467   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 468   if test -f $1; then
 469     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 470     status=$?
 471     case $status in
 472       0)
 473         AC_MSG_RESULT([yes])
 474         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 475         ;;
 476       1)
 477         AC_MSG_RESULT([no])
 478         $5
 479         ;;
 480       *)
 481         AC_MSG_ERROR([grep exited with status $status])
 482         ;;
 483     esac
 484   else
 485     AC_MSG_RESULT([file not found])
 486     $5
 487   fi
 488 ])
 489
 490 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 491 dnl
 492 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 493 dnl the function signature starting from the line matching FUNCTION
 494 dnl and ending with the line containing the closing parenthesis.  If
 495 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 496 dnl IF-MATCH is empty then it defines to
 497 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 498 dnl <REGEX> translated to uppercase.
 499 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 500   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 501   if test -f $1; then
 502     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 503     status=$?
 504     case $status in
 505       0)
 506         AC_MSG_RESULT([yes])
 507         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 508         ;;
 509       1)
 510         AC_MSG_RESULT([no])
 511         $5
 512         ;;
 513       *)
 514         AC_MSG_ERROR([grep exited with status $status])
 515         ;;
 516     esac
 517   else
 518     AC_MSG_RESULT([file not found])
 519     $5
 520   fi
 521 ])
 522
 523 dnl OVS_DEFINE(NAME)
 524 dnl
 525 dnl Defines NAME to 1 in kcompat.h.
 526 AC_DEFUN([OVS_DEFINE], [
 527   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 528 ])
 529
 530 dnl OVS_CHECK_LINUX_COMPAT
 531 dnl
 532 dnl Runs various Autoconf checks on the Linux kernel source in
 533 dnl the directory in $KBUILD.
 534 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 535   rm -f datapath/linux/kcompat.h.new
 536   mkdir -p datapath/linux
 537   : > datapath/linux/kcompat.h.new
 538
 539   echo '#include <linux/version.h>
 540 #ifndef RHEL_RELEASE_CODE
 541 #define RHEL_RELEASE_CODE 0
 542 #define RHEL_RELEASE_VERSION(a, b) 0
 543 #endif' >> datapath/linux/kcompat.h.new
 544
 545   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 546                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 547
 548   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 549                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 550
 551   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 552                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 553   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 554
 555   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 556   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 557   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 558
 559   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 560                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 561   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 562                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 563
 564   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 565   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 566
 567   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 568   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 569   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 570   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 571   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 572   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_hwaccel_clear_tag])
 573
 574   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 575   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 576   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 577                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 578   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 579                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 580
 581   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 582                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 583   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 584                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 585   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 586                         [ip_do_fragment], [net],
 587                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 588   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 589                         [ip_local_out], [net],
 590                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 591
 592   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 593
 594   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 595                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 596   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 597   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 598                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 599   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 600                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 601   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 602   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 603   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 604                         [frags_work])
 605   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 606                         [rwlock])
 607   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 608                         [list_evictor])
 609   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 610   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 611                         [sub_frag_mem_limit], [struct.netns_frags],
 612                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 613   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 614                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 615   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 616                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 617
 618   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 619   dnl OVS does not really need ipv6 label field, but its presence signifies that
 620   dnl the stack has all required ipv6 support.
 621   dnl OVS also does not need dst_cache But this dependency allows us to write
 622   dnl much cleaner code.
 623
 624   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 625                         [label],
 626                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 627                                          [iptunnel_pull_offloads],
 628                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 629                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 630                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 631
 632   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 633                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 634   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 635                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 636   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 637                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 638   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 639   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 640   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 641   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 642   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 643   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 644   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 645   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 646   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 647   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 648                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 649   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 650   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 651   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 652   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 653   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 654   dnl So check type of tstats.
 655   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 656                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 657   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 658                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 659   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 660   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 661   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 662                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 663   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 664   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 665   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 666                         [extended])
 667   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 668                         [netdev_master_upper_dev_link], [upper_priv],
 669                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 670   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 671                   [netdev_master_upper_dev_link_rh],
 672                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 673
 674   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 675                         [max_mtu])
 676   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 677                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 678   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 679                         [dev_change_flags], [extack],
 680                         [OVS_DEFINE([HAVE_DEV_CHANGE_FLAGS_TAKES_EXTACK])])
 681
 682   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 683   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state],
 684                         [struct net ], [OVS_DEFINE([HAVE_NF_HOOK_STATE_NET])])
 685   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 686   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 687                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 688   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 689                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 690   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 691                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 692   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 693   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [CONFIG_NF_NAT_NEEDED])
 694
 695
 696   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 697                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 698
 699   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 700                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 701                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 702   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 703                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 704
 705   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 706                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 707                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 708   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 709                   [nf_ct_get_tuplepr], [struct.net],
 710                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 711   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 712                   [nf_ct_set])
 713   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 714                   [nf_ct_is_untracked])
 715   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 716                   [nf_ct_invert_tuplepr])
 717   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 718                   [nf_ct_zone_init])
 719   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 720                   [net_ns_get])
 721   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 722                   [nf_connlabels_get])
 723   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 724                   [nf_connlabels_get], [int bit],
 725                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 726   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 727                         [nf_conn_labels], [words])
 728   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 729   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 730   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 731   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_packet],
 732                   [OVS_DEFINE([HAVE_UPSTREAM_NF_NAT])])
 733   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 734   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 735                   [OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h],
 736                                    [int nf_conncount_add],
 737                                    [], [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])])
 738   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [nf_ct_set_timeout])
 739   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [struct nf_ct_timeout],
 740                   [OVS_DEFINE([HAVE_NF_CT_TIMEOUT])])
 741   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h],
 742                         [\(*nf_ct_timeout_find_get_hook\)], [net],
 743                         [OVS_DEFINE([HAVE_NF_CT_TIMEOUT_FIND_GET_HOOK_NET])])
 744
 745   OVS_GREP_IFELSE([$KSRC/include/linux/random.h],
 746                   [prandom_u32[[\(]]],
 747                   [OVS_DEFINE([HAVE_PRANDOM_U32])])
 748   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 749
 750   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 751   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 752   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 753                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 754   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 755
 756   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 757                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 758                                    [rcu_read_lock_held])])
 759   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 760   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 761   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
 762                         [rtnl_create_link], [extack],
 763                         [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_TAKES_EXTACK])])
 764   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [nf_reset_ct])
 765
 766   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 767   # is necessary because some versions of this header remove the
 768   # member but retain the kerneldoc comment that describes it (which
 769   # starts with @).  The brackets must be doubled because of m4
 770   # quoting rules.
 771   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 772                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 773   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 774   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 775   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 776   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 777   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 778   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 779   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 780                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 781   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 782                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 783   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 784                   [skb_copy_from_linear_data_offset])
 785   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 786                   [skb_reset_tail_pointer])
 787   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 788   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 789                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 790   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 791   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 792   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 793   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 794   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 795   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 796   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 797   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 798                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 799   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 800   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 801                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 802   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 803                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 804   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 805   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 806   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 807   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 808   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 809   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 810   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 811   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 812   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 813
 814   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 815                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 816   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 817                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 818
 819   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 820   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 821
 822   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 823   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 824
 825   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 826   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 827   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 828   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 829                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 830   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 831   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 832                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 833   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_validate_flags])
 834   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 835                         [genl_notify], [net],
 836                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 837
 838
 839   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 840                         [genl_multicast_group], [id])
 841   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 842
 843   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 844   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 845   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 846   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 847   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 848   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 849                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 850   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 851                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 852
 853   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 854   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 855   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 856   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 857   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 858   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 859   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 860   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 861   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_nest_start_noflag])
 862   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 863                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 864   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 865                         [nla_parse], [netlink_ext_ack],
 866                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 867
 868   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 869
 870   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 871   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 872   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 873   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 874   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 875
 876   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 877                         [metadata_dst_alloc], [metadata_type])
 878
 879   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 880
 881   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 882                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 883   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 884                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 885                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 886   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 887   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 888   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 889                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 890   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 891                         [gro_receive])
 892
 893   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 894                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 895   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 896                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 897
 898   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 899   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 900   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 901                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 902   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 903                         [udp_add_offload], [net],
 904                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 905   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 906                         [nf_defrag_ipv6_enable], [net],
 907                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 908   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 909                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 910   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 911                         [needs_free_netdev],
 912                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 913   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 914                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 915   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 916                   [nf_conntrack_helper_put],
 917                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 918   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 919                   [nf_nat_helper_try_module_get])
 920   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 921                   [nf_nat_helper_put])
 922   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 923                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 924   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 925                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 926   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 927                         [extack],
 928                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 929   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 930                         [list],
 931                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 932   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 933                   [IP_CT_UNTRACKED])
 934   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 935                         [netdev_master_upper_dev_link], [extack],
 936                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 937   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 938                   [__LINUX_COMPILER_TYPES_H],
 939                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 940   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 941                   [ktime_get_ts64],
 942                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 943   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 944                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 945                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 946   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 947                   [ktime_get_ns],
 948                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 949   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 950                   frag_percpu_counter_batch[],
 951                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 952   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 953                   [null_compute_pseudo],
 954                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 955   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 956                   [__skb_checksum_convert],
 957                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
 958   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 959                         [max_mtu],
 960                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
 961   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
 962                         [erspan_ver],
 963                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
 964   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 965                   [SKB_GSO_IPXIP6],
 966                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
 967   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
 968                         [ip6_make_flowlabel], [fl6],
 969                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
 970   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
 971                         [auto_flowlabels],
 972                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
 973   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 974                   [netif_keep_dst],
 975                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
 976   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 977                         [ndo_get_iflink],
 978                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
 979   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 980                   [skb_set_inner_ipproto],
 981                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
 982   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 983                   [tunnel_encap_types],
 984                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
 985   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 986                   [IFLA_IPTUN_ENCAP_TYPE],
 987                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
 988   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 989                   [IFLA_IPTUN_COLLECT_METADATA],
 990                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
 991   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 992                   [IFLA_GRE_ENCAP_DPORT])
 993   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 994                   [IFLA_GRE_COLLECT_METADATA])
 995   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 996                   [IFLA_GRE_IGNORE_DF])
 997   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 998                   [IFLA_GRE_FWMARK])
 999   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1000                   [IFLA_GRE_ERSPAN_INDEX])
1001   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1002                   [IFLA_GRE_ERSPAN_HWID])
1003   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1004                   [IFLA_IPTUN_FWMARK])
1005   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1006                         [csum_valid],
1007                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
1008   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1009                         [vlan_present],
1010                         [OVS_DEFINE([HAVE_SKBUFF_VLAN_PRESENT])])
1011   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1012                   [skb_checksum_simple_validate])
1013   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
1014                   [void.*ndo_get_stats64],
1015                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
1016   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
1017                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
1018   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
1019                         [ip_tunnel_info_opts_set], [flags],
1020                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
1021   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
1022                         [rnd],
1023                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
1024   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [__LINUX_OVERFLOW_H],
1025                   [OVS_DEFINE([HAVE_OVERFLOW_H])])
1026   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [struct_size],
1027                   [OVS_DEFINE([HAVE_STRUCT_SIZE])])
1028   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_array],
1029                   [OVS_DEFINE([HAVE_KVMALLOC_ARRAY])])
1030   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_node],
1031                   [OVS_DEFINE([HAVE_KVMALLOC_NODE])])
1032   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
1033                   [nf_conntrack_l3proto],
1034                   [OVS_DEFINE([HAVE_NF_CONNTRACK_L3PROATO_H])])
1035   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_core.h],
1036                         [nf_conntrack_in], [nf_hook_state],
1037                         [OVS_DEFINE([HAVE_NF_CONNTRACK_IN_TAKES_NF_HOOK_STATE])])
1038   OVS_GREP_IFELSE([$KSRC/include/net/ipv6_frag.h], [IP6_DEFRAG_CONNTRACK_IN],
1039                   [OVS_DEFINE([HAVE_IPV6_FRAG_H])])
1040   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
1041                         [nf_ct_helper_ext_add], [nf_conntrack_helper],
1042                         [OVS_DEFINE([HAVE_NF_CT_HELPER_EXT_ADD_TAKES_HELPER])])
1043   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_calc_hlen],
1044                   [OVS_DEFINE([HAVE_GRE_CALC_HLEN])])
1045   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [ip_gre_calc_hlen],
1046                   [OVS_DEFINE([HAVE_IP_GRE_CALC_HLEN])])
1047   OVS_GREP_IFELSE([$KSRC/include/linux/rbtree.h], [rb_link_node_rcu],
1048                   [OVS_DEFINE([HAVE_RBTREE_RB_LINK_NODE_RCU])])
1049   OVS_GREP_IFELSE([$KSRC/include/net/dst_ops.h], [bool confirm_neigh],
1050                   [OVS_DEFINE([HAVE_DST_OPS_CONFIRM_NEIGH])])
1051
1052   if cmp -s datapath/linux/kcompat.h.new \
1053             datapath/linux/kcompat.h >/dev/null 2>&1; then
1054     rm datapath/linux/kcompat.h.new
1055   else
1056     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
1057   fi
1058 ])
1059
1060 dnl Checks for net/if_dl.h.
1061 dnl
1062 dnl (We use this as a proxy for checking whether we're building on FreeBSD
1063 dnl or NetBSD.)
1064 AC_DEFUN([OVS_CHECK_IF_DL],
1065   [AC_CHECK_HEADER([net/if_dl.h],
1066                    [HAVE_IF_DL=yes],
1067                    [HAVE_IF_DL=no])
1068    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
1069    if test "$HAVE_IF_DL" = yes; then
1070       AC_DEFINE([HAVE_IF_DL], [1],
1071                 [Define to 1 if net/if_dl.h is available.])
1072
1073       # On these platforms we use libpcap to access network devices.
1074       AC_SEARCH_LIBS([pcap_open_live], [pcap])
1075    fi])
1076
1077 dnl Checks for buggy strtok_r.
1078 dnl
1079 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
1080 dnl with optimization that can cause segfaults:
1081 dnl
1082 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
1083 AC_DEFUN([OVS_CHECK_STRTOK_R],
1084   [AC_CACHE_CHECK(
1085      [whether strtok_r macro segfaults on some inputs],
1086      [ovs_cv_strtok_r_bug],
1087      [AC_RUN_IFELSE(
1088         [AC_LANG_PROGRAM([#include <stdio.h>
1089                           #include <string.h>
1090                          ],
1091                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
1092                            /* Assume bug is present, because relatively minor
1093                               changes in compiler settings (e.g. optimization
1094                               level) can make it crop up. */
1095                            return 1;
1096                            #else
1097                            char string[] = ":::";
1098                            char *save_ptr = (char *) 0xc0ffee;
1099                            char *token1, *token2;
1100                            token1 = strtok_r(string, ":", &save_ptr);
1101                            token2 = strtok_r(NULL, ":", &save_ptr);
1102                            freopen ("/dev/null", "w", stdout);
1103                            printf ("%s %s\n", token1, token2);
1104                            return 0;
1105                            #endif
1106                           ]])],
1107         [ovs_cv_strtok_r_bug=no],
1108         [ovs_cv_strtok_r_bug=yes],
1109         [ovs_cv_strtok_r_bug=yes])])
1110    if test $ovs_cv_strtok_r_bug = yes; then
1111      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1112                [Define if strtok_r macro segfaults on some inputs])
1113    fi
1114 ])
1115
1116 dnl ----------------------------------------------------------------------
1117 dnl These macros are from GNU PSPP, with the following original license:
1118 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1119 dnl This file is free software; the Free Software Foundation
1120 dnl gives unlimited permission to copy and/or distribute it,
1121 dnl with or without modifications, as long as this notice is preserved.
1122
1123 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1124   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1125   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1126     [ovs_save_CFLAGS="$CFLAGS"
1127      dnl Include -Werror in the compiler options, because without -Werror
1128      dnl clang's GCC-compatible compiler driver does not return a failure
1129      dnl exit status even though it complains about options it does not
1130      dnl understand.
1131      dnl
1132      dnl Also, check stderr as gcc exits with status 0 for options
1133      dnl rejected at getopt level.
1134      dnl    % touch /tmp/a.c
1135      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1136      dnl    gcc: unrecognized option '-Qunused-arguments'
1137      dnl    0
1138      dnl    %
1139      dnl
1140      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1141      dnl it does not understand, unless it has another error to report, so
1142      dnl instead of testing for -Wno-<foo>, test for the positive version.
1143      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1144      AC_COMPILE_IFELSE(
1145        [AC_LANG_SOURCE([int x;])],
1146        [if test -s conftest.err && grep "unrecognized option" conftest.err
1147         then
1148           ovs_cv_name[]=no
1149         else
1150           ovs_cv_name[]=yes
1151         fi],
1152        [ovs_cv_name[]=no])
1153      CFLAGS="$ovs_save_CFLAGS"])
1154   if test $ovs_cv_name = yes; then
1155     m4_if([$2], [], [:], [$2])
1156   else
1157     m4_if([$3], [], [:], [$3])
1158   fi
1159 ])
1160
1161 dnl OVS_CHECK_WERROR
1162 dnl
1163 dnl Check whether the C compiler accepts -Werror.
1164 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1165 AC_DEFUN([OVS_CHECK_WERROR],
1166   [WERROR=
1167    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1168
1169 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1170 dnl Check whether the given C compiler OPTION is accepted.
1171 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1172 AC_DEFUN([OVS_CHECK_CC_OPTION],
1173   [AC_REQUIRE([OVS_CHECK_WERROR])
1174    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1175
1176 dnl OVS_ENABLE_OPTION([OPTION])
1177 dnl Check whether the given C compiler OPTION is accepted.
1178 dnl If so, add it to WARNING_FLAGS.
1179 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1180 AC_DEFUN([OVS_ENABLE_OPTION],
1181   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1182    AC_SUBST([WARNING_FLAGS])])
1183
1184 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1185 dnl Check whether the given C compiler OPTION is accepted.
1186 dnl If so, enable the given Automake CONDITIONAL.
1187
1188 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1189 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1190   [OVS_CHECK_CC_OPTION(
1191     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1192    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1193 dnl ----------------------------------------------------------------------
1194
1195 dnl Check for too-old XenServer.
1196 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1197   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1198     [if test -e /etc/redhat-release; then
1199        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1200      fi
1201      if test -z "$ovs_cv_xsversion"; then
1202        ovs_cv_xsversion=none
1203      fi])
1204   case $ovs_cv_xsversion in
1205     none)
1206       ;;
1207
1208     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1209     [[6-9]]* |                           dnl XenServer 6 or later
1210     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1211     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1212     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1213     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1214       ;;
1215
1216     *)
1217       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1218       ;;
1219   esac])
1220
1221 dnl OVS_CHECK_SPARSE_TARGET
1222 dnl
1223 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1224 dnl target for which the code is being built.  This helps it out.
1225 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1226   [AC_CACHE_CHECK(
1227     [target hint for cgcc],
1228     [ac_cv_sparse_target],
1229     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1230        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1231        [x86_64-*], [ac_cv_sparse_target=x86_64],
1232        [ac_cv_sparse_target=other])])
1233    AS_CASE([$ac_cv_sparse_target],
1234      [x86], [SPARSEFLAGS= CGCCFLAGS="-target=i86 -target=host_os_specs"],
1235      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS="-target=x86_64 -target=host_os_specs"],
1236      [SPARSEFLAGS= CGCCFLAGS=])
1237
1238    dnl Get the default defines for vector instructions from compiler to
1239    dnl allow "sparse" correctly check the same code that will be built.
1240    dnl Required for checking DPDK headers.
1241    AC_MSG_CHECKING([vector options for cgcc])
1242    VECTOR=$($CC -dM -E - < /dev/null | grep -E "MMX|SSE|AVX" | \
1243             cut -c 9- | sed 's/ /=/' | sed 's/^/-D/' | tr '\n' ' ')
1244    AC_MSG_RESULT([$VECTOR])
1245    CGCCFLAGS="$CGCCFLAGS $VECTOR"
1246
1247    AC_SUBST([SPARSEFLAGS])
1248    AC_SUBST([CGCCFLAGS])])
1249
1250 dnl OVS_SPARSE_EXTRA_INCLUDES
1251 dnl
1252 dnl The cgcc script from "sparse" does not search gcc's default
1253 dnl search path. Get the default search path from GCC and pass
1254 dnl them to sparse.
1255 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1256     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1257            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1258
1259 dnl OVS_ENABLE_SPARSE
1260 AC_DEFUN([OVS_ENABLE_SPARSE],
1261   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1262    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1263    : ${SPARSE=sparse}
1264    AC_SUBST([SPARSE])
1265    AC_CONFIG_COMMANDS_PRE(
1266      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1267
1268    AC_ARG_ENABLE(
1269      [sparse],
1270      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1271      [], [enable_sparse=no])
1272    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1273
1274 dnl OVS_CTAGS_IDENTIFIERS
1275 dnl
1276 dnl ctags ignores symbols with extras identifiers. This builds a list of
1277 dnl specially handled identifiers to be ignored.
1278 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1279     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1280            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1281
1282 dnl OVS_PTHREAD_SET_NAME
1283 dnl
1284 dnl This checks for three known variants of pthreads functions for setting
1285 dnl the name of the current thread:
1286 dnl
1287 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1288 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1289 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1290 dnl
1291 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1292 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1293 dnl provide to it.
1294 dnl
1295 dnl This macro defines:
1296 dnl
1297 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1298 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1299 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1300 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1301   [AC_CHECK_FUNCS([pthread_set_name_np])
1302    if test $ac_cv_func_pthread_set_name_np != yes; then
1303      AC_CACHE_CHECK(
1304        [for pthread_setname_np() variant],
1305        [ovs_cv_pthread_setname_np],
1306        [AC_LINK_IFELSE(
1307          [AC_LANG_PROGRAM([#include <pthread.h>
1308   ], [pthread_setname_np(pthread_self(), "name");])],
1309          [ovs_cv_pthread_setname_np=glibc],
1310          [AC_LINK_IFELSE(
1311            [AC_LANG_PROGRAM([#include <pthread.h>
1312 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1313            [ovs_cv_pthread_setname_np=netbsd],
1314            [ovs_cv_pthread_setname_np=none])])])
1315      case $ovs_cv_pthread_setname_np in # (
1316        glibc)
1317           AC_DEFINE(
1318             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1319             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1320           ;; # (
1321        netbsd)
1322           AC_DEFINE(
1323             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1324             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1325           ;;
1326      esac
1327    fi])
1328
1329 dnl OVS_CHECK_LINUX_HOST.
1330 dnl
1331 dnl Checks whether we're building for a Linux host, based on the presence of
1332 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1333 dnl LINUX based on the result.
1334 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1335   [AC_CACHE_CHECK(
1336      [whether __linux__ is defined],
1337      [ovs_cv_linux],
1338      [AC_COMPILE_IFELSE(
1339         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1340         [ovs_cv_linux=true],
1341         [ovs_cv_linux=false])])
1342    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])