acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2019 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl Set OVS DPCLS Autovalidator as default subtable search at compile time?
  18 dnl This enables automatically running all unit tests with all DPCLS
  19 dnl implementations.
  20 AC_DEFUN([OVS_CHECK_DPCLS_AUTOVALIDATOR], [
  21   AC_ARG_ENABLE([autovalidator],
  22                 [AC_HELP_STRING([--enable-autovalidator], [Enable DPCLS autovalidator as default subtable search implementation.])],
  23                 [autovalidator=yes],[autovalidator=no])
  24   AC_MSG_CHECKING([whether DPCLS Autovalidator is default implementation])
  25   if test "$autovalidator" != yes; then
  26     AC_MSG_RESULT([no])
  27   else
  28     OVS_CFLAGS="$OVS_CFLAGS -DDPCLS_AUTOVALIDATOR_DEFAULT"
  29     AC_MSG_RESULT([yes])
  30   fi
  31 ])
  32
  33 dnl OVS_ENABLE_WERROR
  34 AC_DEFUN([OVS_ENABLE_WERROR],
  35   [AC_ARG_ENABLE(
  36      [Werror],
  37      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  38      [], [enable_Werror=no])
  39    AC_CONFIG_COMMANDS_PRE(
  40      [if test "X$enable_Werror" = Xyes; then
  41         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  42       fi])
  43
  44    # Unless --enable-Werror is specified, report but do not fail the build
  45    # for errors reported by flake8.
  46    if test "X$enable_Werror" = Xyes; then
  47      FLAKE8_WERROR=
  48    else
  49      FLAKE8_WERROR=-
  50    fi
  51    AC_SUBST([FLAKE8_WERROR])
  52
  53    # If --enable-Werror is specified, fail the build on sparse warnings.
  54    if test "X$enable_Werror" = Xyes; then
  55      SPARSE_WERROR=-Wsparse-error
  56    else
  57      SPARSE_WERROR=
  58    fi
  59    AC_SUBST([SPARSE_WERROR])])
  60
  61 dnl OVS_CHECK_LINUX
  62 dnl
  63 dnl Configure linux kernel source tree
  64 AC_DEFUN([OVS_CHECK_LINUX], [
  65   AC_ARG_WITH([linux],
  66               [AC_HELP_STRING([--with-linux=/path/to/linux],
  67                               [Specify the Linux kernel build directory])])
  68   AC_ARG_WITH([linux-source],
  69               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  70                               [Specify the Linux kernel source directory
  71                                (usually figured out automatically from build
  72                                directory)])])
  73
  74   # Deprecated equivalents to --with-linux, --with-linux-source.
  75   AC_ARG_WITH([l26])
  76   AC_ARG_WITH([l26-source])
  77
  78   if test X"$with_linux" != X; then
  79     KBUILD=$with_linux
  80   elif test X"$with_l26" != X; then
  81     KBUILD=$with_l26
  82     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  83   else
  84     KBUILD=
  85   fi
  86
  87   if test X"$KBUILD" != X; then
  88     if test X"$with_linux_source" != X; then
  89       KSRC=$with_linux_source
  90     elif test X"$with_l26_source" != X; then
  91       KSRC=$with_l26_source
  92       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  93     else
  94       KSRC=
  95     fi
  96   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  97     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  98   fi
  99
 100   if test -n "$KBUILD"; then
 101     KBUILD=`eval echo "$KBUILD"`
 102     case $KBUILD in
 103         /*) ;;
 104         *) KBUILD=`pwd`/$KBUILD ;;
 105     esac
 106
 107     # The build directory is what the user provided.
 108     # Make sure that it exists.
 109     AC_MSG_CHECKING([for Linux build directory])
 110     if test -d "$KBUILD"; then
 111         AC_MSG_RESULT([$KBUILD])
 112         AC_SUBST(KBUILD)
 113     else
 114         AC_MSG_RESULT([no])
 115         AC_ERROR([source dir $KBUILD doesn't exist])
 116     fi
 117
 118     # Debian breaks kernel headers into "source" header and "build" headers.
 119     # We want the source headers, but $KBUILD gives us the "build" headers.
 120     # Use heuristics to find the source headers.
 121     AC_MSG_CHECKING([for Linux source directory])
 122     if test -n "$KSRC"; then
 123       KSRC=`eval echo "$KSRC"`
 124       case $KSRC in
 125           /*) ;;
 126           *) KSRC=`pwd`/$KSRC ;;
 127       esac
 128       if test ! -e $KSRC/include/linux/kernel.h; then
 129         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 130       fi
 131     else
 132       KSRC=$KBUILD
 133       if test ! -e $KSRC/include/linux/kernel.h; then
 134         # Debian kernel build Makefiles tend to include a line of the form:
 135         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 136         # First try to extract the source directory from this line.
 137         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 138         if test ! -e "$KSRC"/include/linux/kernel.h; then
 139           # Didn't work.  Fall back to name-based heuristics that used to work.
 140           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 141             */build)
 142               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 143               ;; # (
 144             *)
 145               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 146               ;;
 147           esac
 148         fi
 149       fi
 150       if test ! -e "$KSRC"/include/linux/kernel.h; then
 151         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 152       fi
 153     fi
 154     AC_MSG_RESULT([$KSRC])
 155
 156     AC_MSG_CHECKING([for kernel version])
 157     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 158     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 159     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 160     if test X"$version" = X || test X"$patchlevel" = X; then
 161        AC_ERROR([cannot determine kernel version])
 162     elif test X"$sublevel" = X; then
 163        kversion=$version.$patchlevel
 164     else
 165        kversion=$version.$patchlevel.$sublevel
 166     fi
 167     AC_MSG_RESULT([$kversion])
 168
 169     if test "$version" -ge 5; then
 170        if test "$version" = 5 && test "$patchlevel" -le 5; then
 171           : # Linux 5.x
 172        else
 173           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 5.5.x is not supported (please refer to the FAQ for advice)])
 174        fi
 175     elif test "$version" = 4; then
 176        : # Linux 4.x
 177     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 178        : # Linux 3.x
 179     else
 180        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 181     fi
 182     if (test ! -e "$KBUILD"/include/linux/version.h && \
 183         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 184        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 185         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 186         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 187     fi
 188     OVS_CHECK_LINUX_COMPAT
 189   fi
 190   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 191 ])
 192
 193 dnl OVS_CHECK_LINUX_NETLINK
 194 dnl
 195 dnl Configure Linux netlink compat.
 196 AC_DEFUN([OVS_CHECK_LINUX_NETLINK], [
 197   AC_COMPILE_IFELSE([
 198     AC_LANG_PROGRAM([#include <linux/netlink.h>], [
 199         struct nla_bitfield32 x =  { 0 };
 200     ])],
 201     [AC_DEFINE([HAVE_NLA_BITFIELD32], [1],
 202     [Define to 1 if struct nla_bitfield32 is available.])])
 203 ])
 204
 205 dnl OVS_CHECK_LINUX_TC
 206 dnl
 207 dnl Configure Linux tc compat.
 208 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 209   AC_COMPILE_IFELSE([
 210     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 211         int x = TCA_ACT_FLAGS;
 212     ])],
 213     [AC_DEFINE([HAVE_TCA_ACT_FLAGS], [1],
 214                [Define to 1 if TCA_ACT_FLAGS is available.])])
 215
 216   AC_CHECK_MEMBERS([struct tcf_t.firstuse], [], [], [#include <linux/pkt_cls.h>])
 217
 218   AC_COMPILE_IFELSE([
 219     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 220         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 221     ])],
 222     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 223                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 224
 225   AC_COMPILE_IFELSE([
 226     AC_LANG_PROGRAM([#include <linux/tc_act/tc_mpls.h>], [
 227         int x = TCA_MPLS_TTL;
 228     ])],
 229     [AC_DEFINE([HAVE_TCA_MPLS_TTL], [1],
 230                [Define to 1 if HAVE_TCA_MPLS_TTL is available.])])
 231
 232   AC_COMPILE_IFELSE([
 233     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 234         int x = TCA_TUNNEL_KEY_ENC_TTL;
 235     ])],
 236     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 237                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 238
 239   AC_COMPILE_IFELSE([
 240     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 241         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 242     ])],
 243     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 244                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 245
 246   AC_COMPILE_IFELSE([
 247     AC_LANG_PROGRAM([#include <linux/tc_act/tc_skbedit.h>], [
 248         int x = TCA_SKBEDIT_FLAGS;
 249     ])],
 250     [AC_DEFINE([HAVE_TCA_SKBEDIT_FLAGS], [1],
 251                [Define to 1 if TCA_SKBEDIT_FLAGS is available.])])
 252 ])
 253
 254 dnl OVS_CHECK_LINUX_SCTP_CT
 255 dnl
 256 dnl Checks for kernels which need additional SCTP state
 257 AC_DEFUN([OVS_CHECK_LINUX_SCTP_CT], [
 258   AC_COMPILE_IFELSE([
 259     AC_LANG_PROGRAM([#include <linux/netfilter/nfnetlink.h>
 260 #include <linux/netfilter/nfnetlink_conntrack.h>
 261 #include <linux/netfilter/nf_conntrack_common.h>
 262 #include <linux/netfilter/nf_conntrack_sctp.h>], [
 263         int x = SCTP_CONNTRACK_HEARTBEAT_SENT;
 264     ])],
 265     [AC_DEFINE([HAVE_SCTP_CONNTRACK_HEARTBEATS], [1],
 266                [Define to 1 if SCTP_CONNTRACK_HEARTBEAT_SENT is available.])])
 267 ])
 268
 269 dnl OVS_CHECK_LINUX_VIRTIO_TYPES
 270 dnl
 271 dnl Checks for kernels that need virtio_types definition.
 272 AC_DEFUN([OVS_CHECK_LINUX_VIRTIO_TYPES], [
 273   AC_COMPILE_IFELSE([
 274     AC_LANG_PROGRAM([#include <linux/virtio_types.h>], [
 275         __virtio16 x =  0;
 276     ])],
 277     [AC_DEFINE([HAVE_VIRTIO_TYPES], [1],
 278     [Define to 1 if __virtio16 is available.])])
 279 ])
 280
 281 dnl OVS_FIND_DEPENDENCY(FUNCTION, SEARCH_LIBS, NAME_TO_PRINT)
 282 dnl
 283 dnl Check for a function in a library list.
 284 AC_DEFUN([OVS_FIND_DEPENDENCY], [
 285   AC_SEARCH_LIBS([$1], [$2], [], [
 286     AC_MSG_ERROR([unable to find $3, install the dependency package])
 287   ])
 288 ])
 289
 290 dnl OVS_CHECK_LINUX_AF_XDP
 291 dnl
 292 dnl Check both Linux kernel AF_XDP and libbpf support
 293 AC_DEFUN([OVS_CHECK_LINUX_AF_XDP], [
 294   AC_ARG_ENABLE([afxdp],
 295                 [AC_HELP_STRING([--enable-afxdp], [Enable AF-XDP support])],
 296                 [], [enable_afxdp=no])
 297   AC_MSG_CHECKING([whether AF_XDP is enabled])
 298   if test "$enable_afxdp" != yes; then
 299     AC_MSG_RESULT([no])
 300     AF_XDP_ENABLE=false
 301   else
 302     AC_MSG_RESULT([yes])
 303     AF_XDP_ENABLE=true
 304
 305     AC_CHECK_HEADER([bpf/libbpf.h], [],
 306       [AC_MSG_ERROR([unable to find bpf/libbpf.h for AF_XDP support])])
 307
 308     AC_CHECK_HEADER([linux/if_xdp.h], [],
 309       [AC_MSG_ERROR([unable to find linux/if_xdp.h for AF_XDP support])])
 310
 311     AC_CHECK_HEADER([bpf/xsk.h], [],
 312       [AC_MSG_ERROR([unable to find bpf/xsk.h for AF_XDP support])])
 313
 314     AC_CHECK_FUNCS([pthread_spin_lock], [],
 315       [AC_MSG_ERROR([unable to find pthread_spin_lock for AF_XDP support])])
 316
 317     OVS_FIND_DEPENDENCY([numa_alloc_onnode], [numa], [libnuma])
 318
 319     AC_DEFINE([HAVE_AF_XDP], [1],
 320               [Define to 1 if AF_XDP support is available and enabled.])
 321     LIBBPF_LDADD=" -lbpf -lelf"
 322     AC_SUBST([LIBBPF_LDADD])
 323
 324     AC_CHECK_DECL([xsk_ring_prod__needs_wakeup], [
 325       AC_DEFINE([HAVE_XDP_NEED_WAKEUP], [1],
 326         [XDP need wakeup support detected in xsk.h.])
 327     ], [], [[#include <bpf/xsk.h>]])
 328   fi
 329   AM_CONDITIONAL([HAVE_AF_XDP], test "$AF_XDP_ENABLE" = true)
 330 ])
 331
 332 dnl OVS_CHECK_DPDK
 333 dnl
 334 dnl Configure DPDK source tree
 335 AC_DEFUN([OVS_CHECK_DPDK], [
 336   AC_ARG_WITH([dpdk],
 337               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 338                               [Specify the DPDK build directory])],
 339               [have_dpdk=true])
 340
 341   AC_MSG_CHECKING([whether dpdk is enabled])
 342   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 343     AC_MSG_RESULT([no])
 344     DPDKLIB_FOUND=false
 345   else
 346     AC_MSG_RESULT([yes])
 347     case "$with_dpdk" in
 348       yes)
 349         DPDK_AUTO_DISCOVER="true"
 350         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 351             DPDK_INCLUDE="$DPDK_CFLAGS"
 352             DPDK_LIB="$DPDK_LIBS"], [
 353             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 354             DPDK_LIB="-ldpdk"])
 355         ;;
 356       *)
 357         DPDK_AUTO_DISCOVER="false"
 358         DPDK_INCLUDE_PATH="$with_dpdk/include"
 359         # If 'with_dpdk' is passed install directory, point to headers
 360         # installed in $DESTDIR/$prefix/include/dpdk
 361         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 362            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 363         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 364            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 365         fi
 366         DPDK_LIB_DIR="$with_dpdk/lib"
 367         DPDK_LIB="-ldpdk"
 368         ;;
 369     esac
 370
 371     ovs_save_CFLAGS="$CFLAGS"
 372     ovs_save_LDFLAGS="$LDFLAGS"
 373     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 374     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 375       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 376     fi
 377
 378     AC_CHECK_HEADERS([rte_config.h], [], [
 379       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 380     ], [AC_INCLUDES_DEFAULT])
 381
 382     AC_CHECK_DECLS([RTE_LIBRTE_VHOST_NUMA, RTE_EAL_NUMA_AWARE_HUGEPAGES], [
 383       OVS_FIND_DEPENDENCY([get_mempolicy], [numa], [libnuma])
 384     ], [], [[#include <rte_config.h>]])
 385
 386     AC_CHECK_DECL([RTE_LIBRTE_PMD_PCAP], [
 387       OVS_FIND_DEPENDENCY([pcap_dump_close], [pcap], [libpcap])
 388     ], [], [[#include <rte_config.h>]])
 389
 390     AC_CHECK_DECL([RTE_LIBRTE_PMD_AF_XDP], [
 391       LIBBPF_LDADD="-lbpf"
 392     ], [], [[#include <rte_config.h>]])
 393
 394     AC_CHECK_DECL([RTE_LIBRTE_VHOST_NUMA], [
 395       AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])
 396     ], [], [[#include <rte_config.h>]])
 397
 398     AC_CHECK_DECL([RTE_LIBRTE_MLX5_PMD], [dnl found
 399       OVS_FIND_DEPENDENCY([mnl_attr_put], [mnl], [libmnl])
 400       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 401         OVS_FIND_DEPENDENCY([mlx5dv_create_wq], [mlx5], [libmlx5])
 402         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 403       ], [[#include <rte_config.h>]])
 404     ], [], [[#include <rte_config.h>]])
 405
 406     AC_CHECK_DECL([RTE_LIBRTE_MLX4_PMD], [dnl found
 407       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 408         OVS_FIND_DEPENDENCY([mlx4dv_init_obj], [mlx4], [libmlx4])
 409         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 410       ], [[#include <rte_config.h>]])
 411     ], [], [[#include <rte_config.h>]])
 412
 413     # DPDK uses dlopen to load plugins.
 414     OVS_FIND_DEPENDENCY([dlopen], [dl], [libdl])
 415
 416     AC_MSG_CHECKING([whether linking with dpdk works])
 417     LIBS="$DPDK_LIB $LIBS"
 418     AC_LINK_IFELSE(
 419       [AC_LANG_PROGRAM([#include <rte_config.h>
 420                         #include <rte_eal.h>],
 421                        [int rte_argc; char ** rte_argv;
 422                         rte_eal_init(rte_argc, rte_argv);])],
 423       [AC_MSG_RESULT([yes])
 424        DPDKLIB_FOUND=true],
 425       [AC_MSG_RESULT([no])
 426        if test "$DPDK_AUTO_DISCOVER" = "true"; then
 427          AC_MSG_ERROR(m4_normalize([
 428             Could not find DPDK library in default search path, Use --with-dpdk
 429             to specify the DPDK library installed in non-standard location]))
 430        else
 431          AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 432        fi
 433       ])
 434
 435     CFLAGS="$ovs_save_CFLAGS"
 436     LDFLAGS="$ovs_save_LDFLAGS"
 437     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 438       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 439     fi
 440     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 441     OVS_ENABLE_OPTION([-mssse3])
 442
 443     # DPDK pmd drivers are not linked unless --whole-archive is used.
 444     #
 445     # This happens because the rest of the DPDK code doesn't use any symbol in
 446     # the pmd driver objects, and the drivers register themselves using an
 447     # __attribute__((constructor)) function.
 448     #
 449     # These options are specified inside a single -Wl directive to prevent
 450     # autotools from reordering them.
 451     #
 452     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 453     # will already have flagged just the right set of libs with
 454     # --whole-archive - in those cases do not wrap it once more.
 455     case "$DPDK_LIB" in
 456       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 457       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 458     esac
 459     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 460     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 461   fi
 462
 463   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 464 ])
 465
 466 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 467 dnl
 468 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 469 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 470 dnl <REGEX> translated to uppercase.
 471 AC_DEFUN([OVS_GREP_IFELSE], [
 472   AC_MSG_CHECKING([whether $2 matches in $1])
 473   if test -f $1; then
 474     grep '$2' $1 >/dev/null 2>&1
 475     status=$?
 476     case $status in
 477       0)
 478         AC_MSG_RESULT([yes])
 479         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 480         ;;
 481       1)
 482         AC_MSG_RESULT([no])
 483         $4
 484         ;;
 485       *)
 486         AC_MSG_ERROR([grep exited with status $status])
 487         ;;
 488     esac
 489   else
 490     AC_MSG_RESULT([file not found])
 491     $4
 492   fi
 493 ])
 494
 495 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 496 dnl
 497 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 498 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 499 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 500 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 501 dnl translated to uppercase.
 502 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 503   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 504   if test -f $1; then
 505     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 506     status=$?
 507     case $status in
 508       0)
 509         AC_MSG_RESULT([yes])
 510         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 511         ;;
 512       1)
 513         AC_MSG_RESULT([no])
 514         $5
 515         ;;
 516       *)
 517         AC_MSG_ERROR([grep exited with status $status])
 518         ;;
 519     esac
 520   else
 521     AC_MSG_RESULT([file not found])
 522     $5
 523   fi
 524 ])
 525
 526 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 527 dnl
 528 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 529 dnl the function signature starting from the line matching FUNCTION
 530 dnl and ending with the line containing the closing parenthesis.  If
 531 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 532 dnl IF-MATCH is empty then it defines to
 533 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 534 dnl <REGEX> translated to uppercase.
 535 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 536   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 537   if test -f $1; then
 538     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 539     status=$?
 540     case $status in
 541       0)
 542         AC_MSG_RESULT([yes])
 543         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 544         ;;
 545       1)
 546         AC_MSG_RESULT([no])
 547         $5
 548         ;;
 549       *)
 550         AC_MSG_ERROR([grep exited with status $status])
 551         ;;
 552     esac
 553   else
 554     AC_MSG_RESULT([file not found])
 555     $5
 556   fi
 557 ])
 558
 559 dnl OVS_FIND_OP_PARAM_IFELSE(FILE, OP, REGEX, [IF-MATCH], [IF-NO-MATCH])
 560 dnl
 561 dnl Looks for OP in FILE. If it is found, greps for REGEX within the
 562 dnl OP definition. If this is successful, runs IF-MATCH, otherwise
 563 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 564 dnl OVS_DEFINE(HAVE_<OP>_WITH_<REGEX>), with <OP> and <REGEX>
 565 dnl translated to uppercase.
 566 AC_DEFUN([OVS_FIND_OP_PARAM_IFELSE], [
 567   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 568   if test -f $1; then
 569     awk '/$2[[ \t\n]]*\)\(/,/;/' $1 2>/dev/null | grep '$3' >/dev/null
 570     status=$?
 571     case $status in
 572       0)
 573         AC_MSG_RESULT([yes])
 574         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 575         ;;
 576       1)
 577         AC_MSG_RESULT([no])
 578         $5
 579         ;;
 580       *)
 581         AC_MSG_ERROR([grep exited with status $status])
 582         ;;
 583     esac
 584   else
 585     AC_MSG_RESULT([file not found])
 586     $5
 587   fi
 588 ])
 589
 590 dnl OVS_DEFINE(NAME)
 591 dnl
 592 dnl Defines NAME to 1 in kcompat.h.
 593 AC_DEFUN([OVS_DEFINE], [
 594   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 595 ])
 596
 597 dnl OVS_CHECK_LINUX_COMPAT
 598 dnl
 599 dnl Runs various Autoconf checks on the Linux kernel source in
 600 dnl the directory in $KBUILD.
 601 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 602   rm -f datapath/linux/kcompat.h.new
 603   mkdir -p datapath/linux
 604   : > datapath/linux/kcompat.h.new
 605
 606   echo '#include <linux/version.h>
 607 #ifndef RHEL_RELEASE_CODE
 608 #define RHEL_RELEASE_CODE 0
 609 #define RHEL_RELEASE_VERSION(a, b) 0
 610 #endif' >> datapath/linux/kcompat.h.new
 611
 612   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 613                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 614
 615   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 616                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 617
 618   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub],
 619                         [dst_entry])
 620   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 621                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 622   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup_flow.*net],
 623                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_FLOW_NET])])
 624   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 625   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup_flow])
 626
 627   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 628   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 629   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 630
 631   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 632                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 633   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 634                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 635
 636   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 637   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 638
 639   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 640   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 641   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 642   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 643   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 644   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_hwaccel_clear_tag])
 645
 646   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 647   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 648   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 649                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 650   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 651                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 652
 653   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 654                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 655   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 656                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 657   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 658                         [ip_do_fragment], [net],
 659                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 660   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 661                         [ip_local_out], [net],
 662                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 663
 664   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 665
 666   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 667                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 668   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 669   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 670                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 671   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 672                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 673   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 674   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 675   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 676                         [frags_work])
 677   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 678                         [rwlock])
 679   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 680                         [list_evictor])
 681   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 682   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 683                         [sub_frag_mem_limit], [struct.netns_frags],
 684                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 685   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 686                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 687   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 688                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 689
 690   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 691   dnl OVS does not really need ipv6 label field, but its presence signifies that
 692   dnl the stack has all required ipv6 support.
 693   dnl OVS also does not need dst_cache But this dependency allows us to write
 694   dnl much cleaner code.
 695
 696   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 697                         [label],
 698                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 699                                          [iptunnel_pull_offloads],
 700                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 701                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 702                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 703
 704   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 705                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 706   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 707                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 708   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 709                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 710   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 711   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 712   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 713   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 714   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 715   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 716   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 717   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 718   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 719   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 720                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 721   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 722   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 723   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 724   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 725   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 726   dnl So check type of tstats.
 727   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 728                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 729   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 730                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 731   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 732   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 733   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 734                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 735   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 736   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 737   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 738                         [extended])
 739   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 740                         [netdev_master_upper_dev_link], [upper_priv],
 741                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 742   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 743                   [netdev_master_upper_dev_link_rh],
 744                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 745
 746   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 747                         [max_mtu])
 748   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 749                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 750   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 751                         [dev_change_flags], [extack],
 752                         [OVS_DEFINE([HAVE_DEV_CHANGE_FLAGS_TAKES_EXTACK])])
 753
 754   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 755   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state],
 756                         [struct net ], [OVS_DEFINE([HAVE_NF_HOOK_STATE_NET])])
 757   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 758   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 759                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 760   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 761                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 762   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 763                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 764   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 765   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [CONFIG_NF_NAT_NEEDED])
 766
 767
 768   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 769                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 770
 771   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 772                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 773                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 774   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 775                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 776
 777   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 778                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 779                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 780   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 781                   [nf_ct_get_tuplepr], [struct.net],
 782                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 783   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 784                   [nf_ct_set])
 785   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 786                   [nf_ct_is_untracked])
 787   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 788                   [nf_ct_invert_tuplepr])
 789   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 790                   [nf_ct_zone_init])
 791   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 792                   [net_ns_get])
 793   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 794                   [nf_connlabels_get])
 795   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 796                   [nf_connlabels_get], [int bit],
 797                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 798   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 799                         [nf_conn_labels], [words])
 800   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 801   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 802   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 803   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_packet],
 804                   [OVS_DEFINE([HAVE_UPSTREAM_NF_NAT])])
 805   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 806   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 807                   [OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h],
 808                                    [int nf_conncount_add],
 809                                    [], [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])])
 810   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [nf_ct_set_timeout])
 811   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [struct nf_ct_timeout],
 812                   [OVS_DEFINE([HAVE_NF_CT_TIMEOUT])])
 813   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h],
 814                         [\(*nf_ct_timeout_find_get_hook\)], [net],
 815                         [OVS_DEFINE([HAVE_NF_CT_TIMEOUT_FIND_GET_HOOK_NET])])
 816
 817   OVS_GREP_IFELSE([$KSRC/include/linux/random.h],
 818                   [prandom_u32[[\(]]],
 819                   [OVS_DEFINE([HAVE_PRANDOM_U32])])
 820   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 821
 822   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 823   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 824   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 825                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 826   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 827
 828   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 829                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 830                                    [rcu_read_lock_held])])
 831   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 832   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 833   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
 834                         [rtnl_create_link], [extack],
 835                         [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_TAKES_EXTACK])])
 836   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [nf_reset_ct])
 837
 838   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 839   # is necessary because some versions of this header remove the
 840   # member but retain the kerneldoc comment that describes it (which
 841   # starts with @).  The brackets must be doubled because of m4
 842   # quoting rules.
 843   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 844                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 845   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 846   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 847   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 848   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 849   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 850   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 851   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 852                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 853   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 854                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 855   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 856                   [skb_copy_from_linear_data_offset])
 857   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 858                   [skb_reset_tail_pointer])
 859   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 860   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 861                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 862   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 863   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 864   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 865   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 866   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 867   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 868   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 869   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 870                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 871   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 872   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 873                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 874   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 875                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 876   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 877   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 878   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 879   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 880   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 881   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 882   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 883   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 884   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 885
 886   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 887                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 888   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 889                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 890
 891   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 892   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 893
 894   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 895   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 896
 897   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 898   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 899   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 900   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 901                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 902   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 903   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 904                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 905   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_validate_flags])
 906   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 907                         [genl_notify], [net],
 908                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 909
 910
 911   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 912                         [genl_multicast_group], [id])
 913   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 914
 915   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 916   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 917   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 918   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 919   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 920   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 921                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 922   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 923                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 924
 925   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 926   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 927   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 928   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 929   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 930   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 931   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 932   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 933   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_nest_start_noflag])
 934   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 935                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 936   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 937                         [nla_parse], [netlink_ext_ack],
 938                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 939
 940   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 941
 942   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 943   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 944   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 945   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 946   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 947
 948   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 949                         [metadata_dst_alloc], [metadata_type])
 950
 951   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 952
 953   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 954                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 955   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 956                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 957                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 958   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 959   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 960   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 961                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 962   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 963                         [gro_receive])
 964
 965   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 966                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 967   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 968                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 969
 970   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 971   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 972   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 973                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 974   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 975                         [udp_add_offload], [net],
 976                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 977   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 978                         [nf_defrag_ipv6_enable], [net],
 979                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 980   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 981                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 982   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 983                         [needs_free_netdev],
 984                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 985   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 986                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 987   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 988                   [nf_conntrack_helper_put],
 989                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 990   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 991                   [nf_nat_helper_try_module_get])
 992   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 993                   [nf_nat_helper_put])
 994   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 995                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 996   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 997                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 998   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 999                         [extack],
1000                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
1001   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
1002                         [list],
1003                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
1004   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
1005                   [IP_CT_UNTRACKED])
1006   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
1007                         [netdev_master_upper_dev_link], [extack],
1008                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
1009   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
1010                   [__LINUX_COMPILER_TYPES_H],
1011                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
1012   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
1013                   [ktime_get_ts64],
1014                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
1015   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
1016                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
1017                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
1018   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
1019                   [ktime_get_ns],
1020                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
1021   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
1022                   frag_percpu_counter_batch[],
1023                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
1024   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1025                   [null_compute_pseudo],
1026                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
1027   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1028                   [__skb_checksum_convert],
1029                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
1030   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
1031                         [max_mtu],
1032                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
1033   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
1034                         [erspan_ver],
1035                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
1036   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1037                   [SKB_GSO_IPXIP6],
1038                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
1039   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
1040                         [ip6_make_flowlabel], [fl6],
1041                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
1042   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
1043                         [auto_flowlabels],
1044                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
1045   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
1046                   [netif_keep_dst],
1047                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
1048   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
1049                         [ndo_get_iflink],
1050                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
1051   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1052                   [skb_set_inner_ipproto],
1053                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
1054   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1055                   [tunnel_encap_types],
1056                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
1057   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1058                   [IFLA_IPTUN_ENCAP_TYPE],
1059                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
1060   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1061                   [IFLA_IPTUN_COLLECT_METADATA],
1062                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
1063   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1064                   [IFLA_GRE_ENCAP_DPORT])
1065   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1066                   [IFLA_GRE_COLLECT_METADATA])
1067   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1068                   [IFLA_GRE_IGNORE_DF])
1069   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1070                   [IFLA_GRE_FWMARK])
1071   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1072                   [IFLA_GRE_ERSPAN_INDEX])
1073   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1074                   [IFLA_GRE_ERSPAN_HWID])
1075   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1076                   [IFLA_IPTUN_FWMARK])
1077   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1078                         [csum_valid],
1079                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
1080   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1081                         [vlan_present],
1082                         [OVS_DEFINE([HAVE_SKBUFF_VLAN_PRESENT])])
1083   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1084                   [skb_checksum_simple_validate])
1085   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
1086                   [void.*ndo_get_stats64],
1087                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
1088   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
1089                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
1090   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
1091                         [ip_tunnel_info_opts_set], [flags],
1092                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
1093   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
1094                         [rnd],
1095                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
1096   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [__LINUX_OVERFLOW_H],
1097                   [OVS_DEFINE([HAVE_OVERFLOW_H])])
1098   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [struct_size],
1099                   [OVS_DEFINE([HAVE_STRUCT_SIZE])])
1100   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_array],
1101                   [OVS_DEFINE([HAVE_KVMALLOC_ARRAY])])
1102   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_node],
1103                   [OVS_DEFINE([HAVE_KVMALLOC_NODE])])
1104   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
1105                   [nf_conntrack_l3proto],
1106                   [OVS_DEFINE([HAVE_NF_CONNTRACK_L3PROATO_H])])
1107   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_core.h],
1108                         [nf_conntrack_in], [nf_hook_state],
1109                         [OVS_DEFINE([HAVE_NF_CONNTRACK_IN_TAKES_NF_HOOK_STATE])])
1110   OVS_GREP_IFELSE([$KSRC/include/net/ipv6_frag.h], [IP6_DEFRAG_CONNTRACK_IN],
1111                   [OVS_DEFINE([HAVE_IPV6_FRAG_H])])
1112   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
1113                         [nf_ct_helper_ext_add], [nf_conntrack_helper],
1114                         [OVS_DEFINE([HAVE_NF_CT_HELPER_EXT_ADD_TAKES_HELPER])])
1115   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_calc_hlen],
1116                   [OVS_DEFINE([HAVE_GRE_CALC_HLEN])])
1117   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [ip_gre_calc_hlen],
1118                   [OVS_DEFINE([HAVE_IP_GRE_CALC_HLEN])])
1119   OVS_GREP_IFELSE([$KSRC/include/linux/rbtree.h], [rb_link_node_rcu],
1120                   [OVS_DEFINE([HAVE_RBTREE_RB_LINK_NODE_RCU])])
1121   OVS_GREP_IFELSE([$KSRC/include/net/dst_ops.h], [bool confirm_neigh],
1122                   [OVS_DEFINE([HAVE_DST_OPS_CONFIRM_NEIGH])])
1123   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [fqdir],
1124                   [OVS_DEFINE([HAVE_INET_FRAG_FQDIR])])
1125   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h], [genl_ops],
1126                         [policy],
1127                         [OVS_DEFINE([HAVE_GENL_OPS_POLICY])])
1128   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h],
1129                   [nla_parse_deprecated_strict],
1130                   [OVS_DEFINE([HAVE_NLA_PARSE_DEPRECATED_STRICT])])
1131   OVS_FIND_OP_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
1132                            [validate], [extack],
1133                            [OVS_DEFINE([HAVE_RTNLOP_VALIDATE_WITH_EXTACK])])
1134   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1135                   [__skb_set_hash])
1136   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [sw_hash])
1137   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash_raw])
1138
1139   if cmp -s datapath/linux/kcompat.h.new \
1140             datapath/linux/kcompat.h >/dev/null 2>&1; then
1141     rm datapath/linux/kcompat.h.new
1142   else
1143     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
1144   fi
1145 ])
1146
1147 dnl Checks for net/if_dl.h.
1148 dnl
1149 dnl (We use this as a proxy for checking whether we're building on FreeBSD
1150 dnl or NetBSD.)
1151 AC_DEFUN([OVS_CHECK_IF_DL],
1152   [AC_CHECK_HEADER([net/if_dl.h],
1153                    [HAVE_IF_DL=yes],
1154                    [HAVE_IF_DL=no])
1155    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
1156    if test "$HAVE_IF_DL" = yes; then
1157       AC_DEFINE([HAVE_IF_DL], [1],
1158                 [Define to 1 if net/if_dl.h is available.])
1159
1160       # On these platforms we use libpcap to access network devices.
1161       AC_SEARCH_LIBS([pcap_open_live], [pcap])
1162    fi])
1163
1164 dnl Checks for buggy strtok_r.
1165 dnl
1166 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
1167 dnl with optimization that can cause segfaults:
1168 dnl
1169 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
1170 AC_DEFUN([OVS_CHECK_STRTOK_R],
1171   [AC_CACHE_CHECK(
1172      [whether strtok_r macro segfaults on some inputs],
1173      [ovs_cv_strtok_r_bug],
1174      [AC_RUN_IFELSE(
1175         [AC_LANG_PROGRAM([#include <stdio.h>
1176                           #include <string.h>
1177                          ],
1178                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
1179                            /* Assume bug is present, because relatively minor
1180                               changes in compiler settings (e.g. optimization
1181                               level) can make it crop up. */
1182                            return 1;
1183                            #else
1184                            char string[] = ":::";
1185                            char *save_ptr = (char *) 0xc0ffee;
1186                            char *token1, *token2;
1187                            token1 = strtok_r(string, ":", &save_ptr);
1188                            token2 = strtok_r(NULL, ":", &save_ptr);
1189                            freopen ("/dev/null", "w", stdout);
1190                            printf ("%s %s\n", token1, token2);
1191                            return 0;
1192                            #endif
1193                           ]])],
1194         [ovs_cv_strtok_r_bug=no],
1195         [ovs_cv_strtok_r_bug=yes],
1196         [ovs_cv_strtok_r_bug=yes])])
1197    if test $ovs_cv_strtok_r_bug = yes; then
1198      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1199                [Define if strtok_r macro segfaults on some inputs])
1200    fi
1201 ])
1202
1203 dnl ----------------------------------------------------------------------
1204 dnl These macros are from GNU PSPP, with the following original license:
1205 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1206 dnl This file is free software; the Free Software Foundation
1207 dnl gives unlimited permission to copy and/or distribute it,
1208 dnl with or without modifications, as long as this notice is preserved.
1209
1210 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1211   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1212   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1213     [ovs_save_CFLAGS="$CFLAGS"
1214      dnl Include -Werror in the compiler options, because without -Werror
1215      dnl clang's GCC-compatible compiler driver does not return a failure
1216      dnl exit status even though it complains about options it does not
1217      dnl understand.
1218      dnl
1219      dnl Also, check stderr as gcc exits with status 0 for options
1220      dnl rejected at getopt level.
1221      dnl    % touch /tmp/a.c
1222      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1223      dnl    gcc: unrecognized option '-Qunused-arguments'
1224      dnl    0
1225      dnl    %
1226      dnl
1227      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1228      dnl it does not understand, unless it has another error to report, so
1229      dnl instead of testing for -Wno-<foo>, test for the positive version.
1230      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1231      AC_COMPILE_IFELSE(
1232        [AC_LANG_SOURCE([int x;])],
1233        [if test -s conftest.err && grep "unrecognized option" conftest.err
1234         then
1235           ovs_cv_name[]=no
1236         else
1237           ovs_cv_name[]=yes
1238         fi],
1239        [ovs_cv_name[]=no])
1240      CFLAGS="$ovs_save_CFLAGS"])
1241   if test $ovs_cv_name = yes; then
1242     m4_if([$2], [], [:], [$2])
1243   else
1244     m4_if([$3], [], [:], [$3])
1245   fi
1246 ])
1247
1248 dnl OVS_CHECK_WERROR
1249 dnl
1250 dnl Check whether the C compiler accepts -Werror.
1251 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1252 AC_DEFUN([OVS_CHECK_WERROR],
1253   [WERROR=
1254    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1255
1256 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1257 dnl Check whether the given C compiler OPTION is accepted.
1258 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1259 AC_DEFUN([OVS_CHECK_CC_OPTION],
1260   [AC_REQUIRE([OVS_CHECK_WERROR])
1261    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1262
1263 dnl OVS_ENABLE_OPTION([OPTION])
1264 dnl Check whether the given C compiler OPTION is accepted.
1265 dnl If so, add it to WARNING_FLAGS.
1266 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1267 AC_DEFUN([OVS_ENABLE_OPTION],
1268   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1269    AC_SUBST([WARNING_FLAGS])])
1270
1271 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1272 dnl Check whether the given C compiler OPTION is accepted.
1273 dnl If so, enable the given Automake CONDITIONAL.
1274
1275 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1276 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1277   [OVS_CHECK_CC_OPTION(
1278     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1279    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1280 dnl ----------------------------------------------------------------------
1281
1282 dnl Check for too-old XenServer.
1283 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1284   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1285     [if test -e /etc/redhat-release; then
1286        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1287      fi
1288      if test -z "$ovs_cv_xsversion"; then
1289        ovs_cv_xsversion=none
1290      fi])
1291   case $ovs_cv_xsversion in
1292     none)
1293       ;;
1294
1295     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1296     [[6-9]]* |                           dnl XenServer 6 or later
1297     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1298     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1299     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1300     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1301       ;;
1302
1303     *)
1304       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1305       ;;
1306   esac])
1307
1308 dnl OVS_CHECK_SPARSE_TARGET
1309 dnl
1310 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1311 dnl target for which the code is being built.  This helps it out.
1312 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1313   [AC_CACHE_CHECK(
1314     [target hint for cgcc],
1315     [ac_cv_sparse_target],
1316     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1317        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1318        [x86_64-*], [ac_cv_sparse_target=x86_64],
1319        [ac_cv_sparse_target=other])])
1320    AS_CASE([$ac_cv_sparse_target],
1321      [x86], [SPARSEFLAGS= CGCCFLAGS="-target=i86 -target=host_os_specs"],
1322      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS="-target=x86_64 -target=host_os_specs"],
1323      [SPARSEFLAGS= CGCCFLAGS=])
1324
1325    dnl Get the default defines for vector instructions from compiler to
1326    dnl allow "sparse" correctly check the same code that will be built.
1327    dnl Required for checking DPDK headers.
1328    AC_MSG_CHECKING([vector options for cgcc])
1329    VECTOR=$($CC -dM -E - < /dev/null | grep -E "MMX|SSE|AVX" | \
1330             cut -c 9- | sed 's/ /=/' | sed 's/^/-D/' | tr '\n' ' ')
1331    AC_MSG_RESULT([$VECTOR])
1332    CGCCFLAGS="$CGCCFLAGS $VECTOR"
1333
1334    AC_SUBST([SPARSEFLAGS])
1335    AC_SUBST([CGCCFLAGS])])
1336
1337 dnl OVS_SPARSE_EXTRA_INCLUDES
1338 dnl
1339 dnl The cgcc script from "sparse" does not search gcc's default
1340 dnl search path. Get the default search path from GCC and pass
1341 dnl them to sparse.
1342 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1343     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1344            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1345
1346 dnl OVS_ENABLE_SPARSE
1347 AC_DEFUN([OVS_ENABLE_SPARSE],
1348   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1349    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1350    : ${SPARSE=sparse}
1351    AC_SUBST([SPARSE])
1352    AC_CONFIG_COMMANDS_PRE(
1353      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1354
1355    AC_ARG_ENABLE(
1356      [sparse],
1357      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1358      [], [enable_sparse=no])
1359    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1360
1361 dnl OVS_CTAGS_IDENTIFIERS
1362 dnl
1363 dnl ctags ignores symbols with extras identifiers. This is a list of
1364 dnl specially handled identifiers to be ignored. [ctags(1) -I <list>].
1365 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1366     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1367            ["OVS_LOCKABLE OVS_NO_THREAD_SAFETY_ANALYSIS OVS_REQ_RDLOCK+ OVS_ACQ_RDLOCK+ OVS_REQ_WRLOCK+ OVS_ACQ_WRLOCK+ OVS_REQUIRES+ OVS_ACQUIRES+ OVS_TRY_WRLOCK+ OVS_TRY_RDLOCK+ OVS_TRY_LOCK+ OVS_GUARDED_BY+ OVS_EXCLUDED+ OVS_RELEASES+ OVS_ACQ_BEFORE+ OVS_ACQ_AFTER+"]))
1368
1369 dnl OVS_PTHREAD_SET_NAME
1370 dnl
1371 dnl This checks for three known variants of pthreads functions for setting
1372 dnl the name of the current thread:
1373 dnl
1374 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1375 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1376 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1377 dnl
1378 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1379 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1380 dnl provide to it.
1381 dnl
1382 dnl This macro defines:
1383 dnl
1384 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1385 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1386 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1387 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1388   [AC_CHECK_FUNCS([pthread_set_name_np])
1389    if test $ac_cv_func_pthread_set_name_np != yes; then
1390      AC_CACHE_CHECK(
1391        [for pthread_setname_np() variant],
1392        [ovs_cv_pthread_setname_np],
1393        [AC_LINK_IFELSE(
1394          [AC_LANG_PROGRAM([#include <pthread.h>
1395   ], [pthread_setname_np(pthread_self(), "name");])],
1396          [ovs_cv_pthread_setname_np=glibc],
1397          [AC_LINK_IFELSE(
1398            [AC_LANG_PROGRAM([#include <pthread.h>
1399 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1400            [ovs_cv_pthread_setname_np=netbsd],
1401            [ovs_cv_pthread_setname_np=none])])])
1402      case $ovs_cv_pthread_setname_np in # (
1403        glibc)
1404           AC_DEFINE(
1405             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1406             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1407           ;; # (
1408        netbsd)
1409           AC_DEFINE(
1410             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1411             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1412           ;;
1413      esac
1414    fi])
1415
1416 dnl OVS_CHECK_LINUX_HOST.
1417 dnl
1418 dnl Checks whether we're building for a Linux host, based on the presence of
1419 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1420 dnl LINUX based on the result.
1421 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1422   [AC_CACHE_CHECK(
1423      [whether __linux__ is defined],
1424      [ovs_cv_linux],
1425      [AC_COMPILE_IFELSE(
1426         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1427         [ovs_cv_linux=true],
1428         [ovs_cv_linux=false])])
1429    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])