acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2019 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 5; then
 154        if test "$version" = 5 && test "$patchlevel" -le 0; then
 155           : # Linux 5.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 5.0.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 4; then
 160        : # Linux 4.x
 161     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 162        : # Linux 3.x
 163     else
 164        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 165     fi
 166     if (test ! -e "$KBUILD"/include/linux/version.h && \
 167         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 168        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 169         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 170         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 171     fi
 172     OVS_CHECK_LINUX_COMPAT
 173   fi
 174   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 175 ])
 176
 177 dnl OVS_CHECK_LINUX_NETLINK
 178 dnl
 179 dnl Configure Linux netlink compat.
 180 AC_DEFUN([OVS_CHECK_LINUX_NETLINK], [
 181   AC_COMPILE_IFELSE([
 182     AC_LANG_PROGRAM([#include <linux/netlink.h>], [
 183         struct nla_bitfield32 x =  { 0 };
 184     ])],
 185     [AC_DEFINE([HAVE_NLA_BITFIELD32], [1],
 186     [Define to 1 if struct nla_bitfield32 is available.])])
 187 ])
 188
 189 dnl OVS_CHECK_LINUX_TC
 190 dnl
 191 dnl Configure Linux tc compat.
 192 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 193   AC_COMPILE_IFELSE([
 194     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 195         int x = TCA_ACT_FLAGS;
 196     ])],
 197     [AC_DEFINE([HAVE_TCA_ACT_FLAGS], [1],
 198                [Define to 1 if TCA_ACT_FLAGS is available.])])
 199
 200   AC_CHECK_MEMBERS([struct tcf_t.firstuse], [], [], [#include <linux/pkt_cls.h>])
 201
 202   AC_COMPILE_IFELSE([
 203     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 204         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 205     ])],
 206     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 207                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 208
 209   AC_COMPILE_IFELSE([
 210     AC_LANG_PROGRAM([#include <linux/tc_act/tc_mpls.h>], [
 211         int x = TCA_MPLS_TTL;
 212     ])],
 213     [AC_DEFINE([HAVE_TCA_MPLS_TTL], [1],
 214                [Define to 1 if HAVE_TCA_MPLS_TTL is available.])])
 215
 216   AC_COMPILE_IFELSE([
 217     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 218         int x = TCA_TUNNEL_KEY_ENC_TTL;
 219     ])],
 220     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 221                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 222
 223   AC_COMPILE_IFELSE([
 224     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 225         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 226     ])],
 227     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 228                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 229
 230   AC_COMPILE_IFELSE([
 231     AC_LANG_PROGRAM([#include <linux/tc_act/tc_skbedit.h>], [
 232         int x = TCA_SKBEDIT_FLAGS;
 233     ])],
 234     [AC_DEFINE([HAVE_TCA_SKBEDIT_FLAGS], [1],
 235                [Define to 1 if TCA_SKBEDIT_FLAGS is available.])])
 236 ])
 237
 238 dnl OVS_CHECK_LINUX_SCTP_CT
 239 dnl
 240 dnl Checks for kernels which need additional SCTP state
 241 AC_DEFUN([OVS_CHECK_LINUX_SCTP_CT], [
 242   AC_COMPILE_IFELSE([
 243     AC_LANG_PROGRAM([#include <linux/netfilter/nfnetlink.h>
 244 #include <linux/netfilter/nfnetlink_conntrack.h>
 245 #include <linux/netfilter/nf_conntrack_common.h>
 246 #include <linux/netfilter/nf_conntrack_sctp.h>], [
 247         int x = SCTP_CONNTRACK_HEARTBEAT_SENT;
 248     ])],
 249     [AC_DEFINE([HAVE_SCTP_CONNTRACK_HEARTBEATS], [1],
 250                [Define to 1 if SCTP_CONNTRACK_HEARTBEAT_SENT is available.])])
 251 ])
 252
 253 dnl OVS_FIND_DEPENDENCY(FUNCTION, SEARCH_LIBS, NAME_TO_PRINT)
 254 dnl
 255 dnl Check for a function in a library list.
 256 AC_DEFUN([OVS_FIND_DEPENDENCY], [
 257   AC_SEARCH_LIBS([$1], [$2], [], [
 258     AC_MSG_ERROR([unable to find $3, install the dependency package])
 259   ])
 260 ])
 261
 262 dnl OVS_CHECK_LINUX_AF_XDP
 263 dnl
 264 dnl Check both Linux kernel AF_XDP and libbpf support
 265 AC_DEFUN([OVS_CHECK_LINUX_AF_XDP], [
 266   AC_ARG_ENABLE([afxdp],
 267                 [AC_HELP_STRING([--enable-afxdp], [Enable AF-XDP support])],
 268                 [], [enable_afxdp=no])
 269   AC_MSG_CHECKING([whether AF_XDP is enabled])
 270   if test "$enable_afxdp" != yes; then
 271     AC_MSG_RESULT([no])
 272     AF_XDP_ENABLE=false
 273   else
 274     AC_MSG_RESULT([yes])
 275     AF_XDP_ENABLE=true
 276
 277     AC_CHECK_HEADER([bpf/libbpf.h], [],
 278       [AC_MSG_ERROR([unable to find bpf/libbpf.h for AF_XDP support])])
 279
 280     AC_CHECK_HEADER([linux/if_xdp.h], [],
 281       [AC_MSG_ERROR([unable to find linux/if_xdp.h for AF_XDP support])])
 282
 283     AC_CHECK_HEADER([bpf/xsk.h], [],
 284       [AC_MSG_ERROR([unable to find bpf/xsk.h for AF_XDP support])])
 285
 286     AC_CHECK_FUNCS([pthread_spin_lock], [],
 287       [AC_MSG_ERROR([unable to find pthread_spin_lock for AF_XDP support])])
 288
 289     OVS_FIND_DEPENDENCY([numa_alloc_onnode], [numa], [libnuma])
 290
 291     AC_DEFINE([HAVE_AF_XDP], [1],
 292               [Define to 1 if AF_XDP support is available and enabled.])
 293     LIBBPF_LDADD=" -lbpf -lelf"
 294     AC_SUBST([LIBBPF_LDADD])
 295
 296     AC_CHECK_DECL([xsk_ring_prod__needs_wakeup], [
 297       AC_DEFINE([HAVE_XDP_NEED_WAKEUP], [1],
 298         [XDP need wakeup support detected in xsk.h.])
 299     ], [], [[#include <bpf/xsk.h>]])
 300   fi
 301   AM_CONDITIONAL([HAVE_AF_XDP], test "$AF_XDP_ENABLE" = true)
 302 ])
 303
 304 dnl OVS_CHECK_DPDK
 305 dnl
 306 dnl Configure DPDK source tree
 307 AC_DEFUN([OVS_CHECK_DPDK], [
 308   AC_ARG_WITH([dpdk],
 309               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 310                               [Specify the DPDK build directory])],
 311               [have_dpdk=true])
 312
 313   AC_MSG_CHECKING([whether dpdk is enabled])
 314   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 315     AC_MSG_RESULT([no])
 316     DPDKLIB_FOUND=false
 317   else
 318     AC_MSG_RESULT([yes])
 319     case "$with_dpdk" in
 320       yes)
 321         DPDK_AUTO_DISCOVER="true"
 322         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 323             DPDK_INCLUDE="$DPDK_CFLAGS"
 324             DPDK_LIB="$DPDK_LIBS"], [
 325             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 326             DPDK_LIB="-ldpdk"])
 327         ;;
 328       *)
 329         DPDK_AUTO_DISCOVER="false"
 330         DPDK_INCLUDE_PATH="$with_dpdk/include"
 331         # If 'with_dpdk' is passed install directory, point to headers
 332         # installed in $DESTDIR/$prefix/include/dpdk
 333         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 334            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 335         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 336            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 337         fi
 338         DPDK_LIB_DIR="$with_dpdk/lib"
 339         DPDK_LIB="-ldpdk"
 340         ;;
 341     esac
 342
 343     ovs_save_CFLAGS="$CFLAGS"
 344     ovs_save_LDFLAGS="$LDFLAGS"
 345     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 346     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 347       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 348     fi
 349
 350     AC_CHECK_HEADERS([rte_config.h], [], [
 351       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 352     ], [AC_INCLUDES_DEFAULT])
 353
 354     AC_CHECK_DECLS([RTE_LIBRTE_VHOST_NUMA, RTE_EAL_NUMA_AWARE_HUGEPAGES], [
 355       OVS_FIND_DEPENDENCY([get_mempolicy], [numa], [libnuma])
 356     ], [], [[#include <rte_config.h>]])
 357
 358     AC_CHECK_DECL([RTE_LIBRTE_VHOST_NUMA], [
 359       AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])
 360     ], [], [[#include <rte_config.h>]])
 361
 362    AC_MSG_CHECKING([whether DPDK pdump support is enabled])
 363    AC_ARG_ENABLE(
 364      [dpdk-pdump],
 365      [AC_HELP_STRING([--enable-dpdk-pdump],
 366                      [Enable DPDK pdump packet capture support])],
 367      [AC_MSG_RESULT([yes])
 368       AC_MSG_WARN([DPDK pdump is deprecated, consider using ovs-tcpdump instead])
 369       AC_CHECK_DECL([RTE_LIBRTE_PMD_PCAP], [
 370         OVS_FIND_DEPENDENCY([pcap_dump], [pcap], [libpcap])
 371         AC_CHECK_DECL([RTE_LIBRTE_PDUMP], [
 372           AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])
 373         ], [
 374           AC_MSG_ERROR([RTE_LIBRTE_PDUMP is not defined in rte_config.h])
 375         ], [[#include <rte_config.h>]])
 376       ], [
 377         AC_MSG_ERROR([RTE_LIBRTE_PMD_PCAP is not defined in rte_config.h])
 378       ], [[#include <rte_config.h>]])],
 379       [AC_MSG_RESULT([no])])
 380
 381     AC_CHECK_DECL([RTE_LIBRTE_MLX5_PMD], [dnl found
 382       OVS_FIND_DEPENDENCY([mnl_attr_put], [mnl], [libmnl])
 383       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 384         OVS_FIND_DEPENDENCY([mlx5dv_create_wq], [mlx5], [libmlx5])
 385         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 386       ], [[#include <rte_config.h>]])
 387     ], [], [[#include <rte_config.h>]])
 388
 389     AC_CHECK_DECL([RTE_LIBRTE_MLX4_PMD], [dnl found
 390       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 391         OVS_FIND_DEPENDENCY([mlx4dv_init_obj], [mlx4], [libmlx4])
 392         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 393       ], [[#include <rte_config.h>]])
 394     ], [], [[#include <rte_config.h>]])
 395
 396     # DPDK uses dlopen to load plugins.
 397     OVS_FIND_DEPENDENCY([dlopen], [dl], [libdl])
 398
 399     AC_MSG_CHECKING([whether linking with dpdk works])
 400     LIBS="$DPDK_LIB $LIBS"
 401     AC_LINK_IFELSE(
 402       [AC_LANG_PROGRAM([#include <rte_config.h>
 403                         #include <rte_eal.h>],
 404                        [int rte_argc; char ** rte_argv;
 405                         rte_eal_init(rte_argc, rte_argv);])],
 406       [AC_MSG_RESULT([yes])
 407        DPDKLIB_FOUND=true],
 408       [AC_MSG_RESULT([no])
 409        if test "$DPDK_AUTO_DISCOVER" = "true"; then
 410          AC_MSG_ERROR(m4_normalize([
 411             Could not find DPDK library in default search path, Use --with-dpdk
 412             to specify the DPDK library installed in non-standard location]))
 413        else
 414          AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 415        fi
 416       ])
 417
 418     CFLAGS="$ovs_save_CFLAGS"
 419     LDFLAGS="$ovs_save_LDFLAGS"
 420     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 421       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 422     fi
 423     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 424     OVS_ENABLE_OPTION([-mssse3])
 425
 426     # DPDK pmd drivers are not linked unless --whole-archive is used.
 427     #
 428     # This happens because the rest of the DPDK code doesn't use any symbol in
 429     # the pmd driver objects, and the drivers register themselves using an
 430     # __attribute__((constructor)) function.
 431     #
 432     # These options are specified inside a single -Wl directive to prevent
 433     # autotools from reordering them.
 434     #
 435     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 436     # will already have flagged just the right set of libs with
 437     # --whole-archive - in those cases do not wrap it once more.
 438     case "$DPDK_LIB" in
 439       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 440       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 441     esac
 442     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 443     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 444   fi
 445
 446   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 447 ])
 448
 449 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 450 dnl
 451 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 452 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 453 dnl <REGEX> translated to uppercase.
 454 AC_DEFUN([OVS_GREP_IFELSE], [
 455   AC_MSG_CHECKING([whether $2 matches in $1])
 456   if test -f $1; then
 457     grep '$2' $1 >/dev/null 2>&1
 458     status=$?
 459     case $status in
 460       0)
 461         AC_MSG_RESULT([yes])
 462         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 463         ;;
 464       1)
 465         AC_MSG_RESULT([no])
 466         $4
 467         ;;
 468       *)
 469         AC_MSG_ERROR([grep exited with status $status])
 470         ;;
 471     esac
 472   else
 473     AC_MSG_RESULT([file not found])
 474     $4
 475   fi
 476 ])
 477
 478 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 479 dnl
 480 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 481 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 482 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 483 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 484 dnl translated to uppercase.
 485 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 486   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 487   if test -f $1; then
 488     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 489     status=$?
 490     case $status in
 491       0)
 492         AC_MSG_RESULT([yes])
 493         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 494         ;;
 495       1)
 496         AC_MSG_RESULT([no])
 497         $5
 498         ;;
 499       *)
 500         AC_MSG_ERROR([grep exited with status $status])
 501         ;;
 502     esac
 503   else
 504     AC_MSG_RESULT([file not found])
 505     $5
 506   fi
 507 ])
 508
 509 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 510 dnl
 511 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 512 dnl the function signature starting from the line matching FUNCTION
 513 dnl and ending with the line containing the closing parenthesis.  If
 514 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 515 dnl IF-MATCH is empty then it defines to
 516 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 517 dnl <REGEX> translated to uppercase.
 518 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 519   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 520   if test -f $1; then
 521     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 522     status=$?
 523     case $status in
 524       0)
 525         AC_MSG_RESULT([yes])
 526         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 527         ;;
 528       1)
 529         AC_MSG_RESULT([no])
 530         $5
 531         ;;
 532       *)
 533         AC_MSG_ERROR([grep exited with status $status])
 534         ;;
 535     esac
 536   else
 537     AC_MSG_RESULT([file not found])
 538     $5
 539   fi
 540 ])
 541
 542 dnl OVS_DEFINE(NAME)
 543 dnl
 544 dnl Defines NAME to 1 in kcompat.h.
 545 AC_DEFUN([OVS_DEFINE], [
 546   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 547 ])
 548
 549 dnl OVS_CHECK_LINUX_COMPAT
 550 dnl
 551 dnl Runs various Autoconf checks on the Linux kernel source in
 552 dnl the directory in $KBUILD.
 553 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 554   rm -f datapath/linux/kcompat.h.new
 555   mkdir -p datapath/linux
 556   : > datapath/linux/kcompat.h.new
 557
 558   echo '#include <linux/version.h>
 559 #ifndef RHEL_RELEASE_CODE
 560 #define RHEL_RELEASE_CODE 0
 561 #define RHEL_RELEASE_VERSION(a, b) 0
 562 #endif' >> datapath/linux/kcompat.h.new
 563
 564   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 565                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 566
 567   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 568                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 569
 570   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 571                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 572   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 573
 574   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 575   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 576   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 577
 578   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 579                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 580   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 581                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 582
 583   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 584   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 585
 586   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 587   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 588   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 589   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 590   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 591   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_hwaccel_clear_tag])
 592
 593   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 594   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 595   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 596                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 597   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 598                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 599
 600   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 601                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 602   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 603                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 604   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 605                         [ip_do_fragment], [net],
 606                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 607   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 608                         [ip_local_out], [net],
 609                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 610
 611   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 612
 613   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 614                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 615   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 616   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 617                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 618   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 619                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 620   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 621   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 622   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 623                         [frags_work])
 624   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 625                         [rwlock])
 626   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 627                         [list_evictor])
 628   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 629   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 630                         [sub_frag_mem_limit], [struct.netns_frags],
 631                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 632   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 633                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 634   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 635                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 636
 637   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 638   dnl OVS does not really need ipv6 label field, but its presence signifies that
 639   dnl the stack has all required ipv6 support.
 640   dnl OVS also does not need dst_cache But this dependency allows us to write
 641   dnl much cleaner code.
 642
 643   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 644                         [label],
 645                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 646                                          [iptunnel_pull_offloads],
 647                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 648                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 649                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 650
 651   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 652                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 653   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 654                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 655   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 656                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 657   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 658   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 659   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 660   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 661   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 662   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 663   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 664   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 665   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 666   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 667                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 668   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 669   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 670   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 671   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 672   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 673   dnl So check type of tstats.
 674   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 675                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 676   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 677                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 678   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 679   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 680   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 681                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 682   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 683   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 684   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 685                         [extended])
 686   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 687                         [netdev_master_upper_dev_link], [upper_priv],
 688                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 689   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 690                   [netdev_master_upper_dev_link_rh],
 691                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 692
 693   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 694                         [max_mtu])
 695   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 696                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 697   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 698                         [dev_change_flags], [extack],
 699                         [OVS_DEFINE([HAVE_DEV_CHANGE_FLAGS_TAKES_EXTACK])])
 700
 701   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 702   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state],
 703                         [struct net ], [OVS_DEFINE([HAVE_NF_HOOK_STATE_NET])])
 704   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 705   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 706                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 707   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 708                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 709   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 710                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 711   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 712   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [CONFIG_NF_NAT_NEEDED])
 713
 714
 715   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 716                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 717
 718   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 719                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 720                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 721   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 722                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 723
 724   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 725                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 726                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 727   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 728                   [nf_ct_get_tuplepr], [struct.net],
 729                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 730   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 731                   [nf_ct_set])
 732   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 733                   [nf_ct_is_untracked])
 734   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 735                   [nf_ct_invert_tuplepr])
 736   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 737                   [nf_ct_zone_init])
 738   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 739                   [net_ns_get])
 740   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 741                   [nf_connlabels_get])
 742   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 743                   [nf_connlabels_get], [int bit],
 744                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 745   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 746                         [nf_conn_labels], [words])
 747   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 748   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 749   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 750   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_packet],
 751                   [OVS_DEFINE([HAVE_UPSTREAM_NF_NAT])])
 752   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 753   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 754                   [OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h],
 755                                    [int nf_conncount_add],
 756                                    [], [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])])
 757   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [nf_ct_set_timeout])
 758   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [struct nf_ct_timeout],
 759                   [OVS_DEFINE([HAVE_NF_CT_TIMEOUT])])
 760   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h],
 761                         [\(*nf_ct_timeout_find_get_hook\)], [net],
 762                         [OVS_DEFINE([HAVE_NF_CT_TIMEOUT_FIND_GET_HOOK_NET])])
 763
 764   OVS_GREP_IFELSE([$KSRC/include/linux/random.h],
 765                   [prandom_u32[[\(]]],
 766                   [OVS_DEFINE([HAVE_PRANDOM_U32])])
 767   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 768
 769   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 770   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 771   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 772                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 773   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 774
 775   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 776                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 777                                    [rcu_read_lock_held])])
 778   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 779   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 780   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
 781                         [rtnl_create_link], [extack],
 782                         [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_TAKES_EXTACK])])
 783   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [nf_reset_ct])
 784
 785   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 786   # is necessary because some versions of this header remove the
 787   # member but retain the kerneldoc comment that describes it (which
 788   # starts with @).  The brackets must be doubled because of m4
 789   # quoting rules.
 790   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 791                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 792   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 793   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 794   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 795   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 796   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 797   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 798   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 799                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 800   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 801                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 802   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 803                   [skb_copy_from_linear_data_offset])
 804   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 805                   [skb_reset_tail_pointer])
 806   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 807   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 808                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 809   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 810   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 811   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 812   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 813   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 814   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 815   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 816   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 817                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 818   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 819   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 820                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 821   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 822                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 823   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 824   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 825   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 826   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 827   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 828   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 829   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 830   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 831   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 832
 833   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 834                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 835   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 836                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 837   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 838                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 839
 840   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 841   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 842
 843   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 844   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 845
 846   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 847   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 848   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 849   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 850                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 851   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 852   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 853                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 854   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_validate_flags])
 855   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 856                         [genl_notify], [net],
 857                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 858
 859
 860   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 861                         [genl_multicast_group], [id])
 862   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 863
 864   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 865   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 866   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 867   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 868   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 869   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 870                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 871   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 872                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 873
 874   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 875   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 876   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 877   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 878   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 879   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 880   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 881   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 882   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_nest_start_noflag])
 883   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 884                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 885   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 886                         [nla_parse], [netlink_ext_ack],
 887                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 888
 889   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 890
 891   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 892   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 893   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 894   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 895   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 896
 897   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 898                         [metadata_dst_alloc], [metadata_type])
 899
 900   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 901
 902   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 903                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 904   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 905                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 906                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 907   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 908   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 909   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 910                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 911   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 912                         [gro_receive])
 913
 914   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 915                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 916   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 917                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 918
 919   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 920   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 921   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 922                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 923   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 924                         [udp_add_offload], [net],
 925                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 926   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 927                         [nf_defrag_ipv6_enable], [net],
 928                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 929   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 930                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 931   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 932                         [needs_free_netdev],
 933                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 934   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 935                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 936   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 937                   [nf_conntrack_helper_put],
 938                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 939   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 940                   [nf_nat_helper_try_module_get])
 941   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 942                   [nf_nat_helper_put])
 943   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 944                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 945   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 946                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 947   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 948                         [extack],
 949                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 950   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 951                         [list],
 952                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 953   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 954                   [IP_CT_UNTRACKED])
 955   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 956                         [netdev_master_upper_dev_link], [extack],
 957                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 958   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 959                   [__LINUX_COMPILER_TYPES_H],
 960                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 961   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 962                   [ktime_get_ts64],
 963                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 964   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 965                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 966                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 967   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 968                   [ktime_get_ns],
 969                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 970   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 971                   frag_percpu_counter_batch[],
 972                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 973   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 974                   [null_compute_pseudo],
 975                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 976   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 977                   [__skb_checksum_convert],
 978                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
 979   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 980                         [max_mtu],
 981                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
 982   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
 983                         [erspan_ver],
 984                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
 985   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 986                   [SKB_GSO_IPXIP6],
 987                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
 988   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
 989                         [ip6_make_flowlabel], [fl6],
 990                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
 991   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
 992                         [auto_flowlabels],
 993                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
 994   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 995                   [netif_keep_dst],
 996                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
 997   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 998                         [ndo_get_iflink],
 999                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
1000   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1001                   [skb_set_inner_ipproto],
1002                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
1003   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1004                   [tunnel_encap_types],
1005                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
1006   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1007                   [IFLA_IPTUN_ENCAP_TYPE],
1008                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
1009   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1010                   [IFLA_IPTUN_COLLECT_METADATA],
1011                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
1012   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1013                   [IFLA_GRE_ENCAP_DPORT])
1014   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1015                   [IFLA_GRE_COLLECT_METADATA])
1016   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1017                   [IFLA_GRE_IGNORE_DF])
1018   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1019                   [IFLA_GRE_FWMARK])
1020   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1021                   [IFLA_GRE_ERSPAN_INDEX])
1022   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1023                   [IFLA_GRE_ERSPAN_HWID])
1024   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1025                   [IFLA_IPTUN_FWMARK])
1026   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1027                         [csum_valid],
1028                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
1029   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1030                         [vlan_present],
1031                         [OVS_DEFINE([HAVE_SKBUFF_VLAN_PRESENT])])
1032   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1033                   [skb_checksum_simple_validate])
1034   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
1035                   [void.*ndo_get_stats64],
1036                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
1037   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
1038                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
1039   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
1040                         [ip_tunnel_info_opts_set], [flags],
1041                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
1042   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
1043                         [rnd],
1044                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
1045   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [__LINUX_OVERFLOW_H],
1046                   [OVS_DEFINE([HAVE_OVERFLOW_H])])
1047   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [struct_size],
1048                   [OVS_DEFINE([HAVE_STRUCT_SIZE])])
1049   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_array],
1050                   [OVS_DEFINE([HAVE_KVMALLOC_ARRAY])])
1051   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_node],
1052                   [OVS_DEFINE([HAVE_KVMALLOC_NODE])])
1053   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
1054                   [nf_conntrack_l3proto],
1055                   [OVS_DEFINE([HAVE_NF_CONNTRACK_L3PROATO_H])])
1056   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_core.h],
1057                         [nf_conntrack_in], [nf_hook_state],
1058                         [OVS_DEFINE([HAVE_NF_CONNTRACK_IN_TAKES_NF_HOOK_STATE])])
1059   OVS_GREP_IFELSE([$KSRC/include/net/ipv6_frag.h], [IP6_DEFRAG_CONNTRACK_IN],
1060                   [OVS_DEFINE([HAVE_IPV6_FRAG_H])])
1061   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
1062                         [nf_ct_helper_ext_add], [nf_conntrack_helper],
1063                         [OVS_DEFINE([HAVE_NF_CT_HELPER_EXT_ADD_TAKES_HELPER])])
1064   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_calc_hlen],
1065                   [OVS_DEFINE([HAVE_GRE_CALC_HLEN])])
1066   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [ip_gre_calc_hlen],
1067                   [OVS_DEFINE([HAVE_IP_GRE_CALC_HLEN])])
1068   OVS_GREP_IFELSE([$KSRC/include/linux/rbtree.h], [rb_link_node_rcu],
1069                   [OVS_DEFINE([HAVE_RBTREE_RB_LINK_NODE_RCU])])
1070   OVS_GREP_IFELSE([$KSRC/include/net/dst_ops.h], [bool confirm_neigh],
1071                   [OVS_DEFINE([HAVE_DST_OPS_CONFIRM_NEIGH])])
1072
1073   if cmp -s datapath/linux/kcompat.h.new \
1074             datapath/linux/kcompat.h >/dev/null 2>&1; then
1075     rm datapath/linux/kcompat.h.new
1076   else
1077     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
1078   fi
1079 ])
1080
1081 dnl Checks for net/if_dl.h.
1082 dnl
1083 dnl (We use this as a proxy for checking whether we're building on FreeBSD
1084 dnl or NetBSD.)
1085 AC_DEFUN([OVS_CHECK_IF_DL],
1086   [AC_CHECK_HEADER([net/if_dl.h],
1087                    [HAVE_IF_DL=yes],
1088                    [HAVE_IF_DL=no])
1089    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
1090    if test "$HAVE_IF_DL" = yes; then
1091       AC_DEFINE([HAVE_IF_DL], [1],
1092                 [Define to 1 if net/if_dl.h is available.])
1093
1094       # On these platforms we use libpcap to access network devices.
1095       AC_SEARCH_LIBS([pcap_open_live], [pcap])
1096    fi])
1097
1098 dnl Checks for buggy strtok_r.
1099 dnl
1100 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
1101 dnl with optimization that can cause segfaults:
1102 dnl
1103 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
1104 AC_DEFUN([OVS_CHECK_STRTOK_R],
1105   [AC_CACHE_CHECK(
1106      [whether strtok_r macro segfaults on some inputs],
1107      [ovs_cv_strtok_r_bug],
1108      [AC_RUN_IFELSE(
1109         [AC_LANG_PROGRAM([#include <stdio.h>
1110                           #include <string.h>
1111                          ],
1112                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
1113                            /* Assume bug is present, because relatively minor
1114                               changes in compiler settings (e.g. optimization
1115                               level) can make it crop up. */
1116                            return 1;
1117                            #else
1118                            char string[] = ":::";
1119                            char *save_ptr = (char *) 0xc0ffee;
1120                            char *token1, *token2;
1121                            token1 = strtok_r(string, ":", &save_ptr);
1122                            token2 = strtok_r(NULL, ":", &save_ptr);
1123                            freopen ("/dev/null", "w", stdout);
1124                            printf ("%s %s\n", token1, token2);
1125                            return 0;
1126                            #endif
1127                           ]])],
1128         [ovs_cv_strtok_r_bug=no],
1129         [ovs_cv_strtok_r_bug=yes],
1130         [ovs_cv_strtok_r_bug=yes])])
1131    if test $ovs_cv_strtok_r_bug = yes; then
1132      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1133                [Define if strtok_r macro segfaults on some inputs])
1134    fi
1135 ])
1136
1137 dnl ----------------------------------------------------------------------
1138 dnl These macros are from GNU PSPP, with the following original license:
1139 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1140 dnl This file is free software; the Free Software Foundation
1141 dnl gives unlimited permission to copy and/or distribute it,
1142 dnl with or without modifications, as long as this notice is preserved.
1143
1144 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1145   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1146   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1147     [ovs_save_CFLAGS="$CFLAGS"
1148      dnl Include -Werror in the compiler options, because without -Werror
1149      dnl clang's GCC-compatible compiler driver does not return a failure
1150      dnl exit status even though it complains about options it does not
1151      dnl understand.
1152      dnl
1153      dnl Also, check stderr as gcc exits with status 0 for options
1154      dnl rejected at getopt level.
1155      dnl    % touch /tmp/a.c
1156      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1157      dnl    gcc: unrecognized option '-Qunused-arguments'
1158      dnl    0
1159      dnl    %
1160      dnl
1161      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1162      dnl it does not understand, unless it has another error to report, so
1163      dnl instead of testing for -Wno-<foo>, test for the positive version.
1164      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1165      AC_COMPILE_IFELSE(
1166        [AC_LANG_SOURCE([int x;])],
1167        [if test -s conftest.err && grep "unrecognized option" conftest.err
1168         then
1169           ovs_cv_name[]=no
1170         else
1171           ovs_cv_name[]=yes
1172         fi],
1173        [ovs_cv_name[]=no])
1174      CFLAGS="$ovs_save_CFLAGS"])
1175   if test $ovs_cv_name = yes; then
1176     m4_if([$2], [], [:], [$2])
1177   else
1178     m4_if([$3], [], [:], [$3])
1179   fi
1180 ])
1181
1182 dnl OVS_CHECK_WERROR
1183 dnl
1184 dnl Check whether the C compiler accepts -Werror.
1185 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1186 AC_DEFUN([OVS_CHECK_WERROR],
1187   [WERROR=
1188    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1189
1190 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1191 dnl Check whether the given C compiler OPTION is accepted.
1192 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1193 AC_DEFUN([OVS_CHECK_CC_OPTION],
1194   [AC_REQUIRE([OVS_CHECK_WERROR])
1195    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1196
1197 dnl OVS_ENABLE_OPTION([OPTION])
1198 dnl Check whether the given C compiler OPTION is accepted.
1199 dnl If so, add it to WARNING_FLAGS.
1200 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1201 AC_DEFUN([OVS_ENABLE_OPTION],
1202   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1203    AC_SUBST([WARNING_FLAGS])])
1204
1205 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1206 dnl Check whether the given C compiler OPTION is accepted.
1207 dnl If so, enable the given Automake CONDITIONAL.
1208
1209 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1210 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1211   [OVS_CHECK_CC_OPTION(
1212     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1213    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1214 dnl ----------------------------------------------------------------------
1215
1216 dnl Check for too-old XenServer.
1217 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1218   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1219     [if test -e /etc/redhat-release; then
1220        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1221      fi
1222      if test -z "$ovs_cv_xsversion"; then
1223        ovs_cv_xsversion=none
1224      fi])
1225   case $ovs_cv_xsversion in
1226     none)
1227       ;;
1228
1229     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1230     [[6-9]]* |                           dnl XenServer 6 or later
1231     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1232     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1233     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1234     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1235       ;;
1236
1237     *)
1238       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1239       ;;
1240   esac])
1241
1242 dnl OVS_CHECK_SPARSE_TARGET
1243 dnl
1244 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1245 dnl target for which the code is being built.  This helps it out.
1246 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1247   [AC_CACHE_CHECK(
1248     [target hint for cgcc],
1249     [ac_cv_sparse_target],
1250     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1251        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1252        [x86_64-*], [ac_cv_sparse_target=x86_64],
1253        [ac_cv_sparse_target=other])])
1254    AS_CASE([$ac_cv_sparse_target],
1255      [x86], [SPARSEFLAGS= CGCCFLAGS="-target=i86 -target=host_os_specs"],
1256      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS="-target=x86_64 -target=host_os_specs"],
1257      [SPARSEFLAGS= CGCCFLAGS=])
1258
1259    dnl Get the default defines for vector instructions from compiler to
1260    dnl allow "sparse" correctly check the same code that will be built.
1261    dnl Required for checking DPDK headers.
1262    AC_MSG_CHECKING([vector options for cgcc])
1263    VECTOR=$($CC -dM -E - < /dev/null | grep -E "MMX|SSE|AVX" | \
1264             cut -c 9- | sed 's/ /=/' | sed 's/^/-D/' | tr '\n' ' ')
1265    AC_MSG_RESULT([$VECTOR])
1266    CGCCFLAGS="$CGCCFLAGS $VECTOR"
1267
1268    AC_SUBST([SPARSEFLAGS])
1269    AC_SUBST([CGCCFLAGS])])
1270
1271 dnl OVS_SPARSE_EXTRA_INCLUDES
1272 dnl
1273 dnl The cgcc script from "sparse" does not search gcc's default
1274 dnl search path. Get the default search path from GCC and pass
1275 dnl them to sparse.
1276 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1277     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1278            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1279
1280 dnl OVS_ENABLE_SPARSE
1281 AC_DEFUN([OVS_ENABLE_SPARSE],
1282   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1283    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1284    : ${SPARSE=sparse}
1285    AC_SUBST([SPARSE])
1286    AC_CONFIG_COMMANDS_PRE(
1287      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1288
1289    AC_ARG_ENABLE(
1290      [sparse],
1291      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1292      [], [enable_sparse=no])
1293    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1294
1295 dnl OVS_CTAGS_IDENTIFIERS
1296 dnl
1297 dnl ctags ignores symbols with extras identifiers. This builds a list of
1298 dnl specially handled identifiers to be ignored.
1299 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1300     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1301            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1302
1303 dnl OVS_PTHREAD_SET_NAME
1304 dnl
1305 dnl This checks for three known variants of pthreads functions for setting
1306 dnl the name of the current thread:
1307 dnl
1308 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1309 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1310 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1311 dnl
1312 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1313 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1314 dnl provide to it.
1315 dnl
1316 dnl This macro defines:
1317 dnl
1318 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1319 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1320 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1321 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1322   [AC_CHECK_FUNCS([pthread_set_name_np])
1323    if test $ac_cv_func_pthread_set_name_np != yes; then
1324      AC_CACHE_CHECK(
1325        [for pthread_setname_np() variant],
1326        [ovs_cv_pthread_setname_np],
1327        [AC_LINK_IFELSE(
1328          [AC_LANG_PROGRAM([#include <pthread.h>
1329   ], [pthread_setname_np(pthread_self(), "name");])],
1330          [ovs_cv_pthread_setname_np=glibc],
1331          [AC_LINK_IFELSE(
1332            [AC_LANG_PROGRAM([#include <pthread.h>
1333 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1334            [ovs_cv_pthread_setname_np=netbsd],
1335            [ovs_cv_pthread_setname_np=none])])])
1336      case $ovs_cv_pthread_setname_np in # (
1337        glibc)
1338           AC_DEFINE(
1339             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1340             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1341           ;; # (
1342        netbsd)
1343           AC_DEFINE(
1344             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1345             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1346           ;;
1347      esac
1348    fi])
1349
1350 dnl OVS_CHECK_LINUX_HOST.
1351 dnl
1352 dnl Checks whether we're building for a Linux host, based on the presence of
1353 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1354 dnl LINUX based on the result.
1355 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1356   [AC_CACHE_CHECK(
1357      [whether __linux__ is defined],
1358      [ovs_cv_linux],
1359      [AC_COMPILE_IFELSE(
1360         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1361         [ovs_cv_linux=true],
1362         [ovs_cv_linux=false])])
1363    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])