acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 4; then
 154        if test "$version" = 4 && test "$patchlevel" -le 15; then
 155           : # Linux 4.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.15.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 160        : # Linux 3.x
 161     else
 162        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 163     fi
 164     if (test ! -e "$KBUILD"/include/linux/version.h && \
 165         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 166        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 167         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 168         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 169     fi
 170     OVS_CHECK_LINUX_COMPAT
 171   fi
 172   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 173 ])
 174
 175 dnl OVS_CHECK_LINUX_TC
 176 dnl
 177 dnl Configure Linux tc compat.
 178 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 179   AC_COMPILE_IFELSE([
 180     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 181         int x = TCA_FLOWER_KEY_FLAGS_FRAG_IS_FIRST;
 182     ])],
 183     [AC_DEFINE([HAVE_TCA_FLOWER_KEY_FLAGS_FRAG_IS_FIRST], [1],
 184                [Define to 1 if TCA_FLOWER_KEY_FLAGS_FRAG_IS_FIRST is avaiable.])])
 185
 186   AC_COMPILE_IFELSE([
 187     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 188         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 189     ])],
 190     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 191                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is avaiable.])])
 192
 193   AC_COMPILE_IFELSE([
 194     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 195         int x = TCA_TUNNEL_KEY_ENC_DST_PORT;
 196     ])],
 197     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_DST_PORT], [1],
 198                [Define to 1 if TCA_TUNNEL_KEY_ENC_DST_PORT is avaiable.])])
 199
 200   AC_COMPILE_IFELSE([
 201     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 202         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 203     ])],
 204     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 205                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is avaiable.])])
 206 ])
 207
 208 dnl OVS_CHECK_DPDK
 209 dnl
 210 dnl Configure DPDK source tree
 211 AC_DEFUN([OVS_CHECK_DPDK], [
 212   AC_ARG_WITH([dpdk],
 213               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 214                               [Specify the DPDK build directory])],
 215               [have_dpdk=true])
 216
 217   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 218   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 219     AC_MSG_RESULT([no])
 220     DPDKLIB_FOUND=false
 221   else
 222     AC_MSG_RESULT([yes])
 223     case "$with_dpdk" in
 224       yes)
 225         DPDK_AUTO_DISCOVER="true"
 226         PKG_CHECK_MODULES([DPDK], [libdpdk],
 227                           [DPDK_INCLUDE="$DPDK_CFLAGS"],
 228                           [DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"])
 229         ;;
 230       *)
 231         DPDK_AUTO_DISCOVER="false"
 232         DPDK_INCLUDE_PATH="$with_dpdk/include"
 233         # If 'with_dpdk' is passed install directory, point to headers
 234         # installed in $DESTDIR/$prefix/include/dpdk
 235         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 236            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 237         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 238            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 239         fi
 240         DPDK_LIB_DIR="$with_dpdk/lib"
 241         ;;
 242     esac
 243
 244     DPDK_LIB="-ldpdk"
 245     DPDK_EXTRA_LIB=""
 246
 247     ovs_save_CFLAGS="$CFLAGS"
 248     ovs_save_LDFLAGS="$LDFLAGS"
 249     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 250     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 251       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 252     fi
 253
 254     AC_COMPILE_IFELSE([
 255       AC_LANG_PROGRAM(
 256         [
 257           #include <rte_config.h>
 258 #if RTE_LIBRTE_VHOST_NUMA
 259 #error
 260 #endif
 261         ], [])
 262       ], [],
 263       [AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])])
 264        DPDK_EXTRA_LIB="-lnuma"
 265        AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])])
 266
 267     AC_COMPILE_IFELSE([
 268       AC_LANG_PROGRAM(
 269         [
 270           #include <rte_config.h>
 271 #if RTE_LIBRTE_PMD_PCAP
 272 #error
 273 #endif
 274         ], [])
 275       ], [],
 276       [AC_SEARCH_LIBS([pcap_dump],[pcap],[],[AC_MSG_ERROR([unable to find libpcap, install the dependency package])])
 277        DPDK_EXTRA_LIB="-lpcap"
 278        AC_COMPILE_IFELSE([
 279          AC_LANG_PROGRAM(
 280            [
 281              #include <rte_config.h>
 282 #if RTE_LIBRTE_PDUMP
 283 #error
 284 #endif
 285          ], [])
 286        ], [],
 287        [AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])])
 288      ])
 289
 290     # On some systems we have to add -ldl to link with dpdk
 291     #
 292     # This code, at first, tries to link without -ldl (""),
 293     # then adds it and tries again.
 294     # Before each attempt the search cache must be unset,
 295     # otherwise autoconf will stick with the old result
 296
 297     DPDKLIB_FOUND=false
 298     save_LIBS=$LIBS
 299     for extras in "" "-ldl"; do
 300         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 301         AC_LINK_IFELSE(
 302            [AC_LANG_PROGRAM([#include <rte_config.h>
 303                              #include <rte_eal.h>],
 304                             [int rte_argc; char ** rte_argv;
 305                              rte_eal_init(rte_argc, rte_argv);])],
 306            [DPDKLIB_FOUND=true])
 307         if $DPDKLIB_FOUND; then
 308             break
 309         fi
 310     done
 311
 312     # If linking unsuccessful
 313     if test "$DPDKLIB_FOUND" = "false" ; then
 314       if $DPDK_AUTO_DISCOVER; then
 315         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 316       else
 317         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 318       fi
 319     fi
 320     CFLAGS="$ovs_save_CFLAGS"
 321     LDFLAGS="$ovs_save_LDFLAGS"
 322     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 323       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 324     fi
 325     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 326     OVS_ENABLE_OPTION([-mssse3])
 327
 328     # DPDK pmd drivers are not linked unless --whole-archive is used.
 329     #
 330     # This happens because the rest of the DPDK code doesn't use any symbol in
 331     # the pmd driver objects, and the drivers register themselves using an
 332     # __attribute__((constructor)) function.
 333     #
 334     # These options are specified inside a single -Wl directive to prevent
 335     # autotools from reordering them.
 336     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 337     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 338     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 339   fi
 340
 341   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 342 ])
 343
 344 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 345 dnl
 346 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 347 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 348 dnl <REGEX> translated to uppercase.
 349 AC_DEFUN([OVS_GREP_IFELSE], [
 350   AC_MSG_CHECKING([whether $2 matches in $1])
 351   if test -f $1; then
 352     grep '$2' $1 >/dev/null 2>&1
 353     status=$?
 354     case $status in
 355       0)
 356         AC_MSG_RESULT([yes])
 357         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 358         ;;
 359       1)
 360         AC_MSG_RESULT([no])
 361         $4
 362         ;;
 363       *)
 364         AC_MSG_ERROR([grep exited with status $status])
 365         ;;
 366     esac
 367   else
 368     AC_MSG_RESULT([file not found])
 369     $4
 370   fi
 371 ])
 372
 373 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 374 dnl
 375 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 376 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 377 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 378 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 379 dnl translated to uppercase.
 380 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 381   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 382   if test -f $1; then
 383     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 384     status=$?
 385     case $status in
 386       0)
 387         AC_MSG_RESULT([yes])
 388         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 389         ;;
 390       1)
 391         AC_MSG_RESULT([no])
 392         $5
 393         ;;
 394       *)
 395         AC_MSG_ERROR([grep exited with status $status])
 396         ;;
 397     esac
 398   else
 399     AC_MSG_RESULT([file not found])
 400     $5
 401   fi
 402 ])
 403
 404 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 405 dnl
 406 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 407 dnl the function signature starting from the line matching FUNCTION
 408 dnl and ending with the line containing the closing parenthesis.  If
 409 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 410 dnl IF-MATCH is empty then it defines to
 411 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 412 dnl <REGEX> translated to uppercase.
 413 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 414   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 415   if test -f $1; then
 416     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 417     status=$?
 418     case $status in
 419       0)
 420         AC_MSG_RESULT([yes])
 421         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 422         ;;
 423       1)
 424         AC_MSG_RESULT([no])
 425         $5
 426         ;;
 427       *)
 428         AC_MSG_ERROR([grep exited with status $status])
 429         ;;
 430     esac
 431   else
 432     AC_MSG_RESULT([file not found])
 433     $5
 434   fi
 435 ])
 436
 437 dnl OVS_DEFINE(NAME)
 438 dnl
 439 dnl Defines NAME to 1 in kcompat.h.
 440 AC_DEFUN([OVS_DEFINE], [
 441   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 442 ])
 443
 444 dnl OVS_CHECK_LINUX_COMPAT
 445 dnl
 446 dnl Runs various Autoconf checks on the Linux kernel source in
 447 dnl the directory in $KBUILD.
 448 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 449   rm -f datapath/linux/kcompat.h.new
 450   mkdir -p datapath/linux
 451   : > datapath/linux/kcompat.h.new
 452
 453   echo '#include <linux/version.h>
 454 #ifndef RHEL_RELEASE_CODE
 455 #define RHEL_RELEASE_CODE 0
 456 #define RHEL_RELEASE_VERSION(a, b) 0
 457 #endif' >> datapath/linux/kcompat.h.new
 458
 459   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 460                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 461
 462   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 463                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 464   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 465
 466   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 467   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 468   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 469
 470   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 471   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 472
 473   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 474   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 475   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 476   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 477   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 478
 479   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 480   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 481   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 482                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 483   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 484                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 485
 486   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 487                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 488   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 489                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 490   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 491                         [ip_do_fragment], [net],
 492                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 493   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 494                         [ip_local_out], [net],
 495                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 496
 497   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 498
 499   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 500                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 501   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 502   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 503                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 504   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 505                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 506   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 507   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 508   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 509                         [frags_work])
 510   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 511                         [rwlock])
 512   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 513                         [list_evictor])
 514   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 515   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 516                         [sub_frag_mem_limit], [struct.netns_frags],
 517                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 518   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 519                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 520   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 521                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 522
 523   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 524   dnl OVS does not really need ipv6 label field, but its presence signifies that
 525   dnl the stack has all required ipv6 support.
 526   dnl OVS also does not need dst_cache But this dependency allows us to write
 527   dnl much cleaner code.
 528
 529   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 530                         [label],
 531                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 532                                          [iptunnel_pull_offloads],
 533                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 534                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])
 535
 536   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 537                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 538   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 539                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 540   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 541   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 542   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 543   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 544   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 545   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 546   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 547   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 548   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 549   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 550                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 551   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 552   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 553   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 554   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 555   dnl So check type of tstats.
 556   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 557                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 558   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 559                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 560   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 561   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 562   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 563                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 564   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 565   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 566   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 567                         [extended])
 568   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 569                         [netdev_master_upper_dev_link], [upper_priv],
 570                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 571   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 572                   [netdev_master_upper_dev_link_rh],
 573                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 574
 575   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 576                         [max_mtu])
 577
 578   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 579   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 580   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 581                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 582   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 583                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 584   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 585                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 586
 587   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 588                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 589
 590   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 591                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 592                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 593   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 594                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 595
 596   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 597                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 598                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 599   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 600                   [nf_ct_get_tuplepr], [struct.net],
 601                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 602   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 603                   [nf_ct_set])
 604   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 605                   [nf_ct_is_untracked])
 606   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 607                   [nf_ct_zone_init])
 608   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 609                   [nf_connlabels_get])
 610   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 611                   [nf_connlabels_get], [int bit],
 612                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 613   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 614                         [nf_conn_labels], [words])
 615   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 616   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 617   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 618
 619   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 620   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 621
 622   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 623   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 624   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 625                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 626   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 627
 628   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 629                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 630                                    [rcu_read_lock_held])])
 631   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 632
 633   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 634   # is necessary because some versions of this header remove the
 635   # member but retain the kerneldoc comment that describes it (which
 636   # starts with @).  The brackets must be doubled because of m4
 637   # quoting rules.
 638   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 639                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 640   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 641   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 642   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 643   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 644   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 645   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 646   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 647                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 648   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 649                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 650   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 651                   [skb_copy_from_linear_data_offset])
 652   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 653                   [skb_reset_tail_pointer])
 654   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 655   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 656                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 657   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 658   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 659   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 660   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 661   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 662   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 663   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 664   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 665                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 666   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 667   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 668                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 669   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 670                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 671   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 672   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 673   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 674   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 675   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 676   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 677   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 678   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 679   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 680
 681   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 682                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 683   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 684                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 685   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 686                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 687
 688   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 689   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 690
 691   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 692   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 693
 694   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 695   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 696   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 697   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 698                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 699   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 700   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 701                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 702   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 703                         [genl_notify], [net],
 704                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 705
 706
 707   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 708                         [genl_multicast_group], [id])
 709   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 710
 711   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 712   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 713   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 714   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 715   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 716   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 717                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 718   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 719                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 720
 721   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 722   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 723   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 724   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 725   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 726   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 727   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 728   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 729   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 730                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 731   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 732                         [nla_parse], [netlink_ext_ack],
 733                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 734
 735   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 736
 737   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 738                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 739   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 740   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 741   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 742   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 743   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 744
 745   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 746                         [metadata_dst_alloc], [metadata_type])
 747
 748   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 749
 750   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 751                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 752   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 753                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 754                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 755   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 756   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 757   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 758                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 759   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 760                         [gro_receive])
 761
 762   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 763                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 764   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 765                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 766
 767   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 768   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 769   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 770                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 771   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 772                         [udp_add_offload], [net],
 773                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 774   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 775                         [nf_defrag_ipv6_enable], [net],
 776                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 777   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 778                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 779   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 780                         [needs_free_netdev],
 781                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 782   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 783                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 784   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 785                   [nf_conntrack_helper_put],
 786                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 787   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 788                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 789   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 790                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 791   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 792                         [extack],
 793                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 794   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 795                         [list],
 796                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 797   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 798                   [IP_CT_UNTRACKED])
 799   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 800                         [netdev_master_upper_dev_link], [extack],
 801                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 802   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 803                   [__LINUX_COMPILER_TYPES_H],
 804                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 805   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 806                   [ktime_get_ts64],
 807                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 808   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 809                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 810                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 811   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 812                   [ktime_get_ns],
 813                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 814   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 815                   frag_percpu_counter_batch[],
 816                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 817
 818
 819   if cmp -s datapath/linux/kcompat.h.new \
 820             datapath/linux/kcompat.h >/dev/null 2>&1; then
 821     rm datapath/linux/kcompat.h.new
 822   else
 823     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 824   fi
 825 ])
 826
 827 dnl Checks for net/if_packet.h.
 828 AC_DEFUN([OVS_CHECK_IF_PACKET],
 829   [AC_CHECK_HEADER([net/if_packet.h],
 830                    [HAVE_IF_PACKET=yes],
 831                    [HAVE_IF_PACKET=no])
 832    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 833    if test "$HAVE_IF_PACKET" = yes; then
 834       AC_DEFINE([HAVE_IF_PACKET], [1],
 835                 [Define to 1 if net/if_packet.h is available.])
 836    fi])
 837
 838 dnl Checks for net/if_dl.h.
 839 dnl
 840 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 841 dnl or NetBSD.)
 842 AC_DEFUN([OVS_CHECK_IF_DL],
 843   [AC_CHECK_HEADER([net/if_dl.h],
 844                    [HAVE_IF_DL=yes],
 845                    [HAVE_IF_DL=no])
 846    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 847    if test "$HAVE_IF_DL" = yes; then
 848       AC_DEFINE([HAVE_IF_DL], [1],
 849                 [Define to 1 if net/if_dl.h is available.])
 850
 851       # On these platforms we use libpcap to access network devices.
 852       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 853    fi])
 854
 855 dnl Checks for buggy strtok_r.
 856 dnl
 857 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 858 dnl with optimization that can cause segfaults:
 859 dnl
 860 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 861 AC_DEFUN([OVS_CHECK_STRTOK_R],
 862   [AC_CACHE_CHECK(
 863      [whether strtok_r macro segfaults on some inputs],
 864      [ovs_cv_strtok_r_bug],
 865      [AC_RUN_IFELSE(
 866         [AC_LANG_PROGRAM([#include <stdio.h>
 867                           #include <string.h>
 868                          ],
 869                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 870                            /* Assume bug is present, because relatively minor
 871                               changes in compiler settings (e.g. optimization
 872                               level) can make it crop up. */
 873                            return 1;
 874                            #else
 875                            char string[] = ":::";
 876                            char *save_ptr = (char *) 0xc0ffee;
 877                            char *token1, *token2;
 878                            token1 = strtok_r(string, ":", &save_ptr);
 879                            token2 = strtok_r(NULL, ":", &save_ptr);
 880                            freopen ("/dev/null", "w", stdout);
 881                            printf ("%s %s\n", token1, token2);
 882                            return 0;
 883                            #endif
 884                           ]])],
 885         [ovs_cv_strtok_r_bug=no],
 886         [ovs_cv_strtok_r_bug=yes],
 887         [ovs_cv_strtok_r_bug=yes])])
 888    if test $ovs_cv_strtok_r_bug = yes; then
 889      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 890                [Define if strtok_r macro segfaults on some inputs])
 891    fi
 892 ])
 893
 894 dnl ----------------------------------------------------------------------
 895 dnl These macros are from GNU PSPP, with the following original license:
 896 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 897 dnl This file is free software; the Free Software Foundation
 898 dnl gives unlimited permission to copy and/or distribute it,
 899 dnl with or without modifications, as long as this notice is preserved.
 900
 901 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 902   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
 903   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 904     [ovs_save_CFLAGS="$CFLAGS"
 905      dnl Include -Werror in the compiler options, because without -Werror
 906      dnl clang's GCC-compatible compiler driver does not return a failure
 907      dnl exit status even though it complains about options it does not
 908      dnl understand.
 909      dnl
 910      dnl Also, check stderr as gcc exits with status 0 for options
 911      dnl rejected at getopt level.
 912      dnl    % touch /tmp/a.c
 913      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 914      dnl    gcc: unrecognized option '-Qunused-arguments'
 915      dnl    0
 916      dnl    %
 917      CFLAGS="$CFLAGS $WERROR $1"
 918      AC_COMPILE_IFELSE(
 919        [AC_LANG_SOURCE([int x;])],
 920        [if test -s conftest.err && grep "unrecognized option" conftest.err
 921         then
 922           ovs_cv_name[]=no
 923         else
 924           ovs_cv_name[]=yes
 925         fi],
 926        [ovs_cv_name[]=no])
 927      CFLAGS="$ovs_save_CFLAGS"])
 928   if test $ovs_cv_name = yes; then
 929     m4_if([$2], [], [:], [$2])
 930   else
 931     m4_if([$3], [], [:], [$3])
 932   fi
 933 ])
 934
 935 dnl OVS_CHECK_WERROR
 936 dnl
 937 dnl Check whether the C compiler accepts -Werror.
 938 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 939 AC_DEFUN([OVS_CHECK_WERROR],
 940   [WERROR=
 941    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 942
 943 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 944 dnl Check whether the given C compiler OPTION is accepted.
 945 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 946 AC_DEFUN([OVS_CHECK_CC_OPTION],
 947   [AC_REQUIRE([OVS_CHECK_WERROR])
 948    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 949
 950 dnl OVS_ENABLE_OPTION([OPTION])
 951 dnl Check whether the given C compiler OPTION is accepted.
 952 dnl If so, add it to WARNING_FLAGS.
 953 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 954 AC_DEFUN([OVS_ENABLE_OPTION],
 955   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 956    AC_SUBST([WARNING_FLAGS])])
 957
 958 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 959 dnl Check whether the given C compiler OPTION is accepted.
 960 dnl If so, enable the given Automake CONDITIONAL.
 961
 962 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 963 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 964   [OVS_CHECK_CC_OPTION(
 965     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 966    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 967 dnl ----------------------------------------------------------------------
 968
 969 dnl Check for too-old XenServer.
 970 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 971   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 972     [if test -e /etc/redhat-release; then
 973        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 974      fi
 975      if test -z "$ovs_cv_xsversion"; then
 976        ovs_cv_xsversion=none
 977      fi])
 978   case $ovs_cv_xsversion in
 979     none)
 980       ;;
 981
 982     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 983     [[6-9]]* |                           dnl XenServer 6 or later
 984     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 985     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 986     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 987     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 988       ;;
 989
 990     *)
 991       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 992       ;;
 993   esac])
 994
 995 dnl OVS_CHECK_SPARSE_TARGET
 996 dnl
 997 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 998 dnl target for which the code is being built.  This helps it out.
 999 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1000   [AC_CACHE_CHECK(
1001     [target hint for cgcc],
1002     [ac_cv_sparse_target],
1003     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1004        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1005        [x86_64-*], [ac_cv_sparse_target=x86_64],
1006        [ac_cv_sparse_target=other])])
1007    AS_CASE([$ac_cv_sparse_target],
1008      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
1009      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
1010      [SPARSEFLAGS= CGCCFLAGS=])
1011    AC_SUBST([SPARSEFLAGS])
1012    AC_SUBST([CGCCFLAGS])])
1013
1014 dnl OVS_SPARSE_EXTRA_INCLUDES
1015 dnl
1016 dnl The cgcc script from "sparse" does not search gcc's default
1017 dnl search path. Get the default search path from GCC and pass
1018 dnl them to sparse.
1019 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1020     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1021            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1022
1023 dnl OVS_ENABLE_SPARSE
1024 AC_DEFUN([OVS_ENABLE_SPARSE],
1025   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1026    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1027    : ${SPARSE=sparse}
1028    AC_SUBST([SPARSE])
1029    AC_CONFIG_COMMANDS_PRE(
1030      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1031
1032    AC_ARG_ENABLE(
1033      [sparse],
1034      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1035      [], [enable_sparse=no])
1036    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1037
1038 dnl OVS_CTAGS_IDENTIFIERS
1039 dnl
1040 dnl ctags ignores symbols with extras identifiers. This builds a list of
1041 dnl specially handled identifiers to be ignored.
1042 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1043     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1044            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1045
1046 dnl OVS_PTHREAD_SET_NAME
1047 dnl
1048 dnl This checks for three known variants of pthreads functions for setting
1049 dnl the name of the current thread:
1050 dnl
1051 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1052 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1053 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1054 dnl
1055 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1056 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1057 dnl provide to it.
1058 dnl
1059 dnl This macro defines:
1060 dnl
1061 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1062 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1063 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1064 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1065   [AC_CHECK_FUNCS([pthread_set_name_np])
1066    if test $ac_cv_func_pthread_set_name_np != yes; then
1067      AC_CACHE_CHECK(
1068        [for pthread_setname_np() variant],
1069        [ovs_cv_pthread_setname_np],
1070        [AC_LINK_IFELSE(
1071          [AC_LANG_PROGRAM([#include <pthread.h>
1072   ], [pthread_setname_np(pthread_self(), "name");])],
1073          [ovs_cv_pthread_setname_np=glibc],
1074          [AC_LINK_IFELSE(
1075            [AC_LANG_PROGRAM([#include <pthread.h>
1076 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1077            [ovs_cv_pthread_setname_np=netbsd],
1078            [ovs_cv_pthread_setname_np=none])])])
1079      case $ovs_cv_pthread_setname_np in # (
1080        glibc)
1081           AC_DEFINE(
1082             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1083             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1084           ;; # (
1085        netbsd)
1086           AC_DEFINE(
1087             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1088             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1089           ;;
1090      esac
1091    fi])
1092
1093 dnl OVS_CHECK_LINUX_HOST.
1094 dnl
1095 dnl Checks whether we're building for a Linux host, based on the presence of
1096 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1097 dnl LINUX based on the result.
1098 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1099   [AC_CACHE_CHECK(
1100      [whether __linux__ is defined],
1101      [ovs_cv_linux],
1102      [AC_COMPILE_IFELSE(
1103         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1104         [ovs_cv_linux=true],
1105         [ovs_cv_linux=false])])
1106    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])