src/bin/pmgpolicy

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use Getopt::Long;
   6 use POSIX qw(errno_h signal_h);
   7
   8 use Net::Server::PreForkSimple;
   9 use Net::DNS::Resolver;
  10 use Mail::SPF;
  11 use Fcntl;
  12 use Fcntl ':flock';
  13 use IO::Multiplex;
  14 use Time::HiRes qw(gettimeofday);
  15 use Time::Zone;
  16
  17 use PVE::INotify;
  18 use PVE::Tools;
  19 use PVE::SafeSyslog;
  20
  21 use PMG::Utils;
  22 use PMG::RuleDB;
  23 use PMG::DBTools;
  24 use PMG::RuleCache;
  25 use PMG::Config;
  26 use PMG::ClusterConfig;
  27
  28 use base qw(Net::Server::PreForkSimple);
  29
  30 my $greylist_delay = 3*60;            # greylist window
  31 my $greylist_lifetime = 3600*24*2;    # retry window
  32 my $greylist_awlifetime = 3600*24*36; # expire window
  33
  34 my $opt_commandline = [$0, @ARGV];
  35
  36 my $opt_max_dequeue = 1;
  37 my $opt_dequeue_time = 60*2;
  38
  39 my $opt_testmode;
  40 my $opt_pidfile;
  41 my $opt_database;
  42 my $opt_policy_port = 10022;
  43
  44 my %_opts = (
  45     'pidfile=s' => \$opt_pidfile,
  46     'testmode' => \$opt_testmode,
  47     'database=s' => \$opt_database,
  48     'port=i' => \$opt_policy_port,
  49 );
  50 if (!GetOptions(%_opts)) {
  51     die "usage error\n";
  52     exit (-1);
  53 }
  54
  55 $opt_pidfile = "/run/pmgpolicy.pid" if !$opt_pidfile;
  56 $opt_max_dequeue = 0 if $opt_testmode;
  57
  58 initlog('pmgpolicy', 'mail');
  59
  60 my $max_servers = 5;
  61
  62 if (!$opt_testmode) {
  63
  64     my $pmg_cfg = PMG::Config->new ();
  65     my $demo = $pmg_cfg->get('admin', 'demo');
  66     $max_servers = $pmg_cfg->get('mail', 'max_policy');
  67
  68     if ($demo) {
  69         syslog('info', 'demo mode detected - not starting server');
  70         exit(0);
  71     }
  72 }
  73
  74 my $daemonize = 1;
  75 if (defined ($ENV{BOUND_SOCKETS})) {
  76     $daemonize = undef;
  77 }
  78
  79
  80 my $server_attr = {
  81     port => [ $opt_policy_port ],
  82     host => '127.0.0.1',
  83     max_servers => $max_servers,
  84     max_dequeue => $opt_max_dequeue,
  85     check_for_dequeue => $opt_dequeue_time,
  86     log_level => 3,
  87     pid_file => $opt_pidfile,
  88     commandline => $opt_commandline,
  89     no_close_by_child => 1,
  90     setsid => $daemonize,
  91 };
  92
  93 my $database;
  94 if (defined($opt_database)) {
  95     $database = $opt_database;
  96 } else {
  97     $database = "Proxmox_ruledb";
  98 }
  99
 100 $SIG{'__WARN__'} = sub {
 101     my $err = $@;
 102     my $t = $_[0];
 103     chomp $t;
 104     syslog('warning', "WARNING: %s", $t);
 105     $@ = $err;
 106 };
 107
 108 sub update_rbl_stats {
 109     my ($dbh, $lcid) = @_;
 110
 111     my ($rbl_count, $pregreet_count) = PMG::Utils::scan_journal_for_rbl_rejects();
 112     return if !$rbl_count && !$pregreet_count;
 113
 114     my $timezone = tz_local_offset();;
 115     my $hour = int((time() + $timezone)/3600) * 3600;
 116
 117     my $sth = $dbh->prepare(
 118         'INSERT INTO LocalStat (Time, RBLCount, PregreetCount, CID, MTime) ' .
 119         'VALUES (?, ?, ?, ?, EXTRACT(EPOCH FROM now())) ' .
 120         'ON CONFLICT (Time, CID) DO UPDATE SET ' .
 121         'RBLCount = LocalStat.RBLCount + excluded.RBLCount, ' .
 122         'PregreetCount = LocalStat.PregreetCount + excluded.PregreetCount, ' .
 123         'MTime = excluded.MTime');
 124
 125     $sth->execute($hour, $rbl_count, $pregreet_count, $lcid);
 126     $sth->finish();
 127 };
 128
 129 sub run_dequeue {
 130     my $self = shift;
 131
 132     $self->log(2, "starting policy database maintainance (greylist, rbl)");
 133
 134     my $cinfo = PMG::ClusterConfig->new();
 135     my $lcid = $cinfo->{local}->{cid};
 136     my $role = $cinfo->{local}->{type} // '-';
 137
 138     my $dbh;
 139
 140     eval {
 141         $dbh = PMG::DBTools::open_ruledb($database);
 142     };
 143     my $err = $@;
 144
 145     if ($err) {
 146         $self->log(0, "ERROR: $err");
 147         return;
 148     }
 149
 150     my ($csec, $usec) = gettimeofday ();
 151
 152     eval { update_rbl_stats($dbh, $lcid); };
 153     $err = $@;
 154
 155     my ($csec_end, $usec_end) = gettimeofday ();
 156     my $rbltime = int (($csec_end-$csec)*1000 + ($usec_end - $usec)/1000);
 157     ($csec, $usec) = ($csec_end, $usec_end);
 158
 159     if ($err) {
 160         $self->log(0, "rbl update error: $err");
 161         # continue;
 162     }
 163
 164     my $now = time();
 165
 166     my $ecount = 0;
 167
 168     eval {
 169
 170         $dbh->begin_work;
 171
 172         # we do not lock the table here to avoid delays
 173         # but that is OK, because we only touch expired records
 174         # which do not change nornmally
 175         ## $dbh->do ("LOCK TABLE CGreylist IN ROW EXCLUSIVE MODE");
 176
 177         # move expired and undelivered records from Greylist to Statistic
 178
 179         my $rntxt = '';
 180         if (!$lcid) {
 181             $rntxt = "AND CID = 0";
 182         } else {
 183             if ($role eq 'master') {
 184                 # master is responsible for all non-cluster (deleted) nodes
 185                 foreach my $rcid (@{$cinfo->{remnodes}}) {
 186                     $rntxt .= $rntxt ? " AND CID != $rcid" : "AND (CID != $rcid";
 187                 }
 188                 $rntxt .= ")" if $rntxt;
 189             } else {
 190                 $rntxt = "AND (CID = 0 OR CID = $lcid)";
 191             }
 192         }
 193
 194
 195         my $cmds = '';
 196
 197         my $sth = $dbh->prepare(
 198             "SELECT distinct instance, sender FROM CGreylist " .
 199             "WHERE passed = 0 AND extime < ? $rntxt");
 200
 201         $sth->execute ($now);
 202
 203
 204         while (my $ref = $sth->fetchrow_hashref()) {
 205             my $sth2 = $dbh->prepare(
 206                 "SELECT * FROM CGreylist WHERE instance = ? AND sender = ?");
 207             $sth2->execute ($ref->{instance}, $ref->{sender});
 208             my $rctime;
 209             my @rcvrs;
 210             my $bc = 0;
 211
 212             while (my $ref2 = $sth2->fetchrow_hashref()) {
 213                 $rctime = $ref2->{rctime} if !$rctime;
 214                 $bc += $ref2->{blocked};
 215                 push  @rcvrs, $ref2->{receiver};
 216             }
 217
 218             $sth2->finish();
 219
 220             # hack: sometimes query sth2 does not return anything - maybe a
 221             # postgres bug? We simply ignore (when rctime is undefined) it
 222             # to avoid problems.
 223
 224             if ($rctime) {
 225                 $cmds .=  "SELECT nextval ('cstatistic_id_seq');" .
 226                     "INSERT INTO CStatistic " .
 227                     "(CID, RID, ID, Time, Bytes, Direction, Spamlevel, VirusInfo, PTime, Sender) VALUES (" .
 228                     "$lcid, currval ('cstatistic_id_seq'), currval ('cstatistic_id_seq'), ";
 229
 230                 my $sl = $bc >= 100000 ? 4 : 5;
 231                 $cmds .= $rctime . ", 0, '1', $sl, NULL, 0, ";
 232                 $cmds .= $dbh->quote ($ref->{sender}) . ');';
 233
 234                 foreach my $r (@rcvrs) {
 235                     my $tmp = $dbh->quote ($r);
 236                     $cmds .= "INSERT INTO CReceivers (CStatistic_CID, CStatistic_RID, Receiver, Blocked) ".
 237                         "VALUES ($lcid, currval ('cstatistic_id_seq'), $tmp, '1'); ";
 238                 }
 239             }
 240
 241             if (length ($cmds) > 100000) {
 242                 $dbh->do ($cmds);
 243                 $cmds = '';
 244             }
 245
 246             $ecount++;
 247
 248             # this produces too much log traffic
 249             # my $targets = join (", ", @rcvrs);
 250             #my $msg = "expire mail $ref->{instance} from $ref->{sender} to $targets";
 251             #$self->log (0, $msg);
 252         }
 253
 254         $dbh->do ($cmds) if $cmds;
 255
 256         $sth->finish();
 257
 258         if ($ecount > 0) {
 259             my $msg = "found $ecount expired mails in greylisting database";
 260             $self->log (0, $msg);
 261         }
 262
 263         $dbh->do ("DELETE FROM CGreylist WHERE extime < $now");
 264
 265         $dbh->commit;
 266     };
 267     $err = $@;
 268
 269     ($csec_end, $usec_end) = gettimeofday ();
 270     my $ptime = int (($csec_end-$csec)*1000 + ($usec_end - $usec)/1000);
 271
 272     if ($err) {
 273         $dbh->rollback if $dbh;
 274         $self->log(0, "greylist database update error: $err");
 275     }
 276
 277     $self->log(2, "end policy database maintainance ($rbltime ms, $ptime ms)");
 278
 279     $dbh->disconnect() if $dbh;
 280 }
 281
 282 sub pre_loop_hook {
 283     my $self = shift;
 284
 285     my $prop = $self->{server};
 286
 287     $prop->{log_level} = 3;
 288
 289     $self->log(0, "Policy daemon (re)started");
 290
 291     $SIG{'USR1'} = sub {
 292         # reloading server configuration
 293         if (defined $prop->{children}) {
 294             foreach my $pid (keys %{$prop->{children}}) {
 295                 kill(10, $pid); # SIGUSR1 childs
 296             }
 297         }
 298     };
 299
 300     my $sig_set = POSIX::SigSet->new;
 301     $sig_set->addset (&POSIX::SIGHUP);
 302     $sig_set->addset (&POSIX::SIGCHLD);
 303     my $old_sig_set = POSIX::SigSet->new();
 304
 305     sigprocmask (SIG_UNBLOCK, $sig_set, $old_sig_set);
 306 }
 307
 308 sub load_config {
 309     my $self = shift;
 310
 311     my $prop = $self->{server};
 312
 313     if ($self->{ruledb}) {
 314         $self->log(0, "reloading configuration $database");
 315         $self->{ruledb}->close();
 316     }
 317
 318     my $pmg_cfg = PMG::Config->new ();
 319     $self->{use_spf} = $pmg_cfg->get('mail', 'spf');
 320     $self->{use_greylist} = $pmg_cfg->get('mail', 'greylist');
 321
 322     if ($opt_testmode) {
 323         $self->{use_spf} = 1;
 324         $self->{use_greylist} = 1;
 325     }
 326
 327     my $nodename = PVE::INotify::nodename();
 328     $self->{fqdn} = PVE::Tools::get_fqdn($nodename);
 329
 330     my $cinfo = PMG::ClusterConfig->new();
 331     my $lcid = $cinfo->{local}->{cid};
 332     $self->{cinfo} = $cinfo;
 333     $self->{lcid} = $lcid;
 334
 335     my $dbh;
 336
 337     eval {
 338         $dbh = PMG::DBTools::open_ruledb($database);
 339         $self->{ruledb} = PMG::RuleDB->new($dbh);
 340         $self->{rulecache} = PMG::RuleCache->new($self->{ruledb});
 341     };
 342     if (my $err = $@) {
 343         $self->log(0, "ERROR: unable to load database : $err");
 344     }
 345
 346     $self->{reload_config} = 0;
 347 }
 348
 349 sub child_init_hook {
 350     my $self = shift;
 351
 352     my $prop = $self->{server};
 353
 354     $0 = 'pmgpolicy child';
 355
 356     setup_fork_signal_mask(0); # unblocking signals for children
 357
 358     eval {
 359         $self->load_config();
 360
 361         $self->{mux} = IO::Multiplex->new();
 362         $self->{mux}->set_callback_object($self);
 363
 364         my %dnsargs = (
 365             tcp_timeout => 3,
 366             udp_timeout => 3,
 367             retry => 1,
 368             retrans => 0,
 369             dnsrch => 0,
 370             defnames => 0,
 371             );
 372
 373         if ($opt_testmode) {
 374             # $dnsargs{nameservers} = [ qw (213.129.232.1 213.129.226.2) ];
 375         }
 376
 377         $self->{dns_resolver} = Net::DNS::Resolver->new(%dnsargs);
 378
 379         $self->{spf_server} = Mail::SPF::Server->new(
 380             hostname => $self->{fqdn}, dns_resolver => $self->{dns_resolver},
 381             default_authority_explanation => 'Rejected by SPF: %{C} is not a designated mailserver for %{S} (context %{_scope}, on %{R})');
 382     };
 383     if (my $err = $@) {
 384         $self->log(0, $err);
 385         $self->child_finish_hook;
 386         exit(-1);
 387     }
 388
 389     $SIG{'USR1'} = sub {
 390         $self->{reload_config} = 1;
 391     }
 392 }
 393
 394 sub child_finish_hook {
 395     my $self = shift;
 396
 397     my $prop = $self->{server};
 398
 399     $self->{ruledb}->close() if $self->{ruledb};
 400 }
 401
 402 sub get_spf_result {
 403     my ($self, $instance, $ip, $helo, $sender) = @_;
 404
 405     my $result;
 406     my $spf_header;
 407     my $local_expl;
 408     my $auth_expl;
 409
 410     # we only use helo tests when we have no sender,
 411     # helo is sometimes empty, so we cant use SPF helo tests
 412     # in that case - strange
 413     if ($helo && !$sender) {
 414         my $query;
 415
 416         if (defined ($self->{cache}->{$instance}) &&
 417             defined ($self->{cache}->{$instance}->{spf_helo_result})) {
 418
 419             $query = $self->{cache}->{$instance}->{spf_helo_result};
 420
 421         } else {
 422             my $request = Mail::SPF::Request->new(
 423                 scope => 'helo', identity => $helo, ip_address => $ip);
 424
 425             $query = $self->{cache}->{$instance}->{spf_helo_result} =
 426                 $self->{spf_server}->process ($request);
 427         }
 428
 429         $result = $query->code;
 430         $spf_header = $query->received_spf_header;
 431         $local_expl = $query->local_explanation;
 432         $auth_expl = $query->authority_explanation if $query->is_code('fail');
 433
 434         # return if we get a definitive result
 435         if ($result eq 'pass' || $result eq 'fail' || $result eq 'temperror') {
 436             return ($result, $spf_header, $local_expl, $auth_expl);
 437         }
 438     }
 439
 440     if ($sender) {
 441
 442         my $query;
 443
 444         if (defined ($self->{cache}->{$instance}) &&
 445             defined ($self->{cache}->{$instance}->{spf_mfrom_result})) {
 446
 447             $query = $self->{cache}->{$instance}->{spf_mfrom_result};
 448
 449         } else {
 450
 451             my $request = Mail::SPF::Request->new(
 452                 scope => 'mfrom', identity => $sender,
 453                 ip_address => $ip, helo_identity => $helo);
 454
 455             $query = $self->{cache}->{$instance}->{spf_mfrom_result} =
 456                 $self->{spf_server}->process($request);
 457         }
 458
 459         $result = $query->code;
 460         $spf_header = $query->received_spf_header;
 461         $local_expl = $query->local_explanation;
 462         $auth_expl = $query->authority_explanation if $query->is_code('fail');
 463
 464         return ($result, $spf_header, $local_expl, $auth_expl);
 465     }
 466
 467     return undef;
 468 }
 469
 470 sub is_backup_mx {
 471     my ($self, $ip, $receiver) = @_;
 472
 473     my ($rdomain) = $receiver =~ /([^@]+)$/;
 474
 475     my $dkey = "BKMX:$rdomain";
 476
 477     if (defined ($self->{cache}->{$dkey}) &&
 478         ($self->{cache}->{$dkey}->{status} == 1)) {
 479         return $self->{cache}->{$dkey}->{$ip};
 480     }
 481
 482     my $resolver = $self->{dns_resolver};
 483
 484     if (my $mx = $resolver->send($rdomain, 'MX')) {
 485         $self->{cache}->{$dkey}->{status} = 1;
 486         my @mxa = grep { $_->type eq 'MX' } $mx->answer;
 487         my @mxl = sort { $a->preference <=> $b->preference } @mxa;
 488         # shift @mxl; # optionaly skip primary MX ?
 489         foreach my $rr (@mxl) {
 490             my $a = $resolver->send ($rr->exchange, 'A');
 491             if ($a) {
 492                 foreach my $rra ($a->answer) {
 493                     if ($rra->type eq 'A') {
 494                         $self->{cache}->{$dkey}->{$rra->address} = 1;
 495                     }
 496                 }
 497             }
 498         }
 499     } else {
 500         $self->{cache}->{$dkey}->{status} = 0;
 501     }
 502
 503     return $self->{cache}->{$dkey}->{$ip};
 504 }
 505
 506 sub greylist_value {
 507     my ($self, $ctime, $helo, $ip, $sender, $rcpt, $instance) = @_;
 508
 509     my $rulecache = $self->{rulecache};
 510
 511     my $dbh = $self->{ruledb}->{dbh};
 512
 513     # try to reconnect if database connection is broken
 514     if (!$dbh->ping) {
 515         $self->log(0, 'Database connection broken - trying to reconnect');
 516         my $dbh;
 517         eval {
 518             $dbh = PMG::DBTools::open_ruledb($database);
 519         };
 520         my $err = $@;
 521         if ($err) {
 522             $self->log(0, "unable to reconnect to database server: $err");
 523             return 'dunno';
 524         }
 525         $self->{ruledb} = PMG::RuleDB->new($dbh);
 526     }
 527
 528     # some sender substitutions
 529     my ($user, $domain) = split('@', $sender, 2);
 530     if (defined ($user) && defined ($domain)) {
 531         # see http://cr.yp.to/proto/verp.txt
 532         $user =~ s/\+.*//; # strip extensions  (mailing-list VERP)
 533         $user =~ s/\b\d+\b/#/g; #replace nubmers in VERP address
 534         $sender = "$user\@$domain";
 535     }
 536
 537     if ($self->is_backup_mx($ip, $rcpt)) {
 538         $self->log(3, "accept mails from backup MX host - $ip");
 539         return 'dunno';
 540     }
 541
 542     # greylist exclusion (sender whitelist)
 543     if ($rulecache->greylist_match ($sender, $ip)) {
 544         $self->log(3, "accept mails from whitelist - $ip");
 545         return 'dunno';
 546     }
 547
 548     # greylist exclusion (receiver whitelist)
 549     if ($rulecache->greylist_match_receiver ($rcpt)) {
 550         $self->log(3, "accept mails to whitelist - <$rcpt>");
 551         return 'dunno';
 552     }
 553
 554     my ($net, $host) = $ip =~ m/(\d+\.\d+\.\d+)\.(\d+)/; # IPv4 for now
 555     return 'dunno' if !defined($net);
 556     my $masklen = 24;
 557
 558     my $spf_header;
 559
 560     if ((!$opt_testmode && $self->{use_spf}) ||
 561         ($opt_testmode && ($rcpt =~ m/^testspf/))) {
 562
 563         # ask SPF
 564         my $spf_result;
 565         my $local_expl,
 566         my $auth_expl;
 567
 568         my $previous_alarm;
 569
 570         my ($result, $smtp_comment, $header_comment);
 571
 572         eval {
 573             $previous_alarm = alarm(10);
 574             local $SIG{ALRM} = sub { die "SPF timeout\n" };
 575
 576             ($result, $spf_header, $local_expl, $auth_expl) =
 577                 $self->get_spf_result($instance, $ip, $helo, $sender);
 578
 579             alarm(0); # avoid race condition
 580         };
 581         my $err = $@;
 582
 583         alarm($previous_alarm) if defined($previous_alarm);
 584
 585         if ($err) {
 586             $err = $err->text if UNIVERSAL::isa ($err, 'Mail::SPF::Exception');
 587             $self->log (0, $err);
 588         } else {
 589
 590             if ($result && $result eq 'pass') {
 591                 $self->log(3, "SPF says $result");
 592                 $spf_result = $spf_header ? "prepend $spf_header" : 'dunno';
 593             }
 594
 595             if ($result && $result eq 'fail') {
 596                 $self->log(3, "SPF says $result");
 597                 $spf_result = "reject ${auth_expl}";
 598
 599                 eval {
 600
 601                     $dbh->begin_work;
 602
 603                     # try to avoid locks everywhere - we use merge instead of insert
 604                     #$dbh->do ("LOCK TABLE CGreylist IN ROW EXCLUSIVE MODE");
 605
 606                     # check if there is already a record in the GL database
 607                     my $sth = $dbh->prepare(
 608                         "SELECT * FROM CGreylist " .
 609                         "WHERE IPNet::cidr = network(set_masklen(?, ?)) AND ".
 610                         "Sender = ? AND Receiver = ?");
 611
 612                     $sth->execute($ip, $masklen, $sender, $rcpt);
 613                     my $ref = $sth->fetchrow_hashref();
 614                     $sth->finish();
 615
 616                     # else add an entry to the GL Database with short
 617                     # expiration time. run_dequeue() moves those entries into the statistic
 618                     # table later. We set 'blocked' to 100000 to identify those entries.
 619
 620                     if (!defined($ref->{rctime})) {
 621
 622                         # FIXME: drop Host column with PMG 7.0
 623                         $dbh->do(PMG::DBTools::cgreylist_merge_sql(1), undef,
 624                                  $ip, $masklen, 0, $sender, $rcpt, $instance,
 625                                  $ctime, $ctime + 10, 0, 100000, 0, $ctime, $self->{lcid});
 626                     }
 627
 628                     $dbh->commit;
 629                 };
 630                 if (my $err = $@) {
 631                     $dbh->rollback;
 632                     $self->log(0, $err);
 633                 }
 634             }
 635         }
 636
 637         return $spf_result if $spf_result;
 638     }
 639
 640
 641     my $res = 'dunno';
 642
 643     # add spf_header once - SA can re-use this information
 644     if (!defined($self->{cache}->{$instance}) ||
 645         !$self->{cache}->{$instance}->{spf_header_added}) {
 646         $res = "prepend $spf_header" if $spf_header;
 647         $self->{cache}->{$instance}->{spf_header_added} = 1;
 648     }
 649
 650     return $res if !$self->{use_greylist};
 651
 652     my $defer_res = "defer_if_permit Service is unavailable (try later)";
 653
 654     eval {
 655
 656         # we dont use alarm here, because it does not work with DBI
 657
 658         $dbh->begin_work;
 659
 660         # try to avoid locks everywhere - we use merge instead of insert
 661         #$dbh->do ("LOCK TABLE CGreylist IN ROW EXCLUSIVE MODE");
 662
 663         my $sth = $dbh->prepare(
 664             "SELECT * FROM CGreylist " .
 665             "WHERE IPNet::cidr = network(set_masklen(?, ?)) AND ".
 666             "Sender = ? AND Receiver = ?");
 667
 668         $sth->execute($ip, $masklen, $sender, $rcpt);
 669
 670         my $ref = $sth->fetchrow_hashref();
 671
 672         $sth->finish();
 673
 674         if (!defined($ref->{rctime})) {
 675
 676             $dbh->do(PMG::DBTools::cgreylist_merge_sql(1), undef,
 677                     $ip, $masklen, 0, $sender, $rcpt, $instance,
 678                     $ctime, $ctime + $greylist_lifetime, 0, 1, 0, $ctime, $self->{lcid});
 679
 680             $res = $defer_res;
 681             $self->log(3, "defer greylisted mail");
 682         } else {
 683             my $age = $ctime - $ref->{rctime};
 684
 685             if ($age < $greylist_delay) {
 686                 # defer (resent within greylist_delay window)
 687                 $res = $defer_res;
 688                 $self->log(3, "defer greylisted mail");
 689                 $dbh->do("UPDATE CGreylist " .
 690                         "SET Blocked = Blocked + 1, MTime = ? " .
 691                         "WHERE IPNet::cidr = network(set_masklen(?, ?)) AND ".
 692                         "Sender = ? AND Receiver = ?", undef,
 693                         $ctime, $ip, $masklen, $sender, $rcpt);
 694             } else {
 695                 if ($ctime < $ref->{extime}) {
 696                     # accept (not expired)
 697                     my $lifetime = $sender eq "" ? 0 : $greylist_awlifetime;
 698                     my $delay = $ref->{passed} ? "" : "Delay = $age, ";
 699                     $dbh->do("UPDATE CGreylist " .
 700                             "SET Passed = Passed + 1, $delay ExTime = ?, MTime = ? " .
 701                             "WHERE IPNet::cidr = network(set_masklen(?, ?)) AND ".
 702                             "Sender = ? AND Receiver = ?", undef,
 703                             $ctime + $lifetime, $ctime, $ip, $masklen, $sender, $rcpt);
 704                 } else {
 705                     # defer (record is expired)
 706                     $res = $defer_res;
 707                     $dbh->do("UPDATE CGreylist " .
 708                             "SET RCTime = ?, ExTime = ?, MTime = ?, Instance = ?, " .
 709                             "Blocked = 1, Passed = 0 " .
 710                             "WHERE IPNet::cidr = network(set_masklen(?, ?)) AND ".
 711                             "Sender = ? AND Receiver = ?", undef,
 712                             $ctime, $ctime + $greylist_lifetime, $ctime, $instance,
 713                             $ip, $masklen, $sender, $rcpt);
 714                 }
 715             }
 716         }
 717
 718         $dbh->commit;
 719     };
 720     if (my $err = $@) {
 721         $dbh->rollback;
 722         $self->log (0, $err);
 723     }
 724
 725     return $res;
 726 }
 727
 728 # shutdown connections: we need this - else file handles are
 729 # not closed and we run out of handles
 730 sub mux_eof {
 731     my ($self, $mux, $fh) = @_;
 732
 733     $mux->shutdown($fh, 1);
 734 }
 735
 736
 737 my $last_reload_test = 0;
 738 my $last_confid_version;
 739 my (undef, $pmgconffilename) = PVE::INotify::ccache_info('pmg.conf');
 740 sub test_config_version {
 741
 742     my $ctime = time();
 743
 744     if (($ctime - $last_reload_test) < 5) { return 0; }
 745
 746     $last_reload_test = $ctime;
 747
 748     my $version = PVE::INotify::poll_changes($pmgconffilename);
 749
 750     if (!defined($last_confid_version) ||
 751         $last_confid_version != $version) {
 752         $last_confid_version = $version;
 753         return 1;
 754     }
 755
 756     return 0;
 757 }
 758
 759 sub mux_input {
 760     my ($self, $mux, $fh, $dataref) = @_;
 761     my $prop = $self->{server};
 762
 763     my $attribute = {};
 764
 765     eval {
 766         $self->{reload_config} = 1 if test_config_version();
 767         $self->load_config() if $self->{reload_config};
 768
 769         while ($$dataref =~ s/^([^\r\n]*)\r?\n//) {
 770             my $line = $1;
 771             next if !defined ($line);
 772
 773             if ($line =~ m/([^=]+)=(.*)/) {
 774                 $attribute->{substr($1, 0, 255)} = substr($2, 0, 255);
 775             } elsif ($line eq '') {
 776                 my $res = 'dunno';
 777                 my $ctime = time;
 778
 779                 if ($opt_testmode) {
 780                     die "undefined test time :ERROR" if !defined $attribute->{testtime};
 781                     $ctime = $attribute->{testtime};
 782                 }
 783
 784                 if ($attribute->{instance} && $attribute->{recipient} &&
 785                     $attribute->{client_address} && $attribute->{request} &&
 786                     $attribute->{request} eq 'smtpd_access_policy') {
 787
 788                     eval {
 789
 790                         $res = $self->greylist_value(
 791                             $ctime,
 792                             lc ($attribute->{helo_name}),
 793                             lc ($attribute->{client_address}),
 794                             lc ($attribute->{sender}),
 795                             lc ($attribute->{recipient}),
 796                             lc ($attribute->{instance}));
 797                     };
 798                     if (my $err = $@) {
 799                         $self->log(0, $err);
 800                     }
 801                 }
 802
 803                 print $fh "action=$res\n\n";
 804
 805                 $attribute = {};
 806             } else {
 807                 $self->log(0, "greylist policy protocol error - got '%s'", $line);
 808             }
 809         }
 810     };
 811     my $err = $@;
 812
 813     # remove remaining data, if any
 814     if ($$dataref ne '') {
 815         $self->log(0, "greylist policy protocol error - unused data '%s'", $$dataref);
 816         $$dataref = '';
 817     }
 818
 819     $self->log(0, $err) if $err;
 820 }
 821
 822 sub restart_close_hook {
 823     my $self = shift;
 824
 825     my $sig_set = POSIX::SigSet->new;
 826     $sig_set->addset(&POSIX::SIGHUP);
 827     $sig_set->addset(&POSIX::SIGCHLD); # to avoid zombies
 828     my $old_sig_set = POSIX::SigSet->new();
 829
 830     sigprocmask(SIG_BLOCK, $sig_set, $old_sig_set);
 831 }
 832
 833 sub pre_server_close_hook {
 834     my $self = shift;
 835
 836     my $prop = $self->{server};
 837
 838     if (defined $prop->{_HUP}) {
 839         undef $prop->{pid_file_unlink};
 840     }
 841
 842     if (defined $prop->{children}) {
 843         foreach my $pid (keys %{$prop->{children}}) {
 844             kill(1, $pid); # HUP childs
 845         }
 846     }
 847
 848     # nicely shutdown childs (give them max 30 seconds to shut down)
 849     my $previous_alarm = alarm(30);
 850     eval {
 851         local $SIG{ALRM} = sub { die "Timed Out!\n" };
 852
 853         my $pid;
 854         1 while ((($pid = waitpid(-1, 0)) > 0) || ($! == EINTR));
 855
 856         alarm(0); # avoid race
 857     };
 858     alarm ($previous_alarm);
 859 }
 860
 861 sub setup_fork_signal_mask {
 862     my $block = shift;
 863
 864     my $sig_set = POSIX::SigSet->new;
 865     $sig_set->addset(&POSIX::SIGINT);
 866     $sig_set->addset(&POSIX::SIGTERM);
 867     $sig_set->addset(&POSIX::SIGQUIT);
 868     $sig_set->addset(&POSIX::SIGHUP);
 869     my $old_sig_set = POSIX::SigSet->new();
 870
 871     if ($block) {
 872         sigprocmask (SIG_BLOCK, $sig_set, $old_sig_set);
 873     } else {
 874         sigprocmask (SIG_UNBLOCK, $sig_set, $old_sig_set);
 875     }
 876 }
 877
 878 # subroutine to start up a specified number of children.
 879 # We need to block signals until handlers are set up correctly.
 880 # Else its possible that HUP occurs after fork, which triggers
 881 # singal TERM at childs and calls server_close() instead of
 882 # simply exit the child.
 883 # Note: on server startup signals are setup to trigger
 884 # asynchronously for a short period of time (in PreForkSimple]::loop,
 885 # run_n_children is called before run_parent)
 886 # Net::Server::PreFork does not have this problem, because it is using
 887 # signal HUP stop children
 888 sub run_n_children {
 889     my ($self, $n)  = @_;
 890
 891     my $prop  = $self->{server};
 892
 893     setup_fork_signal_mask(1); # block signals
 894
 895     $self->SUPER::run_n_children($n);
 896
 897     setup_fork_signal_mask(0); # unblocking signals for parent
 898 }
 899
 900 # test sig_hup with: for ((;;)) ;do kill -HUP  `cat /run/pmgpolicy.pid`; done;
 901 # wrapper to avoid multiple calls to sig_hup
 902 sub sig_hup {
 903     my $self = shift;
 904
 905     my $prop = $self->{server};
 906
 907     return if defined($prop->{_HUP}); # do not call twice
 908
 909     $self->SUPER::sig_hup();
 910 }
 911
 912 ### child process which will accept on the port
 913 sub run_child {
 914     my $self = shift;
 915
 916     my $prop = $self->{server};
 917
 918     $self->log(4, "Child Preforked ($$)\n");
 919
 920     # set correct signal handlers before enabling signals again
 921     $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = sub {
 922         $self->child_finish_hook;
 923         exit;
 924     };
 925
 926     delete $prop->{children};
 927
 928     $self->child_init_hook;
 929
 930     # accept connections
 931
 932     my $sock = $prop->{sock}->[0];
 933
 934     # make sure we got a good sock
 935     if (!defined ($sock)){
 936         $self->log(0, "ERROR: Received a bad socket");
 937         exit (-1);
 938     }
 939
 940     # sometimes the socket is not usable, don't know why
 941     my $flags = fcntl($sock, F_GETFL, 0);
 942     if (!$flags) {
 943         $self->log(0, "socket not ready - $!");
 944         exit (-1);
 945     }
 946
 947     # cache is limited, because postfix does max. 100 queries
 948     $self->{cache} = {};
 949
 950     eval {
 951         my $mux = $self->{mux};
 952         $mux->listen ($sock);
 953         $mux->loop;
 954     };
 955     if (my $err = $@) {
 956         $self->log(0, "ERROR: $err");
 957     }
 958
 959     $self->child_finish_hook;
 960
 961     exit;
 962 }
 963
 964 my $syslog_map = {
 965     0 => 'err',
 966     1 => 'warning',
 967     2 => 'notice',
 968     3 => 'info',
 969     4 => 'debug'
 970 };
 971
 972 sub log {
 973     my ($self, $level, $msg, @therest) = @_;
 974
 975     my $prop = $self->{server};
 976
 977     return if $level =~ /^\d+$/ && $level > $prop->{log_level};
 978
 979     $level = $syslog_map->{$level} || $level;
 980     if (@therest) {
 981         syslog($level, $msg, @therest);
 982     } else {
 983         syslog ($level, $msg);
 984     }
 985 }
 986
 987 my $server = bless {
 988     server => $server_attr,
 989 };
 990
 991 $server->sig_chld(); # avoid zombies after restart
 992
 993 $server->run ();
 994
 995 exit (0);
 996
 997 __END__
 998
 999 =head1 NAME
1000
1001 pmgpolicy - The Proxmox policy daemon
1002
1003 =head1 SYNOPSIS
1004
1005 pmgpolicy
1006
1007 =head1 DESCRIPTION
1008
1009 Documentation is available at www.proxmox.com