config/spl-meta.m4

   1 dnl #
   2 dnl # DESCRIPTION:
   3 dnl # Read meta data from the META file.  When building from a git repository
   4 dnl # the SPL_META_RELEASE field will be overwritten if there is an annotated
   5 dnl # tag matching the form SPL_META_NAME-SPL_META_VERSION-*.  This allows
   6 dnl # for working builds to be uniquely identified using the git commit hash.
   7 dnl #
   8 dnl #    The META file format is as follows:
   9 dnl #      ^[ ]*KEY:[ \t]+VALUE$
  10 dnl #
  11 dnl #    In other words:
  12 dnl #    - KEY is separated from VALUE by a colon and one or more spaces/tabs.
  13 dnl #    - KEY and VALUE are case sensitive.
  14 dnl #    - Leading spaces are ignored.
  15 dnl #    - First match wins for duplicate keys.
  16 dnl #
  17 dnl #    A line can be commented out by preceding it with a '#' (or technically
  18 dnl #    any non-space character since that will prevent the regex from
  19 dnl #    matching).
  20 dnl #
  21 dnl # WARNING:
  22 dnl #   Placing a colon followed by a space or tab (ie, ":[ \t]+") within the
  23 dnl #   VALUE will prematurely terminate the string since that sequence is
  24 dnl #   used as the awk field separator.
  25 dnl #
  26 dnl # KEYS:
  27 dnl #   The following META keys are recognized:
  28 dnl #     Name, Version, Release, Date, Author, LT_Current, LT_Revision, LT_Age
  29 dnl #
  30 dnl # Written by Chris Dunlap <cdunlap@llnl.gov>.
  31 dnl # Modified by Brian Behlendorf <behlendorf1@llnl.gov>.
  32 dnl #
  33 AC_DEFUN([SPL_AC_META], [
  34         AC_PROG_AWK
  35         AC_MSG_CHECKING([metadata])
  36
  37         META="$srcdir/META"
  38         _spl_ac_meta_type="none"
  39         if test -f "$META"; then
  40                 _spl_ac_meta_type="META file"
  41
  42                 SPL_META_NAME=_SPL_AC_META_GETVAL([(Name|Project|Package)]);
  43                 if test -n "$SPL_META_NAME"; then
  44                         AC_DEFINE_UNQUOTED([SPL_META_NAME], ["$SPL_META_NAME"],
  45                                 [Define the project name.]
  46                         )
  47                         AC_SUBST([SPL_META_NAME])
  48                 fi
  49
  50                 SPL_META_VERSION=_SPL_AC_META_GETVAL([Version]);
  51                 if test -n "$SPL_META_VERSION"; then
  52                         AC_DEFINE_UNQUOTED([SPL_META_VERSION], ["$SPL_META_VERSION"],
  53                                 [Define the project version.]
  54                         )
  55                         AC_SUBST([SPL_META_VERSION])
  56                 fi
  57
  58                 SPL_META_RELEASE=_SPL_AC_META_GETVAL([Release]);
  59                 if test ! -f ".nogitrelease" && git rev-parse --git-dir > /dev/null 2>&1; then
  60                         _match="${SPL_META_NAME}-${SPL_META_VERSION}"
  61                         _alias=$(git describe --match=${_match} 2>/dev/null)
  62                         _release=$(echo ${_alias}|cut -f3- -d'-'|sed 's/-/_/g')
  63                         if test -n "${_release}"; then
  64                                 SPL_META_RELEASE=${_release}
  65                                 _spl_ac_meta_type="git describe"
  66                         fi
  67                 fi
  68
  69                 if test -n "$SPL_META_RELEASE"; then
  70                         AC_DEFINE_UNQUOTED([SPL_META_RELEASE], ["$SPL_META_RELEASE"],
  71                                 [Define the project release.]
  72                         )
  73                         AC_SUBST([SPL_META_RELEASE])
  74
  75                         RELEASE="$SPL_META_RELEASE"
  76                         AC_SUBST([RELEASE])
  77                 fi
  78
  79                 SPL_META_LICENSE=_SPL_AC_META_GETVAL([License]);
  80                 if test -n "$SPL_META_LICENSE"; then
  81                         AC_DEFINE_UNQUOTED([SPL_META_LICENSE], ["$SPL_META_LICENSE"],
  82                                 [Define the project license.]
  83                         )
  84                         AC_SUBST([SPL_META_LICENSE])
  85                 fi
  86
  87                 if test -n "$SPL_META_NAME" -a -n "$SPL_META_VERSION"; then
  88                                 SPL_META_ALIAS="$SPL_META_NAME-$SPL_META_VERSION"
  89                                 test -n "$SPL_META_RELEASE" &&
  90                                         SPL_META_ALIAS="$SPL_META_ALIAS-$SPL_META_RELEASE"
  91                                 AC_DEFINE_UNQUOTED([SPL_META_ALIAS],
  92                                         ["$SPL_META_ALIAS"],
  93                                         [Define the project alias string.]
  94                                 )
  95                                 AC_SUBST([SPL_META_ALIAS])
  96                 fi
  97
  98                 SPL_META_DATA=_SPL_AC_META_GETVAL([Date]);
  99                 if test -n "$SPL_META_DATA"; then
 100                         AC_DEFINE_UNQUOTED([SPL_META_DATA], ["$SPL_META_DATA"],
 101                                 [Define the project release date.]
 102                         )
 103                         AC_SUBST([SPL_META_DATA])
 104                 fi
 105
 106                 SPL_META_AUTHOR=_SPL_AC_META_GETVAL([Author]);
 107                 if test -n "$SPL_META_AUTHOR"; then
 108                         AC_DEFINE_UNQUOTED([SPL_META_AUTHOR], ["$SPL_META_AUTHOR"],
 109                                 [Define the project author.]
 110                         )
 111                         AC_SUBST([SPL_META_AUTHOR])
 112                 fi
 113
 114                 m4_pattern_allow([^LT_(CURRENT|REVISION|AGE)$])
 115                 SPL_META_LT_CURRENT=_SPL_AC_META_GETVAL([LT_Current]);
 116                 SPL_META_LT_REVISION=_SPL_AC_META_GETVAL([LT_Revision]);
 117                 SPL_META_LT_AGE=_SPL_AC_META_GETVAL([LT_Age]);
 118                 if test -n "$SPL_META_LT_CURRENT" \
 119                                  -o -n "$SPL_META_LT_REVISION" \
 120                                  -o -n "$SPL_META_LT_AGE"; then
 121                         test -n "$SPL_META_LT_CURRENT" || SPL_META_LT_CURRENT="0"
 122                         test -n "$SPL_META_LT_REVISION" || SPL_META_LT_REVISION="0"
 123                         test -n "$SPL_META_LT_AGE" || SPL_META_LT_AGE="0"
 124                         AC_DEFINE_UNQUOTED([SPL_META_LT_CURRENT],
 125                                 ["$SPL_META_LT_CURRENT"],
 126                                 [Define the libtool library 'current'
 127                                  version information.]
 128                         )
 129                         AC_DEFINE_UNQUOTED([SPL_META_LT_REVISION],
 130                                 ["$SPL_META_LT_REVISION"],
 131                                 [Define the libtool library 'revision'
 132                                  version information.]
 133                         )
 134                         AC_DEFINE_UNQUOTED([SPL_META_LT_AGE], ["$SPL_META_LT_AGE"],
 135                                 [Define the libtool library 'age'
 136                                  version information.]
 137                         )
 138                         AC_SUBST([SPL_META_LT_CURRENT])
 139                         AC_SUBST([SPL_META_LT_REVISION])
 140                         AC_SUBST([SPL_META_LT_AGE])
 141                 fi
 142         fi
 143
 144         AC_MSG_RESULT([$_spl_ac_meta_type])
 145         ]
 146 )
 147
 148 dnl # _SPL_AC_META_GETVAL (KEY_NAME_OR_REGEX)
 149 dnl #
 150 dnl # Returns the META VALUE associated with the given KEY_NAME_OR_REGEX expr.
 151 dnl #
 152 dnl # Despite their resemblance to line noise,
 153 dnl #   the "@<:@" and "@:>@" constructs are quadrigraphs for "[" and "]".
 154 dnl #   <www.gnu.org/software/autoconf/manual/autoconf.html#Quadrigraphs>
 155 dnl #
 156 dnl # The "$[]1" and "$[]2" constructs prevent M4 parameter expansion
 157 dnl #   so a literal $1 and $2 will be passed to the resulting awk script,
 158 dnl #   whereas the "$1" will undergo M4 parameter expansion for the META key.
 159 dnl #
 160 AC_DEFUN([_SPL_AC_META_GETVAL],
 161         [`$AWK -F ':@<:@ \t@:>@+' '$[]1 ~ /^ *$1$/ { print $[]2; exit }' $META`]dnl
 162 )