qapi/meson.build

   1 util_ss.add(files(
   2   'opts-visitor.c',
   3   'qapi-clone-visitor.c',
   4   'qapi-dealloc-visitor.c',
   5   'qapi-forward-visitor.c',
   6   'qapi-util.c',
   7   'qapi-visit-core.c',
   8   'qobject-input-visitor.c',
   9   'qobject-output-visitor.c',
  10   'string-input-visitor.c',
  11   'string-output-visitor.c',
  12 ))
  13 if have_system
  14   util_ss.add(files('qapi-type-helpers.c'))
  15 endif
  16 if have_system or have_tools or have_ga
  17   util_ss.add(files(
  18     'qmp-dispatch.c',
  19     'qmp-event.c',
  20     'qmp-registry.c',
  21   ))
  22 endif
  23
  24 qapi_all_modules = [
  25   'authz',
  26   'block',
  27   'block-core',
  28   'block-export',
  29   'char',
  30   'common',
  31   'compat',
  32   'control',
  33   'crypto',
  34   'cxl',
  35   'dump',
  36   'error',
  37   'introspect',
  38   'job',
  39   'machine-common',
  40   'machine',
  41   'machine-target',
  42   'migration',
  43   'misc',
  44   'misc-target',
  45   'net',
  46   'pragma',
  47   'qom',
  48   'replay',
  49   'run-state',
  50   'sockets',
  51   'stats',
  52   'trace',
  53   'transaction',
  54   'virtio',
  55   'yank',
  56 ]
  57 if have_system
  58   qapi_all_modules += [
  59     'acpi',
  60     'audio',
  61     'cryptodev',
  62     'qdev',
  63     'pci',
  64     'rdma',
  65     'rocker',
  66     'tpm',
  67   ]
  68 endif
  69 if have_system or have_tools
  70   qapi_all_modules += [
  71     'ui',
  72   ]
  73 endif
  74
  75 qapi_nonmodule_outputs = [
  76   'qapi-introspect.c', 'qapi-introspect.h',
  77   'qapi-types.c', 'qapi-types.h',
  78   'qapi-visit.h', 'qapi-visit.c',
  79   'qapi-commands.h', 'qapi-commands.c',
  80   'qapi-init-commands.h', 'qapi-init-commands.c',
  81   'qapi-events.h', 'qapi-events.c',
  82   'qapi-emit-events.c', 'qapi-emit-events.h',
  83 ]
  84
  85 # First build all sources
  86 qapi_util_outputs = [
  87   'qapi-builtin-types.c', 'qapi-builtin-visit.c',
  88   'qapi-builtin-types.h', 'qapi-builtin-visit.h',
  89 ]
  90
  91 qapi_inputs = []
  92 qapi_specific_outputs = []
  93 foreach module : qapi_all_modules
  94   qapi_inputs += [ files(module + '.json') ]
  95   qapi_module_outputs = [
  96     'qapi-types-@0@.c'.format(module),
  97     'qapi-types-@0@.h'.format(module),
  98     'qapi-visit-@0@.c'.format(module),
  99     'qapi-visit-@0@.h'.format(module),
 100   ]
 101   if have_system or have_tools
 102     qapi_module_outputs += [
 103       'qapi-events-@0@.c'.format(module),
 104       'qapi-events-@0@.h'.format(module),
 105       'qapi-commands-@0@.c'.format(module),
 106       'qapi-commands-@0@.h'.format(module),
 107       'qapi-commands-@0@.trace-events'.format(module),
 108     ]
 109   endif
 110   if module.endswith('-target')
 111     qapi_specific_outputs += qapi_module_outputs
 112   else
 113     qapi_util_outputs += qapi_module_outputs
 114   endif
 115 endforeach
 116
 117 qapi_files = custom_target('shared QAPI source files',
 118   output: qapi_util_outputs + qapi_specific_outputs + qapi_nonmodule_outputs,
 119   input: [ files('qapi-schema.json') ],
 120   command: [ qapi_gen, '-o', 'qapi', '-b', '@INPUT0@' ],
 121   depend_files: [ qapi_inputs, qapi_gen_depends ])
 122
 123 # Now go through all the outputs and add them to the right sourceset.
 124 # These loops must be synchronized with the output of the above custom target.
 125
 126 i = 0
 127 foreach output : qapi_util_outputs
 128   if output.endswith('.h')
 129     genh += qapi_files[i]
 130   endif
 131   if output.endswith('.trace-events')
 132     qapi_trace_events += qapi_files[i]
 133   endif
 134   util_ss.add(qapi_files[i])
 135   i = i + 1
 136 endforeach
 137
 138 foreach output : qapi_specific_outputs + qapi_nonmodule_outputs
 139   if output.endswith('.h')
 140     genh += qapi_files[i]
 141   endif
 142   if output.endswith('.trace-events')
 143     qapi_trace_events += qapi_files[i]
 144   endif
 145   specific_ss.add(when: 'CONFIG_SYSTEM_ONLY', if_true: qapi_files[i])
 146   i = i + 1
 147 endforeach