acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 4; then
 154        if test "$version" = 4 && test "$patchlevel" -le 17; then
 155           : # Linux 4.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.17.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 160        : # Linux 3.x
 161     else
 162        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 163     fi
 164     if (test ! -e "$KBUILD"/include/linux/version.h && \
 165         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 166        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 167         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 168         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 169     fi
 170     OVS_CHECK_LINUX_COMPAT
 171   fi
 172   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 173 ])
 174
 175 dnl OVS_CHECK_LINUX_TC
 176 dnl
 177 dnl Configure Linux tc compat.
 178 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 179   AC_COMPILE_IFELSE([
 180     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 181         int x = TCA_FLOWER_KEY_ENC_IP_TTL_MASK;
 182     ])],
 183     [AC_DEFINE([HAVE_TCA_FLOWER_KEY_ENC_IP_TTL_MASK], [1],
 184                [Define to 1 if TCA_FLOWER_KEY_ENC_IP_TTL_MASK is available.])])
 185
 186   AC_COMPILE_IFELSE([
 187     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 188         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 189     ])],
 190     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 191                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 192
 193   AC_COMPILE_IFELSE([
 194     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 195         int x = TCA_TUNNEL_KEY_ENC_TTL;
 196     ])],
 197     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 198                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 199
 200   AC_COMPILE_IFELSE([
 201     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 202         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 203     ])],
 204     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 205                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 206 ])
 207
 208 dnl OVS_CHECK_DPDK
 209 dnl
 210 dnl Configure DPDK source tree
 211 AC_DEFUN([OVS_CHECK_DPDK], [
 212   AC_ARG_WITH([dpdk],
 213               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 214                               [Specify the DPDK build directory])],
 215               [have_dpdk=true])
 216
 217   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 218   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 219     AC_MSG_RESULT([no])
 220     DPDKLIB_FOUND=false
 221   else
 222     AC_MSG_RESULT([yes])
 223     case "$with_dpdk" in
 224       yes)
 225         DPDK_AUTO_DISCOVER="true"
 226         PKG_CHECK_MODULES([DPDK], [libdpdk],
 227                           [DPDK_INCLUDE="$DPDK_CFLAGS"],
 228                           [DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"])
 229         ;;
 230       *)
 231         DPDK_AUTO_DISCOVER="false"
 232         DPDK_INCLUDE_PATH="$with_dpdk/include"
 233         # If 'with_dpdk' is passed install directory, point to headers
 234         # installed in $DESTDIR/$prefix/include/dpdk
 235         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 236            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 237         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 238            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 239         fi
 240         DPDK_LIB_DIR="$with_dpdk/lib"
 241         ;;
 242     esac
 243
 244     DPDK_LIB="-ldpdk"
 245     DPDK_EXTRA_LIB=""
 246
 247     ovs_save_CFLAGS="$CFLAGS"
 248     ovs_save_LDFLAGS="$LDFLAGS"
 249     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 250     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 251       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 252     fi
 253
 254     AC_COMPILE_IFELSE([
 255       AC_LANG_PROGRAM(
 256         [
 257           #include <rte_config.h>
 258 #if RTE_LIBRTE_VHOST_NUMA
 259 #error
 260 #endif
 261         ], [])
 262       ], [],
 263       [AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])])
 264        DPDK_EXTRA_LIB="-lnuma"
 265        AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])])
 266
 267     AC_COMPILE_IFELSE([
 268       AC_LANG_PROGRAM(
 269         [
 270           #include <rte_config.h>
 271 #if RTE_LIBRTE_PMD_PCAP
 272 #error
 273 #endif
 274         ], [])
 275       ], [],
 276       [AC_SEARCH_LIBS([pcap_dump],[pcap],[],[AC_MSG_ERROR([unable to find libpcap, install the dependency package])])
 277        DPDK_EXTRA_LIB="-lpcap"
 278        AC_COMPILE_IFELSE([
 279          AC_LANG_PROGRAM(
 280            [
 281              #include <rte_config.h>
 282 #if RTE_LIBRTE_PDUMP
 283 #error
 284 #endif
 285          ], [])
 286        ], [],
 287        [AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])])
 288      ])
 289
 290     AC_COMPILE_IFELSE([
 291       AC_LANG_PROGRAM(
 292         [
 293           #include <rte_config.h>
 294 #if RTE_LIBRTE_MLX5_PMD
 295 #error
 296 #endif
 297         ], [])
 298       ], [],
 299       [AC_SEARCH_LIBS([mnl_attr_put],[mnl],[],[AC_MSG_ERROR([unable to find libmnl, install the dependency package])])
 300        DPDK_EXTRA_LIB="-lmnl"
 301        AC_DEFINE([DPDK_MNL], [1], [MLX5 PMD detected in DPDK.])])
 302
 303     # On some systems we have to add -ldl to link with dpdk
 304     #
 305     # This code, at first, tries to link without -ldl (""),
 306     # then adds it and tries again.
 307     # Before each attempt the search cache must be unset,
 308     # otherwise autoconf will stick with the old result
 309
 310     DPDKLIB_FOUND=false
 311     save_LIBS=$LIBS
 312     for extras in "" "-ldl"; do
 313         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 314         AC_LINK_IFELSE(
 315            [AC_LANG_PROGRAM([#include <rte_config.h>
 316                              #include <rte_eal.h>],
 317                             [int rte_argc; char ** rte_argv;
 318                              rte_eal_init(rte_argc, rte_argv);])],
 319            [DPDKLIB_FOUND=true])
 320         if $DPDKLIB_FOUND; then
 321             break
 322         fi
 323     done
 324
 325     # If linking unsuccessful
 326     if test "$DPDKLIB_FOUND" = "false" ; then
 327       if $DPDK_AUTO_DISCOVER; then
 328         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 329       else
 330         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 331       fi
 332     fi
 333     CFLAGS="$ovs_save_CFLAGS"
 334     LDFLAGS="$ovs_save_LDFLAGS"
 335     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 336       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 337     fi
 338     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 339     OVS_ENABLE_OPTION([-mssse3])
 340
 341     # DPDK pmd drivers are not linked unless --whole-archive is used.
 342     #
 343     # This happens because the rest of the DPDK code doesn't use any symbol in
 344     # the pmd driver objects, and the drivers register themselves using an
 345     # __attribute__((constructor)) function.
 346     #
 347     # These options are specified inside a single -Wl directive to prevent
 348     # autotools from reordering them.
 349     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 350     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 351     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 352   fi
 353
 354   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 355 ])
 356
 357 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 358 dnl
 359 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 360 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 361 dnl <REGEX> translated to uppercase.
 362 AC_DEFUN([OVS_GREP_IFELSE], [
 363   AC_MSG_CHECKING([whether $2 matches in $1])
 364   if test -f $1; then
 365     grep '$2' $1 >/dev/null 2>&1
 366     status=$?
 367     case $status in
 368       0)
 369         AC_MSG_RESULT([yes])
 370         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 371         ;;
 372       1)
 373         AC_MSG_RESULT([no])
 374         $4
 375         ;;
 376       *)
 377         AC_MSG_ERROR([grep exited with status $status])
 378         ;;
 379     esac
 380   else
 381     AC_MSG_RESULT([file not found])
 382     $4
 383   fi
 384 ])
 385
 386 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 387 dnl
 388 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 389 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 390 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 391 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 392 dnl translated to uppercase.
 393 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 394   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 395   if test -f $1; then
 396     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 397     status=$?
 398     case $status in
 399       0)
 400         AC_MSG_RESULT([yes])
 401         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 402         ;;
 403       1)
 404         AC_MSG_RESULT([no])
 405         $5
 406         ;;
 407       *)
 408         AC_MSG_ERROR([grep exited with status $status])
 409         ;;
 410     esac
 411   else
 412     AC_MSG_RESULT([file not found])
 413     $5
 414   fi
 415 ])
 416
 417 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 418 dnl
 419 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 420 dnl the function signature starting from the line matching FUNCTION
 421 dnl and ending with the line containing the closing parenthesis.  If
 422 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 423 dnl IF-MATCH is empty then it defines to
 424 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 425 dnl <REGEX> translated to uppercase.
 426 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 427   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 428   if test -f $1; then
 429     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 430     status=$?
 431     case $status in
 432       0)
 433         AC_MSG_RESULT([yes])
 434         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 435         ;;
 436       1)
 437         AC_MSG_RESULT([no])
 438         $5
 439         ;;
 440       *)
 441         AC_MSG_ERROR([grep exited with status $status])
 442         ;;
 443     esac
 444   else
 445     AC_MSG_RESULT([file not found])
 446     $5
 447   fi
 448 ])
 449
 450 dnl OVS_DEFINE(NAME)
 451 dnl
 452 dnl Defines NAME to 1 in kcompat.h.
 453 AC_DEFUN([OVS_DEFINE], [
 454   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 455 ])
 456
 457 dnl OVS_CHECK_LINUX_COMPAT
 458 dnl
 459 dnl Runs various Autoconf checks on the Linux kernel source in
 460 dnl the directory in $KBUILD.
 461 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 462   rm -f datapath/linux/kcompat.h.new
 463   mkdir -p datapath/linux
 464   : > datapath/linux/kcompat.h.new
 465
 466   echo '#include <linux/version.h>
 467 #ifndef RHEL_RELEASE_CODE
 468 #define RHEL_RELEASE_CODE 0
 469 #define RHEL_RELEASE_VERSION(a, b) 0
 470 #endif' >> datapath/linux/kcompat.h.new
 471
 472   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 473                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 474
 475   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 476                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 477
 478   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 479                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 480   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 481
 482   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 483   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 484   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 485
 486   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 487                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 488
 489   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 490   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 491
 492   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 493   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 494   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 495   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 496   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 497
 498   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 499   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 500   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 501                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 502   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 503                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 504
 505   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 506                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 507   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 508                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 509   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 510                         [ip_do_fragment], [net],
 511                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 512   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 513                         [ip_local_out], [net],
 514                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 515
 516   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 517
 518   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 519                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 520   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 521   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 522                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 523   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 524                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 525   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 526   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 527   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 528                         [frags_work])
 529   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 530                         [rwlock])
 531   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 532                         [list_evictor])
 533   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 534   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 535                         [sub_frag_mem_limit], [struct.netns_frags],
 536                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 537   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 538                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 539   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 540                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 541
 542   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 543   dnl OVS does not really need ipv6 label field, but its presence signifies that
 544   dnl the stack has all required ipv6 support.
 545   dnl OVS also does not need dst_cache But this dependency allows us to write
 546   dnl much cleaner code.
 547
 548   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 549                         [label],
 550                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 551                                          [iptunnel_pull_offloads],
 552                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 553                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 554                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 555
 556   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 557                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 558   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 559                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 560   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 561                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 562   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 563   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 564   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 565   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 566   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 567   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 568   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 569   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 570   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 571   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 572                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 573   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 574   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 575   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 576   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 577   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 578   dnl So check type of tstats.
 579   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 580                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 581   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 582                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 583   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 584   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 585   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 586                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 587   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 588   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 589   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 590                         [extended])
 591   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 592                         [netdev_master_upper_dev_link], [upper_priv],
 593                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 594   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 595                   [netdev_master_upper_dev_link_rh],
 596                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 597
 598   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 599                         [max_mtu])
 600   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 601                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 602
 603   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 604   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 605   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 606                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 607   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 608                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 609   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 610                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 611   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 612
 613
 614   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 615                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 616
 617   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 618                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 619                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 620   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 621                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 622
 623   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 624                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 625                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 626   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 627                   [nf_ct_get_tuplepr], [struct.net],
 628                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 629   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 630                   [nf_ct_set])
 631   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 632                   [nf_ct_is_untracked])
 633   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 634                   [nf_ct_zone_init])
 635   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 636                         [net_ns_get])
 637   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 638                   [nf_connlabels_get])
 639   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 640                   [nf_connlabels_get], [int bit],
 641                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 642   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 643                         [nf_conn_labels], [words])
 644   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 645   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 646   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 647   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 648   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 649                   [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])
 650
 651   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 652   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 653
 654   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 655   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 656   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 657                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 658   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 659
 660   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 661                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 662                                    [rcu_read_lock_held])])
 663   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 664   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 665
 666   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 667   # is necessary because some versions of this header remove the
 668   # member but retain the kerneldoc comment that describes it (which
 669   # starts with @).  The brackets must be doubled because of m4
 670   # quoting rules.
 671   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 672                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 673   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 674   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 675   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 676   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 677   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 678   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 679   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 680                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 681   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 682                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 683   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 684                   [skb_copy_from_linear_data_offset])
 685   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 686                   [skb_reset_tail_pointer])
 687   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 688   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 689                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 690   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 691   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 692   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 693   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 694   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 695   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 696   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 697   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 698                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 699   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 700   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 701                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 702   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 703                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 704   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 705   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 706   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 707   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 708   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 709   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 710   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 711   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 712   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 713
 714   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 715                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 716   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 717                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 718   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 719                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 720
 721   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 722   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 723
 724   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 725   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 726
 727   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 728   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 729   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 730   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 731                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 732   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 733   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 734                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 735   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 736                         [genl_notify], [net],
 737                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 738
 739
 740   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 741                         [genl_multicast_group], [id])
 742   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 743
 744   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 745   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 746   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 747   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 748   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 749   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 750                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 751   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 752                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 753
 754   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 755   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 756   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 757   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 758   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 759   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 760   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 761   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 762   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 763                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 764   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 765                         [nla_parse], [netlink_ext_ack],
 766                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 767
 768   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 769
 770   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 771                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 772   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 773   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 774   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 775   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 776   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 777
 778   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 779                         [metadata_dst_alloc], [metadata_type])
 780
 781   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 782
 783   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 784                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 785   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 786                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 787                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 788   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 789   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 790   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 791                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 792   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 793                         [gro_receive])
 794
 795   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 796                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 797   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 798                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 799
 800   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 801   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 802   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 803                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 804   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 805                         [udp_add_offload], [net],
 806                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 807   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 808                         [nf_defrag_ipv6_enable], [net],
 809                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 810   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 811                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 812   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 813                         [needs_free_netdev],
 814                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 815   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 816                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 817   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 818                   [nf_conntrack_helper_put],
 819                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 820   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 821                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 822   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 823                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 824   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 825                         [extack],
 826                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 827   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 828                         [list],
 829                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 830   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 831                   [IP_CT_UNTRACKED])
 832   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 833                         [netdev_master_upper_dev_link], [extack],
 834                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 835   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 836                   [__LINUX_COMPILER_TYPES_H],
 837                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 838   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 839                   [ktime_get_ts64],
 840                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 841   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 842                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 843                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 844   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 845                   [ktime_get_ns],
 846                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 847   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 848                   frag_percpu_counter_batch[],
 849                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 850   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 851                   [null_compute_pseudo],
 852                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 853   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 854                   [__skb_checksum_convert],
 855                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
 856   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 857                         [max_mtu],
 858                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
 859   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
 860                         [erspan_ver],
 861                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
 862   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 863                   [SKB_GSO_IPXIP6],
 864                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
 865   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
 866                         [ip6_make_flowlabel], [fl6],
 867                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
 868   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
 869                         [auto_flowlabels],
 870                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
 871   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 872                   [netif_keep_dst],
 873                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
 874   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 875                         [ndo_get_iflink],
 876                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
 877   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 878                   [skb_set_inner_ipproto],
 879                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
 880   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 881                   [tunnel_encap_types],
 882                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
 883   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 884                   [IFLA_IPTUN_ENCAP_TYPE],
 885                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
 886   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 887                   [IFLA_IPTUN_COLLECT_METADATA],
 888                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
 889   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 890                   [IFLA_GRE_ENCAP_DPORT])
 891   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 892                   [IFLA_GRE_COLLECT_METADATA])
 893   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 894                   [IFLA_GRE_IGNORE_DF])
 895   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 896                   [IFLA_GRE_FWMARK])
 897   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 898                   [IFLA_GRE_ERSPAN_INDEX])
 899   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 900                   [IFLA_GRE_ERSPAN_HWID])
 901   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 902                   [IFLA_IPTUN_FWMARK])
 903   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
 904                         [csum_valid],
 905                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
 906   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 907                   [skb_checksum_simple_validate])
 908   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 909                   [void.*ndo_get_stats64],
 910                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
 911   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
 912                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
 913   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
 914                         [ip_tunnel_info_opts_set], [flags],
 915                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
 916
 917   if cmp -s datapath/linux/kcompat.h.new \
 918             datapath/linux/kcompat.h >/dev/null 2>&1; then
 919     rm datapath/linux/kcompat.h.new
 920   else
 921     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 922   fi
 923 ])
 924
 925 dnl Checks for net/if_dl.h.
 926 dnl
 927 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 928 dnl or NetBSD.)
 929 AC_DEFUN([OVS_CHECK_IF_DL],
 930   [AC_CHECK_HEADER([net/if_dl.h],
 931                    [HAVE_IF_DL=yes],
 932                    [HAVE_IF_DL=no])
 933    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 934    if test "$HAVE_IF_DL" = yes; then
 935       AC_DEFINE([HAVE_IF_DL], [1],
 936                 [Define to 1 if net/if_dl.h is available.])
 937
 938       # On these platforms we use libpcap to access network devices.
 939       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 940    fi])
 941
 942 dnl Checks for buggy strtok_r.
 943 dnl
 944 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 945 dnl with optimization that can cause segfaults:
 946 dnl
 947 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 948 AC_DEFUN([OVS_CHECK_STRTOK_R],
 949   [AC_CACHE_CHECK(
 950      [whether strtok_r macro segfaults on some inputs],
 951      [ovs_cv_strtok_r_bug],
 952      [AC_RUN_IFELSE(
 953         [AC_LANG_PROGRAM([#include <stdio.h>
 954                           #include <string.h>
 955                          ],
 956                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 957                            /* Assume bug is present, because relatively minor
 958                               changes in compiler settings (e.g. optimization
 959                               level) can make it crop up. */
 960                            return 1;
 961                            #else
 962                            char string[] = ":::";
 963                            char *save_ptr = (char *) 0xc0ffee;
 964                            char *token1, *token2;
 965                            token1 = strtok_r(string, ":", &save_ptr);
 966                            token2 = strtok_r(NULL, ":", &save_ptr);
 967                            freopen ("/dev/null", "w", stdout);
 968                            printf ("%s %s\n", token1, token2);
 969                            return 0;
 970                            #endif
 971                           ]])],
 972         [ovs_cv_strtok_r_bug=no],
 973         [ovs_cv_strtok_r_bug=yes],
 974         [ovs_cv_strtok_r_bug=yes])])
 975    if test $ovs_cv_strtok_r_bug = yes; then
 976      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 977                [Define if strtok_r macro segfaults on some inputs])
 978    fi
 979 ])
 980
 981 dnl ----------------------------------------------------------------------
 982 dnl These macros are from GNU PSPP, with the following original license:
 983 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 984 dnl This file is free software; the Free Software Foundation
 985 dnl gives unlimited permission to copy and/or distribute it,
 986 dnl with or without modifications, as long as this notice is preserved.
 987
 988 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 989   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
 990   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 991     [ovs_save_CFLAGS="$CFLAGS"
 992      dnl Include -Werror in the compiler options, because without -Werror
 993      dnl clang's GCC-compatible compiler driver does not return a failure
 994      dnl exit status even though it complains about options it does not
 995      dnl understand.
 996      dnl
 997      dnl Also, check stderr as gcc exits with status 0 for options
 998      dnl rejected at getopt level.
 999      dnl    % touch /tmp/a.c
1000      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1001      dnl    gcc: unrecognized option '-Qunused-arguments'
1002      dnl    0
1003      dnl    %
1004      dnl
1005      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1006      dnl it does not understand, unless it has another error to report, so
1007      dnl instead of testing for -Wno-<foo>, test for the positive version.
1008      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1009      AC_COMPILE_IFELSE(
1010        [AC_LANG_SOURCE([int x;])],
1011        [if test -s conftest.err && grep "unrecognized option" conftest.err
1012         then
1013           ovs_cv_name[]=no
1014         else
1015           ovs_cv_name[]=yes
1016         fi],
1017        [ovs_cv_name[]=no])
1018      CFLAGS="$ovs_save_CFLAGS"])
1019   if test $ovs_cv_name = yes; then
1020     m4_if([$2], [], [:], [$2])
1021   else
1022     m4_if([$3], [], [:], [$3])
1023   fi
1024 ])
1025
1026 dnl OVS_CHECK_WERROR
1027 dnl
1028 dnl Check whether the C compiler accepts -Werror.
1029 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1030 AC_DEFUN([OVS_CHECK_WERROR],
1031   [WERROR=
1032    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1033
1034 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1035 dnl Check whether the given C compiler OPTION is accepted.
1036 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1037 AC_DEFUN([OVS_CHECK_CC_OPTION],
1038   [AC_REQUIRE([OVS_CHECK_WERROR])
1039    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1040
1041 dnl OVS_ENABLE_OPTION([OPTION])
1042 dnl Check whether the given C compiler OPTION is accepted.
1043 dnl If so, add it to WARNING_FLAGS.
1044 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1045 AC_DEFUN([OVS_ENABLE_OPTION],
1046   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1047    AC_SUBST([WARNING_FLAGS])])
1048
1049 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1050 dnl Check whether the given C compiler OPTION is accepted.
1051 dnl If so, enable the given Automake CONDITIONAL.
1052
1053 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1054 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1055   [OVS_CHECK_CC_OPTION(
1056     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1057    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1058 dnl ----------------------------------------------------------------------
1059
1060 dnl Check for too-old XenServer.
1061 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1062   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1063     [if test -e /etc/redhat-release; then
1064        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1065      fi
1066      if test -z "$ovs_cv_xsversion"; then
1067        ovs_cv_xsversion=none
1068      fi])
1069   case $ovs_cv_xsversion in
1070     none)
1071       ;;
1072
1073     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1074     [[6-9]]* |                           dnl XenServer 6 or later
1075     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1076     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1077     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1078     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1079       ;;
1080
1081     *)
1082       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1083       ;;
1084   esac])
1085
1086 dnl OVS_CHECK_SPARSE_TARGET
1087 dnl
1088 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1089 dnl target for which the code is being built.  This helps it out.
1090 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1091   [AC_CACHE_CHECK(
1092     [target hint for cgcc],
1093     [ac_cv_sparse_target],
1094     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1095        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1096        [x86_64-*], [ac_cv_sparse_target=x86_64],
1097        [ac_cv_sparse_target=other])])
1098    AS_CASE([$ac_cv_sparse_target],
1099      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
1100      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
1101      [SPARSEFLAGS= CGCCFLAGS=])
1102    AC_SUBST([SPARSEFLAGS])
1103    AC_SUBST([CGCCFLAGS])])
1104
1105 dnl OVS_SPARSE_EXTRA_INCLUDES
1106 dnl
1107 dnl The cgcc script from "sparse" does not search gcc's default
1108 dnl search path. Get the default search path from GCC and pass
1109 dnl them to sparse.
1110 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1111     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1112            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1113
1114 dnl OVS_ENABLE_SPARSE
1115 AC_DEFUN([OVS_ENABLE_SPARSE],
1116   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1117    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1118    : ${SPARSE=sparse}
1119    AC_SUBST([SPARSE])
1120    AC_CONFIG_COMMANDS_PRE(
1121      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1122
1123    AC_ARG_ENABLE(
1124      [sparse],
1125      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1126      [], [enable_sparse=no])
1127    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1128
1129 dnl OVS_CTAGS_IDENTIFIERS
1130 dnl
1131 dnl ctags ignores symbols with extras identifiers. This builds a list of
1132 dnl specially handled identifiers to be ignored.
1133 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1134     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1135            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1136
1137 dnl OVS_PTHREAD_SET_NAME
1138 dnl
1139 dnl This checks for three known variants of pthreads functions for setting
1140 dnl the name of the current thread:
1141 dnl
1142 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1143 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1144 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1145 dnl
1146 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1147 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1148 dnl provide to it.
1149 dnl
1150 dnl This macro defines:
1151 dnl
1152 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1153 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1154 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1155 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1156   [AC_CHECK_FUNCS([pthread_set_name_np])
1157    if test $ac_cv_func_pthread_set_name_np != yes; then
1158      AC_CACHE_CHECK(
1159        [for pthread_setname_np() variant],
1160        [ovs_cv_pthread_setname_np],
1161        [AC_LINK_IFELSE(
1162          [AC_LANG_PROGRAM([#include <pthread.h>
1163   ], [pthread_setname_np(pthread_self(), "name");])],
1164          [ovs_cv_pthread_setname_np=glibc],
1165          [AC_LINK_IFELSE(
1166            [AC_LANG_PROGRAM([#include <pthread.h>
1167 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1168            [ovs_cv_pthread_setname_np=netbsd],
1169            [ovs_cv_pthread_setname_np=none])])])
1170      case $ovs_cv_pthread_setname_np in # (
1171        glibc)
1172           AC_DEFINE(
1173             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1174             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1175           ;; # (
1176        netbsd)
1177           AC_DEFINE(
1178             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1179             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1180           ;;
1181      esac
1182    fi])
1183
1184 dnl OVS_CHECK_LINUX_HOST.
1185 dnl
1186 dnl Checks whether we're building for a Linux host, based on the presence of
1187 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1188 dnl LINUX based on the result.
1189 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1190   [AC_CACHE_CHECK(
1191      [whether __linux__ is defined],
1192      [ovs_cv_linux],
1193      [AC_COMPILE_IFELSE(
1194         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1195         [ovs_cv_linux=true],
1196         [ovs_cv_linux=false])])
1197    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])