backup: fix #3146 add email notifications

this patch addresses the missing email notification for scheduled
backup related tasks, which we have in all our other products, for our
mail product.

the parameter names are inspired by PBS' datastore config.

the default is 'never' in order to stay consistent with the current
code.

it uses the templateing system for the notification, because this
results in less code and a bit of added flexibility for the users.

the recipient address is currently hardcoded to the admin address in
pmg.conf as we also send the (admin) pmgreport there, and I did not
want to overengineer this (even more).

I shortly considered adding a $SIG{'__DIE__'} handler to the
run_backup API call but dropped the idea due to the warning in
perlvar(1).

Signed-off-by: Stoiko Ivanov <s.ivanov@proxmox.com>
Signed-off-by: Thomas Lamprecht <t.lamprecht@proxmox.com>

diff --git a/src/Makefile b/src/Makefile
index 67e6878dfe8ae7384beff713095db8b8ba373d0d..8891a3c905b59355f73f90f4427263410472497d 100644 (file)
--- a/src/Makefile
+++ b/src/Makefile
@@ -43,6 +43,7 @@ TEMPLATES =                           \
        clamd.conf.in                   \
        postgresql.conf.in              \
        pg_hba.conf.in                  \
+       backup-notification.tt          \
 
 TEMPLATES_FILES = $(addprefix templates/, ${TEMPLATES})
 

diff --git a/src/PMG/API2/PBS/Job.pm b/src/PMG/API2/PBS/Job.pm
index c095d258ed9fe33e835147535488c4997f46e029..1177a5a2927bf9f7b051e1982eabcb9c1f46dc56 100644 (file)
--- a/src/PMG/API2/PBS/Job.pm
+++ b/src/PMG/API2/PBS/Job.pm
@@ -273,6 +273,13 @@ __PACKAGE__->register_method ({
                optional => 1,
                default => 1,
            },
+           notify => {
+               description => "Specify when to notify via e-mail",
+               type => 'string',
+               enum => [ 'always', 'error', 'never' ],
+               optional => 1,
+               default => 'never',
+           },
        },
     },
     returns => { type => "string" },
@@ -292,6 +299,7 @@ __PACKAGE__->register_method ({
        die "PBS remote '$remote' is disabled\n" if $remote_config->{disable};
 
        $param->{statistic} //= $remote_config->{'include-statistics'} // 1;
+       my $notify = $param->{notify} // $remote_config->{notify} // 'never';
 
        my $pbs = PVE::PBSClient->new($remote_config, $remote, $conf->{secret_dir});
 
@@ -301,7 +309,10 @@ __PACKAGE__->register_method ({
        my $worker = sub {
            my $upid = shift;
 
-           print "starting update of current backup state\n";
+           my $full_log = "";
+           my $log = sub { print "$_[0]\n"; $full_log .= "$_[0]\n"; };
+
+           $log->("starting update of current backup state");
 
            eval {
                -d $backup_dir || mkdir $backup_dir;
@@ -312,25 +323,32 @@ __PACKAGE__->register_method ({
                rmtree $backup_dir;
            };
            if (my $err = $@) {
+               $log->($err);
+               PMG::Backup::send_backup_notification($notify, $remote, $full_log, $err);
                rmtree $backup_dir;
                die "backup failed: $err\n";
-
            }
-           print "backup finished\n";
+           $log->("backup finished");
 
            my $group = "host/$node";
            if (defined(my $prune_opts = $conf->prune_options($remote))) {
-               print "starting prune of $group\n";
-               my $res = $pbs->prune_group(undef, $prune_opts, $group);
-
+               $log->("starting prune of $group");
+               my $res = eval { $pbs->prune_group(undef, $prune_opts, $group) };
+               if (my $err = $@) {
+                   $log->($err);
+                   PMG::Backup::send_backup_notification($notify, $remote, $full_log, $err);
+                   die "pruning failed: $err\n";
+               }
                foreach my $pruned (@$res){
                    my $time = strftime("%FT%TZ", gmtime($pruned->{'backup-time'}));
                    my $snap = $pruned->{'backup-type'} . '/' . $pruned->{'backup-id'} . '/' .  $time;
-                   print "pruned snapshot: $snap\n";
+                   $log->("pruned snapshot: $snap");
                }
-               print "prune finished\n";
+               $log->("prune finished");
            }
 
+           PMG::Backup::send_backup_notification($notify, $remote, $full_log, undef);
+
            return;
        };
 

diff --git a/src/PMG/Backup.pm b/src/PMG/Backup.pm
index 303bbb4e60bacc1e333618d6686b0833befb9b4d..2f96412f472da83345728eae6822aa8691ed4613 100644 (file)
--- a/src/PMG/Backup.pm
+++ b/src/PMG/Backup.pm
@@ -5,6 +5,7 @@ use warnings;
 use Data::Dumper;
 use File::Basename;
 use File::Path;
+use POSIX qw(strftime);
 
 use PVE::JSONSchema qw(get_standard_option);
 use PVE::Tools;
@@ -376,4 +377,38 @@ sub pmg_restore {
     die $err if $err;
 }
 
+sub send_backup_notification {
+    my ($notify_on, $target, $log, $err) = @_;
+
+    return if !$notify_on;
+    return if $notify_on eq 'never';
+    return if $notify_on eq 'error' && !$err;
+
+    my $cfg = PMG::Config->new();
+    my $email = $cfg->get ('admin', 'email');
+    if (!$email) {
+       warn "not sending notifcation: no admin email configured\n";
+       return;
+    }
+
+    my $nodename = PVE::INotify::nodename();
+    my $fqdn = PVE::Tools::get_fqdn($nodename);
+
+
+    my $vars = {
+       hostname => $nodename,
+       fqdn => $fqdn,
+       date => strftime("%F", localtime()),
+       target => $target,
+       log => $log,
+       err => $err,
+    };
+
+    my $tt = PMG::Config::get_template_toolkit();
+
+    my $mailfrom = "Proxmox Mail Gateway <postmaster>";
+    PMG::Utils::finalize_report($tt, 'backup-notification.tt', $vars, $mailfrom, $email);
+
+}
+
 1;

diff --git a/src/PMG/PBSConfig.pm b/src/PMG/PBSConfig.pm
index 29cff220d1e339e4215b20ed8134193897a9363a..965d162d0be2df1625532d498ba58350ff4306b0 100644 (file)
--- a/src/PMG/PBSConfig.pm
+++ b/src/PMG/PBSConfig.pm
@@ -90,6 +90,12 @@ sub properties {
            description => "Username or API token ID on the Proxmox Backup Server"
        }),
        fingerprint => get_standard_option('fingerprint-sha256'),
+       notify => {
+           description => "Specify when to notify via e-mail",
+           type => 'string',
+           enum => [ 'always', 'error', 'never' ],
+           optional => 1,
+       },
        'include-statistics' => {
            description => "Include statistics in scheduled backups",
            type => 'boolean',
@@ -107,6 +113,7 @@ sub options {
        username => { optional => 1 },
        password => { optional => 1 },
        fingerprint => { optional => 1 },
+       notify => { optional => 1 },
        'include-statistics' => { optional => 1 },
        'keep-last' => { optional => 1 },
        'keep-hourly' =>  { optional => 1 },

diff --git a/src/templates/backup-notification.tt b/src/templates/backup-notification.tt
new file mode 100644 (file)
index 0000000..3f956b0
--- /dev/null
+++ b/src/templates/backup-notification.tt
@@ -0,0 +1,19 @@
+[%- IF err -%]
+[%- SET titleprefix = "Backup failed" -%]
+[%- ELSE %]
+[%- SET titleprefix = "Backup successful" -%]
+[%- END -%]
+[%- IF target -%]
+[%- SET titlesuffix = "to ${target} - ($fqdn)" -%]
+[%- ELSE %]
+[%- SET titlesuffix = "($fqdn)" -%]
+[%- END -%]
+<html>
+  <head>
+    <title>[% titleprefix %] [% titlesuffix %]</title>
+  </head>
+  <body>
+    Detailed backup logs:<br /><br />
+    <pre>[% log %]</pre>
+  </body>
+</html>