src/bin/pmgpolicy

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use Getopt::Long;
   6 use POSIX qw(errno_h signal_h);
   7
   8 use Net::Server::PreForkSimple;
   9 use Net::DNS::Resolver;
  10 use Mail::SPF;
  11 use Fcntl;
  12 use Fcntl ':flock';
  13 use IO::Multiplex;
  14 use Time::HiRes qw(gettimeofday);
  15 use Time::Zone;
  16
  17 use PVE::INotify;
  18 use PVE::Tools;
  19 use PVE::SafeSyslog;
  20
  21 use PMG::Utils;
  22 use PMG::RuleDB;
  23 use PMG::DBTools;
  24 use PMG::RuleCache;
  25 use PMG::Config;
  26 use PMG::ClusterConfig;
  27
  28 use base qw(Net::Server::PreForkSimple);
  29
  30 my $greylist_delay = 3*60;            # greylist window
  31 my $greylist_lifetime = 3600*24*2;    # retry window
  32 my $greylist_awlifetime = 3600*24*36; # expire window
  33
  34 my $opt_commandline = [$0, @ARGV];
  35
  36 my $opt_max_dequeue = 1;
  37 my $opt_dequeue_time = 60*2;
  38
  39 my $opt_testmode;
  40 my $opt_pidfile;
  41 my $opt_database;
  42 my $opt_policy_port = 10022;
  43
  44 my %_opts = (
  45     'pidfile=s' => \$opt_pidfile,
  46     'testmode' => \$opt_testmode,
  47     'database=s' => \$opt_database,
  48     'port=i' => \$opt_policy_port,
  49 );
  50 if (!GetOptions(%_opts)) {
  51     die "usage error\n";
  52     exit (-1);
  53 }
  54
  55 $opt_pidfile = "/run/pmgpolicy.pid" if !$opt_pidfile;
  56 $opt_max_dequeue = 0 if $opt_testmode;
  57
  58 initlog('pmgpolicy', 'mail');
  59
  60 my $max_servers = 5;
  61
  62 if (!$opt_testmode) {
  63
  64     my $pmg_cfg = PMG::Config->new ();
  65     my $demo = $pmg_cfg->get('admin', 'demo');
  66     $max_servers = $pmg_cfg->get('mail', 'max_policy');
  67
  68     if ($demo) {
  69         syslog('info', 'demo mode detected - not starting server');
  70         exit(0);
  71     }
  72 }
  73
  74 my $daemonize = 1;
  75 if (defined ($ENV{BOUND_SOCKETS})) {
  76     $daemonize = undef;
  77 }
  78
  79
  80 my $server_attr = {
  81     port => [ $opt_policy_port ],
  82     host => '127.0.0.1',
  83     max_servers => $max_servers,
  84     max_dequeue => $opt_max_dequeue,
  85     check_for_dequeue => $opt_dequeue_time,
  86     log_level => 3,
  87     pid_file => $opt_pidfile,
  88     commandline => $opt_commandline,
  89     no_close_by_child => 1,
  90     setsid => $daemonize,
  91 };
  92
  93 my $database;
  94 if (defined($opt_database)) {
  95     $database = $opt_database;
  96 } else {
  97     $database = "Proxmox_ruledb";
  98 }
  99
 100 $SIG{'__WARN__'} = sub {
 101     my $err = $@;
 102     my $t = $_[0];
 103     chomp $t;
 104     syslog('warning', "WARNING: %s", $t);
 105     $@ = $err;
 106 };
 107
 108 sub update_rbl_stats {
 109     my ($dbh, $lcid) = @_;
 110
 111     my ($rbl_count, $pregreet_count) = PMG::Utils::scan_journal_for_rbl_rejects();
 112     return if !$rbl_count && !$pregreet_count;
 113
 114     my $timezone = tz_local_offset();;
 115     my $hour = int((time() + $timezone)/3600) * 3600;
 116
 117     my $sth = $dbh->prepare(
 118         'INSERT INTO LocalStat (Time, RBLCount, PregreetCount, CID, MTime) ' .
 119         'VALUES (?, ?, ?, ?, EXTRACT(EPOCH FROM now())) ' .
 120         'ON CONFLICT (Time, CID) DO UPDATE SET ' .
 121         'RBLCount = LocalStat.RBLCount + excluded.RBLCount, ' .
 122         'PregreetCount = LocalStat.PregreetCount + excluded.PregreetCount, ' .
 123         'MTime = excluded.MTime');
 124
 125     $sth->execute($hour, $rbl_count, $pregreet_count, $lcid);
 126     $sth->finish();
 127 };
 128
 129 sub run_dequeue {
 130     my $self = shift;
 131
 132     $self->log(2, "starting policy database maintainance (greylist, rbl)");
 133
 134     my $cinfo = PMG::ClusterConfig->new();
 135     my $lcid = $cinfo->{local}->{cid};
 136     my $role = $cinfo->{local}->{type} // '-';
 137
 138     my $dbh;
 139
 140     eval {
 141         $dbh = PMG::DBTools::open_ruledb($database);
 142     };
 143     my $err = $@;
 144
 145     if ($err) {
 146         $self->log(0, "ERROR: $err");
 147         return;
 148     }
 149
 150     my ($csec, $usec) = gettimeofday ();
 151
 152     eval { update_rbl_stats($dbh, $lcid); };
 153     $err = $@;
 154
 155     my ($csec_end, $usec_end) = gettimeofday ();
 156     my $rbltime = int (($csec_end-$csec)*1000 + ($usec_end - $usec)/1000);
 157     ($csec, $usec) = ($csec_end, $usec_end);
 158
 159     if ($err) {
 160         $self->log(0, "rbl update error: $err");
 161         # continue;
 162     }
 163
 164     my $now = time();
 165
 166     my $ecount = 0;
 167
 168     eval {
 169
 170         $dbh->begin_work;
 171
 172         # we do not lock the table here to avoid delays
 173         # but that is OK, because we only touch expired records
 174         # which do not change nornmally
 175         ## $dbh->do ("LOCK TABLE CGreylist IN ROW EXCLUSIVE MODE");
 176
 177         # move expired and undelivered records from Greylist to Statistic
 178
 179         my $rntxt = '';
 180         if (!$lcid) {
 181             $rntxt = "AND CID = 0";
 182         } else {
 183             if ($role eq 'master') {
 184                 # master is responsible for all non-cluster (deleted) nodes
 185                 foreach my $rcid (@{$cinfo->{remnodes}}) {
 186                     $rntxt .= $rntxt ? " AND CID != $rcid" : "AND (CID != $rcid";
 187                 }
 188                 $rntxt .= ")" if $rntxt;
 189             } else {
 190                 $rntxt = "AND (CID = 0 OR CID = $lcid)";
 191             }
 192         }
 193
 194
 195         my $cmds = '';
 196
 197         my $sth = $dbh->prepare(
 198             "SELECT distinct instance, sender FROM CGreylist " .
 199             "WHERE passed = 0 AND extime < ? $rntxt");
 200
 201         $sth->execute ($now);
 202
 203
 204         while (my $ref = $sth->fetchrow_hashref()) {
 205             my $sth2 = $dbh->prepare(
 206                 "SELECT * FROM CGreylist WHERE instance = ? AND sender = ?");
 207             $sth2->execute ($ref->{instance}, $ref->{sender});
 208             my $rctime;
 209             my @rcvrs;
 210             my $bc = 0;
 211
 212             while (my $ref2 = $sth2->fetchrow_hashref()) {
 213                 $rctime = $ref2->{rctime} if !$rctime;
 214                 $bc += $ref2->{blocked};
 215                 push  @rcvrs, $ref2->{receiver};
 216             }
 217
 218             $sth2->finish();
 219
 220             # hack: sometimes query sth2 does not return anything - maybe a
 221             # postgres bug? We simply ignore (when rctime is undefined) it
 222             # to avoid problems.
 223
 224             if ($rctime) {
 225                 $cmds .=  "SELECT nextval ('cstatistic_id_seq');" .
 226                     "INSERT INTO CStatistic " .
 227                     "(CID, RID, ID, Time, Bytes, Direction, Spamlevel, VirusInfo, PTime, Sender) VALUES (" .
 228                     "$lcid, currval ('cstatistic_id_seq'), currval ('cstatistic_id_seq'), ";
 229
 230                 my $sl = $bc >= 100000 ? 4 : 5;
 231                 $cmds .= $rctime . ", 0, '1', $sl, NULL, 0, ";
 232                 $cmds .= $dbh->quote ($ref->{sender}) . ');';
 233
 234                 foreach my $r (@rcvrs) {
 235                     my $tmp = $dbh->quote ($r);
 236                     $cmds .= "INSERT INTO CReceivers (CStatistic_CID, CStatistic_RID, Receiver, Blocked) ".
 237                         "VALUES ($lcid, currval ('cstatistic_id_seq'), $tmp, '1'); ";
 238                 }
 239             }
 240
 241             if (length ($cmds) > 100000) {
 242                 $dbh->do ($cmds);
 243                 $cmds = '';
 244             }
 245
 246             $ecount++;
 247
 248             # this produces too much log traffic
 249             # my $targets = join (", ", @rcvrs);
 250             #my $msg = "expire mail $ref->{instance} from $ref->{sender} to $targets";
 251             #$self->log (0, $msg);
 252         }
 253
 254         $dbh->do ($cmds) if $cmds;
 255
 256         $sth->finish();
 257
 258         if ($ecount > 0) {
 259             my $msg = "found $ecount expired mails in greylisting database";
 260             $self->log (0, $msg);
 261         }
 262
 263         $dbh->do ("DELETE FROM CGreylist WHERE extime < $now");
 264
 265         $dbh->commit;
 266     };
 267     $err = $@;
 268
 269     ($csec_end, $usec_end) = gettimeofday ();
 270     my $ptime = int (($csec_end-$csec)*1000 + ($usec_end - $usec)/1000);
 271
 272     if ($err) {
 273         $dbh->rollback if $dbh;
 274         $self->log(0, "greylist database update error: $err");
 275     }
 276
 277     $self->log(2, "end policy database maintainance ($rbltime ms, $ptime ms)");
 278
 279     $dbh->disconnect() if $dbh;
 280 }
 281
 282 sub pre_loop_hook {
 283     my $self = shift;
 284
 285     my $prop = $self->{server};
 286
 287     $prop->{log_level} = 3;
 288
 289     $self->log(0, "Policy daemon (re)started");
 290
 291     $SIG{'USR1'} = sub {
 292         # reloading server configuration
 293         if (defined $prop->{children}) {
 294             foreach my $pid (keys %{$prop->{children}}) {
 295                 kill(10, $pid); # SIGUSR1 childs
 296             }
 297         }
 298     };
 299
 300     my $sig_set = POSIX::SigSet->new;
 301     $sig_set->addset (&POSIX::SIGHUP);
 302     $sig_set->addset (&POSIX::SIGCHLD);
 303     my $old_sig_set = POSIX::SigSet->new();
 304
 305     sigprocmask (SIG_UNBLOCK, $sig_set, $old_sig_set);
 306 }
 307
 308 sub load_config {
 309     my $self = shift;
 310
 311     my $prop = $self->{server};
 312
 313     if ($self->{ruledb}) {
 314         $self->log(0, "reloading configuration $database");
 315         $self->{ruledb}->close();
 316     }
 317
 318     my $pmg_cfg = PMG::Config->new ();
 319     $self->{use_spf} = $pmg_cfg->get('mail', 'spf');
 320     $self->{use_greylist} = $pmg_cfg->get('mail', 'greylist');
 321
 322     if ($opt_testmode) {
 323         $self->{use_spf} = 1;
 324         $self->{use_greylist} = 1;
 325     }
 326
 327     my $nodename = PVE::INotify::nodename();
 328     $self->{fqdn} = PVE::Tools::get_fqdn($nodename);
 329
 330     my $cinfo = PMG::ClusterConfig->new();
 331     my $lcid = $cinfo->{local}->{cid};
 332     $self->{cinfo} = $cinfo;
 333     $self->{lcid} = $lcid;
 334
 335     my $dbh;
 336
 337     eval {
 338         $dbh = PMG::DBTools::open_ruledb($database);
 339         $self->{ruledb} = PMG::RuleDB->new($dbh);
 340         $self->{rulecache} = PMG::RuleCache->new($self->{ruledb});
 341     };
 342     if (my $err = $@) {
 343         $self->log(0, "ERROR: unable to load database : $err");
 344     }
 345
 346     $self->{reload_config} = 0;
 347 }
 348
 349 sub child_init_hook {
 350     my $self = shift;
 351
 352     my $prop = $self->{server};
 353
 354     $0 = 'pmgpolicy child';
 355
 356     setup_fork_signal_mask(0); # unblocking signals for children
 357
 358     eval {
 359         $self->load_config();
 360
 361         $self->{mux} = IO::Multiplex->new();
 362         $self->{mux}->set_callback_object($self);
 363
 364         my %dnsargs = (
 365             tcp_timeout => 3,
 366             udp_timeout => 3,
 367             retry => 1,
 368             retrans => 0,
 369             dnsrch => 0,
 370             defnames => 0,
 371             );
 372
 373         if ($opt_testmode) {
 374             # $dnsargs{nameservers} = [ qw (213.129.232.1 213.129.226.2) ];
 375         }
 376
 377         $self->{dns_resolver} = Net::DNS::Resolver->new(%dnsargs);
 378
 379         $self->{spf_server} = Mail::SPF::Server->new(
 380             hostname => $self->{fqdn}, dns_resolver => $self->{dns_resolver},
 381             default_authority_explanation => 'Rejected by SPF: %{C} is not a designated mailserver for %{S} (context %{_scope}, on %{R})');
 382     };
 383     if (my $err = $@) {
 384         $self->log(0, $err);
 385         $self->child_finish_hook;
 386         exit(-1);
 387     }
 388
 389     $SIG{'USR1'} = sub {
 390         $self->{reload_config} = 1;
 391     }
 392 }
 393
 394 sub child_finish_hook {
 395     my $self = shift;
 396
 397     my $prop = $self->{server};
 398
 399     $self->{ruledb}->close() if $self->{ruledb};
 400 }
 401
 402 sub get_spf_result {
 403     my ($self, $instance, $ip, $helo, $sender) = @_;
 404
 405     my $result;
 406     my $spf_header;
 407     my $local_expl;
 408     my $auth_expl;
 409
 410     # we only use helo tests when we have no sender,
 411     # helo is sometimes empty, so we cant use SPF helo tests
 412     # in that case - strange
 413     if ($helo && !$sender) {
 414         my $query;
 415
 416         if (defined ($self->{cache}->{$instance}) &&
 417             defined ($self->{cache}->{$instance}->{spf_helo_result})) {
 418
 419             $query = $self->{cache}->{$instance}->{spf_helo_result};
 420
 421         } else {
 422             my $request = Mail::SPF::Request->new(
 423                 scope => 'helo', identity => $helo, ip_address => $ip);
 424
 425             $query = $self->{cache}->{$instance}->{spf_helo_result} =
 426                 $self->{spf_server}->process ($request);
 427         }
 428
 429         $result = $query->code;
 430         $spf_header = $query->received_spf_header;
 431         $local_expl = $query->local_explanation;
 432         $auth_expl = $query->authority_explanation if $query->is_code('fail');
 433
 434         # return if we get a definitive result
 435         if ($result eq 'pass' || $result eq 'fail' || $result eq 'temperror') {
 436             return ($result, $spf_header, $local_expl, $auth_expl);
 437         }
 438     }
 439
 440     if ($sender) {
 441
 442         my $query;
 443
 444         if (defined ($self->{cache}->{$instance}) &&
 445             defined ($self->{cache}->{$instance}->{spf_mfrom_result})) {
 446
 447             $query = $self->{cache}->{$instance}->{spf_mfrom_result};
 448
 449         } else {
 450
 451             my $request = Mail::SPF::Request->new(
 452                 scope => 'mfrom', identity => $sender,
 453                 ip_address => $ip, helo_identity => $helo);
 454
 455             $query = $self->{cache}->{$instance}->{spf_mfrom_result} =
 456                 $self->{spf_server}->process($request);
 457         }
 458
 459         $result = $query->code;
 460         $spf_header = $query->received_spf_header;
 461         $local_expl = $query->local_explanation;
 462         $auth_expl = $query->authority_explanation if $query->is_code('fail');
 463
 464         return ($result, $spf_header, $local_expl, $auth_expl);
 465     }
 466
 467     return undef;
 468 }
 469
 470 sub is_backup_mx {
 471     my ($self, $ip, $receiver) = @_;
 472
 473     my ($rdomain) = $receiver =~ /([^@]+)$/;
 474
 475     my $dkey = "BKMX:$rdomain";
 476
 477     if (defined ($self->{cache}->{$dkey}) &&
 478         ($self->{cache}->{$dkey}->{status} == 1)) {
 479         return $self->{cache}->{$dkey}->{$ip};
 480     }
 481
 482     my $resolver = $self->{dns_resolver};
 483
 484     if (my $mx = $resolver->send($rdomain, 'MX')) {
 485         $self->{cache}->{$dkey}->{status} = 1;
 486         my @mxa = grep { $_->type eq 'MX' } $mx->answer;
 487         my @mxl = sort { $a->preference <=> $b->preference } @mxa;
 488         # shift @mxl; # optionaly skip primary MX ?
 489         foreach my $rr (@mxl) {
 490             my $a = $resolver->send ($rr->exchange, 'A');
 491             if ($a) {
 492                 foreach my $rra ($a->answer) {
 493                     if ($rra->type eq 'A') {
 494                         $self->{cache}->{$dkey}->{$rra->address} = 1;
 495                     }
 496                 }
 497             }
 498         }
 499     } else {
 500         $self->{cache}->{$dkey}->{status} = 0;
 501     }
 502
 503     return $self->{cache}->{$dkey}->{$ip};
 504 }
 505
 506 sub greylist_value {
 507     my ($self, $ctime, $helo, $ip, $sender, $rcpt, $instance) = @_;
 508
 509     my $rulecache = $self->{rulecache};
 510
 511     my $dbh = $self->{ruledb}->{dbh};
 512
 513     # try to reconnect if database connection is broken
 514     if (!$dbh->ping) {
 515         $self->log(0, 'Database connection broken - trying to reconnect');
 516         my $dbh;
 517         eval {
 518             $dbh = PMG::DBTools::open_ruledb($database);
 519         };
 520         my $err = $@;
 521         if ($err) {
 522             $self->log(0, "unable to reconnect to database server: $err");
 523             return 'dunno';
 524         }
 525         $self->{ruledb} = PMG::RuleDB->new($dbh);
 526     }
 527
 528     # some sender substitutions
 529     my ($user, $domain) = split('@', $sender, 2);
 530     if (defined ($user) && defined ($domain)) {
 531         # see http://cr.yp.to/proto/verp.txt
 532         $user =~ s/\+.*//; # strip extensions  (mailing-list VERP)
 533         $user =~ s/\b\d+\b/#/g; #replace nubmers in VERP address
 534         $sender = "$user\@$domain";
 535     }
 536
 537     if ($self->is_backup_mx($ip, $rcpt)) {
 538         $self->log(3, "accept mails from backup MX host - $ip");
 539         return 'dunno';
 540     }
 541
 542     # greylist exclusion (sender whitelist)
 543     if ($rulecache->greylist_match ($sender, $ip)) {
 544         $self->log(3, "accept mails from whitelist - $ip");
 545         return 'dunno';
 546     }
 547
 548     # greylist exclusion (receiver whitelist)
 549     if ($rulecache->greylist_match_receiver ($rcpt)) {
 550         $self->log(3, "accept mails to whitelist - <$rcpt>");
 551         return 'dunno';
 552     }
 553
 554     my ($net, $host) = $ip =~ m/(\d+\.\d+\.\d+)\.(\d+)/; # IPv4 for now
 555     return 'dunno' if !defined($net);
 556
 557     my $spf_header;
 558
 559     if ((!$opt_testmode && $self->{use_spf}) ||
 560         ($opt_testmode && ($rcpt =~ m/^testspf/))) {
 561
 562         # ask SPF
 563         my $spf_result;
 564         my $local_expl,
 565         my $auth_expl;
 566
 567         my $previous_alarm;
 568
 569         my ($result, $smtp_comment, $header_comment);
 570
 571         eval {
 572             $previous_alarm = alarm(10);
 573             local $SIG{ALRM} = sub { die "SPF timeout\n" };
 574
 575             ($result, $spf_header, $local_expl, $auth_expl) =
 576                 $self->get_spf_result($instance, $ip, $helo, $sender);
 577
 578             alarm(0); # avoid race condition
 579         };
 580         my $err = $@;
 581
 582         alarm($previous_alarm) if defined($previous_alarm);
 583
 584         if ($err) {
 585             $err = $err->text if UNIVERSAL::isa ($err, 'Mail::SPF::Exception');
 586             $self->log (0, $err);
 587         } else {
 588
 589             if ($result && $result eq 'pass') {
 590                 $self->log(3, "SPF says $result");
 591                 $spf_result = $spf_header ? "prepend $spf_header" : 'dunno';
 592             }
 593
 594             if ($result && $result eq 'fail') {
 595                 $self->log(3, "SPF says $result");
 596                 $spf_result = "reject ${auth_expl}";
 597
 598                 eval {
 599
 600                     $dbh->begin_work;
 601
 602                     # try to avoid locks everywhere - we use merge instead of insert
 603                     #$dbh->do ("LOCK TABLE CGreylist IN ROW EXCLUSIVE MODE");
 604
 605                     # check if there is already a record in the GL database
 606                     my $sth = $dbh->prepare(
 607                         "SELECT * FROM CGreylist " .
 608                         "where IPNet = ? AND Sender = ? AND Receiver = ?");
 609
 610                     $sth->execute($net, $sender, $rcpt);
 611                     my $ref = $sth->fetchrow_hashref();
 612                     $sth->finish();
 613
 614                     # else add an entry to the GL Database with short
 615                     # expiration time. run_dequeue() moves those entries into the statistic
 616                     # table later. We set 'blocked' to 100000 to identify those entries.
 617
 618                     if (!defined($ref->{rctime})) {
 619
 620                         $dbh->do($PMG::DBTools::cgreylist_merge_sql, undef,
 621                                  $net, $host, $sender, $rcpt, $instance,
 622                                  $ctime, $ctime + 10, 0, 100000, 0, $ctime, $self->{lcid});
 623                     }
 624
 625                     $dbh->commit;
 626                 };
 627                 if (my $err = $@) {
 628                     $dbh->rollback;
 629                     $self->log(0, $err);
 630                 }
 631             }
 632         }
 633
 634         return $spf_result if $spf_result;
 635     }
 636
 637
 638     my $res = 'dunno';
 639
 640     # add spf_header once - SA can re-use this information
 641     if (!defined($self->{cache}->{$instance}) ||
 642         !$self->{cache}->{$instance}->{spf_header_added}) {
 643         $res = "prepend $spf_header" if $spf_header;
 644         $self->{cache}->{$instance}->{spf_header_added} = 1;
 645     }
 646
 647     return $res if !$self->{use_greylist};
 648
 649     my $defer_res = "defer_if_permit Service is unavailable (try later)";
 650
 651     eval {
 652
 653         # we dont use alarm here, because it does not work with DBI
 654
 655         $dbh->begin_work;
 656
 657         # try to avoid locks everywhere - we use merge instead of insert
 658         #$dbh->do ("LOCK TABLE CGreylist IN ROW EXCLUSIVE MODE");
 659
 660         my $sth = $dbh->prepare(
 661             "SELECT * FROM CGreylist " .
 662             "where IPNet = ? AND Sender = ? AND Receiver = ?");
 663
 664         $sth->execute($net, $sender, $rcpt);
 665
 666         my $ref = $sth->fetchrow_hashref();
 667
 668         $sth->finish();
 669
 670         if (!defined($ref->{rctime})) {
 671
 672             $dbh->do($PMG::DBTools::cgreylist_merge_sql, undef,
 673                      $net, $host, $sender, $rcpt, $instance,
 674                      $ctime, $ctime + $greylist_lifetime, 0, 1, 0, $ctime, $self->{lcid});
 675
 676             $res = $defer_res;
 677             $self->log(3, "defer greylisted mail");
 678         } else {
 679             my $age = $ctime - $ref->{rctime};
 680
 681             if ($age < $greylist_delay) {
 682                 # defer (resent within greylist_delay window)
 683                 $res = $defer_res;
 684                 $self->log(3, "defer greylisted mail");
 685                 $dbh->do("UPDATE CGreylist " .
 686                          "SET  Blocked = Blocked + 1, Host = ?, MTime = ? " .
 687                          "WHERE IPNet = ? AND Sender = ? AND Receiver = ?", undef,
 688                          $host, $ctime, $net, $sender, $rcpt);
 689             } else {
 690                 if ($ctime < $ref->{extime}) {
 691                     # accept (not expired)
 692                     my $lifetime = $sender eq "" ? 0 : $greylist_awlifetime;
 693                     my $delay = $ref->{passed} ? "" : "Delay = $age, ";
 694                     $dbh->do("UPDATE CGreylist " .
 695                              "SET  Passed =  Passed + 1, $delay Host = ?, ExTime = ?, MTime = ? " .
 696                              "WHERE IPNet =  ? AND Sender = ? AND Receiver = ?", undef,
 697                              $host, $ctime + $lifetime, $ctime, $net, $sender, $rcpt);
 698                 } else {
 699                     # defer (record is expired)
 700                     $res = $defer_res;
 701                     $dbh->do("UPDATE CGreylist " .
 702                              "SET  Host = ?, RCTime = ?, ExTime = ?, MTime = ?, Instance = ?, " .
 703                              "Blocked = 1, Passed = 0 " .
 704                              "WHERE IPNet =  ? AND Sender = ? AND Receiver = ?", undef,
 705                              $host, $ctime, $ctime + $greylist_lifetime, $ctime, $instance,
 706                              $net, $sender, $rcpt);
 707                 }
 708             }
 709         }
 710
 711         $dbh->commit;
 712     };
 713     if (my $err = $@) {
 714         $dbh->rollback;
 715         $self->log (0, $err);
 716     }
 717
 718     return $res;
 719 }
 720
 721 # shutdown connections: we need this - else file handles are
 722 # not closed and we run out of handles
 723 sub mux_eof {
 724     my ($self, $mux, $fh) = @_;
 725
 726     $mux->shutdown($fh, 1);
 727 }
 728
 729
 730 my $last_reload_test = 0;
 731 my $last_confid_version;
 732 my (undef, $pmgconffilename) = PVE::INotify::ccache_info('pmg.conf');
 733 sub test_config_version {
 734
 735     my $ctime = time();
 736
 737     if (($ctime - $last_reload_test) < 5) { return 0; }
 738
 739     $last_reload_test = $ctime;
 740
 741     my $version = PVE::INotify::poll_changes($pmgconffilename);
 742
 743     if (!defined($last_confid_version) ||
 744         $last_confid_version != $version) {
 745         $last_confid_version = $version;
 746         return 1;
 747     }
 748
 749     return 0;
 750 }
 751
 752 sub mux_input {
 753     my ($self, $mux, $fh, $dataref) = @_;
 754     my $prop = $self->{server};
 755
 756     my $attribute = {};
 757
 758     eval {
 759         $self->{reload_config} = 1 if test_config_version();
 760         $self->load_config() if $self->{reload_config};
 761
 762         while ($$dataref =~ s/^([^\r\n]*)\r?\n//) {
 763             my $line = $1;
 764             next if !defined ($line);
 765
 766             if ($line =~ m/([^=]+)=(.*)/) {
 767                 $attribute->{substr($1, 0, 255)} = substr($2, 0, 255);
 768             } elsif ($line eq '') {
 769                 my $res = 'dunno';
 770                 my $ctime = time;
 771
 772                 if ($opt_testmode) {
 773                     die "undefined test time :ERROR" if !defined $attribute->{testtime};
 774                     $ctime = $attribute->{testtime};
 775                 }
 776
 777                 if ($attribute->{instance} && $attribute->{recipient} &&
 778                     $attribute->{client_address} && $attribute->{request} &&
 779                     $attribute->{request} eq 'smtpd_access_policy') {
 780
 781                     eval {
 782
 783                         $res = $self->greylist_value(
 784                             $ctime,
 785                             lc ($attribute->{helo_name}),
 786                             lc ($attribute->{client_address}),
 787                             lc ($attribute->{sender}),
 788                             lc ($attribute->{recipient}),
 789                             lc ($attribute->{instance}));
 790                     };
 791                     if (my $err = $@) {
 792                         $self->log(0, $err);
 793                     }
 794                 }
 795
 796                 print $fh "action=$res\n\n";
 797
 798                 $attribute = {};
 799             } else {
 800                 $self->log(0, "greylist policy protocol error - got '%s'", $line);
 801             }
 802         }
 803     };
 804     my $err = $@;
 805
 806     # remove remaining data, if any
 807     if ($$dataref ne '') {
 808         $self->log(0, "greylist policy protocol error - unused data '%s'", $$dataref);
 809         $$dataref = '';
 810     }
 811
 812     $self->log(0, $err) if $err;
 813 }
 814
 815 sub restart_close_hook {
 816     my $self = shift;
 817
 818     my $sig_set = POSIX::SigSet->new;
 819     $sig_set->addset(&POSIX::SIGHUP);
 820     $sig_set->addset(&POSIX::SIGCHLD); # to avoid zombies
 821     my $old_sig_set = POSIX::SigSet->new();
 822
 823     sigprocmask(SIG_BLOCK, $sig_set, $old_sig_set);
 824 }
 825
 826 sub pre_server_close_hook {
 827     my $self = shift;
 828
 829     my $prop = $self->{server};
 830
 831     if (defined $prop->{_HUP}) {
 832         undef $prop->{pid_file_unlink};
 833     }
 834
 835     if (defined $prop->{children}) {
 836         foreach my $pid (keys %{$prop->{children}}) {
 837             kill(1, $pid); # HUP childs
 838         }
 839     }
 840
 841     # nicely shutdown childs (give them max 30 seconds to shut down)
 842     my $previous_alarm = alarm(30);
 843     eval {
 844         local $SIG{ALRM} = sub { die "Timed Out!\n" };
 845
 846         my $pid;
 847         1 while ((($pid = waitpid(-1, 0)) > 0) || ($! == EINTR));
 848
 849         alarm(0); # avoid race
 850     };
 851     alarm ($previous_alarm);
 852 }
 853
 854 sub setup_fork_signal_mask {
 855     my $block = shift;
 856
 857     my $sig_set = POSIX::SigSet->new;
 858     $sig_set->addset(&POSIX::SIGINT);
 859     $sig_set->addset(&POSIX::SIGTERM);
 860     $sig_set->addset(&POSIX::SIGQUIT);
 861     $sig_set->addset(&POSIX::SIGHUP);
 862     my $old_sig_set = POSIX::SigSet->new();
 863
 864     if ($block) {
 865         sigprocmask (SIG_BLOCK, $sig_set, $old_sig_set);
 866     } else {
 867         sigprocmask (SIG_UNBLOCK, $sig_set, $old_sig_set);
 868     }
 869 }
 870
 871 # subroutine to start up a specified number of children.
 872 # We need to block signals until handlers are set up correctly.
 873 # Else its possible that HUP occurs after fork, which triggers
 874 # singal TERM at childs and calls server_close() instead of
 875 # simply exit the child.
 876 # Note: on server startup signals are setup to trigger
 877 # asynchronously for a short period of time (in PreForkSimple]::loop,
 878 # run_n_children is called before run_parent)
 879 # Net::Server::PreFork does not have this problem, because it is using
 880 # signal HUP stop children
 881 sub run_n_children {
 882     my ($self, $n)  = @_;
 883
 884     my $prop  = $self->{server};
 885
 886     setup_fork_signal_mask(1); # block signals
 887
 888     $self->SUPER::run_n_children($n);
 889
 890     setup_fork_signal_mask(0); # unblocking signals for parent
 891 }
 892
 893 # test sig_hup with: for ((;;)) ;do kill -HUP  `cat /run/pmgpolicy.pid`; done;
 894 # wrapper to avoid multiple calls to sig_hup
 895 sub sig_hup {
 896     my $self = shift;
 897
 898     my $prop = $self->{server};
 899
 900     return if defined($prop->{_HUP}); # do not call twice
 901
 902     $self->SUPER::sig_hup();
 903 }
 904
 905 ### child process which will accept on the port
 906 sub run_child {
 907     my $self = shift;
 908
 909     my $prop = $self->{server};
 910
 911     $self->log(4, "Child Preforked ($$)\n");
 912
 913     # set correct signal handlers before enabling signals again
 914     $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = sub {
 915         $self->child_finish_hook;
 916         exit;
 917     };
 918
 919     delete $prop->{children};
 920
 921     $self->child_init_hook;
 922
 923     # accept connections
 924
 925     my $sock = $prop->{sock}->[0];
 926
 927     # make sure we got a good sock
 928     if (!defined ($sock)){
 929         $self->log(0, "ERROR: Received a bad socket");
 930         exit (-1);
 931     }
 932
 933     # sometimes the socket is not usable, don't know why
 934     my $flags = fcntl($sock, F_GETFL, 0);
 935     if (!$flags) {
 936         $self->log(0, "socket not ready - $!");
 937         exit (-1);
 938     }
 939
 940     # cache is limited, because postfix does max. 100 queries
 941     $self->{cache} = {};
 942
 943     eval {
 944         my $mux = $self->{mux};
 945         $mux->listen ($sock);
 946         $mux->loop;
 947     };
 948     if (my $err = $@) {
 949         $self->log(0, "ERROR: $err");
 950     }
 951
 952     $self->child_finish_hook;
 953
 954     exit;
 955 }
 956
 957 my $syslog_map = {
 958     0 => 'err',
 959     1 => 'warning',
 960     2 => 'notice',
 961     3 => 'info',
 962     4 => 'debug'
 963 };
 964
 965 sub log {
 966     my ($self, $level, $msg, @therest) = @_;
 967
 968     my $prop = $self->{server};
 969
 970     return if $level =~ /^\d+$/ && $level > $prop->{log_level};
 971
 972     $level = $syslog_map->{$level} || $level;
 973     if (@therest) {
 974         syslog($level, $msg, @therest);
 975     } else {
 976         syslog ($level, $msg);
 977     }
 978 }
 979
 980 my $server = bless {
 981     server => $server_attr,
 982 };
 983
 984 $server->sig_chld(); # avoid zombies after restart
 985
 986 $server->run ();
 987
 988 exit (0);
 989
 990 __END__
 991
 992 =head1 NAME
 993
 994 pmgpolicy - The Proxmox policy daemon
 995
 996 =head1 SYNOPSIS
 997
 998 pmgpolicy
 999
1000 =head1 DESCRIPTION
1001
1002 Documentation is available at www.proxmox.com