src/PMG/HTTPServer.pm

   1 package PMG::HTTPServer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::INotify;
   8 use PVE::Tools;
   9 use PVE::APIServer::AnyEvent;
  10 use PVE::Exception qw(raise_param_exc);
  11 use PMG::RESTEnvironment;
  12
  13 use PMG::Ticket;
  14 use PMG::Cluster;
  15 use PMG::API2;
  16
  17 use Data::Dumper;
  18
  19 use base('PVE::APIServer::AnyEvent');
  20
  21 use HTTP::Status qw(:constants);
  22
  23
  24 sub new {
  25     my ($this, %args) = @_;
  26
  27     my $class = ref($this) || $this;
  28
  29     my $self = $class->SUPER::new(%args);
  30
  31     $self->{rpcenv} = PMG::RESTEnvironment->init(
  32         $self->{trusted_env} ? 'priv' : 'pub', atfork =>  sub { $self->atfork_handler() });
  33
  34     return $self;
  35 }
  36
  37
  38 sub generate_csrf_prevention_token {
  39     my ($username) = @_;
  40
  41     return PMG::Ticket::assemble_csrf_prevention_token ($username);
  42 }
  43
  44 sub auth_handler {
  45     my ($self, $method, $rel_uri, $ticket, $token, $peer_host) = @_;
  46
  47     my $rpcenv = $self->{rpcenv};
  48
  49     # set environment variables
  50     $rpcenv->set_user(undef);
  51     $rpcenv->set_role(undef);
  52     $rpcenv->set_language('C');
  53     $rpcenv->set_client_ip($peer_host);
  54
  55     $rpcenv->init_request();
  56
  57     my $require_auth = 1;
  58
  59     # explicitly allow some calls without auth
  60     if (($rel_uri eq '/access/domains' && $method eq 'GET') ||
  61         ($rel_uri eq '/access/ticket' && ($method eq 'GET' || $method eq 'POST'))) {
  62         $require_auth = 0;
  63     }
  64
  65     my ($username, $age);
  66
  67     if ($require_auth) {
  68
  69         die "No ticket\n" if !$ticket;
  70
  71         if ($ticket =~ m/^PMGQUAR:/) {
  72             ($username, $age) = PMG::Ticket::verify_quarantine_ticket($ticket);
  73             $rpcenv->set_user($username);
  74             $rpcenv->set_role('quser');
  75         } else {
  76             ($username, $age) = PMG::Ticket::verify_ticket($ticket);
  77             my $role = PMG::AccessControl::check_user_enabled($self->{usercfg}, $username);
  78             $rpcenv->set_user($username);
  79             $rpcenv->set_role($role);
  80         }
  81
  82         $rpcenv->set_ticket($ticket);
  83
  84         my $euid = $>;
  85         PMG::Ticket::verify_csrf_prevention_token($username, $token)
  86             if ($euid != 0) && ($method ne 'GET');
  87     }
  88
  89     return {
  90         ticket => $ticket,
  91         token => $token,
  92         userid => $username,
  93         age => $age,
  94         isUpload => 0,
  95     };
  96 }
  97
  98 sub rest_handler {
  99     my ($self, $clientip, $method, $rel_uri, $auth, $params, $format) = @_;
 100
 101     my $rpcenv = $self->{rpcenv};
 102     $rpcenv->set_format($format);
 103
 104     my $resp = {
 105         status => HTTP_NOT_IMPLEMENTED,
 106         message => "Method '$method $rel_uri' not implemented",
 107     };
 108
 109     my ($handler, $info);
 110
 111     eval {
 112         my $uri_param = {};
 113         ($handler, $info) = PMG::API2->find_handler($method, $rel_uri, $uri_param);
 114         return if !$handler || !$info;
 115
 116         foreach my $p (keys %{$params}) {
 117             if (defined($uri_param->{$p})) {
 118                 raise_param_exc({$p =>  "duplicate parameter (already defined in URI)"});
 119             }
 120             $uri_param->{$p} = $params->{$p};
 121         }
 122
 123         # check access permissions
 124         $rpcenv->check_api2_permissions($info->{permissions}, $uri_param);
 125
 126         if (my $pn = $info->{proxyto}) {
 127
 128             my $node;
 129             if ($pn eq 'master') {
 130                 $node = PMG::Cluster::get_master_node();
 131             } else {
 132                 $node = $uri_param->{$pn};
 133                 raise_param_exc({$pn =>  "proxy parameter '$pn' does not exists"}) if !$node;
 134             }
 135
 136             if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
 137                 die "unable to proxy file uploads" if $auth->{isUpload};
 138                 my $remip = $self->remote_node_ip($node);
 139                 $resp = { proxy => $remip, proxynode => $node, proxy_params => $params };
 140                 return;
 141             }
 142         }
 143
 144         my $euid = $>;
 145         if ($info->{protected} && ($euid != 0)) {
 146             $resp = { proxy => 'localhost' , proxy_params => $params };
 147             return;
 148         }
 149
 150         if (my $pn = $info->{proxyto}) {
 151             if ($pn eq 'master') {
 152                 $rpcenv->check_node_is_master();
 153             }
 154         }
 155
 156
 157         my $result = $handler->handle($info, $uri_param);
 158
 159         $resp = {
 160             info => $info, # useful to format output
 161             status => HTTP_OK,
 162         };
 163
 164         if ($info->{download}) {
 165             my $type =  $info->{returns}->{type};
 166             if ($type eq 'string' || $type eq 'object') {
 167                 $resp->{download} = $result;
 168             } else {
 169                 die "API calls which trigger downloads need to have return type 'string' or 'object' - internal error"
 170             }
 171
 172         } else {
 173             $resp->{data} = $result;
 174         }
 175
 176         if (my $count = $rpcenv->get_result_attrib('total')) {
 177             $resp->{total} = $count;
 178         }
 179
 180         if (my $diff = $rpcenv->get_result_attrib('changes')) {
 181             $resp->{changes} = $diff;
 182         }
 183     };
 184     my $err = $@;
 185
 186     $rpcenv->set_user(undef); # clear after request
 187     $rpcenv->set_role(undef); # clear after request
 188     $rpcenv->set_format(undef); # clear after request
 189
 190     if ($err) {
 191         $resp = { info => $info };
 192         if (ref($err) eq "PVE::Exception") {
 193             $resp->{status} = $err->{code} || HTTP_INTERNAL_SERVER_ERROR;
 194             $resp->{errors} = $err->{errors} if $err->{errors};
 195             $resp->{message} = $err->{msg};
 196         } else {
 197             $resp->{status} =  HTTP_INTERNAL_SERVER_ERROR;
 198             $resp->{message} = $err;
 199         }
 200     }
 201
 202     return $resp;
 203 }
 204
 205 sub check_cert_fingerprint {
 206     my ($self, $cert) = @_;
 207
 208     return PMG::Cluster::check_cert_fingerprint($cert);
 209 }
 210
 211 sub initialize_cert_cache {
 212     my ($self, $node) = @_;
 213
 214     PMG::Cluster::initialize_cert_cache($node);
 215 }
 216
 217 sub remote_node_ip {
 218     my ($self, $node) = @_;
 219
 220     my $remip = PMG::Cluster::remote_node_ip($node);
 221
 222     die "unable to get remote IP address for node '$node'\n" if !$remip;
 223
 224     return $remip;
 225 }
 226
 227 1;