src/PMG/Service/pmgproxy.pm

   1 package PMG::Service::pmgproxy;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Daemon;
   8 use HTTP::Response;
   9 use URI;
  10 use URI::Escape;
  11
  12 use URI::QueryParam;
  13 use Data::Dumper;
  14
  15 use PVE::Tools;
  16 use PVE::APIServer::Formatter;
  17 use PVE::APIServer::Formatter::Standard;
  18 use PVE::APIServer::Formatter::HTML;
  19 use PVE::APIServer::AnyEvent;
  20 use PVE::APIServer::Utils;
  21
  22 use PMG::HTTPServer;
  23 use PMG::API2;
  24
  25 use Template;
  26
  27 use base qw(PVE::Daemon);
  28
  29 my $cmdline = [$0, @ARGV];
  30
  31 my %daemon_options = (
  32     max_workers => 3,
  33     restart_on_error => 5,
  34     stop_wait_time => 15,
  35     leave_children_open_on_reload => 1,
  36     setuid => 'www-data',
  37     setgid => 'www-data',
  38     pidfile => '/run/pmgproxy/pmgproxy.pid',
  39 );
  40
  41 my $daemon = __PACKAGE__->new('pmgproxy', $cmdline, %daemon_options);
  42
  43 sub add_dirs {
  44     my ($result_hash, $alias, $subdir) = @_;
  45
  46     PVE::APIServer::AnyEvent::add_dirs($result_hash, $alias, $subdir);
  47 }
  48
  49 my $gui_base_dir = "/usr/share/javascript/pmg-gui";
  50 my $extjs_dir = "/usr/share/javascript/extjs/";
  51 my $fontawesome_dir = "/usr/share/fonts-font-awesome";
  52 my $xtermjs_dir = '/usr/share/pve-xtermjs';
  53 my $framework7_dir = '/usr/share/javascript/framework7';
  54 my $widgettoolkit_dir = '/usr/share/javascript/proxmox-widget-toolkit';
  55
  56 sub init {
  57     my ($self) = @_;
  58
  59     my $proxyconf = PVE::APIServer::Utils::read_proxy_config($self->{name});
  60
  61     my $accept_lock_fn = "/var/lock/pmgproxy.lck";
  62
  63     my $lockfh = IO::File->new(">>${accept_lock_fn}") ||
  64         die "unable to open lock file '${accept_lock_fn}' - $!\n";
  65
  66     my $family = PVE::Tools::get_host_address_family($self->{nodename});
  67     my $socket = $self->create_reusable_socket(8006, undef, $family);
  68
  69     my $dirs = {};
  70
  71     add_dirs($dirs, '/pve2/locale/', '/usr/share/pmg-i18n/');
  72     add_dirs($dirs, '/pve2/ext6/', $extjs_dir);
  73     add_dirs($dirs, '/pve2/images/' => "$gui_base_dir/images/");
  74     add_dirs($dirs, '/pve2/css/' => "$gui_base_dir/css/");
  75     add_dirs($dirs, '/pve2/js/' => "$gui_base_dir/js/");
  76     add_dirs($dirs, '/fontawesome/css/' => "$fontawesome_dir/css/");
  77     add_dirs($dirs, '/fontawesome/fonts/' => "$fontawesome_dir/fonts/");
  78     add_dirs($dirs, '/framework7/fonts/' => "$framework7_dir/fonts/");
  79     add_dirs($dirs, '/framework7/css/' => "$framework7_dir/css/");
  80     add_dirs($dirs, '/framework7/js/' => "$framework7_dir/js/");
  81     add_dirs($dirs, '/xtermjs/' => "$xtermjs_dir/");
  82     add_dirs($dirs, '/pmg-docs/' => '/usr/share/pmg-docs/');
  83     add_dirs($dirs, '/pmg-docs/api-viewer/extjs/' => $extjs_dir);
  84     add_dirs($dirs, '/pwt/css/' => "$widgettoolkit_dir/css/");
  85
  86     $self->{server_config} = {
  87         title => 'Proxmox Mail Gateway API',
  88         cookie_name => 'PMGAuthCookie',
  89         keep_alive => 100,
  90         max_conn => 500,
  91         max_requests => 1000,
  92         lockfile => $accept_lock_fn,
  93         socket => $socket,
  94         lockfh => $lockfh,
  95         debug => $self->{debug},
  96         trusted_env => 0, # not trusted, anyone can connect
  97         logfile => '/var/log/pmgproxy/pmgproxy.log',
  98         allow_from => $proxyconf->{ALLOW_FROM},
  99         deny_from => $proxyconf->{DENY_FROM},
 100         policy => $proxyconf->{POLICY},
 101         ssl => {
 102             cert_file => '/etc/pmg/pmg-api.pem',
 103             dh => 'skip2048',
 104             cipher_list => $proxyconf->{CIPHERS},
 105             honor_cipher_order => $proxyconf->{HONOR_CIPHER_ORDER},
 106         },
 107         compression => $proxyconf->{COMPRESSION},
 108         # Note: there is no authentication for those pages and dirs!
 109         pages => {
 110             '/' => sub { get_index($self->{nodename}, @_) },
 111             '/quarantine' => sub { get_index($self->{nodename}, @_) },
 112             # avoid authentication when accessing favicon
 113             '/favicon.ico' => {
 114                 file => '/usr/share/doc/pmg-api/favicon.ico',
 115             },
 116             '/proxmoxlib.js' => {
 117                 file => '/usr/share/javascript/proxmox-widget-toolkit/proxmoxlib.js',
 118             },
 119         },
 120         dirs => $dirs,
 121     };
 122
 123     if (defined($proxyconf->{DHPARAMS})) {
 124         $self->{server_config}->{ssl}->{dh_file} = $proxyconf->{DHPARAMS};
 125     }
 126 }
 127
 128 sub run {
 129     my ($self) = @_;
 130
 131     my $server = PMG::HTTPServer->new(%{$self->{server_config}});
 132     $server->run();
 133 }
 134
 135 $daemon->register_start_command();
 136 $daemon->register_restart_command(1);
 137 $daemon->register_stop_command();
 138 $daemon->register_status_command();
 139
 140 our $cmddef = {
 141     start => [ __PACKAGE__, 'start', []],
 142     restart => [ __PACKAGE__, 'restart', []],
 143     stop => [ __PACKAGE__, 'stop', []],
 144     status => [ __PACKAGE__, 'status', [], undef, sub { print shift . "\n";} ],
 145 };
 146
 147 my $template_toolkit;
 148
 149 sub get_template_toolkit {
 150
 151     return $template_toolkit if $template_toolkit;
 152
 153     $template_toolkit = Template->new(
 154         { INCLUDE_PATH => [$gui_base_dir, $xtermjs_dir]});
 155
 156     return $template_toolkit;
 157 }
 158
 159 sub is_phone {
 160     my ($ua) = @_;
 161
 162     return 0 if !$ua;
 163
 164     if ($ua =~ m/(
 165         iPhone|
 166         iPod|
 167         Windows\ Phone|
 168         Android|
 169         BlackBerry
 170         )/xi) {
 171         return 1;
 172     }
 173
 174     return 0;
 175 }
 176
 177 sub get_index {
 178     my ($nodename, $server, $r, $args) = @_;
 179
 180     my $lang = 'en';
 181     my $username;
 182     my $token = 'null';
 183     my $quarantine = ($r->uri->path() =~ m/quarantine$/);
 184     my $mobile = is_phone($r->header('User-Agent'));
 185     if (defined($args->{mobile})) {
 186         $mobile = $args->{mobile} ? 1 : 0;
 187     }
 188
 189     if (my $cookie = $r->header('Cookie')) {
 190         if (my $newlang = ($cookie =~ /(?:^|\s)PMGLangCookie=([^;]*)/)[0]) {
 191             if ($newlang =~ m/^[a-z]{2,3}(_[A-Z]{2,3})?$/) {
 192                 $lang = $newlang;
 193             }
 194         }
 195         my $ticket = PVE::APIServer::Formatter::extract_auth_cookie($cookie, $server->{cookie_name});
 196
 197         if ($ticket =~ m/^PMGQUAR:/) {
 198             $username = PMG::Ticket::verify_quarantine_ticket($ticket, 1);
 199         } else {
 200             $username = PMG::Ticket::verify_ticket($ticket, 1);
 201         }
 202     } else {
 203         if (defined($args->{ticket})) {
 204             my $ticket = uri_unescape($args->{ticket});
 205             $username = PMG::Ticket::verify_quarantine_ticket($ticket, 1);
 206         }
 207     }
 208
 209     $token = PMG::Ticket::assemble_csrf_prevention_token($username)
 210         if defined($username);
 211
 212     my $langfile = 0;
 213
 214     if (-f  "/usr/share/pmg-i18n/pmg-lang-$lang.js") {
 215         $langfile = 1;
 216     }
 217
 218     my $wtversionraw = PVE::Tools::file_read_firstline("$widgettoolkit_dir/proxmoxlib.js");
 219     my $wtversion = '';
 220     if ($wtversionraw =~ m|^// (.*)$|) {
 221         $wtversion = $1;
 222     };
 223
 224     my $versionraw = PVE::Tools::file_read_firstline("$gui_base_dir/js/pmgmanagerlib.js");
 225     my $version = '';
 226     if ($versionraw =~ m|^// (.*)$|) {
 227         $version = $1;
 228     };
 229
 230
 231     $username = '' if !$username;
 232
 233     my $page = '';
 234
 235     my $vars = {
 236         lang => $lang,
 237         langfile => $langfile,
 238         username => $username,
 239         token => $token,
 240         console => $args->{console},
 241         nodename => $nodename,
 242         debug => $args->{debug} || $server->{debug},
 243         version => $version,
 244         wtversion => $wtversion,
 245     };
 246
 247     my $template_name;
 248     if (defined($args->{console}) && $args->{xtermjs}) {
 249         $template_name = "index.html.tpl"; # fixme: use better name
 250     } elsif ($mobile && $quarantine) {
 251         $template_name = "pmg-mobile-index.html.tt";
 252     } else {
 253         $template_name = "pmg-index.html.tt";
 254     }
 255
 256     my $tt = get_template_toolkit();
 257
 258     $tt->process($template_name, $vars, \$page) ||
 259         die $tt->error() . "\n";
 260
 261     my $headers = HTTP::Headers->new(Content_Type => "text/html; charset=utf-8");
 262     my $resp = HTTP::Response->new(200, "OK", $headers, $page);
 263
 264     return $resp;
 265 }
 266
 267 1;