acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2019 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 4; then
 154        if test "$version" = 4 && test "$patchlevel" -le 18; then
 155           : # Linux 4.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.18.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 160        : # Linux 3.x
 161     else
 162        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 163     fi
 164     if (test ! -e "$KBUILD"/include/linux/version.h && \
 165         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 166        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 167         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 168         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 169     fi
 170     OVS_CHECK_LINUX_COMPAT
 171   fi
 172   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 173 ])
 174
 175 dnl OVS_CHECK_LINUX_TC
 176 dnl
 177 dnl Configure Linux tc compat.
 178 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 179   AC_COMPILE_IFELSE([
 180     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 181         int x = TCA_FLOWER_KEY_ENC_IP_TTL_MASK;
 182     ])],
 183     [AC_DEFINE([HAVE_TCA_FLOWER_KEY_ENC_IP_TTL_MASK], [1],
 184                [Define to 1 if TCA_FLOWER_KEY_ENC_IP_TTL_MASK is available.])])
 185
 186   AC_COMPILE_IFELSE([
 187     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 188         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 189     ])],
 190     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 191                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 192
 193   AC_COMPILE_IFELSE([
 194     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 195         int x = TCA_TUNNEL_KEY_ENC_TTL;
 196     ])],
 197     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 198                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 199
 200   AC_COMPILE_IFELSE([
 201     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 202         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 203     ])],
 204     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 205                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 206
 207   AC_COMPILE_IFELSE([
 208     AC_LANG_PROGRAM([#include <linux/tc_act/tc_skbedit.h>], [
 209         int x = TCA_SKBEDIT_FLAGS;
 210     ])],
 211     [AC_DEFINE([HAVE_TCA_SKBEDIT_FLAGS], [1],
 212                [Define to 1 if TCA_SKBEDIT_FLAGS is available.])])
 213 ])
 214
 215 dnl OVS_FIND_DEPENDENCY(FUNCTION, SEARCH_LIBS, NAME_TO_PRINT)
 216 dnl
 217 dnl Check for a function in a library list.
 218 AC_DEFUN([OVS_FIND_DEPENDENCY], [
 219   AC_SEARCH_LIBS([$1], [$2], [], [
 220     AC_MSG_ERROR([unable to find $3, install the dependency package])
 221   ])
 222 ])
 223
 224 dnl OVS_CHECK_DPDK
 225 dnl
 226 dnl Configure DPDK source tree
 227 AC_DEFUN([OVS_CHECK_DPDK], [
 228   AC_ARG_WITH([dpdk],
 229               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 230                               [Specify the DPDK build directory])],
 231               [have_dpdk=true])
 232
 233   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 234   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 235     AC_MSG_RESULT([no])
 236     DPDKLIB_FOUND=false
 237   else
 238     AC_MSG_RESULT([yes])
 239     case "$with_dpdk" in
 240       yes)
 241         DPDK_AUTO_DISCOVER="true"
 242         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 243             DPDK_INCLUDE="$DPDK_CFLAGS"
 244             DPDK_LIB="$DPDK_LIBS"], [
 245             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 246             DPDK_LIB="-ldpdk"])
 247         ;;
 248       *)
 249         DPDK_AUTO_DISCOVER="false"
 250         DPDK_INCLUDE_PATH="$with_dpdk/include"
 251         # If 'with_dpdk' is passed install directory, point to headers
 252         # installed in $DESTDIR/$prefix/include/dpdk
 253         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 254            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 255         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 256            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 257         fi
 258         DPDK_LIB_DIR="$with_dpdk/lib"
 259         DPDK_LIB="-ldpdk"
 260         ;;
 261     esac
 262
 263     ovs_save_CFLAGS="$CFLAGS"
 264     ovs_save_LDFLAGS="$LDFLAGS"
 265     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 266     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 267       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 268     fi
 269
 270     AC_CHECK_HEADERS([rte_config.h], [], [
 271       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 272     ], [AC_INCLUDES_DEFAULT])
 273
 274     AC_CHECK_DECLS([RTE_LIBRTE_VHOST_NUMA, RTE_EAL_NUMA_AWARE_HUGEPAGES], [
 275       OVS_FIND_DEPENDENCY([get_mempolicy], [numa], [libnuma])
 276     ], [], [[#include <rte_config.h>]])
 277
 278     AC_CHECK_DECL([RTE_LIBRTE_VHOST_NUMA], [
 279       AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])
 280     ], [], [[#include <rte_config.h>]])
 281
 282     AC_CHECK_DECL([RTE_LIBRTE_PMD_PCAP], [
 283       OVS_FIND_DEPENDENCY([pcap_dump], [pcap], [libpcap])
 284       AC_CHECK_DECL([RTE_LIBRTE_PDUMP], [
 285         AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])
 286       ], [], [[#include <rte_config.h>]])
 287     ], [], [[#include <rte_config.h>]])
 288
 289     AC_CHECK_DECL([RTE_LIBRTE_MLX5_PMD], [dnl found
 290       OVS_FIND_DEPENDENCY([mnl_attr_put], [mnl], [libmnl])
 291       AC_CHECK_DECL([RTE_LIBRTE_MLX5_DLOPEN_DEPS], [], [dnl not found
 292         OVS_FIND_DEPENDENCY([mlx5dv_create_wq], [mlx5], [libmlx5])
 293         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 294       ], [[#include <rte_config.h>]])
 295     ], [], [[#include <rte_config.h>]])
 296
 297     AC_CHECK_DECL([RTE_LIBRTE_MLX4_PMD], [dnl found
 298       AC_CHECK_DECL([RTE_LIBRTE_MLX4_DLOPEN_DEPS], [], [dnl not found
 299         OVS_FIND_DEPENDENCY([mlx4dv_init_obj], [mlx4], [libmlx4])
 300         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 301       ], [[#include <rte_config.h>]])
 302     ], [], [[#include <rte_config.h>]])
 303
 304     # DPDK uses dlopen to load plugins.
 305     OVS_FIND_DEPENDENCY([dlopen], [dl], [libdl])
 306
 307     AC_MSG_CHECKING([whether linking with dpdk works])
 308     LIBS="$DPDK_LIB $LIBS"
 309     AC_LINK_IFELSE(
 310       [AC_LANG_PROGRAM([#include <rte_config.h>
 311                         #include <rte_eal.h>],
 312                        [int rte_argc; char ** rte_argv;
 313                         rte_eal_init(rte_argc, rte_argv);])],
 314       [AC_MSG_RESULT([yes])
 315        DPDKLIB_FOUND=true],
 316       [AC_MSG_RESULT([no])
 317        if test "$DPDK_AUTO_DISCOVER" = "true"; then
 318          AC_MSG_ERROR(m4_normalize([
 319             Could not find DPDK library in default search path, Use --with-dpdk
 320             to specify the DPDK library installed in non-standard location]))
 321        else
 322          AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 323        fi
 324       ])
 325
 326     CFLAGS="$ovs_save_CFLAGS"
 327     LDFLAGS="$ovs_save_LDFLAGS"
 328     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 329       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 330     fi
 331     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 332     OVS_ENABLE_OPTION([-mssse3])
 333
 334     # DPDK pmd drivers are not linked unless --whole-archive is used.
 335     #
 336     # This happens because the rest of the DPDK code doesn't use any symbol in
 337     # the pmd driver objects, and the drivers register themselves using an
 338     # __attribute__((constructor)) function.
 339     #
 340     # These options are specified inside a single -Wl directive to prevent
 341     # autotools from reordering them.
 342     #
 343     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 344     # will already have flagged just the right set of libs with
 345     # --whole-archive - in those cases do not wrap it once more.
 346     case "$DPDK_LIB" in
 347       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 348       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 349     esac
 350     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 351     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 352   fi
 353
 354   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 355 ])
 356
 357 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 358 dnl
 359 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 360 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 361 dnl <REGEX> translated to uppercase.
 362 AC_DEFUN([OVS_GREP_IFELSE], [
 363   AC_MSG_CHECKING([whether $2 matches in $1])
 364   if test -f $1; then
 365     grep '$2' $1 >/dev/null 2>&1
 366     status=$?
 367     case $status in
 368       0)
 369         AC_MSG_RESULT([yes])
 370         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 371         ;;
 372       1)
 373         AC_MSG_RESULT([no])
 374         $4
 375         ;;
 376       *)
 377         AC_MSG_ERROR([grep exited with status $status])
 378         ;;
 379     esac
 380   else
 381     AC_MSG_RESULT([file not found])
 382     $4
 383   fi
 384 ])
 385
 386 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 387 dnl
 388 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 389 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 390 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 391 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 392 dnl translated to uppercase.
 393 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 394   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 395   if test -f $1; then
 396     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 397     status=$?
 398     case $status in
 399       0)
 400         AC_MSG_RESULT([yes])
 401         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 402         ;;
 403       1)
 404         AC_MSG_RESULT([no])
 405         $5
 406         ;;
 407       *)
 408         AC_MSG_ERROR([grep exited with status $status])
 409         ;;
 410     esac
 411   else
 412     AC_MSG_RESULT([file not found])
 413     $5
 414   fi
 415 ])
 416
 417 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 418 dnl
 419 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 420 dnl the function signature starting from the line matching FUNCTION
 421 dnl and ending with the line containing the closing parenthesis.  If
 422 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 423 dnl IF-MATCH is empty then it defines to
 424 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 425 dnl <REGEX> translated to uppercase.
 426 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 427   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 428   if test -f $1; then
 429     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 430     status=$?
 431     case $status in
 432       0)
 433         AC_MSG_RESULT([yes])
 434         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 435         ;;
 436       1)
 437         AC_MSG_RESULT([no])
 438         $5
 439         ;;
 440       *)
 441         AC_MSG_ERROR([grep exited with status $status])
 442         ;;
 443     esac
 444   else
 445     AC_MSG_RESULT([file not found])
 446     $5
 447   fi
 448 ])
 449
 450 dnl OVS_DEFINE(NAME)
 451 dnl
 452 dnl Defines NAME to 1 in kcompat.h.
 453 AC_DEFUN([OVS_DEFINE], [
 454   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 455 ])
 456
 457 dnl OVS_CHECK_LINUX_COMPAT
 458 dnl
 459 dnl Runs various Autoconf checks on the Linux kernel source in
 460 dnl the directory in $KBUILD.
 461 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 462   rm -f datapath/linux/kcompat.h.new
 463   mkdir -p datapath/linux
 464   : > datapath/linux/kcompat.h.new
 465
 466   echo '#include <linux/version.h>
 467 #ifndef RHEL_RELEASE_CODE
 468 #define RHEL_RELEASE_CODE 0
 469 #define RHEL_RELEASE_VERSION(a, b) 0
 470 #endif' >> datapath/linux/kcompat.h.new
 471
 472   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 473                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 474
 475   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 476                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 477
 478   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 479                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 480   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 481
 482   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 483   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 484   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 485
 486   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 487                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 488   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 489                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 490
 491   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 492   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 493
 494   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 495   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 496   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 497   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 498   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 499
 500   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 501   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 502   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 503                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 504   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 505                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 506
 507   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 508                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 509   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 510                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 511   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 512                         [ip_do_fragment], [net],
 513                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 514   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 515                         [ip_local_out], [net],
 516                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 517
 518   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 519
 520   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 521                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 522   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 523   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 524                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 525   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 526                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 527   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 528   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 529   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 530                         [frags_work])
 531   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 532                         [rwlock])
 533   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 534                         [list_evictor])
 535   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 536   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 537                         [sub_frag_mem_limit], [struct.netns_frags],
 538                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 539   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 540                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 541   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 542                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 543
 544   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 545   dnl OVS does not really need ipv6 label field, but its presence signifies that
 546   dnl the stack has all required ipv6 support.
 547   dnl OVS also does not need dst_cache But this dependency allows us to write
 548   dnl much cleaner code.
 549
 550   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 551                         [label],
 552                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 553                                          [iptunnel_pull_offloads],
 554                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 555                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 556                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 557
 558   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 559                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 560   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 561                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 562   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 563                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 564   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 565   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 566   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 567   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 568   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 569   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 570   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 571   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 572   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 573   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 574                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 575   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 576   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 577   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 578   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 579   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 580   dnl So check type of tstats.
 581   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 582                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 583   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 584                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 585   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 586   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 587   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 588                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 589   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 590   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 591   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 592                         [extended])
 593   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 594                         [netdev_master_upper_dev_link], [upper_priv],
 595                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 596   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 597                   [netdev_master_upper_dev_link_rh],
 598                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 599
 600   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 601                         [max_mtu])
 602   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 603                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 604
 605   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 606   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state],
 607                         [struct net ], [OVS_DEFINE([HAVE_NF_HOOK_STATE_NET])])
 608   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 609   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 610                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 611   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 612                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 613   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 614                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 615   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 616
 617
 618   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 619                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 620
 621   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 622                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 623                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 624   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 625                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 626
 627   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 628                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 629                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 630   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 631                   [nf_ct_get_tuplepr], [struct.net],
 632                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 633   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 634                   [nf_ct_set])
 635   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 636                   [nf_ct_is_untracked])
 637   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 638                   [nf_ct_zone_init])
 639   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 640                   [net_ns_get])
 641   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 642                   [nf_connlabels_get])
 643   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 644                   [nf_connlabels_get], [int bit],
 645                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 646   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 647                         [nf_conn_labels], [words])
 648   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 649   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 650   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 651   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 652   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 653                   [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])
 654
 655   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 656   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 657
 658   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 659   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 660   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 661                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 662   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 663
 664   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 665                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 666                                    [rcu_read_lock_held])])
 667   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 668   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 669
 670   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 671   # is necessary because some versions of this header remove the
 672   # member but retain the kerneldoc comment that describes it (which
 673   # starts with @).  The brackets must be doubled because of m4
 674   # quoting rules.
 675   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 676                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 677   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 678   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 679   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 680   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 681   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 682   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 683   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 684                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 685   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 686                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 687   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 688                   [skb_copy_from_linear_data_offset])
 689   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 690                   [skb_reset_tail_pointer])
 691   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 692   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 693                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 694   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 695   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 696   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 697   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 698   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 699   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 700   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 701   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 702                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 703   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 704   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 705                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 706   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 707                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 708   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 709   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 710   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 711   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 712   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 713   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 714   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 715   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 716   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 717
 718   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 719                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 720   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 721                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 722   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 723                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 724
 725   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 726   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 727
 728   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 729   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 730
 731   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 732   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 733   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 734   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 735                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 736   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 737   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 738                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 739   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 740                         [genl_notify], [net],
 741                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 742
 743
 744   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 745                         [genl_multicast_group], [id])
 746   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 747
 748   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 749   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 750   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 751   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 752   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 753   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 754                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 755   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 756                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 757
 758   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 759   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 760   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 761   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 762   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 763   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 764   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 765   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 766   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 767                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 768   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 769                         [nla_parse], [netlink_ext_ack],
 770                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 771
 772   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 773
 774   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 775                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 776   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 777   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 778   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 779   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 780   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 781
 782   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 783                         [metadata_dst_alloc], [metadata_type])
 784
 785   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 786
 787   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 788                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 789   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 790                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 791                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 792   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 793   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 794   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 795                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 796   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 797                         [gro_receive])
 798
 799   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 800                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 801   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 802                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 803
 804   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 805   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 806   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 807                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 808   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 809                         [udp_add_offload], [net],
 810                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 811   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 812                         [nf_defrag_ipv6_enable], [net],
 813                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 814   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 815                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 816   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 817                         [needs_free_netdev],
 818                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 819   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 820                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 821   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 822                   [nf_conntrack_helper_put],
 823                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 824   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 825                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 826   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 827                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 828   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 829                         [extack],
 830                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 831   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 832                         [list],
 833                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 834   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 835                   [IP_CT_UNTRACKED])
 836   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 837                         [netdev_master_upper_dev_link], [extack],
 838                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 839   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 840                   [__LINUX_COMPILER_TYPES_H],
 841                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 842   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 843                   [ktime_get_ts64],
 844                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 845   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 846                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 847                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 848   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 849                   [ktime_get_ns],
 850                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 851   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 852                   frag_percpu_counter_batch[],
 853                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 854   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 855                   [null_compute_pseudo],
 856                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 857   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 858                   [__skb_checksum_convert],
 859                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
 860   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 861                         [max_mtu],
 862                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
 863   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
 864                         [erspan_ver],
 865                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
 866   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 867                   [SKB_GSO_IPXIP6],
 868                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
 869   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
 870                         [ip6_make_flowlabel], [fl6],
 871                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
 872   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
 873                         [auto_flowlabels],
 874                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
 875   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 876                   [netif_keep_dst],
 877                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
 878   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 879                         [ndo_get_iflink],
 880                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
 881   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 882                   [skb_set_inner_ipproto],
 883                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
 884   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 885                   [tunnel_encap_types],
 886                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
 887   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 888                   [IFLA_IPTUN_ENCAP_TYPE],
 889                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
 890   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 891                   [IFLA_IPTUN_COLLECT_METADATA],
 892                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
 893   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 894                   [IFLA_GRE_ENCAP_DPORT])
 895   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 896                   [IFLA_GRE_COLLECT_METADATA])
 897   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 898                   [IFLA_GRE_IGNORE_DF])
 899   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 900                   [IFLA_GRE_FWMARK])
 901   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 902                   [IFLA_GRE_ERSPAN_INDEX])
 903   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 904                   [IFLA_GRE_ERSPAN_HWID])
 905   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 906                   [IFLA_IPTUN_FWMARK])
 907   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
 908                         [csum_valid],
 909                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
 910   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 911                   [skb_checksum_simple_validate])
 912   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 913                   [void.*ndo_get_stats64],
 914                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
 915   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
 916                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
 917   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
 918                         [ip_tunnel_info_opts_set], [flags],
 919                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
 920   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 921                         [rnd],
 922                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
 923   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [__LINUX_OVERFLOW_H],
 924                   [OVS_DEFINE([HAVE_OVERFLOW_H])])
 925   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [struct_size],
 926                   [OVS_DEFINE([HAVE_STRUCT_SIZE])])
 927   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_array],
 928                   [OVS_DEFINE([HAVE_KVMALLOC_ARRAY])])
 929   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_node],
 930                   [OVS_DEFINE([HAVE_KVMALLOC_NODE])])
 931   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 932                   [nf_conntrack_l3proto],
 933                   [OVS_DEFINE([HAVE_NF_CONNTRACK_L3PROATO_H])])
 934   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_core.h],
 935                         [nf_conntrack_in], [nf_hook_state],
 936                         [OVS_DEFINE([HAVE_NF_CONNTRACK_IN_TAKES_NF_HOOK_STATE])])
 937   OVS_GREP_IFELSE([$KSRC/include/net/ipv6_frag.h], [IP6_DEFRAG_CONNTRACK_IN],
 938                   [OVS_DEFINE([HAVE_IPV6_FRAG_H])])
 939
 940   if cmp -s datapath/linux/kcompat.h.new \
 941             datapath/linux/kcompat.h >/dev/null 2>&1; then
 942     rm datapath/linux/kcompat.h.new
 943   else
 944     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 945   fi
 946 ])
 947
 948 dnl Checks for net/if_dl.h.
 949 dnl
 950 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 951 dnl or NetBSD.)
 952 AC_DEFUN([OVS_CHECK_IF_DL],
 953   [AC_CHECK_HEADER([net/if_dl.h],
 954                    [HAVE_IF_DL=yes],
 955                    [HAVE_IF_DL=no])
 956    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 957    if test "$HAVE_IF_DL" = yes; then
 958       AC_DEFINE([HAVE_IF_DL], [1],
 959                 [Define to 1 if net/if_dl.h is available.])
 960
 961       # On these platforms we use libpcap to access network devices.
 962       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 963    fi])
 964
 965 dnl Checks for buggy strtok_r.
 966 dnl
 967 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 968 dnl with optimization that can cause segfaults:
 969 dnl
 970 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 971 AC_DEFUN([OVS_CHECK_STRTOK_R],
 972   [AC_CACHE_CHECK(
 973      [whether strtok_r macro segfaults on some inputs],
 974      [ovs_cv_strtok_r_bug],
 975      [AC_RUN_IFELSE(
 976         [AC_LANG_PROGRAM([#include <stdio.h>
 977                           #include <string.h>
 978                          ],
 979                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 980                            /* Assume bug is present, because relatively minor
 981                               changes in compiler settings (e.g. optimization
 982                               level) can make it crop up. */
 983                            return 1;
 984                            #else
 985                            char string[] = ":::";
 986                            char *save_ptr = (char *) 0xc0ffee;
 987                            char *token1, *token2;
 988                            token1 = strtok_r(string, ":", &save_ptr);
 989                            token2 = strtok_r(NULL, ":", &save_ptr);
 990                            freopen ("/dev/null", "w", stdout);
 991                            printf ("%s %s\n", token1, token2);
 992                            return 0;
 993                            #endif
 994                           ]])],
 995         [ovs_cv_strtok_r_bug=no],
 996         [ovs_cv_strtok_r_bug=yes],
 997         [ovs_cv_strtok_r_bug=yes])])
 998    if test $ovs_cv_strtok_r_bug = yes; then
 999      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1000                [Define if strtok_r macro segfaults on some inputs])
1001    fi
1002 ])
1003
1004 dnl ----------------------------------------------------------------------
1005 dnl These macros are from GNU PSPP, with the following original license:
1006 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1007 dnl This file is free software; the Free Software Foundation
1008 dnl gives unlimited permission to copy and/or distribute it,
1009 dnl with or without modifications, as long as this notice is preserved.
1010
1011 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1012   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1013   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1014     [ovs_save_CFLAGS="$CFLAGS"
1015      dnl Include -Werror in the compiler options, because without -Werror
1016      dnl clang's GCC-compatible compiler driver does not return a failure
1017      dnl exit status even though it complains about options it does not
1018      dnl understand.
1019      dnl
1020      dnl Also, check stderr as gcc exits with status 0 for options
1021      dnl rejected at getopt level.
1022      dnl    % touch /tmp/a.c
1023      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1024      dnl    gcc: unrecognized option '-Qunused-arguments'
1025      dnl    0
1026      dnl    %
1027      dnl
1028      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1029      dnl it does not understand, unless it has another error to report, so
1030      dnl instead of testing for -Wno-<foo>, test for the positive version.
1031      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1032      AC_COMPILE_IFELSE(
1033        [AC_LANG_SOURCE([int x;])],
1034        [if test -s conftest.err && grep "unrecognized option" conftest.err
1035         then
1036           ovs_cv_name[]=no
1037         else
1038           ovs_cv_name[]=yes
1039         fi],
1040        [ovs_cv_name[]=no])
1041      CFLAGS="$ovs_save_CFLAGS"])
1042   if test $ovs_cv_name = yes; then
1043     m4_if([$2], [], [:], [$2])
1044   else
1045     m4_if([$3], [], [:], [$3])
1046   fi
1047 ])
1048
1049 dnl OVS_CHECK_WERROR
1050 dnl
1051 dnl Check whether the C compiler accepts -Werror.
1052 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1053 AC_DEFUN([OVS_CHECK_WERROR],
1054   [WERROR=
1055    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1056
1057 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1058 dnl Check whether the given C compiler OPTION is accepted.
1059 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1060 AC_DEFUN([OVS_CHECK_CC_OPTION],
1061   [AC_REQUIRE([OVS_CHECK_WERROR])
1062    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1063
1064 dnl OVS_ENABLE_OPTION([OPTION])
1065 dnl Check whether the given C compiler OPTION is accepted.
1066 dnl If so, add it to WARNING_FLAGS.
1067 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1068 AC_DEFUN([OVS_ENABLE_OPTION],
1069   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1070    AC_SUBST([WARNING_FLAGS])])
1071
1072 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1073 dnl Check whether the given C compiler OPTION is accepted.
1074 dnl If so, enable the given Automake CONDITIONAL.
1075
1076 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1077 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1078   [OVS_CHECK_CC_OPTION(
1079     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1080    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1081 dnl ----------------------------------------------------------------------
1082
1083 dnl Check for too-old XenServer.
1084 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1085   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1086     [if test -e /etc/redhat-release; then
1087        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1088      fi
1089      if test -z "$ovs_cv_xsversion"; then
1090        ovs_cv_xsversion=none
1091      fi])
1092   case $ovs_cv_xsversion in
1093     none)
1094       ;;
1095
1096     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1097     [[6-9]]* |                           dnl XenServer 6 or later
1098     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1099     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1100     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1101     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1102       ;;
1103
1104     *)
1105       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1106       ;;
1107   esac])
1108
1109 dnl OVS_CHECK_SPARSE_TARGET
1110 dnl
1111 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1112 dnl target for which the code is being built.  This helps it out.
1113 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1114   [AC_CACHE_CHECK(
1115     [target hint for cgcc],
1116     [ac_cv_sparse_target],
1117     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1118        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1119        [x86_64-*], [ac_cv_sparse_target=x86_64],
1120        [ac_cv_sparse_target=other])])
1121    AS_CASE([$ac_cv_sparse_target],
1122      [x86], [SPARSEFLAGS= CGCCFLAGS="-target=i86 -target=host_os_specs"],
1123      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS="-target=x86_64 -target=host_os_specs"],
1124      [SPARSEFLAGS= CGCCFLAGS=])
1125    AC_SUBST([SPARSEFLAGS])
1126    AC_SUBST([CGCCFLAGS])])
1127
1128 dnl OVS_SPARSE_EXTRA_INCLUDES
1129 dnl
1130 dnl The cgcc script from "sparse" does not search gcc's default
1131 dnl search path. Get the default search path from GCC and pass
1132 dnl them to sparse.
1133 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1134     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1135            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1136
1137 dnl OVS_ENABLE_SPARSE
1138 AC_DEFUN([OVS_ENABLE_SPARSE],
1139   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1140    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1141    : ${SPARSE=sparse}
1142    AC_SUBST([SPARSE])
1143    AC_CONFIG_COMMANDS_PRE(
1144      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1145
1146    AC_ARG_ENABLE(
1147      [sparse],
1148      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1149      [], [enable_sparse=no])
1150    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1151
1152 dnl OVS_CTAGS_IDENTIFIERS
1153 dnl
1154 dnl ctags ignores symbols with extras identifiers. This builds a list of
1155 dnl specially handled identifiers to be ignored.
1156 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1157     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1158            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1159
1160 dnl OVS_PTHREAD_SET_NAME
1161 dnl
1162 dnl This checks for three known variants of pthreads functions for setting
1163 dnl the name of the current thread:
1164 dnl
1165 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1166 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1167 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1168 dnl
1169 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1170 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1171 dnl provide to it.
1172 dnl
1173 dnl This macro defines:
1174 dnl
1175 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1176 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1177 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1178 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1179   [AC_CHECK_FUNCS([pthread_set_name_np])
1180    if test $ac_cv_func_pthread_set_name_np != yes; then
1181      AC_CACHE_CHECK(
1182        [for pthread_setname_np() variant],
1183        [ovs_cv_pthread_setname_np],
1184        [AC_LINK_IFELSE(
1185          [AC_LANG_PROGRAM([#include <pthread.h>
1186   ], [pthread_setname_np(pthread_self(), "name");])],
1187          [ovs_cv_pthread_setname_np=glibc],
1188          [AC_LINK_IFELSE(
1189            [AC_LANG_PROGRAM([#include <pthread.h>
1190 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1191            [ovs_cv_pthread_setname_np=netbsd],
1192            [ovs_cv_pthread_setname_np=none])])])
1193      case $ovs_cv_pthread_setname_np in # (
1194        glibc)
1195           AC_DEFINE(
1196             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1197             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1198           ;; # (
1199        netbsd)
1200           AC_DEFINE(
1201             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1202             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1203           ;;
1204      esac
1205    fi])
1206
1207 dnl OVS_CHECK_LINUX_HOST.
1208 dnl
1209 dnl Checks whether we're building for a Linux host, based on the presence of
1210 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1211 dnl LINUX based on the result.
1212 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1213   [AC_CACHE_CHECK(
1214      [whether __linux__ is defined],
1215      [ovs_cv_linux],
1216      [AC_COMPILE_IFELSE(
1217         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1218         [ovs_cv_linux=true],
1219         [ovs_cv_linux=false])])
1220    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])