zfs/config/kernel-bdi.m4

   1 dnl #
   2 dnl # 2.6.32 - 2.6.33, bdi_setup_and_register() is not exported.
   3 dnl # 2.6.34 - 3.19, bdi_setup_and_register() takes 3 arguments.
   4 dnl # 4.0 - 4.11, bdi_setup_and_register() takes 2 arguments.
   5 dnl # 4.12 - x.y, super_setup_bdi_name() new interface.
   6 dnl #
   7 AC_DEFUN([ZFS_AC_KERNEL_BDI], [
   8         AC_MSG_CHECKING([whether super_setup_bdi_name() exists])
   9         ZFS_LINUX_TRY_COMPILE_SYMBOL([
  10                 #include <linux/fs.h>
  11                 struct super_block sb;
  12         ], [
  13                 char *name = "bdi";
  14                 int error __attribute__((unused)) =
  15                     super_setup_bdi_name(&sb, name);
  16         ], [super_setup_bdi_name], [fs/super.c], [
  17                 AC_MSG_RESULT(yes)
  18                 AC_DEFINE(HAVE_SUPER_SETUP_BDI_NAME, 1,
  19                     [super_setup_bdi_name() exits])
  20         ], [
  21                 AC_MSG_RESULT(no)
  22                 AC_MSG_CHECKING(
  23                     [whether bdi_setup_and_register() wants 2 args])
  24                 ZFS_LINUX_TRY_COMPILE_SYMBOL([
  25                         #include <linux/backing-dev.h>
  26                         struct backing_dev_info bdi;
  27                 ], [
  28                         char *name = "bdi";
  29                         int error __attribute__((unused)) =
  30                             bdi_setup_and_register(&bdi, name);
  31                 ], [bdi_setup_and_register], [mm/backing-dev.c], [
  32                         AC_MSG_RESULT(yes)
  33                         AC_DEFINE(HAVE_2ARGS_BDI_SETUP_AND_REGISTER, 1,
  34                             [bdi_setup_and_register() wants 2 args])
  35                 ], [
  36                         AC_MSG_RESULT(no)
  37                         AC_MSG_CHECKING(
  38                             [whether bdi_setup_and_register() wants 3 args])
  39                         ZFS_LINUX_TRY_COMPILE_SYMBOL([
  40                                 #include <linux/backing-dev.h>
  41                                 struct backing_dev_info bdi;
  42                         ], [
  43                                 char *name = "bdi";
  44                                 unsigned int cap = BDI_CAP_MAP_COPY;
  45                                 int error __attribute__((unused)) =
  46                                     bdi_setup_and_register(&bdi, name, cap);
  47                         ], [bdi_setup_and_register], [mm/backing-dev.c], [
  48                                 AC_MSG_RESULT(yes)
  49                                 AC_DEFINE(HAVE_3ARGS_BDI_SETUP_AND_REGISTER, 1,
  50                                     [bdi_setup_and_register() wants 3 args])
  51                         ], [
  52                                 AC_MSG_RESULT(no)
  53                         ])
  54                 ])
  55         ])
  56 ])