acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2019 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 5; then
 154        if test "$version" = 5 && test "$patchlevel" -le 0; then
 155           : # Linux 5.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 5.0.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 4; then
 160        : # Linux 4.x
 161     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 162        : # Linux 3.x
 163     else
 164        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 165     fi
 166     if (test ! -e "$KBUILD"/include/linux/version.h && \
 167         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 168        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 169         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 170         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 171     fi
 172     OVS_CHECK_LINUX_COMPAT
 173   fi
 174   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 175 ])
 176
 177 dnl OVS_CHECK_LINUX_NETLINK
 178 dnl
 179 dnl Configure Linux netlink compat.
 180 AC_DEFUN([OVS_CHECK_LINUX_NETLINK], [
 181   AC_COMPILE_IFELSE([
 182     AC_LANG_PROGRAM([#include <linux/netlink.h>], [
 183         struct nla_bitfield32 x =  { 0 };
 184     ])],
 185     [AC_DEFINE([HAVE_NLA_BITFIELD32], [1],
 186     [Define to 1 if struct nla_bitfield32 is available.])])
 187 ])
 188
 189 dnl OVS_CHECK_LINUX_TC
 190 dnl
 191 dnl Configure Linux tc compat.
 192 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 193   AC_COMPILE_IFELSE([
 194     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 195         int x = TCA_ACT_FLAGS;
 196     ])],
 197     [AC_DEFINE([HAVE_TCA_ACT_FLAGS], [1],
 198                [Define to 1 if TCA_ACT_FLAGS is available.])])
 199
 200   AC_CHECK_MEMBERS([struct tcf_t.firstuse], [], [], [#include <linux/pkt_cls.h>])
 201
 202   AC_COMPILE_IFELSE([
 203     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 204         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 205     ])],
 206     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 207                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 208
 209   AC_COMPILE_IFELSE([
 210     AC_LANG_PROGRAM([#include <linux/tc_act/tc_mpls.h>], [
 211         int x = TCA_MPLS_TTL;
 212     ])],
 213     [AC_DEFINE([HAVE_TCA_MPLS_TTL], [1],
 214                [Define to 1 if HAVE_TCA_MPLS_TTL is available.])])
 215
 216   AC_COMPILE_IFELSE([
 217     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 218         int x = TCA_TUNNEL_KEY_ENC_TTL;
 219     ])],
 220     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 221                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 222
 223   AC_COMPILE_IFELSE([
 224     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 225         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 226     ])],
 227     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 228                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 229
 230   AC_COMPILE_IFELSE([
 231     AC_LANG_PROGRAM([#include <linux/tc_act/tc_skbedit.h>], [
 232         int x = TCA_SKBEDIT_FLAGS;
 233     ])],
 234     [AC_DEFINE([HAVE_TCA_SKBEDIT_FLAGS], [1],
 235                [Define to 1 if TCA_SKBEDIT_FLAGS is available.])])
 236 ])
 237
 238 dnl OVS_CHECK_LINUX_SCTP_CT
 239 dnl
 240 dnl Checks for kernels which need additional SCTP state
 241 AC_DEFUN([OVS_CHECK_LINUX_SCTP_CT], [
 242   AC_COMPILE_IFELSE([
 243     AC_LANG_PROGRAM([#include <linux/netfilter/nfnetlink.h>
 244 #include <linux/netfilter/nfnetlink_conntrack.h>
 245 #include <linux/netfilter/nf_conntrack_common.h>
 246 #include <linux/netfilter/nf_conntrack_sctp.h>], [
 247         int x = SCTP_CONNTRACK_HEARTBEAT_SENT;
 248     ])],
 249     [AC_DEFINE([HAVE_SCTP_CONNTRACK_HEARTBEATS], [1],
 250                [Define to 1 if SCTP_CONNTRACK_HEARTBEAT_SENT is available.])])
 251 ])
 252
 253 dnl OVS_FIND_DEPENDENCY(FUNCTION, SEARCH_LIBS, NAME_TO_PRINT)
 254 dnl
 255 dnl Check for a function in a library list.
 256 AC_DEFUN([OVS_FIND_DEPENDENCY], [
 257   AC_SEARCH_LIBS([$1], [$2], [], [
 258     AC_MSG_ERROR([unable to find $3, install the dependency package])
 259   ])
 260 ])
 261
 262 dnl OVS_CHECK_LINUX_AF_XDP
 263 dnl
 264 dnl Check both Linux kernel AF_XDP and libbpf support
 265 AC_DEFUN([OVS_CHECK_LINUX_AF_XDP], [
 266   AC_ARG_ENABLE([afxdp],
 267                 [AC_HELP_STRING([--enable-afxdp], [Enable AF-XDP support])],
 268                 [], [enable_afxdp=no])
 269   AC_MSG_CHECKING([whether AF_XDP is enabled])
 270   if test "$enable_afxdp" != yes; then
 271     AC_MSG_RESULT([no])
 272     AF_XDP_ENABLE=false
 273   else
 274     AC_MSG_RESULT([yes])
 275     AF_XDP_ENABLE=true
 276
 277     AC_CHECK_HEADER([bpf/libbpf.h], [],
 278       [AC_MSG_ERROR([unable to find bpf/libbpf.h for AF_XDP support])])
 279
 280     AC_CHECK_HEADER([linux/if_xdp.h], [],
 281       [AC_MSG_ERROR([unable to find linux/if_xdp.h for AF_XDP support])])
 282
 283     AC_CHECK_HEADER([bpf/xsk.h], [],
 284       [AC_MSG_ERROR([unable to find bpf/xsk.h for AF_XDP support])])
 285
 286     AC_CHECK_FUNCS([pthread_spin_lock], [],
 287       [AC_MSG_ERROR([unable to find pthread_spin_lock for AF_XDP support])])
 288
 289     AC_DEFINE([HAVE_AF_XDP], [1],
 290               [Define to 1 if AF_XDP support is available and enabled.])
 291     LIBBPF_LDADD=" -lbpf -lelf"
 292     AC_SUBST([LIBBPF_LDADD])
 293
 294     AC_CHECK_DECL([xsk_ring_prod__needs_wakeup], [
 295       AC_DEFINE([HAVE_XDP_NEED_WAKEUP], [1],
 296         [XDP need wakeup support detected in xsk.h.])
 297     ], [], [[#include <bpf/xsk.h>]])
 298   fi
 299   AM_CONDITIONAL([HAVE_AF_XDP], test "$AF_XDP_ENABLE" = true)
 300 ])
 301
 302 dnl OVS_CHECK_DPDK
 303 dnl
 304 dnl Configure DPDK source tree
 305 AC_DEFUN([OVS_CHECK_DPDK], [
 306   AC_ARG_WITH([dpdk],
 307               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 308                               [Specify the DPDK build directory])],
 309               [have_dpdk=true])
 310
 311   AC_MSG_CHECKING([whether dpdk is enabled])
 312   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 313     AC_MSG_RESULT([no])
 314     DPDKLIB_FOUND=false
 315   else
 316     AC_MSG_RESULT([yes])
 317     case "$with_dpdk" in
 318       yes)
 319         DPDK_AUTO_DISCOVER="true"
 320         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 321             DPDK_INCLUDE="$DPDK_CFLAGS"
 322             DPDK_LIB="$DPDK_LIBS"], [
 323             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 324             DPDK_LIB="-ldpdk"])
 325         ;;
 326       *)
 327         DPDK_AUTO_DISCOVER="false"
 328         DPDK_INCLUDE_PATH="$with_dpdk/include"
 329         # If 'with_dpdk' is passed install directory, point to headers
 330         # installed in $DESTDIR/$prefix/include/dpdk
 331         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 332            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 333         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 334            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 335         fi
 336         DPDK_LIB_DIR="$with_dpdk/lib"
 337         DPDK_LIB="-ldpdk"
 338         ;;
 339     esac
 340
 341     ovs_save_CFLAGS="$CFLAGS"
 342     ovs_save_LDFLAGS="$LDFLAGS"
 343     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 344     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 345       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 346     fi
 347
 348     AC_CHECK_HEADERS([rte_config.h], [], [
 349       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 350     ], [AC_INCLUDES_DEFAULT])
 351
 352     AC_CHECK_DECLS([RTE_LIBRTE_VHOST_NUMA, RTE_EAL_NUMA_AWARE_HUGEPAGES], [
 353       OVS_FIND_DEPENDENCY([get_mempolicy], [numa], [libnuma])
 354     ], [], [[#include <rte_config.h>]])
 355
 356     AC_CHECK_DECL([RTE_LIBRTE_VHOST_NUMA], [
 357       AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])
 358     ], [], [[#include <rte_config.h>]])
 359
 360    AC_MSG_CHECKING([whether DPDK pdump support is enabled])
 361    AC_ARG_ENABLE(
 362      [dpdk-pdump],
 363      [AC_HELP_STRING([--enable-dpdk-pdump],
 364                      [Enable DPDK pdump packet capture support])],
 365      [AC_MSG_RESULT([yes])
 366       AC_MSG_WARN([DPDK pdump is deprecated, consider using ovs-tcpdump instead])
 367       AC_CHECK_DECL([RTE_LIBRTE_PMD_PCAP], [
 368         OVS_FIND_DEPENDENCY([pcap_dump], [pcap], [libpcap])
 369         AC_CHECK_DECL([RTE_LIBRTE_PDUMP], [
 370           AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])
 371         ], [
 372           AC_MSG_ERROR([RTE_LIBRTE_PDUMP is not defined in rte_config.h])
 373         ], [[#include <rte_config.h>]])
 374       ], [
 375         AC_MSG_ERROR([RTE_LIBRTE_PMD_PCAP is not defined in rte_config.h])
 376       ], [[#include <rte_config.h>]])],
 377       [AC_MSG_RESULT([no])])
 378
 379     AC_CHECK_DECL([RTE_LIBRTE_MLX5_PMD], [dnl found
 380       OVS_FIND_DEPENDENCY([mnl_attr_put], [mnl], [libmnl])
 381       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 382         OVS_FIND_DEPENDENCY([mlx5dv_create_wq], [mlx5], [libmlx5])
 383         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 384       ], [[#include <rte_config.h>]])
 385     ], [], [[#include <rte_config.h>]])
 386
 387     AC_CHECK_DECL([RTE_LIBRTE_MLX4_PMD], [dnl found
 388       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 389         OVS_FIND_DEPENDENCY([mlx4dv_init_obj], [mlx4], [libmlx4])
 390         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 391       ], [[#include <rte_config.h>]])
 392     ], [], [[#include <rte_config.h>]])
 393
 394     # DPDK uses dlopen to load plugins.
 395     OVS_FIND_DEPENDENCY([dlopen], [dl], [libdl])
 396
 397     AC_MSG_CHECKING([whether linking with dpdk works])
 398     LIBS="$DPDK_LIB $LIBS"
 399     AC_LINK_IFELSE(
 400       [AC_LANG_PROGRAM([#include <rte_config.h>
 401                         #include <rte_eal.h>],
 402                        [int rte_argc; char ** rte_argv;
 403                         rte_eal_init(rte_argc, rte_argv);])],
 404       [AC_MSG_RESULT([yes])
 405        DPDKLIB_FOUND=true],
 406       [AC_MSG_RESULT([no])
 407        if test "$DPDK_AUTO_DISCOVER" = "true"; then
 408          AC_MSG_ERROR(m4_normalize([
 409             Could not find DPDK library in default search path, Use --with-dpdk
 410             to specify the DPDK library installed in non-standard location]))
 411        else
 412          AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 413        fi
 414       ])
 415
 416     CFLAGS="$ovs_save_CFLAGS"
 417     LDFLAGS="$ovs_save_LDFLAGS"
 418     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 419       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 420     fi
 421     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 422     OVS_ENABLE_OPTION([-mssse3])
 423
 424     # DPDK pmd drivers are not linked unless --whole-archive is used.
 425     #
 426     # This happens because the rest of the DPDK code doesn't use any symbol in
 427     # the pmd driver objects, and the drivers register themselves using an
 428     # __attribute__((constructor)) function.
 429     #
 430     # These options are specified inside a single -Wl directive to prevent
 431     # autotools from reordering them.
 432     #
 433     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 434     # will already have flagged just the right set of libs with
 435     # --whole-archive - in those cases do not wrap it once more.
 436     case "$DPDK_LIB" in
 437       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 438       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 439     esac
 440     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 441     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 442   fi
 443
 444   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 445 ])
 446
 447 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 448 dnl
 449 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 450 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 451 dnl <REGEX> translated to uppercase.
 452 AC_DEFUN([OVS_GREP_IFELSE], [
 453   AC_MSG_CHECKING([whether $2 matches in $1])
 454   if test -f $1; then
 455     grep '$2' $1 >/dev/null 2>&1
 456     status=$?
 457     case $status in
 458       0)
 459         AC_MSG_RESULT([yes])
 460         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 461         ;;
 462       1)
 463         AC_MSG_RESULT([no])
 464         $4
 465         ;;
 466       *)
 467         AC_MSG_ERROR([grep exited with status $status])
 468         ;;
 469     esac
 470   else
 471     AC_MSG_RESULT([file not found])
 472     $4
 473   fi
 474 ])
 475
 476 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 477 dnl
 478 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 479 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 480 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 481 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 482 dnl translated to uppercase.
 483 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 484   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 485   if test -f $1; then
 486     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 487     status=$?
 488     case $status in
 489       0)
 490         AC_MSG_RESULT([yes])
 491         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 492         ;;
 493       1)
 494         AC_MSG_RESULT([no])
 495         $5
 496         ;;
 497       *)
 498         AC_MSG_ERROR([grep exited with status $status])
 499         ;;
 500     esac
 501   else
 502     AC_MSG_RESULT([file not found])
 503     $5
 504   fi
 505 ])
 506
 507 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 508 dnl
 509 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 510 dnl the function signature starting from the line matching FUNCTION
 511 dnl and ending with the line containing the closing parenthesis.  If
 512 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 513 dnl IF-MATCH is empty then it defines to
 514 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 515 dnl <REGEX> translated to uppercase.
 516 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 517   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 518   if test -f $1; then
 519     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 520     status=$?
 521     case $status in
 522       0)
 523         AC_MSG_RESULT([yes])
 524         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 525         ;;
 526       1)
 527         AC_MSG_RESULT([no])
 528         $5
 529         ;;
 530       *)
 531         AC_MSG_ERROR([grep exited with status $status])
 532         ;;
 533     esac
 534   else
 535     AC_MSG_RESULT([file not found])
 536     $5
 537   fi
 538 ])
 539
 540 dnl OVS_DEFINE(NAME)
 541 dnl
 542 dnl Defines NAME to 1 in kcompat.h.
 543 AC_DEFUN([OVS_DEFINE], [
 544   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 545 ])
 546
 547 dnl OVS_CHECK_LINUX_COMPAT
 548 dnl
 549 dnl Runs various Autoconf checks on the Linux kernel source in
 550 dnl the directory in $KBUILD.
 551 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 552   rm -f datapath/linux/kcompat.h.new
 553   mkdir -p datapath/linux
 554   : > datapath/linux/kcompat.h.new
 555
 556   echo '#include <linux/version.h>
 557 #ifndef RHEL_RELEASE_CODE
 558 #define RHEL_RELEASE_CODE 0
 559 #define RHEL_RELEASE_VERSION(a, b) 0
 560 #endif' >> datapath/linux/kcompat.h.new
 561
 562   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 563                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 564
 565   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 566                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 567
 568   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 569                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 570   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 571
 572   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 573   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 574   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 575
 576   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 577                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 578   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 579                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 580
 581   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 582   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 583
 584   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 585   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 586   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 587   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 588   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 589   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_hwaccel_clear_tag])
 590
 591   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 592   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 593   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 594                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 595   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 596                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 597
 598   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 599                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 600   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 601                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 602   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 603                         [ip_do_fragment], [net],
 604                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 605   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 606                         [ip_local_out], [net],
 607                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 608
 609   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 610
 611   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 612                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 613   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 614   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 615                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 616   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 617                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 618   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 619   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 620   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 621                         [frags_work])
 622   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 623                         [rwlock])
 624   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 625                         [list_evictor])
 626   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 627   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 628                         [sub_frag_mem_limit], [struct.netns_frags],
 629                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 630   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 631                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 632   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 633                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 634
 635   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 636   dnl OVS does not really need ipv6 label field, but its presence signifies that
 637   dnl the stack has all required ipv6 support.
 638   dnl OVS also does not need dst_cache But this dependency allows us to write
 639   dnl much cleaner code.
 640
 641   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 642                         [label],
 643                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 644                                          [iptunnel_pull_offloads],
 645                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 646                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 647                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 648
 649   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 650                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 651   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 652                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 653   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 654                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 655   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 656   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 657   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 658   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 659   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 660   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 661   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 662   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 663   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 664   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 665                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 666   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 667   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 668   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 669   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 670   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 671   dnl So check type of tstats.
 672   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 673                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 674   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 675                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 676   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 677   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 678   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 679                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 680   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 681   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 682   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 683                         [extended])
 684   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 685                         [netdev_master_upper_dev_link], [upper_priv],
 686                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 687   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 688                   [netdev_master_upper_dev_link_rh],
 689                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 690
 691   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 692                         [max_mtu])
 693   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 694                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 695   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 696                         [dev_change_flags], [extack],
 697                         [OVS_DEFINE([HAVE_DEV_CHANGE_FLAGS_TAKES_EXTACK])])
 698
 699   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 700   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state],
 701                         [struct net ], [OVS_DEFINE([HAVE_NF_HOOK_STATE_NET])])
 702   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 703   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 704                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 705   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 706                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 707   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 708                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 709   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 710   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [CONFIG_NF_NAT_NEEDED])
 711
 712
 713   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 714                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 715
 716   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 717                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 718                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 719   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 720                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 721
 722   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 723                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 724                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 725   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 726                   [nf_ct_get_tuplepr], [struct.net],
 727                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 728   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 729                   [nf_ct_set])
 730   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 731                   [nf_ct_is_untracked])
 732   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 733                   [nf_ct_invert_tuplepr])
 734   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 735                   [nf_ct_zone_init])
 736   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 737                   [net_ns_get])
 738   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 739                   [nf_connlabels_get])
 740   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 741                   [nf_connlabels_get], [int bit],
 742                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 743   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 744                         [nf_conn_labels], [words])
 745   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 746   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 747   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 748   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_packet],
 749                   [OVS_DEFINE([HAVE_UPSTREAM_NF_NAT])])
 750   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 751   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 752                   [OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h],
 753                                    [int nf_conncount_add],
 754                                    [], [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])])
 755   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [nf_ct_set_timeout])
 756   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [struct nf_ct_timeout],
 757                   [OVS_DEFINE([HAVE_NF_CT_TIMEOUT])])
 758   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h],
 759                         [\(*nf_ct_timeout_find_get_hook\)], [net],
 760                         [OVS_DEFINE([HAVE_NF_CT_TIMEOUT_FIND_GET_HOOK_NET])])
 761
 762   OVS_GREP_IFELSE([$KSRC/include/linux/random.h],
 763                   [prandom_u32[[\(]]],
 764                   [OVS_DEFINE([HAVE_PRANDOM_U32])])
 765   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 766
 767   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 768   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 769   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 770                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 771   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 772
 773   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 774                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 775                                    [rcu_read_lock_held])])
 776   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 777   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 778   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
 779                         [rtnl_create_link], [extack],
 780                         [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_TAKES_EXTACK])])
 781   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [nf_reset_ct])
 782
 783   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 784   # is necessary because some versions of this header remove the
 785   # member but retain the kerneldoc comment that describes it (which
 786   # starts with @).  The brackets must be doubled because of m4
 787   # quoting rules.
 788   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 789                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 790   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 791   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 792   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 793   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 794   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 795   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 796   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 797                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 798   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 799                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 800   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 801                   [skb_copy_from_linear_data_offset])
 802   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 803                   [skb_reset_tail_pointer])
 804   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 805   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 806                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 807   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 808   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 809   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 810   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 811   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 812   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 813   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 814   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 815                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 816   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 817   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 818                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 819   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 820                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 821   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 822   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 823   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 824   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 825   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 826   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 827   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 828   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 829   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 830
 831   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 832                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 833   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 834                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 835   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 836                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 837
 838   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 839   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 840
 841   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 842   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 843
 844   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 845   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 846   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 847   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 848                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 849   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 850   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 851                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 852   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_validate_flags])
 853   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 854                         [genl_notify], [net],
 855                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 856
 857
 858   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 859                         [genl_multicast_group], [id])
 860   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 861
 862   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 863   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 864   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 865   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 866   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 867   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 868                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 869   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 870                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 871
 872   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 873   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 874   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 875   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 876   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 877   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 878   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 879   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 880   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_nest_start_noflag])
 881   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 882                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 883   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 884                         [nla_parse], [netlink_ext_ack],
 885                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 886
 887   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 888
 889   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 890   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 891   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 892   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 893   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 894
 895   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 896                         [metadata_dst_alloc], [metadata_type])
 897
 898   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 899
 900   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 901                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 902   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 903                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 904                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 905   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 906   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 907   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 908                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 909   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 910                         [gro_receive])
 911
 912   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 913                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 914   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 915                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 916
 917   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 918   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 919   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 920                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 921   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 922                         [udp_add_offload], [net],
 923                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 924   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 925                         [nf_defrag_ipv6_enable], [net],
 926                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 927   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 928                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 929   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 930                         [needs_free_netdev],
 931                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 932   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 933                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 934   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 935                   [nf_conntrack_helper_put],
 936                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 937   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 938                   [nf_nat_helper_try_module_get])
 939   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 940                   [nf_nat_helper_put])
 941   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 942                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 943   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 944                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 945   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 946                         [extack],
 947                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 948   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 949                         [list],
 950                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 951   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 952                   [IP_CT_UNTRACKED])
 953   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 954                         [netdev_master_upper_dev_link], [extack],
 955                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 956   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 957                   [__LINUX_COMPILER_TYPES_H],
 958                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 959   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 960                   [ktime_get_ts64],
 961                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 962   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 963                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 964                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 965   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 966                   [ktime_get_ns],
 967                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 968   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 969                   frag_percpu_counter_batch[],
 970                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 971   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 972                   [null_compute_pseudo],
 973                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 974   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 975                   [__skb_checksum_convert],
 976                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
 977   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 978                         [max_mtu],
 979                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
 980   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
 981                         [erspan_ver],
 982                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
 983   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 984                   [SKB_GSO_IPXIP6],
 985                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
 986   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
 987                         [ip6_make_flowlabel], [fl6],
 988                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
 989   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
 990                         [auto_flowlabels],
 991                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
 992   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 993                   [netif_keep_dst],
 994                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
 995   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 996                         [ndo_get_iflink],
 997                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
 998   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 999                   [skb_set_inner_ipproto],
1000                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
1001   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1002                   [tunnel_encap_types],
1003                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
1004   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1005                   [IFLA_IPTUN_ENCAP_TYPE],
1006                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
1007   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1008                   [IFLA_IPTUN_COLLECT_METADATA],
1009                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
1010   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1011                   [IFLA_GRE_ENCAP_DPORT])
1012   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1013                   [IFLA_GRE_COLLECT_METADATA])
1014   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1015                   [IFLA_GRE_IGNORE_DF])
1016   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1017                   [IFLA_GRE_FWMARK])
1018   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1019                   [IFLA_GRE_ERSPAN_INDEX])
1020   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1021                   [IFLA_GRE_ERSPAN_HWID])
1022   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1023                   [IFLA_IPTUN_FWMARK])
1024   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1025                         [csum_valid],
1026                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
1027   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1028                         [vlan_present],
1029                         [OVS_DEFINE([HAVE_SKBUFF_VLAN_PRESENT])])
1030   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1031                   [skb_checksum_simple_validate])
1032   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
1033                   [void.*ndo_get_stats64],
1034                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
1035   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
1036                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
1037   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
1038                         [ip_tunnel_info_opts_set], [flags],
1039                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
1040   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
1041                         [rnd],
1042                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
1043   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [__LINUX_OVERFLOW_H],
1044                   [OVS_DEFINE([HAVE_OVERFLOW_H])])
1045   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [struct_size],
1046                   [OVS_DEFINE([HAVE_STRUCT_SIZE])])
1047   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_array],
1048                   [OVS_DEFINE([HAVE_KVMALLOC_ARRAY])])
1049   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_node],
1050                   [OVS_DEFINE([HAVE_KVMALLOC_NODE])])
1051   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
1052                   [nf_conntrack_l3proto],
1053                   [OVS_DEFINE([HAVE_NF_CONNTRACK_L3PROATO_H])])
1054   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_core.h],
1055                         [nf_conntrack_in], [nf_hook_state],
1056                         [OVS_DEFINE([HAVE_NF_CONNTRACK_IN_TAKES_NF_HOOK_STATE])])
1057   OVS_GREP_IFELSE([$KSRC/include/net/ipv6_frag.h], [IP6_DEFRAG_CONNTRACK_IN],
1058                   [OVS_DEFINE([HAVE_IPV6_FRAG_H])])
1059   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
1060                         [nf_ct_helper_ext_add], [nf_conntrack_helper],
1061                         [OVS_DEFINE([HAVE_NF_CT_HELPER_EXT_ADD_TAKES_HELPER])])
1062   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_calc_hlen],
1063                   [OVS_DEFINE([HAVE_GRE_CALC_HLEN])])
1064   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [ip_gre_calc_hlen],
1065                   [OVS_DEFINE([HAVE_IP_GRE_CALC_HLEN])])
1066   OVS_GREP_IFELSE([$KSRC/include/linux/rbtree.h], [rb_link_node_rcu],
1067                   [OVS_DEFINE([HAVE_RBTREE_RB_LINK_NODE_RCU])])
1068   OVS_GREP_IFELSE([$KSRC/include/net/dst_ops.h], [bool confirm_neigh],
1069                   [OVS_DEFINE([HAVE_DST_OPS_CONFIRM_NEIGH])])
1070
1071   if cmp -s datapath/linux/kcompat.h.new \
1072             datapath/linux/kcompat.h >/dev/null 2>&1; then
1073     rm datapath/linux/kcompat.h.new
1074   else
1075     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
1076   fi
1077 ])
1078
1079 dnl Checks for net/if_dl.h.
1080 dnl
1081 dnl (We use this as a proxy for checking whether we're building on FreeBSD
1082 dnl or NetBSD.)
1083 AC_DEFUN([OVS_CHECK_IF_DL],
1084   [AC_CHECK_HEADER([net/if_dl.h],
1085                    [HAVE_IF_DL=yes],
1086                    [HAVE_IF_DL=no])
1087    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
1088    if test "$HAVE_IF_DL" = yes; then
1089       AC_DEFINE([HAVE_IF_DL], [1],
1090                 [Define to 1 if net/if_dl.h is available.])
1091
1092       # On these platforms we use libpcap to access network devices.
1093       AC_SEARCH_LIBS([pcap_open_live], [pcap])
1094    fi])
1095
1096 dnl Checks for buggy strtok_r.
1097 dnl
1098 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
1099 dnl with optimization that can cause segfaults:
1100 dnl
1101 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
1102 AC_DEFUN([OVS_CHECK_STRTOK_R],
1103   [AC_CACHE_CHECK(
1104      [whether strtok_r macro segfaults on some inputs],
1105      [ovs_cv_strtok_r_bug],
1106      [AC_RUN_IFELSE(
1107         [AC_LANG_PROGRAM([#include <stdio.h>
1108                           #include <string.h>
1109                          ],
1110                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
1111                            /* Assume bug is present, because relatively minor
1112                               changes in compiler settings (e.g. optimization
1113                               level) can make it crop up. */
1114                            return 1;
1115                            #else
1116                            char string[] = ":::";
1117                            char *save_ptr = (char *) 0xc0ffee;
1118                            char *token1, *token2;
1119                            token1 = strtok_r(string, ":", &save_ptr);
1120                            token2 = strtok_r(NULL, ":", &save_ptr);
1121                            freopen ("/dev/null", "w", stdout);
1122                            printf ("%s %s\n", token1, token2);
1123                            return 0;
1124                            #endif
1125                           ]])],
1126         [ovs_cv_strtok_r_bug=no],
1127         [ovs_cv_strtok_r_bug=yes],
1128         [ovs_cv_strtok_r_bug=yes])])
1129    if test $ovs_cv_strtok_r_bug = yes; then
1130      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1131                [Define if strtok_r macro segfaults on some inputs])
1132    fi
1133 ])
1134
1135 dnl ----------------------------------------------------------------------
1136 dnl These macros are from GNU PSPP, with the following original license:
1137 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1138 dnl This file is free software; the Free Software Foundation
1139 dnl gives unlimited permission to copy and/or distribute it,
1140 dnl with or without modifications, as long as this notice is preserved.
1141
1142 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1143   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1144   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1145     [ovs_save_CFLAGS="$CFLAGS"
1146      dnl Include -Werror in the compiler options, because without -Werror
1147      dnl clang's GCC-compatible compiler driver does not return a failure
1148      dnl exit status even though it complains about options it does not
1149      dnl understand.
1150      dnl
1151      dnl Also, check stderr as gcc exits with status 0 for options
1152      dnl rejected at getopt level.
1153      dnl    % touch /tmp/a.c
1154      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1155      dnl    gcc: unrecognized option '-Qunused-arguments'
1156      dnl    0
1157      dnl    %
1158      dnl
1159      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1160      dnl it does not understand, unless it has another error to report, so
1161      dnl instead of testing for -Wno-<foo>, test for the positive version.
1162      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1163      AC_COMPILE_IFELSE(
1164        [AC_LANG_SOURCE([int x;])],
1165        [if test -s conftest.err && grep "unrecognized option" conftest.err
1166         then
1167           ovs_cv_name[]=no
1168         else
1169           ovs_cv_name[]=yes
1170         fi],
1171        [ovs_cv_name[]=no])
1172      CFLAGS="$ovs_save_CFLAGS"])
1173   if test $ovs_cv_name = yes; then
1174     m4_if([$2], [], [:], [$2])
1175   else
1176     m4_if([$3], [], [:], [$3])
1177   fi
1178 ])
1179
1180 dnl OVS_CHECK_WERROR
1181 dnl
1182 dnl Check whether the C compiler accepts -Werror.
1183 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1184 AC_DEFUN([OVS_CHECK_WERROR],
1185   [WERROR=
1186    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1187
1188 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1189 dnl Check whether the given C compiler OPTION is accepted.
1190 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1191 AC_DEFUN([OVS_CHECK_CC_OPTION],
1192   [AC_REQUIRE([OVS_CHECK_WERROR])
1193    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1194
1195 dnl OVS_ENABLE_OPTION([OPTION])
1196 dnl Check whether the given C compiler OPTION is accepted.
1197 dnl If so, add it to WARNING_FLAGS.
1198 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1199 AC_DEFUN([OVS_ENABLE_OPTION],
1200   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1201    AC_SUBST([WARNING_FLAGS])])
1202
1203 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1204 dnl Check whether the given C compiler OPTION is accepted.
1205 dnl If so, enable the given Automake CONDITIONAL.
1206
1207 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1208 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1209   [OVS_CHECK_CC_OPTION(
1210     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1211    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1212 dnl ----------------------------------------------------------------------
1213
1214 dnl Check for too-old XenServer.
1215 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1216   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1217     [if test -e /etc/redhat-release; then
1218        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1219      fi
1220      if test -z "$ovs_cv_xsversion"; then
1221        ovs_cv_xsversion=none
1222      fi])
1223   case $ovs_cv_xsversion in
1224     none)
1225       ;;
1226
1227     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1228     [[6-9]]* |                           dnl XenServer 6 or later
1229     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1230     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1231     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1232     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1233       ;;
1234
1235     *)
1236       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1237       ;;
1238   esac])
1239
1240 dnl OVS_CHECK_SPARSE_TARGET
1241 dnl
1242 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1243 dnl target for which the code is being built.  This helps it out.
1244 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1245   [AC_CACHE_CHECK(
1246     [target hint for cgcc],
1247     [ac_cv_sparse_target],
1248     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1249        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1250        [x86_64-*], [ac_cv_sparse_target=x86_64],
1251        [ac_cv_sparse_target=other])])
1252    AS_CASE([$ac_cv_sparse_target],
1253      [x86], [SPARSEFLAGS= CGCCFLAGS="-target=i86 -target=host_os_specs"],
1254      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS="-target=x86_64 -target=host_os_specs"],
1255      [SPARSEFLAGS= CGCCFLAGS=])
1256
1257    dnl Get the default defines for vector instructions from compiler to
1258    dnl allow "sparse" correctly check the same code that will be built.
1259    dnl Required for checking DPDK headers.
1260    AC_MSG_CHECKING([vector options for cgcc])
1261    VECTOR=$($CC -dM -E - < /dev/null | grep -E "MMX|SSE|AVX" | \
1262             cut -c 9- | sed 's/ /=/' | sed 's/^/-D/' | tr '\n' ' ')
1263    AC_MSG_RESULT([$VECTOR])
1264    CGCCFLAGS="$CGCCFLAGS $VECTOR"
1265
1266    AC_SUBST([SPARSEFLAGS])
1267    AC_SUBST([CGCCFLAGS])])
1268
1269 dnl OVS_SPARSE_EXTRA_INCLUDES
1270 dnl
1271 dnl The cgcc script from "sparse" does not search gcc's default
1272 dnl search path. Get the default search path from GCC and pass
1273 dnl them to sparse.
1274 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1275     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1276            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1277
1278 dnl OVS_ENABLE_SPARSE
1279 AC_DEFUN([OVS_ENABLE_SPARSE],
1280   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1281    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1282    : ${SPARSE=sparse}
1283    AC_SUBST([SPARSE])
1284    AC_CONFIG_COMMANDS_PRE(
1285      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1286
1287    AC_ARG_ENABLE(
1288      [sparse],
1289      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1290      [], [enable_sparse=no])
1291    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1292
1293 dnl OVS_CTAGS_IDENTIFIERS
1294 dnl
1295 dnl ctags ignores symbols with extras identifiers. This builds a list of
1296 dnl specially handled identifiers to be ignored.
1297 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1298     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1299            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1300
1301 dnl OVS_PTHREAD_SET_NAME
1302 dnl
1303 dnl This checks for three known variants of pthreads functions for setting
1304 dnl the name of the current thread:
1305 dnl
1306 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1307 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1308 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1309 dnl
1310 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1311 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1312 dnl provide to it.
1313 dnl
1314 dnl This macro defines:
1315 dnl
1316 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1317 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1318 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1319 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1320   [AC_CHECK_FUNCS([pthread_set_name_np])
1321    if test $ac_cv_func_pthread_set_name_np != yes; then
1322      AC_CACHE_CHECK(
1323        [for pthread_setname_np() variant],
1324        [ovs_cv_pthread_setname_np],
1325        [AC_LINK_IFELSE(
1326          [AC_LANG_PROGRAM([#include <pthread.h>
1327   ], [pthread_setname_np(pthread_self(), "name");])],
1328          [ovs_cv_pthread_setname_np=glibc],
1329          [AC_LINK_IFELSE(
1330            [AC_LANG_PROGRAM([#include <pthread.h>
1331 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1332            [ovs_cv_pthread_setname_np=netbsd],
1333            [ovs_cv_pthread_setname_np=none])])])
1334      case $ovs_cv_pthread_setname_np in # (
1335        glibc)
1336           AC_DEFINE(
1337             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1338             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1339           ;; # (
1340        netbsd)
1341           AC_DEFINE(
1342             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1343             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1344           ;;
1345      esac
1346    fi])
1347
1348 dnl OVS_CHECK_LINUX_HOST.
1349 dnl
1350 dnl Checks whether we're building for a Linux host, based on the presence of
1351 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1352 dnl LINUX based on the result.
1353 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1354   [AC_CACHE_CHECK(
1355      [whether __linux__ is defined],
1356      [ovs_cv_linux],
1357      [AC_COMPILE_IFELSE(
1358         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1359         [ovs_cv_linux=true],
1360         [ovs_cv_linux=false])])
1361    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])