[mirror_spl.git] / autoconf / spl-build.m4

AC_DEFUN([SPL_AC_KERNEL], [
	ver=`uname -r`

	AC_ARG_WITH([linux],
		AS_HELP_STRING([--with-linux=PATH],
		[Path to kernel source]),
		[kernelsrc="$withval"; kernelbuild="$withval"])

	AC_ARG_WITH([linux-obj],
		AS_HELP_STRING([--with-linux-obj=PATH],
		[Path to kernel build objects]),
		[kernelbuild="$withval"])

	AC_MSG_CHECKING([kernel source directory])
	if test -z "$kernelsrc"; then
		kernelbuild=
		sourcelink=/lib/modules/${ver}/source
		buildlink=/lib/modules/${ver}/build

		if test -e $sourcelink; then
			kernelsrc=`(cd $sourcelink; /bin/pwd)`
		fi
		if test -e $buildlink; then
			kernelbuild=`(cd $buildlink; /bin/pwd)`
		fi
		if test -z "$kernelsrc"; then
			kernelsrc=$kernelbuild
		fi
		if test -z "$kernelsrc" -o -z "$kernelbuild"; then
			AC_MSG_RESULT([Not found])
			AC_MSG_ERROR([
			*** Please specify the location of the kernel source
			*** with the '--with-kernel=PATH' option])
		fi
	fi

	AC_MSG_RESULT([$kernelsrc])
	AC_MSG_CHECKING([kernel build directory])
	AC_MSG_RESULT([$kernelbuild])

	AC_MSG_CHECKING([kernel source version])
	if test -r $kernelbuild/include/linux/version.h && 
		fgrep -q UTS_RELEASE $kernelbuild/include/linux/version.h; then

		kernsrcver=`(echo "#include <linux/version.h>"; 
		             echo "kernsrcver=UTS_RELEASE") | 
	        	     cpp -I $kernelbuild/include |
		             grep "^kernsrcver=" | cut -d \" -f 2`

	elif test -r $kernelbuild/include/linux/utsrelease.h && 
		fgrep -q UTS_RELEASE $kernelbuild/include/linux/utsrelease.h; then

		kernsrcver=`(echo "#include <linux/utsrelease.h>"; 
		             echo "kernsrcver=UTS_RELEASE") | 
	        	     cpp -I $kernelbuild/include |
		             grep "^kernsrcver=" | cut -d \" -f 2`
	fi

	if test -z "$kernsrcver"; then
		AC_MSG_RESULT([Not found])
		AC_MSG_ERROR([
		*** Cannot determine the version of the linux kernel source.
		*** Please prepare the kernel before running this script])
	fi

	AC_MSG_RESULT([$kernsrcver])

	kmoduledir=${INSTALL_MOD_PATH}/lib/modules/$kernsrcver
	LINUX=${kernelsrc}
	LINUX_OBJ=${kernelbuild}

	AC_SUBST(LINUX)
	AC_SUBST(LINUX_OBJ)
	AC_SUBST(kmoduledir)
])

AC_DEFUN([SPL_AC_DEBUG], [
	AC_MSG_CHECKING([whether debugging is enabled])
	AC_ARG_ENABLE( [debug],
		AS_HELP_STRING([--enable-debug],
		[Enable generic debug support (default off)]),
		[ case "$enableval" in
			yes) spl_ac_debug=yes ;;
			no)  spl_ac_debug=no  ;;
			*) AC_MSG_RESULT([Error!])
			AC_MSG_ERROR([Bad value "$enableval" for --enable-debug]) ;;
		esac ]
	) 
	if test "$spl_ac_debug" = yes; then
		AC_MSG_RESULT([yes])
		KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG"
	else
		AC_MSG_RESULT([no])
		AC_DEFINE([NDEBUG], [1],
		[Define to 1 to disable debug tracing])
		KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG"
	fi
])

AC_DEFUN([SPL_AC_DEBUG_KMEM], [
	AC_MSG_CHECKING([whether kmem debugging is enabled])
	AC_ARG_ENABLE( [debug-kmem],
		AS_HELP_STRING([--enable-debug-kmem],
		[Enable kmem debug support (default off)]),
		[ case "$enableval" in
			yes) spl_ac_debug_kmem=yes ;;
			no)  spl_ac_debug_kmem=no  ;;
			*) AC_MSG_RESULT([Error!])
			AC_MSG_ERROR([Bad value "$enableval" for --enable-debug-kmem]) ;;
		esac ]
	) 
	if test "$spl_ac_debug_kmem" = yes; then
		AC_MSG_RESULT([yes])
		AC_DEFINE([DEBUG_KMEM], [1],
		[Define to 1 to enable kmem debugging])
		KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM"
	else
		AC_MSG_RESULT([no])
	fi
])

AC_DEFUN([SPL_AC_DEBUG_MUTEX], [
	AC_MSG_CHECKING([whether mutex debugging is enabled])
	AC_ARG_ENABLE( [debug-mutex],
		AS_HELP_STRING([--enable-debug-mutex],
		[Enable mutex debug support (default off)]),
		[ case "$enableval" in
			yes) spl_ac_debug_mutex=yes ;;
			no)  spl_ac_debug_mutex=no  ;;
			*) AC_MSG_RESULT([Error!])
			AC_MSG_ERROR([Bad value "$enableval" for --enable-debug-mutex]) ;;
		esac ]
	) 
	if test "$spl_ac_debug_mutex" = yes; then
		AC_MSG_RESULT([yes])
		AC_DEFINE([DEBUG_MUTEX], [1],
		[Define to 1 to enable mutex debugging])
		KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_MUTEX"
	else
		AC_MSG_RESULT([no])
	fi
])

AC_DEFUN([SPL_AC_DEBUG_KSTAT], [
	AC_MSG_CHECKING([whether kstat debugging is enabled])
	AC_ARG_ENABLE( [debug-kstat],
		AS_HELP_STRING([--enable-debug-kstat],
		[Enable kstat debug support (default off)]),
		[ case "$enableval" in
			yes) spl_ac_debug_kstat=yes ;;
			no)  spl_ac_debug_kstat=no  ;;
			*) AC_MSG_RESULT([Error!])
			AC_MSG_ERROR([Bad value "$enableval" for --enable-debug-kstat]) ;;
		esac ]
	) 
	if test "$spl_ac_debug_kstat" = yes; then
		AC_MSG_RESULT([yes])
		AC_DEFINE([DEBUG_KSTAT], [1],
		[Define to 1 to enable kstat debugging])
		KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KSTAT"
	else
		AC_MSG_RESULT([no])
	fi
])

AC_DEFUN([SPL_AC_DEBUG_CALLB], [
	AC_MSG_CHECKING([whether callb debugging is enabled])
	AC_ARG_ENABLE( [debug-callb],
		AS_HELP_STRING([--enable-debug-callb],
		[Enable callb debug support (default off)]),
		[ case "$enableval" in
			yes) spl_ac_debug_callb=yes ;;
			no)  spl_ac_debug_callb=no  ;;
			*) AC_MSG_RESULT([Error!])
			AC_MSG_ERROR([Bad value "$enableval" for --enable-debug-callb]) ;;
		esac ]
	) 
	if test "$spl_ac_debug_callb" = yes; then
		AC_MSG_RESULT([yes])
		AC_DEFINE([DEBUG_CALLB], [1],
		[Define to 1 to enable callb debugging])
		KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_CALLB"
	else
		AC_MSG_RESULT([no])
	fi
])

dnl #
dnl # SPL_LINUX_CONFTEST
dnl #
AC_DEFUN([SPL_LINUX_CONFTEST], [
cat >conftest.c <<_ACEOF
$1
_ACEOF
])

dnl #
dnl # SPL_LANG_PROGRAM(C)([PROLOGUE], [BODY])
dnl #
m4_define([SPL_LANG_PROGRAM], [
$1
int
main (void)
{
dnl Do *not* indent the following line: there may be CPP directives.
dnl Don't move the `;' right after for the same reason.
$2
  ;
  return 0;
}
])

dnl #
dnl # SPL_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
dnl #
AC_DEFUN([SPL_LINUX_COMPILE_IFELSE], [
m4_ifvaln([$1], [SPL_LINUX_CONFTEST([$1])])dnl
rm -f build/conftest.o build/conftest.mod.c build/conftest.ko build/Makefile
echo "obj-m := conftest.o" >build/Makefile
dnl AS_IF([AC_TRY_COMMAND(cp conftest.c build && make [$2] CC="$CC" -f $PWD/build/Makefile LINUXINCLUDE="-Iinclude -include include/linux/autoconf.h" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM SUBDIRS=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
AS_IF([AC_TRY_COMMAND(cp conftest.c build && make [$2] CC="$CC" LINUXINCLUDE="-Iinclude -include include/linux/autoconf.h" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
        [$4],
        [_AC_MSG_LOG_CONFTEST
m4_ifvaln([$5],[$5])dnl])dnl
rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
])

dnl #
dnl # SPL_LINUX_TRY_COMPILE like AC_TRY_COMPILE
dnl #
AC_DEFUN([SPL_LINUX_TRY_COMPILE],
	[SPL_LINUX_COMPILE_IFELSE(
        [AC_LANG_SOURCE([SPL_LANG_PROGRAM([[$1]], [[$2]])])],
        [modules],
        [test -s build/conftest.o],
        [$3], [$4])
])

dnl #
dnl # SPL_LINUX_CONFIG
dnl #
AC_DEFUN([SPL_LINUX_CONFIG],
	[AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
	SPL_LINUX_TRY_COMPILE([
		#ifndef AUTOCONF_INCLUDED
		#include <linux/config.h>
		#endif
	],[
		#ifndef CONFIG_$1
		#error CONFIG_$1 not #defined
		#endif
	],[
		AC_MSG_RESULT([yes])
		$2
	],[
		AC_MSG_RESULT([no])
		$3
	])
])

dnl #
dnl # SPL_CHECK_SYMBOL_EXPORT
dnl # check symbol exported or not
dnl #
AC_DEFUN([SPL_CHECK_SYMBOL_EXPORT],
	[AC_MSG_CHECKING([whether symbol $1 is exported])
	grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX/Module.symvers 2>/dev/null
	rc=$?
	if test $rc -ne 0; then
		export=0
		for file in $2; do
			grep -q -E "EXPORT_SYMBOL.*($1)" "$LINUX/$file" 2>/dev/null
			rc=$?
		        if test $rc -eq 0; then
		                export=1
		                break;
		        fi
		done
		if test $export -eq 0; then
			AC_MSG_RESULT([no])
			$4
		else
			AC_MSG_RESULT([yes])
			$3
		fi
	else
		AC_MSG_RESULT([yes])
		$3
	fi
])

dnl #
dnl # SPL_CHECK_HEADER
dnl # check whether header exists and define HAVE_$2_HEADER
dnl #
AC_DEFUN([SPL_CHECK_HEADER],
	[AC_MSG_CHECKING([whether header $1 exists])
	SPL_LINUX_TRY_COMPILE([
        	#include <$1>
	],[
		return 0;
	],[
		AC_DEFINE(HAVE_$2_HEADER, 1, [$1 exists])
		AC_MSG_RESULT(yes)
		$3
	],[
		AC_MSG_RESULT(no)
		$4
	])
])

dnl #
dnl # 2.6.24 API change,
dnl # check if uintptr_t typedef is defined
dnl #
AC_DEFUN([SPL_AC_TYPE_UINTPTR_T],
	[AC_MSG_CHECKING([whether kernel defines uintptr_t])
	SPL_LINUX_TRY_COMPILE([
	        #include <linux/types.h>
	],[
	        uintptr_t *ptr;
	],[
	        AC_MSG_RESULT([yes])
	        AC_DEFINE(HAVE_UINTPTR_T, 1,
		          [kernel defines uintptr_t])
	],[
	        AC_MSG_RESULT([no])
	])
])

dnl #
dnl # 2.6.19 API change,
dnl # panic_notifier_list use atomic_notifier operations
dnl #

AC_DEFUN([SPL_AC_ATOMIC_PANIC_NOTIFIER],
	[AC_MSG_CHECKING([whether panic_notifier_list is atomic])
	SPL_LINUX_TRY_COMPILE([
	        #include <linux/notifier.h>
	        #include <linux/kernel.h>
	],[
	        struct atomic_notifier_head panic_notifier_list;
	],[
	        AC_MSG_RESULT(yes)
	        AC_DEFINE(HAVE_ATOMIC_PANIC_NOTIFIER, 1,
	                [panic_notifier_list is atomic])
	],[
	        AC_MSG_RESULT(no)
	])
])

dnl #
dnl # 2.6.20 API change,
dnl # INIT_WORK use 2 args and not store data inside
dnl #
AC_DEFUN([SPL_AC_3ARGS_INIT_WORK],
	[AC_MSG_CHECKING([whether INIT_WORK wants 3 args])
	SPL_LINUX_TRY_COMPILE([
	        #include <linux/workqueue.h>
	],[
	        struct work_struct work;

	        INIT_WORK(&work, NULL, NULL);
	],[
	        AC_MSG_RESULT(yes)
	        AC_DEFINE(HAVE_3ARGS_INIT_WORK, 1,
	                  [INIT_WORK wants 3 args])
	],[
	        AC_MSG_RESULT(no)
	])
])

dnl #
dnl # 2.6.21 API change,
dnl # 'register_sysctl_table' use only one argument instead of two
dnl #
AC_DEFUN([SPL_AC_2ARGS_REGISTER_SYSCTL],
	[AC_MSG_CHECKING([whether register_sysctl_table() wants 2 args])
	SPL_LINUX_TRY_COMPILE([
	        #include <linux/sysctl.h>
	],[
	        return register_sysctl_table(NULL,0);
	],[
        AC_MSG_RESULT(yes)
	        AC_DEFINE(HAVE_2ARGS_REGISTER_SYSCTL, 1,
        	          [register_sysctl_table() wants 2 args])
	],[
	        AC_MSG_RESULT(no)
	])
])

dnl #
dnl # 2.6.23 API change
dnl # Old set_shrinker API replaced with register_shrinker
dnl #
AC_DEFUN([SPL_AC_SET_SHRINKER], [
	AC_MSG_CHECKING([whether set_shrinker() available])
	SPL_LINUX_TRY_COMPILE([
		#include <linux/mm.h>
	],[
		return set_shrinker(DEFAULT_SEEKS, NULL);
	],[
		AC_MSG_RESULT([yes])
		AC_DEFINE(HAVE_SET_SHRINKER, 1,
		          [set_shrinker() available])
	],[
		AC_MSG_RESULT([no])
	])
])

dnl #
dnl # 2.6.25 API change,
dnl # struct path entry added to struct nameidata
dnl #
AC_DEFUN([SPL_AC_PATH_IN_NAMEIDATA],
	[AC_MSG_CHECKING([whether struct path used in struct nameidata])
	SPL_LINUX_TRY_COMPILE([
	        #include <linux/namei.h>
	],[
	        struct nameidata nd;

		nd.path.mnt = NULL;
		nd.path.dentry = NULL;
	],[
	        AC_MSG_RESULT(yes)
	        AC_DEFINE(HAVE_PATH_IN_NAMEIDATA, 1,
	                  [struct path used in struct nameidata])
	],[
	        AC_MSG_RESULT(no)
	])
])

dnl #
dnl # Custom SPL patch may export this system it is not required
dnl #
AC_DEFUN([SPL_AC_TASK_CURR], [
	SPL_CHECK_SYMBOL_EXPORT([task_curr], [kernel/sched.c],
		[AC_DEFINE(HAVE_TASK_CURR, 1, [task_curr() exported])],
		[])
])

dnl #
dnl # 2.6.19 API change,
dnl # Use CTL_UNNUMBERED when binary sysctl is not required
dnl #
AC_DEFUN([SPL_AC_CTL_UNNUMBERED],
	[AC_MSG_CHECKING([whether unnumbered sysctl support exists])
	SPL_LINUX_TRY_COMPILE([
	        #include <linux/sysctl.h>
	],[
		#ifndef CTL_UNNUMBERED
		#error CTL_UNNUMBERED undefined
		#endif
	],[
	        AC_MSG_RESULT(yes)
	        AC_DEFINE(HAVE_CTL_UNNUMBERED, 1,
	                  [unnumbered sysctl support exists])
	],[
	        AC_MSG_RESULT(no)
	])
])

dnl #
dnl # 2.6.16 API change.
dnl # Check if 'fls64()' is available
dnl #
AC_DEFUN([SPL_AC_FLS64],
	[AC_MSG_CHECKING([whether fls64() is available])
	SPL_LINUX_TRY_COMPILE([
		#include <linux/bitops.h>
	],[
		return fls64(0);
	],[
		AC_MSG_RESULT(yes)
		AC_DEFINE(HAVE_FLS64, 1, [fls64() is available])
	],[
		AC_MSG_RESULT(no)
	])
])

dnl #
dnl # 2.6.18 API change, check whether device_create() is available.
dnl # Device_create() was introduced in 2.6.18 and depricated 
dnl # class_device_create() which was fully removed in 2.6.26.
dnl #
AC_DEFUN([SPL_AC_DEVICE_CREATE], [
	SPL_CHECK_SYMBOL_EXPORT(
		[device_create],
		[drivers/base/core.c],
		[AC_DEFINE(HAVE_DEVICE_CREATE, 1,
		[device_create() is available])],
		[])
])

dnl #
dnl # 2.6.13 API change, check whether class_device_create() is available.
dnl # Class_device_create() was introduced in 2.6.13 and depricated
dnl # class_simple_device_add() which was fully removed in 2.6.13.
dnl #
AC_DEFUN([SPL_AC_CLASS_DEVICE_CREATE], [
	SPL_CHECK_SYMBOL_EXPORT(
		[class_device_create],
		[drivers/base/class.c],
		[AC_DEFINE(HAVE_CLASS_DEVICE_CREATE, 1,
		[class_device_create() is available])],
		[])
])

dnl #
dnl # 2.6.26 API change, set_normalized_timespec() is exported.
dnl #
AC_DEFUN([SPL_AC_SET_NORMALIZED_TIMESPEC_EXPORT], [
	SPL_CHECK_SYMBOL_EXPORT(
		[set_normalized_timespec],
		[kernel/time.c],
		[AC_DEFINE(HAVE_SET_NORMALIZED_TIMESPEC_EXPORT, 1,
		[set_normalized_timespec() is available as export])],
		[])
])

dnl #
dnl # 2.6.16 API change, set_normalize_timespec() moved to time.c
dnl # previously it was available in time.h as an inline.
dnl #
AC_DEFUN([SPL_AC_SET_NORMALIZED_TIMESPEC_INLINE], [
	AC_MSG_CHECKING([whether set_normalized_timespec() is an inline])
	SPL_LINUX_TRY_COMPILE([
		#include <linux/time.h>
		void set_normalized_timespec(struct timespec *ts,
		                             time_t sec, long nsec) { }
	],
	[],
	[
		AC_MSG_RESULT(no)
	],[
		AC_MSG_RESULT(yes)
		AC_DEFINE(HAVE_SET_NORMALIZED_TIMESPEC_INLINE, 1,
		          [set_normalized_timespec() is available as inline])
	])
])

dnl #
dnl # 2.6.18 API change,
dnl # timespec_sub() inline function available in linux/time.h
dnl #
AC_DEFUN([SPL_AC_TIMESPEC_SUB], [
	AC_MSG_CHECKING([whether timespec_sub() is available])
	SPL_LINUX_TRY_COMPILE([
		#include <linux/time.h>
	],[
		struct timespec a, b, c = { 0 };
		c = timespec_sub(a, b);
	],[
		AC_MSG_RESULT(yes)
		AC_DEFINE(HAVE_TIMESPEC_SUB, 1, [timespec_sub() is available])
	],[
		AC_MSG_RESULT(no)
	])
])

dnl #
dnl # 2.6.19 API change,
dnl # check if init_utsname() is available in linux/utsname.h
dnl #
AC_DEFUN([SPL_AC_INIT_UTSNAME], [
	AC_MSG_CHECKING([whether init_utsname() is available])
	SPL_LINUX_TRY_COMPILE([
		#include <linux/utsname.h>
	],[
		struct new_utsname *a = init_utsname();
	],[
		AC_MSG_RESULT(yes)
		AC_DEFINE(HAVE_INIT_UTSNAME, 1, [init_utsname() is available])
	],[
		AC_MSG_RESULT(no)
	])
])

dnl #
dnl # 2.6.26 API change,
dnl # definition of struct fdtable relocated to linux/fdtable.h
dnl #
AC_DEFUN([SPL_AC_FDTABLE_HEADER], [
	SPL_CHECK_HEADER([linux/fdtable.h], [FDTABLE], [], [])
])

dnl #
dnl # 2.6.14 API change,
dnl # check whether 'files_fdtable()' exists
dnl #
AC_DEFUN([SPL_AC_FILES_FDTABLE], [
	AC_MSG_CHECKING([whether files_fdtable() is available])
	SPL_LINUX_TRY_COMPILE([
		#include <linux/sched.h>
		#include <linux/file.h>
		#ifdef HAVE_FDTABLE_HEADER
		#include <linux/fdtable.h>
		#endif
	],[
		struct files_struct *files = current->files;
		struct fdtable *fdt = files_fdtable(files);
	],[
		AC_MSG_RESULT(yes)
		AC_DEFINE(HAVE_FILES_FDTABLE, 1, [files_fdtable() is available])
	],[
		AC_MSG_RESULT(no)
	])
])

dnl #
dnl # 2.6.18 API change,
dnl # added linux/uaccess.h
dnl #
AC_DEFUN([SPL_AC_UACCESS_HEADER], [
	SPL_CHECK_HEADER([linux/uaccess.h], [UACCESS], [], [])
])

dnl #
dnl # 2.6.12 API change,
dnl # check whether 'kmalloc_node()' is available.
dnl #
AC_DEFUN([SPL_AC_KMALLOC_NODE], [
	AC_MSG_CHECKING([whether kmalloc_node() is available])
	SPL_LINUX_TRY_COMPILE([
		#include <linux/slab.h>
	],[
		void *a = kmalloc_node(1, GFP_KERNEL, 0);
	],[
		AC_MSG_RESULT(yes)
		AC_DEFINE(HAVE_KMALLOC_NODE, 1, [kmalloc_node() is available])
	],[
		AC_MSG_RESULT(no)
	])
])

dnl #
dnl # 2.6.9 API change,
dnl # check whether 'monotonic_clock()' is available it may
dnl # be available for some archs but not others.
dnl #
AC_DEFUN([SPL_AC_MONOTONIC_CLOCK], [
	SPL_CHECK_SYMBOL_EXPORT(
		[monotonic_clock],
		[],
		[AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1,
		[monotonic_clock() is available])],
		[])
])

dnl #
dnl # 2.6.16 API change,
dnl # check whether 'struct inode' has i_mutex
dnl #
AC_DEFUN([SPL_AC_INODE_I_MUTEX], [
	AC_MSG_CHECKING([whether struct inode has i_mutex])
	SPL_LINUX_TRY_COMPILE([
		#include <linux/fs.h>
		#include <linux/mutex.h>
	],[
		struct inode i;
		mutex_init(&i.i_mutex);
	],[
		AC_MSG_RESULT(yes)
		AC_DEFINE(HAVE_INODE_I_MUTEX, 1, [struct inode has i_mutex])
	],[
		AC_MSG_RESULT(no)
	])
])

dnl #
dnl # 2.6.14 API change,
dnl # check whether 'div64_64()' is available
dnl #
AC_DEFUN([SPL_AC_DIV64_64], [
	AC_MSG_CHECKING([whether div64_64() is available])
	SPL_LINUX_TRY_COMPILE([
		#include <asm/div64.h>
	],[
		uint64_t i = div64_64(1ULL, 1ULL);
	],[
		AC_MSG_RESULT(yes)
		AC_DEFINE(HAVE_DIV64_64, 1, [div64_64() is available])
	],[
		AC_MSG_RESULT(no)
	])
])
Commit	Line	Data
57d86234	1	AC_DEFUN([SPL_AC_KERNEL], [
	2	ver=`uname -r`
	3
	4	AC_ARG_WITH([linux],
	5	AS_HELP_STRING([--with-linux=PATH],
	6	[Path to kernel source]),
	7	[kernelsrc="$withval"; kernelbuild="$withval"])
	8
	9	AC_ARG_WITH([linux-obj],
	10	AS_HELP_STRING([--with-linux-obj=PATH],
	11	[Path to kernel build objects]),
	12	[kernelbuild="$withval"])
	13
	14	AC_MSG_CHECKING([kernel source directory])
	15	if test -z "$kernelsrc"; then
	16	kernelbuild=
	17	sourcelink=/lib/modules/${ver}/source
	18	buildlink=/lib/modules/${ver}/build
	19
	20	if test -e $sourcelink; then
	21	kernelsrc=`(cd $sourcelink; /bin/pwd)`
	22	fi
	23	if test -e $buildlink; then
	24	kernelbuild=`(cd $buildlink; /bin/pwd)`
	25	fi
	26	if test -z "$kernelsrc"; then
	27	kernelsrc=$kernelbuild
	28	fi
	29	if test -z "$kernelsrc" -o -z "$kernelbuild"; then
	30	AC_MSG_RESULT([Not found])
	31	AC_MSG_ERROR([
	32	*** Please specify the location of the kernel source
	33	*** with the '--with-kernel=PATH' option])
	34	fi
	35	fi
	36
	37	AC_MSG_RESULT([$kernelsrc])
	38	AC_MSG_CHECKING([kernel build directory])
	39	AC_MSG_RESULT([$kernelbuild])
	40
	41	AC_MSG_CHECKING([kernel source version])
	42	if test -r $kernelbuild/include/linux/version.h &&
	43	fgrep -q UTS_RELEASE $kernelbuild/include/linux/version.h; then
	44
	45	kernsrcver=`(echo "#include <linux/version.h>";
	46	echo "kernsrcver=UTS_RELEASE") \|
	47	cpp -I $kernelbuild/include \|
	48	grep "^kernsrcver=" \| cut -d \" -f 2`
	49
	50	elif test -r $kernelbuild/include/linux/utsrelease.h &&
	51	fgrep -q UTS_RELEASE $kernelbuild/include/linux/utsrelease.h; then
	52
	53	kernsrcver=`(echo "#include <linux/utsrelease.h>";
	54	echo "kernsrcver=UTS_RELEASE") \|
	55	cpp -I $kernelbuild/include \|
	56	grep "^kernsrcver=" \| cut -d \" -f 2`
	57	fi
	58
	59	if test -z "$kernsrcver"; then
	60	AC_MSG_RESULT([Not found])
	61	AC_MSG_ERROR([
	62	*** Cannot determine the version of the linux kernel source.
	63	*** Please prepare the kernel before running this script])
	64	fi
65
66	AC_MSG_RESULT([$kernsrcver])
67
68	kmoduledir=${INSTALL_MOD_PATH}/lib/modules/$kernsrcver
69	LINUX=${kernelsrc}
70	LINUX_OBJ=${kernelbuild}
71
72	AC_SUBST(LINUX)
73	AC_SUBST(LINUX_OBJ)
74	AC_SUBST(kmoduledir)
75	])
76
77	AC_DEFUN([SPL_AC_DEBUG], [
78	AC_MSG_CHECKING([whether debugging is enabled])
79	AC_ARG_ENABLE( [debug],
80	AS_HELP_STRING([--enable-debug],
81	[Enable generic debug support (default off)]),
82	[ case "$enableval" in
83	yes) spl_ac_debug=yes ;;
475cdc78	84	no) spl_ac_debug=no ;;
57d86234	85	*) AC_MSG_RESULT([Error!])
	86	AC_MSG_ERROR([Bad value "$enableval" for --enable-debug]) ;;
	87	esac ]
	88	)
	89	if test "$spl_ac_debug" = yes; then
475cdc78	90	AC_MSG_RESULT([yes])
57d86234	91	KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG"
57d86234	92	else
475cdc78	93	AC_MSG_RESULT([no])
57d86234	94	AC_DEFINE([NDEBUG], [1],
57d86234	95	[Define to 1 to disable debug tracing])
475cdc78	96	KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG"
57d86234	97	fi
57d86234	98	])
	99
	100	AC_DEFUN([SPL_AC_DEBUG_KMEM], [
	101	AC_MSG_CHECKING([whether kmem debugging is enabled])
	102	AC_ARG_ENABLE( [debug-kmem],
	103	AS_HELP_STRING([--enable-debug-kmem],
	104	[Enable kmem debug support (default off)]),
	105	[ case "$enableval" in
475cdc78	106	yes) spl_ac_debug_kmem=yes ;;
475cdc78	107	no) spl_ac_debug_kmem=no ;;
57d86234	108	*) AC_MSG_RESULT([Error!])
	109	AC_MSG_ERROR([Bad value "$enableval" for --enable-debug-kmem]) ;;
	110	esac ]
	111	)
475cdc78	112	if test "$spl_ac_debug_kmem" = yes; then
475cdc78	113	AC_MSG_RESULT([yes])
57d86234	114	AC_DEFINE([DEBUG_KMEM], [1],
57d86234	115	[Define to 1 to enable kmem debugging])
475cdc78	116	KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM"
	117	else
	118	AC_MSG_RESULT([no])
57d86234	119	fi
57d86234	120	])
	121
	122	AC_DEFUN([SPL_AC_DEBUG_MUTEX], [
	123	AC_MSG_CHECKING([whether mutex debugging is enabled])
	124	AC_ARG_ENABLE( [debug-mutex],
	125	AS_HELP_STRING([--enable-debug-mutex],
	126	[Enable mutex debug support (default off)]),
	127	[ case "$enableval" in
475cdc78	128	yes) spl_ac_debug_mutex=yes ;;
475cdc78	129	no) spl_ac_debug_mutex=no ;;
57d86234	130	*) AC_MSG_RESULT([Error!])
	131	AC_MSG_ERROR([Bad value "$enableval" for --enable-debug-mutex]) ;;
	132	esac ]
	133	)
475cdc78	134	if test "$spl_ac_debug_mutex" = yes; then
475cdc78	135	AC_MSG_RESULT([yes])
57d86234	136	AC_DEFINE([DEBUG_MUTEX], [1],
57d86234	137	[Define to 1 to enable mutex debugging])
475cdc78	138	KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_MUTEX"
	139	else
	140	AC_MSG_RESULT([no])
57d86234	141	fi
57d86234	142	])
	143
	144	AC_DEFUN([SPL_AC_DEBUG_KSTAT], [
	145	AC_MSG_CHECKING([whether kstat debugging is enabled])
	146	AC_ARG_ENABLE( [debug-kstat],
	147	AS_HELP_STRING([--enable-debug-kstat],
	148	[Enable kstat debug support (default off)]),
	149	[ case "$enableval" in
475cdc78	150	yes) spl_ac_debug_kstat=yes ;;
475cdc78	151	no) spl_ac_debug_kstat=no ;;
57d86234	152	*) AC_MSG_RESULT([Error!])
	153	AC_MSG_ERROR([Bad value "$enableval" for --enable-debug-kstat]) ;;
	154	esac ]
	155	)
475cdc78	156	if test "$spl_ac_debug_kstat" = yes; then
475cdc78	157	AC_MSG_RESULT([yes])
57d86234	158	AC_DEFINE([DEBUG_KSTAT], [1],
57d86234	159	[Define to 1 to enable kstat debugging])
475cdc78	160	KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KSTAT"
	161	else
	162	AC_MSG_RESULT([no])
57d86234	163	fi
57d86234	164	])
	165
	166	AC_DEFUN([SPL_AC_DEBUG_CALLB], [
	167	AC_MSG_CHECKING([whether callb debugging is enabled])
	168	AC_ARG_ENABLE( [debug-callb],
	169	AS_HELP_STRING([--enable-debug-callb],
	170	[Enable callb debug support (default off)]),
	171	[ case "$enableval" in
475cdc78	172	yes) spl_ac_debug_callb=yes ;;
475cdc78	173	no) spl_ac_debug_callb=no ;;
57d86234	174	*) AC_MSG_RESULT([Error!])
	175	AC_MSG_ERROR([Bad value "$enableval" for --enable-debug-callb]) ;;
	176	esac ]
	177	)
475cdc78	178	if test "$spl_ac_debug_callb" = yes; then
475cdc78	179	AC_MSG_RESULT([yes])
57d86234	180	AC_DEFINE([DEBUG_CALLB], [1],
57d86234	181	[Define to 1 to enable callb debugging])
475cdc78	182	KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_CALLB"
	183	else
	184	AC_MSG_RESULT([no])
57d86234	185	fi
57d86234	186	])
	187
	188	dnl #
	189	dnl # SPL_LINUX_CONFTEST
	190	dnl #
	191	AC_DEFUN([SPL_LINUX_CONFTEST], [
	192	cat >conftest.c <<_ACEOF
	193	$1
	194	_ACEOF
	195	])
	196
	197	dnl #
	198	dnl # SPL_LANG_PROGRAM(C)([PROLOGUE], [BODY])
	199	dnl #
	200	m4_define([SPL_LANG_PROGRAM], [
	201	$1
	202	int
	203	main (void)
	204	{
	205	dnl Do not indent the following line: there may be CPP directives.
	206	dnl Don't move the `;' right after for the same reason.
	207	$2
	208	;
	209	return 0;
	210	}
	211	])
	212
	213	dnl #
	214	dnl # SPL_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
	215	dnl #
	216	AC_DEFUN([SPL_LINUX_COMPILE_IFELSE], [
	217	m4_ifvaln([$1], [SPL_LINUX_CONFTEST([$1])])dnl
	218	rm -f build/conftest.o build/conftest.mod.c build/conftest.ko build/Makefile
	219	echo "obj-m := conftest.o" >build/Makefile
	220	dnl AS_IF([AC_TRY_COMMAND(cp conftest.c build && make [$2] CC="$CC" -f $PWD/build/Makefile LINUXINCLUDE="-Iinclude -include include/linux/autoconf.h" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM SUBDIRS=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
	221	AS_IF([AC_TRY_COMMAND(cp conftest.c build && make [$2] CC="$CC" LINUXINCLUDE="-Iinclude -include include/linux/autoconf.h" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
	222	[$4],
	223	[_AC_MSG_LOG_CONFTEST
	224	m4_ifvaln([$5],[$5])dnl])dnl
	225	rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
	226	])
	227
	228	dnl #
	229	dnl # SPL_LINUX_TRY_COMPILE like AC_TRY_COMPILE
	230	dnl #
	231	AC_DEFUN([SPL_LINUX_TRY_COMPILE],
	232	[SPL_LINUX_COMPILE_IFELSE(
	233	[AC_LANG_SOURCE([SPL_LANG_PROGRAM([[$1]], [[$2]])])],
	234	[modules],
	235	[test -s build/conftest.o],
	236	[$3], [$4])
	237	])
	238
	239	dnl #
	240	dnl # SPL_LINUX_CONFIG
	241	dnl #
	242	AC_DEFUN([SPL_LINUX_CONFIG],
	243	[AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
	244	SPL_LINUX_TRY_COMPILE([
	245	#ifndef AUTOCONF_INCLUDED
	246	#include <linux/config.h>
	247	#endif
	248	],[
	249	#ifndef CONFIG_$1
250	#error CONFIG_$1 not #defined
251	#endif
252	],[
253	AC_MSG_RESULT([yes])
254	$2
255	],[
256	AC_MSG_RESULT([no])
257	$3
258	])
259	])
260
261	dnl #
262	dnl # SPL_CHECK_SYMBOL_EXPORT
263	dnl # check symbol exported or not
264	dnl #
265	AC_DEFUN([SPL_CHECK_SYMBOL_EXPORT],
266	[AC_MSG_CHECKING([whether symbol $1 is exported])
267	grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX/Module.symvers 2>/dev/null
268	rc=$?
269	if test $rc -ne 0; then
270	export=0
271	for file in $2; do
272	grep -q -E "EXPORT_SYMBOL.*($1)" "$LINUX/$file" 2>/dev/null
273	rc=$?
274	if test $rc -eq 0; then
275	export=1
276	break;
277	fi
278	done
279	if test $export -eq 0; then
280	AC_MSG_RESULT([no])
281	$4
282	else
283	AC_MSG_RESULT([yes])
284	$3
285	fi
286	else
287	AC_MSG_RESULT([yes])
288	$3
289	fi
290	])
291
86de8532	292	dnl #
	293	dnl # SPL_CHECK_HEADER
	294	dnl # check whether header exists and define HAVE_$2_HEADER
	295	dnl #
	296	AC_DEFUN([SPL_CHECK_HEADER],
	297	[AC_MSG_CHECKING([whether header $1 exists])
	298	SPL_LINUX_TRY_COMPILE([
	299	#include <$1>
	300	],[
	301	return 0;
	302	],[
	303	AC_DEFINE(HAVE_$2_HEADER, 1, [$1 exists])
	304	AC_MSG_RESULT(yes)
	305	$3
	306	],[
	307	AC_MSG_RESULT(no)
	308	$4
	309	])
	310	])
6a6cafbe	311
57d86234	312	dnl #
3d061e9d	313	dnl # 2.6.24 API change,
57d86234	314	dnl # check if uintptr_t typedef is defined
	315	dnl #
	316	AC_DEFUN([SPL_AC_TYPE_UINTPTR_T],
	317	[AC_MSG_CHECKING([whether kernel defines uintptr_t])
	318	SPL_LINUX_TRY_COMPILE([
	319	#include <linux/types.h>
	320	],[
	321	uintptr_t *ptr;
	322	],[
	323	AC_MSG_RESULT([yes])
	324	AC_DEFINE(HAVE_UINTPTR_T, 1,
	325	[kernel defines uintptr_t])
	326	],[
	327	AC_MSG_RESULT([no])
	328	])
	329	])
	330
57d86234	331	dnl #
3d061e9d	332	dnl # 2.6.19 API change,
57d86234	333	dnl # panic_notifier_list use atomic_notifier operations
	334	dnl #
	335
	336	AC_DEFUN([SPL_AC_ATOMIC_PANIC_NOTIFIER],
	337	[AC_MSG_CHECKING([whether panic_notifier_list is atomic])
	338	SPL_LINUX_TRY_COMPILE([
	339	#include <linux/notifier.h>
	340	#include <linux/kernel.h>
	341	],[
	342	struct atomic_notifier_head panic_notifier_list;
	343	],[
	344	AC_MSG_RESULT(yes)
	345	AC_DEFINE(HAVE_ATOMIC_PANIC_NOTIFIER, 1,
	346	[panic_notifier_list is atomic])
	347	],[
	348	AC_MSG_RESULT(no)
	349	])
	350	])
	351
	352	dnl #
3d061e9d	353	dnl # 2.6.20 API change,
57d86234	354	dnl # INIT_WORK use 2 args and not store data inside
	355	dnl #
	356	AC_DEFUN([SPL_AC_3ARGS_INIT_WORK],
	357	[AC_MSG_CHECKING([whether INIT_WORK wants 3 args])
	358	SPL_LINUX_TRY_COMPILE([
	359	#include <linux/workqueue.h>
	360	],[
	361	struct work_struct work;
	362
	363	INIT_WORK(&work, NULL, NULL);
	364	],[
	365	AC_MSG_RESULT(yes)
	366	AC_DEFINE(HAVE_3ARGS_INIT_WORK, 1,
	367	[INIT_WORK wants 3 args])
	368	],[
	369	AC_MSG_RESULT(no)
	370	])
	371	])
	372
	373	dnl #
3d061e9d	374	dnl # 2.6.21 API change,
57d86234	375	dnl # 'register_sysctl_table' use only one argument instead of two
	376	dnl #
	377	AC_DEFUN([SPL_AC_2ARGS_REGISTER_SYSCTL],
	378	[AC_MSG_CHECKING([whether register_sysctl_table() wants 2 args])
	379	SPL_LINUX_TRY_COMPILE([
	380	#include <linux/sysctl.h>
	381	],[
	382	return register_sysctl_table(NULL,0);
	383	],[
	384	AC_MSG_RESULT(yes)
	385	AC_DEFINE(HAVE_2ARGS_REGISTER_SYSCTL, 1,
	386	[register_sysctl_table() wants 2 args])
	387	],[
	388	AC_MSG_RESULT(no)
	389	])
	390	])
	391
57d86234	392	dnl #
3d061e9d	393	dnl # 2.6.23 API change
57d86234	394	dnl # Old set_shrinker API replaced with register_shrinker
	395	dnl #
	396	AC_DEFUN([SPL_AC_SET_SHRINKER], [
	397	AC_MSG_CHECKING([whether set_shrinker() available])
	398	SPL_LINUX_TRY_COMPILE([
	399	#include <linux/mm.h>
	400	],[
	401	return set_shrinker(DEFAULT_SEEKS, NULL);
	402	],[
	403	AC_MSG_RESULT([yes])
	404	AC_DEFINE(HAVE_SET_SHRINKER, 1,
	405	[set_shrinker() available])
	406	],[
	407	AC_MSG_RESULT([no])
	408	])
	409	])
	410
	411	dnl #
3d061e9d	412	dnl # 2.6.25 API change,
57d86234	413	dnl # struct path entry added to struct nameidata
	414	dnl #
	415	AC_DEFUN([SPL_AC_PATH_IN_NAMEIDATA],
	416	[AC_MSG_CHECKING([whether struct path used in struct nameidata])
	417	SPL_LINUX_TRY_COMPILE([
	418	#include <linux/namei.h>
	419	],[
	420	struct nameidata nd;
	421
	422	nd.path.mnt = NULL;
	423	nd.path.dentry = NULL;
	424	],[
	425	AC_MSG_RESULT(yes)
	426	AC_DEFINE(HAVE_PATH_IN_NAMEIDATA, 1,
	427	[struct path used in struct nameidata])
	428	],[
	429	AC_MSG_RESULT(no)
	430	])
	431	])
	432
	433	dnl #
	434	dnl # Custom SPL patch may export this system it is not required
	435	dnl #
	436	AC_DEFUN([SPL_AC_TASK_CURR], [
	437	SPL_CHECK_SYMBOL_EXPORT([task_curr], [kernel/sched.c],
	438	[AC_DEFINE(HAVE_TASK_CURR, 1, [task_curr() exported])],
	439	[])
	440	])
	441
	442	dnl #
3d061e9d	443	dnl # 2.6.19 API change,
57d86234	444	dnl # Use CTL_UNNUMBERED when binary sysctl is not required
	445	dnl #
	446	AC_DEFUN([SPL_AC_CTL_UNNUMBERED],
	447	[AC_MSG_CHECKING([whether unnumbered sysctl support exists])
	448	SPL_LINUX_TRY_COMPILE([
	449	#include <linux/sysctl.h>
	450	],[
	451	#ifndef CTL_UNNUMBERED
	452	#error CTL_UNNUMBERED undefined
	453	#endif
	454	],[
	455	AC_MSG_RESULT(yes)
	456	AC_DEFINE(HAVE_CTL_UNNUMBERED, 1,
	457	[unnumbered sysctl support exists])
	458	],[
	459	AC_MSG_RESULT(no)
	460	])
	461	])
877a32e9	462
	463	dnl #
	464	dnl # 2.6.16 API change.
	465	dnl # Check if 'fls64()' is available
	466	dnl #
	467	AC_DEFUN([SPL_AC_FLS64],
6a6cafbe	468	[AC_MSG_CHECKING([whether fls64() is available])
	469	SPL_LINUX_TRY_COMPILE([
	470	#include <linux/bitops.h>
	471	],[
	472	return fls64(0);
	473	],[
	474	AC_MSG_RESULT(yes)
	475	AC_DEFINE(HAVE_FLS64, 1, [fls64() is available])
	476	],[
	477	AC_MSG_RESULT(no)
	478	])
877a32e9	479	])
46c685d0	480
	481	dnl #
	482	dnl # 2.6.18 API change, check whether device_create() is available.
	483	dnl # Device_create() was introduced in 2.6.18 and depricated
	484	dnl # class_device_create() which was fully removed in 2.6.26.
	485	dnl #
	486	AC_DEFUN([SPL_AC_DEVICE_CREATE], [
	487	SPL_CHECK_SYMBOL_EXPORT(
	488	[device_create],
	489	[drivers/base/core.c],
	490	[AC_DEFINE(HAVE_DEVICE_CREATE, 1,
	491	[device_create() is available])],
6a6cafbe	492	[])
46c685d0	493	])
	494
	495	dnl #
	496	dnl # 2.6.13 API change, check whether class_device_create() is available.
	497	dnl # Class_device_create() was introduced in 2.6.13 and depricated
	498	dnl # class_simple_device_add() which was fully removed in 2.6.13.
	499	dnl #
	500	AC_DEFUN([SPL_AC_CLASS_DEVICE_CREATE], [
	501	SPL_CHECK_SYMBOL_EXPORT(
	502	[class_device_create],
	503	[drivers/base/class.c],
	504	[AC_DEFINE(HAVE_CLASS_DEVICE_CREATE, 1,
	505	[class_device_create() is available])],
6a6cafbe	506	[])
46c685d0	507	])
6a6cafbe	508
6a6cafbe	509	dnl #
	510	dnl # 2.6.26 API change, set_normalized_timespec() is exported.
	511	dnl #
	512	AC_DEFUN([SPL_AC_SET_NORMALIZED_TIMESPEC_EXPORT], [
	513	SPL_CHECK_SYMBOL_EXPORT(
	514	[set_normalized_timespec],
	515	[kernel/time.c],
	516	[AC_DEFINE(HAVE_SET_NORMALIZED_TIMESPEC_EXPORT, 1,
	517	[set_normalized_timespec() is available as export])],
	518	[])
	519	])
	520
	521	dnl #
	522	dnl # 2.6.16 API change, set_normalize_timespec() moved to time.c
	523	dnl # previously it was available in time.h as an inline.
	524	dnl #
86de8532	525	AC_DEFUN([SPL_AC_SET_NORMALIZED_TIMESPEC_INLINE], [
86de8532	526	AC_MSG_CHECKING([whether set_normalized_timespec() is an inline])
6a6cafbe	527	SPL_LINUX_TRY_COMPILE([
6a6cafbe	528	#include <linux/time.h>
6a6cafbe	529	void set_normalized_timespec(struct timespec *ts,
25557fd8	530	time_t sec, long nsec) { }
	531	],
	532	[],
	533	[
6a6cafbe	534	AC_MSG_RESULT(no)
	535	],[
	536	AC_MSG_RESULT(yes)
	537	AC_DEFINE(HAVE_SET_NORMALIZED_TIMESPEC_INLINE, 1,
	538	[set_normalized_timespec() is available as inline])
	539	])
	540	])
	541
	542	dnl #
	543	dnl # 2.6.18 API change,
	544	dnl # timespec_sub() inline function available in linux/time.h
	545	dnl #
86de8532	546	AC_DEFUN([SPL_AC_TIMESPEC_SUB], [
86de8532	547	AC_MSG_CHECKING([whether timespec_sub() is available])
6a6cafbe	548	SPL_LINUX_TRY_COMPILE([
	549	#include <linux/time.h>
	550	],[
	551	struct timespec a, b, c = { 0 };
	552	c = timespec_sub(a, b);
	553	],[
	554	AC_MSG_RESULT(yes)
	555	AC_DEFINE(HAVE_TIMESPEC_SUB, 1, [timespec_sub() is available])
	556	],[
	557	AC_MSG_RESULT(no)
	558	])
	559	])
	560
86de8532	561	dnl #
3d061e9d	562	dnl # 2.6.19 API change,
	563	dnl # check if init_utsname() is available in linux/utsname.h
	564	dnl #
	565	AC_DEFUN([SPL_AC_INIT_UTSNAME], [
	566	AC_MSG_CHECKING([whether init_utsname() is available])
	567	SPL_LINUX_TRY_COMPILE([
	568	#include <linux/utsname.h>
	569	],[
	570	struct new_utsname *a = init_utsname();
	571	],[
	572	AC_MSG_RESULT(yes)
	573	AC_DEFINE(HAVE_INIT_UTSNAME, 1, [init_utsname() is available])
	574	],[
	575	AC_MSG_RESULT(no)
	576	])
	577	])
	578
	579	dnl #
	580	dnl # 2.6.26 API change,
	581	dnl # definition of struct fdtable relocated to linux/fdtable.h
86de8532	582	dnl #
	583	AC_DEFUN([SPL_AC_FDTABLE_HEADER], [
	584	SPL_CHECK_HEADER([linux/fdtable.h], [FDTABLE], [], [])
	585	])
322640b7	586
322640b7	587	dnl #
3d061e9d	588	dnl # 2.6.14 API change,
	589	dnl # check whether 'files_fdtable()' exists
	590	dnl #
	591	AC_DEFUN([SPL_AC_FILES_FDTABLE], [
	592	AC_MSG_CHECKING([whether files_fdtable() is available])
	593	SPL_LINUX_TRY_COMPILE([
	594	#include <linux/sched.h>
	595	#include <linux/file.h>
	596	#ifdef HAVE_FDTABLE_HEADER
	597	#include <linux/fdtable.h>
	598	#endif
	599	],[
	600	struct files_struct *files = current->files;
	601	struct fdtable *fdt = files_fdtable(files);
	602	],[
	603	AC_MSG_RESULT(yes)
	604	AC_DEFINE(HAVE_FILES_FDTABLE, 1, [files_fdtable() is available])
	605	],[
	606	AC_MSG_RESULT(no)
	607	])
	608	])
	609
	610	dnl #
	611	dnl # 2.6.18 API change,
	612	dnl # added linux/uaccess.h
322640b7	613	dnl #
	614	AC_DEFUN([SPL_AC_UACCESS_HEADER], [
	615	SPL_CHECK_HEADER([linux/uaccess.h], [UACCESS], [], [])
	616	])
3d061e9d	617
	618	dnl #
	619	dnl # 2.6.12 API change,
	620	dnl # check whether 'kmalloc_node()' is available.
	621	dnl #
	622	AC_DEFUN([SPL_AC_KMALLOC_NODE], [
	623	AC_MSG_CHECKING([whether kmalloc_node() is available])
	624	SPL_LINUX_TRY_COMPILE([
	625	#include <linux/slab.h>
	626	],[
	627	void *a = kmalloc_node(1, GFP_KERNEL, 0);
	628	],[
	629	AC_MSG_RESULT(yes)
	630	AC_DEFINE(HAVE_KMALLOC_NODE, 1, [kmalloc_node() is available])
	631	],[
	632	AC_MSG_RESULT(no)
	633	])
	634	])
	635
	636	dnl #
	637	dnl # 2.6.9 API change,
	638	dnl # check whether 'monotonic_clock()' is available it may
	639	dnl # be available for some archs but not others.
	640	dnl #
	641	AC_DEFUN([SPL_AC_MONOTONIC_CLOCK], [
	642	SPL_CHECK_SYMBOL_EXPORT(
	643	[monotonic_clock],
	644	[],
	645	[AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1,
	646	[monotonic_clock() is available])],
	647	[])
	648	])
	649
	650	dnl #
	651	dnl # 2.6.16 API change,
	652	dnl # check whether 'struct inode' has i_mutex
	653	dnl #
	654	AC_DEFUN([SPL_AC_INODE_I_MUTEX], [
	655	AC_MSG_CHECKING([whether struct inode has i_mutex])
	656	SPL_LINUX_TRY_COMPILE([
	657	#include <linux/fs.h>
	658	#include <linux/mutex.h>
	659	],[
	660	struct inode i;
	661	mutex_init(&i.i_mutex);
	662	],[
	663	AC_MSG_RESULT(yes)
	664	AC_DEFINE(HAVE_INODE_I_MUTEX, 1, [struct inode has i_mutex])
	665	],[
	666	AC_MSG_RESULT(no)
	667	])
	668	])
b61a6e8b	669
	670	dnl #
	671	dnl # 2.6.14 API change,
	672	dnl # check whether 'div64_64()' is available
	673	dnl #
	674	AC_DEFUN([SPL_AC_DIV64_64], [
	675	AC_MSG_CHECKING([whether div64_64() is available])
	676	SPL_LINUX_TRY_COMPILE([
	677	#include <asm/div64.h>
	678	],[
	679	uint64_t i = div64_64(1ULL, 1ULL);
	680	],[
	681	AC_MSG_RESULT(yes)
	682	AC_DEFINE(HAVE_DIV64_64, 1, [div64_64() is available])
	683	],[
	684	AC_MSG_RESULT(no)
	685	])
	686	])