PMG/Utils.pm

   1 package PMG::Utils;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use Net::Cmd;
   7 use Net::SMTP;
   8 use IO::File;
   9 use File::stat;
  10 use POSIX qw(strftime);
  11 use File::stat;
  12 use File::Basename;
  13 use MIME::Words;
  14 use MIME::Parser;
  15 use Time::HiRes qw (gettimeofday);
  16 use Xdgmime;
  17 use Data::Dumper;
  18 use Digest::SHA;
  19 use Net::IP;
  20 use Socket;
  21 use RRDs;
  22 use Filesys::Df;
  23 use Encode;
  24
  25 use PVE::ProcFSTools;
  26 use PVE::Network;
  27 use PVE::Tools;
  28 use PVE::SafeSyslog;
  29 use PVE::ProcFSTools;
  30 use PMG::AtomicFile;
  31 use PMG::MailQueue;
  32 use PMG::SMTPPrinter;
  33
  34 my $realm_regex = qr/[A-Za-z][A-Za-z0-9\.\-_]+/;
  35
  36 PVE::JSONSchema::register_format('pmg-realm', \&verify_realm);
  37 sub verify_realm {
  38     my ($realm, $noerr) = @_;
  39
  40     if ($realm !~ m/^${realm_regex}$/) {
  41         return undef if $noerr;
  42         die "value does not look like a valid realm\n";
  43     }
  44     return $realm;
  45 }
  46
  47 PVE::JSONSchema::register_standard_option('realm', {
  48     description => "Authentication domain ID",
  49     type => 'string', format => 'pmg-realm',
  50     maxLength => 32,
  51 });
  52
  53 PVE::JSONSchema::register_format('pmg-userid', \&verify_username);
  54 sub verify_username {
  55     my ($username, $noerr) = @_;
  56
  57     $username = '' if !$username;
  58     my $len = length($username);
  59     if ($len < 3) {
  60         die "user name '$username' is too short\n" if !$noerr;
  61         return undef;
  62     }
  63     if ($len > 64) {
  64         die "user name '$username' is too long ($len > 64)\n" if !$noerr;
  65         return undef;
  66     }
  67
  68     # we only allow a limited set of characters
  69     # colon is not allowed, because we store usernames in
  70     # colon separated lists)!
  71     # slash is not allowed because it is used as pve API delimiter
  72     # also see "man useradd"
  73     if ($username =~ m!^([^\s:/]+)\@(${realm_regex})$!) {
  74         return wantarray ? ($username, $1, $2) : $username;
  75     }
  76
  77     die "value '$username' does not look like a valid user name\n" if !$noerr;
  78
  79     return undef;
  80 }
  81
  82 PVE::JSONSchema::register_standard_option('userid', {
  83     description => "User ID",
  84     type => 'string', format => 'pmg-userid',
  85     minLength => 4,
  86     maxLength => 64,
  87 });
  88
  89 PVE::JSONSchema::register_standard_option('username', {
  90     description => "Username (without realm)",
  91     type => 'string',
  92     pattern => '[^\s:\/\@]{3,60}',
  93     minLength => 4,
  94     maxLength => 64,
  95 });
  96
  97 sub msgquote {
  98     my $msg = shift || '';
  99     $msg =~ s/%/%%/g;
 100     return $msg;
 101 }
 102
 103 sub lastid {
 104     my ($dbh, $seq) = @_;
 105
 106     return $dbh->last_insert_id(
 107         undef, undef, undef, undef, { sequence => $seq});
 108 }
 109
 110 sub file_older_than {
 111     my ($filename, $lasttime) = @_;
 112
 113     my $st = stat($filename);
 114
 115     return 0 if !defined($st);
 116
 117     return ($lasttime >= $st->ctime);
 118 }
 119
 120 sub extract_filename {
 121     my ($head) = @_;
 122
 123     if (my $value = $head->recommended_filename()) {
 124         chomp $value;
 125         if (my $decvalue = MIME::Words::decode_mimewords($value)) {
 126             $decvalue =~ s/\0/ /g;
 127             $decvalue = PVE::Tools::trim($decvalue);
 128             return $decvalue;
 129         }
 130     }
 131
 132     return undef;
 133 }
 134
 135 sub remove_marks {
 136     my ($entity, $add_id, $id) = @_;
 137
 138     $id //= 1;
 139
 140     foreach my $tag (grep {/^x-proxmox-tmp/i} $entity->head->tags) {
 141         $entity->head->delete ($tag);
 142     }
 143
 144     $entity->head->replace('X-Proxmox-tmp-AID', $id) if $add_id;
 145
 146     foreach my $part ($entity->parts)  {
 147         $id = remove_marks($part, $add_id, $id + 1);
 148     }
 149
 150     return $id;
 151 }
 152
 153 sub subst_values {
 154     my ($body, $dh) = @_;
 155
 156     return if !$body;
 157
 158     foreach my $k (keys %$dh) {
 159         my $v = $dh->{$k};
 160         if (defined($v)) {
 161             $body =~ s/__\Q${k}\E__/$v/gs;
 162         }
 163     }
 164
 165     return $body;
 166 }
 167
 168 sub reinject_mail {
 169     my ($entity, $sender, $targets, $xforward, $me, $nodsn) = @_;
 170
 171     my $smtp;
 172     my $resid;
 173     my $rescode;
 174     my $resmess;
 175
 176     eval {
 177         my $smtp = Net::SMTP->new('127.0.0.1', Port => 10025, Hello => $me) ||
 178             die "unable to connect to localhost at port 10025";
 179
 180         if (defined($xforward)) {
 181             my $xfwd;
 182
 183             foreach my $attr (keys %{$xforward}) {
 184                 $xfwd .= " $attr=$xforward->{$attr}";
 185             }
 186
 187             if ($xfwd && $smtp->command("XFORWARD", $xfwd)->response() != CMD_OK) {
 188                 syslog('err', "xforward error - got: %s %s", $smtp->code, scalar($smtp->message));
 189             }
 190         }
 191
 192         if (!$smtp->mail($sender)) {
 193             syslog('err', "smtp error - got: %s %s", $smtp->code, scalar ($smtp->message));
 194             die "smtp from: ERROR";
 195         }
 196
 197         my $dsnopts = $nodsn ? {Notify => ['NEVER']} : {};
 198
 199         if (!$smtp->to (@$targets, $dsnopts)) {
 200             syslog ('err', "smtp error - got: %s %s", $smtp->code, scalar($smtp->message));
 201             die "smtp to: ERROR";
 202         }
 203
 204         # Output the head:
 205         #$entity->sync_headers ();
 206         $smtp->data();
 207
 208         my $out = PMG::SMTPPrinter->new($smtp);
 209         $entity->print($out);
 210
 211         # make sure we always have a newline at the end of the mail
 212         # else dataend() fails
 213         $smtp->datasend("\n");
 214
 215         if ($smtp->dataend()) {
 216             my @msgs = $smtp->message;
 217             $resmess = $msgs[$#msgs];
 218             ($resid) = $resmess =~ m/Ok: queued as ([0-9A-Z]+)/;
 219             $rescode = $smtp->code;
 220             if (!$resid) {
 221                 die sprintf("unexpected SMTP result - got: %s %s : WARNING", $smtp->code, $resmess);
 222             }
 223         } else {
 224             my @msgs = $smtp->message;
 225             $resmess = $msgs[$#msgs];
 226             $rescode = $smtp->code;
 227             die sprintf("sending data failed - got: %s %s : ERROR", $smtp->code, $resmess);
 228         }
 229     };
 230     my $err = $@;
 231
 232     $smtp->quit if $smtp;
 233
 234     if ($err) {
 235         syslog ('err', $err);
 236     }
 237
 238     return wantarray ? ($resid, $rescode, $resmess) : $resid;
 239 }
 240
 241 sub analyze_virus_clam {
 242     my ($queue, $dname, $pmg_cfg) = @_;
 243
 244     my $timeout = 60*5;
 245     my $vinfo;
 246
 247     my $clamdscan_opts = "--stdout";
 248
 249     my ($csec, $usec) = gettimeofday();
 250
 251     my $previous_alarm;
 252
 253     eval {
 254
 255         $previous_alarm = alarm($timeout);
 256
 257         $SIG{ALRM} = sub {
 258             die "$queue->{logid}: Maximum time ($timeout sec) exceeded. " .
 259                 "virus analyze (clamav) failed: ERROR";
 260         };
 261
 262         open(CMD, "/usr/bin/clamdscan $clamdscan_opts '$dname'|") ||
 263             die "$queue->{logid}: can't exec clamdscan: $! : ERROR";
 264
 265         my $ifiles;
 266
 267         my $response = '';
 268         while (defined(my $line = <CMD>)) {
 269             if ($line =~ m/^$dname.*:\s+([^ :]*)\s+FOUND$/) {
 270                 # we just use the first detected virus name
 271                 $vinfo = $1 if !$vinfo;
 272             } elsif ($line =~ m/^Infected files:\s(\d*)$/i) {
 273                 $ifiles = $1;
 274             }
 275
 276             $response .= $line;
 277         }
 278
 279         close(CMD);
 280
 281         alarm(0); # avoid race conditions
 282
 283         if (!defined($ifiles)) {
 284             die "$queue->{logid}: got undefined output from " .
 285                 "virus detector: $response : ERROR";
 286         }
 287
 288         if ($vinfo) {
 289             syslog('info', "$queue->{logid}: virus detected: $vinfo (clamav)");
 290         }
 291     };
 292     my $err = $@;
 293
 294     alarm($previous_alarm);
 295
 296     my ($csec_end, $usec_end) = gettimeofday();
 297     $queue->{ptime_clam} =
 298         int (($csec_end-$csec)*1000 + ($usec_end - $usec)/1000);
 299
 300     if ($err) {
 301         syslog ('err', $err);
 302         $vinfo = undef;
 303         $queue->{errors} = 1;
 304     }
 305
 306     $queue->{vinfo_clam} = $vinfo;
 307
 308     return $vinfo ? "$vinfo (clamav)" : undef;
 309 }
 310
 311 sub analyze_virus {
 312     my ($queue, $filename, $pmg_cfg, $testmode) = @_;
 313
 314     # TODO: support other virus scanners?
 315
 316     # always scan with clamav
 317     return analyze_virus_clam($queue, $filename, $pmg_cfg);
 318 }
 319
 320 sub magic_mime_type_for_file {
 321     my ($filename) = @_;
 322
 323     # we do not use get_mime_type_for_file, because that considers
 324     # filename extensions - we only want magic type detection
 325
 326     my $bufsize = Xdgmime::xdg_mime_get_max_buffer_extents();
 327     die "got strange value for max_buffer_extents" if $bufsize > 4096*10;
 328
 329     my $ct = "application/octet-stream";
 330
 331     my $fh = IO::File->new("<$filename") ||
 332         die "unable to open file '$filename' - $!";
 333
 334     my ($buf, $len);
 335     if (($len = $fh->read($buf, $bufsize)) > 0) {
 336         $ct = xdg_mime_get_mime_type_for_data($buf, $len);
 337     }
 338     $fh->close();
 339
 340     die "unable to read file '$filename' - $!" if ($len < 0);
 341
 342     return $ct;
 343 }
 344
 345 sub add_ct_marks {
 346     my ($entity) = @_;
 347
 348     if (my $path = $entity->{PMX_decoded_path}) {
 349
 350         # set a reasonable default if magic does not give a result
 351         $entity->{PMX_magic_ct} = $entity->head->mime_attr('content-type');
 352
 353         if (my $ct = magic_mime_type_for_file($path)) {
 354             if ($ct ne 'application/octet-stream' || !$entity->{PMX_magic_ct}) {
 355                 $entity->{PMX_magic_ct} = $ct;
 356             }
 357         }
 358
 359         my $filename = $entity->head->recommended_filename;
 360         $filename = basename($path) if !defined($filename) || $filename eq '';
 361
 362         if (my $ct = xdg_mime_get_mime_type_from_file_name($filename)) {
 363             $entity->{PMX_glob_ct} = $ct;
 364         }
 365     }
 366
 367     foreach my $part ($entity->parts)  {
 368         add_ct_marks ($part);
 369     }
 370 }
 371
 372 # x509 certificate utils
 373
 374 # only write output if something fails
 375 sub run_silent_cmd {
 376     my ($cmd) = @_;
 377
 378     my $outbuf = '';
 379
 380     my $record_output = sub {
 381         $outbuf .= shift;
 382         $outbuf .= "\n";
 383     };
 384
 385     eval {
 386         PVE::Tools::run_command($cmd, outfunc => $record_output,
 387                                 errfunc => $record_output);
 388     };
 389     my $err = $@;
 390
 391     if ($err) {
 392         print STDERR $outbuf;
 393         die $err;
 394     }
 395 }
 396
 397 my $proxmox_tls_cert_fn = "/etc/pmg/pmg-tls.pem";
 398
 399 sub gen_proxmox_tls_cert {
 400     my ($force) = @_;
 401
 402     my $resolv = PVE::INotify::read_file('resolvconf');
 403     my $domain = $resolv->{search};
 404
 405     my $company = $domain; # what else ?
 406     my $cn = "*.$domain";
 407
 408    return if !$force && -f $proxmox_tls_cert_fn;
 409
 410     my $sslconf = <<__EOD__;
 411 RANDFILE = /root/.rnd
 412 extensions = v3_req
 413
 414 [ req ]
 415 default_bits = 4096
 416 distinguished_name = req_distinguished_name
 417 req_extensions = v3_req
 418 prompt = no
 419 string_mask = nombstr
 420
 421 [ req_distinguished_name ]
 422 organizationalUnitName = Proxmox Mail Gateway
 423 organizationName = $company
 424 commonName = $cn
 425
 426 [ v3_req ]
 427 basicConstraints = CA:FALSE
 428 nsCertType = server
 429 keyUsage = nonRepudiation, digitalSignature, keyEncipherment
 430 __EOD__
 431
 432     my $cfgfn = "/tmp/pmgtlsconf-$$.tmp";
 433     my $fh = IO::File->new ($cfgfn, "w");
 434     print $fh $sslconf;
 435     close ($fh);
 436
 437     eval {
 438         my $cmd = ['openssl', 'req', '-batch', '-x509', '-new', '-sha256',
 439                    '-config', $cfgfn, '-days', 3650, '-nodes',
 440                    '-out', $proxmox_tls_cert_fn,
 441                    '-keyout', $proxmox_tls_cert_fn];
 442         run_silent_cmd($cmd);
 443     };
 444
 445     if (my $err = $@) {
 446         unlink $proxmox_tls_cert_fn;
 447         unlink $cfgfn;
 448         die "unable to generate proxmox certificate request:\n$err";
 449     }
 450
 451     unlink $cfgfn;
 452 }
 453
 454 sub find_local_network_for_ip {
 455     my ($ip) = @_;
 456
 457     my $testip = Net::IP->new($ip);
 458
 459     my $isv6 = $testip->version == 6;
 460     my $routes = $isv6 ?
 461         PVE::ProcFSTools::read_proc_net_ipv6_route() :
 462         PVE::ProcFSTools::read_proc_net_route();
 463
 464     foreach my $entry (@$routes) {
 465         my $mask;
 466         if ($isv6) {
 467             $mask = $entry->{prefix};
 468             next if !$mask; # skip the default route...
 469         } else {
 470             $mask = $PVE::Network::ipv4_mask_hash_localnet->{$entry->{mask}};
 471             next if !defined($mask);
 472         }
 473         my $cidr = "$entry->{dest}/$mask";
 474         my $testnet = Net::IP->new($cidr);
 475         my $overlap = $testnet->overlaps($testip);
 476         if ($overlap == $Net::IP::IP_B_IN_A_OVERLAP ||
 477             $overlap == $Net::IP::IP_IDENTICAL)
 478         {
 479             return $cidr;
 480         }
 481     }
 482
 483     die "unable to detect local network for ip '$ip'\n";
 484 }
 485
 486 sub get_full_service_state {
 487     my ($service) = @_;
 488
 489     my $res;
 490
 491     my $parser = sub {
 492         my $line = shift;
 493         if ($line =~ m/^([^=\s]+)=(.*)$/) {
 494             $res->{$1} = $2;
 495         }
 496     };
 497
 498     $service = 'postfix@-' if $service eq 'postfix';
 499     PVE::Tools::run_command(['systemctl', 'show', $service], outfunc => $parser);
 500
 501     return $res;
 502 }
 503
 504 sub service_cmd {
 505     my ($service, $cmd) = @_;
 506
 507     die "unknown service command '$cmd'\n"
 508         if $cmd !~ m/^(start|stop|restart|reload)$/;
 509
 510     if ($service eq 'pmgdaemon' || $service eq 'pmgproxy') {
 511         if ($cmd eq 'restart') {
 512             # OK
 513         } else {
 514             die "invalid service cmd '$service $cmd': ERROR";
 515         }
 516     }
 517
 518     $service = 'postfix@-' if $service eq 'postfix';
 519     PVE::Tools::run_command(['systemctl', $cmd, $service]);
 520 };
 521
 522 # this is also used to get the IP of the local node
 523 sub lookup_node_ip {
 524     my ($nodename, $noerr) = @_;
 525
 526     my ($family, $packed_ip);
 527
 528     eval {
 529         my @res = PVE::Tools::getaddrinfo_all($nodename);
 530         $family = $res[0]->{family};
 531         $packed_ip = (PVE::Tools::unpack_sockaddr_in46($res[0]->{addr}))[2];
 532     };
 533
 534     if ($@) {
 535         die "hostname lookup failed:\n$@" if !$noerr;
 536         return undef;
 537     }
 538
 539     my $ip = Socket::inet_ntop($family, $packed_ip);
 540     if ($ip =~ m/^127\.|^::1$/) {
 541         die "hostname lookup failed - got local IP address ($nodename = $ip)\n" if !$noerr;
 542         return undef;
 543     }
 544
 545     return wantarray ? ($ip, $family) : $ip;
 546 }
 547
 548 sub run_postmap {
 549     my ($filename) = @_;
 550
 551     # make sure the file exists (else postmap fails)
 552     IO::File->new($filename, 'a', 0644);
 553
 554     eval {
 555         PVE::Tools::run_command(
 556             ['/usr/sbin/postmap', $filename],
 557             errmsg => "unable to update postfix table $filename");
 558     };
 559     my $err = $@;
 560
 561     warn $err if $err;
 562 }
 563
 564 sub clamav_dbstat {
 565
 566     my $res = [];
 567
 568     my $read_cvd_info = sub {
 569         my ($dbname, $dbfile) = @_;
 570
 571         my $header;
 572         my $fh = IO::File->new("<$dbfile");
 573         if (!$fh) {
 574             warn "cant open ClamAV Database $dbname ($dbfile) - $!\n";
 575             return;
 576         }
 577         $fh->read($header, 512);
 578         $fh->close();
 579
 580         ## ClamAV-VDB:16 Mar 2016 23-17 +0000:57:4218790:60:06386f34a16ebeea2733ab037f0536be:
 581         if ($header =~ m/^(ClamAV-VDB):([^:]+):(\d+):(\d+):/) {
 582             my ($ftype, $btime, $version, $nsigs) = ($1, $2, $3, $4);
 583             push @$res, {
 584                 name => $dbname,
 585                 type => $ftype,
 586                 build_time => $btime,
 587                 version => $version,
 588                 nsigs => $nsigs,
 589             };
 590         } else {
 591             warn "unable to parse ClamAV Database $dbname ($dbfile)\n";
 592         }
 593     };
 594
 595     # main database
 596     my $filename = "/var/lib/clamav/main.inc/main.info";
 597     $filename = "/var/lib/clamav/main.cvd" if ! -f $filename;
 598
 599     $read_cvd_info->('main', $filename) if -f $filename;
 600
 601     # daily database
 602     $filename = "/var/lib/clamav/daily.inc/daily.info";
 603     $filename = "/var/lib/clamav/daily.cvd" if ! -f $filename;
 604     $filename = "/var/lib/clamav/daily.cld" if ! -f $filename;
 605
 606     $read_cvd_info->('daily', $filename) if -f $filename;
 607
 608     $filename = "/var/lib/clamav/bytecode.cvd";
 609     $read_cvd_info->('bytecode', $filename) if -f $filename;
 610
 611     $filename = "/var/lib/clamav/safebrowsing.cvd";
 612     $read_cvd_info->('safebrowsing', $filename) if -f $filename;
 613
 614     my $ss_dbs_fn = "/var/lib/clamav-unofficial-sigs/configs/ss-include-dbs.txt";
 615     my $ss_dbs_files = {};
 616     if (my $ssfh = IO::File->new("<${ss_dbs_fn}")) {
 617         while (defined(my $line = <$ssfh>)) {
 618             chomp $line;
 619             $ss_dbs_files->{$line} = 1;
 620         }
 621     }
 622     my $last = 0;
 623     my $nsigs = 0;
 624     foreach $filename (</var/lib/clamav/*>) {
 625         my $fn = basename($filename);
 626         next if !$ss_dbs_files->{$fn};
 627
 628         my $fh = IO::File->new("<$filename");
 629         next if !defined($fh);
 630         my $st = stat($fh);
 631         next if !$st;
 632         my $mtime = $st->mtime();
 633         $last = $mtime if $mtime > $last;
 634         while (defined(my $line = <$fh>)) { $nsigs++; }
 635     }
 636
 637     if ($nsigs > 0) {
 638         push @$res, {
 639             name => 'sanesecurity',
 640             type => 'unofficial',
 641             build_time => strftime("%d %b %Y %H-%M %z", localtime($last)),
 642             nsigs => $nsigs,
 643         };
 644     }
 645
 646     return $res;
 647 }
 648
 649 # RRD related code
 650 my $rrd_dir = "/var/lib/rrdcached/db";
 651 my $rrdcached_socket = "/var/run/rrdcached.sock";
 652
 653 my $rrd_def_node = [
 654     "DS:loadavg:GAUGE:120:0:U",
 655     "DS:maxcpu:GAUGE:120:0:U",
 656     "DS:cpu:GAUGE:120:0:U",
 657     "DS:iowait:GAUGE:120:0:U",
 658     "DS:memtotal:GAUGE:120:0:U",
 659     "DS:memused:GAUGE:120:0:U",
 660     "DS:swaptotal:GAUGE:120:0:U",
 661     "DS:swapused:GAUGE:120:0:U",
 662     "DS:roottotal:GAUGE:120:0:U",
 663     "DS:rootused:GAUGE:120:0:U",
 664     "DS:netin:DERIVE:120:0:U",
 665     "DS:netout:DERIVE:120:0:U",
 666
 667     "RRA:AVERAGE:0.5:1:70", # 1 min avg - one hour
 668     "RRA:AVERAGE:0.5:30:70", # 30 min avg - one day
 669     "RRA:AVERAGE:0.5:180:70", # 3 hour avg - one week
 670     "RRA:AVERAGE:0.5:720:70", # 12 hour avg - one month
 671     "RRA:AVERAGE:0.5:10080:70", # 7 day avg - ony year
 672
 673     "RRA:MAX:0.5:1:70", # 1 min max - one hour
 674     "RRA:MAX:0.5:30:70", # 30 min max - one day
 675     "RRA:MAX:0.5:180:70", # 3 hour max - one week
 676     "RRA:MAX:0.5:720:70", # 12 hour max - one month
 677     "RRA:MAX:0.5:10080:70", # 7 day max - ony year
 678 ];
 679
 680 sub cond_create_rrd_file {
 681     my ($filename, $rrddef) = @_;
 682
 683     return if -f $filename;
 684
 685     my @args = ($filename);
 686
 687     push @args, "--daemon" => "unix:${rrdcached_socket}"
 688         if -S $rrdcached_socket;
 689
 690     push @args, '--step', 60;
 691
 692     push @args, @$rrddef;
 693
 694     # print "TEST: " . join(' ', @args) . "\n";
 695
 696     RRDs::create(@args);
 697     my $err = RRDs::error;
 698     die "RRD error: $err\n" if $err;
 699 }
 700
 701 sub update_node_status_rrd {
 702
 703     my $filename = "$rrd_dir/pmg-node-v1.rrd";
 704     cond_create_rrd_file($filename, $rrd_def_node);
 705
 706     my ($avg1, $avg5, $avg15) = PVE::ProcFSTools::read_loadavg();
 707
 708     my $stat = PVE::ProcFSTools::read_proc_stat();
 709
 710     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 711
 712     my ($uptime) = PVE::ProcFSTools::read_proc_uptime();
 713
 714     my $cpuinfo = PVE::ProcFSTools::read_cpuinfo();
 715
 716     my $maxcpu = $cpuinfo->{cpus};
 717
 718     # traffic from/to physical interface cards
 719     my $netin = 0;
 720     my $netout = 0;
 721     foreach my $dev (keys %$netdev) {
 722         next if $dev !~ m/^eth\d+$/;
 723         $netin += $netdev->{$dev}->{receive};
 724         $netout += $netdev->{$dev}->{transmit};
 725     }
 726
 727     my $meminfo = PVE::ProcFSTools::read_meminfo();
 728
 729     my $dinfo = df('/', 1); # output is bytes
 730
 731     my $ctime = time();
 732
 733     # everything not free is considered to be used
 734     my $dused = $dinfo->{blocks} - $dinfo->{bfree};
 735
 736     my $data = "$ctime:$avg1:$maxcpu:$stat->{cpu}:$stat->{wait}:" .
 737         "$meminfo->{memtotal}:$meminfo->{memused}:" .
 738         "$meminfo->{swaptotal}:$meminfo->{swapused}:" .
 739         "$dinfo->{blocks}:$dused:$netin:$netout";
 740
 741
 742     my @args = ($filename);
 743
 744     push @args, "--daemon" => "unix:${rrdcached_socket}"
 745         if -S $rrdcached_socket;
 746
 747     push @args, $data;
 748
 749     # print "TEST: " . join(' ', @args) . "\n";
 750
 751     RRDs::update(@args);
 752     my $err = RRDs::error;
 753     die "RRD error: $err\n" if $err;
 754 }
 755
 756 sub create_rrd_data {
 757     my ($rrdname, $timeframe, $cf) = @_;
 758
 759     my $rrd = "${rrd_dir}/$rrdname";
 760
 761     my $setup = {
 762         hour =>  [ 60, 70 ],
 763         day  =>  [ 60*30, 70 ],
 764         week =>  [ 60*180, 70 ],
 765         month => [ 60*720, 70 ],
 766         year =>  [ 60*10080, 70 ],
 767     };
 768
 769     my ($reso, $count) = @{$setup->{$timeframe}};
 770     my $ctime  = $reso*int(time()/$reso);
 771     my $req_start = $ctime - $reso*$count;
 772
 773     $cf = "AVERAGE" if !$cf;
 774
 775     my @args = (
 776         "-s" => $req_start,
 777         "-e" => $ctime - 1,
 778         "-r" => $reso,
 779         );
 780
 781     push @args, "--daemon" => "unix:${rrdcached_socket}"
 782         if -S $rrdcached_socket;
 783
 784     my ($start, $step, $names, $data) = RRDs::fetch($rrd, $cf, @args);
 785
 786     my $err = RRDs::error;
 787     die "RRD error: $err\n" if $err;
 788
 789     die "got wrong time resolution ($step != $reso)\n"
 790         if $step != $reso;
 791
 792     my $res = [];
 793     my $fields = scalar(@$names);
 794     for my $line (@$data) {
 795         my $entry = { 'time' => $start };
 796         $start += $step;
 797         for (my $i = 0; $i < $fields; $i++) {
 798             my $name = $names->[$i];
 799             if (defined(my $val = $line->[$i])) {
 800                 $entry->{$name} = $val;
 801             } else {
 802                 # leave empty fields undefined
 803                 # maybe make this configurable?
 804             }
 805         }
 806         push @$res, $entry;
 807     }
 808
 809     return $res;
 810 }
 811
 812 1;