PVE/API2/AccessControl.pm

   1 package PVE::API2::AccessControl;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::Exception qw(raise raise_perm_exc);
   7 use PVE::SafeSyslog;
   8 use PVE::RPCEnvironment;
   9 use PVE::Cluster qw(cfs_read_file);
  10 use PVE::RESTHandler;
  11 use PVE::AccessControl;
  12 use PVE::JSONSchema qw(get_standard_option);
  13 use PVE::API2::Domains;
  14 use PVE::API2::User;
  15 use PVE::API2::Group;
  16 use PVE::API2::Role;
  17 use PVE::API2::ACL;
  18
  19 use base qw(PVE::RESTHandler);
  20
  21 __PACKAGE__->register_method ({
  22     subclass => "PVE::API2::User",
  23     path => 'users',
  24 });
  25
  26 __PACKAGE__->register_method ({
  27     subclass => "PVE::API2::Group",
  28     path => 'groups',
  29 });
  30
  31 __PACKAGE__->register_method ({
  32     subclass => "PVE::API2::Role",
  33     path => 'roles',
  34 });
  35
  36 __PACKAGE__->register_method ({
  37     subclass => "PVE::API2::ACL",
  38     path => 'acl',
  39 });
  40
  41 __PACKAGE__->register_method ({
  42     subclass => "PVE::API2::Domains",
  43     path => 'domains',
  44 });
  45
  46 __PACKAGE__->register_method ({
  47     name => 'index',
  48     path => '',
  49     method => 'GET',
  50     description => "Directory index.",
  51     permissions => {
  52         user => 'all',
  53     },
  54     parameters => {
  55         additionalProperties => 0,
  56         properties => {},
  57     },
  58     returns => {
  59         type => 'array',
  60         items => {
  61             type => "object",
  62             properties => {
  63                 subdir => { type => 'string' },
  64             },
  65         },
  66         links => [ { rel => 'child', href => "{subdir}" } ],
  67     },
  68     code => sub {
  69         my ($param) = @_;
  70
  71         my $res = [];
  72
  73         my $ma = __PACKAGE__->method_attributes();
  74
  75         foreach my $info (@$ma) {
  76             next if !$info->{subclass};
  77
  78             my $subpath = $info->{match_re}->[0];
  79
  80             push @$res, { subdir => $subpath };
  81         }
  82
  83         push @$res, { subdir => 'ticket' };
  84         push @$res, { subdir => 'password' };
  85
  86         return $res;
  87     }});
  88
  89
  90 my $verify_auth = sub {
  91     my ($rpcenv, $username, $pw_or_ticket, $path, $privs) = @_;
  92
  93     my $normpath = PVE::AccessControl::normalize_path($path);
  94
  95     my $ticketuser;
  96     if (($ticketuser = PVE::AccessControl::verify_ticket($pw_or_ticket, 1)) &&
  97         ($ticketuser eq $username)) {
  98         # valid ticket
  99     } elsif (PVE::AccessControl::verify_vnc_ticket($pw_or_ticket, $username, $normpath, 1)) {
 100         # valid vnc ticket
 101     } else {
 102         $username = PVE::AccessControl::authenticate_user($username, $pw_or_ticket);
 103     }
 104
 105     my $privlist = [ PVE::Tools::split_list($privs) ];
 106     if (!($normpath && scalar(@$privlist) && $rpcenv->check($username, $normpath, $privlist))) {
 107         die "no permission ($path, $privs)\n";
 108     }
 109
 110     return { username => $username };
 111 };
 112
 113 my $create_ticket = sub {
 114     my ($rpcenv, $username, $pw_or_ticket) = @_;
 115
 116     my $ticketuser;
 117     if (($ticketuser = PVE::AccessControl::verify_ticket($pw_or_ticket, 1)) &&
 118         ($ticketuser eq 'root@pam' || $ticketuser eq $username)) {
 119         # valid ticket. Note: root@pam can create tickets for other users
 120     } else {
 121         $username = PVE::AccessControl::authenticate_user($username, $pw_or_ticket);
 122     }
 123
 124     my $ticket = PVE::AccessControl::assemble_ticket($username);
 125     my $csrftoken = PVE::AccessControl::assemble_csrf_prevention_token($username);
 126
 127     return {
 128         ticket => $ticket,
 129         username => $username,
 130         CSRFPreventionToken => $csrftoken,
 131     };
 132 };
 133
 134 my $compute_api_permission = sub {
 135     my ($rpcenv, $authuser) = @_;
 136
 137     my $usercfg = $rpcenv->{user_cfg};
 138
 139     my $nodelist = PVE::Cluster::get_nodelist();
 140     my $vmlist = PVE::Cluster::get_vmlist() || {};
 141     my $idlist = $vmlist->{ids} || {};
 142
 143     my $cfg = PVE::Storage::config();
 144     my @sids =  PVE::Storage::storage_ids ($cfg);
 145
 146     my $res = {
 147         vms => {},
 148         storage => {},
 149         access => {},
 150         nodes => {},
 151         dc => {},
 152     };
 153
 154     my $extract_vm_caps = sub {
 155         my ($path) = @_;
 156
 157         my $perm = $rpcenv->permissions($authuser, $path);
 158         foreach my $priv (keys %$perm) {
 159             next if !($priv eq 'Permissions.Modify' || $priv =~ m/^VM\./);
 160             $res->{vms}->{$priv} = 1;
 161         }
 162     };
 163
 164     foreach my $pool (keys %{$usercfg->{pools}}) {
 165         &$extract_vm_caps("/pool/$pool");
 166     }
 167
 168     foreach my $vmid (keys %$idlist, '__phantom__') {
 169         &$extract_vm_caps("/vms/$vmid");
 170     }
 171
 172     foreach my $storeid (@sids, '__phantom__') {
 173         my $perm = $rpcenv->permissions($authuser, "/storage/$storeid");
 174         foreach my $priv (keys %$perm) {
 175             next if !($priv eq 'Permissions.Modify' || $priv =~ m/^Datastore\./);
 176             $res->{storage}->{$priv} = 1;
 177         }
 178     }
 179
 180     foreach my $path (('/access/groups')) {
 181         my $perm = $rpcenv->permissions($authuser, $path);
 182         foreach my $priv (keys %$perm) {
 183             next if $priv !~ m/^(User|Group)\./;
 184             $res->{access}->{$priv} = 1;
 185         }
 186     }
 187
 188     foreach my $group (keys %{$usercfg->{users}->{$authuser}->{groups}}, '__phantom__') {
 189         my $perm = $rpcenv->permissions($authuser, "/access/groups/$group");
 190         if ($perm->{'User.Modify'}) {
 191             $res->{access}->{'User.Modify'} = 1;
 192         }
 193     }
 194
 195     foreach my $node (@$nodelist) {
 196         my $perm = $rpcenv->permissions($authuser, "/nodes/$node");
 197         foreach my $priv (keys %$perm) {
 198             next if $priv !~ m/^Sys\./;
 199             $res->{nodes}->{$priv} = 1;
 200         }
 201     }
 202
 203     my $perm = $rpcenv->permissions($authuser, "/");
 204     $res->{dc}->{'Sys.Audit'} = 1 if $perm->{'Sys.Audit'};
 205
 206     return $res;
 207 };
 208
 209 __PACKAGE__->register_method ({
 210     name => 'get_ticket',
 211     path => 'ticket',
 212     method => 'GET',
 213     permissions => { user => 'world' },
 214     description => "Dummy. Useful for formaters which want to priovde a login page.",
 215     parameters => {
 216         additionalProperties => 0,
 217     },
 218     returns => { type => "null" },
 219     code => sub { return undef; }});
 220
 221 __PACKAGE__->register_method ({
 222     name => 'create_ticket',
 223     path => 'ticket',
 224     method => 'POST',
 225     permissions => {
 226         description => "You need to pass valid credientials.",
 227         user => 'world'
 228     },
 229     protected => 1, # else we can't access shadow files
 230     description => "Create or verify authentication ticket.",
 231     parameters => {
 232         additionalProperties => 0,
 233         properties => {
 234             username => {
 235                 description => "User name",
 236                 type => 'string',
 237                 maxLength => 64,
 238             },
 239             realm =>  get_standard_option('realm', {
 240                 description => "You can optionally pass the realm using this parameter. Normally the realm is simply added to the username <username>\@<relam>.",
 241                 optional => 1}),
 242             password => {
 243                 description => "The secret password. This can also be a valid ticket.",
 244                 type => 'string',
 245             },
 246             path => {
 247                 description => "Verify ticket, and check if user have access 'privs' on 'path'",
 248                 type => 'string',
 249                 requires => 'privs',
 250                 optional => 1,
 251                 maxLength => 64,
 252             },
 253             privs => {
 254                 description => "Verify ticket, and check if user have access 'privs' on 'path'",
 255                 type => 'string' , format => 'pve-priv-list',
 256                 requires => 'path',
 257                 optional => 1,
 258                 maxLength => 64,
 259             },
 260         }
 261     },
 262     returns => {
 263         type => "object",
 264         properties => {
 265             username => { type => 'string' },
 266             ticket => { type => 'string', optional => 1},
 267             CSRFPreventionToken => { type => 'string', optional => 1 },
 268         }
 269     },
 270     code => sub {
 271         my ($param) = @_;
 272
 273         my $username = $param->{username};
 274         $username .= "\@$param->{realm}" if $param->{realm};
 275
 276         my $rpcenv = PVE::RPCEnvironment::get();
 277
 278         my $res;
 279         eval {
 280             # test if user exists and is enabled
 281             $rpcenv->check_user_enabled($username);
 282
 283             if ($param->{path} && $param->{privs}) {
 284                 $res = &$verify_auth($rpcenv, $username, $param->{password},
 285                                      $param->{path}, $param->{privs});
 286             } else {
 287                 $res = &$create_ticket($rpcenv, $username, $param->{password});
 288             }
 289         };
 290         if (my $err = $@) {
 291             my $clientip = $rpcenv->get_client_ip() || '';
 292             syslog('err', "authentication failure; rhost=$clientip user=$username msg=$err");
 293             # do not return any info to prevent user enumeration attacks
 294             die PVE::Exception->new("authentication failure\n", code => 401);
 295         }
 296
 297         $res->{cap} = &$compute_api_permission($rpcenv, $username);
 298
 299         PVE::Cluster::log_msg('info', 'root@pam', "successful auth for user '$username'");
 300
 301         return $res;
 302     }});
 303
 304 __PACKAGE__->register_method ({
 305     name => 'change_passsword',
 306     path => 'password',
 307     method => 'PUT',
 308     permissions => {
 309         description => "Each user is allowed to change his own password. A user can change the password of another user if he has 'Realm.AllocateUser' (on the realm of user <userid>) and 'User.Modify' permission on /access/groups/<group> on a group where user <userid> is member of.",
 310         check => [ 'or',
 311                    ['userid-param', 'self'],
 312                    [ 'and',
 313                      [ 'userid-param', 'Realm.AllocateUser'],
 314                      [ 'userid-group', ['User.Modify']]
 315                    ]
 316             ],
 317     },
 318     protected => 1, # else we can't access shadow files
 319     description => "Change user password.",
 320     parameters => {
 321         additionalProperties => 0,
 322         properties => {
 323             userid => get_standard_option('userid'),
 324             password => {
 325                 description => "The new password.",
 326                 type => 'string',
 327                 minLength => 5,
 328                 maxLength => 64,
 329             },
 330         }
 331     },
 332     returns => { type => "null" },
 333     code => sub {
 334         my ($param) = @_;
 335
 336         my $rpcenv = PVE::RPCEnvironment::get();
 337         my $authuser = $rpcenv->get_user();
 338
 339         my ($userid, $ruid, $realm) = PVE::AccessControl::verify_username($param->{userid});
 340
 341         $rpcenv->check_user_exist($userid);
 342
 343         if ($authuser eq 'root@pam') {
 344             # OK - root can change anything
 345         } else {
 346             if ($authuser eq $userid) {
 347                 $rpcenv->check_user_enabled($userid);
 348                 # OK - each user can change its own password
 349             } else {
 350                 # only root may change root password
 351                 raise_perm_exc() if $userid eq 'root@pam';
 352                 # do not allow to change system user passwords
 353                 raise_perm_exc() if $realm eq 'pam';
 354             }
 355         }
 356
 357         PVE::AccessControl::domain_set_password($realm, $ruid, $param->{password});
 358
 359         PVE::Cluster::log_msg('info', 'root@pam', "changed password for user '$userid'");
 360
 361         return undef;
 362     }});
 363
 364 1;