src/PMG/Service/pmgproxy.pm

   1 package PMG::Service::pmgproxy;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Daemon;
   8 use HTTP::Response;
   9 use URI;
  10 use URI::Escape;
  11
  12 use URI::QueryParam;
  13 use Data::Dumper;
  14
  15 use PVE::Tools;
  16 use PVE::APIServer::Formatter;
  17 use PVE::APIServer::Formatter::Standard;
  18 use PVE::APIServer::Formatter::HTML;
  19 use PVE::APIServer::AnyEvent;
  20 use PVE::APIServer::Utils;
  21
  22 use PMG::HTTPServer;
  23 use PMG::API2;
  24
  25 use Template;
  26
  27 use base qw(PVE::Daemon);
  28
  29 my $cmdline = [$0, @ARGV];
  30
  31 my %daemon_options = (
  32     max_workers => 3,
  33     restart_on_error => 5,
  34     stop_wait_time => 15,
  35     leave_children_open_on_reload => 1,
  36     setuid => 'www-data',
  37     setgid => 'www-data',
  38     pidfile => '/run/pmgproxy/pmgproxy.pid',
  39 );
  40
  41 my $daemon = __PACKAGE__->new('pmgproxy', $cmdline, %daemon_options);
  42
  43 sub add_dirs {
  44     my ($result_hash, $alias, $subdir) = @_;
  45
  46     PVE::APIServer::AnyEvent::add_dirs($result_hash, $alias, $subdir);
  47 }
  48
  49 my $gui_base_dir = "/usr/share/javascript/pmg-gui";
  50 my $fontawesome_dir = "/usr/share/fonts-font-awesome";
  51 my $xtermjs_dir = '/usr/share/pve-xtermjs';
  52 my $framework7_dir = '/usr/share/javascript/framework7';
  53
  54 sub init {
  55     my ($self) = @_;
  56
  57     my $proxyconf = PVE::APIServer::Utils::read_proxy_config($self->{name});
  58
  59     my $accept_lock_fn = "/var/lock/pmgproxy.lck";
  60
  61     my $lockfh = IO::File->new(">>${accept_lock_fn}") ||
  62         die "unable to open lock file '${accept_lock_fn}' - $!\n";
  63
  64     my $family = PVE::Tools::get_host_address_family($self->{nodename});
  65     my $socket = $self->create_reusable_socket(8006, undef, $family);
  66
  67     my $dirs = {};
  68
  69     add_dirs($dirs, '/pve2/locale/', '/usr/share/pmg-i18n/');
  70     add_dirs($dirs, '/pve2/ext6/', '/usr/share/javascript/extjs/');
  71     add_dirs($dirs, '/pve2/images/' => "$gui_base_dir/images/");
  72     add_dirs($dirs, '/pve2/css/' => "$gui_base_dir/css/");
  73     add_dirs($dirs, '/pve2/js/' => "$gui_base_dir/js/");
  74     add_dirs($dirs, '/fontawesome/css/' => "$fontawesome_dir/css/");
  75     add_dirs($dirs, '/fontawesome/fonts/' => "$fontawesome_dir/fonts/");
  76     add_dirs($dirs, '/framework7/fonts/' => "$framework7_dir/fonts/");
  77     add_dirs($dirs, '/framework7/css/' => "$framework7_dir/css/");
  78     add_dirs($dirs, '/framework7/js/' => "$framework7_dir/js/");
  79     add_dirs($dirs, '/xtermjs/' => "$xtermjs_dir/");
  80     add_dirs($dirs, '/pmg-docs/' => '/usr/share/pmg-docs/');
  81
  82     $self->{server_config} = {
  83         title => 'Proxmox Mail Gateway API',
  84         cookie_name => 'PMGAuthCookie',
  85         keep_alive => 100,
  86         max_conn => 500,
  87         max_requests => 1000,
  88         lockfile => $accept_lock_fn,
  89         socket => $socket,
  90         lockfh => $lockfh,
  91         debug => $self->{debug},
  92         trusted_env => 0, # not trusted, anyone can connect
  93         logfile => '/var/log/pmgproxy/pmgproxy.log',
  94         allow_from => $proxyconf->{ALLOW_FROM},
  95         deny_from => $proxyconf->{DENY_FROM},
  96         policy => $proxyconf->{POLICY},
  97         ssl => {
  98             cert_file => '/etc/pmg/pmg-api.pem',
  99             dh => 'skip2048',
 100             cipher_list => $proxyconf->{CIPHERS},
 101             honor_cipher_order => $proxyconf->{HONOR_CIPHER_ORDER},
 102         },
 103         compression => $proxyconf->{COMPRESSION},
 104         # Note: there is no authentication for those pages and dirs!
 105         pages => {
 106             '/' => sub { get_index($self->{nodename}, @_) },
 107             '/quarantine' => sub { get_index($self->{nodename}, @_) },
 108             # avoid authentication when accessing favicon
 109             '/favicon.ico' => {
 110                 file => '/usr/share/doc/pmg-api/favicon.ico',
 111             },
 112             '/proxmoxlib.js' => {
 113                 file => '/usr/share/javascript/proxmox-widget-toolkit/proxmoxlib.js',
 114             },
 115         },
 116         dirs => $dirs,
 117     };
 118
 119     if (defined($proxyconf->{DHPARAMS})) {
 120         $self->{server_config}->{ssl}->{dh_file} = $proxyconf->{DHPARAMS};
 121     }
 122 }
 123
 124 sub run {
 125     my ($self) = @_;
 126
 127     my $server = PMG::HTTPServer->new(%{$self->{server_config}});
 128     $server->run();
 129 }
 130
 131 $daemon->register_start_command();
 132 $daemon->register_restart_command(1);
 133 $daemon->register_stop_command();
 134 $daemon->register_status_command();
 135
 136 our $cmddef = {
 137     start => [ __PACKAGE__, 'start', []],
 138     restart => [ __PACKAGE__, 'restart', []],
 139     stop => [ __PACKAGE__, 'stop', []],
 140     status => [ __PACKAGE__, 'status', [], undef, sub { print shift . "\n";} ],
 141 };
 142
 143 my $template_toolkit;
 144
 145 sub get_template_toolkit {
 146
 147     return $template_toolkit if $template_toolkit;
 148
 149     $template_toolkit = Template->new(
 150         { INCLUDE_PATH => [$gui_base_dir, $xtermjs_dir]});
 151
 152     return $template_toolkit;
 153 }
 154
 155 sub is_phone {
 156     my ($ua) = @_;
 157
 158     return 0 if !$ua;
 159
 160     if ($ua =~ m/(
 161         iPhone|
 162         iPod|
 163         Windows\ Phone|
 164         Android|
 165         BlackBerry
 166         )/xi) {
 167         return 1;
 168     }
 169
 170     return 0;
 171 }
 172
 173 sub get_index {
 174     my ($nodename, $server, $r, $args) = @_;
 175
 176     my $lang = 'en';
 177     my $username;
 178     my $token = 'null';
 179     my $quarantine = ($r->uri->path() =~ m/quarantine$/);
 180     my $mobile = is_phone($r->header('User-Agent'));
 181     if (defined($args->{mobile})) {
 182         $mobile = $args->{mobile} ? 1 : 0;
 183     }
 184
 185     if (my $cookie = $r->header('Cookie')) {
 186         if (my $newlang = ($cookie =~ /(?:^|\s)PMGLangCookie=([^;]*)/)[0]) {
 187             if ($newlang =~ m/^[a-z]{2,3}(_[A-Z]{2,3})?$/) {
 188                 $lang = $newlang;
 189             }
 190         }
 191         my $ticket = PVE::APIServer::Formatter::extract_auth_cookie($cookie, $server->{cookie_name});
 192
 193         if ($ticket =~ m/^PMGQUAR:/) {
 194             $username = PMG::Ticket::verify_quarantine_ticket($ticket, 1);
 195         } else {
 196             $username = PMG::Ticket::verify_ticket($ticket, 1);
 197         }
 198     } else {
 199         if (defined($args->{ticket})) {
 200             my $ticket = uri_unescape($args->{ticket});
 201             $username = PMG::Ticket::verify_quarantine_ticket($ticket, 1);
 202         }
 203     }
 204
 205     $token = PMG::Ticket::assemble_csrf_prevention_token($username)
 206         if defined($username);
 207
 208     my $langfile = 0;
 209
 210     if (-f  "/usr/share/pmg-i18n/pmg-lang-$lang.js") {
 211         $langfile = 1;
 212     }
 213
 214     $username = '' if !$username;
 215
 216     my $page = '';
 217
 218     my $vars = {
 219         lang => $lang,
 220         langfile => $langfile,
 221         username => $username,
 222         token => $token,
 223         console => $args->{console},
 224         nodename => $nodename,
 225         debug => $args->{debug} || $server->{debug},
 226     };
 227
 228     my $template_name;
 229     if (defined($args->{console}) && $args->{xtermjs}) {
 230         $template_name = "index.html.tpl"; # fixme: use better name
 231     } elsif ($mobile && $quarantine) {
 232         $template_name = "pmg-mobile-index.html.tt";
 233     } else {
 234         $template_name = "pmg-index.html.tt";
 235     }
 236
 237     my $tt = get_template_toolkit();
 238
 239     $tt->process($template_name, $vars, \$page) ||
 240         die $tt->error() . "\n";
 241
 242     my $headers = HTTP::Headers->new(Content_Type => "text/html; charset=utf-8");
 243     my $resp = HTTP::Response->new(200, "OK", $headers, $page);
 244
 245     return $resp;
 246 }
 247
 248 1;