PMG/Statistic.pm

   1 package PMG::Statistic;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use Time::Local;
   7 use Time::Zone;
   8
   9 use PVE::SafeSyslog;
  10
  11 use PMG::ClusterConfig;
  12 use PMG::RuleDB;
  13
  14 sub new {
  15     my ($self, $start, $end, $advanced) = @_;
  16
  17     $self = {};
  18
  19     bless($self);
  20
  21     if (defined($start) && defined($end)) {
  22         $self->timespan($start, $end);
  23     } else {
  24         my $ctime = time();
  25         $self->timespan($ctime, $ctime - 24*3600);
  26     }
  27
  28     $self->{adv} = $advanced;
  29
  30     return $self;
  31 }
  32
  33 sub clear_stats {
  34     my ($dbh) = @_;
  35
  36     eval {
  37         $dbh->begin_work;
  38
  39         $dbh->do ("LOCK TABLE StatInfo");
  40         $dbh->do ("LOCK TABLE ClusterInfo");
  41
  42         $dbh->do ("DELETE FROM Statinfo");
  43         $dbh->do ("DELETE FROM DailyStat");
  44         $dbh->do ("DELETE FROM DomainStat");
  45         $dbh->do ("DELETE FROM VirusInfo");
  46         $dbh->do ("DELETE FROM ClusterInfo WHERE name = 'lastmt_DomainStat'");
  47         $dbh->do ("DELETE FROM ClusterInfo WHERE name = 'lastmt_DailyStat'");
  48         $dbh->do ("DELETE FROM ClusterInfo WHERE name = 'lastmt_VirusInfo'");
  49
  50         $dbh->commit;
  51     };
  52     if ($@) {
  53         $dbh->rollback;
  54         die $@;
  55     }
  56 }
  57
  58 sub update_stats_generic  {
  59     my ($dbh, $statinfoid, $select, $update, $insert) = @_;
  60
  61     my $todo = 0;
  62     my $maxentries = 100000;
  63
  64
  65     eval {
  66         $dbh->begin_work;
  67
  68         $dbh->do("LOCK TABLE StatInfo IN EXCLUSIVE MODE");
  69
  70         my $sth = $dbh->prepare("SELECT last_value FROM cstatistic_id_seq");
  71         $sth->execute();
  72         my $maxinfo = $sth->fetchrow_hashref();
  73         goto COMMIT if !$maxinfo;
  74         my $last_value = $maxinfo->{last_value};
  75         goto COMMIT if !defined ($last_value);
  76
  77         $sth = $dbh->prepare("SELECT ivalue as value FROM StatInfo WHERE NAME = '$statinfoid'");
  78         $sth->execute();
  79         my $statinfo = $sth->fetchrow_hashref();
  80
  81         my $startid = $statinfo ? $statinfo->{value} : 0;
  82         goto COMMIT if $startid > $last_value;
  83
  84         my $endid = $startid + $maxentries;
  85         $endid = $last_value + 1 if $endid > $last_value;
  86         $todo = $last_value + 1 - $endid;
  87
  88         my $timezone = tz_local_offset();;
  89
  90         $select =~ s/__timezone__/$timezone/g;
  91         $select =~ s/__startid__/$startid/g;
  92         $select =~ s/__endid__/$endid/g;
  93
  94         $sth = $dbh->prepare($select);
  95         $sth->execute();
  96
  97         my $cmd = "";
  98         #print "TEST:$last_value:$endid:$todo\n";
  99
 100         while (my $ref = $sth->fetchrow_hashref()) {
 101             if ($ref->{exists}) {
 102                 $cmd .= &$update($ref);
 103             } else {
 104                 $cmd .= &$insert($ref);
 105             }
 106         }
 107
 108         $dbh->do ($cmd) if $cmd;
 109
 110         $sth->finish();
 111
 112         if ($statinfo) {
 113             $dbh->do("UPDATE StatInfo SET ivalue = $endid WHERE NAME = '$statinfoid'");
 114         } else {
 115             $dbh->do("INSERT INTO StatInfo VALUES ('$statinfoid', $endid)");
 116         }
 117
 118       COMMIT:
 119         $dbh->commit;
 120     };
 121
 122     if ($@) {
 123         $dbh->rollback;
 124         die $@;
 125     }
 126
 127     return $todo;
 128 }
 129
 130 sub update_stats_dailystat  {
 131     my ($dbh, $cinfo) = @_;
 132
 133     my $role = $cinfo->{local}->{type} // '-';
 134     return 0 if !(($role eq '-') || ($role eq 'master'));
 135
 136     my $select = "SELECT sub.*, dailystat.time IS NOT NULL as exists FROM " .
 137         "(SELECT COUNT (CASE WHEN direction THEN 1 ELSE NULL END) as count_in, " .
 138         "COUNT (CASE WHEN NOT direction THEN 1 ELSE NULL END) as count_out, " .
 139         "SUM (CASE WHEN direction THEN bytes ELSE NULL END) / (1024.0*1024) as bytes_in, " .
 140         "SUM (CASE WHEN NOT direction THEN bytes ELSE NULL END) / (1024.0*1024) as bytes_out, " .
 141         "COUNT (CASE WHEN virusinfo IS NOT NULL AND direction THEN 1 ELSE NULL END) AS virus_in, " .
 142         "COUNT (CASE WHEN virusinfo IS NOT NULL AND NOT direction THEN 1 ELSE NULL END) AS virus_out, " .
 143         "COUNT (CASE WHEN virusinfo IS NULL AND direction AND ptime > 0 AND spamlevel >= 3 THEN 1 ELSE NULL END) as spam_in, " .
 144         "COUNT (CASE WHEN virusinfo IS NULL AND NOT direction AND ptime > 0 AND spamlevel >= 3 THEN 1 ELSE NULL END) as spam_out, " .
 145         "COUNT (CASE WHEN virusinfo IS NULL AND direction AND sender = '' THEN 1 ELSE NULL END) as bounces_in, " .
 146         "COUNT (CASE WHEN virusinfo IS NULL AND NOT direction AND sender = '' THEN 1 ELSE NULL END) as bounces_out, " .
 147         "COUNT (CASE WHEN virusinfo IS NULL AND ptime = 0 AND spamlevel = 5 THEN 1 ELSE NULL END) as glcount, " .
 148         "COUNT (CASE WHEN virusinfo IS NULL AND ptime = 0 AND spamlevel = 4 THEN 1 ELSE NULL END) as spfcount, " .
 149         "sum (cstatistic.ptime) / 1000.0 as ptimesum, " .
 150         "((cstatistic.time + __timezone__) / 3600) * 3600 as hour " .
 151         "from cstatistic where id >= __startid__ and id < __endid__ group by hour) as sub " .
 152         "left join dailystat on (sub.hour = dailystat.time)";
 153
 154     my $update = sub {
 155         my $ref = shift;
 156         my @values = ();
 157         my $sql = '';
 158
 159         push @values, "CountIn = CountIn + $ref->{count_in}" if $ref->{count_in};
 160         push @values, "CountOut = CountOut + $ref->{count_out}" if $ref->{count_out};
 161         push @values, "BytesIn = BytesIn + $ref->{bytes_in}" if $ref->{bytes_in};
 162         push @values, "BytesOut = BytesOut + $ref->{bytes_out}" if $ref->{bytes_out};
 163         push @values, "VirusIn = VirusIn + $ref->{virus_in}" if $ref->{virus_in};
 164         push @values, "VirusOut = VirusOut + $ref->{virus_out}" if $ref->{virus_out};
 165         push @values, "SpamIn = SpamIn + $ref->{spam_in}" if $ref->{spam_in};
 166         push @values, "SpamOut = SpamOut + $ref->{spam_out}" if $ref->{spam_out};
 167         push @values, "BouncesIn = BouncesIn + $ref->{bounces_in}" if $ref->{bounces_in};
 168         push @values, "BouncesOut = BouncesOut + $ref->{bounces_out}" if $ref->{bounces_out};
 169         push @values, "GreylistCount = GreylistCount + $ref->{glcount}" if $ref->{glcount};
 170         push @values, "SPFCount = SPFCount + $ref->{spfcount}" if $ref->{spfcount};
 171         push @values, "PTimeSum = PTimeSum + $ref->{ptimesum}" if $ref->{ptimesum};
 172         push @values, "MTime = EXTRACT(EPOCH FROM now())";
 173
 174         if (scalar (@values)) {
 175             $sql .= "UPDATE dailystat SET ";
 176             $sql .= join (',', @values);
 177             $sql .= " WHERE time = $ref->{hour};";
 178         }
 179         return $sql;
 180     };
 181
 182     my $insert = sub {
 183         my $ref = shift;
 184
 185         my $sql = "INSERT INTO dailystat " .
 186             "(Time,CountIn,CountOut,BytesIn,BytesOut,VirusIn,VirusOut,SpamIn,SpamOut," .
 187             "BouncesIn,BouncesOut,GreylistCount,SPFCount,RBLCount,PTimeSum,Mtime) " .
 188             "VALUES ($ref->{hour}," . ($ref->{count_in} || 0) . ',' . ($ref->{count_out} || 0) . ',' .
 189             ($ref->{bytes_in} || 0) . ',' . ($ref->{bytes_out} || 0) . ',' .
 190             ($ref->{virus_in} || 0) . ',' . ($ref->{virus_out} || 0) . ',' .
 191             ($ref->{spam_in} || 0) . ',' . ($ref->{spam_out} || 0) . ',' .
 192             ($ref->{bounces_in} || 0) . ',' . ($ref->{bounces_out} || 0) . ',' .
 193             ($ref->{glcount} || 0) . ',' . ($ref->{spfcount} || 0) . ',0,' . ($ref->{ptimesum} || 0) .
 194             ",EXTRACT(EPOCH FROM now()));";
 195
 196         return $sql;
 197     };
 198
 199     return update_stats_generic ($dbh, 'dailystat_index', $select, $update, $insert);
 200
 201 }
 202
 203 sub update_stats_domainstat_in  {
 204     my ($dbh, $cinfo) = @_;
 205
 206     my $role = $cinfo->{local}->{type} // '-';
 207     return 0 if !(($role eq '-') || ($role eq 'master'));
 208
 209     my $sub1 = "select distinct cstatistic_cid, cstatistic_rid, " .
 210         "lower(substring(receiver from position ('\@' in receiver) + 1)) as domain, " .
 211         "((cstatistic.time + __timezone__) / 86400) * 86400 as day " .
 212         "from CStatistic, CReceivers where cid = cstatistic_cid AND rid = cstatistic_rid AND " .
 213         "id >= __startid__ and id < __endid__ AND direction " .
 214         "group by cstatistic_cid, cstatistic_rid, day, domain";
 215
 216
 217     my $select = "SELECT sub.*, domainstat.time IS NOT NULL as exists FROM " .
 218         "(SELECT day, domain, COUNT (id) as count_in, SUM (bytes) / (1024.0*1024) as bytes_in, " .
 219         "COUNT (CASE WHEN virusinfo IS NOT NULL THEN 1 ELSE NULL END) AS virus_in, " .
 220         "COUNT (CASE WHEN virusinfo IS NULL AND spamlevel >= 3 THEN 1 ELSE NULL END) as spam_in, " .
 221         "COUNT (CASE WHEN virusinfo IS NULL AND sender = '' THEN 1 ELSE NULL END) as bounces_in, " .
 222         "sum (cstatistic.ptime) / 1000.0 as ptimesum " .
 223         "from cstatistic, ($sub1) as ddb " .
 224         "WHERE ddb.cstatistic_cid = cstatistic.cid AND ddb.cstatistic_rid = cstatistic.rid GROUP BY day, domain) as sub " .
 225         "left join domainstat on (day = domainstat.time and sub.domain = domainstat.domain)";
 226
 227     my $update = sub {
 228         my $ref = shift;
 229         my @values = ();
 230         my $sql = '';
 231
 232         push @values, "CountIn = CountIn + $ref->{count_in}" if $ref->{count_in};
 233         push @values, "BytesIn = BytesIn + $ref->{bytes_in}" if $ref->{bytes_in};
 234         push @values, "VirusIn = VirusIn + $ref->{virus_in}" if $ref->{virus_in};
 235         push @values, "SpamIn = SpamIn + $ref->{spam_in}" if $ref->{spam_in};
 236         push @values, "BouncesIn = BouncesIn + $ref->{bounces_in}" if $ref->{bounces_in};
 237         push @values, "PTimeSum = PTimeSum + $ref->{ptimesum}" if $ref->{ptimesum};
 238         push @values, "MTime = EXTRACT(EPOCH FROM now())";
 239
 240         if (scalar (@values)) {
 241             $sql .= "UPDATE domainstat SET ";
 242             $sql .= join (',', @values);
 243             $sql .= " WHERE time = $ref->{day} and domain = " . $dbh->quote($ref->{domain}) . ';';
 244         }
 245         return $sql;
 246     };
 247
 248     my $insert = sub {
 249         my $ref = shift;
 250
 251         my $sql .= "INSERT INTO domainstat values ($ref->{day}, " .  $dbh->quote($ref->{domain}) . ',' .
 252                     ($ref->{count_in} || 0) . ',0,' .
 253                     ($ref->{bytes_in} || 0) . ',0,' .
 254                     ($ref->{virus_in} || 0) . ',0,' .
 255                     ($ref->{spam_in} || 0) . ',0,' .
 256                     ($ref->{bounces_in} || 0) . ',0,' .
 257                     ($ref->{ptimesum} || 0) .
 258                     ",EXTRACT(EPOCH FROM now()));";
 259
 260         return $sql;
 261     };
 262
 263     update_stats_generic ($dbh, 'domainstat_in_index', $select, $update, $insert);
 264
 265 }
 266
 267 sub update_stats_domainstat_out  {
 268     my ($dbh, $cinfo) = @_;
 269
 270     my $role = $cinfo->{local}->{type} // '-';
 271     return 0 if !(($role eq '-') || ($role eq 'master'));
 272
 273     my $select = "SELECT sub.*, domainstat.time IS NOT NULL as exists FROM " .
 274         "(SELECT COUNT (ID) as count_out, SUM (bytes) / (1024.0*1024) as bytes_out, " .
 275         "COUNT (CASE WHEN virusinfo IS NOT NULL THEN 1 ELSE NULL END) AS virus_out, " .
 276         "COUNT (CASE WHEN virusinfo IS NULL AND spamlevel >= 3 THEN 1 ELSE NULL END) as spam_out, " .
 277         "COUNT (CASE WHEN virusinfo IS NULL AND sender = '' THEN 1 ELSE NULL END) as bounces_out, " .
 278         "sum (cstatistic.ptime) / 1000.0 as ptimesum, " .
 279         "((cstatistic.time + __timezone__) / 86400) * 86400 as day, " .
 280         "lower(substring(sender from position ('\@' in sender) + 1)) as domain " .
 281         "from cstatistic where id >= __startid__ and id < __endid__ and not direction " .
 282         "group by day, domain) as sub " .
 283         "left join domainstat on (day = domainstat.time and sub.domain = domainstat.domain)";
 284
 285     my $update = sub {
 286         my $ref = shift;
 287         my @values = ();
 288         my $sql = '';
 289
 290         push @values, "CountOut = CountOut + $ref->{count_out}" if $ref->{count_out};
 291         push @values, "BytesOut = BytesOut + $ref->{bytes_out}" if $ref->{bytes_out};
 292         push @values, "VirusOut = VirusOut + $ref->{virus_out}" if $ref->{virus_out};
 293         push @values, "SpamOut = SpamOut + $ref->{spam_out}" if $ref->{spam_out};
 294         push @values, "BouncesOut = BouncesOut + $ref->{bounces_out}" if $ref->{bounces_out};
 295         push @values, "PTimeSum = PTimeSum + $ref->{ptimesum}" if $ref->{ptimesum};
 296         push @values, "MTime = EXTRACT(EPOCH FROM now())";
 297
 298         if (scalar (@values)) {
 299             $sql .= "UPDATE domainstat SET ";
 300             $sql .= join (',', @values);
 301             $sql .= " WHERE time = $ref->{day} and domain = " . $dbh->quote($ref->{domain}) . ';';
 302         }
 303         return $sql;
 304     };
 305
 306     my $insert = sub {
 307         my $ref = shift;
 308
 309         my $sql .= "INSERT INTO domainstat values ($ref->{day}, " .  $dbh->quote($ref->{domain}) .
 310             ',0,' . ($ref->{count_out} || 0) .
 311             ',0,' . ($ref->{bytes_out} || 0) .
 312             ',0,' . ($ref->{virus_out} || 0) .
 313             ',0,' . ($ref->{spam_out} || 0) .
 314             ',0,' . ($ref->{bounces_out} || 0) .
 315             ','. ($ref->{ptimesum} || 0) .
 316             ",EXTRACT(EPOCH FROM now()));";
 317
 318         return $sql;
 319     };
 320
 321     update_stats_generic ($dbh, 'domainstat_out_index', $select, $update, $insert);
 322
 323 }
 324
 325 sub update_stats_virusinfo  {
 326     my ($dbh, $cinfo) = @_;
 327
 328     my $role = $cinfo->{local}->{type} // '-';
 329     return 0 if !(($role eq '-') || ($role eq 'master'));
 330
 331     my $select = "SELECT sub.*, virusinfo.time IS NOT NULL as exists FROM " .
 332         "(SELECT ((cstatistic.time + __timezone__) / 86400) * 86400 as day, " .
 333         "count (virusinfo) as count, virusinfo AS name " .
 334         "FROM cstatistic WHERE id >= __startid__ AND id < __endid__ AND virusinfo IS NOT NULL " .
 335         "group by day, name) as sub " .
 336         "left join VirusInfo on (day = virusinfo.time and sub.name = virusinfo.name)";
 337
 338     my $update = sub {
 339         my $ref = shift;
 340         my @values = ();
 341         my $sql = '';
 342
 343         push @values, "Count = Count + $ref->{count}" if $ref->{count};
 344         push @values, "MTime = EXTRACT(EPOCH FROM now())";
 345
 346         if (scalar (@values)) {
 347             $sql .= "UPDATE VirusInfo SET ";
 348             $sql .= join (',', @values);
 349             $sql .= " WHERE time = $ref->{day} and Name = " . $dbh->quote($ref->{name}) . ';';
 350         }
 351         return $sql;
 352     };
 353
 354     my $insert = sub {
 355         my $ref = shift;
 356
 357         my $sql .= "INSERT INTO VirusInfo values ($ref->{day}, " .  $dbh->quote($ref->{name}) .
 358             ',' . ($ref->{count} || 0) .
 359             ",EXTRACT(EPOCH FROM now()));";
 360
 361         return $sql;
 362     };
 363
 364     update_stats_generic ($dbh, 'virusinfo_index', $select, $update, $insert);
 365
 366 }
 367
 368
 369 sub update_stats  {
 370     my ($dbh, $cinfo) = @_;
 371
 372     while (update_stats_dailystat ($dbh, $cinfo) > 0) {};
 373     while (update_stats_domainstat_in ($dbh, $cinfo) > 0) {};
 374     while (update_stats_domainstat_out ($dbh, $cinfo) > 0) {};
 375     while (update_stats_virusinfo ($dbh, $cinfo) > 0) {};
 376 }
 377
 378 sub total_mail_stat {
 379     my ($self, $rdb) = @_;
 380
 381     my ($from, $to) = $self->localdayspan();
 382
 383     my ($sth, $ref);
 384     my $glcount = 0;
 385
 386 #    this is to slow for high volume sites
 387 #    $sth = $rdb->{dbh}->prepare("SELECT COUNT(DISTINCT Instance) AS GL FROM CGreylist " .
 388 #                               "WHERE passed = 0 AND rctime >= ? AND rctime < ? ");
 389 #    $sth->execute($from, $to);
 390 #    $ref = $sth->fetchrow_hashref();
 391 #    $glcount = $ref->{gl};
 392
 393     my $cmds = "SELECT sum(CountIn) + $glcount AS count_in, sum(CountOut) AS count_out, " .
 394         "sum (VirusIn) AS viruscount_in, sum (VirusOut) AS viruscount_out, " .
 395         "sum (SpamIn) AS spamcount_in, sum (SpamOut) AS spamcount_out, " .
 396         "sum (BytesIn) AS bytes_in, sum (BytesOut) AS bytes_out, " .
 397         "sum (BouncesIn) AS bounces_in, sum (BouncesOut) AS bounces_out, " .
 398         "sum (GreylistCount) + $glcount as glcount, " .
 399         "sum (SPFCount) as spfcount, " .
 400         "sum (RBLCount) as rblcount, " .
 401         "sum(PTimeSum)/(sum(CountIn) + $glcount + sum(CountOut)) AS avptime " .
 402         "FROM DailyStat where time >= $from and time < $to";
 403
 404     $sth = $rdb->{dbh}->prepare($cmds);
 405     $sth->execute();
 406     $ref = $sth->fetchrow_hashref();
 407     $sth->finish();
 408
 409     foreach my $k (keys %$ref) { $ref->{$k} += 0; } # convert to numbers
 410
 411     if (!$ref->{avptime}) {
 412         $ref->{count_in} = $ref->{count_out} = $ref->{viruscount_in} = $ref->{viruscount_out} =
 413             $ref->{spamcount_in} = $ref->{spamcount_out} = $ref->{glcount} = $ref->{spfcount} =
 414             $ref->{rblcount} = $ref->{bounces_in} = $ref->{bounces_out} = $ref->{bytes_in} =
 415             $ref->{bytes_out} = $ref->{avptime} = 0;
 416     }
 417
 418     $ref->{count} = $ref->{count_in} + $ref->{count_out};
 419
 420     $ref->{junk_in} = $ref->{viruscount_in} + $ref->{spamcount_in} + $ref->{glcount} +
 421         $ref->{spfcount} + $ref->{rblcount};
 422
 423     $ref->{junk_out} = $ref->{viruscount_out} + $ref->{spamcount_out};
 424
 425     return $ref;
 426 }
 427
 428 sub total_spam_stat {
 429     my ($self, $rdb) = @_;
 430     my ($from, $to) = $self->timespan();
 431
 432     my $sth = $rdb->{dbh}->prepare("SELECT spamlevel, COUNT(spamlevel) AS count FROM CStatistic " .
 433                                    "WHERE virusinfo IS NULL and time >= ? AND time < ? AND ptime > 0 AND spamlevel > 0 " .
 434                                    "GROUP BY spamlevel ORDER BY spamlevel LIMIT 10");
 435     $sth->execute($from, $to);
 436
 437     my $res = $sth->fetchall_arrayref({});
 438
 439     $sth->finish();
 440
 441     return $res;
 442 }
 443
 444 sub total_virus_stat {
 445     my ($self, $rdb, $order) = @_;
 446
 447     my ($from, $to) = $self->localdayspan();
 448
 449     $order = "count" if !$order;
 450
 451     my @oa = split (',', $order);
 452
 453     $order = join (' DESC, ', @oa);
 454     $order .= ' DESC';
 455
 456     my $sth = $rdb->{dbh}->prepare("SELECT Name, SUM (Count) as count FROM VirusInfo " .
 457                                    "WHERE time >= ? AND time < ? " .
 458                                    "GROUP BY name ORDER BY $order, name");
 459
 460     $sth->execute($from, $to);
 461
 462     my $res = $sth->fetchall_arrayref({});
 463
 464     $sth->finish();
 465
 466     return $res;
 467 }
 468
 469 sub rule_count {
 470     my ($self, $rdb) = @_;
 471
 472     my $sth = $rdb->{dbh}->prepare("SELECT id, name, count from rule order by count desc, name");
 473     $sth->execute();
 474
 475     my $res = $sth->fetchall_arrayref({});
 476     $sth->finish();
 477
 478     return $res;
 479 }
 480
 481 sub total_domain_stat {
 482     my ($self, $rdb, $orderby) = @_;
 483
 484     $orderby || ($orderby = 'domain');
 485     my $sortdir = sort_dir ($orderby);
 486
 487     my ($from, $to) = $self->localdayspan();
 488
 489     my $query = "SELECT domain, SUM (CountIn) AS count_in, SUM (CountOut) AS count_out," .
 490         "SUM (BytesIn) AS mbytes_in, SUM (BytesOut) AS mbytes_out, " .
 491         "SUM (VirusIn) AS viruscount_in, SUM (VirusOut) AS viruscount_out," .
 492         "SUM (SpamIn) as spamcount_in, SUM (SpamOut) as spamcount_out " .
 493         "FROM DomainStat where time >= $from AND time < $to " .
 494         "GROUP BY domain ORDER BY $orderby $sortdir, domain ASC";
 495
 496     my $sth = $rdb->{dbh}->prepare($query);
 497     $sth->execute();
 498
 499     my $res = $sth->fetchall_arrayref({});
 500
 501     $sth->finish();
 502
 503     return $res;
 504 }
 505
 506 sub clear_rule_count {
 507     my ($self, $rdb, $id) = @_;
 508
 509     if (defined($id)) {
 510         $rdb->{dbh}->do ("UPDATE rule set count = 0 where id = ?", undef, $id);
 511     } else {
 512         $rdb->{dbh}->do("UPDATE rule set count = 0");
 513     }
 514 }
 515
 516 sub query_cond_good_mail {
 517     my ($self, $from, $to) = @_;
 518     return "time >= $from AND time < $to AND bytes > 0 AND sender IS NOT NULL";
 519 }
 520
 521 sub query_active_workers {
 522     my ($self) = @_;
 523     my ($from, $to) = $self->timespan();
 524
 525     my $start = $from - (3600*24)*90; # from - 90 days
 526     my $cond_good_mail = $self->query_cond_good_mail ($start, $to);
 527
 528     return "SELECT DISTINCT sender as worker FROM CStatistic WHERE $cond_good_mail AND NOT direction";
 529 }
 530
 531 sub sort_dir {
 532     my ($orderby) = @_;
 533
 534     my $sortdir = ($orderby eq "virusinfo" || $orderby eq 'sender' || $orderby eq 'domain' || $orderby eq 'receiver') ? 'ASC' : 'DESC';
 535
 536     return $sortdir;
 537 }
 538
 539 my $compute_sql_orderby = sub {
 540     my ($sorters, $sort_default, $sort_always_prop) = @_;
 541
 542     my $has_default_sort;
 543
 544     my $orderby = '';
 545
 546     foreach my $obj (@$sorters) {
 547         $has_default_sort = 1 if $obj->{property} eq $sort_always_prop;
 548         $orderby .= ', ' if $orderby;
 549         $orderby .= "$obj->{property} $obj->{direction}"
 550     }
 551
 552     $orderby .= $sort_default if !$orderby;
 553
 554     $orderby .= ", $sort_always_prop" if !$has_default_sort;
 555
 556     return $orderby;
 557 };
 558
 559 sub user_stat_contact_details {
 560     my ($self, $rdb, $receiver, $limit, $sorters, $filter) = @_;
 561
 562     my ($from, $to) = $self->timespan();
 563
 564     my $orderby = $compute_sql_orderby->($sorters, 'time ASC', 'sender');
 565
 566     my $cond_good_mail = $self->query_cond_good_mail ($from, $to);
 567
 568     my $query = "SELECT * FROM CStatistic, CReceivers " .
 569         "WHERE cid = cstatistic_cid AND rid = cstatistic_rid AND $cond_good_mail " .
 570         "AND NOT direction AND sender != '' AND receiver = ? " .
 571         ($filter ? "AND sender like " . $rdb->{dbh}->quote("%${filter}%") . ' ' : '') .
 572         "ORDER BY $orderby limit $limit";
 573
 574     my $sth = $rdb->{dbh}->prepare($query);
 575
 576     $sth->execute($receiver);
 577
 578     my $res = [];
 579     while (my $ref = $sth->fetchrow_hashref()) {
 580         push @$res, $ref;
 581     }
 582
 583     $sth->finish();
 584
 585     return $res;
 586 }
 587
 588 sub user_stat_contact {
 589     my ($self, $rdb, $limit, $sorters, $filter) = @_;
 590
 591     my ($from, $to) = $self->timespan();
 592
 593     my $orderby = $compute_sql_orderby->($sorters, 'count DESC', 'contact');
 594
 595     my $cond_good_mail = $self->query_cond_good_mail($from, $to);
 596
 597     my $query = "SELECT receiver as contact, count(*) AS count, sum (bytes) AS bytes, " .
 598         "count (virusinfo) as viruscount " .
 599         "FROM CStatistic, CReceivers " .
 600         "WHERE cid = cstatistic_cid AND rid = cstatistic_rid " .
 601         ($filter ? "AND receiver like " . $rdb->{dbh}->quote("%${filter}%") . ' ' : '') .
 602         "AND $cond_good_mail AND NOT direction AND sender != '' ";
 603
 604     if ($self->{adv}) {
 605         my $active_workers = $self->query_active_workers ();
 606
 607         $query .= "AND receiver NOT IN ($active_workers) ";
 608     }
 609
 610     $query .="GROUP BY contact ORDER BY $orderby limit $limit";
 611     my $sth = $rdb->{dbh}->prepare($query);
 612
 613     $sth->execute();
 614
 615     my $res = [];
 616     while (my $ref = $sth->fetchrow_hashref()) {
 617         push @$res, $ref;
 618     }
 619
 620     $sth->finish();
 621
 622     return $res;
 623 }
 624
 625 sub user_stat_sender_details {
 626     my ($self, $rdb, $sender, $limit, $sorters, $filter) = @_;
 627
 628     my ($from, $to) = $self->timespan();
 629
 630     my $orderby = $compute_sql_orderby->($sorters, 'time ASC', 'receiver');
 631
 632     my $cond_good_mail = $self->query_cond_good_mail($from, $to);
 633
 634     my $sth = $rdb->{dbh}->prepare(
 635         "SELECT " .
 636         "blocked, bytes, ptime, sender, receiver, spamlevel, time, virusinfo " .
 637         "FROM CStatistic, CReceivers " .
 638         "WHERE cid = cstatistic_cid AND rid = cstatistic_rid AND " .
 639         "$cond_good_mail AND NOT direction AND sender = ? " .
 640         ($filter ? "AND receiver like " . $rdb->{dbh}->quote("%${filter}%") . ' ' : '') .
 641         "ORDER BY $orderby limit $limit");
 642
 643     $sth->execute($sender);
 644
 645     my $res = [];
 646     while (my $ref = $sth->fetchrow_hashref()) {
 647         push @$res, $ref;
 648     }
 649
 650     $sth->finish();
 651
 652     return $res;
 653 }
 654
 655 sub user_stat_sender {
 656     my ($self, $rdb, $limit, $sorters, $filter) = @_;
 657
 658     my ($from, $to) = $self->timespan();
 659
 660     my $orderby = $compute_sql_orderby->($sorters, 'count DESC', 'sender');
 661
 662     my $cond_good_mail = $self->query_cond_good_mail ($from, $to);
 663
 664     my $query = "SELECT sender,count(*) AS count, sum (bytes) AS bytes, " .
 665         "count (virusinfo) as viruscount, " .
 666         "count (CASE WHEN spamlevel >= 3 THEN 1 ELSE NULL END) as spamcount " .
 667         "FROM CStatistic WHERE $cond_good_mail AND NOT direction AND sender != '' " .
 668         ($filter ? "AND sender like " . $rdb->{dbh}->quote("%${filter}%") . ' ' : '') .
 669         "GROUP BY sender ORDER BY $orderby limit $limit";
 670
 671     my $sth = $rdb->{dbh}->prepare($query);
 672     $sth->execute();
 673
 674     my $res = [];
 675     while (my $ref = $sth->fetchrow_hashref()) {
 676         push @$res, $ref;
 677     }
 678
 679     $sth->finish();
 680
 681     return $res;
 682 }
 683
 684 sub user_stat_receiver_details {
 685     my ($self, $rdb, $receiver, $limit, $sorters, $filter) = @_;
 686
 687     my ($from, $to) = $self->timespan();
 688
 689     my $orderby = $compute_sql_orderby->($sorters, 'time ASC', 'sender');
 690
 691     my $cond_good_mail = $self->query_cond_good_mail($from, $to);
 692
 693     my $sth = $rdb->{dbh}->prepare(
 694         "SELECT blocked, bytes, ptime, sender, receiver, spamlevel, time, virusinfo " .
 695         "FROM CStatistic, CReceivers " .
 696         "WHERE cid = cstatistic_cid AND rid = cstatistic_rid AND $cond_good_mail AND receiver = ? " .
 697         ($filter ? "AND sender like " . $rdb->{dbh}->quote("%${filter}%") . ' ' : '') .
 698         "ORDER BY $orderby limit $limit");
 699
 700     $sth->execute($receiver);
 701
 702     my $res = [];
 703     while (my $ref = $sth->fetchrow_hashref()) {
 704         push @$res, $ref;
 705     }
 706
 707     $sth->finish();
 708
 709     return $res;
 710 }
 711
 712 sub user_stat_receiver {
 713     my ($self, $rdb, $limit, $sorters, $filter) = @_;
 714
 715     my ($from, $to) = $self->timespan();
 716
 717     my $orderby = $compute_sql_orderby->($sorters, 'count DESC', 'receiver');
 718
 719     my $cond_good_mail = $self->query_cond_good_mail ($from, $to) . " AND " .
 720         "receiver IS NOT NULL AND receiver != ''";
 721
 722     my $query = "SELECT receiver, " .
 723         "count(*) AS count, " .
 724         "sum (bytes) AS bytes, " .
 725         "count (virusinfo) as viruscount, " .
 726         "count (CASE WHEN spamlevel >= 3 THEN 1 ELSE NULL END) as spamcount ";
 727
 728     if ($self->{adv}) {
 729         my $active_workers = $self->query_active_workers ();
 730
 731         $query .= "FROM CStatistic, CReceivers, ($active_workers) as workers ";
 732
 733         $query .= "WHERE cid = cstatistic_cid AND rid = cstatistic_rid AND worker=receiver ";
 734
 735     } else {
 736         $query .= "FROM CStatistic, CReceivers ";
 737
 738         $query .= "WHERE cid = cstatistic_cid AND rid = cstatistic_rid ";
 739     }
 740
 741     $query .= "AND $cond_good_mail and direction " .
 742         ($filter ? "AND receiver like " . $rdb->{dbh}->quote("%${filter}%") . ' ' : '') .
 743         "GROUP BY receiver ORDER BY $orderby LIMIT $limit";
 744
 745     my $sth = $rdb->{dbh}->prepare($query);
 746     $sth->execute();
 747
 748     my $res = [];
 749     while (my $ref = $sth->fetchrow_hashref()) {
 750         push @$res, $ref;
 751     }
 752
 753     $sth->finish();
 754
 755     return $res;
 756 }
 757
 758 sub traffic_stat_graph {
 759     my ($self, $rdb, $span) = @_;
 760     my $res;
 761
 762     my ($from, $to) = $self->localhourspan();
 763     my $timezone = tz_local_offset();;
 764
 765     my $cmd = "SELECT " .
 766         "(time - $from) / $span AS index, " .
 767         "sum(CountIn) as count_in, sum(CountOut) as count_out, " .
 768         "sum(VirusIn) as viruscount_in, sum (VirusOut) as viruscount_out, " .
 769         "sum(SpamIn) + sum (GreylistCount) + sum (SPFCount) + sum (RBLCount) as spamcount_in, " .
 770         "sum(SpamOut) as spamcount_out, " .
 771         "sum(BouncesIn) as bounces_in, " .
 772         "sum(BouncesOut) as bounces_out " .
 773         "FROM DailyStat WHERE time >= $from AND time < $to " .
 774         "GROUP BY index ORDER BY index";
 775
 776     my $sth =  $rdb->{dbh}->prepare($cmd);
 777
 778     $sth->execute ();
 779
 780     while (my $ref = $sth->fetchrow_hashref()) {
 781         @$res[$ref->{index}] = $ref;
 782     }
 783
 784     my $c = int (($to - $from) / $span);
 785
 786     for (my $i = 0; $i < $c; $i++) {
 787         @$res[$i] //= {
 788             index => $i,
 789             count => 0, count_in => 0, count_out => 0,
 790             spamcount_in => 0, spamcount_out => 0,
 791             viruscount_in => 0, viruscount_out => 0,
 792             bounces_in => 0, bounces_out => 0 };
 793
 794         my $d = @$res[$i];
 795
 796         $d->{time} = $from + ($i+1)*$span - $timezone;
 797         $d->{count} = $d->{count_in} + $d->{count_out};
 798     }
 799     $sth->finish();
 800
 801     return $res;
 802 }
 803
 804 sub traffic_stat_day_dist {
 805     my ($self, $rdb) = @_;
 806     my $res;
 807
 808     my ($from, $to) = $self->localhourspan();
 809
 810     my $cmd = "SELECT " .
 811         "((time - $from) / 3600) % 24 AS index, " .
 812         "sum(CountIn) as count_in, sum(CountOut) as count_out, " .
 813         "sum(VirusIn) as viruscount_in, sum (VirusOut) as viruscount_out, " .
 814         "sum(SpamIn) + sum (GreylistCount) + sum (SPFCount) + sum (RBLCount) as spamcount_in, " .
 815         "sum(SpamOut) as spamcount_out, " .
 816         "sum(BouncesIn) as bounces_in, sum(BouncesOut) as bounces_out " .
 817         "FROM DailyStat WHERE time >= $from AND time < $to " .
 818         "GROUP BY index ORDER BY index";
 819
 820     my $sth =  $rdb->{dbh}->prepare($cmd);
 821
 822     $sth->execute ();
 823
 824     while (my $ref = $sth->fetchrow_hashref()) {
 825         @$res[$ref->{index}] = $ref;
 826     }
 827
 828     for (my $i = 0; $i < 24; $i++) {
 829         @$res[$i] //= {
 830             index => $i,
 831             count => 0, count_in => 0, count_out => 0,
 832             spamcount_in => 0, spamcount_out => 0,
 833             viruscount_in => 0, viruscount_out => 0,
 834             bounces_in => 0, bounces_out => 0 };
 835
 836         my $d = @$res[$i];
 837         $d->{count} = $d->{count_in} + $d->{count_out};
 838     }
 839     $sth->finish();
 840
 841     return $res;
 842 }
 843
 844 sub timespan {
 845     my ($self, $from, $to) = @_;
 846
 847     if (defined ($from) && defined ($to)) {
 848         $self->{from} = $from;
 849         $self->{to} = $to;
 850     }
 851
 852     return ($self->{from}, $self->{to});
 853 }
 854
 855 sub localdayspan {
 856     my ($self) = @_;
 857
 858     my ($from, $to) = $self->timespan();
 859
 860     my $timezone = tz_local_offset();;
 861     $from = (($from + $timezone)/86400) * 86400;
 862     $to = (($to + $timezone)/86400) * 86400;
 863
 864     $to += 86400 if $from == $to;
 865
 866     return ($from, $to);
 867 }
 868
 869 sub localhourspan {
 870     my ($self) = @_;
 871
 872     my ($from, $to) = $self->timespan();
 873
 874     my $timezone = tz_local_offset();;
 875     $from = (($from + $timezone)/3600) * 3600;
 876     $to = (($to + $timezone)/3600) * 3600;
 877
 878     $to += 3600 if $from == $to;
 879
 880     return ($from, $to);
 881 }
 882
 883
 884 1;