acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 4; then
 154        if test "$version" = 4 && test "$patchlevel" -le 18; then
 155           : # Linux 4.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.18.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 160        : # Linux 3.x
 161     else
 162        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 163     fi
 164     if (test ! -e "$KBUILD"/include/linux/version.h && \
 165         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 166        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 167         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 168         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 169     fi
 170     OVS_CHECK_LINUX_COMPAT
 171   fi
 172   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 173 ])
 174
 175 dnl OVS_CHECK_LINUX_TC
 176 dnl
 177 dnl Configure Linux tc compat.
 178 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 179   AC_COMPILE_IFELSE([
 180     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 181         int x = TCA_FLOWER_KEY_ENC_IP_TTL_MASK;
 182     ])],
 183     [AC_DEFINE([HAVE_TCA_FLOWER_KEY_ENC_IP_TTL_MASK], [1],
 184                [Define to 1 if TCA_FLOWER_KEY_ENC_IP_TTL_MASK is available.])])
 185
 186   AC_COMPILE_IFELSE([
 187     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 188         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 189     ])],
 190     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 191                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 192
 193   AC_COMPILE_IFELSE([
 194     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 195         int x = TCA_TUNNEL_KEY_ENC_TTL;
 196     ])],
 197     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 198                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 199
 200   AC_COMPILE_IFELSE([
 201     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 202         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 203     ])],
 204     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 205                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 206 ])
 207
 208 dnl OVS_CHECK_DPDK
 209 dnl
 210 dnl Configure DPDK source tree
 211 AC_DEFUN([OVS_CHECK_DPDK], [
 212   AC_ARG_WITH([dpdk],
 213               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 214                               [Specify the DPDK build directory])],
 215               [have_dpdk=true])
 216
 217   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 218   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 219     AC_MSG_RESULT([no])
 220     DPDKLIB_FOUND=false
 221   else
 222     AC_MSG_RESULT([yes])
 223     case "$with_dpdk" in
 224       yes)
 225         DPDK_AUTO_DISCOVER="true"
 226         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 227             DPDK_INCLUDE="$DPDK_CFLAGS"
 228             DPDK_LIB="$DPDK_LIBS"], [
 229             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 230             DPDK_LIB="-ldpdk"])
 231         ;;
 232       *)
 233         DPDK_AUTO_DISCOVER="false"
 234         DPDK_INCLUDE_PATH="$with_dpdk/include"
 235         # If 'with_dpdk' is passed install directory, point to headers
 236         # installed in $DESTDIR/$prefix/include/dpdk
 237         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 238            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 239         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 240            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 241         fi
 242         DPDK_LIB_DIR="$with_dpdk/lib"
 243         DPDK_LIB="-ldpdk"
 244         ;;
 245     esac
 246
 247     ovs_save_CFLAGS="$CFLAGS"
 248     ovs_save_LDFLAGS="$LDFLAGS"
 249     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 250     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 251       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 252     fi
 253
 254     AC_CHECK_HEADERS([rte_config.h], [], [
 255       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 256     ], [AC_INCLUDES_DEFAULT])
 257
 258     AC_COMPILE_IFELSE([
 259       AC_LANG_PROGRAM(
 260         [
 261           #include <rte_config.h>
 262 #if defined(RTE_LIBRTE_VHOST_NUMA) || defined(RTE_EAL_NUMA_AWARE_HUGEPAGES)
 263 #error
 264 #endif
 265         ], [])
 266       ], [],
 267       [AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])])
 268        AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])])
 269
 270     AC_COMPILE_IFELSE([
 271       AC_LANG_PROGRAM(
 272         [
 273           #include <rte_config.h>
 274 #if RTE_LIBRTE_PMD_PCAP
 275 #error
 276 #endif
 277         ], [])
 278       ], [],
 279       [AC_SEARCH_LIBS([pcap_dump],[pcap],[],[AC_MSG_ERROR([unable to find libpcap, install the dependency package])])
 280        AC_COMPILE_IFELSE([
 281          AC_LANG_PROGRAM(
 282            [
 283              #include <rte_config.h>
 284 #if RTE_LIBRTE_PDUMP
 285 #error
 286 #endif
 287          ], [])
 288        ], [],
 289        [AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])])
 290      ])
 291
 292     AC_COMPILE_IFELSE([
 293       AC_LANG_PROGRAM(
 294         [
 295           #include <rte_config.h>
 296 #if RTE_LIBRTE_MLX5_PMD
 297 #error
 298 #endif
 299         ], [])
 300       ], [],
 301       [AC_SEARCH_LIBS([mnl_attr_put],[mnl],[],[AC_MSG_ERROR([unable to find libmnl, install the dependency package])])
 302        AC_DEFINE([DPDK_MNL], [1], [MLX5 PMD detected in DPDK.])])
 303
 304     # On some systems we have to add -ldl to link with dpdk
 305     #
 306     # This code, at first, tries to link without -ldl (""),
 307     # then adds it and tries again.
 308     # Before each attempt the search cache must be unset,
 309     # otherwise autoconf will stick with the old result
 310
 311     DPDKLIB_FOUND=false
 312     save_LIBS=$LIBS
 313     for extras in "" "-ldl"; do
 314         LIBS="$DPDK_LIB $extras $save_LIBS"
 315         AC_LINK_IFELSE(
 316            [AC_LANG_PROGRAM([#include <rte_config.h>
 317                              #include <rte_eal.h>],
 318                             [int rte_argc; char ** rte_argv;
 319                              rte_eal_init(rte_argc, rte_argv);])],
 320            [DPDKLIB_FOUND=true])
 321         if $DPDKLIB_FOUND; then
 322             break
 323         fi
 324     done
 325
 326     # If linking unsuccessful
 327     if test "$DPDKLIB_FOUND" = "false" ; then
 328       if $DPDK_AUTO_DISCOVER; then
 329         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 330       else
 331         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 332       fi
 333     fi
 334     CFLAGS="$ovs_save_CFLAGS"
 335     LDFLAGS="$ovs_save_LDFLAGS"
 336     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 337       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 338     fi
 339     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 340     OVS_ENABLE_OPTION([-mssse3])
 341
 342     # DPDK pmd drivers are not linked unless --whole-archive is used.
 343     #
 344     # This happens because the rest of the DPDK code doesn't use any symbol in
 345     # the pmd driver objects, and the drivers register themselves using an
 346     # __attribute__((constructor)) function.
 347     #
 348     # These options are specified inside a single -Wl directive to prevent
 349     # autotools from reordering them.
 350     #
 351     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 352     # will already have flagged just the right set of libs with
 353     # --whole-archive - in those cases do not wrap it once more.
 354     case "$DPDK_LIB" in
 355       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 356       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 357     esac
 358     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 359     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 360   fi
 361
 362   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 363 ])
 364
 365 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 366 dnl
 367 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 368 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 369 dnl <REGEX> translated to uppercase.
 370 AC_DEFUN([OVS_GREP_IFELSE], [
 371   AC_MSG_CHECKING([whether $2 matches in $1])
 372   if test -f $1; then
 373     grep '$2' $1 >/dev/null 2>&1
 374     status=$?
 375     case $status in
 376       0)
 377         AC_MSG_RESULT([yes])
 378         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 379         ;;
 380       1)
 381         AC_MSG_RESULT([no])
 382         $4
 383         ;;
 384       *)
 385         AC_MSG_ERROR([grep exited with status $status])
 386         ;;
 387     esac
 388   else
 389     AC_MSG_RESULT([file not found])
 390     $4
 391   fi
 392 ])
 393
 394 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 395 dnl
 396 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 397 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 398 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 399 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 400 dnl translated to uppercase.
 401 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 402   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 403   if test -f $1; then
 404     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 405     status=$?
 406     case $status in
 407       0)
 408         AC_MSG_RESULT([yes])
 409         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 410         ;;
 411       1)
 412         AC_MSG_RESULT([no])
 413         $5
 414         ;;
 415       *)
 416         AC_MSG_ERROR([grep exited with status $status])
 417         ;;
 418     esac
 419   else
 420     AC_MSG_RESULT([file not found])
 421     $5
 422   fi
 423 ])
 424
 425 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 426 dnl
 427 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 428 dnl the function signature starting from the line matching FUNCTION
 429 dnl and ending with the line containing the closing parenthesis.  If
 430 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 431 dnl IF-MATCH is empty then it defines to
 432 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 433 dnl <REGEX> translated to uppercase.
 434 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 435   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 436   if test -f $1; then
 437     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 438     status=$?
 439     case $status in
 440       0)
 441         AC_MSG_RESULT([yes])
 442         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 443         ;;
 444       1)
 445         AC_MSG_RESULT([no])
 446         $5
 447         ;;
 448       *)
 449         AC_MSG_ERROR([grep exited with status $status])
 450         ;;
 451     esac
 452   else
 453     AC_MSG_RESULT([file not found])
 454     $5
 455   fi
 456 ])
 457
 458 dnl OVS_DEFINE(NAME)
 459 dnl
 460 dnl Defines NAME to 1 in kcompat.h.
 461 AC_DEFUN([OVS_DEFINE], [
 462   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 463 ])
 464
 465 dnl OVS_CHECK_LINUX_COMPAT
 466 dnl
 467 dnl Runs various Autoconf checks on the Linux kernel source in
 468 dnl the directory in $KBUILD.
 469 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 470   rm -f datapath/linux/kcompat.h.new
 471   mkdir -p datapath/linux
 472   : > datapath/linux/kcompat.h.new
 473
 474   echo '#include <linux/version.h>
 475 #ifndef RHEL_RELEASE_CODE
 476 #define RHEL_RELEASE_CODE 0
 477 #define RHEL_RELEASE_VERSION(a, b) 0
 478 #endif' >> datapath/linux/kcompat.h.new
 479
 480   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 481                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 482
 483   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 484                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 485
 486   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 487                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 488   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 489
 490   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 491   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 492   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 493
 494   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 495                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 496   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 497                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 498
 499   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 500   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 501
 502   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 503   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 504   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 505   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 506   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 507
 508   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 509   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 510   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 511                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 512   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 513                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 514
 515   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 516                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 517   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 518                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 519   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 520                         [ip_do_fragment], [net],
 521                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 522   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 523                         [ip_local_out], [net],
 524                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 525
 526   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 527
 528   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 529                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 530   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 531   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 532                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 533   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 534                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 535   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 536   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 537   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 538                         [frags_work])
 539   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 540                         [rwlock])
 541   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 542                         [list_evictor])
 543   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 544   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 545                         [sub_frag_mem_limit], [struct.netns_frags],
 546                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 547   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 548                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 549   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 550                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 551
 552   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 553   dnl OVS does not really need ipv6 label field, but its presence signifies that
 554   dnl the stack has all required ipv6 support.
 555   dnl OVS also does not need dst_cache But this dependency allows us to write
 556   dnl much cleaner code.
 557
 558   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 559                         [label],
 560                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 561                                          [iptunnel_pull_offloads],
 562                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 563                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 564                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 565
 566   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 567                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 568   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 569                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 570   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 571                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 572   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 573   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 574   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 575   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 576   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 577   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 578   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 579   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 580   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 581   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 582                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 583   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 584   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 585   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 586   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 587   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 588   dnl So check type of tstats.
 589   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 590                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 591   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 592                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 593   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 594   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 595   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 596                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 597   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 598   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 599   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 600                         [extended])
 601   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 602                         [netdev_master_upper_dev_link], [upper_priv],
 603                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 604   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 605                   [netdev_master_upper_dev_link_rh],
 606                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 607
 608   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 609                         [max_mtu])
 610   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 611                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 612
 613   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 614   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 615   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 616                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 617   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 618                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 619   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 620                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 621   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 622
 623
 624   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 625                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 626
 627   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 628                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 629                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 630   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 631                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 632
 633   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 634                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 635                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 636   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 637                   [nf_ct_get_tuplepr], [struct.net],
 638                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 639   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 640                   [nf_ct_set])
 641   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 642                   [nf_ct_is_untracked])
 643   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 644                   [nf_ct_zone_init])
 645   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 646                   [net_ns_get])
 647   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 648                   [nf_connlabels_get])
 649   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 650                   [nf_connlabels_get], [int bit],
 651                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 652   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 653                         [nf_conn_labels], [words])
 654   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 655   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 656   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 657   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 658   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 659                   [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])
 660
 661   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 662   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 663
 664   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 665   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 666   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 667                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 668   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 669
 670   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 671                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 672                                    [rcu_read_lock_held])])
 673   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 674   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 675
 676   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 677   # is necessary because some versions of this header remove the
 678   # member but retain the kerneldoc comment that describes it (which
 679   # starts with @).  The brackets must be doubled because of m4
 680   # quoting rules.
 681   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 682                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 683   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 684   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 685   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 686   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 687   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 688   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 689   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 690                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 691   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 692                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 693   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 694                   [skb_copy_from_linear_data_offset])
 695   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 696                   [skb_reset_tail_pointer])
 697   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 698   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 699                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 700   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 701   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 702   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 703   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 704   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 705   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 706   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 707   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 708                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 709   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 710   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 711                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 712   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 713                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 714   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 715   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 716   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 717   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 718   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 719   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 720   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 721   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 722   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 723
 724   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 725                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 726   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 727                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 728   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 729                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 730
 731   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 732   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 733
 734   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 735   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 736
 737   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 738   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 739   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 740   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 741                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 742   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 743   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 744                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 745   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 746                         [genl_notify], [net],
 747                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 748
 749
 750   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 751                         [genl_multicast_group], [id])
 752   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 753
 754   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 755   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 756   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 757   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 758   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 759   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 760                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 761   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 762                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 763
 764   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 765   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 766   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 767   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 768   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 769   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 770   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 771   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 772   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 773                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 774   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 775                         [nla_parse], [netlink_ext_ack],
 776                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 777
 778   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 779
 780   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 781                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 782   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 783   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 784   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 785   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 786   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 787
 788   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 789                         [metadata_dst_alloc], [metadata_type])
 790
 791   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 792
 793   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 794                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 795   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 796                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 797                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 798   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 799   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 800   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 801                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 802   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 803                         [gro_receive])
 804
 805   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 806                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 807   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 808                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 809
 810   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 811   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 812   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 813                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 814   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 815                         [udp_add_offload], [net],
 816                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 817   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 818                         [nf_defrag_ipv6_enable], [net],
 819                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 820   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 821                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 822   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 823                         [needs_free_netdev],
 824                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 825   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 826                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 827   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 828                   [nf_conntrack_helper_put],
 829                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 830   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 831                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 832   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 833                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 834   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 835                         [extack],
 836                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 837   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 838                         [list],
 839                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 840   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 841                   [IP_CT_UNTRACKED])
 842   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 843                         [netdev_master_upper_dev_link], [extack],
 844                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 845   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 846                   [__LINUX_COMPILER_TYPES_H],
 847                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 848   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 849                   [ktime_get_ts64],
 850                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 851   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 852                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 853                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 854   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 855                   [ktime_get_ns],
 856                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 857   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 858                   frag_percpu_counter_batch[],
 859                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 860   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 861                   [null_compute_pseudo],
 862                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 863   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 864                   [__skb_checksum_convert],
 865                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
 866   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 867                         [max_mtu],
 868                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
 869   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
 870                         [erspan_ver],
 871                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
 872   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 873                   [SKB_GSO_IPXIP6],
 874                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
 875   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
 876                         [ip6_make_flowlabel], [fl6],
 877                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
 878   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
 879                         [auto_flowlabels],
 880                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
 881   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 882                   [netif_keep_dst],
 883                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
 884   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 885                         [ndo_get_iflink],
 886                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
 887   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 888                   [skb_set_inner_ipproto],
 889                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
 890   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 891                   [tunnel_encap_types],
 892                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
 893   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 894                   [IFLA_IPTUN_ENCAP_TYPE],
 895                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
 896   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 897                   [IFLA_IPTUN_COLLECT_METADATA],
 898                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
 899   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 900                   [IFLA_GRE_ENCAP_DPORT])
 901   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 902                   [IFLA_GRE_COLLECT_METADATA])
 903   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 904                   [IFLA_GRE_IGNORE_DF])
 905   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 906                   [IFLA_GRE_FWMARK])
 907   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 908                   [IFLA_GRE_ERSPAN_INDEX])
 909   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 910                   [IFLA_GRE_ERSPAN_HWID])
 911   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 912                   [IFLA_IPTUN_FWMARK])
 913   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
 914                         [csum_valid],
 915                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
 916   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 917                   [skb_checksum_simple_validate])
 918   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 919                   [void.*ndo_get_stats64],
 920                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
 921   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
 922                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
 923   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
 924                         [ip_tunnel_info_opts_set], [flags],
 925                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
 926   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 927                         [rnd],
 928                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
 929
 930   if cmp -s datapath/linux/kcompat.h.new \
 931             datapath/linux/kcompat.h >/dev/null 2>&1; then
 932     rm datapath/linux/kcompat.h.new
 933   else
 934     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 935   fi
 936 ])
 937
 938 dnl Checks for net/if_dl.h.
 939 dnl
 940 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 941 dnl or NetBSD.)
 942 AC_DEFUN([OVS_CHECK_IF_DL],
 943   [AC_CHECK_HEADER([net/if_dl.h],
 944                    [HAVE_IF_DL=yes],
 945                    [HAVE_IF_DL=no])
 946    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 947    if test "$HAVE_IF_DL" = yes; then
 948       AC_DEFINE([HAVE_IF_DL], [1],
 949                 [Define to 1 if net/if_dl.h is available.])
 950
 951       # On these platforms we use libpcap to access network devices.
 952       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 953    fi])
 954
 955 dnl Checks for buggy strtok_r.
 956 dnl
 957 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 958 dnl with optimization that can cause segfaults:
 959 dnl
 960 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 961 AC_DEFUN([OVS_CHECK_STRTOK_R],
 962   [AC_CACHE_CHECK(
 963      [whether strtok_r macro segfaults on some inputs],
 964      [ovs_cv_strtok_r_bug],
 965      [AC_RUN_IFELSE(
 966         [AC_LANG_PROGRAM([#include <stdio.h>
 967                           #include <string.h>
 968                          ],
 969                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 970                            /* Assume bug is present, because relatively minor
 971                               changes in compiler settings (e.g. optimization
 972                               level) can make it crop up. */
 973                            return 1;
 974                            #else
 975                            char string[] = ":::";
 976                            char *save_ptr = (char *) 0xc0ffee;
 977                            char *token1, *token2;
 978                            token1 = strtok_r(string, ":", &save_ptr);
 979                            token2 = strtok_r(NULL, ":", &save_ptr);
 980                            freopen ("/dev/null", "w", stdout);
 981                            printf ("%s %s\n", token1, token2);
 982                            return 0;
 983                            #endif
 984                           ]])],
 985         [ovs_cv_strtok_r_bug=no],
 986         [ovs_cv_strtok_r_bug=yes],
 987         [ovs_cv_strtok_r_bug=yes])])
 988    if test $ovs_cv_strtok_r_bug = yes; then
 989      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 990                [Define if strtok_r macro segfaults on some inputs])
 991    fi
 992 ])
 993
 994 dnl ----------------------------------------------------------------------
 995 dnl These macros are from GNU PSPP, with the following original license:
 996 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 997 dnl This file is free software; the Free Software Foundation
 998 dnl gives unlimited permission to copy and/or distribute it,
 999 dnl with or without modifications, as long as this notice is preserved.
1000
1001 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1002   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1003   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1004     [ovs_save_CFLAGS="$CFLAGS"
1005      dnl Include -Werror in the compiler options, because without -Werror
1006      dnl clang's GCC-compatible compiler driver does not return a failure
1007      dnl exit status even though it complains about options it does not
1008      dnl understand.
1009      dnl
1010      dnl Also, check stderr as gcc exits with status 0 for options
1011      dnl rejected at getopt level.
1012      dnl    % touch /tmp/a.c
1013      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1014      dnl    gcc: unrecognized option '-Qunused-arguments'
1015      dnl    0
1016      dnl    %
1017      dnl
1018      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1019      dnl it does not understand, unless it has another error to report, so
1020      dnl instead of testing for -Wno-<foo>, test for the positive version.
1021      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1022      AC_COMPILE_IFELSE(
1023        [AC_LANG_SOURCE([int x;])],
1024        [if test -s conftest.err && grep "unrecognized option" conftest.err
1025         then
1026           ovs_cv_name[]=no
1027         else
1028           ovs_cv_name[]=yes
1029         fi],
1030        [ovs_cv_name[]=no])
1031      CFLAGS="$ovs_save_CFLAGS"])
1032   if test $ovs_cv_name = yes; then
1033     m4_if([$2], [], [:], [$2])
1034   else
1035     m4_if([$3], [], [:], [$3])
1036   fi
1037 ])
1038
1039 dnl OVS_CHECK_WERROR
1040 dnl
1041 dnl Check whether the C compiler accepts -Werror.
1042 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1043 AC_DEFUN([OVS_CHECK_WERROR],
1044   [WERROR=
1045    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1046
1047 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1048 dnl Check whether the given C compiler OPTION is accepted.
1049 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1050 AC_DEFUN([OVS_CHECK_CC_OPTION],
1051   [AC_REQUIRE([OVS_CHECK_WERROR])
1052    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1053
1054 dnl OVS_ENABLE_OPTION([OPTION])
1055 dnl Check whether the given C compiler OPTION is accepted.
1056 dnl If so, add it to WARNING_FLAGS.
1057 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1058 AC_DEFUN([OVS_ENABLE_OPTION],
1059   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1060    AC_SUBST([WARNING_FLAGS])])
1061
1062 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1063 dnl Check whether the given C compiler OPTION is accepted.
1064 dnl If so, enable the given Automake CONDITIONAL.
1065
1066 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1067 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1068   [OVS_CHECK_CC_OPTION(
1069     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1070    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1071 dnl ----------------------------------------------------------------------
1072
1073 dnl Check for too-old XenServer.
1074 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1075   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1076     [if test -e /etc/redhat-release; then
1077        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1078      fi
1079      if test -z "$ovs_cv_xsversion"; then
1080        ovs_cv_xsversion=none
1081      fi])
1082   case $ovs_cv_xsversion in
1083     none)
1084       ;;
1085
1086     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1087     [[6-9]]* |                           dnl XenServer 6 or later
1088     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1089     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1090     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1091     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1092       ;;
1093
1094     *)
1095       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1096       ;;
1097   esac])
1098
1099 dnl OVS_CHECK_SPARSE_TARGET
1100 dnl
1101 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1102 dnl target for which the code is being built.  This helps it out.
1103 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1104   [AC_CACHE_CHECK(
1105     [target hint for cgcc],
1106     [ac_cv_sparse_target],
1107     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1108        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1109        [x86_64-*], [ac_cv_sparse_target=x86_64],
1110        [ac_cv_sparse_target=other])])
1111    AS_CASE([$ac_cv_sparse_target],
1112      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
1113      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
1114      [SPARSEFLAGS= CGCCFLAGS=])
1115    AC_SUBST([SPARSEFLAGS])
1116    AC_SUBST([CGCCFLAGS])])
1117
1118 dnl OVS_SPARSE_EXTRA_INCLUDES
1119 dnl
1120 dnl The cgcc script from "sparse" does not search gcc's default
1121 dnl search path. Get the default search path from GCC and pass
1122 dnl them to sparse.
1123 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1124     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1125            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1126
1127 dnl OVS_ENABLE_SPARSE
1128 AC_DEFUN([OVS_ENABLE_SPARSE],
1129   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1130    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1131    : ${SPARSE=sparse}
1132    AC_SUBST([SPARSE])
1133    AC_CONFIG_COMMANDS_PRE(
1134      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1135
1136    AC_ARG_ENABLE(
1137      [sparse],
1138      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1139      [], [enable_sparse=no])
1140    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1141
1142 dnl OVS_CTAGS_IDENTIFIERS
1143 dnl
1144 dnl ctags ignores symbols with extras identifiers. This builds a list of
1145 dnl specially handled identifiers to be ignored.
1146 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1147     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1148            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1149
1150 dnl OVS_PTHREAD_SET_NAME
1151 dnl
1152 dnl This checks for three known variants of pthreads functions for setting
1153 dnl the name of the current thread:
1154 dnl
1155 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1156 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1157 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1158 dnl
1159 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1160 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1161 dnl provide to it.
1162 dnl
1163 dnl This macro defines:
1164 dnl
1165 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1166 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1167 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1168 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1169   [AC_CHECK_FUNCS([pthread_set_name_np])
1170    if test $ac_cv_func_pthread_set_name_np != yes; then
1171      AC_CACHE_CHECK(
1172        [for pthread_setname_np() variant],
1173        [ovs_cv_pthread_setname_np],
1174        [AC_LINK_IFELSE(
1175          [AC_LANG_PROGRAM([#include <pthread.h>
1176   ], [pthread_setname_np(pthread_self(), "name");])],
1177          [ovs_cv_pthread_setname_np=glibc],
1178          [AC_LINK_IFELSE(
1179            [AC_LANG_PROGRAM([#include <pthread.h>
1180 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1181            [ovs_cv_pthread_setname_np=netbsd],
1182            [ovs_cv_pthread_setname_np=none])])])
1183      case $ovs_cv_pthread_setname_np in # (
1184        glibc)
1185           AC_DEFINE(
1186             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1187             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1188           ;; # (
1189        netbsd)
1190           AC_DEFINE(
1191             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1192             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1193           ;;
1194      esac
1195    fi])
1196
1197 dnl OVS_CHECK_LINUX_HOST.
1198 dnl
1199 dnl Checks whether we're building for a Linux host, based on the presence of
1200 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1201 dnl LINUX based on the result.
1202 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1203   [AC_CACHE_CHECK(
1204      [whether __linux__ is defined],
1205      [ovs_cv_linux],
1206      [AC_COMPILE_IFELSE(
1207         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1208         [ovs_cv_linux=true],
1209         [ovs_cv_linux=false])])
1210    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])